qcsrc/server/campaign.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qh"
   5     #include "../dpdefs/dpextensions.qh"
   6     #include "autocvars.qh"
   7     #include "defs.qh"
   8     #include "campaign.qh"
   9     #include "../common/campaign_common.qh"
  10     #include "../common/mapinfo.qh"
  11     #include "cheats.qh"
  12 #endif
  13
  14 // campaign cvars:
  15 //   _campaign_index: index of CURRENT map
  16 //   _campaign_name: name of the current campaign
  17 //   g_campaign(name)_index: index of current LAST map (saved)
  18 //   g_campaign_skill: bot skill offset
  19
  20 float campaign_level;
  21 float campaign_won;
  22 string campaign_index_var;
  23 //float checkrules_equality;
  24
  25 float CampaignBailout(string s)
  26 {
  27         cvar = cvar_normal;
  28         cvar_string = cvar_string_normal;
  29         cvar_set = cvar_set_normal;
  30         cvar_set("g_campaign", "0");
  31         print("^4campaign initialization failed: ", s, "\n");
  32         if(autocvar__campaign_testrun)
  33                 error("CAMPAIGN FAIL AHAHAHAHAHAHAHAHAH))");
  34         return 1;
  35 }
  36
  37 string cvar_campaignwrapper_list; // string of format ; var value; var value; var value;
  38 string cvar_string_campaignwrapper(string theCvar)
  39 {
  40         float p, q;
  41         p = strstrofs(cvar_campaignwrapper_list, strcat("; ", theCvar, " "), 0);
  42         if(p < 0)
  43                 return cvar_defstring(theCvar);
  44         p += strlen(theCvar) + 3;
  45         q = strstrofs(cvar_campaignwrapper_list, ";", p);
  46         if(q < 0)
  47                 return cvar_defstring(theCvar);
  48         return substring(cvar_campaignwrapper_list, p, q - p);
  49 }
  50 float cvar_campaignwrapper(string theCvar)
  51 {
  52         return stof(cvar_string_campaignwrapper(theCvar));
  53 }
  54 void cvar_set_campaignwrapper(string theCvar, string theValue)
  55 {
  56         if(cvar_string_campaignwrapper(theCvar) == theValue)
  57                 return;
  58         string s;
  59         s = cvar_campaignwrapper_list;
  60         cvar_campaignwrapper_list = strzone(strcat("; ", theCvar, " ", theValue, s));
  61         strunzone(s);
  62         //print(cvar_campaignwrapper_list, "\n");
  63 }
  64
  65 float Campaign_Invalid()
  66 {
  67         string thismapname, wantedmapname;
  68         thismapname = GetMapname();
  69         wantedmapname = campaign_gametype[0];
  70         if(MapInfo_CurrentGametype() != MapInfo_Type_FromString(wantedmapname))
  71                 return CampaignBailout("wrong game type!");
  72         wantedmapname = campaign_mapname[0];
  73         if(wantedmapname != thismapname)
  74                 return CampaignBailout(strcat("wrong map: ", wantedmapname, " != ", thismapname));
  75         return 0;
  76 }
  77
  78 void CampaignPreInit()
  79 {
  80         float baseskill;
  81         string title;
  82         if(autocvar_sv_cheats)
  83         {
  84                 CampaignBailout("JOLLY CHEATS AHAHAHAHAHAHAH))");
  85                 return;
  86         }
  87         campaign_level = autocvar__campaign_index;
  88         campaign_name = strzone(autocvar__campaign_name);
  89         campaign_index_var = strzone(strcat("g_campaign", campaign_name, "_index"));
  90         CampaignFile_Load(campaign_level, 2);
  91         if(campaign_entries < 1)
  92         {
  93                 CampaignBailout("unknown map");
  94                 return;
  95         }
  96
  97         baseskill = autocvar_g_campaign_skill;
  98         baseskill = baseskill + campaign_botskill[0];
  99         if(baseskill < 0)
 100                 baseskill = 0;
 101
 102         cvar_set("sv_public", "0");
 103         cvar_set("pausable", "1");
 104
 105         cvar_campaignwrapper_list = strzone(strcat("; ", campaign_mutators[0], "; "));
 106
 107         cvar = cvar_campaignwrapper;
 108         cvar_string = cvar_string_campaignwrapper;
 109         cvar_set = cvar_set_campaignwrapper;
 110
 111         cvar_set("g_campaign", "1");
 112         cvar_set("g_dm", "0");
 113         cvar_set("skill", ftos(baseskill));
 114         cvar_set("bot_number", ftos(campaign_bots[0]));
 115         MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0]));
 116
 117         // copy sv_gravity cvar, as the engine needs it too (sorry, this will mess
 118         // with the menu a little still...)
 119         cvar_set_normal("sv_gravity", ftos(autocvar_sv_gravity));
 120
 121         if(Campaign_Invalid())
 122                 return;
 123
 124         title = campaign_shortdesc[0];
 125         title = strzone(strcat("Level ", ftos(campaign_level + 1), ": ", title));
 126         campaign_message = strzone(strcat(title, "\n^3\n", campaign_longdesc[0], "\n\n^1press jump to enter the game"));
 127         strunzone(title);
 128 }
 129
 130 string GetMapname();
 131 void CampaignPostInit()
 132 {
 133         // now some sanity checks
 134         if(Campaign_Invalid())
 135                 return;
 136         if(autocvar__campaign_testrun)
 137         {
 138                 cvar_set("fraglimit", "0");
 139                 cvar_set("timelimit", "0.01");
 140                 cvar_set_normal("fraglimit", "0");
 141                 cvar_set_normal("timelimit", "0.01");
 142         }
 143         else
 144         {
 145                 cvar_set("fraglimit", ftos(campaign_fraglimit[0]));
 146                 cvar_set("timelimit", ftos(campaign_timelimit[0]));
 147                 cvar_set_normal("fraglimit", ftos(campaign_fraglimit[0]));
 148                 cvar_set_normal("timelimit", ftos(campaign_timelimit[0]));
 149         }
 150 }
 151
 152 void CampaignSaveCvar(string cvarname, float value)
 153 {
 154         float fh;
 155         float len;
 156         string contents;
 157         string l;
 158
 159         registercvar(cvarname, ftos(value));
 160         cvar_set_normal(cvarname, ftos(value));
 161         // note: cvarname must be remembered
 162
 163         fh = fopen("campaign.cfg", FILE_READ);
 164         contents = "";
 165         if(fh >= 0)
 166         {
 167                 while((l = fgets(fh)))
 168                 {
 169                         len = tokenize_console(l);
 170                         if(len != 3)
 171                                 continue;
 172                         if(argv(0) != "set")
 173                                 continue;
 174                         if(argv(1) == cvarname)
 175                                 continue;
 176                         contents = strcat(contents, "set ", argv(1), " ", argv(2), "\n");
 177                 }
 178                 fclose(fh);
 179         }
 180         contents = strcat(contents, "set ", cvarname,  " ", ftos(value), "\n");
 181         fh = fopen("campaign.cfg", FILE_WRITE);
 182         if(fh >= 0)
 183         {
 184                 fputs(fh, contents);
 185         }
 186         else
 187         {
 188                 error("Cannot write to campaign file");
 189         }
 190 }
 191
 192 void CampaignPreIntermission()
 193 {
 194         entity head;
 195         float won;
 196         float lost;
 197         string savevar;
 198
 199         won = lost = 0;
 200
 201         head = findchain(classname, "player");
 202         while(head)
 203         {
 204                 if(IS_REAL_CLIENT(head))
 205                 {
 206                         if(head.winning)
 207                                 won = won + 1;
 208                         else
 209                                 lost = lost + 1;
 210                 }
 211                 head = head.chain;
 212         }
 213
 214         if(autocvar__campaign_testrun)
 215         {
 216                 campaign_won = 1;
 217                 bprint("Campaign test run, advancing level.\n");
 218         }
 219         else if(won == 1 && lost == 0 && checkrules_equality == 0)
 220         {
 221                 if(autocvar_timelimit != 0 && autocvar_fraglimit != 0 && time > autocvar_timelimit * 60) // checks if the timelimit has expired.
 222                 {
 223                         campaign_won = 0;
 224                         bprint("Time's up! The current level has been LOST.\n");
 225                         // sound!
 226                 }
 227                 else
 228                 {
 229                         campaign_won = 1;
 230                         bprint("The current level has been WON.\n");
 231                         // sound!
 232                 }
 233         }
 234         else if(autocvar_timelimit != 0 && time > autocvar_timelimit * 60)
 235         {
 236                 campaign_won = 0;
 237                 bprint("Time's up! The current level has been LOST.\n");
 238                 // sound!
 239         }
 240         else
 241         {
 242                 campaign_won = 0;
 243                 bprint("The current level has been LOST.\n");
 244                 // sound!
 245         }
 246
 247         if(campaign_won && cheatcount_total == 0 && !autocvar__campaign_testrun)
 248         {
 249                 if(campaign_level == cvar_normal(campaign_index_var))
 250                 {
 251                         if(campaign_entries < 2)
 252                         {
 253                                 // I have won
 254                                 savevar = strcat("g_campaign", campaign_name, "_won");
 255                                 CampaignSaveCvar(savevar, 1);
 256                                 // advance level (for menu to show it right)
 257                                 CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 258                         }
 259                         else
 260                         {
 261                                 // advance level
 262                                 CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 263                         }
 264                 }
 265         }
 266 }
 267
 268 void CampaignPostIntermission()
 269 {
 270         // NOTE: campaign_won is 0 or 1, that is, points to the next level
 271
 272         if(campaign_won && campaign_entries < 2)
 273         {
 274                 // last map won!
 275                 print("^2test run: campaign looks GOOD\n");
 276                 localcmd("togglemenu 1\n");
 277                 CampaignFile_Unload();
 278                 return;
 279         }
 280
 281         CampaignSetup(campaign_won);
 282         CampaignFile_Unload();
 283         strunzone(campaign_message);
 284         strunzone(campaign_index_var);
 285         strunzone(campaign_name);
 286         campaign_name = "";
 287 }
 288
 289
 290
 291 void CampaignLevelWarp(float n)
 292 {
 293         if(n < 0)
 294                 n = campaign_level + 1;
 295         CampaignFile_Unload();
 296         CampaignFile_Load(n, 1);
 297         if(campaign_entries)
 298                 CampaignSetup(0);
 299         else
 300                 error("Sorry, cheater. You are NOT WELCOME.");
 301         CampaignFile_Unload();
 302 }
 303