qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.v_angle = oldself.v_angle;
 159         self.avelocity = oldself.avelocity;
 160         self.classname = "body";
 161         self.damageforcescale = oldself.damageforcescale;
 162         self.effects = oldself.effects;
 163         self.glowmod = oldself.glowmod;
 164         self.event_damage = oldself.event_damage;
 165         self.anim_state = oldself.anim_state;
 166         self.anim_time = oldself.anim_time;
 167         self.anim_lower_action = oldself.anim_lower_action;
 168         self.anim_lower_time = oldself.anim_lower_time;
 169         self.anim_upper_action = oldself.anim_upper_action;
 170         self.anim_upper_time = oldself.anim_upper_time;
 171         self.anim_implicit_state = oldself.anim_implicit_state;
 172         self.anim_implicit_time = oldself.anim_implicit_time;
 173         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 174         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 175         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 176         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 177         self.dphitcontentsmask = oldself.dphitcontentsmask;
 178         self.death_time = oldself.death_time;
 179         self.pain_finished = oldself.pain_finished;
 180         self.health = oldself.health;
 181         self.armorvalue = oldself.armorvalue;
 182         self.armortype = oldself.armortype;
 183         self.model = oldself.model;
 184         self.modelindex = oldself.modelindex;
 185         self.skin = oldself.skin;
 186         self.species = oldself.species;
 187         self.movetype = oldself.movetype;
 188         self.solid = oldself.solid;
 189         self.ballistics_density = oldself.ballistics_density;
 190         self.takedamage = oldself.takedamage;
 191         self.customizeentityforclient = oldself.customizeentityforclient;
 192         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 193         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 194         if (keepvelocity == 1)
 195                 self.velocity = oldself.velocity;
 196         self.oldvelocity = self.velocity;
 197         self.alpha = oldself.alpha;
 198         self.fade_time = oldself.fade_time;
 199         self.fade_rate = oldself.fade_rate;
 200         //self.weapon = oldself.weapon;
 201         setorigin(self, oldself.origin);
 202         setsize(self, oldself.mins, oldself.maxs);
 203         self.prevorigin = oldself.origin;
 204         self.reset = SUB_Remove;
 205
 206         Drag_MoveDrag(oldself, self);
 207
 208         if(self.colormap <= maxclients && self.colormap > 0)
 209                 self.colormap = 1024 + oldself.clientcolors;
 210
 211         CSQCMODEL_AUTOINIT();
 212         self.CopyBody_nextthink = oldself.nextthink;
 213         self.CopyBody_think = oldself.think;
 214         self.nextthink = time;
 215         self.think = CopyBody_Think;
 216         // "bake" the current animation frame for clones (they don't get clientside animation)
 217         animdecide_init(self);
 218         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 219
 220         self = oldself;
 221 }
 222
 223 float player_getspecies()
 224 {
 225         float s;
 226         get_model_parameters(self.model, self.skin);
 227         s = get_model_parameters_species;
 228         get_model_parameters(string_null, 0);
 229         if(s < 0)
 230                 return SPECIES_HUMAN;
 231         return s;
 232 }
 233
 234 void player_setupanimsformodel()
 235 {
 236         // load animation info
 237         animdecide_init(self);
 238         animdecide_setstate(self, 0, FALSE);
 239 }
 240
 241 void player_anim (void)
 242 {
 243         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 244         if(self.deadflag && !deadbits)
 245                 if(random() < 0.5)
 246                         deadbits = ANIMSTATE_DEAD1;
 247                 else
 248                         deadbits = ANIMSTATE_DEAD2;
 249         float animbits = deadbits;
 250         if(self.frozen)
 251                 animbits |= ANIMSTATE_FROZEN;
 252         if(self.crouch)
 253                 animbits |= ANIMSTATE_DUCK;
 254         animdecide_setstate(self, animbits, FALSE);
 255         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 256
 257         if (self.weaponentity)
 258         {
 259                 updateanim(self.weaponentity);
 260                 if (!self.weaponentity.animstate_override)
 261                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 262         }
 263 }
 264
 265 void SpawnThrownWeapon (vector org, float w)
 266 {
 267         if(self.weapons & WepSet_FromWeapon(self.weapon))
 268                 if(W_IsWeaponThrowable(self.weapon))
 269                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 270 }
 271
 272 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 273 {
 274         float take, save;
 275         vector v;
 276         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 277
 278         // damage resistance (ignore most of the damage from a bullet or similar)
 279         damage = max(damage - 5, 1);
 280
 281         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 282         take = v_x;
 283         save = v_y;
 284
 285         if(sound_allowed(MSG_BROADCAST, attacker))
 286         {
 287                 if (save > 10)
 288                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 289                 else if (take > 30)
 290                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 291                 else if (take > 10)
 292                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);
 293         }
 294
 295         if (take > 50)
 296                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 297         if (take > 100)
 298                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 299
 300         if (!(self.flags & FL_GODMODE))
 301         {
 302                 self.armorvalue = self.armorvalue - save;
 303                 self.health = self.health - take;
 304                 // pause regeneration for 5 seconds
 305                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 306         }
 307         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 308         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 309         self.dmg_inflictor = inflictor;
 310
 311         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 312         {
 313                 // don't use any animations as a gib
 314                 self.frame = 0;
 315                 // view just above the floor
 316                 self.view_ofs = '0 0 4';
 317
 318                 Violence_GibSplash(self, 1, 1, attacker);
 319                 self.alpha = -1;
 320                 self.solid = SOLID_NOT; // restore later
 321                 self.takedamage = DAMAGE_NO; // restore later
 322                 self.damagedbycontents = FALSE;
 323         }
 324 }
 325
 326 // g_<gametype>_str:
 327 // If 0, default is used.
 328 // If <0, 0 is used.
 329 // Otherwise, g_str (default value) is used.
 330 // For consistency, negative values there are mapped to zero too.
 331 #define GAMETYPE_DEFAULTED_SETTING(str) \
 332         ((gametype_setting_tmp = cvar(strcat("g_", GetGametype(), "_" #str))), \
 333          (gametype_setting_tmp < 0) ? 0 : \
 334          (gametype_setting_tmp == 0) ? max(0, autocvar_g_##str) : \
 335          gametype_setting_tmp)
 336
 337
 338 void calculate_player_respawn_time()
 339 {
 340         float gametype_setting_tmp;
 341         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 342         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 343         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 344         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 345         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 346         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 347
 348         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 349         entity pl;
 350         if (teamplay)
 351         {
 352                 FOR_EACH_PLAYER(pl)
 353                         if (pl != self)
 354                                 if (pl.team == self.team)
 355                                         ++pcount;
 356                 if (sdelay_small_count == 0)
 357                         sdelay_small_count = 1;
 358                 if (sdelay_large_count == 0)
 359                         sdelay_large_count = 1;
 360         }
 361         else
 362         {
 363                 FOR_EACH_PLAYER(pl)
 364                         if (pl != self)
 365                                 ++pcount;
 366                 if (sdelay_small_count == 0)
 367                 {
 368                         if (g_cts)
 369                         {
 370                                 // Players play independently. No point in requiring enemies.
 371                                 sdelay_small_count = 1;
 372                         }
 373                         else
 374                         {
 375                                 // Players play AGAINST each other. Enemies required.
 376                                 sdelay_small_count = 2;
 377                         }
 378                 }
 379                 if (sdelay_large_count == 0)
 380                 {
 381                         if (g_cts)
 382                         {
 383                                 // Players play independently. No point in requiring enemies.
 384                                 sdelay_large_count = 1;
 385                         }
 386                         else
 387                         {
 388                                 // Players play AGAINST each other. Enemies required.
 389                                 sdelay_large_count = 2;
 390                         }
 391                 }
 392         }
 393
 394         float sdelay;
 395
 396         if (pcount <= sdelay_small_count)
 397                 sdelay = sdelay_small;
 398         else if (pcount >= sdelay_large_count)
 399                 sdelay = sdelay_large;
 400         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 401                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 402
 403         if(waves)
 404                 self.respawn_time = ceil((time + sdelay) / waves) * waves;
 405         else
 406                 self.respawn_time = time + sdelay;
 407
 408         if(sdelay < sdelay_max)
 409                 self.respawn_time_max = time + sdelay_max;
 410         else
 411                 self.respawn_time_max = self.respawn_time;
 412
 413         if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 414                 self.respawn_countdown = 10; // first number to count down from is 10
 415         else
 416                 self.respawn_countdown = -1; // do not count down
 417
 418         if(autocvar_g_forced_respawn)
 419                 self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 420 }
 421
 422 void ClientKill_Now_TeamChange();
 423
 424 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 425 {
 426         float take, save, dh, da, j;
 427         vector v;
 428         float valid_damage_for_weaponstats;
 429         float excess;
 430
 431         dh = max(self.health, 0);
 432         da = max(self.armorvalue, 0);
 433
 434         if(!DEATH_ISSPECIAL(deathtype))
 435         {
 436                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 437                 if(self != attacker)
 438                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 439         }
 440
 441         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 442         {
 443                 // tuba causes blood to come out of the ears
 444                 vector ear1, ear2;
 445                 vector d;
 446                 float f;
 447                 ear1 = self.origin;
 448                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 449                 ear2 = ear1;
 450                 makevectors(self.angles);
 451                 ear1 += v_right * -10;
 452                 ear2 += v_right * +10;
 453                 d = inflictor.origin - self.origin;
 454                 if (d)
 455                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 456                 else
 457                         f = 0;  // Assum ecenter.
 458                 force = v_right * vlen(force);
 459                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 460                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 461                 if(f > 0)
 462                 {
 463                         hitloc = ear1;
 464                         force = force * -1;
 465                 }
 466                 else
 467                 {
 468                         hitloc = ear2;
 469                         // force is already good
 470                 }
 471         }
 472         else
 473                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 474
 475
 476         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 477         take = v_x;
 478         save = v_y;
 479
 480         if(attacker == self)
 481         {
 482                 // don't reset pushltime for self damage as it may be an attempt to
 483                 // escape a lava pit or similar
 484                 //self.pushltime = 0;
 485                 self.istypefrag = 0;
 486         }
 487         else if(IS_PLAYER(attacker))
 488         {
 489                 self.pusher = attacker;
 490                 self.pushltime = time + autocvar_g_maxpushtime;
 491                 self.istypefrag = self.BUTTON_CHAT;
 492         }
 493         else if(time < self.pushltime)
 494         {
 495                 attacker = self.pusher;
 496                 self.pushltime = max(self.pushltime, time + 0.6);
 497         }
 498         else
 499         {
 500                 self.pushltime = 0;
 501                 self.istypefrag = 0;
 502         }
 503
 504         frag_inflictor = inflictor;
 505         frag_attacker = attacker;
 506         frag_target = self;
 507         frag_damage = damage;
 508         damage_take = take;
 509         damage_save = save;
 510         damage_force = force;
 511         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 512         take = bound(0, damage_take, self.health);
 513         save = bound(0, damage_save, self.armorvalue);
 514         excess = max(0, damage - take - save);
 515
 516         if(sound_allowed(MSG_BROADCAST, attacker))
 517         {
 518                 if (save > 10)
 519                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 520                 else if (take > 30)
 521                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 522                 else if (take > 10)
 523                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 524         }
 525
 526         if (take > 50)
 527                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 528         if (take > 100)
 529                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 530
 531         if (time >= self.spawnshieldtime)
 532         {
 533                 if (!(self.flags & FL_GODMODE))
 534                 {
 535                         self.armorvalue = self.armorvalue - save;
 536                         self.health = self.health - take;
 537                         // pause regeneration for 5 seconds
 538                         if(take)
 539                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 540
 541                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 542                         {
 543                                 self.pain_finished = time + 0.5;        //Supajoe
 544
 545                                 if(autocvar_sv_gentle < 1) {
 546                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 547                                         {
 548                                                 if (!self.animstate_override)
 549                                                 {
 550                                                         if (random() > 0.5)
 551                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 552                                                         else
 553                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 554                                                 }
 555                                         }
 556
 557                                         if(sound_allowed(MSG_BROADCAST, attacker))
 558                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 559                                         if(self.health > 1)
 560                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 561                                         {
 562                                                 if(deathtype == DEATH_FALL)
 563                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 564                                                 else if(self.health > 75) // TODO make a "gentle" version?
 565                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 566                                                 else if(self.health > 50)
 567                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 568                                                 else if(self.health > 25)
 569                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 570                                                 else
 571                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 572                                         }
 573                                 }
 574
 575                                 // throw off bot aim temporarily
 576                                 float shake;
 577                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 578                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 579                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 580                         }
 581                 }
 582                 else
 583                         self.max_armorvalue += (save + take);
 584         }
 585         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 586         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 587         self.dmg_inflictor = inflictor;
 588
 589         float abot, vbot, awep;
 590         abot = (IS_BOT_CLIENT(attacker));
 591         vbot = (IS_BOT_CLIENT(self));
 592
 593         valid_damage_for_weaponstats = 0;
 594         awep = 0;
 595
 596         if(vbot || IS_REAL_CLIENT(self))
 597         if(abot || IS_REAL_CLIENT(attacker))
 598         if(attacker && self != attacker)
 599         if(DIFF_TEAM(self, attacker))
 600         {
 601                 if(DEATH_ISSPECIAL(deathtype))
 602                         awep = attacker.weapon;
 603                 else
 604                         awep = DEATH_WEAPONOF(deathtype);
 605                 valid_damage_for_weaponstats = 1;
 606         }
 607
 608         if(valid_damage_for_weaponstats)
 609         {
 610                 dh = dh - max(self.health, 0);
 611                 da = da - max(self.armorvalue, 0);
 612                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 613         }
 614
 615         if (self.health < 1)
 616         {
 617                 float defer_ClientKill_Now_TeamChange;
 618                 defer_ClientKill_Now_TeamChange = FALSE;
 619
 620                 if(self.alivetime)
 621                 {
 622                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 623                         self.alivetime = 0;
 624                 }
 625
 626                 if(valid_damage_for_weaponstats)
 627                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 628
 629                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 630                 if(sound_allowed(MSG_BROADCAST, attacker))
 631                 {
 632                         if(deathtype == DEATH_DROWN)
 633                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 634                         else
 635                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 636                 }
 637
 638                 // get rid of kill indicator
 639                 if(self.killindicator)
 640                 {
 641                         remove(self.killindicator);
 642                         self.killindicator = world;
 643                         if(self.killindicator_teamchange)
 644                                 defer_ClientKill_Now_TeamChange = TRUE;
 645
 646                         if(self.classname == "body")
 647                         if(deathtype == DEATH_KILL)
 648                         {
 649                                 // for the lemmings fans, a small harmless explosion
 650                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 651                         }
 652                 }
 653
 654                 // print an obituary message
 655                 if(self.classname != "body")
 656                         Obituary (attacker, inflictor, self, deathtype);
 657
 658         // increment frag counter for used weapon type
 659         float w;
 660         w = DEATH_WEAPONOF(deathtype);
 661         if(WEP_VALID(w))
 662         if(accuracy_isgooddamage(attacker, self))
 663         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 664
 665                 frag_attacker = attacker;
 666                 frag_inflictor = inflictor;
 667                 frag_target = self;
 668                 frag_deathtype = deathtype;
 669                 MUTATOR_CALLHOOK(PlayerDies);
 670
 671                 weapon_action(self.weapon, WR_PLAYERDEATH);
 672
 673                 RemoveGrapplingHook(self);
 674
 675                 Portal_ClearAllLater(self);
 676
 677                 self.fixangle = TRUE;
 678
 679                 if(defer_ClientKill_Now_TeamChange)
 680                         ClientKill_Now_TeamChange(); // can turn player into spectator
 681
 682                 // player could have been miraculously resuscitated ;)
 683                 // e.g. players in freezetag get frozen, they don't really die
 684                 if(self.health >= 1 || !(IS_PLAYER(self) || self.classname == "body"))
 685                         return;
 686
 687                 // when we get here, player actually dies
 688
 689                 Unfreeze(self); // remove any icy remains
 690                 self.health = 0; // Unfreeze resets health, so we need to set it back
 691
 692                 // clear waypoints
 693                 WaypointSprite_PlayerDead();
 694                 // throw a weapon
 695                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 696
 697                 // become fully visible
 698                 self.alpha = default_player_alpha;
 699                 // make the corpse upright (not tilted)
 700                 self.angles_x = 0;
 701                 self.angles_z = 0;
 702                 // don't spin
 703                 self.avelocity = '0 0 0';
 704                 // view from the floor
 705                 self.view_ofs = '0 0 -8';
 706                 // toss the corpse
 707                 self.movetype = MOVETYPE_TOSS;
 708                 // shootable corpse
 709                 self.solid = SOLID_CORPSE;
 710                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 711                 // don't stick to the floor
 712                 self.flags &= ~FL_ONGROUND;
 713                 // dying animation
 714                 self.deadflag = DEAD_DYING;
 715                 // when to allow respawn
 716                 calculate_player_respawn_time();
 717
 718                 self.death_time = time;
 719                 if (random() < 0.5)
 720                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 721                 else
 722                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 723                 if (self.maxs_z > 5)
 724                 {
 725                         self.maxs_z = 5;
 726                         setsize(self, self.mins, self.maxs);
 727                 }
 728                 // set damage function to corpse damage
 729                 self.event_damage = PlayerCorpseDamage;
 730                 // call the corpse damage function just in case it wants to gib
 731                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 732                 // set up to fade out later
 733                 SUB_SetFade (self, time + 6 + random (), 1);
 734
 735                 // reset body think wrapper broken by SUB_SetFade
 736                 if(self.classname == "body" && self.think != CopyBody_Think) {
 737                         self.CopyBody_think = self.think;
 738                         self.CopyBody_nextthink = self.nextthink;
 739                         self.think = CopyBody_Think;
 740                         self.nextthink = time;
 741                 }
 742
 743                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 744                         // remove corpse
 745                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 746                 }
 747
 748                 // reset fields the weapons may use just in case
 749                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 750                 {
 751                         weapon_action(j, WR_RESETPLAYER);
 752                         ATTACK_FINISHED_FOR(self, j) = 0;
 753                 }
 754         }
 755 }
 756
 757 .float muted; // to be used by prvm_edictset server playernumber muted 1
 758 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 759 // message "": do not say, just test flood control
 760 // return value:
 761 //   1 = accept
 762 //   0 = reject
 763 //  -1 = fake accept
 764 {
 765         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, colorprefix;
 766         float flood;
 767         var .float flood_field;
 768         entity head;
 769         float ret;
 770         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 771
 772         if(!teamsay && !privatesay)
 773                 if(substring(msgin, 0, 1) == " ")
 774                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 775
 776         msgin = formatmessage(msgin);
 777
 778         if (!IS_PLAYER(source))
 779                 colorstr = "^0"; // black for spectators
 780         else if(teamplay)
 781                 colorstr = Team_ColorCode(source.team);
 782         else
 783         {
 784                 colorstr = "";
 785                 teamsay = FALSE;
 786         }
 787
 788         if(intermission_running)
 789                 teamsay = FALSE;
 790
 791         if(msgin != "")
 792                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 793
 794         /*
 795          * using bprint solves this... me stupid
 796         // how can we prevent the message from appearing in a listen server?
 797         // for now, just give "say" back and only handle say_team
 798         if(!teamsay)
 799         {
 800                 clientcommand(self, strcat("say ", msgin));
 801                 return;
 802         }
 803         */
 804
 805         if(autocvar_g_chat_teamcolors)
 806                 namestr = playername(source);
 807         else
 808                 namestr = source.netname;
 809
 810         if(strdecolorize(namestr) == namestr)
 811                 colorprefix = "^3";
 812         else
 813                 colorprefix = "^7";
 814
 815         if(msgin != "")
 816         {
 817                 if(privatesay)
 818                 {
 819                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 820                         privatemsgprefixlen = strlen(msgstr);
 821                         msgstr = strcat(msgstr, msgin);
 822                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 823                         if(autocvar_g_chat_teamcolors)
 824                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 825                         else
 826                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 827                 }
 828                 else if(teamsay)
 829                 {
 830                         msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 831                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 832                 }
 833                 else
 834                 {
 835                         msgstr = strcat("\{1}", colorprefix, namestr, "^7: ", msgin);
 836                         cmsgstr = "";
 837                 }
 838                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 839         }
 840         else
 841         {
 842                 msgstr = cmsgstr = "";
 843         }
 844
 845         fullmsgstr = msgstr;
 846         fullcmsgstr = cmsgstr;
 847
 848         // FLOOD CONTROL
 849         flood = 0;
 850         flood_field = floodcontrol_chat;
 851         if(floodcontrol)
 852         {
 853                 float flood_spl;
 854                 float flood_burst;
 855                 float flood_lmax;
 856                 float lines;
 857                 if(privatesay)
 858                 {
 859                         flood_spl = autocvar_g_chat_flood_spl_tell;
 860                         flood_burst = autocvar_g_chat_flood_burst_tell;
 861                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 862                         flood_field = floodcontrol_chattell;
 863                 }
 864                 else if(teamsay)
 865                 {
 866                         flood_spl = autocvar_g_chat_flood_spl_team;
 867                         flood_burst = autocvar_g_chat_flood_burst_team;
 868                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 869                         flood_field = floodcontrol_chatteam;
 870                 }
 871                 else
 872                 {
 873                         flood_spl = autocvar_g_chat_flood_spl;
 874                         flood_burst = autocvar_g_chat_flood_burst;
 875                         flood_lmax = autocvar_g_chat_flood_lmax;
 876                         flood_field = floodcontrol_chat;
 877                 }
 878                 flood_burst = max(0, flood_burst - 1);
 879                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 880
 881                 // do flood control for the default line size
 882                 if(msgstr != "")
 883                 {
 884                         getWrappedLine_remaining = msgstr;
 885                         msgstr = "";
 886                         lines = 0;
 887                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 888                         {
 889                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 890                                 ++lines;
 891                         }
 892                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 893
 894                         if(getWrappedLine_remaining != "")
 895                         {
 896                                 msgstr = strcat(msgstr, "\n");
 897                                 flood = 2;
 898                         }
 899
 900                         if(time >= source.flood_field)
 901                         {
 902                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 903                         }
 904                         else
 905                         {
 906                                 flood = 1;
 907                                 msgstr = fullmsgstr;
 908                         }
 909                 }
 910                 else
 911                 {
 912                         if(time >= source.flood_field)
 913                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 914                         else
 915                                 flood = 1;
 916                 }
 917
 918                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 919                         source.flood_field = flood = 0;
 920         }
 921
 922         if(flood == 2) // cannot happen for empty msgstr
 923         {
 924                 if(autocvar_g_chat_flood_notify_flooder)
 925                 {
 926                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 927                         sourcecmsgstr = "";
 928                 }
 929                 else
 930                 {
 931                         sourcemsgstr = fullmsgstr;
 932                         sourcecmsgstr = fullcmsgstr;
 933                 }
 934                 cmsgstr = "";
 935         }
 936         else
 937         {
 938                 sourcemsgstr = msgstr;
 939                 sourcecmsgstr = cmsgstr;
 940         }
 941
 942         if(!privatesay)
 943         if (!IS_PLAYER(source))
 944         {
 945                 if (!intermission_running)
 946                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 947                                 teamsay = -1; // spectators
 948         }
 949
 950         if(flood)
 951                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 952
 953         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 954         if(privatesay)
 955                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 956
 957         if(source.muted)
 958         {
 959                 // always fake the message
 960                 ret = -1;
 961         }
 962         else if(flood == 1)
 963         {
 964                 if(autocvar_g_chat_flood_notify_flooder)
 965                 {
 966                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 967                         ret = 0;
 968                 }
 969                 else
 970                         ret = -1;
 971         }
 972         else
 973         {
 974                 ret = 1;
 975         }
 976
 977         if(sourcemsgstr != "" && ret != 0)
 978         {
 979                 if(ret < 0) // faked message, because the player is muted
 980                 {
 981                         sprint(source, sourcemsgstr);
 982                         if(sourcecmsgstr != "" && !privatesay)
 983                                 centerprint(source, sourcecmsgstr);
 984                 }
 985                 else if(privatesay) // private message, between 2 people only
 986                 {
 987                         sprint(source, sourcemsgstr);
 988                         sprint(privatesay, msgstr);
 989                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 990                         if(cmsgstr != "")
 991                                 centerprint(privatesay, cmsgstr);
 992                 }
 993                 else if(teamsay > 0) // team message, only sent to team mates
 994                 {
 995                         sprint(source, sourcemsgstr);
 996                         dedicated_print(msgstr); // send to server console too
 997                         if(sourcecmsgstr != "")
 998                                 centerprint(source, sourcecmsgstr);
 999                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1000                                 if(head != source)
1001                                 {
1002                                         sprint(head, msgstr);
1003                                         if(cmsgstr != "")
1004                                                 centerprint(head, cmsgstr);
1005                                 }
1006                 }
1007                 else if(teamsay < 0) // spectator message, only sent to spectators
1008                 {
1009                         sprint(source, sourcemsgstr);
1010                         dedicated_print(msgstr); // send to server console too
1011                         FOR_EACH_REALCLIENT(head) if (!IS_PLAYER(head))
1012                                 if(head != source)
1013                                         sprint(head, msgstr);
1014                 }
1015                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1016                 {
1017                         sprint(source, sourcemsgstr);
1018                         dedicated_print(msgstr); // send to server console too
1019                         FOR_EACH_REALCLIENT(head)
1020                                 if(head != source)
1021                                         sprint(head, msgstr);
1022                 }
1023                 else
1024                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1025         }
1026
1027         return ret;
1028 }
1029
1030 float GetVoiceMessageVoiceType(string type)
1031 {
1032         if(type == "taunt")
1033                 return VOICETYPE_TAUNT;
1034         if(type == "teamshoot")
1035                 return VOICETYPE_LASTATTACKER;
1036         return VOICETYPE_TEAMRADIO;
1037 }
1038
1039 string allvoicesamples;
1040 .string GetVoiceMessageSampleField(string type)
1041 {
1042         GetPlayerSoundSampleField_notFound = 0;
1043         switch(type)
1044         {
1045 #define _VOICEMSG(m) case #m: return playersound_##m;
1046                 ALLVOICEMSGS
1047 #undef _VOICEMSG
1048         }
1049         GetPlayerSoundSampleField_notFound = 1;
1050         return playersound_taunt;
1051 }
1052
1053 .string GetPlayerSoundSampleField(string type)
1054 {
1055         GetPlayerSoundSampleField_notFound = 0;
1056         switch(type)
1057         {
1058 #define _VOICEMSG(m) case #m: return playersound_##m;
1059                 ALLPLAYERSOUNDS
1060 #undef _VOICEMSG
1061         }
1062         GetPlayerSoundSampleField_notFound = 1;
1063         return playersound_taunt;
1064 }
1065
1066 void PrecacheGlobalSound(string samplestring)
1067 {
1068         float n, i;
1069         tokenize_console(samplestring);
1070         n = stof(argv(1));
1071         if(n > 0)
1072         {
1073                 for(i = 1; i <= n; ++i)
1074                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1075         }
1076         else
1077         {
1078                 precache_sound(strcat(argv(0), ".wav"));
1079         }
1080 }
1081
1082 void PrecachePlayerSounds(string f)
1083 {
1084         float fh;
1085         string s;
1086         fh = fopen(f, FILE_READ);
1087         if(fh < 0)
1088                 return;
1089         while((s = fgets(fh)))
1090         {
1091                 if(tokenize_console(s) != 3)
1092                 {
1093                         dprint("Invalid sound info line: ", s, "\n");
1094                         continue;
1095                 }
1096                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1097         }
1098         fclose(fh);
1099
1100         if (!allvoicesamples)
1101         {
1102 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1103                 ALLVOICEMSGS
1104 #undef _VOICEMSG
1105                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1106         }
1107 }
1108
1109 void ClearPlayerSounds()
1110 {
1111 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1112         ALLPLAYERSOUNDS
1113         ALLVOICEMSGS
1114 #undef _VOICEMSG
1115 }
1116
1117 float LoadPlayerSounds(string f, float first)
1118 {
1119         float fh;
1120         string s;
1121         var .string field;
1122         fh = fopen(f, FILE_READ);
1123         if(fh < 0)
1124         {
1125                 dprint("Player sound file not found: ", f, "\n");
1126                 return 0;
1127         }
1128         while((s = fgets(fh)))
1129         {
1130                 if(tokenize_console(s) != 3)
1131                         continue;
1132                 field = GetPlayerSoundSampleField(argv(0));
1133                 if(GetPlayerSoundSampleField_notFound)
1134                         field = GetVoiceMessageSampleField(argv(0));
1135                 if(GetPlayerSoundSampleField_notFound)
1136                         continue;
1137                 if(self.field)
1138                         strunzone(self.field);
1139                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1140         }
1141         fclose(fh);
1142         return 1;
1143 }
1144
1145 .float modelindex_for_playersound;
1146 .float skin_for_playersound;
1147 void UpdatePlayerSounds()
1148 {
1149         if(self.modelindex == self.modelindex_for_playersound)
1150         if(self.skin == self.skin_for_playersound)
1151                 return;
1152         self.modelindex_for_playersound = self.modelindex;
1153         self.skin_for_playersound = self.skin;
1154         ClearPlayerSounds();
1155         LoadPlayerSounds("sound/player/default.sounds", 1);
1156         if(!autocvar_g_debug_defaultsounds)
1157                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1158                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1159 }
1160
1161 void FakeGlobalSound(string sample, float chan, float voicetype)
1162 {
1163         float n;
1164         float tauntrand;
1165
1166         if(sample == "")
1167                 return;
1168
1169         tokenize_console(sample);
1170         n = stof(argv(1));
1171         if(n > 0)
1172                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1173         else
1174                 sample = strcat(argv(0), ".wav"); // randomization
1175
1176         switch(voicetype)
1177         {
1178                 case VOICETYPE_LASTATTACKER_ONLY:
1179                         break;
1180                 case VOICETYPE_LASTATTACKER:
1181                         if(self.pusher)
1182                         {
1183                                 msg_entity = self;
1184                                 if(IS_REAL_CLIENT(msg_entity))
1185                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1186                         }
1187                         break;
1188                 case VOICETYPE_TEAMRADIO:
1189                         msg_entity = self;
1190                         if(msg_entity.cvar_cl_voice_directional == 1)
1191                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1192                         else
1193                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1194                         break;
1195                 case VOICETYPE_AUTOTAUNT:
1196                         if(!sv_autotaunt)
1197                                 break;
1198                         if(!sv_taunt)
1199                                 break;
1200                         if(autocvar_sv_gentle)
1201                                 break;
1202                         tauntrand = random();
1203                         msg_entity = self;
1204                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1205                         {
1206                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1207                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1208                                 else
1209                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1210                         }
1211                         break;
1212                 case VOICETYPE_TAUNT:
1213                         if(IS_PLAYER(self))
1214                                 if(self.deadflag == DEAD_NO)
1215                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1216                         if(!sv_taunt)
1217                                 break;
1218                         if(autocvar_sv_gentle)
1219                                 break;
1220                         msg_entity = self;
1221                         if (msg_entity.cvar_cl_voice_directional >= 1)
1222                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1223                         else
1224                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1225                         break;
1226                 case VOICETYPE_PLAYERSOUND:
1227                         msg_entity = self;
1228                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1229                         break;
1230                 default:
1231                         backtrace("Invalid voice type!");
1232                         break;
1233         }
1234 }
1235
1236 void GlobalSound(string sample, float chan, float voicetype)
1237 {
1238         float n;
1239         float tauntrand;
1240
1241         if(sample == "")
1242                 return;
1243
1244         tokenize_console(sample);
1245         n = stof(argv(1));
1246         if(n > 0)
1247                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1248         else
1249                 sample = strcat(argv(0), ".wav"); // randomization
1250
1251         switch(voicetype)
1252         {
1253                 case VOICETYPE_LASTATTACKER_ONLY:
1254                         if(self.pusher)
1255                         {
1256                                 msg_entity = self.pusher;
1257                                 if(IS_REAL_CLIENT(msg_entity))
1258                                 {
1259                                         if(msg_entity.cvar_cl_voice_directional == 1)
1260                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1261                                         else
1262                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1263                                 }
1264                         }
1265                         break;
1266                 case VOICETYPE_LASTATTACKER:
1267                         if(self.pusher)
1268                         {
1269                                 msg_entity = self.pusher;
1270                                 if(IS_REAL_CLIENT(msg_entity))
1271                                 {
1272                                         if(msg_entity.cvar_cl_voice_directional == 1)
1273                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1274                                         else
1275                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1276                                 }
1277                                 msg_entity = self;
1278                                 if(IS_REAL_CLIENT(msg_entity))
1279                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1280                         }
1281                         break;
1282                 case VOICETYPE_TEAMRADIO:
1283                         FOR_EACH_REALCLIENT(msg_entity)
1284                                 if(!teamplay || msg_entity.team == self.team)
1285                                 {
1286                                         if(msg_entity.cvar_cl_voice_directional == 1)
1287                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1288                                         else
1289                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1290                                 }
1291                         break;
1292                 case VOICETYPE_AUTOTAUNT:
1293                         if(!sv_autotaunt)
1294                                 break;
1295                         if(!sv_taunt)
1296                                 break;
1297                         if(autocvar_sv_gentle)
1298                                 break;
1299                         tauntrand = random();
1300                         FOR_EACH_REALCLIENT(msg_entity)
1301                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1302                                 {
1303                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1304                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1305                                         else
1306                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1307                                 }
1308                         break;
1309                 case VOICETYPE_TAUNT:
1310                         if(IS_PLAYER(self))
1311                                 if(self.deadflag == DEAD_NO)
1312                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1313                         if(!sv_taunt)
1314                                 break;
1315                         if(autocvar_sv_gentle)
1316                                 break;
1317                         FOR_EACH_REALCLIENT(msg_entity)
1318                         {
1319                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1320                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1321                                 else
1322                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1323                         }
1324                         break;
1325                 case VOICETYPE_PLAYERSOUND:
1326                         sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1327                         break;
1328                 default:
1329                         backtrace("Invalid voice type!");
1330                         break;
1331         }
1332 }
1333
1334 void PlayerSound(.string samplefield, float chan, float voicetype)
1335 {
1336         GlobalSound(self.samplefield, chan, voicetype);
1337 }
1338
1339 void VoiceMessage(string type, string msg)
1340 {
1341         var .string sample;
1342         float voicetype, ownteam;
1343         float flood;
1344         sample = GetVoiceMessageSampleField(type);
1345
1346         if(GetPlayerSoundSampleField_notFound)
1347         {
1348                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1349                 return;
1350         }
1351
1352         voicetype = GetVoiceMessageVoiceType(type);
1353         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1354
1355         flood = Say(self, ownteam, world, msg, 1);
1356
1357         if (flood > 0)
1358                 GlobalSound(self.sample, CH_VOICE, voicetype);
1359         else if (flood < 0)
1360                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1361 }
1362
1363 void MoveToTeam(entity client, float team_colour, float type)
1364 {
1365         float lockteams_backup;
1366
1367         lockteams_backup = lockteams;  // backup any team lock
1368
1369         lockteams = 0;  // disable locked teams
1370
1371         TeamchangeFrags(client);  // move the players frags
1372         SetPlayerColors(client, team_colour - 1);  // set the players colour
1373         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1374
1375         lockteams = lockteams_backup;  // restore the team lock
1376
1377         LogTeamchange(client.playerid, client.team, type);
1378 }