qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "cheats.qh"
  20 #include "g_world.qh"
  21 #include "race.qh"
  22 #include "antilag.qh"
  23 #include "campaign.qh"
  24 #include "command/common.qh"
  25 #include "scores_rules.qh"
  26
  27 #include "bot/api.qh"
  28
  29 #include "../common/ent_cs.qh"
  30 #include "../common/wepent.qh"
  31 #include <common/state.qh>
  32
  33 #include <common/effects/qc/globalsound.qh>
  34
  35 #include "../common/triggers/func/conveyor.qh"
  36 #include "../common/triggers/teleporters.qh"
  37
  38 #include "../common/vehicles/all.qh"
  39
  40 #include "weapons/hitplot.qh"
  41 #include "weapons/weaponsystem.qh"
  42
  43 #include "../common/net_notice.qh"
  44 #include "../common/net_linked.qh"
  45 #include "../common/physics/player.qh"
  46
  47 #include "../common/items/_mod.qh"
  48
  49 #include "../common/mutators/mutator/waypoints/all.qh"
  50
  51 #include "../common/triggers/subs.qh"
  52 #include "../common/triggers/triggers.qh"
  53 #include "../common/triggers/trigger/secret.qh"
  54
  55 #include "../common/minigames/sv_minigames.qh"
  56
  57 #include "../common/items/inventory.qh"
  58
  59 #include "../common/monsters/sv_monsters.qh"
  60
  61 #include "../lib/warpzone/server.qh"
  62
  63 STATIC_METHOD(Client, Add, void(Client this, int _team))
  64 {
  65     ClientConnect(this);
  66     TRANSMUTE(Player, this);
  67     this.frame = 12; // 7
  68     this.team = _team;
  69     PutClientInServer(this);
  70 }
  71
  72 void PutObserverInServer(entity this);
  73
  74 STATIC_METHOD(Client, Remove, void(Client this))
  75 {
  76     TRANSMUTE(Observer, this);
  77     PutClientInServer(this);
  78     ClientDisconnect(this);
  79 }
  80
  81 void send_CSQC_teamnagger() {
  82         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  83 }
  84
  85 int CountSpectators(entity player, entity to)
  86 {
  87         if(!player) { return 0; } // not sure how, but best to be safe
  88
  89         int spec_count = 0;
  90
  91         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  92         {
  93                 spec_count++;
  94         });
  95
  96         return spec_count;
  97 }
  98
  99 void WriteSpectators(entity player, entity to)
 100 {
 101         if(!player) { return; } // not sure how, but best to be safe
 102
 103         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 104         {
 105                 WriteByte(MSG_ENTITY, num_for_edict(it));
 106         });
 107 }
 108
 109 bool ClientData_Send(entity this, entity to, int sf)
 110 {
 111         assert(to == this.owner, return false);
 112
 113         entity e = to;
 114         if (IS_SPEC(e)) e = e.enemy;
 115
 116         sf = 0;
 117         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 118         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 119         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 120         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 121
 122         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 123         WriteByte(MSG_ENTITY, sf);
 124
 125         if (sf & BIT(1))
 126                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 127
 128         if(sf & BIT(4))
 129         {
 130                 float specs = CountSpectators(e, to);
 131                 WriteByte(MSG_ENTITY, specs);
 132                 WriteSpectators(e, to);
 133         }
 134
 135         return true;
 136 }
 137
 138 void ClientData_Attach(entity this)
 139 {
 140         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 141         CS(this).clientdata.drawonlytoclient = this;
 142         CS(this).clientdata.owner = this;
 143 }
 144
 145 void ClientData_Detach(entity this)
 146 {
 147         delete(CS(this).clientdata);
 148         CS(this).clientdata = NULL;
 149 }
 150
 151 void ClientData_Touch(entity e)
 152 {
 153         CS(e).clientdata.SendFlags = 1;
 154
 155         // make it spectatable
 156         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 157 }
 158
 159 void SetSpectatee(entity this, entity spectatee);
 160 void SetSpectatee_status(entity this, int spectatee_num);
 161
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel;
 172 string CheckPlayerModel(string plyermodel) {
 173         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 174         {
 175                 // note: we cannot summon Don Strunzone here, some player may
 176                 // still have the model string set. In case anyone manages how
 177                 // to change a cvar default, we'll have a small leak here.
 178                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 179         }
 180         // only in right path
 181         if( substring(plyermodel,0,14) != "models/player/")
 182                 return FallbackPlayerModel;
 183         // only good file extensions
 184         if(substring(plyermodel,-4,4) != ".zym")
 185         if(substring(plyermodel,-4,4) != ".dpm")
 186         if(substring(plyermodel,-4,4) != ".iqm")
 187         if(substring(plyermodel,-4,4) != ".md3")
 188         if(substring(plyermodel,-4,4) != ".psk")
 189                 return FallbackPlayerModel;
 190         // forbid the LOD models
 191         if(substring(plyermodel, -9,5) == "_lod1")
 192                 return FallbackPlayerModel;
 193         if(substring(plyermodel, -9,5) == "_lod2")
 194                 return FallbackPlayerModel;
 195         if(plyermodel != strtolower(plyermodel))
 196                 return FallbackPlayerModel;
 197         // also, restrict to server models
 198         if(autocvar_sv_servermodelsonly)
 199         {
 200                 if(!fexists(plyermodel))
 201                         return FallbackPlayerModel;
 202         }
 203         return plyermodel;
 204 }
 205
 206 void setplayermodel(entity e, string modelname)
 207 {
 208         precache_model(modelname);
 209         _setmodel(e, modelname);
 210         player_setupanimsformodel(e);
 211         if(!autocvar_g_debug_globalsounds)
 212                 UpdatePlayerSounds(e);
 213 }
 214
 215 void FixPlayermodel(entity player);
 216 /** putting a client as observer in the server */
 217 void PutObserverInServer(entity this)
 218 {
 219     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 220         PlayerState_detach(this);
 221
 222         if (IS_PLAYER(this) && this.health >= 1) {
 223         // despawn effect
 224                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 225     }
 226
 227     {
 228         entity spot = SelectSpawnPoint(this, true);
 229         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 230         this.angles = vec2(spot.angles);
 231         this.fixangle = true;
 232         // offset it so that the spectator spawns higher off the ground, looks better this way
 233         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 234         if (IS_REAL_CLIENT(this))
 235         {
 236             msg_entity = this;
 237             WriteByte(MSG_ONE, SVC_SETVIEW);
 238             WriteEntity(MSG_ONE, this);
 239         }
 240         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 241         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 242         if(!autocvar_g_debug_globalsounds)
 243         {
 244                 // needed for player sounds
 245                 this.model = "";
 246                 FixPlayermodel(this);
 247         }
 248         setmodel(this, MDL_Null);
 249         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 250         this.view_ofs = '0 0 0';
 251     }
 252
 253     RemoveGrapplingHooks(this);
 254         Portal_ClearAll(this);
 255         Unfreeze(this);
 256         SetSpectatee(this, NULL);
 257
 258         if (this.alivetime)
 259         {
 260                 if (!warmup_stage)
 261                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 262                 this.alivetime = 0;
 263         }
 264
 265         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 266
 267         WaypointSprite_PlayerDead(this);
 268
 269         if (mutator_returnvalue) {
 270             // mutator prevents resetting teams+score
 271         } else {
 272                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 273         this.frags = FRAGS_SPECTATOR;
 274         PlayerScore_Clear(this);  // clear scores when needed
 275     }
 276
 277         if (CS(this).killcount != FRAGS_SPECTATOR)
 278         {
 279                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 280                 if(!game_stopped)
 281                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 282                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 283
 284                 if(!CS(this).just_joined)
 285                         LogTeamchange(this.playerid, -1, 4);
 286                 else
 287                         CS(this).just_joined = false;
 288         }
 289
 290         accuracy_resend(this);
 291
 292         CS(this).spectatortime = time;
 293         if(this.bot_attack)
 294                 IL_REMOVE(g_bot_targets, this);
 295         this.bot_attack = false;
 296     this.hud = HUD_NORMAL;
 297         TRANSMUTE(Observer, this);
 298         this.iscreature = false;
 299         this.teleportable = TELEPORT_SIMPLE;
 300         if(this.damagedbycontents)
 301                 IL_REMOVE(g_damagedbycontents, this);
 302         this.damagedbycontents = false;
 303         this.health = FRAGS_SPECTATOR;
 304         SetSpectatee_status(this, etof(this));
 305         this.takedamage = DAMAGE_NO;
 306         this.solid = SOLID_NOT;
 307         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 308         this.flags = FL_CLIENT | FL_NOTARGET;
 309         this.armorvalue = 666;
 310         this.effects = 0;
 311         this.armorvalue = autocvar_g_balance_armor_start;
 312         this.pauserotarmor_finished = 0;
 313         this.pauserothealth_finished = 0;
 314         this.pauseregen_finished = 0;
 315         this.damageforcescale = 0;
 316         this.death_time = 0;
 317         this.respawn_flags = 0;
 318         this.respawn_time = 0;
 319         this.stat_respawn_time = 0;
 320         this.alpha = 0;
 321         this.scale = 0;
 322         this.fade_time = 0;
 323         this.pain_frame = 0;
 324         this.pain_finished = 0;
 325         this.strength_finished = 0;
 326         this.invincible_finished = 0;
 327         this.superweapons_finished = 0;
 328         this.pushltime = 0;
 329         this.istypefrag = 0;
 330         setthink(this, func_null);
 331         this.nextthink = 0;
 332         this.deadflag = DEAD_NO;
 333         this.crouch = false;
 334         this.revive_progress = 0;
 335         this.revival_time = 0;
 336
 337         this.items = 0;
 338         this.weapons = '0 0 0';
 339         this.drawonlytoclient = this;
 340
 341         this.weaponmodel = "";
 342         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 343         {
 344                 this.weaponentities[slot] = NULL;
 345         }
 346         this.exteriorweaponentity = NULL;
 347         CS(this).killcount = FRAGS_SPECTATOR;
 348         this.velocity = '0 0 0';
 349         this.avelocity = '0 0 0';
 350         this.punchangle = '0 0 0';
 351         this.punchvector = '0 0 0';
 352         this.oldvelocity = this.velocity;
 353         this.fire_endtime = -1;
 354         this.event_damage = func_null;
 355
 356         for(int slot = 0; slot < MAX_AXH; ++slot)
 357         {
 358                 entity axh = this.(AuxiliaryXhair[slot]);
 359                 this.(AuxiliaryXhair[slot]) = NULL;
 360
 361                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 362                         delete(axh);
 363         }
 364 }
 365
 366 int player_getspecies(entity this)
 367 {
 368         get_model_parameters(this.model, this.skin);
 369         int s = get_model_parameters_species;
 370         get_model_parameters(string_null, 0);
 371         if (s < 0) return SPECIES_HUMAN;
 372         return s;
 373 }
 374
 375 .float model_randomizer;
 376 void FixPlayermodel(entity player)
 377 {
 378         string defaultmodel = "";
 379         int defaultskin = 0;
 380         if(autocvar_sv_defaultcharacter)
 381         {
 382                 if(teamplay)
 383                 {
 384                         switch(player.team)
 385                         {
 386                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 387                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 388                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 389                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 390                         }
 391                 }
 392
 393                 if(defaultmodel == "")
 394                 {
 395                         defaultmodel = autocvar_sv_defaultplayermodel;
 396                         defaultskin = autocvar_sv_defaultplayerskin;
 397                 }
 398
 399                 int n = tokenize_console(defaultmodel);
 400                 if(n > 0)
 401                 {
 402                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 403                         // However, do NOT randomize if the player-selected model is in the list.
 404                         for (int i = 0; i < n; ++i)
 405                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 406                                         defaultmodel = argv(i);
 407                 }
 408
 409                 int i = strstrofs(defaultmodel, ":", 0);
 410                 if(i >= 0)
 411                 {
 412                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 413                         defaultmodel = substring(defaultmodel, 0, i);
 414                 }
 415         }
 416         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 417         {
 418                 if(teamplay)
 419                 {
 420                         switch(player.team)
 421                         {
 422                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 423                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 424                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 425                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 426                         }
 427                 }
 428
 429                 if(!defaultskin)
 430                         defaultskin = autocvar_sv_defaultplayerskin;
 431         }
 432
 433         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 434         defaultmodel = M_ARGV(0, string);
 435         defaultskin = M_ARGV(1, int);
 436
 437         bool chmdl = false;
 438         int oldskin;
 439         if(defaultmodel != "")
 440         {
 441                 if (defaultmodel != player.model)
 442                 {
 443                         vector m1 = player.mins;
 444                         vector m2 = player.maxs;
 445                         setplayermodel (player, defaultmodel);
 446                         setsize (player, m1, m2);
 447                         chmdl = true;
 448                 }
 449
 450                 oldskin = player.skin;
 451                 player.skin = defaultskin;
 452         } else {
 453                 if (player.playermodel != player.model || player.playermodel == "")
 454                 {
 455                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 456                         vector m1 = player.mins;
 457                         vector m2 = player.maxs;
 458                         setplayermodel (player, player.playermodel);
 459                         setsize (player, m1, m2);
 460                         chmdl = true;
 461                 }
 462
 463                 if(!autocvar_sv_defaultcharacterskin)
 464                 {
 465                         oldskin = player.skin;
 466                         player.skin = stof(player.playerskin);
 467                 }
 468                 else
 469                 {
 470                         oldskin = player.skin;
 471                         player.skin = defaultskin;
 472                 }
 473         }
 474
 475         if(chmdl || oldskin != player.skin) // model or skin has changed
 476         {
 477                 player.species = player_getspecies(player); // update species
 478                 if(!autocvar_g_debug_globalsounds)
 479                         UpdatePlayerSounds(player); // update skin sounds
 480         }
 481
 482         if(!teamplay)
 483                 if(strlen(autocvar_sv_defaultplayercolors))
 484                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 485                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 486 }
 487
 488 void PutPlayerInServer(entity this)
 489 {
 490         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 491
 492         PlayerState_attach(this);
 493         accuracy_resend(this);
 494
 495         if (this.team < 0)
 496                 JoinBestTeam(this, false, true);
 497
 498         entity spot = SelectSpawnPoint(this, false);
 499         if (!spot) {
 500                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 501                 return; // spawn failed
 502         }
 503
 504         TRANSMUTE(Player, this);
 505
 506         CS(this).wasplayer = true;
 507         this.iscreature = true;
 508         this.teleportable = TELEPORT_NORMAL;
 509         if(!this.damagedbycontents)
 510                 IL_PUSH(g_damagedbycontents, this);
 511         this.damagedbycontents = true;
 512         set_movetype(this, MOVETYPE_WALK);
 513         this.solid = SOLID_SLIDEBOX;
 514         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 515         if (autocvar_g_playerclip_collisions)
 516                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 517         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 518                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 519         this.frags = FRAGS_PLAYER;
 520         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 521         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 522         if (autocvar__notarget)
 523                 this.flags |= FL_NOTARGET;
 524         this.takedamage = DAMAGE_AIM;
 525         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 526         this.dmg = 2; // WTF
 527
 528         if (warmup_stage) {
 529                 this.ammo_shells = warmup_start_ammo_shells;
 530                 this.ammo_nails = warmup_start_ammo_nails;
 531                 this.ammo_rockets = warmup_start_ammo_rockets;
 532                 this.ammo_cells = warmup_start_ammo_cells;
 533                 this.ammo_plasma = warmup_start_ammo_plasma;
 534                 this.ammo_fuel = warmup_start_ammo_fuel;
 535                 this.health = warmup_start_health;
 536                 this.armorvalue = warmup_start_armorvalue;
 537                 this.weapons = WARMUP_START_WEAPONS;
 538         } else {
 539                 this.ammo_shells = start_ammo_shells;
 540                 this.ammo_nails = start_ammo_nails;
 541                 this.ammo_rockets = start_ammo_rockets;
 542                 this.ammo_cells = start_ammo_cells;
 543                 this.ammo_plasma = start_ammo_plasma;
 544                 this.ammo_fuel = start_ammo_fuel;
 545                 this.health = start_health;
 546                 this.armorvalue = start_armorvalue;
 547                 this.weapons = start_weapons;
 548         }
 549         SetSpectatee_status(this, 0);
 550
 551         PS(this).dual_weapons = '0 0 0';
 552
 553         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 554
 555         this.items = start_items;
 556
 557         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 558         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 559         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 560         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 561         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 562         // extend the pause of rotting if client was reset at the beginning of the countdown
 563         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 564                 float f = game_starttime - time;
 565                 this.spawnshieldtime += f;
 566                 this.pauserotarmor_finished += f;
 567                 this.pauserothealth_finished += f;
 568                 this.pauseregen_finished += f;
 569         }
 570         this.damageforcescale = 2;
 571         this.death_time = 0;
 572         this.respawn_flags = 0;
 573         this.respawn_time = 0;
 574         this.stat_respawn_time = 0;
 575         this.scale = autocvar_sv_player_scale;
 576         this.fade_time = 0;
 577         this.pain_frame = 0;
 578         this.pain_finished = 0;
 579         this.pushltime = 0;
 580         setthink(this, func_null); // players have no think function
 581         this.nextthink = 0;
 582         this.dmg_team = 0;
 583         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 584
 585         this.deadflag = DEAD_NO;
 586
 587         this.angles = spot.angles;
 588         this.angles_z = 0; // never spawn tilted even if the spot says to
 589         if (IS_BOT_CLIENT(this))
 590                 this.v_angle = this.angles;
 591         this.fixangle = true; // turn this way immediately
 592         this.oldvelocity = this.velocity = '0 0 0';
 593         this.avelocity = '0 0 0';
 594         this.punchangle = '0 0 0';
 595         this.punchvector = '0 0 0';
 596
 597         this.strength_finished = 0;
 598         this.invincible_finished = 0;
 599         this.fire_endtime = -1;
 600         this.revive_progress = 0;
 601         this.revival_time = 0;
 602         this.air_finished = time + 12;
 603
 604         entity spawnevent = new_pure(spawnevent);
 605         spawnevent.owner = this;
 606         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 607
 608         // Cut off any still running player sounds.
 609         stopsound(this, CH_PLAYER_SINGLE);
 610
 611         this.model = "";
 612         FixPlayermodel(this);
 613         this.drawonlytoclient = NULL;
 614
 615         this.viewloc = NULL;
 616
 617         this.crouch = false;
 618         this.view_ofs = STAT(PL_VIEW_OFS, this);
 619         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 620         this.spawnorigin = spot.origin;
 621         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 622         // don't reset back to last position, even if new position is stuck in solid
 623         this.oldorigin = this.origin;
 624         this.lastteleporttime = time; // prevent insane speeds due to changing origin
 625         if(this.conveyor)
 626                 IL_REMOVE(g_conveyed, this);
 627         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 628         this.hud = HUD_NORMAL;
 629
 630         this.event_damage = PlayerDamage;
 631
 632         if(!this.bot_attack)
 633                 IL_PUSH(g_bot_targets, this);
 634         this.bot_attack = true;
 635         if(!this.monster_attack)
 636                 IL_PUSH(g_monster_targets, this);
 637         this.monster_attack = true;
 638         navigation_dynamicgoal_init(this, false);
 639
 640         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 641
 642         if (CS(this).killcount == FRAGS_SPECTATOR) {
 643                 PlayerScore_Clear(this);
 644                 CS(this).killcount = 0;
 645         }
 646
 647         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 648         {
 649                 .entity weaponentity = weaponentities[slot];
 650                 entity oldwep = this.(weaponentity);
 651                 CL_SpawnWeaponentity(this, weaponentity);
 652                 if(oldwep && oldwep.owner == this)
 653                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 654         }
 655         this.alpha = default_player_alpha;
 656         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 657         this.exteriorweaponentity.alpha = default_weapon_alpha;
 658
 659         this.speedrunning = false;
 660
 661         target_voicescript_clear(this);
 662
 663         // reset fields the weapons may use
 664         FOREACH(Weapons, true, {
 665                 it.wr_resetplayer(it, this);
 666                         // reload all reloadable weapons
 667                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 668                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 669                         {
 670                                 .entity weaponentity = weaponentities[slot];
 671                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 672                         }
 673                 }
 674         });
 675
 676         {
 677                 string s = spot.target;
 678                 spot.target = string_null;
 679                 SUB_UseTargets(spot, this, NULL);
 680                 spot.target = s;
 681         }
 682
 683         Unfreeze(this);
 684
 685         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 686
 687         if (autocvar_spawn_debug)
 688         {
 689                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 690                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 691         }
 692
 693         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 694         {
 695                 .entity weaponentity = weaponentities[slot];
 696                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 697                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 698                 else
 699                         this.(weaponentity).m_switchweapon = WEP_Null;
 700                 this.(weaponentity).m_weapon = WEP_Null;
 701                 this.(weaponentity).weaponname = "";
 702                 this.(weaponentity).m_switchingweapon = WEP_Null;
 703                 this.(weaponentity).cnt = -1;
 704         }
 705
 706         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 707
 708         if (!warmup_stage && !this.alivetime)
 709                 this.alivetime = time;
 710
 711         antilag_clear(this, CS(this));
 712 }
 713
 714 /** Called when a client spawns in the server */
 715 void PutClientInServer(entity this)
 716 {
 717         if (IS_BOT_CLIENT(this)) {
 718                 TRANSMUTE(Player, this);
 719         } else if (IS_REAL_CLIENT(this)) {
 720                 msg_entity = this;
 721                 WriteByte(MSG_ONE, SVC_SETVIEW);
 722                 WriteEntity(MSG_ONE, this);
 723         }
 724         if (game_stopped)
 725                 TRANSMUTE(Observer, this);
 726
 727         SetSpectatee(this, NULL);
 728
 729         // reset player keys
 730         if(PS(this))
 731                 PS(this).itemkeys = 0;
 732
 733         MUTATOR_CALLHOOK(PutClientInServer, this);
 734
 735         if (IS_OBSERVER(this)) {
 736                 PutObserverInServer(this);
 737         } else if (IS_PLAYER(this)) {
 738                 PutPlayerInServer(this);
 739         }
 740 }
 741
 742 void ClientInit_misc(entity this);
 743
 744 // TODO do we need all these fields, or should we stop autodetecting runtime
 745 // changes and just have a console command to update this?
 746 bool ClientInit_SendEntity(entity this, entity to, int sf)
 747 {
 748         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 749         return = true;
 750         msg_entity = to;
 751         // MSG_INIT replacement
 752         // TODO: make easier to use
 753         Registry_send_all();
 754         W_PROP_reload(MSG_ONE, to);
 755         ClientInit_misc(this);
 756         MUTATOR_CALLHOOK(Ent_Init);
 757 }
 758 void ClientInit_misc(entity this)
 759 {
 760         int channel = MSG_ONE;
 761         WriteHeader(channel, ENT_CLIENT_INIT);
 762         WriteByte(channel, g_nexball_meter_period * 32);
 763         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 764         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 765         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 766         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 767         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 768         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 769         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 770         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 771
 772         if(sv_foginterval && world.fog != "")
 773                 WriteString(channel, world.fog);
 774         else
 775                 WriteString(channel, "");
 776         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 777         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 778         WriteByte(channel, serverflags);
 779         WriteCoord(channel, autocvar_g_trueaim_minrange);
 780 }
 781
 782 void ClientInit_CheckUpdate(entity this)
 783 {
 784         this.nextthink = time;
 785         if(this.count != autocvar_g_balance_armor_blockpercent)
 786         {
 787                 this.count = autocvar_g_balance_armor_blockpercent;
 788                 this.SendFlags |= 1;
 789         }
 790         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 791         {
 792                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 793                 this.SendFlags |= 1;
 794         }
 795 }
 796
 797 void ClientInit_Spawn()
 798 {
 799         entity e = new_pure(clientinit);
 800         setthink(e, ClientInit_CheckUpdate);
 801         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 802
 803         ClientInit_CheckUpdate(e);
 804 }
 805
 806 /*
 807 =============
 808 SetNewParms
 809 =============
 810 */
 811 void SetNewParms ()
 812 {
 813         // initialize parms for a new player
 814         parm1 = -(86400 * 366);
 815
 816         MUTATOR_CALLHOOK(SetNewParms);
 817 }
 818
 819 /*
 820 =============
 821 SetChangeParms
 822 =============
 823 */
 824 void SetChangeParms (entity this)
 825 {
 826         // save parms for level change
 827         parm1 = CS(this).parm_idlesince - time;
 828
 829         MUTATOR_CALLHOOK(SetChangeParms);
 830 }
 831
 832 /*
 833 =============
 834 DecodeLevelParms
 835 =============
 836 */
 837 void DecodeLevelParms(entity this)
 838 {
 839         // load parms
 840         CS(this).parm_idlesince = parm1;
 841         if (CS(this).parm_idlesince == -(86400 * 366))
 842                 CS(this).parm_idlesince = time;
 843
 844         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 845         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 846
 847         MUTATOR_CALLHOOK(DecodeLevelParms);
 848 }
 849
 850 /*
 851 =============
 852 ClientKill
 853
 854 Called when a client types 'kill' in the console
 855 =============
 856 */
 857
 858 .float clientkill_nexttime;
 859 void ClientKill_Now_TeamChange(entity this)
 860 {
 861         if(CS(this).killindicator_teamchange == -1)
 862         {
 863                 JoinBestTeam( this, false, true );
 864         }
 865         else if(CS(this).killindicator_teamchange == -2)
 866         {
 867                 if(blockSpectators)
 868                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 869                 PutObserverInServer(this);
 870         }
 871         else
 872                 SV_ChangeTeam(this, CS(this).killindicator_teamchange - 1);
 873         CS(this).killindicator_teamchange = 0;
 874 }
 875
 876 void ClientKill_Now(entity this)
 877 {
 878         if(this.vehicle)
 879         {
 880             vehicles_exit(this.vehicle, VHEF_RELEASE);
 881             if(!CS(this).killindicator_teamchange)
 882             {
 883             this.vehicle_health = -1;
 884             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 885             }
 886         }
 887
 888         if(this.killindicator && !wasfreed(this.killindicator))
 889                 delete(this.killindicator);
 890
 891         this.killindicator = NULL;
 892
 893         if(CS(this).killindicator_teamchange)
 894                 ClientKill_Now_TeamChange(this);
 895
 896         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 897                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 898
 899         // now I am sure the player IS dead
 900 }
 901 void KillIndicator_Think(entity this)
 902 {
 903         if (game_stopped)
 904         {
 905                 this.owner.killindicator = NULL;
 906                 delete(this);
 907                 return;
 908         }
 909
 910         if (this.owner.alpha < 0 && !this.owner.vehicle)
 911         {
 912                 this.owner.killindicator = NULL;
 913                 delete(this);
 914                 return;
 915         }
 916
 917         if(this.cnt <= 0)
 918         {
 919                 ClientKill_Now(this.owner);
 920                 return;
 921         }
 922     else if(this.health == 1) // health == 1 means that it's silent
 923     {
 924         this.nextthink = time + 1;
 925         this.cnt -= 1;
 926     }
 927         else
 928         {
 929                 if(this.cnt <= 10)
 930                         setmodel(this, MDL_NUM(this.cnt));
 931                 if(IS_REAL_CLIENT(this.owner))
 932                 {
 933                         if(this.cnt <= 10)
 934                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 935                 }
 936                 this.nextthink = time + 1;
 937                 this.cnt -= 1;
 938         }
 939 }
 940
 941 float clientkilltime;
 942 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 943 {
 944         float killtime;
 945         float starttime;
 946
 947         if (game_stopped)
 948                 return;
 949
 950         killtime = autocvar_g_balance_kill_delay;
 951
 952     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 953         return;
 954     killtime = M_ARGV(1, float);
 955
 956         CS(this).killindicator_teamchange = targetteam;
 957
 958     if(!this.killindicator)
 959         {
 960                 if(!IS_DEAD(this))
 961                 {
 962                         killtime = max(killtime, this.clientkill_nexttime - time);
 963                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 964                 }
 965
 966                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 967                 {
 968                         ClientKill_Now(this);
 969                 }
 970                 else
 971                 {
 972                         starttime = max(time, clientkilltime);
 973
 974                         this.killindicator = spawn();
 975                         this.killindicator.owner = this;
 976                         this.killindicator.scale = 0.5;
 977                         setattachment(this.killindicator, this, "");
 978                         setorigin(this.killindicator, '0 0 52');
 979                         setthink(this.killindicator, KillIndicator_Think);
 980                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 981                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 982                         this.killindicator.cnt = ceil(killtime);
 983                         this.killindicator.count = bound(0, ceil(killtime), 10);
 984                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 985
 986                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 987                         {
 988                                 it.killindicator = spawn();
 989                                 it.killindicator.owner = it;
 990                                 it.killindicator.scale = 0.5;
 991                                 setattachment(it.killindicator, it, "");
 992                                 setorigin(it.killindicator, '0 0 52');
 993                                 setthink(it.killindicator, KillIndicator_Think);
 994                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 995                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 996                                 it.killindicator.cnt = ceil(killtime);
 997                         });
 998                         this.lip = 0;
 999                 }
1000         }
1001         if(this.killindicator)
1002         {
1003                 if(targetteam == 0) // just die
1004                 {
1005                         this.killindicator.colormod = '0 0 0';
1006                         if(IS_REAL_CLIENT(this))
1007                         if(this.killindicator.cnt > 0)
1008                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1009                 }
1010                 else if(targetteam == -1) // auto
1011                 {
1012                         this.killindicator.colormod = '0 1 0';
1013                         if(IS_REAL_CLIENT(this))
1014                         if(this.killindicator.cnt > 0)
1015                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1016                 }
1017                 else if(targetteam == -2) // spectate
1018                 {
1019                         this.killindicator.colormod = '0.5 0.5 0.5';
1020                         if(IS_REAL_CLIENT(this))
1021                         if(this.killindicator.cnt > 0)
1022                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1023                 }
1024                 else
1025                 {
1026                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1027                         if(IS_REAL_CLIENT(this))
1028                         if(this.killindicator.cnt > 0)
1029                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1030                 }
1031         }
1032
1033 }
1034
1035 void ClientKill (entity this)
1036 {
1037         if(game_stopped) return;
1038         if(this.player_blocked) return;
1039         if(STAT(FROZEN, this)) return;
1040
1041         ClientKill_TeamChange(this, 0);
1042 }
1043
1044 void FixClientCvars(entity e)
1045 {
1046         // send prediction settings to the client
1047         stuffcmd(e, "\nin_bindmap 0 0\n");
1048         if(autocvar_g_antilag == 3) // client side hitscan
1049                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1050         if(autocvar_sv_gentle)
1051                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1052
1053         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1054         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1055
1056         MUTATOR_CALLHOOK(FixClientCvars, e);
1057 }
1058
1059 bool findinlist_abbrev(string tofind, string list)
1060 {
1061         if(list == "" || tofind == "")
1062                 return false; // empty list or search, just return
1063
1064         // this function allows abbreviated strings!
1065         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1066         {
1067                 return true;
1068         });
1069
1070         return false;
1071 }
1072
1073 bool PlayerInIPList(entity p, string iplist)
1074 {
1075         // some safety checks (never allow local?)
1076         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1077                 return false;
1078
1079         return findinlist_abbrev(p.netaddress, iplist);
1080 }
1081
1082 bool PlayerInIDList(entity p, string idlist)
1083 {
1084         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1085         if(!p.crypto_idfp)
1086                 return false;
1087
1088         return findinlist_abbrev(p.crypto_idfp, idlist);
1089 }
1090
1091 bool PlayerInList(entity player, string list)
1092 {
1093         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1094 }
1095
1096 #ifdef DP_EXT_PRECONNECT
1097 /*
1098 =============
1099 ClientPreConnect
1100
1101 Called once (not at each match start) when a client begins a connection to the server
1102 =============
1103 */
1104 void ClientPreConnect(entity this)
1105 {
1106         if(autocvar_sv_eventlog)
1107         {
1108                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1109                         this.playerid,
1110                         etof(this),
1111                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1112                 ));
1113         }
1114 }
1115 #endif
1116
1117 /**
1118 =============
1119 ClientConnect
1120
1121 Called when a client connects to the server
1122 =============
1123 */
1124 void ClientConnect(entity this)
1125 {
1126         if (Ban_MaybeEnforceBanOnce(this)) return;
1127         assert(!IS_CLIENT(this), return);
1128         this.flags |= FL_CLIENT;
1129         assert(player_count >= 0, player_count = 0);
1130
1131 #ifdef WATERMARK
1132         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1133 #endif
1134         TRANSMUTE(Client, this);
1135         CS(this).version_nagtime = time + 10 + random() * 10;
1136
1137         // identify the right forced team
1138         if (autocvar_g_campaign)
1139         {
1140                 if (IS_REAL_CLIENT(this)) // only players, not bots
1141                 {
1142                         switch (autocvar_g_campaign_forceteam)
1143                         {
1144                                 case 1: this.team_forced = NUM_TEAM_1; break;
1145                                 case 2: this.team_forced = NUM_TEAM_2; break;
1146                                 case 3: this.team_forced = NUM_TEAM_3; break;
1147                                 case 4: this.team_forced = NUM_TEAM_4; break;
1148                                 default: this.team_forced = 0;
1149                         }
1150                 }
1151         }
1152         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1153         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1154         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1155         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1156         else switch (autocvar_g_forced_team_otherwise)
1157         {
1158                 default: this.team_forced = 0; break;
1159                 case "red": this.team_forced = NUM_TEAM_1; break;
1160                 case "blue": this.team_forced = NUM_TEAM_2; break;
1161                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1162                 case "pink": this.team_forced = NUM_TEAM_4; break;
1163                 case "spectate":
1164                 case "spectator":
1165                         this.team_forced = -1;
1166                         break;
1167         }
1168         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1169
1170     {
1171         int id = this.playerid;
1172         this.playerid = 0; // silent
1173             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1174             this.playerid = id;
1175     }
1176
1177         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1178                 TRANSMUTE(Observer, this);
1179         } else {
1180                 if (!teamplay || autocvar_g_balance_teams) {
1181                         TRANSMUTE(Player, this);
1182                         campaign_bots_may_start = true;
1183                 } else {
1184                         TRANSMUTE(Observer, this); // do it anyway
1185                 }
1186         }
1187
1188         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1189
1190         // always track bots, don't ask for cl_allow_uidtracking
1191         if (IS_BOT_CLIENT(this))
1192                 PlayerStats_GameReport_AddPlayer(this);
1193         else
1194                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1195
1196         if (autocvar_sv_eventlog)
1197                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1198
1199         LogTeamchange(this.playerid, this.team, 1);
1200
1201         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1202
1203         CS(this).netname_previous = strzone(this.netname);
1204
1205         if(teamplay && IS_PLAYER(this))
1206                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1207         else
1208                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1209
1210         stuffcmd(this, clientstuff, "\n");
1211         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1212
1213         FixClientCvars(this);
1214
1215         // get version info from player
1216         stuffcmd(this, "cmd clientversion $gameversion\n");
1217
1218         // notify about available teams
1219         if (teamplay)
1220         {
1221                 CheckAllowedTeams(this);
1222                 int t = 0;
1223                 if (c1 >= 0) t |= BIT(0);
1224                 if (c2 >= 0) t |= BIT(1);
1225                 if (c3 >= 0) t |= BIT(2);
1226                 if (c4 >= 0) t |= BIT(3);
1227                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1228         }
1229         else
1230         {
1231                 stuffcmd(this, "set _teams_available 0\n");
1232         }
1233
1234         bot_relinkplayerlist();
1235
1236         CS(this).spectatortime = time;
1237         if (blockSpectators)
1238         {
1239                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1240         }
1241
1242         CS(this).jointime = time;
1243
1244         if (IS_REAL_CLIENT(this))
1245         {
1246                 if (g_weaponarena_weapons == WEPSET(TUBA))
1247                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1248         }
1249
1250         if (!sv_foginterval && world.fog != "")
1251                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1252
1253         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1254                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1255                         send_CSQC_teamnagger();
1256
1257         CSQCMODEL_AUTOINIT(this);
1258
1259         CS(this).model_randomizer = random();
1260
1261         if (IS_REAL_CLIENT(this))
1262                 sv_notice_join(this);
1263
1264         // update physics stats (players can spawn before physics runs)
1265         Physics_UpdateStats(this);
1266
1267         IL_EACH(g_initforplayer, it.init_for_player, {
1268                 it.init_for_player(it, this);
1269         });
1270
1271         MUTATOR_CALLHOOK(ClientConnect, this);
1272
1273         if (IS_REAL_CLIENT(this))
1274         {
1275                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1276                 {
1277                         CS(this).motd_actived_time = -1;
1278                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1279                 }
1280         }
1281 }
1282 /*
1283 =============
1284 ClientDisconnect
1285
1286 Called when a client disconnects from the server
1287 =============
1288 */
1289 .entity chatbubbleentity;
1290 void ReadyCount();
1291 void ClientDisconnect(entity this)
1292 {
1293         assert(IS_CLIENT(this), return);
1294
1295         PlayerStats_GameReport_FinalizePlayer(this);
1296         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1297         if (CS(this).active_minigame) part_minigame(this);
1298         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1299
1300         if (autocvar_sv_eventlog)
1301                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1302
1303         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1304
1305         if(IS_SPEC(this))
1306                 SetSpectatee(this, NULL);
1307
1308     MUTATOR_CALLHOOK(ClientDisconnect, this);
1309
1310         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1311         ClientState_detach(this);
1312
1313         Portal_ClearAll(this);
1314
1315         Unfreeze(this);
1316
1317         RemoveGrapplingHooks(this);
1318
1319         // Here, everything has been done that requires this player to be a client.
1320
1321         this.flags &= ~FL_CLIENT;
1322
1323         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1324         if (this.killindicator) delete(this.killindicator);
1325
1326         WaypointSprite_PlayerGone(this);
1327
1328         bot_relinkplayerlist();
1329
1330         if (this.clientstatus) strunzone(this.clientstatus);
1331         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1332         if (this.personal) delete(this.personal);
1333
1334         this.playerid = 0;
1335         ReadyCount();
1336         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1337
1338         ONREMOVE(this);
1339 }
1340
1341 void ChatBubbleThink(entity this)
1342 {
1343         this.nextthink = time;
1344         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1345         {
1346                 if(this.owner) // but why can that ever be NULL?
1347                         this.owner.chatbubbleentity = NULL;
1348                 delete(this);
1349                 return;
1350         }
1351
1352         this.mdl = "";
1353
1354         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1355         {
1356                 if ( CS(this.owner).active_minigame )
1357                         this.mdl = "models/sprites/minigame_busy.iqm";
1358                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1359                         this.mdl = "models/misc/chatbubble.spr";
1360         }
1361
1362         if ( this.model != this.mdl )
1363                 _setmodel(this, this.mdl);
1364
1365 }
1366
1367 void UpdateChatBubble(entity this)
1368 {
1369         if (this.alpha < 0)
1370                 return;
1371         // spawn a chatbubble entity if needed
1372         if (!this.chatbubbleentity)
1373         {
1374                 this.chatbubbleentity = new(chatbubbleentity);
1375                 this.chatbubbleentity.owner = this;
1376                 this.chatbubbleentity.exteriormodeltoclient = this;
1377                 setthink(this.chatbubbleentity, ChatBubbleThink);
1378                 this.chatbubbleentity.nextthink = time;
1379                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1380                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1381                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1382                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1383                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1384                 //this.chatbubbleentity.model = "";
1385                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1386         }
1387 }
1388
1389
1390 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1391 // added to the model skins
1392 /*void UpdateColorModHack()
1393 {
1394         float c;
1395         c = this.clientcolors & 15;
1396         // LordHavoc: only bothering to support white, green, red, yellow, blue
1397              if (!teamplay) this.colormod = '0 0 0';
1398         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1399         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1400         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1401         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1402         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1403         else this.colormod = '1 1 1';
1404 }*/
1405
1406 void respawn(entity this)
1407 {
1408         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1409         {
1410                 this.solid = SOLID_NOT;
1411                 this.takedamage = DAMAGE_NO;
1412                 set_movetype(this, MOVETYPE_FLY);
1413                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1414                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1415                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1416                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1417                 if(autocvar_g_respawn_ghosts_maxtime)
1418                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1419         }
1420
1421         CopyBody(this, 1);
1422
1423         this.effects |= EF_NODRAW; // prevent another CopyBody
1424         PutClientInServer(this);
1425 }
1426
1427 void play_countdown(entity this, float finished, Sound samp)
1428 {
1429     TC(Sound, samp);
1430         if(IS_REAL_CLIENT(this))
1431                 if(floor(finished - time - frametime) != floor(finished - time))
1432                         if(finished - time < 6)
1433                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1434 }
1435
1436 void player_powerups(entity this)
1437 {
1438         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1439         int items_prev = this.items;
1440
1441         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1442                 this.modelflags |= MF_ROCKET;
1443         else
1444                 this.modelflags &= ~MF_ROCKET;
1445
1446         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1447
1448         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1449                 return;
1450
1451         Fire_ApplyDamage(this);
1452         Fire_ApplyEffect(this);
1453
1454         if (!g_instagib)
1455         {
1456                 if (this.items & ITEM_Strength.m_itemid)
1457                 {
1458                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1459                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1460                         if (time > this.strength_finished)
1461                         {
1462                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1463                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1464                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1465                         }
1466                 }
1467                 else
1468                 {
1469                         if (time < this.strength_finished)
1470                         {
1471                                 this.items = this.items | ITEM_Strength.m_itemid;
1472                                 if(!g_cts)
1473                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1474                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1475                         }
1476                 }
1477                 if (this.items & ITEM_Shield.m_itemid)
1478                 {
1479                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1480                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1481                         if (time > this.invincible_finished)
1482                         {
1483                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1484                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1485                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1486                         }
1487                 }
1488                 else
1489                 {
1490                         if (time < this.invincible_finished)
1491                         {
1492                                 this.items = this.items | ITEM_Shield.m_itemid;
1493                                 if(!g_cts)
1494                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1495                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1496                         }
1497                 }
1498                 if (this.items & IT_SUPERWEAPON)
1499                 {
1500                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1501                         {
1502                                 this.superweapons_finished = 0;
1503                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1504                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1505                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1506                         }
1507                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1508                         {
1509                                 // don't let them run out
1510                         }
1511                         else
1512                         {
1513                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1514                                 if (time > this.superweapons_finished)
1515                                 {
1516                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1517                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1518                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1519                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1520                                 }
1521                         }
1522                 }
1523                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1524                 {
1525                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1526                         {
1527                                 this.items = this.items | IT_SUPERWEAPON;
1528                                 if(!g_cts)
1529                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1530                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1531                         }
1532                         else
1533                         {
1534                                 this.superweapons_finished = 0;
1535                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1536                         }
1537                 }
1538                 else
1539                 {
1540                         this.superweapons_finished = 0;
1541                 }
1542         }
1543
1544         if(autocvar_g_nodepthtestplayers)
1545                 this.effects = this.effects | EF_NODEPTHTEST;
1546
1547         if(autocvar_g_fullbrightplayers)
1548                 this.effects = this.effects | EF_FULLBRIGHT;
1549
1550         if (time >= game_starttime)
1551         if (time < this.spawnshieldtime)
1552                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1553
1554         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1555 }
1556
1557 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1558 {
1559         if(current > stable)
1560                 return current;
1561         else if(current > stable - 0.25) // when close enough, "snap"
1562                 return stable;
1563         else
1564                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1565 }
1566
1567 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1568 {
1569         if(current < stable)
1570                 return current;
1571         else if(current < stable + 0.25) // when close enough, "snap"
1572                 return stable;
1573         else
1574                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1575 }
1576
1577 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1578 {
1579         if(current > rotstable)
1580         {
1581                 if(rotframetime > 0)
1582                 {
1583                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1584                         current = max(rotstable, current - rotlinear * rotframetime);
1585                 }
1586         }
1587         else if(current < regenstable)
1588         {
1589                 if(regenframetime > 0)
1590                 {
1591                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1592                         current = min(regenstable, current + regenlinear * regenframetime);
1593                 }
1594         }
1595
1596         if(current > limit)
1597                 current = limit;
1598
1599         return current;
1600 }
1601
1602 void player_regen(entity this)
1603 {
1604         float max_mod, regen_mod, rot_mod, limit_mod;
1605         max_mod = regen_mod = rot_mod = limit_mod = 1;
1606
1607         float regen_health = autocvar_g_balance_health_regen;
1608         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1609         float regen_health_rot = autocvar_g_balance_health_rot;
1610         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1611         float regen_health_stable = autocvar_g_balance_health_regenstable;
1612         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1613         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1614                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1615         max_mod = M_ARGV(1, float);
1616         regen_mod = M_ARGV(2, float);
1617         rot_mod = M_ARGV(3, float);
1618         limit_mod = M_ARGV(4, float);
1619         regen_health = M_ARGV(5, float);
1620         regen_health_linear = M_ARGV(6, float);
1621         regen_health_rot = M_ARGV(7, float);
1622         regen_health_rotlinear = M_ARGV(8, float);
1623         regen_health_stable = M_ARGV(9, float);
1624         regen_health_rotstable = M_ARGV(10, float);
1625
1626         if(!mutator_returnvalue)
1627         if(!STAT(FROZEN, this))
1628         {
1629                 float mina, maxa, limith, limita;
1630                 maxa = autocvar_g_balance_armor_rotstable;
1631                 mina = autocvar_g_balance_armor_regenstable;
1632                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1633                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1634
1635                 regen_health_rotstable = regen_health_rotstable * max_mod;
1636                 regen_health_stable = regen_health_stable * max_mod;
1637                 limith = limith * limit_mod;
1638                 limita = limita * limit_mod;
1639
1640                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1641                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1642         }
1643
1644         // if player rotted to death...  die!
1645         // check this outside above checks, as player may still be able to rot to death
1646         if(this.health < 1)
1647         {
1648                 if(this.vehicle)
1649                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1650                 if(this.event_damage)
1651                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1652         }
1653
1654         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1655         {
1656                 float minf, maxf, limitf;
1657
1658                 maxf = autocvar_g_balance_fuel_rotstable;
1659                 minf = autocvar_g_balance_fuel_regenstable;
1660                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1661
1662                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1663         }
1664         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1665         // TODO: Remove this hack when all code uses GivePlayerHealth and
1666         // GivePlayerArmor.
1667         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1668         {
1669                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1670         }
1671         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1672         {
1673                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1674         }
1675         // End hack.
1676 }
1677
1678 bool zoomstate_set;
1679 void SetZoomState(entity this, float newzoom)
1680 {
1681         if(newzoom != CS(this).zoomstate)
1682         {
1683                 CS(this).zoomstate = newzoom;
1684                 ClientData_Touch(this);
1685         }
1686         zoomstate_set = true;
1687 }
1688
1689 void GetPressedKeys(entity this)
1690 {
1691         MUTATOR_CALLHOOK(GetPressedKeys, this);
1692         int keys = STAT(PRESSED_KEYS, this);
1693         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1694         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1695         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1696         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1697
1698         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1699         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1700         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1701         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1702         CS(this).pressedkeys = keys; // store for other users
1703
1704         STAT(PRESSED_KEYS, this) = keys;
1705 }
1706
1707 /*
1708 ======================
1709 spectate mode routines
1710 ======================
1711 */
1712
1713 void SpectateCopy(entity this, entity spectatee)
1714 {
1715     TC(Client, this); TC(Client, spectatee);
1716
1717         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1718         PS(this) = PS(spectatee);
1719         this.armortype = spectatee.armortype;
1720         this.armorvalue = spectatee.armorvalue;
1721         this.ammo_cells = spectatee.ammo_cells;
1722         this.ammo_plasma = spectatee.ammo_plasma;
1723         this.ammo_shells = spectatee.ammo_shells;
1724         this.ammo_nails = spectatee.ammo_nails;
1725         this.ammo_rockets = spectatee.ammo_rockets;
1726         this.ammo_fuel = spectatee.ammo_fuel;
1727         this.clip_load = spectatee.clip_load;
1728         this.clip_size = spectatee.clip_size;
1729         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1730         this.health = spectatee.health;
1731         CS(this).impulse = 0;
1732         this.items = spectatee.items;
1733         this.last_pickup = spectatee.last_pickup;
1734         this.hit_time = spectatee.hit_time;
1735         this.strength_finished = spectatee.strength_finished;
1736         this.invincible_finished = spectatee.invincible_finished;
1737         this.superweapons_finished = spectatee.superweapons_finished;
1738         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1739         this.weapons = spectatee.weapons;
1740         this.vortex_charge = spectatee.vortex_charge;
1741         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1742         this.hagar_load = spectatee.hagar_load;
1743         this.arc_heat_percent = spectatee.arc_heat_percent;
1744         this.minelayer_mines = spectatee.minelayer_mines;
1745         this.punchangle = spectatee.punchangle;
1746         this.view_ofs = spectatee.view_ofs;
1747         this.velocity = spectatee.velocity;
1748         this.dmg_take = spectatee.dmg_take;
1749         this.dmg_save = spectatee.dmg_save;
1750         this.dmg_inflictor = spectatee.dmg_inflictor;
1751         this.v_angle = spectatee.v_angle;
1752         this.angles = spectatee.v_angle;
1753         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1754         this.revive_progress = spectatee.revive_progress;
1755         this.viewloc = spectatee.viewloc;
1756         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1757                 this.fixangle = true;
1758         setorigin(this, spectatee.origin);
1759         setsize(this, spectatee.mins, spectatee.maxs);
1760         SetZoomState(this, CS(spectatee).zoomstate);
1761
1762         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1763         {
1764                 .entity weaponentity = weaponentities[slot];
1765                 this.(weaponentity) = spectatee.(weaponentity);
1766         }
1767
1768         for(int slot = 0; slot < MAX_AXH; ++slot)
1769         {
1770                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1771         }
1772
1773     anticheat_spectatecopy(this, spectatee);
1774         this.hud = spectatee.hud;
1775         if(spectatee.vehicle)
1776     {
1777         this.angles = spectatee.v_angle;
1778
1779         //this.fixangle = false;
1780         //this.velocity = spectatee.vehicle.velocity;
1781         this.vehicle_health = spectatee.vehicle_health;
1782         this.vehicle_shield = spectatee.vehicle_shield;
1783         this.vehicle_energy = spectatee.vehicle_energy;
1784         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1785         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1786         this.vehicle_reload1 = spectatee.vehicle_reload1;
1787         this.vehicle_reload2 = spectatee.vehicle_reload2;
1788
1789         //msg_entity = this;
1790
1791        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1792             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1793            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1794            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1795
1796         //WriteByte (MSG_ONE, SVC_SETVIEW);
1797         //    WriteEntity(MSG_ONE, this);
1798         //makevectors(spectatee.v_angle);
1799         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1800     }
1801 }
1802
1803 bool SpectateUpdate(entity this)
1804 {
1805         if(!this.enemy)
1806                 return false;
1807
1808         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1809         {
1810                 SetSpectatee(this, NULL);
1811                 return false;
1812         }
1813
1814         SpectateCopy(this, this.enemy);
1815
1816         return true;
1817 }
1818
1819 bool SpectateSet(entity this)
1820 {
1821         if(!IS_PLAYER(this.enemy))
1822                 return false;
1823
1824         ClientData_Touch(this.enemy);
1825
1826         msg_entity = this;
1827         WriteByte(MSG_ONE, SVC_SETVIEW);
1828         WriteEntity(MSG_ONE, this.enemy);
1829         set_movetype(this, MOVETYPE_NONE);
1830         accuracy_resend(this);
1831
1832         if(!SpectateUpdate(this))
1833                 PutObserverInServer(this);
1834
1835         return true;
1836 }
1837
1838 void SetSpectatee_status(entity this, int spectatee_num)
1839 {
1840         int oldspectatee_status = CS(this).spectatee_status;
1841         CS(this).spectatee_status = spectatee_num;
1842
1843         if (CS(this).spectatee_status != oldspectatee_status)
1844         {
1845                 ClientData_Touch(this);
1846                 if (g_race || g_cts) race_InitSpectator();
1847         }
1848 }
1849
1850 void SetSpectatee(entity this, entity spectatee)
1851 {
1852         if(IS_BOT_CLIENT(this))
1853                 return; // bots abuse .enemy, this code is useless to them
1854
1855         entity old_spectatee = this.enemy;
1856
1857         this.enemy = spectatee;
1858
1859         // WEAPONTODO
1860         // these are required to fix the spectator bug with arc
1861         if(old_spectatee)
1862         {
1863                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1864                 {
1865                         .entity weaponentity = weaponentities[slot];
1866                         if(old_spectatee.(weaponentity).arc_beam)
1867                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1868                 }
1869         }
1870         if(this.enemy)
1871         {
1872                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1873                 {
1874                         .entity weaponentity = weaponentities[slot];
1875                         if(this.enemy.(weaponentity).arc_beam)
1876                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1877                 }
1878         }
1879
1880         if (this.enemy)
1881                 SetSpectatee_status(this, etof(this.enemy));
1882
1883         // needed to update spectator list
1884         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1885 }
1886
1887 bool Spectate(entity this, entity pl)
1888 {
1889         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1890                 return false;
1891         pl = M_ARGV(1, entity);
1892
1893         SetSpectatee(this, pl);
1894         return SpectateSet(this);
1895 }
1896
1897 bool SpectateNext(entity this)
1898 {
1899         entity ent = find(this.enemy, classname, STR_PLAYER);
1900
1901         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1902                 ent = M_ARGV(1, entity);
1903         else if (!ent)
1904                 ent = find(ent, classname, STR_PLAYER);
1905
1906         if(ent) { SetSpectatee(this, ent); }
1907
1908         return SpectateSet(this);
1909 }
1910
1911 bool SpectatePrev(entity this)
1912 {
1913         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1914         entity ent = findchain(classname, STR_PLAYER);
1915         if (!ent) // no player
1916                 return false;
1917
1918         entity first = ent;
1919         // skip players until current spectated player
1920         if(this.enemy)
1921         while(ent && ent != this.enemy)
1922                 ent = ent.chain;
1923
1924         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1925         {
1926                 case MUT_SPECPREV_FOUND:
1927                     ent = M_ARGV(1, entity);
1928                     break;
1929                 case MUT_SPECPREV_RETURN:
1930                     return true;
1931                 case MUT_SPECPREV_CONTINUE:
1932                 default:
1933                 {
1934                         if(ent.chain)
1935                                 ent = ent.chain;
1936                         else
1937                                 ent = first;
1938                         break;
1939                 }
1940         }
1941
1942         SetSpectatee(this, ent);
1943         return SpectateSet(this);
1944 }
1945
1946 /*
1947 =============
1948 ShowRespawnCountdown()
1949
1950 Update a respawn countdown display.
1951 =============
1952 */
1953 void ShowRespawnCountdown(entity this)
1954 {
1955         float number;
1956         if(!IS_DEAD(this)) // just respawned?
1957                 return;
1958         else
1959         {
1960                 number = ceil(this.respawn_time - time);
1961                 if(number <= 0)
1962                         return;
1963                 if(number <= this.respawn_countdown)
1964                 {
1965                         this.respawn_countdown = number - 1;
1966                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1967                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1968                 }
1969         }
1970 }
1971
1972 .bool team_selected;
1973 bool ShowTeamSelection(entity this)
1974 {
1975         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1976                 return false;
1977         stuffcmd(this, "menu_showteamselect\n");
1978         return true;
1979 }
1980 void Join(entity this)
1981 {
1982         TRANSMUTE(Player, this);
1983
1984         if(!this.team_selected)
1985         if(autocvar_g_campaign || autocvar_g_balance_teams)
1986                 JoinBestTeam(this, false, true);
1987
1988         if(autocvar_g_campaign)
1989                 campaign_bots_may_start = true;
1990
1991         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1992
1993         PutClientInServer(this);
1994
1995         if(IS_PLAYER(this))
1996         if(teamplay && this.team != -1)
1997                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1998         else
1999                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2000         this.team_selected = false;
2001 }
2002
2003 /**
2004  * Determines whether the player is allowed to join. This depends on cvar
2005  * g_maxplayers, if it isn't used this function always return true, otherwise
2006  * it checks whether the number of currently playing players exceeds g_maxplayers.
2007  * @return int number of free slots for players, 0 if none
2008  */
2009 int nJoinAllowed(entity this, entity ignore)
2010 {
2011         if(!ignore)
2012         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2013         // so report 0 free slots if restricted
2014         {
2015                 if(autocvar_g_forced_team_otherwise == "spectate")
2016                         return 0;
2017                 if(autocvar_g_forced_team_otherwise == "spectator")
2018                         return 0;
2019         }
2020
2021         if(this && this.team_forced < 0)
2022                 return 0; // forced spectators can never join
2023
2024         // TODO simplify this
2025         int totalClients = 0;
2026         int currentlyPlaying = 0;
2027         FOREACH_CLIENT(true, {
2028                 if(it != ignore)
2029                         ++totalClients;
2030                 if(IS_REAL_CLIENT(it))
2031                 if(IS_PLAYER(it) || it.caplayer)
2032                         ++currentlyPlaying;
2033         });
2034
2035         float free_slots = 0;
2036         if (!autocvar_g_maxplayers)
2037                 free_slots = maxclients - totalClients;
2038         else if(currentlyPlaying < autocvar_g_maxplayers)
2039                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2040
2041         static float join_prevent_msg_time = 0;
2042         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2043         {
2044                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2045                 join_prevent_msg_time = time + 3;
2046         }
2047
2048         return free_slots;
2049 }
2050
2051 /**
2052  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2053  * g_maxplayers_spectator_blocktime seconds
2054  */
2055 void checkSpectatorBlock(entity this)
2056 {
2057         if(IS_SPEC(this) || IS_OBSERVER(this))
2058         if(!this.caplayer)
2059         if(IS_REAL_CLIENT(this))
2060         {
2061                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2062                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2063                         dropclient(this);
2064                 }
2065         }
2066 }
2067
2068 void PrintWelcomeMessage(entity this)
2069 {
2070         if(CS(this).motd_actived_time == 0)
2071         {
2072                 if (autocvar_g_campaign) {
2073                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2074                                 CS(this).motd_actived_time = time;
2075                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2076                         }
2077                 } else {
2078                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2079                                 CS(this).motd_actived_time = time;
2080                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2081                         }
2082                 }
2083         }
2084         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2085         {
2086                 if (autocvar_g_campaign) {
2087                         if (PHYS_INPUT_BUTTON_INFO(this))
2088                                 CS(this).motd_actived_time = time;
2089                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2090                                 CS(this).motd_actived_time = 0;
2091                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2092                         }
2093                 } else {
2094                         if (PHYS_INPUT_BUTTON_INFO(this))
2095                                 CS(this).motd_actived_time = time;
2096                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2097                                 CS(this).motd_actived_time = 0;
2098                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2099                         }
2100                 }
2101         }
2102         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2103         {
2104                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2105                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2106                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2107                 {
2108                         // instanctly hide MOTD
2109                         CS(this).motd_actived_time = 0;
2110                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2111                 }
2112         }
2113 }
2114
2115 bool joinAllowed(entity this)
2116 {
2117         if (CS(this).version_mismatch) return false;
2118         if (!nJoinAllowed(this, this)) return false;
2119         if (teamplay && lockteams) return false;
2120         if (ShowTeamSelection(this)) return false;
2121         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2122         return true;
2123 }
2124
2125 .int items_added;
2126 bool PlayerThink(entity this)
2127 {
2128         if (game_stopped || intermission_running) {
2129                 this.modelflags &= ~MF_ROCKET;
2130                 if(intermission_running)
2131                         IntermissionThink(this);
2132                 return false;
2133         }
2134
2135         if (timeout_status == TIMEOUT_ACTIVE) {
2136         // don't allow the player to turn around while game is paused
2137                 // FIXME turn this into CSQC stuff
2138                 this.v_angle = this.lastV_angle;
2139                 this.angles = this.lastV_angle;
2140                 this.fixangle = true;
2141         }
2142
2143         if (frametime) player_powerups(this);
2144
2145         if (IS_DEAD(this)) {
2146                 if (this.personal && g_race_qualifying) {
2147                         if (time > this.respawn_time) {
2148                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2149                                 respawn(this);
2150                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2151                         }
2152                 } else {
2153                         if (frametime) player_anim(this);
2154
2155                         if (this.respawn_flags & RESPAWN_DENY)
2156                         {
2157                                 STAT(RESPAWN_TIME, this) = 0;
2158                                 return false;
2159                         }
2160
2161                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2162
2163                         switch(this.deadflag)
2164                         {
2165                                 case DEAD_DYING:
2166                                 {
2167                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2168                                                 this.deadflag = DEAD_RESPAWNING;
2169                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2170                                                 this.deadflag = DEAD_DEAD;
2171                                         break;
2172                                 }
2173                                 case DEAD_DEAD:
2174                                 {
2175                                         if (button_pressed)
2176                                                 this.deadflag = DEAD_RESPAWNABLE;
2177                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2178                                                 this.deadflag = DEAD_RESPAWNING;
2179                                         break;
2180                                 }
2181                                 case DEAD_RESPAWNABLE:
2182                                 {
2183                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2184                                                 this.deadflag = DEAD_RESPAWNING;
2185                                         break;
2186                                 }
2187                                 case DEAD_RESPAWNING:
2188                                 {
2189                                         if (time > this.respawn_time)
2190                                         {
2191                                                 this.respawn_time = time + 1; // only retry once a second
2192                                                 this.respawn_time_max = this.respawn_time;
2193                                                 respawn(this);
2194                                         }
2195                                         break;
2196                                 }
2197                         }
2198
2199                         ShowRespawnCountdown(this);
2200
2201                         if (this.respawn_flags & RESPAWN_SILENT)
2202                                 STAT(RESPAWN_TIME, this) = 0;
2203                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2204                         {
2205                                 if (time < this.respawn_time)
2206                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2207                                 else if (this.deadflag != DEAD_RESPAWNING)
2208                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2209                         }
2210                         else
2211                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2212                 }
2213
2214                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2215                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2216                         STAT(RESPAWN_TIME, this) *= -1;
2217
2218                 return false;
2219         }
2220
2221         bool have_hook = false;
2222         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2223         {
2224                 .entity weaponentity = weaponentities[slot];
2225                 if(this.(weaponentity).hook.state)
2226                 {
2227                         have_hook = true;
2228                         break;
2229                 }
2230         }
2231         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2232         if (have_hook) {
2233                 do_crouch = false;
2234         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2235                 do_crouch = false;
2236         } else if (this.vehicle) {
2237                 do_crouch = false;
2238         } else if (STAT(FROZEN, this)) {
2239                 do_crouch = false;
2240     }
2241
2242         if (do_crouch) {
2243                 if (!this.crouch) {
2244                         this.crouch = true;
2245                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2246                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2247                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2248                 }
2249         } else if (this.crouch) {
2250         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2251         if (!trace_startsolid) {
2252             this.crouch = false;
2253             this.view_ofs = STAT(PL_VIEW_OFS, this);
2254             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2255         }
2256         }
2257
2258         FixPlayermodel(this);
2259
2260         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2261         //if(frametime)
2262         {
2263                 this.items &= ~this.items_added;
2264
2265                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2266                 {
2267                         .entity weaponentity = weaponentities[slot];
2268                         W_WeaponFrame(this, weaponentity);
2269
2270                         if(slot == 0)
2271                         {
2272                                 this.clip_load = this.(weaponentity).clip_load;
2273                                 this.clip_size = this.(weaponentity).clip_size;
2274                         }
2275                 }
2276
2277                 this.items_added = 0;
2278                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2279             this.items_added |= IT_FUEL;
2280
2281                 this.items |= this.items_added;
2282         }
2283
2284         player_regen(this);
2285
2286         // WEAPONTODO: Add a weapon request for this
2287         // rot vortex charge to the charge limit
2288         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2289         {
2290                 .entity weaponentity = weaponentities[slot];
2291                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2292                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2293         }
2294
2295         if (frametime) player_anim(this);
2296
2297         // secret status
2298         secrets_setstatus(this);
2299
2300         // monsters status
2301         monsters_setstatus(this);
2302
2303         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2304
2305         return true;
2306 }
2307
2308 void ObserverThink(entity this)
2309 {
2310         if ( CS(this).impulse )
2311         {
2312                 MinigameImpulse(this, CS(this).impulse);
2313                 CS(this).impulse = 0;
2314         }
2315
2316         if (this.flags & FL_JUMPRELEASED) {
2317                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2318                         this.flags &= ~FL_JUMPRELEASED;
2319                         this.flags |= FL_SPAWNING;
2320                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2321                         this.flags &= ~FL_JUMPRELEASED;
2322                         if(SpectateNext(this)) {
2323                                 TRANSMUTE(Spectator, this);
2324                         }
2325                 } else {
2326                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2327                         set_movetype(this, preferred_movetype);
2328                 }
2329         } else {
2330                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2331                         this.flags |= FL_JUMPRELEASED;
2332                         if(this.flags & FL_SPAWNING)
2333                         {
2334                                 this.flags &= ~FL_SPAWNING;
2335                                 Join(this);
2336                                 return;
2337                         }
2338                 }
2339         }
2340 }
2341
2342 void SpectatorThink(entity this)
2343 {
2344         if ( CS(this).impulse )
2345         {
2346                 if(MinigameImpulse(this, CS(this).impulse))
2347                         CS(this).impulse = 0;
2348
2349                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2350                 {
2351                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2352                         CS(this).impulse = 0;
2353                         return;
2354                 }
2355         }
2356
2357         if (this.flags & FL_JUMPRELEASED) {
2358                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2359                         this.flags &= ~FL_JUMPRELEASED;
2360                         this.flags |= FL_SPAWNING;
2361                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2362                         this.flags &= ~FL_JUMPRELEASED;
2363                         if(SpectateNext(this)) {
2364                                 TRANSMUTE(Spectator, this);
2365                         } else {
2366                                 TRANSMUTE(Observer, this);
2367                                 PutClientInServer(this);
2368                         }
2369                         CS(this).impulse = 0;
2370                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2371                         this.flags &= ~FL_JUMPRELEASED;
2372                         if(SpectatePrev(this)) {
2373                                 TRANSMUTE(Spectator, this);
2374                         } else {
2375                                 TRANSMUTE(Observer, this);
2376                                 PutClientInServer(this);
2377                         }
2378                         CS(this).impulse = 0;
2379                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2380                         this.flags &= ~FL_JUMPRELEASED;
2381                         TRANSMUTE(Observer, this);
2382                         PutClientInServer(this);
2383                 } else {
2384                         if(!SpectateUpdate(this))
2385                                 PutObserverInServer(this);
2386                 }
2387         } else {
2388                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2389                         this.flags |= FL_JUMPRELEASED;
2390                         if(this.flags & FL_SPAWNING)
2391                         {
2392                                 this.flags &= ~FL_SPAWNING;
2393                                 Join(this);
2394                                 return;
2395                         }
2396                 }
2397                 if(!SpectateUpdate(this))
2398                         PutObserverInServer(this);
2399         }
2400
2401         this.flags |= FL_CLIENT | FL_NOTARGET;
2402 }
2403
2404 void vehicles_enter (entity pl, entity veh);
2405 void PlayerUseKey(entity this)
2406 {
2407         if (!IS_PLAYER(this))
2408                 return;
2409
2410         if(this.vehicle)
2411         {
2412                 if(!game_stopped)
2413                 {
2414                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2415                         return;
2416                 }
2417         }
2418         else if(autocvar_g_vehicles_enter)
2419         {
2420                 if(!STAT(FROZEN, this))
2421                 if(!IS_DEAD(this))
2422                 if(!game_stopped)
2423                 {
2424                         entity head, closest_target = NULL;
2425                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2426
2427                         while(head) // find the closest acceptable target to enter
2428                         {
2429                                 if(IS_VEHICLE(head))
2430                                 if(!IS_DEAD(head))
2431                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2432                                 if(head.takedamage != DAMAGE_NO)
2433                                 {
2434                                         if(closest_target)
2435                                         {
2436                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2437                                                 { closest_target = head; }
2438                                         }
2439                                         else { closest_target = head; }
2440                                 }
2441
2442                                 head = head.chain;
2443                         }
2444
2445                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2446                 }
2447         }
2448
2449         // a use key was pressed; call handlers
2450         MUTATOR_CALLHOOK(PlayerUseKey, this);
2451 }
2452
2453
2454 /*
2455 =============
2456 PlayerPreThink
2457
2458 Called every frame for each client before the physics are run
2459 =============
2460 */
2461 .float last_vehiclecheck;
2462 void PlayerPreThink (entity this)
2463 {
2464         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2465         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2466
2467         WarpZone_PlayerPhysics_FixVAngle(this);
2468
2469         if (frametime) {
2470                 // physics frames: update anticheat stuff
2471                 anticheat_prethink(this);
2472         }
2473
2474         if (blockSpectators && frametime) {
2475                 // WORKAROUND: only use dropclient in server frames (frametime set).
2476                 // Never use it in cl_movement frames (frametime zero).
2477                 checkSpectatorBlock(this);
2478     }
2479
2480         zoomstate_set = false;
2481
2482         // Check for nameless players
2483         if (isInvisibleString(this.netname)) {
2484                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2485                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2486         }
2487         if (this.netname != CS(this).netname_previous) {
2488                 if (autocvar_sv_eventlog) {
2489                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2490         }
2491                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2492                 CS(this).netname_previous = strzone(this.netname);
2493         }
2494
2495         // version nagging
2496         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2497         CS(this).version_nagtime = 0;
2498         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2499             // git client
2500         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2501             // git server
2502             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2503         } else {
2504             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2505             if (r < 0) { // old client
2506                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2507             } else if (r > 0) { // old server
2508                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2509             }
2510         }
2511     }
2512
2513         // GOD MODE info
2514         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2515         {
2516                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2517                 this.max_armorvalue = 0;
2518         }
2519
2520         if(IS_PLAYER(this))
2521         {
2522                 if (STAT(FROZEN, this) == 2)
2523                 {
2524                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2525                         this.health = max(1, this.revive_progress * start_health);
2526                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2527
2528                         if (this.revive_progress >= 1)
2529                                 Unfreeze(this);
2530                 }
2531                 else if (STAT(FROZEN, this) == 3)
2532                 {
2533                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2534                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2535
2536                         if (this.health < 1)
2537                         {
2538                                 if (this.vehicle)
2539                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2540                                 if(this.event_damage)
2541                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2542                         }
2543                         else if (this.revive_progress <= 0)
2544                                 Unfreeze(this);
2545                 }
2546         }
2547
2548         MUTATOR_CALLHOOK(PlayerPreThink, this);
2549
2550         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2551         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2552         {
2553                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2554                 {
2555                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2556                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2557                         {
2558                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2559                         }
2560                         else if(!it.owner)
2561                         {
2562                                 if(!it.team || SAME_TEAM(this, it))
2563                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2564                                 else if(autocvar_g_vehicles_steal)
2565                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2566                         }
2567                 });
2568
2569                 this.last_vehiclecheck = time + 1;
2570         }
2571
2572         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2573         {
2574                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2575                         PlayerUseKey(this);
2576                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2577         }
2578
2579         if (IS_REAL_CLIENT(this))
2580                 PrintWelcomeMessage(this);
2581
2582         if (IS_PLAYER(this)) {
2583                 if(!PlayerThink(this))
2584                         return;
2585         }
2586         else if (game_stopped || intermission_running) {
2587                 if(intermission_running)
2588                         IntermissionThink(this);
2589                 return;
2590         }
2591         else if (IS_OBSERVER(this)) {
2592                 ObserverThink(this);
2593         }
2594         else if (IS_SPEC(this)) {
2595                 SpectatorThink(this);
2596         }
2597
2598         // WEAPONTODO: Add weapon request for this
2599         if (!zoomstate_set) {
2600                 bool wep_zoomed = false;
2601                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2602                 {
2603                         .entity weaponentity = weaponentities[slot];
2604                         Weapon thiswep = this.(weaponentity).m_weapon;
2605                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2606                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2607                 }
2608                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2609     }
2610
2611         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2612         {
2613                 CS(this).teamkill_soundtime = 0;
2614
2615                 entity e = CS(this).teamkill_soundsource;
2616                 entity oldpusher = e.pusher;
2617                 e.pusher = this;
2618                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2619                 e.pusher = oldpusher;
2620         }
2621
2622         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2623                 CS(this).taunt_soundtime = 0;
2624                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2625         }
2626
2627         target_voicescript_next(this);
2628
2629         // WEAPONTODO: Move into weaponsystem somehow
2630         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2631         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2632         {
2633                 .entity weaponentity = weaponentities[slot];
2634                 if(this.(weaponentity).m_weapon == WEP_Null)
2635                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2636         }
2637 }
2638
2639 void DrownPlayer(entity this)
2640 {
2641         if(IS_DEAD(this))
2642                 return;
2643
2644         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2645         {
2646                 if(this.air_finished < time)
2647                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2648                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2649                 this.dmg = 2;
2650         }
2651         else if (this.air_finished < time)
2652         {       // drown!
2653                 if (this.pain_finished < time)
2654                 {
2655                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2656                         this.pain_finished = time + 0.5;
2657                 }
2658         }
2659 }
2660
2661 .bool move_qcphysics;
2662
2663 void Player_Physics(entity this)
2664 {
2665         set_movetype(this, this.move_movetype);
2666
2667         if(!this.move_qcphysics)
2668                 return;
2669
2670         if(!frametime && !CS(this).pm_frametime)
2671                 return;
2672
2673         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2674
2675         CS(this).pm_frametime = 0;
2676 }
2677
2678 /*
2679 =============
2680 PlayerPostThink
2681
2682 Called every frame for each client after the physics are run
2683 =============
2684 */
2685 void PlayerPostThink (entity this)
2686 {
2687         Player_Physics(this);
2688
2689         if (sv_maxidle > 0)
2690         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2691         if (IS_REAL_CLIENT(this))
2692         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2693         {
2694                 int totalClients = 0;
2695                 if(sv_maxidle_slots > 0)
2696                 {
2697                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2698                         {
2699                                 ++totalClients;
2700                         });
2701                 }
2702
2703                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2704                 { /* do nothing */ }
2705                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2706                 {
2707                         if (CS(this).idlekick_lasttimeleft)
2708                         {
2709                                 CS(this).idlekick_lasttimeleft = 0;
2710                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2711                         }
2712                 }
2713                 else
2714                 {
2715                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2716                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2717                                 if (!CS(this).idlekick_lasttimeleft)
2718                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2719                         }
2720                         if (timeleft <= 0) {
2721                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2722                                 dropclient(this);
2723                                 return;
2724                         }
2725                         else if (timeleft <= 10) {
2726                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2727                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2728                 }
2729                                 CS(this).idlekick_lasttimeleft = timeleft;
2730                         }
2731                 }
2732         }
2733
2734         CheatFrame(this);
2735
2736         if (game_stopped)
2737         {
2738                 this.solid = SOLID_NOT;
2739                 this.takedamage = DAMAGE_NO;
2740                 set_movetype(this, MOVETYPE_NONE);
2741         }
2742
2743         if (IS_PLAYER(this)) {
2744                 DrownPlayer(this);
2745                 UpdateChatBubble(this);
2746                 if (CS(this).impulse) ImpulseCommands(this);
2747                 if (game_stopped)
2748                 {
2749                         CSQCMODEL_AUTOUPDATE(this);
2750                         return;
2751                 }
2752                 GetPressedKeys(this);
2753         }
2754
2755         if (this.waypointsprite_attachedforcarrier) {
2756             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2757                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2758     }
2759
2760         playerdemo_write(this);
2761
2762         CSQCMODEL_AUTOUPDATE(this);
2763 }
2764
2765 // hack to copy the button fields from the client entity to the Client State
2766 void PM_UpdateButtons(entity this, entity store)
2767 {
2768         if(this.impulse)
2769                 store.impulse = this.impulse;
2770         this.impulse = 0;
2771
2772         store.button0 = this.button0;
2773         store.button2 = this.button2;
2774         store.button3 = this.button3;
2775         store.button4 = this.button4;
2776         store.button5 = this.button5;
2777         store.button6 = this.button6;
2778         store.button7 = this.button7;
2779         store.button8 = this.button8;
2780         store.button9 = this.button9;
2781         store.button10 = this.button10;
2782         store.button11 = this.button11;
2783         store.button12 = this.button12;
2784         store.button13 = this.button13;
2785         store.button14 = this.button14;
2786         store.button15 = this.button15;
2787         store.button16 = this.button16;
2788         store.buttonuse = this.buttonuse;
2789         store.buttonchat = this.buttonchat;
2790
2791         store.cursor_active = this.cursor_active;
2792         store.cursor_screen = this.cursor_screen;
2793         store.cursor_trace_start = this.cursor_trace_start;
2794         store.cursor_trace_endpos = this.cursor_trace_endpos;
2795         store.cursor_trace_ent = this.cursor_trace_ent;
2796
2797         store.ping = this.ping;
2798         store.ping_packetloss = this.ping_packetloss;
2799         store.ping_movementloss = this.ping_movementloss;
2800
2801         store.v_angle = this.v_angle;
2802         store.movement = this.movement;
2803 }