qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/client.qh>
  15 #include <server/command/banning.qh>
  16 #include <server/command/common.qh>
  17 #include <server/command/vote.qh>
  18 #include <server/damage.qh>
  19 #include <server/gamelog.qh>
  20 #include <server/intermission.qh>
  21 #include <server/mutators/_mod.qh>
  22 #include <server/race.qh>
  23 #include <server/round_handler.qh>
  24 #include <server/scores.qh>
  25 #include <server/teamplay.qh>
  26 #include <server/weapons/accuracy.qh>
  27 #include <server/world.qh>
  28
  29 // =============================================
  30 //  Server side voting code, reworked by Samual
  31 //  Last updated: December 27th, 2011
  32 // =============================================
  33
  34 //  Nagger for players to know status of voting
  35 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  36 {
  37         int nags, i, f, b;
  38         entity e;
  39         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  40
  41         // bits:
  42         //   1 = ready
  43         //   2 = player needs to ready up
  44         //   4 = vote
  45         //   8 = player needs to vote
  46         //  16 = warmup
  47         // sendflags:
  48         //  64 = vote counts
  49         // 128 = vote string
  50
  51         nags = 0;
  52         if (readycount)
  53         {
  54                 nags |= BIT(0);
  55                 if (to.ready == 0) nags |= BIT(1);
  56         }
  57         if (vote_called)
  58         {
  59                 nags |= BIT(2);
  60                 if (to.vote_selection == 0) nags |= BIT(3);
  61         }
  62         if (warmup_stage) nags |= BIT(4);
  63
  64         if (sendflags & BIT(6)) nags |= BIT(6);
  65
  66         if (sendflags & BIT(7)) nags |= BIT(7);
  67
  68         if (!(nags & 4))  // no vote called? send no string
  69                 nags &= ~(BIT(6) | BIT(7));
  70
  71         WriteByte(MSG_ENTITY, nags);
  72
  73         if (nags & BIT(6))
  74         {
  75                 WriteByte(MSG_ENTITY, vote_accept_count);
  76                 WriteByte(MSG_ENTITY, vote_reject_count);
  77                 WriteByte(MSG_ENTITY, vote_needed_overall);
  78                 WriteChar(MSG_ENTITY, to.vote_selection);
  79         }
  80
  81         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  82
  83         if (nags & 1)
  84         {
  85                 for (i = 1; i <= maxclients; i += 8)
  86                 {
  87                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  88                                 if (!IS_REAL_CLIENT(e) || e.ready)
  89                                         f |= b;
  90                         WriteByte(MSG_ENTITY, f);
  91                 }
  92         }
  93
  94         return true;
  95 }
  96
  97 void Nagger_Init()
  98 {
  99         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
 100 }
 101
 102 void Nagger_VoteChanged()
 103 {
 104         if (nagger) nagger.SendFlags |= BIT(7);
 105 }
 106
 107 void Nagger_VoteCountChanged()
 108 {
 109         if (nagger) nagger.SendFlags |= BIT(6);
 110 }
 111
 112 void Nagger_ReadyCounted()
 113 {
 114         if (nagger) nagger.SendFlags |= BIT(0);
 115 }
 116
 117 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 118 string OriginalCallerName()
 119 {
 120         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 121         return vote_caller_name;
 122 }
 123
 124 // =======================
 125 //  Game logic for voting
 126 // =======================
 127
 128 void VoteReset()
 129 {
 130         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 131
 132         if (vote_called)
 133         {
 134                 strfree(vote_called_command);
 135                 strfree(vote_called_display);
 136                 strfree(vote_caller_name);
 137         }
 138
 139         vote_called = VOTE_NULL;
 140         vote_caller = NULL;
 141         vote_endtime = 0;
 142
 143         vote_parsed_command = string_null;
 144         vote_parsed_display = string_null;
 145
 146         Nagger_VoteChanged();
 147 }
 148
 149 void VoteStop(entity stopper)
 150 {
 151         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 152         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 153         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 154         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 155         VoteReset();
 156 }
 157
 158 void VoteAccept()
 159 {
 160         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 161
 162         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 163         else localcmd(strcat(vote_called_command, "\n"));
 164
 165         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 166
 167         VoteReset();
 168         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 169 }
 170
 171 void VoteReject()
 172 {
 173         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 174         VoteReset();
 175         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 176 }
 177
 178 void VoteTimeout()
 179 {
 180         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 181         VoteReset();
 182         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 183 }
 184
 185 void VoteSpam(float notvoters, float mincount, string result)
 186 {
 187         bprint(strcat(
 188                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 189                 strcat("^2:^1", ftos(vote_reject_count)),
 190                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 191                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 192                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 193
 194         if (autocvar_sv_eventlog)
 195         {
 196                 GameLogEcho(strcat(
 197                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 198                         strcat(":", ftos(vote_reject_count)),
 199                         strcat(":", ftos(vote_abstain_count)),
 200                         strcat(":", ftos(notvoters)),
 201                         strcat(":", ftos(mincount))));
 202         }
 203 }
 204
 205 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 206
 207 void VoteCount(float first_count)
 208 {
 209         // declarations
 210         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 211
 212         float vote_player_count = 0, notvoters = 0;
 213         float vote_real_player_count = 0, vote_real_accept_count = 0;
 214         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 215         float vote_needed_of_voted, final_needed_votes;
 216         float vote_factor_overall, vote_factor_of_voted;
 217
 218         Nagger_VoteCountChanged();
 219
 220         // add up all the votes from each connected client
 221         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 222                 ++vote_player_count;
 223                 if (IS_PLAYER(it))   ++vote_real_player_count;
 224                 switch (it.vote_selection)
 225                 {
 226                         case VOTE_SELECT_REJECT:
 227                         { ++vote_reject_count;
 228                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 229                         }
 230                         case VOTE_SELECT_ACCEPT:
 231                         { ++vote_accept_count;
 232                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 233                         }
 234                         case VOTE_SELECT_ABSTAIN:
 235                         { ++vote_abstain_count;
 236                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 237                         }
 238                         default: break;
 239                 }
 240         });
 241
 242         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 243         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 244         {
 245                 if (vote_caller)   vote_caller.vote_waittime = 0;
 246                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 247                 VoteReset();
 248                 return;
 249         }
 250
 251         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 252         if (!spectators_allowed && (vote_real_player_count > 0))
 253         {
 254                 vote_accept_count = vote_real_accept_count;
 255                 vote_reject_count = vote_real_reject_count;
 256                 vote_abstain_count = vote_real_abstain_count;
 257                 vote_player_count = vote_real_player_count;
 258         }
 259
 260         // people who have no opinion in any way :D
 261         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 262
 263         // determine the goal for the vote to be passed or rejected normally
 264         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 265         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 266
 267         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 268         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 269         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 270
 271         // are there any players at all on the server? it could be an admin vote
 272         if (vote_player_count == 0 && first_count)
 273         {
 274                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 275                 VoteAccept();
 276                 return;
 277         }
 278
 279         // since there ARE players, finally calculate the result of the vote
 280         if (vote_accept_count >= vote_needed_overall)
 281         {
 282                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 283                 VoteAccept();
 284                 return;
 285         }
 286
 287         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 288         {
 289                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 290                 VoteReject();
 291                 return;
 292         }
 293
 294         // there is not enough votes in either direction, now lets just calculate what the voters have said
 295         if (time > vote_endtime)
 296         {
 297                 final_needed_votes = vote_needed_overall;
 298
 299                 if (autocvar_sv_vote_majority_factor_of_voted)
 300                 {
 301                         if (vote_accept_count >= vote_needed_of_voted)
 302                         {
 303                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 304                                 VoteAccept();
 305                                 return;
 306                         }
 307
 308                         if (vote_accept_count + vote_reject_count > 0)
 309                         {
 310                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 311                                 VoteReject();
 312                                 return;
 313                         }
 314
 315                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 316                 }
 317
 318                 // it didn't pass or fail, so not enough votes to even make a decision.
 319                 VoteSpam(notvoters, final_needed_votes, "timeout");
 320                 VoteTimeout();
 321         }
 322 }
 323
 324 void VoteThink()
 325 {
 326         if (vote_endtime > 0)        // a vote was called
 327         {
 328                 if (time > vote_endtime) // time is up
 329                         VoteCount(false);
 330         }
 331 }
 332
 333
 334 // =======================
 335 //  Game logic for warmup
 336 // =======================
 337
 338 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 339 void reset_map(bool dorespawn)
 340 {
 341         if (time <= game_starttime)
 342         {
 343                 if (game_stopped)
 344                         return;
 345                 if (round_handler_IsActive())
 346                         round_handler_Reset(game_starttime);
 347         }
 348
 349         if (shuffleteams_on_reset_map)
 350         {
 351                 shuffleteams();
 352                 shuffleteams_on_reset_map = false;
 353         }
 354
 355         FOREACH_CLIENT(true, {
 356                 if (time <= game_starttime)
 357                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 358                 if (!IS_PLAYER(it))
 359                         continue;
 360                 if (STAT(FROZEN, it))
 361                         Unfreeze(it, false);
 362                 player_powerups_remove_all(it);
 363                 entity store = PS(it);
 364                 if (store)
 365                 {
 366                         Inventory_clear(store.inventory);
 367                         Inventory_update(store);
 368                 }
 369         });
 370
 371         MUTATOR_CALLHOOK(reset_map_global);
 372
 373         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 374         {
 375                 if(IS_CLIENT(it))
 376                         continue;
 377                 if (it.reset)
 378                 {
 379                         it.reset(it);
 380                         continue;
 381                 }
 382                 if (it.team_saved) it.team = it.team_saved;
 383                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 384         });
 385
 386         // Waypoints and assault start come LAST
 387         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 388                 if (it.reset2) it.reset2(it);
 389         });
 390
 391         // Moving the player reset code here since the player-reset depends
 392         // on spawnpoint entities which have to be reset first --blub
 393         if (dorespawn)
 394         {
 395                 if (!MUTATOR_CALLHOOK(reset_map_players))
 396                 {
 397                         if (restart_mapalreadyrestarted || (time < game_starttime))
 398                         {
 399                                 FOREACH_CLIENT(IS_PLAYER(it),
 400                                 {
 401                                         /*
 402                                         only reset players if a restart countdown is active
 403                                         this can either be due to cvar sv_ready_restart_after_countdown having set
 404                                         restart_mapalreadyrestarted to 1 after the countdown ended or when
 405                                         sv_ready_restart_after_countdown is not used and countdown is still running
 406                                         */
 407                                         // PlayerScore_Clear(it);
 408                                         CS(it).killcount = 0;
 409                                         // stop the player from moving so that he stands still once he gets respawned
 410                                         it.velocity = '0 0 0';
 411                                         it.avelocity = '0 0 0';
 412                                         CS(it).movement = '0 0 0';
 413                                         PutClientInServer(it);
 414                                 });
 415                         }
 416                 }
 417         }
 418 }
 419
 420 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 421 void ReadyRestart_think(entity this)
 422 {
 423         restart_mapalreadyrestarted = true;
 424         reset_map(true);
 425         Score_ClearAll();
 426         delete(this);
 427 }
 428
 429 // Forces a restart of the game without actually reloading the map // this is a mess...
 430 void ReadyRestart_force()
 431 {
 432         if (time <= game_starttime && game_stopped)
 433                 return;
 434
 435         bprint("^1Server is restarting...\n");
 436
 437         VoteReset();
 438
 439         // clear overtime, we have to decrease timelimit to its original value again.
 440         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 441                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 442         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 443
 444         readyrestart_happened = true;
 445         game_starttime = time + RESTART_COUNTDOWN;
 446
 447         // clear player attributes
 448         FOREACH_CLIENT(IS_PLAYER(it), {
 449                 it.alivetime = 0;
 450                 CS(it).killcount = 0;
 451                 float val = PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, 0);
 452                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, -val);
 453         });
 454
 455         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 456
 457         // disable the warmup global for the server
 458         if(warmup_stage)
 459                 localcmd("\nsv_hook_warmupend\n");
 460         warmup_stage = 0;                // once the game is restarted the game is in match stage
 461
 462         // reset the .ready status of all players (also spectators)
 463         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 464         readycount = 0;
 465         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 466
 467         // lock teams with lockonrestart
 468         if (autocvar_teamplay_lockonrestart && teamplay)
 469         {
 470                 lockteams = true;
 471                 bprint("^1The teams are now locked.\n");
 472         }
 473
 474         // initiate the restart-countdown-announcer entity
 475         if (sv_ready_restart_after_countdown)
 476         {
 477                 entity restart_timer = new_pure(restart_timer);
 478                 setthink(restart_timer, ReadyRestart_think);
 479                 restart_timer.nextthink = game_starttime;
 480         }
 481
 482         // after a restart every players number of allowed timeouts gets reset, too
 483         if (autocvar_sv_timeout)
 484         {
 485                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 486         }
 487
 488         if (!sv_ready_restart_after_countdown) reset_map(true);
 489         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 490 }
 491
 492 void ReadyRestart()
 493 {
 494         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
 495         else localcmd("\nsv_hook_readyrestart\n");
 496
 497         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 498         // Otherwise scores could be manipulated during the countdown.
 499         if (!sv_ready_restart_after_countdown) Score_ClearAll();
 500         ReadyRestart_force();
 501 }
 502
 503 // Count the players who are ready and determine whether or not to restart the match
 504 void ReadyCount()
 505 {
 506         float ready_needed_factor, ready_needed_count;
 507         float t_ready = 0, t_players = 0;
 508
 509         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), {
 510                 ++t_players;
 511                 if (it.ready) ++t_ready;
 512         });
 513
 514         readycount = t_ready;
 515
 516         Nagger_ReadyCounted();
 517
 518         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 519         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 520
 521         if (readycount >= ready_needed_count) ReadyRestart();
 522 }
 523
 524
 525 // ======================================
 526 //  Supporting functions for VoteCommand
 527 // ======================================
 528
 529 float Votecommand_check_assignment(entity caller, float assignment)
 530 {
 531         float from_server = (!caller);
 532
 533         if ((assignment == VC_ASGNMNT_BOTH)
 534             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 535             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 536
 537         return false;
 538 }
 539
 540 string VoteCommand_extractcommand(string input, float startpos, int argc)
 541 {
 542         string output;
 543
 544         if ((argc - 1) < startpos) output = "";
 545         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 546
 547         return output;
 548 }
 549
 550 float VoteCommand_checknasty(string vote_command)
 551 {
 552         if ((strstrofs(vote_command, ";", 0) >= 0)
 553             || (strstrofs(vote_command, "\n", 0) >= 0)
 554             || (strstrofs(vote_command, "\r", 0) >= 0)
 555             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 556
 557         return true;
 558 }
 559
 560 // NOTE: requires input to be surrounded by spaces
 561 string VoteCommand_checkreplacements(string input)
 562 {
 563         string output = input;
 564         // allow gotomap replacements
 565         output = strreplace(" map ", " gotomap ", output);
 566         output = strreplace(" chmap ", " gotomap ", output);
 567         return output;
 568 }
 569
 570 float VoteCommand_checkinlist(string vote_command, string list)
 571 {
 572         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 573
 574         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 575
 576         return false;
 577 }
 578
 579 string ValidateMap(string validated_map, entity caller)
 580 {
 581         validated_map = MapInfo_FixName(validated_map);
 582
 583         if (!validated_map)
 584         {
 585                 print_to(caller, "This map is not available on this server.");
 586                 return string_null;
 587         }
 588
 589         if (!autocvar_sv_vote_override_mostrecent && caller)
 590         {
 591                 if (Map_IsRecent(validated_map))
 592                 {
 593                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 594                         return string_null;
 595                 }
 596         }
 597
 598         if (!MapInfo_CheckMap(validated_map))
 599         {
 600                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 601                 return string_null;
 602         }
 603
 604         return validated_map;
 605 }
 606
 607 float VoteCommand_checkargs(float startpos, int argc)
 608 {
 609         float p, q, check, minargs;
 610         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 611         string cmdrestriction = "";  // No we don't.
 612         string charlist, arg;
 613         float checkmate;
 614
 615         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 616                 cmdrestriction = cvar_string(cvarname);
 617         else
 618                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 619
 620         if (cmdrestriction == "") return true;
 621
 622         ++startpos;  // skip command name
 623
 624         // check minimum arg count
 625
 626         // 0 args: argc == startpos
 627         // 1 args: argc == startpos + 1
 628         // ...
 629
 630         minargs = stof(cmdrestriction);
 631         if (argc - startpos < minargs) return false;
 632
 633         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 634
 635         for ( ; ; )
 636         {
 637                 // we know that at any time, startpos <= argc - minargs
 638                 // so this means: argc-minargs >= startpos >= argc, thus
 639                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 640                 // have been seen already
 641
 642                 if (startpos >= argc) // all args checked? GOOD
 643                         break;
 644
 645                 if (p < 0)            // no more args? FAIL
 646                 {
 647                         // exception: exactly minargs left, this one included
 648                         if (argc - startpos == minargs) break;
 649
 650                         // otherwise fail
 651                         return false;
 652                 }
 653
 654                 // cut to next semicolon
 655                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 656                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 657                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 658
 659                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 660                 // charlist = strreplace("^^", ";", charlist);
 661
 662                 if (charlist != "")
 663                 {
 664                         // verify the arg only contains allowed chars
 665                         arg = argv(startpos);
 666                         checkmate = strlen(arg);
 667                         for (check = 0; check < checkmate; ++check)
 668                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 669                         // not allowed character
 670                         // all characters are allowed. FINE.
 671                 }
 672
 673                 ++startpos;
 674                 --minargs;
 675                 p = q;
 676         }
 677
 678         return true;
 679 }
 680
 681 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 682 {
 683         string first_command = argv(startpos);
 684         int missing_chars = argv_start_index(startpos);
 685
 686         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 687                 return 0;
 688
 689         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 690
 691         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 692
 693         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 694         {
 695                 case MUT_VOTEPARSE_CONTINUE: { break; }
 696                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 697                 case MUT_VOTEPARSE_INVALID: { return -1; }
 698                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 699         }
 700
 701         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 702         {
 703                 case "kick":
 704                 case "kickban":    // catch all kick/kickban commands
 705                 {
 706                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 707                         float accepted = VerifyClientEntity(victim, true, false);
 708
 709                         if (accepted > 0)
 710                         {
 711                                 string reason = "No reason provided";
 712                                 if(argc > next_token)
 713                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 714
 715                                 string command_arguments = reason;
 716                                 if (first_command == "kickban")
 717                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 718
 719                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 720                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 721                         }
 722                         else
 723                         {
 724                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 725                                 return 0;
 726                         }
 727
 728                         break;
 729                 }
 730
 731                 case "map":
 732                 case "chmap":
 733                 case "gotomap":  // re-direct all map selection commands to gotomap
 734                 {
 735                         vote_command = ValidateMap(argv(startpos + 1), caller);
 736                         if (!vote_command)  return -1;
 737                         vote_parsed_command = strcat("gotomap ", vote_command);
 738                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 739
 740                         break;
 741                 }
 742
 743                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 744                 // maybe fallback instead of aborting if map name is invalid?
 745                 case "nextmap":
 746                 {
 747                         vote_command = ValidateMap(argv(startpos + 1), caller);
 748                         if (!vote_command)  return -1;
 749                         vote_parsed_command = strcat("nextmap ", vote_command);
 750                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 751
 752                         break;
 753                 }
 754
 755                 case "timelimit": // include restrictions on the maximum votable time limit
 756                 {
 757                         float timelimit_vote = stof(argv(startpos + 1));
 758                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 759                         {
 760                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 761                                 return -1;
 762                         }
 763                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 764                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 765                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 766
 767                         break;
 768                 }
 769
 770                 case "restart":
 771                 {
 772                         // add a delay so that vote result can be seen and announcer can be heard
 773                         // if the vote is accepted
 774                         vote_parsed_command = strcat("defer 1 ", vote_command);
 775                         vote_parsed_display = strzone(strcat("^1", vote_command));
 776
 777                         break;
 778                 }
 779
 780                 default:
 781                 {
 782                         vote_parsed_command = vote_command;
 783                         vote_parsed_display = strzone(strcat("^1", vote_command));
 784
 785                         break;
 786                 }
 787         }
 788
 789         return 1;
 790 }
 791
 792
 793 // =======================
 794 //  Command Sub-Functions
 795 // =======================
 796
 797 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 798 {
 799         switch (request)
 800         {
 801                 case CMD_REQUEST_COMMAND:
 802                 {
 803                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 804                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 805                         {
 806                                 print_to(caller, "^1You have already voted.");
 807                         }
 808
 809                         else  // everything went okay, continue changing vote
 810                         {
 811                                 print_to(caller, "^1You abstained from your vote.");
 812                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 813                                 msg_entity = caller;
 814                                 if (!autocvar_sv_vote_singlecount)
 815                                         VoteCount(false);
 816                         }
 817
 818                         return;
 819                 }
 820
 821                 default:
 822                 case CMD_REQUEST_USAGE:
 823                 {
 824                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 825                         print_to(caller, "  No arguments required.");
 826                         return;
 827                 }
 828         }
 829 }
 830
 831 void print_available_commands_to(entity caller)
 832 {
 833         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 834 }
 835
 836 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 837 {
 838         switch (request)
 839         {
 840                 case CMD_REQUEST_COMMAND:
 841                 {
 842                         float tmp_playercount = 0;
 843                         int parse_error;
 844
 845                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 846
 847                         if (!autocvar_sv_vote_call && caller)
 848                         {
 849                                 print_to(caller, "^1Vote calling is not allowed.");
 850                         }
 851                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 852                         {
 853                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 854                         }
 855                         else if (vote_called)
 856                         {
 857                                 print_to(caller, "^1There is already a vote called.");
 858                         }
 859                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 860                         {
 861                                 print_to(caller, "^1Only players can call a vote.");
 862                         }
 863                         else if (caller && !IS_CLIENT(caller))
 864                         {
 865                                 print_to(caller, "^1Only connected clients can vote.");
 866                         }
 867                         else if (timeout_status && vote_command != "timein")
 868                         {
 869                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 870                         }
 871                         else if (caller && (time < caller.vote_waittime))
 872                         {
 873                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 874                         }
 875                         else if (!VoteCommand_checknasty(vote_command))
 876                         {
 877                                 print_to(caller, "^1Syntax error in command.");
 878                         }
 879                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 880                         {
 881                                 if(parse_error == 0)
 882                                 {
 883                                         if (vote_called_command == "")
 884                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 885                                         else
 886                                                 print_to(caller, "^1This command is not acceptable or not available.");
 887                                 }
 888                         }
 889                         else  // everything went okay, continue with calling the vote
 890                         {
 891                                 vote_caller = caller;  // remember who called the vote
 892                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 893                                 vote_called = VOTE_NORMAL;
 894                                 vote_called_command = strzone(vote_parsed_command);
 895                                 vote_called_display = strzone(vote_parsed_display);
 896                                 vote_endtime = time + autocvar_sv_vote_timeout;
 897
 898                                 if (caller)
 899                                 {
 900                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 901                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 902                                         msg_entity = caller;
 903                                 }
 904
 905                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 906
 907                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 908                                 if (autocvar_sv_eventlog)
 909                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 910                                 Nagger_VoteChanged();
 911                                 VoteCount(true);  // needed if you are the only one
 912
 913                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 914                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 915                         }
 916
 917                         return;
 918                 }
 919
 920                 default:
 921                 case CMD_REQUEST_USAGE:
 922                 {
 923                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 924                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 925                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 926                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 927                         print_available_commands_to(caller);
 928                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
 929                         return;
 930                 }
 931         }
 932 }
 933
 934 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 935 {
 936         switch (request)
 937         {
 938                 case CMD_REQUEST_COMMAND:
 939                 {
 940                         if (autocvar_sv_vote_master)
 941                         {
 942                                 switch (strtolower(argv(2)))
 943                                 {
 944                                         case "do":
 945                                         {
 946                                                 int parse_error;
 947                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 948
 949                                                 if (!caller.vote_master)
 950                                                         print_to(caller, "^1You do not have vote master privileges.");
 951                                                 else if (!VoteCommand_checknasty(vote_command))
 952                                                 {
 953                                                         print_to(caller, "^1Syntax error in command.");
 954                                                 }
 955                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 956                                                 {
 957                                                         if(parse_error == 0)
 958                                                         {
 959                                                                 if (vote_called_command == "")
 960                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
 961                                                                 else
 962                                                                         print_to(caller, "^1This command is not acceptable or not available.");
 963                                                         }
 964                                                 }
 965                                                 else  // everything went okay, proceed with command
 966                                                 {
 967                                                         localcmd(strcat(vote_parsed_command, "\n"));
 968                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 969                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 970                                                         if (autocvar_sv_eventlog)
 971                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 972                                                 }
 973
 974                                                 return;
 975                                         }
 976
 977                                         case "login":
 978                                         {
 979                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 980                                                 else if (caller.vote_master)
 981                                                 {
 982                                                         print_to(caller, "^1You are already logged in as vote master.");
 983                                                 }
 984                                                 else if (autocvar_sv_vote_master_password != argv(3))
 985                                                 {
 986                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 987                                                 }
 988                                                 else  // everything went okay, proceed with giving this player master privilages
 989                                                 {
 990                                                         caller.vote_master = true;
 991                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 992                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 993                                                         if (autocvar_sv_eventlog)
 994                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
 995                                                 }
 996
 997                                                 return;
 998                                         }
 999
1000                                         default:  // calling a vote for master
1001                                         {
1002                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1003                                                 else if (vote_called)
1004                                                 {
1005                                                         print_to(caller, "^1There is already a vote called.");
1006                                                 }
1007                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1008                                                 {
1009                                                         print_to(caller, "^1Only players can call a vote.");
1010                                                 }
1011                                                 else if (timeout_status)
1012                                                 {
1013                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1014                                                 }
1015                                                 else  // everything went okay, continue with creating vote
1016                                                 {
1017                                                         vote_caller = caller;
1018                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1019                                                         vote_called = VOTE_MASTER;
1020                                                         vote_called_command = strzone("XXX");
1021                                                         vote_called_display = strzone("^3master");
1022                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1023
1024                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1025                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1026
1027                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1028                                                         if (autocvar_sv_eventlog)
1029                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1030                                                         Nagger_VoteChanged();
1031                                                         VoteCount(true);  // needed if you are the only one
1032                                                 }
1033
1034                                                 return;
1035                                         }
1036                                 }
1037                         }
1038                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1039
1040                         return;
1041                 }
1042
1043                 default:
1044                 case CMD_REQUEST_USAGE:
1045                 {
1046                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1047                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1048                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1049                         return;
1050                 }
1051         }
1052 }
1053
1054 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1055 {
1056         switch (request)
1057         {
1058                 case CMD_REQUEST_COMMAND:
1059                 {
1060                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1061                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1062                         {
1063                                 print_to(caller, "^1You have already voted.");
1064                         }
1065                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1066                         {
1067                                 VoteStop(caller);
1068                         }
1069
1070                         else  // everything went okay, continue changing vote
1071                         {
1072                                 print_to(caller, "^1You rejected the vote.");
1073                                 caller.vote_selection = VOTE_SELECT_REJECT;
1074                                 msg_entity = caller;
1075                                 if (!autocvar_sv_vote_singlecount)
1076                                         VoteCount(false);
1077                         }
1078
1079                         return;
1080                 }
1081
1082                 default:
1083                 case CMD_REQUEST_USAGE:
1084                 {
1085                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1086                         print_to(caller, "  No arguments required.");
1087                         return;
1088                 }
1089         }
1090 }
1091
1092 void VoteCommand_status(int request, entity caller)  // BOTH
1093 {
1094         switch (request)
1095         {
1096                 case CMD_REQUEST_COMMAND:
1097                 {
1098                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1099                         else print_to(caller, "^1No vote called.");
1100
1101                         return;
1102                 }
1103
1104                 default:
1105                 case CMD_REQUEST_USAGE:
1106                 {
1107                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1108                         print_to(caller, "  No arguments required.");
1109                         return;
1110                 }
1111         }
1112 }
1113
1114 void VoteCommand_stop(int request, entity caller)  // BOTH
1115 {
1116         switch (request)
1117         {
1118                 case CMD_REQUEST_COMMAND:
1119                 {
1120                         if (!vote_called)   print_to(caller, "^1No vote called.");
1121                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1122                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1123                         return;
1124                 }
1125
1126                 default:
1127                 case CMD_REQUEST_USAGE:
1128                 {
1129                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1130                         print_to(caller, "  No arguments required.");
1131                         return;
1132                 }
1133         }
1134 }
1135
1136 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1137 {
1138         switch (request)
1139         {
1140                 case CMD_REQUEST_COMMAND:
1141                 {
1142                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1143                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1144                         {
1145                                 print_to(caller, "^1You have already voted.");
1146                         }
1147                         else  // everything went okay, continue changing vote
1148                         {
1149                                 print_to(caller, "^1You accepted the vote.");
1150                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1151                                 msg_entity = caller;
1152                                 if (!autocvar_sv_vote_singlecount)
1153                                         VoteCount(false);
1154                         }
1155
1156                         return;
1157                 }
1158
1159                 default:
1160                 case CMD_REQUEST_USAGE:
1161                 {
1162                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1163                         print_to(caller, "  No arguments required.");
1164                         return;
1165                 }
1166         }
1167 }
1168
1169 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1170 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1171 void VoteCommand_(int request)
1172 {
1173     switch(request)
1174     {
1175         case CMD_REQUEST_COMMAND:
1176         {
1177
1178             return;
1179         }
1180
1181         default:
1182         case CMD_REQUEST_USAGE:
1183         {
1184             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1185             print_to(caller, "  No arguments required.");
1186             return;
1187         }
1188     }
1189 }
1190 */
1191
1192
1193 // ================================
1194 //  Macro system for vote commands
1195 // ================================
1196
1197 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1198 #define VOTE_COMMANDS(request, caller, arguments, command) \
1199         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1200         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1201         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1202         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1203         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1204         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1205         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1206         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1207         /* nothing */
1208
1209 void VoteCommand_macro_help(entity caller, int argc)
1210 {
1211         string command_origin = GetCommandPrefix(caller);
1212
1213         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1214         {
1215                 print_to(caller, "\nVoting commands:\n");
1216                 #define VOTE_COMMAND(name, function, description, assignment) \
1217                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1218
1219                 VOTE_COMMANDS(0, caller, 0, "");
1220                 #undef VOTE_COMMAND
1221
1222                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1223                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1224                 print_available_commands_to(caller);
1225         }
1226         else  // usage for individual command
1227         {
1228                 #define VOTE_COMMAND(name, function, description, assignment) \
1229                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1230
1231                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1232                 #undef VOTE_COMMAND
1233
1234                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1235                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1236                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1237                 else if (argv(2) != "")
1238                         print_to(caller, "No documentation exists for this vote");
1239         }
1240 }
1241
1242 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1243 {
1244         #define VOTE_COMMAND(name, function, description, assignment) \
1245                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1246
1247         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1248         #undef VOTE_COMMAND
1249
1250         return false;
1251 }
1252
1253
1254 // ======================================
1255 //  Main function handling vote commands
1256 // ======================================
1257
1258 void VoteCommand(int request, entity caller, int argc, string vote_command)
1259 {
1260         // Guide for working with argc arguments by example:
1261         // argc:   1    - 2      - 3     - 4
1262         // argv:   0    - 1      - 2     - 3
1263         // cmd     vote - master - login - password
1264
1265         switch (request)
1266         {
1267                 case CMD_REQUEST_COMMAND:
1268                 {
1269                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1270                 }
1271
1272                 default:
1273                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1274                 case CMD_REQUEST_USAGE:
1275                 {
1276                         VoteCommand_macro_help(caller, argc);
1277                         return;
1278                 }
1279         }
1280 }