qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5
   6 #include <common/command/_mod.qh>
   7 #include "vote.qh"
   8
   9 #include "common.qh"
  10
  11 #include "../g_damage.qh"
  12 #include "../g_world.qh"
  13 #include "../race.qh"
  14 #include "../round_handler.qh"
  15 #include "../scores.qh"
  16
  17 #include "../mutators/_mod.qh"
  18
  19 #include <common/constants.qh>
  20 #include <common/net_linked.qh>
  21 #include <common/mapinfo.qh>
  22 #include <common/notifications/all.qh>
  23 #include <common/playerstats.qh>
  24 #include <common/util.qh>
  25
  26 // =============================================
  27 //  Server side voting code, reworked by Samual
  28 //  Last updated: December 27th, 2011
  29 // =============================================
  30
  31 //  Nagger for players to know status of voting
  32 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  33 {
  34         int nags, i, f, b;
  35         entity e;
  36         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  37
  38         // bits:
  39         //   1 = ready
  40         //   2 = player needs to ready up
  41         //   4 = vote
  42         //   8 = player needs to vote
  43         //  16 = warmup
  44         // sendflags:
  45         //  64 = vote counts
  46         // 128 = vote string
  47
  48         nags = 0;
  49         if (readycount)
  50         {
  51                 nags |= BIT(0);
  52                 if (to.ready == 0) nags |= BIT(1);
  53         }
  54         if (vote_called)
  55         {
  56                 nags |= BIT(2);
  57                 if (to.vote_selection == 0) nags |= BIT(3);
  58         }
  59         if (warmup_stage) nags |= BIT(4);
  60
  61         if (sendflags & BIT(6)) nags |= BIT(6);
  62
  63         if (sendflags & BIT(7)) nags |= BIT(7);
  64
  65         if (!(nags & 4))  // no vote called? send no string
  66                 nags &= ~(BIT(6) | BIT(7));
  67
  68         WriteByte(MSG_ENTITY, nags);
  69
  70         if (nags & BIT(6))
  71         {
  72                 WriteByte(MSG_ENTITY, vote_accept_count);
  73                 WriteByte(MSG_ENTITY, vote_reject_count);
  74                 WriteByte(MSG_ENTITY, vote_needed_overall);
  75                 WriteChar(MSG_ENTITY, to.vote_selection);
  76         }
  77
  78         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  79
  80         if (nags & 1)
  81         {
  82                 for (i = 1; i <= maxclients; i += 8)
  83                 {
  84                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  85                                 if (!IS_REAL_CLIENT(e) || e.ready)
  86                                         f |= b;
  87                         WriteByte(MSG_ENTITY, f);
  88                 }
  89         }
  90
  91         return true;
  92 }
  93
  94 void Nagger_Init()
  95 {
  96         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  97 }
  98
  99 void Nagger_VoteChanged()
 100 {
 101         if (nagger) nagger.SendFlags |= BIT(7);
 102 }
 103
 104 void Nagger_VoteCountChanged()
 105 {
 106         if (nagger) nagger.SendFlags |= BIT(6);
 107 }
 108
 109 void Nagger_ReadyCounted()
 110 {
 111         if (nagger) nagger.SendFlags |= BIT(0);
 112 }
 113
 114 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 115 string OriginalCallerName()
 116 {
 117         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller, false);
 118         return vote_caller_name;
 119 }
 120
 121 // =======================
 122 //  Game logic for voting
 123 // =======================
 124
 125 void VoteReset()
 126 {
 127         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 128
 129         if (vote_called)
 130         {
 131                 strunzone(vote_called_command);
 132                 strunzone(vote_called_display);
 133                 strunzone(vote_caller_name);
 134         }
 135
 136         vote_called = VOTE_NULL;
 137         vote_caller = NULL;
 138         vote_caller_name = string_null;
 139         vote_endtime = 0;
 140
 141         vote_called_command = string_null;
 142         vote_called_display = string_null;
 143
 144         vote_parsed_command = string_null;
 145         vote_parsed_display = string_null;
 146
 147         Nagger_VoteChanged();
 148 }
 149
 150 void VoteStop(entity stopper)
 151 {
 152         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 153         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 154         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 155         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 156         VoteReset();
 157 }
 158
 159 void VoteAccept()
 160 {
 161         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 162
 163         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 164         else localcmd(strcat(vote_called_command, "\n"));
 165
 166         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 167
 168         VoteReset();
 169         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 170 }
 171
 172 void VoteReject()
 173 {
 174         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 175         VoteReset();
 176         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 177 }
 178
 179 void VoteTimeout()
 180 {
 181         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 182         VoteReset();
 183         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 184 }
 185
 186 void VoteSpam(float notvoters, float mincount, string result)
 187 {
 188         bprint(strcat(
 189                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 190                 strcat("^2:^1", ftos(vote_reject_count)),
 191                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 192                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 193                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 194
 195         if (autocvar_sv_eventlog)
 196         {
 197                 GameLogEcho(strcat(
 198                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 199                         strcat(":", ftos(vote_reject_count)),
 200                         strcat(":", ftos(vote_abstain_count)),
 201                         strcat(":", ftos(notvoters)),
 202                         strcat(":", ftos(mincount))));
 203         }
 204 }
 205
 206 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 207
 208 void VoteCount(float first_count)
 209 {
 210         // declarations
 211         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 212
 213         float vote_player_count = 0, notvoters = 0;
 214         float vote_real_player_count = 0, vote_real_accept_count = 0;
 215         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 216         float vote_needed_of_voted, final_needed_votes;
 217         float vote_factor_overall, vote_factor_of_voted;
 218
 219         Nagger_VoteCountChanged();
 220
 221         // add up all the votes from each connected client
 222         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 223                 ++vote_player_count;
 224                 if (IS_PLAYER(it))   ++vote_real_player_count;
 225                 switch (it.vote_selection)
 226                 {
 227                         case VOTE_SELECT_REJECT:
 228                         { ++vote_reject_count;
 229                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 230                         }
 231                         case VOTE_SELECT_ACCEPT:
 232                         { ++vote_accept_count;
 233                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 234                         }
 235                         case VOTE_SELECT_ABSTAIN:
 236                         { ++vote_abstain_count;
 237                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 238                         }
 239                         default: break;
 240                 }
 241         });
 242
 243         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 244         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 245         {
 246                 if (vote_caller)   vote_caller.vote_waittime = 0;
 247                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 248                 VoteReset();
 249                 return;
 250         }
 251
 252         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 253         if (!spectators_allowed && (vote_real_player_count > 0))
 254         {
 255                 vote_accept_count = vote_real_accept_count;
 256                 vote_reject_count = vote_real_reject_count;
 257                 vote_abstain_count = vote_real_abstain_count;
 258                 vote_player_count = vote_real_player_count;
 259         }
 260
 261         // people who have no opinion in any way :D
 262         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 263
 264         // determine the goal for the vote to be passed or rejected normally
 265         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 266         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 267
 268         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 269         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 270         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 271
 272         // are there any players at all on the server? it could be an admin vote
 273         if (vote_player_count == 0 && first_count)
 274         {
 275                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 276                 VoteAccept();
 277                 return;
 278         }
 279
 280         // since there ARE players, finally calculate the result of the vote
 281         if (vote_accept_count >= vote_needed_overall)
 282         {
 283                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 284                 VoteAccept();
 285                 return;
 286         }
 287
 288         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 289         {
 290                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 291                 VoteReject();
 292                 return;
 293         }
 294
 295         // there is not enough votes in either direction, now lets just calculate what the voters have said
 296         if (time > vote_endtime)
 297         {
 298                 final_needed_votes = vote_needed_overall;
 299
 300                 if (autocvar_sv_vote_majority_factor_of_voted)
 301                 {
 302                         if (vote_accept_count >= vote_needed_of_voted)
 303                         {
 304                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 305                                 VoteAccept();
 306                                 return;
 307                         }
 308
 309                         if (vote_accept_count + vote_reject_count > 0)
 310                         {
 311                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 312                                 VoteReject();
 313                                 return;
 314                         }
 315
 316                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 317                 }
 318
 319                 // it didn't pass or fail, so not enough votes to even make a decision.
 320                 VoteSpam(notvoters, final_needed_votes, "timeout");
 321                 VoteTimeout();
 322         }
 323 }
 324
 325 void VoteThink()
 326 {
 327         if (vote_endtime > 0)        // a vote was called
 328         {
 329                 if (time > vote_endtime) // time is up
 330                         VoteCount(false);
 331         }
 332 }
 333
 334
 335 // =======================
 336 //  Game logic for warmup
 337 // =======================
 338
 339 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 340 void reset_map(bool dorespawn)
 341 {
 342         if (time <= game_starttime)
 343         {
 344                 if (game_stopped)
 345                         return;
 346                 if (round_handler_IsActive())
 347                         round_handler_Reset(game_starttime);
 348         }
 349
 350         MUTATOR_CALLHOOK(reset_map_global);
 351
 352         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 353         {
 354                 if(IS_CLIENT(it))
 355                         continue;
 356                 if (it.reset)
 357                 {
 358                         it.reset(it);
 359                         continue;
 360                 }
 361                 if (it.team_saved) it.team = it.team_saved;
 362                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 363         });
 364
 365         // Waypoints and assault start come LAST
 366         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 367                 if (it.reset2) it.reset2(it);
 368         });
 369
 370         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), { Unfreeze(it); });
 371
 372         // Moving the player reset code here since the player-reset depends
 373         // on spawnpoint entities which have to be reset first --blub
 374         if (dorespawn)
 375         {
 376                 if (!MUTATOR_CALLHOOK(reset_map_players))
 377                 {
 378                         if (restart_mapalreadyrestarted || (time < game_starttime))
 379                         {
 380                                 FOREACH_CLIENT(IS_PLAYER(it),
 381                                 {
 382                                         /*
 383                                         only reset players if a restart countdown is active
 384                                         this can either be due to cvar sv_ready_restart_after_countdown having set
 385                                         restart_mapalreadyrestarted to 1 after the countdown ended or when
 386                                         sv_ready_restart_after_countdown is not used and countdown is still running
 387                                         */
 388                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 389                                         // PlayerScore_Clear(it);
 390                                         CS(it).killcount = 0;
 391                                         // stop the player from moving so that he stands still once he gets respawned
 392                                         it.velocity = '0 0 0';
 393                                         it.avelocity = '0 0 0';
 394                                         CS(it).movement = '0 0 0';
 395                                         PutClientInServer(it);
 396                                 });
 397                         }
 398                 }
 399         }
 400 }
 401
 402 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 403 void ReadyRestart_think(entity this)
 404 {
 405         restart_mapalreadyrestarted = true;
 406         reset_map(true);
 407         Score_ClearAll();
 408         delete(this);
 409 }
 410
 411 // Forces a restart of the game without actually reloading the map // this is a mess...
 412 void ReadyRestart_force()
 413 {
 414         if (time <= game_starttime && game_stopped)
 415                 return;
 416
 417         bprint("^1Server is restarting...\n");
 418
 419         VoteReset();
 420
 421         // clear overtime, we have to decrease timelimit to its original value again.
 422         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 423                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 424         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 425
 426         readyrestart_happened = true;
 427         game_starttime = time + RESTART_COUNTDOWN;
 428
 429         // clear player attributes
 430         FOREACH_CLIENT(IS_PLAYER(it), {
 431                 it.alivetime = 0;
 432                 CS(it).killcount = 0;
 433                 PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(it, PLAYERSTATS_ALIVETIME, 0));
 434         });
 435
 436         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 437
 438         // disable the warmup global for the server
 439         warmup_stage = 0;                // once the game is restarted the game is in match stage
 440
 441         // reset the .ready status of all players (also spectators)
 442         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 443         readycount = 0;
 444         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 445
 446         // lock teams with lockonrestart
 447         if (autocvar_teamplay_lockonrestart && teamplay)
 448         {
 449                 lockteams = true;
 450                 bprint("^1The teams are now locked.\n");
 451         }
 452
 453         // initiate the restart-countdown-announcer entity
 454         if (autocvar_sv_ready_restart_after_countdown)
 455         {
 456                 entity restart_timer = new_pure(restart_timer);
 457                 setthink(restart_timer, ReadyRestart_think);
 458                 restart_timer.nextthink = game_starttime;
 459         }
 460
 461         // after a restart every players number of allowed timeouts gets reset, too
 462         if (autocvar_sv_timeout)
 463         {
 464                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 465         }
 466     // reset map immediately if this cvar is not set
 467     if (!autocvar_sv_ready_restart_after_countdown) reset_map(true);
 468         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 469 }
 470
 471 void ReadyRestart()
 472 {
 473         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || game_stopped || race_completing) localcmd("restart\n");
 474         else localcmd("\nsv_hook_gamerestart\n");
 475
 476         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 477         // Otherwise scores could be manipulated during the countdown.
 478         if (!autocvar_sv_ready_restart_after_countdown) Score_ClearAll();
 479         ReadyRestart_force();
 480 }
 481
 482 // Count the players who are ready and determine whether or not to restart the match
 483 void ReadyCount()
 484 {
 485         float ready_needed_factor, ready_needed_count;
 486         float t_ready = 0, t_players = 0;
 487
 488         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), {
 489                 ++t_players;
 490                 if (it.ready) ++t_ready;
 491         });
 492
 493         readycount = t_ready;
 494
 495         Nagger_ReadyCounted();
 496
 497         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 498         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 499
 500         if (readycount >= ready_needed_count) ReadyRestart();
 501 }
 502
 503
 504 // ======================================
 505 //  Supporting functions for VoteCommand
 506 // ======================================
 507
 508 float Votecommand_check_assignment(entity caller, float assignment)
 509 {
 510         float from_server = (!caller);
 511
 512         if ((assignment == VC_ASGNMNT_BOTH)
 513             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 514             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 515
 516         return false;
 517 }
 518
 519 string VoteCommand_extractcommand(string input, float startpos, float argc)
 520 {
 521         string output;
 522
 523         if ((argc - 1) < startpos) output = "";
 524         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 525
 526         return output;
 527 }
 528
 529 float VoteCommand_checknasty(string vote_command)
 530 {
 531         if ((strstrofs(vote_command, ";", 0) >= 0)
 532             || (strstrofs(vote_command, "\n", 0) >= 0)
 533             || (strstrofs(vote_command, "\r", 0) >= 0)
 534             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 535
 536         return true;
 537 }
 538
 539 float VoteCommand_checkinlist(string vote_command, string list)
 540 {
 541         string l = strcat(" ", list, " ");
 542
 543         if (strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0) return true;
 544
 545         return false;
 546 }
 547
 548 string ValidateMap(string validated_map, entity caller)
 549 {
 550         validated_map = MapInfo_FixName(validated_map);
 551
 552         if (!validated_map)
 553         {
 554                 print_to(caller, "This map is not available on this server.");
 555                 return string_null;
 556         }
 557
 558         if (!autocvar_sv_vote_override_mostrecent && caller)
 559         {
 560                 if (Map_IsRecent(validated_map))
 561                 {
 562                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 563                         return string_null;
 564                 }
 565         }
 566
 567         if (!MapInfo_CheckMap(validated_map))
 568         {
 569                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 570                 return string_null;
 571         }
 572
 573         return validated_map;
 574 }
 575
 576 float VoteCommand_checkargs(float startpos, float argc)
 577 {
 578         float p, q, check, minargs;
 579         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 580         string cmdrestriction = "";  // No we don't.
 581         string charlist, arg;
 582         float checkmate;
 583
 584         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 585                 cmdrestriction = cvar_string(cvarname);
 586         else
 587                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 588
 589         if (cmdrestriction == "") return true;
 590
 591         ++startpos;  // skip command name
 592
 593         // check minimum arg count
 594
 595         // 0 args: argc == startpos
 596         // 1 args: argc == startpos + 1
 597         // ...
 598
 599         minargs = stof(cmdrestriction);
 600         if (argc - startpos < minargs) return false;
 601
 602         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 603
 604         for ( ; ; )
 605         {
 606                 // we know that at any time, startpos <= argc - minargs
 607                 // so this means: argc-minargs >= startpos >= argc, thus
 608                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 609                 // have been seen already
 610
 611                 if (startpos >= argc) // all args checked? GOOD
 612                         break;
 613
 614                 if (p < 0)            // no more args? FAIL
 615                 {
 616                         // exception: exactly minargs left, this one included
 617                         if (argc - startpos == minargs) break;
 618
 619                         // otherwise fail
 620                         return false;
 621                 }
 622
 623                 // cut to next semicolon
 624                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 625                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 626                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 627
 628                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 629                 // charlist = strreplace("^^", ";", charlist);
 630
 631                 if (charlist != "")
 632                 {
 633                         // verify the arg only contains allowed chars
 634                         arg = argv(startpos);
 635                         checkmate = strlen(arg);
 636                         for (check = 0; check < checkmate; ++check)
 637                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 638                         // not allowed character
 639                         // all characters are allowed. FINE.
 640                 }
 641
 642                 ++startpos;
 643                 --minargs;
 644                 p = q;
 645         }
 646
 647         return true;
 648 }
 649
 650 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 651 {
 652         string first_command = argv(startpos);
 653         int missing_chars = argv_start_index(startpos);
 654
 655         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 656                 return 0;
 657
 658         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 659
 660         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 661
 662         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 663         {
 664                 case "kick":
 665                 case "kickban":    // catch all kick/kickban commands
 666                 {
 667                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 668                         float accepted = VerifyClientEntity(victim, true, false);
 669
 670                         if (accepted > 0)
 671                         {
 672                                 string reason = "No reason provided";
 673                                 if(argc > next_token)
 674                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 675
 676                                 string command_arguments = reason;
 677                                 if (first_command == "kickban")
 678                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 679
 680                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 681                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 682                         }
 683                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return 0; }
 684
 685                         break;
 686                 }
 687
 688                 case "map":
 689                 case "chmap":
 690                 case "gotomap":  // re-direct all map selection commands to gotomap
 691                 {
 692                         vote_command = ValidateMap(argv(startpos + 1), caller);
 693                         if (!vote_command)  return -1;
 694                         vote_parsed_command = strcat("gotomap ", vote_command);
 695                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 696
 697                         break;
 698                 }
 699
 700                 default:
 701                 {
 702                         vote_parsed_command = vote_command;
 703                         vote_parsed_display = strzone(strcat("^1", vote_command));
 704
 705                         break;
 706                 }
 707         }
 708
 709         return 1;
 710 }
 711
 712
 713 // =======================
 714 //  Command Sub-Functions
 715 // =======================
 716
 717 void VoteCommand_abstain(float request, entity caller)  // CLIENT ONLY
 718 {
 719         switch (request)
 720         {
 721                 case CMD_REQUEST_COMMAND:
 722                 {
 723                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 724                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 725                         {
 726                                 print_to(caller, "^1You have already voted.");
 727                         }
 728
 729                         else  // everything went okay, continue changing vote
 730                         {
 731                                 print_to(caller, "^1You abstained from your vote.");
 732                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 733                                 msg_entity = caller;
 734                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 735
 736                         return;
 737                 }
 738
 739                 default:
 740                 case CMD_REQUEST_USAGE:
 741                 {
 742                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 743                         print_to(caller, "  No arguments required.");
 744                         return;
 745                 }
 746         }
 747 }
 748
 749 void VoteCommand_call(float request, entity caller, float argc, string vote_command)  // BOTH
 750 {
 751         switch (request)
 752         {
 753                 case CMD_REQUEST_COMMAND:
 754                 {
 755                         float tmp_playercount = 0;
 756                         int parse_error;
 757
 758                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 759
 760                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 761                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 762                         {
 763                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 764                         }
 765                         else if (vote_called)
 766                         {
 767                                 print_to(caller, "^1There is already a vote called.");
 768                         }
 769                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 770                         {
 771                                 print_to(caller, "^1Only players can call a vote.");
 772                         }
 773                         else if (caller && !IS_CLIENT(caller))
 774                         {
 775                                 print_to(caller, "^1Only connected clients can vote.");
 776                         }
 777                         else if (timeout_status)
 778                         {
 779                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 780                         }
 781                         else if (caller && (time < caller.vote_waittime))
 782                         {
 783                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 784                         }
 785                         else if (!VoteCommand_checknasty(vote_command))
 786                         {
 787                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 788                         }
 789                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 790                         {
 791                                 if(parse_error == 0)
 792                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 793                         }
 794
 795                         else  // everything went okay, continue with calling the vote
 796                         {
 797                                 vote_caller = caller;  // remember who called the vote
 798                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 799                                 vote_called = VOTE_NORMAL;
 800                                 vote_called_command = strzone(vote_parsed_command);
 801                                 vote_called_display = strzone(vote_parsed_display);
 802                                 vote_endtime = time + autocvar_sv_vote_timeout;
 803
 804                                 if (caller)
 805                                 {
 806                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 807                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 808                                         msg_entity = caller;
 809                                 }
 810
 811                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 812                                 if (tmp_playercount > 1)
 813                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 814
 815                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 816                                 if (autocvar_sv_eventlog)
 817                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 818                                 Nagger_VoteChanged();
 819                                 VoteCount(true);  // needed if you are the only one
 820                         }
 821
 822                         return;
 823                 }
 824
 825                 default:
 826                 case CMD_REQUEST_USAGE:
 827                 {
 828                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 829                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 830                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 831                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 832                         return;
 833                 }
 834         }
 835 }
 836
 837 void VoteCommand_master(float request, entity caller, float argc, string vote_command)  // CLIENT ONLY
 838 {
 839         switch (request)
 840         {
 841                 case CMD_REQUEST_COMMAND:
 842                 {
 843                         if (autocvar_sv_vote_master)
 844                         {
 845                                 switch (strtolower(argv(2)))
 846                                 {
 847                                         case "do":
 848                                         {
 849                                                 int parse_error;
 850                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 851
 852                                                 if (!caller.vote_master)
 853                                                         print_to(caller, "^1You do not have vote master privileges.");
 854                                                 else if (!VoteCommand_checknasty(vote_command))
 855                                                 {
 856                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 857                                                 }
 858                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 859                                                 {
 860                                                         if(parse_error == 0)
 861                                                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 862                                                 }
 863
 864                                                 else  // everything went okay, proceed with command
 865                                                 {
 866                                                         localcmd(strcat(vote_parsed_command, "\n"));
 867                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 868                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 869                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 870
 871                                                 return;
 872                                         }
 873
 874                                         case "login":
 875                                         {
 876                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 877                                                 else if (caller.vote_master)
 878                                                 {
 879                                                         print_to(caller, "^1You are already logged in as vote master.");
 880                                                 }
 881                                                 else if (autocvar_sv_vote_master_password != argv(3))
 882                                                 {
 883                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 884                                                 }
 885
 886                                                 else  // everything went okay, proceed with giving this player master privilages
 887                                                 {
 888                                                         caller.vote_master = true;
 889                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 890                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 891                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 892
 893                                                 return;
 894                                         }
 895
 896                                         default:  // calling a vote for master
 897                                         {
 898                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 899                                                 else if (vote_called)
 900                                                 {
 901                                                         print_to(caller, "^1There is already a vote called.");
 902                                                 }
 903                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 904                                                 {
 905                                                         print_to(caller, "^1Only players can call a vote.");
 906                                                 }
 907                                                 else if (timeout_status)
 908                                                 {
 909                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 910                                                 }
 911
 912                                                 else  // everything went okay, continue with creating vote
 913                                                 {
 914                                                         vote_caller = caller;
 915                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 916                                                         vote_called = VOTE_MASTER;
 917                                                         vote_called_command = strzone("XXX");
 918                                                         vote_called_display = strzone("^3master");
 919                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 920
 921                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 922                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 923
 924                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 925                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 926                                                         Nagger_VoteChanged();
 927                                                         VoteCount(true);  // needed if you are the only one
 928                                                 }
 929
 930                                                 return;
 931                                         }
 932                                 }
 933                         }
 934                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 935
 936                         return;
 937                 }
 938
 939                 default:
 940                 case CMD_REQUEST_USAGE:
 941                 {
 942                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 943                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 944                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 945                         return;
 946                 }
 947         }
 948 }
 949
 950 void VoteCommand_no(float request, entity caller)  // CLIENT ONLY
 951 {
 952         switch (request)
 953         {
 954                 case CMD_REQUEST_COMMAND:
 955                 {
 956                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 957                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 958                         {
 959                                 print_to(caller, "^1You have already voted.");
 960                         }
 961                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
 962                         {
 963                                 VoteStop(caller);
 964                         }
 965
 966                         else  // everything went okay, continue changing vote
 967                         {
 968                                 print_to(caller, "^1You rejected the vote.");
 969                                 caller.vote_selection = VOTE_SELECT_REJECT;
 970                                 msg_entity = caller;
 971                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 972
 973                         return;
 974                 }
 975
 976                 default:
 977                 case CMD_REQUEST_USAGE:
 978                 {
 979                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
 980                         print_to(caller, "  No arguments required.");
 981                         return;
 982                 }
 983         }
 984 }
 985
 986 void VoteCommand_status(float request, entity caller)  // BOTH
 987 {
 988         switch (request)
 989         {
 990                 case CMD_REQUEST_COMMAND:
 991                 {
 992                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
 993                         else print_to(caller, "^1No vote called.");
 994
 995                         return;
 996                 }
 997
 998                 default:
 999                 case CMD_REQUEST_USAGE:
1000                 {
1001                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1002                         print_to(caller, "  No arguments required.");
1003                         return;
1004                 }
1005         }
1006 }
1007
1008 void VoteCommand_stop(float request, entity caller)  // BOTH
1009 {
1010         switch (request)
1011         {
1012                 case CMD_REQUEST_COMMAND:
1013                 {
1014                         if (!vote_called)   print_to(caller, "^1No vote called.");
1015                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1016                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1017                         return;
1018                 }
1019
1020                 default:
1021                 case CMD_REQUEST_USAGE:
1022                 {
1023                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1024                         print_to(caller, "  No arguments required.");
1025                         return;
1026                 }
1027         }
1028 }
1029
1030 void VoteCommand_yes(float request, entity caller)  // CLIENT ONLY
1031 {
1032         switch (request)
1033         {
1034                 case CMD_REQUEST_COMMAND:
1035                 {
1036                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1037                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1038                         {
1039                                 print_to(caller, "^1You have already voted.");
1040                         }
1041
1042                         else  // everything went okay, continue changing vote
1043                         {
1044                                 print_to(caller, "^1You accepted the vote.");
1045                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1046                                 msg_entity = caller;
1047                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1048
1049                         return;
1050                 }
1051
1052                 default:
1053                 case CMD_REQUEST_USAGE:
1054                 {
1055                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1056                         print_to(caller, "  No arguments required.");
1057                         return;
1058                 }
1059         }
1060 }
1061
1062 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1063 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1064 void VoteCommand_(float request)
1065 {
1066     switch(request)
1067     {
1068         case CMD_REQUEST_COMMAND:
1069         {
1070
1071             return;
1072         }
1073
1074         default:
1075         case CMD_REQUEST_USAGE:
1076         {
1077             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1078             print_to(caller, "  No arguments required.");
1079             return;
1080         }
1081     }
1082 }
1083 */
1084
1085
1086 // ================================
1087 //  Macro system for vote commands
1088 // ================================
1089
1090 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1091 #define VOTE_COMMANDS(request, caller, arguments, command) \
1092         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1093         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1094         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1095         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1096         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1097         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1098         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1099         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1100         /* nothing */
1101
1102 void VoteCommand_macro_help(entity caller, float argc)
1103 {
1104         string command_origin = GetCommandPrefix(caller);
1105
1106         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1107         {
1108                 print_to(caller, "\nVoting commands:\n");
1109                 #define VOTE_COMMAND(name, function, description, assignment) \
1110                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1111
1112                 VOTE_COMMANDS(0, caller, 0, "");
1113 #undef VOTE_COMMAND
1114
1115                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1116                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1117                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1118         }
1119         else  // usage for individual command
1120         {
1121                 #define VOTE_COMMAND(name, function, description, assignment) \
1122                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1123
1124                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1125 #undef VOTE_COMMAND
1126         }
1127 }
1128
1129 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1130 {
1131         #define VOTE_COMMAND(name, function, description, assignment) \
1132                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1133
1134         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1135 #undef VOTE_COMMAND
1136
1137         return false;
1138 }
1139
1140
1141 // ======================================
1142 //  Main function handling vote commands
1143 // ======================================
1144
1145 void VoteCommand(float request, entity caller, float argc, string vote_command)
1146 {
1147         // Guide for working with argc arguments by example:
1148         // argc:   1    - 2      - 3     - 4
1149         // argv:   0    - 1      - 2     - 3
1150         // cmd     vote - master - login - password
1151
1152         switch (request)
1153         {
1154                 case CMD_REQUEST_COMMAND:
1155                 {
1156                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1157                 }
1158
1159                 default:
1160                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1161                 case CMD_REQUEST_USAGE:
1162                 {
1163                         VoteCommand_macro_help(caller, argc);
1164                         return;
1165                 }
1166         }
1167 }