qcsrc/server/g_violence.qc

   1 float Violence_GibSplash_SendEntity(entity to, float sf)
   2 {
   3         WriteByte(MSG_ENTITY, ENT_CLIENT_GIBSPLASH);
   4         WriteByte(MSG_ENTITY, self.state); // actually type
   5         WriteByte(MSG_ENTITY, bound(1, self.cnt * 16, 255)); // gibbage amount multiplier
   6         WriteByte(MSG_ENTITY, self.team); // player num
   7         WriteShort(MSG_ENTITY, floor(self.origin_x / 4)); // not using a coord here, as gibs don't need this accuracy
   8         WriteShort(MSG_ENTITY, floor(self.origin_y / 4)); // not using a coord here, as gibs don't need this accuracy
   9         WriteShort(MSG_ENTITY, floor(self.origin_z / 4)); // not using a coord here, as gibs don't need this accuracy
  10         WriteShort(MSG_ENTITY, self.oldorigin_x); // acrually compressed velocity
  11         return TRUE;
  12 }
  13
  14 // TODO maybe convert this to a TE?
  15 void Violence_GibSplash_At(vector org, vector dir, float type, float amount, entity gibowner, entity attacker)
  16 {
  17         if(g_cts) // no gibs in CTS
  18                 return;
  19
  20         entity e;
  21
  22         e = spawn();
  23         e.classname = "gibsplash";
  24         e.cnt = amount;
  25         e.state = type; // should stay smaller than 15
  26         if(!sound_allowed(MSG_BROADCAST, gibowner) || !sound_allowed(MSG_BROADCAST, attacker))
  27                 e.state |= 0x40; // "silence" bit
  28         e.state |= 8 * self.species; // gib type, ranges from 0 to 15
  29
  30         // if this is a copied dead body, send the num of its player instead
  31         if(self.classname == "body")
  32                 e.team = num_for_edict(self.owner);
  33         else
  34                 e.team = num_for_edict(self);
  35
  36         setorigin(e, org);
  37         e.velocity = dir;
  38
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40
  41         Net_LinkEntity(e, FALSE, 0.2, Violence_GibSplash_SendEntity);
  42 }
  43
  44 void Violence_GibSplash(entity source, float type, float amount, entity attacker)
  45 {
  46         Violence_GibSplash_At(source.origin + source.view_ofs, source.velocity, type, amount, source, attacker);
  47 }
  48
  49 // damage effect
  50
  51 .float damageeffect_lifetime;
  52 .entity damageeffect_repeater;
  53
  54 float Violence_DamageEffect_SendEntity(entity to, float sf)
  55 {
  56         // if the client doesn't have the effect enabled, don't send to him and waste bandwidth
  57         if not(to.cvar_cl_damageeffect)
  58                 return FALSE;
  59         // if the client cannot see the damaged player, avoid sending and further save bandwidth
  60         if not(checkpvs(to.origin + to.view_ofs, self))
  61                 return FALSE;
  62
  63         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEEFFECT);
  64         WriteByte(MSG_ENTITY, self.cnt); // damage weapon
  65         WriteByte(MSG_ENTITY, self.state); // player species
  66         WriteByte(MSG_ENTITY, self.team); // player entnum
  67         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  68         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  69         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  70         return TRUE;
  71 }
  72
  73 void Violence_DamageEffect(entity pl, float type)
  74 {
  75         entity e;
  76
  77         e = spawn();
  78         e.classname = "damageeffect";
  79         e.cnt = type;
  80         e.state |= 8 * pl.species; // gib type, ranges from 0 to 15
  81
  82         // if this is a copied dead body, send the num of its player instead
  83         if(pl.classname == "body")
  84                 e.team = num_for_edict(pl.owner);
  85         else
  86                 e.team = num_for_edict(pl);
  87
  88         // if the player is dead, show the effect lower, else it appears floating above the body
  89         if(pl.health <= 0)
  90                 setorigin(e, pl.origin - '0 0 25');
  91         else
  92                 setorigin(e, pl.origin);
  93
  94         Net_LinkEntity(e, FALSE, 0.2, Violence_DamageEffect_SendEntity);
  95 }
  96
  97 void Violence_DamageEffect_Remove(entity pl);
  98 void Violence_DamageEffect_DoRepeat()
  99 {
 100         if(time > self.damageeffect_lifetime || (self.owner.classname != "player" && self.owner.classname != "body"))
 101         {
 102                 Violence_DamageEffect_Remove(self.owner);
 103                 return;
 104         }
 105
 106         Violence_DamageEffect(self.owner, self.cnt);
 107         self.nextthink = time + autocvar_sv_damageeffect_tick;
 108 }
 109
 110 void Violence_DamageEffect_SetRepeat(entity pl, float damage, float type)
 111 {
 112         if not(autocvar_sv_damageeffect_tick && autocvar_sv_damageeffect_lifetime)
 113                 return;
 114         if(sv_gentle || !type)
 115                 return; // return if gentle mode is enabled or the damage was not caused by a weapon
 116
 117         // if a repeater doesn't exist, spawn one, else update the existing one
 118         if(pl.damageeffect_repeater == world)
 119         {
 120                 pl.damageeffect_repeater = spawn();
 121                 pl.damageeffect_repeater.classname = "damageeffect_repeater";
 122                 pl.damageeffect_repeater.owner = pl;
 123                 pl.damageeffect_repeater.think = Violence_DamageEffect_DoRepeat;
 124
 125                 pl.damageeffect_repeater.damageeffect_lifetime = time + (autocvar_sv_damageeffect_lifetime * damage);
 126         }
 127         else
 128         {
 129                 // if the repeater is being updated, increase its lifetime instead of re-setting it entirely
 130                 // this fixes the shotgun among other things, where only the damage of one bullet would be taken into account
 131                 pl.damageeffect_repeater.damageeffect_lifetime += (autocvar_sv_damageeffect_lifetime * damage);
 132         }
 133
 134         if(autocvar_sv_damageeffect_lifetime_max)
 135                 pl.damageeffect_repeater.damageeffect_lifetime = bound(0, pl.damageeffect_repeater.damageeffect_lifetime, time + autocvar_sv_damageeffect_lifetime_max);
 136
 137         pl.damageeffect_repeater.cnt = type;
 138         pl.damageeffect_repeater.nextthink = time;
 139 }
 140
 141 void Violence_DamageEffect_Remove(entity pl)
 142 {
 143         pl.damageeffect_repeater.nextthink = 0;
 144         remove(pl.damageeffect_repeater);
 145         pl.damageeffect_repeater = world;
 146 }
 147
 148 void Violence_DamageEffect_Copy(entity old_pl, entity pl)
 149 {
 150         if(pl.damageeffect_repeater != world)
 151                 Violence_DamageEffect_Remove(pl);
 152
 153         Violence_DamageEffect_SetRepeat(pl, 0, old_pl.damageeffect_repeater.cnt); // spawn a new repeater
 154         pl.damageeffect_repeater.damageeffect_lifetime = old_pl.damageeffect_repeater.damageeffect_lifetime; // copy the lifetime
 155 }