qcsrc/server/g_violence.qc

   1 float Violence_GibSplash_SendEntity(entity to, float sf)
   2 {
   3         WriteByte(MSG_ENTITY, ENT_CLIENT_GIBSPLASH);
   4         WriteByte(MSG_ENTITY, self.state); // actually type
   5         WriteByte(MSG_ENTITY, bound(1, self.cnt * 16, 255)); // gibbage amount multiplier
   6         WriteShort(MSG_ENTITY, floor(self.origin_x / 4)); // not using a coord here, as gibs don't need this accuracy
   7         WriteShort(MSG_ENTITY, floor(self.origin_y / 4)); // not using a coord here, as gibs don't need this accuracy
   8         WriteShort(MSG_ENTITY, floor(self.origin_z / 4)); // not using a coord here, as gibs don't need this accuracy
   9         WriteShort(MSG_ENTITY, self.oldorigin_x); // acrually compressed velocity
  10         return TRUE;
  11 }
  12
  13 // TODO maybe convert this to a TE?
  14 void Violence_GibSplash_At(vector org, vector dir, float type, float amount, entity gibowner, entity attacker)
  15 {
  16         if(g_cts) // no gibs in CTS
  17                 return;
  18
  19         entity e;
  20
  21         e = spawn();
  22         e.classname = "gibsplash";
  23         e.cnt = amount;
  24         e.state = type; // should stay smaller than 15
  25         if(!sound_allowed(MSG_BROADCAST, gibowner) || !sound_allowed(MSG_BROADCAST, attacker))
  26                 e.state |= 0x40; // "silence" bit
  27         e.state |= 8 * self.species; // gib type, ranges from 0 to 15
  28         setorigin(e, org);
  29         e.velocity = dir;
  30
  31         e.oldorigin_x = compressShortVector(e.velocity);
  32
  33         Net_LinkEntity(e, FALSE, 0.2, Violence_GibSplash_SendEntity);
  34 }
  35
  36 void Violence_GibSplash(entity source, float type, float amount, entity attacker)
  37 {
  38         Violence_GibSplash_At(source.origin + source.view_ofs, source.velocity, type, amount, source, attacker);
  39 }
  40
  41 float Violence_DamageEffect_SendEntity(entity to, float sf)
  42 {
  43         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEEFFECT);
  44         WriteByte(MSG_ENTITY, self.cnt); // the damage weapon
  45         WriteByte(MSG_ENTITY, self.state); // species
  46         WriteByte(MSG_ENTITY, self.team); // is self
  47         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  48         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  49         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  50         return TRUE;
  51 }
  52
  53 void Violence_DamageEffect(entity pl, float type)
  54 {
  55         entity e;
  56
  57         e = spawn();
  58         e.classname = "weapondamage";
  59         e.cnt = type;
  60         e.state |= 8 * pl.species; // gib type, ranges from 0 to 15
  61         setorigin(e, pl.origin);
  62
  63         Net_LinkEntity(e, FALSE, 0.2, Violence_DamageEffect_SendEntity);
  64 }
  65
  66 .entity damageeffect_repeater;
  67 .float lifetime;
  68
  69 void Violence_DamageEffect_DoRepeat()
  70 {
  71         if(time > self.lifetime)
  72         {
  73                 self.nextthink = 0;
  74                 remove(self.owner.damageeffect_repeater);
  75                 self.owner.damageeffect_repeater = world;
  76                 return;
  77         }
  78
  79         Violence_DamageEffect(self.owner, self.cnt);
  80         self.nextthink = time + autocvar_sv_damageeffect_tick;
  81 }
  82
  83 void Violence_DamageEffect_SetRepeat(entity pl, float damage, float type, float isself)
  84 {
  85         if not(autocvar_sv_damageeffect_tick && autocvar_sv_damageeffect_lifetime)
  86                 return;
  87         if(sv_gentle || !type)
  88                 return; // return if gentle mode is enabled or the damage was not caused by a weapon
  89
  90         // if a repeater doesn't exist, spawn one, else update the existing one
  91         if(pl.damageeffect_repeater == world)
  92         {
  93                 pl.damageeffect_repeater = spawn();
  94                 pl.damageeffect_repeater.classname = "damageeffect_repeater";
  95                 pl.damageeffect_repeater.owner = pl;
  96                 pl.damageeffect_repeater.think = Violence_DamageEffect_DoRepeat;
  97
  98                 pl.damageeffect_repeater.team = isself;
  99                 pl.damageeffect_repeater.lifetime = time + (autocvar_sv_damageeffect_lifetime * damage);
 100         }
 101         else
 102         {
 103                 // if the repeater is being updated, increase its lifetime instead of re-setting it entirely
 104                 // this fixes the shotgun among other things, where only the damage of one bullet would be taken into account
 105                 pl.damageeffect_repeater.lifetime += (autocvar_sv_damageeffect_lifetime * damage);
 106         }
 107
 108         pl.damageeffect_repeater.cnt = type;
 109         pl.damageeffect_repeater.nextthink = time;
 110 }