qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap(float reinit);
  48 void ShuffleMaplist()
  49 float(float reinit) DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride(1))
 193                         GotoNextMap(1);
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_ghost_items");
 301                 BADPREFIX("g_playerstats_");
 302                 BADPREFIX("g_respawn_ghosts");
 303                 BADPREFIX("g_voice_flood_");
 304                 BADPREFIX("rcon_");
 305                 BADPREFIX("settemp_");
 306                 BADPREFIX("sv_allowdownloads");
 307                 BADPREFIX("sv_autodemo");
 308                 BADPREFIX("sv_curl_");
 309                 BADPREFIX("sv_eventlog");
 310                 BADPREFIX("sv_logscores_");
 311                 BADPREFIX("sv_master");
 312                 BADPREFIX("sv_weaponstats_");
 313                 BADPREFIX("sv_waypointsprite_");
 314                 BADCVAR("rescan_pending");
 315
 316                 // these can contain player IDs, so better hide
 317                 BADPREFIX("g_forced_team_");
 318
 319                 // mapinfo
 320                 BADCVAR("fraglimit");
 321                 BADCVAR("g_arena");
 322                 BADCVAR("g_assault");
 323                 BADCVAR("g_ca");
 324                 BADCVAR("g_ctf");
 325                 BADCVAR("g_cts");
 326                 BADCVAR("g_dm");
 327                 BADCVAR("g_domination");
 328                 BADCVAR("g_domination_default_teams");
 329                 BADCVAR("g_freezetag");
 330                 BADCVAR("g_keepaway");
 331                 BADCVAR("g_keyhunt");
 332                 BADCVAR("g_keyhunt_teams");
 333                 BADCVAR("g_keyhunt_teams");
 334                 BADCVAR("g_lms");
 335                 BADCVAR("g_nexball");
 336                 BADCVAR("g_onslaught");
 337                 BADCVAR("g_race");
 338                 BADCVAR("g_race_qualifying_timelimit");
 339                 BADCVAR("g_runematch");
 340                 BADCVAR("g_tdm");
 341                 BADCVAR("g_tdm_teams");
 342                 BADCVAR("leadlimit");
 343                 BADCVAR("nextmap");
 344                 BADCVAR("teamplay");
 345                 BADCVAR("timelimit");
 346
 347                 // long
 348                 BADCVAR("hostname");
 349                 BADCVAR("g_maplist");
 350                 BADCVAR("g_maplist_mostrecent");
 351                 BADCVAR("sv_motd");
 352
 353                 v = cvar_string(k);
 354                 d = cvar_defstring(k);
 355                 if(v == d)
 356                         continue;
 357
 358                 if(adding)
 359                 {
 360                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 361                         if(strlen(cvar_changes) > 16384)
 362                         {
 363                                 cvar_changes = "// too many settings have been changed to show them here\n";
 364                                 adding = 0;
 365                         }
 366                 }
 367
 368                 // now check if the changes are actually gameplay relevant
 369
 370                 // does nothing visible
 371                 BADCVAR("captureleadlimit_override");
 372                 BADCVAR("g_arena_point_leadlimit");
 373                 BADCVAR("g_balance_kill_delay");
 374                 BADCVAR("g_ca_point_leadlimit");
 375                 BADCVAR("g_ctf_captimerecord_always");
 376                 BADCVAR("g_ctf_capture_leadlimit");
 377                 BADCVAR("g_ctf_flag_capture_effects");
 378                 BADCVAR("g_ctf_flag_glowtrails");
 379                 BADCVAR("g_ctf_flag_pickup_effects");
 380                 BADCVAR("g_domination_point_leadlimit");
 381                 BADCVAR("g_forced_respawn");
 382                 BADCVAR("g_keyhunt_point_leadlimit");
 383                 BADCVAR("g_nexball_goalleadlimit");
 384                 BADCVAR("g_runematch_point_leadlimit");
 385                 BADCVAR("leadlimit_and_fraglimit");
 386                 BADCVAR("leadlimit_override");
 387                 BADCVAR("pausable");
 388                 BADCVAR("sv_allow_fullbright");
 389                 BADCVAR("sv_checkforpacketsduringsleep");
 390                 BADCVAR("sv_timeout");
 391                 BADPREFIX("sv_timeout_");
 392                 BADCVAR("welcome_message_time");
 393                 BADPREFIX("crypto_");
 394                 BADPREFIX("g_chat_");
 395                 BADPREFIX("g_ctf_captimerecord_");
 396                 BADPREFIX("g_maplist_votable_");
 397                 BADPREFIX("net_");
 398                 BADPREFIX("prvm_");
 399                 BADPREFIX("skill_");
 400                 BADPREFIX("sv_cullentities_");
 401                 BADPREFIX("sv_fraginfo_");
 402                 BADPREFIX("sv_maxidle_");
 403                 BADPREFIX("sv_vote_");
 404                 BADPREFIX("timelimit_");
 405                 BADCVAR("gameversion");
 406                 BADPREFIX("gameversion_");
 407                 BADCVAR("sv_namechangetimer");
 408 #ifndef NO_LEGACY_NETWORKING
 409                 BADCVAR("sv_use_csqc_players"); // transition
 410 #endif
 411
 412                 // allowed changes to server admins (please sync this to server.cfg)
 413                 // vi commands:
 414                 //   :/"impure"/,$d
 415                 //   :g!,^\/\/[^ /],d
 416                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 417                 //   :%!sort
 418                 // yes, this does contain some redundant stuff, don't really care
 419                 BADCVAR("bot_config_file");
 420                 BADCVAR("bot_number");
 421                 BADCVAR("bot_prefix");
 422                 BADCVAR("bot_suffix");
 423                 BADCVAR("capturelimit_override");
 424                 BADCVAR("fraglimit_override");
 425                 BADCVAR("gametype");
 426                 BADCVAR("g_antilag");
 427                 BADCVAR("g_balance_teams");
 428                 BADCVAR("g_balance_teams_force");
 429                 BADCVAR("g_ban_sync_trusted_servers");
 430                 BADCVAR("g_ban_sync_uri");
 431                 BADCVAR("g_ctf_capture_limit");
 432                 BADCVAR("g_ctf_ignore_frags");
 433                 BADCVAR("g_ctf_win_mode");
 434                 BADCVAR("g_domination_point_limit");
 435                 BADCVAR("g_friendlyfire");
 436                 BADCVAR("g_fullbrightitems");
 437                 BADCVAR("g_fullbrightplayers");
 438                 BADCVAR("g_keyhunt_point_limit");
 439                 BADCVAR("g_keyhunt_teams_override");
 440                 BADCVAR("g_lms_lives_override");
 441                 BADCVAR("g_maplist");
 442                 BADCVAR("g_maplist_check_waypoints");
 443                 BADCVAR("g_maplist_mostrecent_count");
 444                 BADCVAR("g_maplist_shuffle");
 445                 BADCVAR("g_maplist_votable");
 446                 BADCVAR("g_maplist_votable_abstain");
 447                 BADCVAR("g_maplist_votable_nodetail");
 448                 BADCVAR("g_maplist_votable_suggestions");
 449                 BADCVAR("g_maxplayers");
 450                 BADCVAR("g_minstagib");
 451                 BADCVAR("g_mirrordamage");
 452                 BADCVAR("g_nexball_goallimit");
 453                 BADCVAR("g_powerups");
 454                 BADCVAR("g_runematch_point_limit");
 455                 BADCVAR("g_start_delay");
 456                 BADCVAR("g_warmup");
 457                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 458                 BADCVAR("hostname");
 459                 BADCVAR("log_file");
 460                 BADCVAR("maxplayers");
 461                 BADCVAR("minplayers");
 462                 BADCVAR("net_address");
 463                 BADCVAR("port");
 464                 BADCVAR("rcon_password");
 465                 BADCVAR("rcon_restricted_commands");
 466                 BADCVAR("rcon_restricted_password");
 467                 BADCVAR("skill");
 468                 BADCVAR("sv_adminnick");
 469                 BADCVAR("sv_autoscreenshot");
 470                 BADCVAR("sv_autotaunt");
 471                 BADCVAR("sv_curl_defaulturl");
 472                 BADCVAR("sv_defaultcharacter");
 473                 BADCVAR("sv_defaultplayercolors");
 474                 BADCVAR("sv_defaultplayermodel");
 475                 BADCVAR("sv_defaultplayerskin");
 476                 BADCVAR("sv_maxidle");
 477                 BADCVAR("sv_maxrate");
 478                 BADCVAR("sv_motd");
 479                 BADCVAR("sv_public");
 480                 BADCVAR("sv_ready_restart");
 481                 BADCVAR("sv_status_privacy");
 482                 BADCVAR("sv_taunt");
 483                 BADCVAR("sv_vote_call");
 484                 BADCVAR("sv_vote_commands");
 485                 BADCVAR("sv_vote_majority_factor");
 486                 BADCVAR("sv_vote_master");
 487                 BADCVAR("sv_vote_master_commands");
 488                 BADCVAR("sv_vote_master_password");
 489                 BADCVAR("sv_vote_simple_majority_factor");
 490                 BADCVAR("sys_ticrate");
 491                 BADCVAR("teamplay_mode");
 492                 BADCVAR("timelimit_override");
 493                 BADCVAR("g_spawnshieldtime");
 494                 BADPREFIX("g_warmup_");
 495                 BADPREFIX("sv_ready_restart_");
 496
 497                 if(autocvar_g_minstagib)
 498                 {
 499                         BADCVAR("g_grappling_hook");
 500                         BADCVAR("g_jetpack");
 501                 }
 502 #undef BADPREFIX
 503 #undef BADCVAR
 504
 505                 if(pureadding)
 506                 {
 507                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 508                         if(strlen(cvar_purechanges) > 16384)
 509                         {
 510                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 511                                 pureadding = 0;
 512                         }
 513                 }
 514                 ++cvar_purechanges_count;
 515                 // WARNING: this variable is used for the server list
 516                 // NEVER dare to skip this code!
 517                 // Hacks to intentionally appearing as "pure server" even though you DO have
 518                 // modified settings may be punished by removal from the server list.
 519                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 520                 // though.
 521         }
 522         buf_del(h);
 523         if(cvar_changes == "")
 524                 cvar_changes = "// this server runs at default server settings\n";
 525         else
 526                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 527         cvar_changes = strzone(cvar_changes);
 528         if(cvar_purechanges == "")
 529                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 530         else
 531                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 532         cvar_purechanges = strzone(cvar_purechanges);
 533 }
 534
 535 void detect_maptype()
 536 {
 537 #if 0
 538         vector o, v;
 539         float i;
 540
 541         for(;;)
 542         {
 543                 o = world.mins;
 544                 o_x += random() * (world.maxs_x - world.mins_x);
 545                 o_y += random() * (world.maxs_y - world.mins_y);
 546                 o_z += random() * (world.maxs_z - world.mins_z);
 547
 548                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 549                 if(trace_fraction == 1)
 550                         continue;
 551
 552                 v = trace_endpos;
 553
 554                 for(i = 0; i < 64; i += 4)
 555                 {
 556                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 557         if(trace_fraction == 1)
 558                 continue;
 559                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 560                 }
 561
 562                 break;
 563         }
 564 #endif
 565 }
 566
 567 entity randomseed;
 568 float RandomSeed_Send(entity to, float sf)
 569 {
 570         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 571         WriteShort(MSG_ENTITY, self.cnt);
 572         return TRUE;
 573 }
 574 void RandomSeed_Think()
 575 {
 576         self.cnt = bound(0, floor(random() * 65536), 65535);
 577         self.nextthink = time + 5;
 578
 579         self.SendFlags |= 1;
 580 }
 581 void RandomSeed_Spawn()
 582 {
 583         randomseed = spawn();
 584         randomseed.think = RandomSeed_Think;
 585         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 586
 587         entity oldself;
 588         oldself = self;
 589         self = randomseed;
 590         self.think(); // sets random seed and nextthink
 591         self = oldself;
 592 }
 593
 594 void spawnfunc___init_dedicated_server(void)
 595 {
 596         // handler for _init/_init map (only for dedicated server initialization)
 597
 598         world_initialized = -1; // don't complain
 599         cvar = cvar_normal;
 600         cvar_string = cvar_string_normal;
 601         cvar_set = cvar_set_normal;
 602
 603         remove = remove_unsafely;
 604
 605         entity e;
 606         e = spawn();
 607         e.think = GotoFirstMap;
 608         e.nextthink = time; // this is usually 1 at this point
 609
 610         e = spawn();
 611         e.classname = "info_player_deathmatch"; // safeguard against player joining
 612
 613         self.classname = "worldspawn"; // safeguard against various stuff ;)
 614
 615         MapInfo_Enumerate();
 616         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 617 }
 618
 619 void Map_MarkAsRecent(string m);
 620 float world_already_spawned;
 621 void RegisterWeapons();
 622 void Nagger_Init();
 623 void ClientInit_Spawn();
 624 void WeaponStats_Init();
 625 void WeaponStats_Shutdown();
 626 void spawnfunc_worldspawn (void)
 627 {
 628         float fd, l, i, j, n;
 629         string s, col;
 630
 631         cvar = cvar_normal;
 632         cvar_string = cvar_string_normal;
 633         cvar_set = cvar_set_normal;
 634
 635         if(world_already_spawned)
 636                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 637         world_already_spawned = TRUE;
 638
 639         remove = remove_safely; // during spawning, watch what you remove!
 640
 641         check_unacceptable_compiler_bugs();
 642
 643         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 644
 645         compressShortVector_init();
 646
 647         allowed_to_spawn = TRUE;
 648
 649         entity head;
 650         head = nextent(world);
 651         maxclients = 0;
 652         while(head)
 653         {
 654                 ++maxclients;
 655                 head = nextent(head);
 656         }
 657
 658         // needs to be done so early as they would still spawn
 659         RegisterWeapons();
 660
 661         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 662
 663         TemporaryDB = db_create();
 664
 665         // 0 normal
 666         lightstyle(0, "m");
 667
 668         // 1 FLICKER (first variety)
 669         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 670
 671         // 2 SLOW STRONG PULSE
 672         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 673
 674         // 3 CANDLE (first variety)
 675         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 676
 677         // 4 FAST STROBE
 678         lightstyle(4, "mamamamamama");
 679
 680         // 5 GENTLE PULSE 1
 681         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 682
 683         // 6 FLICKER (second variety)
 684         lightstyle(6, "nmonqnmomnmomomno");
 685
 686         // 7 CANDLE (second variety)
 687         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 688
 689         // 8 CANDLE (third variety)
 690         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 691
 692         // 9 SLOW STROBE (fourth variety)
 693         lightstyle(9, "aaaaaaaazzzzzzzz");
 694
 695         // 10 FLUORESCENT FLICKER
 696         lightstyle(10, "mmamammmmammamamaaamammma");
 697
 698         // 11 SLOW PULSE NOT FADE TO BLACK
 699         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 700
 701         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 702
 703         // 63 testing
 704         lightstyle(63, "a");
 705
 706         if(autocvar_g_campaign)
 707                 CampaignPreInit();
 708
 709         Map_MarkAsRecent(mapname);
 710
 711         precache_model ("null"); // we need this one before InitGameplayMode
 712         InitGameplayMode();
 713         readlevelcvars();
 714         GrappleHookInit();
 715         ElectroInit();
 716         LaserInit();
 717
 718         player_count = 0;
 719         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 720         if(bot_waypoints_for_items == 1)
 721                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 722                         bot_waypoints_for_items = 0;
 723
 724         precache();
 725
 726         WaypointSprite_Init();
 727
 728         //if (g_domination)
 729         //      dom_init();
 730
 731         GameLogInit(); // prepare everything
 732         // NOTE for matchid:
 733         // changing the logic generating it is okay. But:
 734         // it HAS to stay <= 64 chars
 735         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 736         if(autocvar_sv_eventlog)
 737         {
 738                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 739                 matchid = strzone(s);
 740
 741                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 742                 s = ":gameinfo:mutators:LIST";
 743
 744                 ret_string = s;
 745                 MUTATOR_CALLHOOK(BuildMutatorsString);
 746                 s = ret_string;
 747
 748                 // simple, probably not good in the mutator system
 749                 if(autocvar_g_grappling_hook)
 750                         s = strcat(s, ":grappling_hook");
 751
 752                 // initialiation stuff, not good in the mutator system
 753                 if(!autocvar_g_use_ammunition)
 754                         s = strcat(s, ":no_use_ammunition");
 755
 756                 // initialiation stuff, not good in the mutator system
 757                 if(autocvar_g_pickup_items == 0)
 758                         s = strcat(s, ":no_pickup_items");
 759                 if(autocvar_g_pickup_items > 0)
 760                         s = strcat(s, ":pickup_items");
 761
 762                 // initialiation stuff, not good in the mutator system
 763                 if(autocvar_g_weaponarena != "0")
 764                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 765
 766                 // TODO to mutator system
 767                 if(autocvar_g_norecoil)
 768                         s = strcat(s, ":norecoil");
 769
 770                 // TODO to mutator system
 771                 if(autocvar_g_midair)
 772                         s = strcat(s, ":midair");
 773
 774                 // TODO to mutator system
 775                 if(autocvar_g_minstagib)
 776                         s = strcat(s, ":minstagib");
 777
 778                 // TODO to mutator system
 779                 if(autocvar_g_powerups == 0)
 780                         s = strcat(s, ":no_powerups");
 781                 if(autocvar_g_powerups > 0)
 782                         s = strcat(s, ":powerups");
 783
 784                 GameLogEcho(s);
 785                 GameLogEcho(":gameinfo:end");
 786         }
 787         else
 788                 matchid = strzone(ftos(random()));
 789
 790         cvar_set("nextmap", "");
 791
 792         SetDefaultAlpha();
 793
 794         if(autocvar_g_campaign)
 795                 CampaignPostInit();
 796
 797         fteqcc_testbugs();
 798
 799         Ban_LoadBans();
 800
 801         MapInfo_Enumerate();
 802         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 803
 804         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 805         {
 806                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 807                 if(fd != -1)
 808                 {
 809                         while((s = fgets(fd)))
 810                         {
 811                                 l = tokenize_console(s);
 812                                 if(l < 2)
 813                                         continue;
 814                                 if(argv(0) == "cd")
 815                                 {
 816                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 817                                         print("  cdtrack ", argv(2), "\n");
 818                                 }
 819                                 else if(argv(0) == "fog")
 820                                 {
 821                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 822                                         print("  \"fog\" \"", s, "\"\n");
 823                                 }
 824                                 else if(argv(0) == "set")
 825                                 {
 826                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 827                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 828                                 }
 829                                 else if(argv(0) != "//")
 830                                 {
 831                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 832                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 833                                 }
 834                         }
 835                         fclose(fd);
 836                 }
 837         }
 838
 839         WeaponStats_Init();
 840
 841         addstat(STAT_WEAPONS, AS_INT, weapons);
 842         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 843         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 844         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 845         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 846         Nagger_Init();
 847
 848         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 849         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 850         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 851         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 852         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 853         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 854         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 855         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 856         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 857         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 858         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 859         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 860
 861         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 862         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 863
 864         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 865
 866         if(g_ca || g_freezetag)
 867         {
 868                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 869                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 870                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 871                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 872         }
 873         if(g_freezetag)
 874         {
 875                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 876                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 877         }
 878
 879         // g_movementspeed hack
 880         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 881         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 882         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 883         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 884
 885         // secrets
 886         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 887         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 888
 889         next_pingtime = time + 5;
 890
 891         detect_maptype();
 892
 893         lsmaps_reply = "^7Maps available: ";
 894         lsnewmaps_reply = "^7Maps without a record set: ";
 895         for(i = 0, j = 0; i < MapInfo_count; ++i)
 896         {
 897                 if(MapInfo_Get_ByID(i))
 898                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 899                         {
 900                                 if(mod(i, 2))
 901                                         col = "^2";
 902                                 else
 903                                         col = "^3";
 904                                 ++j;
 905                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 906                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 907                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 908                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 909                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 910                         }
 911         }
 912         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 913         if (!g_race && !g_cts)
 914                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 915         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 916
 917         maplist_reply = "^7Maps in list: ";
 918         n = tokenize_console(autocvar_g_maplist);
 919         for(i = 0, j = 0; i < n; ++i)
 920         {
 921                 if(MapInfo_CheckMap(argv(i)))
 922                 {
 923                         if(mod(j, 2))
 924                                 col = "^2";
 925                         else
 926                                 col = "^3";
 927                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 928                         ++j;
 929                 }
 930         }
 931         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 932         MapInfo_ClearTemps();
 933
 934         for(i = 0; i < 10; ++i)
 935         {
 936                 records_reply[i] = strzone(getrecords(i));
 937         }
 938         if(g_cts)
 939                 ladder_reply = strzone(getladder());
 940
 941         rankings_reply = strzone(getrankings());
 942
 943         ClientInit_Spawn();
 944         RandomSeed_Spawn();
 945         PingPLReport_Spawn();
 946
 947         CheatInit();
 948
 949         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 950
 951         // fill sv_curl_serverpackages from .serverpackage files
 952         if(autocvar_sv_curl_serverpackages_auto)
 953         {
 954                 s = "";
 955                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 956                 for(i = 0; i < n; ++i)
 957                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 958                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 959                                 s = strcat(s, " ", argv(i));
 960                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 961                 if(fd >= 0)
 962                 {
 963                         j = search_getsize(fd);
 964                         for(i = 0; i < j; ++i)
 965                                 s = strcat(s, " ", search_getfilename(fd, i));
 966                         search_end(fd);
 967                 }
 968                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 969                 if(fd >= 0)
 970                 {
 971                         j = search_getsize(fd);
 972                         for(i = 0; i < j; ++i)
 973                                 s = strcat(s, " ", search_getfilename(fd, i));
 974                         search_end(fd);
 975                 }
 976                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 977         }
 978
 979         PlayerStats_Init();
 980
 981         world_initialized = 1;
 982 }
 983
 984 void spawnfunc_light (void)
 985 {
 986         //makestatic (self); // Who the f___ did that?
 987         remove(self);
 988 }
 989
 990 string GetGametype()
 991 {
 992         return GametypeNameFromType(game);
 993 }
 994
 995 string getmapname_stored;
 996 string GetMapname()
 997 {
 998         return mapname;
 999 }
1000
1001 float Map_Count, Map_Current;
1002 string Map_Current_Name;
1003
1004 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1005 float GetMaplistPosition()
1006 {
1007         float pos, idx;
1008         string map;
1009
1010         map = GetMapname();
1011         idx = autocvar_g_maplist_index;
1012
1013         if(idx >= 0)
1014                 if(idx < Map_Count)
1015                         if(map == argv(idx))
1016                                 return idx;
1017
1018         for(pos = 0; pos < Map_Count; ++pos)
1019                 if(map == argv(pos))
1020                         return pos;
1021
1022         // resume normal maplist rotation if current map is not in g_maplist
1023         return idx;
1024 }
1025
1026 float MapHasRightSize(string map)
1027 {
1028         float fh;
1029         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1030         if(autocvar_g_maplist_check_waypoints)
1031         {
1032                 dprint("checkwp "); dprint(map);
1033                 if(!fexists(strcat("maps/", map, ".waypoints")))
1034                 {
1035                         dprint(": no waypoints\n");
1036                         return FALSE;
1037                 }
1038                 dprint(": has waypoints\n");
1039         }
1040
1041         // open map size restriction file
1042         dprint("opensize "); dprint(map);
1043         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1044         if(fh >= 0)
1045         {
1046                 float mapmin, mapmax;
1047                 dprint(": ok, ");
1048                 mapmin = stof(fgets(fh));
1049                 mapmax = stof(fgets(fh));
1050                 fclose(fh);
1051                 if(player_count < mapmin)
1052                 {
1053                         dprint("not enough\n");
1054                         return FALSE;
1055                 }
1056                 if(player_count > mapmax)
1057                 {
1058                         dprint("too many\n");
1059                         return FALSE;
1060                 }
1061                 dprint("right size\n");
1062                 return TRUE;
1063         }
1064         dprint(": not found\n");
1065         return TRUE;
1066 }
1067
1068 string Map_Filename(float position)
1069 {
1070         return strcat("maps/", argv(position), ".bsp");
1071 }
1072
1073 string strwords(string s, float w)
1074 {
1075         float endpos;
1076         for(endpos = 0; w && endpos >= 0; --w)
1077                 endpos = strstrofs(s, " ", endpos + 1);
1078         if(endpos < 0)
1079                 return s;
1080         else
1081                 return substring(s, 0, endpos);
1082 }
1083
1084 float strhasword(string s, string w)
1085 {
1086         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1087 }
1088
1089 void Map_MarkAsRecent(string m)
1090 {
1091         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1092 }
1093
1094 float Map_IsRecent(string m)
1095 {
1096         return strhasword(autocvar_g_maplist_mostrecent, m);
1097 }
1098
1099 float Map_Check(float position, float pass)
1100 {
1101         string filename;
1102         string map_next;
1103         map_next = argv(position);
1104         if(pass <= 1)
1105         {
1106                 if(Map_IsRecent(map_next))
1107                         return 0;
1108         }
1109         filename = Map_Filename(position);
1110         if(MapInfo_CheckMap(map_next))
1111         {
1112                 if(pass == 2)
1113                         return 1;
1114                 if(MapHasRightSize(map_next))
1115                         return 1;
1116                 return 0;
1117         }
1118         else
1119                 dprint( "Couldn't select '", filename, "'..\n" );
1120
1121         return 0;
1122 }
1123
1124 void Map_Goto_SetStr(string nextmapname)
1125 {
1126         if(getmapname_stored != "")
1127                 strunzone(getmapname_stored);
1128         if(nextmapname == "")
1129                 getmapname_stored = "";
1130         else
1131                 getmapname_stored = strzone(nextmapname);
1132 }
1133
1134 void Map_Goto_SetFloat(float position)
1135 {
1136         cvar_set("g_maplist_index", ftos(position));
1137         Map_Goto_SetStr(argv(position));
1138 }
1139
1140 void GameResetCfg()
1141 {
1142         // settings persist, except...
1143         localcmd("\nsettemp_restore\n");
1144 }
1145
1146 void Map_Goto(float reinit)
1147 {
1148         GameResetCfg();
1149         MapInfo_LoadMap(getmapname_stored, reinit);
1150 }
1151
1152 // return codes of map selectors:
1153 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1154 //   -2 = permanent failure
1155 float() MaplistMethod_Iterate = // usual method
1156 {
1157         float pass, i;
1158
1159         for(pass = 1; pass <= 2; ++pass)
1160         {
1161                 for(i = 1; i < Map_Count; ++i)
1162                 {
1163                         float mapindex;
1164                         mapindex = mod(i + Map_Current, Map_Count);
1165                         if(Map_Check(mapindex, pass))
1166                                 return mapindex;
1167                 }
1168         }
1169         return -1;
1170 }
1171
1172 float() MaplistMethod_Repeat = // fallback method
1173 {
1174         if(Map_Check(Map_Current, 2))
1175                 return Map_Current;
1176         return -2;
1177 }
1178
1179 float() MaplistMethod_Random = // random map selection
1180 {
1181         float i, imax;
1182
1183         imax = 42;
1184
1185         for(i = 0; i <= imax; ++i)
1186         {
1187                 float mapindex;
1188                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1189                 if(Map_Check(mapindex, 1))
1190                         return mapindex;
1191         }
1192         return -1;
1193 }
1194
1195 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1196 // the exponent sets a bias on the map selection:
1197 // the higher the exponent, the less likely "shortly repeated" same maps are
1198 {
1199         float i, j, imax, insertpos;
1200
1201         imax = 42;
1202
1203         for(i = 0; i <= imax; ++i)
1204         {
1205                 string newlist;
1206
1207                 // now reinsert this at another position
1208                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1209                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1210                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1211                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1212
1213                 // insert the current map there
1214                 newlist = "";
1215                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1216                         newlist = strcat(newlist, " ", argv(j));
1217                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1218                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1219                         newlist = strcat(newlist, " ", argv(j));
1220                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1221                 cvar_set("g_maplist", newlist);
1222                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1223
1224                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1225                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1226                 if(Map_Check(Map_Current, 1))
1227                         return Map_Current;
1228         }
1229         return -1;
1230 }
1231
1232 void Maplist_Init()
1233 {
1234         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1235         if(Map_Count == 0)
1236         {
1237                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1238                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1239                 if(autocvar_g_maplist_shuffle)
1240                         ShuffleMaplist();
1241                 localcmd("\nmenu_cmd sync\n");
1242                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1243         }
1244         if(Map_Count == 0)
1245                 error("empty maplist, cannot select a new map");
1246         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1247
1248         if(Map_Current_Name)
1249                 strunzone(Map_Current_Name);
1250         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1251         // this may or may not be correct, but who cares, in the worst case a map
1252         // isn't chosen in the first pass that should have been
1253 }
1254
1255 string GetNextMap()
1256 {
1257         float nextMap;
1258
1259         Maplist_Init();
1260         nextMap = -1;
1261
1262         if(nextMap == -1)
1263                 if(autocvar_g_maplist_shuffle > 0)
1264                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1265
1266         if(nextMap == -1)
1267                 if(autocvar_g_maplist_selectrandom)
1268                         nextMap = MaplistMethod_Random();
1269
1270         if(nextMap == -1)
1271                 nextMap = MaplistMethod_Iterate();
1272
1273         if(nextMap == -1)
1274                 nextMap = MaplistMethod_Repeat();
1275
1276         if(nextMap >= 0)
1277         {
1278                 Map_Goto_SetFloat(nextMap);
1279                 return getmapname_stored;
1280         }
1281
1282         return "";
1283 }
1284
1285 float DoNextMapOverride(float reinit)
1286 {
1287         if(autocvar_g_campaign)
1288         {
1289                 CampaignPostIntermission();
1290                 alreadychangedlevel = TRUE;
1291                 return TRUE;
1292         }
1293         if(autocvar_quit_when_empty)
1294         {
1295                 if(player_count <= currentbots)
1296                 {
1297                         localcmd("quit\n");
1298                         alreadychangedlevel = TRUE;
1299                         return TRUE;
1300                 }
1301         }
1302         if(autocvar_quit_and_redirect != "")
1303         {
1304                 redirection_target = strzone(autocvar_quit_and_redirect);
1305                 alreadychangedlevel = TRUE;
1306                 return TRUE;
1307         }
1308         if (autocvar_samelevel) // if samelevel is set, stay on same level
1309         {
1310                 localcmd("restart\n");
1311                 alreadychangedlevel = TRUE;
1312                 return TRUE;
1313         }
1314         if(autocvar_nextmap != "")
1315                 if(MapInfo_CheckMap(autocvar_nextmap))
1316                 {
1317                         Map_Goto_SetStr(autocvar_nextmap);
1318                         Map_Goto(reinit);
1319                         alreadychangedlevel = TRUE;
1320                         return TRUE;
1321                 }
1322         if(autocvar_lastlevel)
1323         {
1324                 GameResetCfg();
1325                 localcmd("set lastlevel 0\ntogglemenu\n");
1326                 alreadychangedlevel = TRUE;
1327                 return TRUE;
1328         }
1329         return FALSE;
1330 }
1331
1332 void GotoNextMap(float reinit)
1333 {
1334         //string nextmap;
1335         //float n, nummaps;
1336         //string s;
1337         if (alreadychangedlevel)
1338                 return;
1339         alreadychangedlevel = TRUE;
1340
1341         {
1342                 string nextMap;
1343                 float allowReset;
1344
1345                 for(allowReset = 1; allowReset >= 0; --allowReset)
1346                 {
1347                         nextMap = GetNextMap();
1348                         if(nextMap != "")
1349                                 break;
1350
1351                         if(allowReset)
1352                         {
1353                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1354                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1355                                 if(autocvar_g_maplist_shuffle)
1356                                         ShuffleMaplist();
1357                                 localcmd("\nmenu_cmd sync\n");
1358                         }
1359                         else
1360                         {
1361                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1362                         }
1363                 }
1364                 Map_Goto(reinit);
1365         }
1366 }
1367
1368
1369 /*
1370 ============
1371 IntermissionThink
1372
1373 When the player presses attack or jump, change to the next level
1374 ============
1375 */
1376 .float autoscreenshot;
1377 void() MapVote_Start;
1378 void() MapVote_Think;
1379 float mapvote_initialized;
1380 void IntermissionThink()
1381 {
1382         FixIntermissionClient(self);
1383
1384         if( (autocvar_sv_autoscreenshot || self.cvar_cl_autoscreenshot)
1385                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1386         {
1387                 self.autoscreenshot = -1;
1388                 if(clienttype(self) == CLIENTTYPE_REAL)
1389                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1390                 return;
1391         }
1392
1393         if (time < intermission_exittime)
1394                 return;
1395
1396         if(!mapvote_initialized)
1397                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1398                         return;
1399
1400         MapVote_Start();
1401 }
1402
1403 /*
1404 ============
1405 FindIntermission
1406
1407 Returns the entity to view from
1408 ============
1409 */
1410 /*
1411 entity FindIntermission()
1412 {
1413         local   entity spot;
1414         local   float cyc;
1415
1416 // look for info_intermission first
1417         spot = find (world, classname, "info_intermission");
1418         if (spot)
1419         {       // pick a random one
1420                 cyc = random() * 4;
1421                 while (cyc > 1)
1422                 {
1423                         spot = find (spot, classname, "info_intermission");
1424                         if (!spot)
1425                                 spot = find (spot, classname, "info_intermission");
1426                         cyc = cyc - 1;
1427                 }
1428                 return spot;
1429         }
1430
1431 // then look for the start position
1432         spot = find (world, classname, "info_player_start");
1433         if (spot)
1434                 return spot;
1435
1436 // testinfo_player_start is only found in regioned levels
1437         spot = find (world, classname, "testplayerstart");
1438         if (spot)
1439                 return spot;
1440
1441 // then look for the start position
1442         spot = find (world, classname, "info_player_deathmatch");
1443         if (spot)
1444                 return spot;
1445
1446         //objerror ("FindIntermission: no spot");
1447         return world;
1448 }
1449 */
1450
1451 /*
1452 ===============================================================================
1453
1454 RULES
1455
1456 ===============================================================================
1457 */
1458
1459 void DumpStats(float final)
1460 {
1461         float file;
1462         string s;
1463         float to_console;
1464         float to_eventlog;
1465         float to_file;
1466         float i;
1467
1468         to_console = autocvar_sv_logscores_console;
1469         to_eventlog = autocvar_sv_eventlog;
1470         to_file = autocvar_sv_logscores_file;
1471
1472         if(!final)
1473         {
1474                 to_console = TRUE; // always print printstats replies
1475                 to_eventlog = FALSE; // but never print them to the event log
1476         }
1477
1478         if(to_eventlog)
1479                 if(autocvar_sv_eventlog_console)
1480                         to_console = FALSE; // otherwise we get the output twice
1481
1482         if(final)
1483                 s = ":scores:";
1484         else
1485                 s = ":status:";
1486         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1487
1488         if(to_console)
1489                 print(s, "\n");
1490         if(to_eventlog)
1491                 GameLogEcho(s);
1492         if(to_file)
1493         {
1494                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1495                 if(file == -1)
1496                         to_file = FALSE;
1497                 else
1498                         fputs(file, strcat(s, "\n"));
1499         }
1500
1501         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1502         if(to_console)
1503                 print(s, "\n");
1504         if(to_eventlog)
1505                 GameLogEcho(s);
1506         if(to_file)
1507                 fputs(file, strcat(s, "\n"));
1508
1509         FOR_EACH_CLIENT(other)
1510         {
1511                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1512                 {
1513                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1514                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1515                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1516                                 s = strcat(s, ftos(other.team), ":");
1517                         else
1518                                 s = strcat(s, "spectator:");
1519
1520                         if(to_console)
1521                                 print(s, other.netname, "\n");
1522                         if(to_eventlog)
1523                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1524                         if(to_file)
1525                                 fputs(file, strcat(s, other.netname, "\n"));
1526                 }
1527         }
1528
1529         if(teamplay)
1530         {
1531                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1532                 if(to_console)
1533                         print(s, "\n");
1534                 if(to_eventlog)
1535                         GameLogEcho(s);
1536                 if(to_file)
1537                         fputs(file, strcat(s, "\n"));
1538
1539                 for(i = 1; i < 16; ++i)
1540                 {
1541                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1542                         s = strcat(s, ":", ftos(i));
1543                         if(to_console)
1544                                 print(s, "\n");
1545                         if(to_eventlog)
1546                                 GameLogEcho(s);
1547                         if(to_file)
1548                                 fputs(file, strcat(s, "\n"));
1549                 }
1550         }
1551
1552         if(to_console)
1553                 print(":end\n");
1554         if(to_eventlog)
1555                 GameLogEcho(":end");
1556         if(to_file)
1557         {
1558                 fputs(file, ":end\n");
1559                 fclose(file);
1560         }
1561 }
1562
1563 void FixIntermissionClient(entity e)
1564 {
1565         string s;
1566         if(!e.autoscreenshot) // initial call
1567         {
1568                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1569                 e.health = -2342;
1570                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1571                 e.solid = SOLID_NOT;
1572                 e.movetype = MOVETYPE_NONE;
1573                 e.takedamage = DAMAGE_NO;
1574                 if(e.weaponentity)
1575                 {
1576                         e.weaponentity.effects = EF_NODRAW;
1577                         if (e.weaponentity.weaponentity)
1578                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1579                 }
1580                 if(clienttype(e) == CLIENTTYPE_REAL)
1581                 {
1582                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1583                         s = autocvar_sv_intermission_cdtrack;
1584                         if(s != "")
1585                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1586                         msg_entity = e;
1587                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1588                 }
1589         }
1590 }
1591
1592
1593 /*
1594 go to the next level for deathmatch
1595 only called if a time or frag limit has expired
1596 */
1597 void NextLevel()
1598 {
1599         gameover = TRUE;
1600
1601         intermission_running = 1;
1602
1603 // enforce a wait time before allowing changelevel
1604         if(player_count > 0)
1605                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1606         else
1607                 intermission_exittime = -1;
1608
1609         /*
1610         WriteByte (MSG_ALL, SVC_CDTRACK);
1611         WriteByte (MSG_ALL, 3);
1612         WriteByte (MSG_ALL, 3);
1613         // done in FixIntermission
1614         */
1615
1616         //pos = FindIntermission ();
1617
1618         VoteReset();
1619
1620         DumpStats(TRUE);
1621
1622         // send statistics
1623         entity e;
1624         PlayerStats_EndMatch(1);
1625         FOR_EACH_CLIENT(e)
1626                 PlayerStats_AddGlobalInfo(e);
1627         PlayerStats_Shutdown();
1628         WeaponStats_Shutdown();
1629
1630         if(autocvar_sv_eventlog)
1631                 GameLogEcho(":gameover");
1632
1633         GameLogClose();
1634
1635         FOR_EACH_PLAYER(other) {
1636                 FixIntermissionClient(other);
1637                 if(other.winning)
1638                         bprint(other.netname, " ^7wins.\n");
1639         }
1640
1641         if(autocvar_g_campaign)
1642                 CampaignPreIntermission();
1643
1644         localcmd("\nsv_hook_gameend\n");
1645 }
1646
1647 /*
1648 ============
1649 CheckRules_Player
1650
1651 Exit deathmatch games upon conditions
1652 ============
1653 */
1654 void CheckRules_Player()
1655 {
1656         if (gameover)   // someone else quit the game already
1657                 return;
1658
1659         if(self.deadflag == DEAD_NO)
1660                 self.play_time += frametime;
1661
1662         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1663         //   (div0: and that in CheckRules_World please)
1664 }
1665
1666 float checkrules_equality;
1667 float checkrules_suddendeathwarning;
1668 float checkrules_suddendeathend;
1669 float checkrules_overtimesadded; //how many overtimes have been already added
1670
1671 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1672 float WINNING_YES = 1; // winner found
1673 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1674 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1675
1676 float InitiateSuddenDeath()
1677 {
1678         // Check first whether normal overtimes could be added before initiating suddendeath mode
1679         // - for this timelimit_overtime needs to be >0 of course
1680         // - also check the winning condition calculated in the previous frame and only add normal overtime
1681         //   again, if at the point at which timelimit would be extended again, still no winner was found
1682         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1683         {
1684                 return 1; // need to call InitiateOvertime later
1685         }
1686         else
1687         {
1688                 if(!checkrules_suddendeathend)
1689                 {
1690                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1691                         if(g_race && !g_race_qualifying)
1692                                 race_StartCompleting();
1693                 }
1694                 return 0;
1695         }
1696 }
1697
1698 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1699 {
1700         ++checkrules_overtimesadded;
1701         //add one more overtime by simply extending the timelimit
1702         float tl;
1703         tl = autocvar_timelimit;
1704         tl += autocvar_timelimit_overtime;
1705         cvar_set("timelimit", ftos(tl));
1706         string minutesPlural;
1707         if (autocvar_timelimit_overtime == 1)
1708                 minutesPlural = " ^3minute";
1709         else
1710                 minutesPlural = " ^3minutes";
1711
1712         bcenterprint(
1713                 strcat(
1714                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1715                         ftos(autocvar_timelimit_overtime),
1716                         minutesPlural,
1717                         " to the game!"
1718                 )
1719         );
1720 }
1721
1722 float GetWinningCode(float fraglimitreached, float equality)
1723 {
1724         if(autocvar_g_campaign == 1)
1725                 if(fraglimitreached)
1726                         return WINNING_YES;
1727                 else
1728                         return WINNING_NO;
1729
1730         else
1731                 if(equality)
1732                         if(fraglimitreached)
1733                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1734                         else
1735                                 return WINNING_NEVER;
1736                 else
1737                         if(fraglimitreached)
1738                                 return WINNING_YES;
1739                         else
1740                                 return WINNING_NO;
1741 }
1742
1743 // set the .winning flag for exactly those players with a given field value
1744 void SetWinners(.float field, float value)
1745 {
1746         entity head;
1747         FOR_EACH_PLAYER(head)
1748                 head.winning = (head.field == value);
1749 }
1750
1751 // set the .winning flag for those players with a given field value
1752 void AddWinners(.float field, float value)
1753 {
1754         entity head;
1755         FOR_EACH_PLAYER(head)
1756                 if(head.field == value)
1757                         head.winning = 1;
1758 }
1759
1760 // clear the .winning flags
1761 void ClearWinners(void)
1762 {
1763         entity head;
1764         FOR_EACH_PLAYER(head)
1765                 head.winning = 0;
1766 }
1767
1768 // Onslaught winning condition:
1769 // game terminates if only one team has a working generator (or none)
1770 float WinningCondition_Onslaught()
1771 {
1772         entity head;
1773         float t1, t2, t3, t4;
1774
1775         WinningConditionHelper(); // set worldstatus
1776
1777         if(inWarmupStage)
1778                 return WINNING_NO;
1779
1780         // first check if the game has ended
1781         t1 = t2 = t3 = t4 = 0;
1782         head = find(world, classname, "onslaught_generator");
1783         while (head)
1784         {
1785                 if (head.health > 0)
1786                 {
1787                         if (head.team == COLOR_TEAM1) t1 = 1;
1788                         if (head.team == COLOR_TEAM2) t2 = 1;
1789                         if (head.team == COLOR_TEAM3) t3 = 1;
1790                         if (head.team == COLOR_TEAM4) t4 = 1;
1791                 }
1792                 head = find(head, classname, "onslaught_generator");
1793         }
1794         if (t1 + t2 + t3 + t4 < 2)
1795         {
1796                 // game over, only one team remains (or none)
1797                 ClearWinners();
1798                 if (t1) SetWinners(team, COLOR_TEAM1);
1799                 if (t2) SetWinners(team, COLOR_TEAM2);
1800                 if (t3) SetWinners(team, COLOR_TEAM3);
1801                 if (t4) SetWinners(team, COLOR_TEAM4);
1802                 dprint("Have a winner, ending game.\n");
1803                 return WINNING_YES;
1804         }
1805
1806         // Two or more teams remain
1807         return WINNING_NO;
1808 }
1809
1810 float LMS_NewPlayerLives()
1811 {
1812         float fl;
1813         fl = autocvar_fraglimit;
1814         if(fl == 0)
1815                 fl = 999;
1816
1817         // first player has left the game for dying too much? Nobody else can get in.
1818         if(lms_lowest_lives < 1)
1819                 return 0;
1820
1821         if(!autocvar_g_lms_join_anytime)
1822                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1823                         return 0;
1824
1825         return bound(1, lms_lowest_lives, fl);
1826 }
1827
1828 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1829 // they win. Otherwise the defending team wins once the timelimit passes.
1830 void assault_new_round();
1831 float WinningCondition_Assault()
1832 {
1833         float status;
1834
1835         WinningConditionHelper(); // set worldstatus
1836
1837         status = WINNING_NO;
1838         // as the timelimit has not yet passed just assume the defending team will win
1839         if(assault_attacker_team == COLOR_TEAM1)
1840         {
1841                 SetWinners(team, COLOR_TEAM2);
1842         }
1843         else
1844         {
1845                 SetWinners(team, COLOR_TEAM1);
1846         }
1847
1848         entity ent;
1849         ent = find(world, classname, "target_assault_roundend");
1850         if(ent)
1851         {
1852                 if(ent.winning) // round end has been triggered by attacking team
1853                 {
1854                         bprint("ASSAULT: round completed...\n");
1855                         SetWinners(team, assault_attacker_team);
1856
1857                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1858
1859                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1860                         {
1861                                 status = WINNING_YES;
1862                         }
1863                         else
1864                         {
1865                                 entity oldself;
1866                                 oldself = self;
1867                                 self = ent;
1868                                 assault_new_round();
1869                                 self = oldself;
1870                         }
1871                 }
1872         }
1873
1874         return status;
1875 }
1876
1877 // LMS winning condition: game terminates if and only if there's at most one
1878 // one player who's living lives. Top two scores being equal cancels the time
1879 // limit.
1880 float WinningCondition_LMS()
1881 {
1882         entity head, head2;
1883         float have_player;
1884         float have_players;
1885         float l;
1886
1887         have_player = FALSE;
1888         have_players = FALSE;
1889         l = LMS_NewPlayerLives();
1890
1891         head = find(world, classname, "player");
1892         if(head)
1893                 have_player = TRUE;
1894         head2 = find(head, classname, "player");
1895         if(head2)
1896                 have_players = TRUE;
1897
1898         if(have_player)
1899         {
1900                 // we have at least one player
1901                 if(have_players)
1902                 {
1903                         // two or more active players - continue with the game
1904                 }
1905                 else
1906                 {
1907                         // exactly one player?
1908
1909                         ClearWinners();
1910                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1911
1912                         if(l)
1913                         {
1914                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1915                                 return WINNING_NO;
1916                         }
1917                         else
1918                         {
1919                                 // a winner!
1920                                 // and assign him his first place
1921                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1922                                 return WINNING_YES;
1923                         }
1924                 }
1925         }
1926         else
1927         {
1928                 // nobody is playing at all...
1929                 if(l)
1930                 {
1931                         // wait for players...
1932                 }
1933                 else
1934                 {
1935                         // SNAFU (maybe a draw game?)
1936                         ClearWinners();
1937                         dprint("No players, ending game.\n");
1938                         return WINNING_YES;
1939                 }
1940         }
1941
1942         // When we get here, we have at least two players who are actually LIVING,
1943         // now check if the top two players have equal score.
1944         WinningConditionHelper();
1945
1946         ClearWinners();
1947         if(WinningConditionHelper_winner)
1948                 WinningConditionHelper_winner.winning = TRUE;
1949         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1950                 return WINNING_NEVER;
1951
1952         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1953         return WINNING_NO;
1954 }
1955
1956 void ShuffleMaplist()
1957 {
1958         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1959 }
1960
1961 float leaderfrags;
1962 float WinningCondition_Scores(float limit, float leadlimit)
1963 {
1964         float limitreached;
1965
1966         // TODO make everything use THIS winning condition (except LMS)
1967         WinningConditionHelper();
1968
1969         if(teamplay)
1970         {
1971                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1972                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1973                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1974                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1975         }
1976
1977         ClearWinners();
1978         if(WinningConditionHelper_winner)
1979                 WinningConditionHelper_winner.winning = 1;
1980         if(WinningConditionHelper_winnerteam >= 0)
1981                 SetWinners(team, WinningConditionHelper_winnerteam);
1982
1983         if(WinningConditionHelper_lowerisbetter)
1984         {
1985                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1986                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1987                 limit = -limit;
1988         }
1989
1990         if(WinningConditionHelper_zeroisworst)
1991                 leadlimit = 0; // not supported in this mode
1992
1993         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1994         // these modes always score in increments of 1, thus this makes sense
1995         {
1996                 if(leaderfrags != WinningConditionHelper_topscore)
1997                 {
1998                         leaderfrags = WinningConditionHelper_topscore;
1999
2000                         if (limit)
2001                         if (leaderfrags == limit - 1)
2002                                 Announce("1fragleft");
2003                         else if (leaderfrags == limit - 2)
2004                                 Announce("2fragsleft");
2005                         else if (leaderfrags == limit - 3)
2006                                 Announce("3fragsleft");
2007                 }
2008         }
2009
2010         limitreached = FALSE;
2011         if(limit)
2012                 if(WinningConditionHelper_topscore >= limit)
2013                         limitreached = TRUE;
2014         if(leadlimit)
2015         {
2016                 float leadlimitreached;
2017                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
2018                 if(autocvar_leadlimit_and_fraglimit)
2019                         limitreached = (limitreached && leadlimitreached);
2020                 else
2021                         limitreached = (limitreached || leadlimitreached);
2022         }
2023
2024         return GetWinningCode(
2025                 WinningConditionHelper_topscore && limitreached,
2026                 WinningConditionHelper_equality
2027         );
2028 }
2029
2030 float WinningCondition_Race(float fraglimit)
2031 {
2032         float wc;
2033         entity p;
2034         float n, c;
2035
2036         n = 0;
2037         c = 0;
2038         FOR_EACH_PLAYER(p)
2039         {
2040                 ++n;
2041                 if(p.race_completed)
2042                         ++c;
2043         }
2044         if(n && (n == c))
2045                 return WINNING_YES;
2046         wc = WinningCondition_Scores(fraglimit, 0);
2047
2048         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2049         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2050         // do NOT support equality when the laps are all raced!
2051                 return WINNING_STARTSUDDENDEATHOVERTIME;
2052         else
2053                 return WINNING_NEVER;
2054         return wc;
2055 }
2056
2057 void ReadyRestart();
2058 float WinningCondition_QualifyingThenRace(float limit)
2059 {
2060         float wc;
2061         wc = WinningCondition_Scores(limit, 0);
2062
2063         // NEVER initiate overtime
2064         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2065         {
2066                 return WINNING_YES;
2067         }
2068
2069         return wc;
2070 }
2071
2072 float WinningCondition_RanOutOfSpawns()
2073 {
2074         entity head;
2075
2076         if(have_team_spawns <= 0)
2077                 return WINNING_NO;
2078
2079         if(autocvar_g_spawn_useallspawns <= 0)
2080                 return WINNING_NO;
2081
2082         if(!some_spawn_has_been_used)
2083                 return WINNING_NO;
2084
2085         team1_score = team2_score = team3_score = team4_score = 0;
2086
2087         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2088         {
2089                 if(head.team == COLOR_TEAM1)
2090                         team1_score = 1;
2091                 else if(head.team == COLOR_TEAM2)
2092                         team2_score = 1;
2093                 else if(head.team == COLOR_TEAM3)
2094                         team3_score = 1;
2095                 else if(head.team == COLOR_TEAM4)
2096                         team4_score = 1;
2097         }
2098
2099         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2100         {
2101                 if(head.team == COLOR_TEAM1)
2102                         team1_score = 1;
2103                 else if(head.team == COLOR_TEAM2)
2104                         team2_score = 1;
2105                 else if(head.team == COLOR_TEAM3)
2106                         team3_score = 1;
2107                 else if(head.team == COLOR_TEAM4)
2108                         team4_score = 1;
2109         }
2110
2111         ClearWinners();
2112         if(team1_score + team2_score + team3_score + team4_score == 0)
2113         {
2114                 checkrules_equality = TRUE;
2115                 return WINNING_YES;
2116         }
2117         else if(team1_score + team2_score + team3_score + team4_score == 1)
2118         {
2119                 float t, i;
2120                 if(team1_score) t = COLOR_TEAM1;
2121                 if(team2_score) t = COLOR_TEAM2;
2122                 if(team3_score) t = COLOR_TEAM3;
2123                 if(team4_score) t = COLOR_TEAM4;
2124                 CheckAllowedTeams(world);
2125                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2126                 {
2127                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2128                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2129                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2130                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2131                 }
2132
2133                 AddWinners(team, t);
2134                 return WINNING_YES;
2135         }
2136         else
2137                 return WINNING_NO;
2138 }
2139
2140 /*
2141 ============
2142 CheckRules_World
2143
2144 Exit deathmatch games upon conditions
2145 ============
2146 */
2147 void CheckRules_World()
2148 {
2149         float timelimit;
2150         float fraglimit;
2151         float leadlimit;
2152
2153         VoteThink();
2154         MapVote_Think();
2155
2156         SetDefaultAlpha();
2157
2158         /*
2159         MapVote_Think should now do that part
2160         if (intermission_running)
2161                 if (time >= intermission_exittime + 60)
2162                 {
2163                         if(!DoNextMapOverride())
2164                                 GotoNextMap();
2165                         return;
2166                 }
2167         */
2168
2169         if (gameover)   // someone else quit the game already
2170         {
2171                 if(player_count == 0) // Nobody there? Then let's go to the next map
2172                         MapVote_Start();
2173                         // this will actually check the player count in the next frame
2174                         // again, but this shouldn't hurt
2175                 return;
2176         }
2177
2178         timelimit = autocvar_timelimit * 60;
2179         fraglimit = autocvar_fraglimit;
2180         leadlimit = autocvar_leadlimit;
2181
2182         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2183         {
2184                 if(timelimit > 0)
2185                         timelimit = 0; // timelimit is not made for warmup
2186                 if(fraglimit > 0)
2187                         fraglimit = 0; // no fraglimit for now
2188                 leadlimit = 0; // no leadlimit for now
2189         }
2190
2191         if(g_onslaught)
2192                 timelimit = 0; // ONS has its own overtime rule
2193
2194         if(timelimit > 0)
2195         {
2196                 timelimit += game_starttime;
2197         }
2198         else if (timelimit < 0)
2199         {
2200                 // endmatch
2201                 NextLevel();
2202                 return;
2203         }
2204
2205         float wantovertime;
2206         wantovertime = 0;
2207
2208         if(checkrules_suddendeathend)
2209         {
2210                 if(!checkrules_suddendeathwarning)
2211                 {
2212                         checkrules_suddendeathwarning = TRUE;
2213                         if(g_race && !g_race_qualifying)
2214                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2215                         else
2216                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2217                 }
2218         }
2219         else
2220         {
2221                 if (timelimit && time >= timelimit)
2222                 {
2223                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2224                         {
2225                                 float totalplayers;
2226                                 float playerswithlaps;
2227                                 float readyplayers;
2228                                 entity head;
2229                                 totalplayers = playerswithlaps = readyplayers = 0;
2230                                 FOR_EACH_PLAYER(head)
2231                                 {
2232                                         ++totalplayers;
2233                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2234                                                 ++playerswithlaps;
2235                                         if(head.ready)
2236                                                 ++readyplayers;
2237                                 }
2238
2239                                 // at least 2 of the players have completed a lap: start the RACE
2240                                 // otherwise, the players should end the qualifying on their own
2241                                 if(readyplayers || playerswithlaps >= 2)
2242                                 {
2243                                         checkrules_suddendeathend = 0;
2244                                         ReadyRestart(); // go to race
2245                                         return;
2246                                 }
2247                                 else
2248                                         wantovertime |= InitiateSuddenDeath();
2249                         }
2250                         else
2251                                 wantovertime |= InitiateSuddenDeath();
2252                 }
2253         }
2254
2255         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2256         {
2257                 NextLevel();
2258                 return;
2259         }
2260
2261         float checkrules_status;
2262         checkrules_status = WinningCondition_RanOutOfSpawns();
2263         if(checkrules_status == WINNING_YES)
2264         {
2265                 bprint("Hey! Someone ran out of spawns!\n");
2266         }
2267         else if(g_race && !g_race_qualifying && timelimit >= 0)
2268         {
2269                 checkrules_status = WinningCondition_Race(fraglimit);
2270                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2271         }
2272         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2273         {
2274                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2275                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2276         }
2277         else if(g_assault)
2278         {
2279                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2280         }
2281         else if(g_lms)
2282         {
2283                 checkrules_status = WinningCondition_LMS();
2284         }
2285         else if (g_onslaught)
2286         {
2287                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2288         }
2289         else
2290         {
2291                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2292                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2293         }
2294
2295         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2296         {
2297                 checkrules_status = WINNING_NEVER;
2298                 checkrules_overtimesadded = -1;
2299                 wantovertime |= InitiateSuddenDeath();
2300         }
2301
2302         if(checkrules_status == WINNING_NEVER)
2303                 // equality cases! Nobody wins if the overtime ends in a draw.
2304                 ClearWinners();
2305
2306         if(wantovertime)
2307         {
2308                 if(checkrules_status == WINNING_NEVER)
2309                         InitiateOvertime();
2310                 else
2311                         checkrules_status = WINNING_YES;
2312         }
2313
2314         if(checkrules_suddendeathend)
2315                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2316                         checkrules_status = WINNING_YES;
2317
2318         if(checkrules_status == WINNING_YES)
2319         {
2320                 //print("WINNING\n");
2321                 NextLevel();
2322         }
2323 }
2324
2325 float mapvote_nextthink;
2326 float mapvote_initialized;
2327 float mapvote_keeptwotime;
2328 float mapvote_timeout;
2329 string mapvote_message;
2330 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2331 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2332 float mapvote_screenshot_dirs_count;
2333
2334 float mapvote_count;
2335 float mapvote_count_real;
2336 string mapvote_maps[MAPVOTE_COUNT];
2337 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2338 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2339 float mapvote_maps_suggested[MAPVOTE_COUNT];
2340 string mapvote_suggestions[MAPVOTE_COUNT];
2341 float mapvote_suggestion_ptr;
2342 float mapvote_voters;
2343 float mapvote_votes[MAPVOTE_COUNT];
2344 float mapvote_run;
2345 float mapvote_detail;
2346 float mapvote_abstain;
2347 .float mapvote;
2348
2349 void MapVote_ClearAllVotes()
2350 {
2351         FOR_EACH_CLIENT(other)
2352                 other.mapvote = 0;
2353 }
2354
2355 string MapVote_Suggest(string m)
2356 {
2357         float i;
2358         if(m == "")
2359                 return "That's not how to use this command.";
2360         if(!autocvar_g_maplist_votable_suggestions)
2361                 return "Suggestions are not accepted on this server.";
2362         if(mapvote_initialized)
2363                 return "Can't suggest - voting is already in progress!";
2364         m = MapInfo_FixName(m);
2365         if(!m)
2366                 return "The map you suggested is not available on this server.";
2367         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2368                 if(Map_IsRecent(m))
2369                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2370
2371         if(!MapInfo_CheckMap(m))
2372                 return "The map you suggested does not support the current game mode.";
2373         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2374                 if(mapvote_suggestions[i] == m)
2375                         return "This map was already suggested.";
2376         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2377         {
2378                 i = floor(random() * mapvote_suggestion_ptr);
2379         }
2380         else
2381         {
2382                 i = mapvote_suggestion_ptr;
2383                 mapvote_suggestion_ptr += 1;
2384         }
2385         if(mapvote_suggestions[i] != "")
2386                 strunzone(mapvote_suggestions[i]);
2387         mapvote_suggestions[i] = strzone(m);
2388         if(autocvar_sv_eventlog)
2389                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2390         return strcat("Suggestion of ", m, " accepted.");
2391 }
2392
2393 void MapVote_AddVotable(string nextMap, float isSuggestion)
2394 {
2395         float j, i, o;
2396         string pakfile, mapfile;
2397
2398         if(nextMap == "")
2399                 return;
2400         for(j = 0; j < mapvote_count; ++j)
2401                 if(mapvote_maps[j] == nextMap)
2402                         return;
2403         // suggestions might be no longer valid/allowed after gametype switch!
2404         if(isSuggestion)
2405                 if(!MapInfo_CheckMap(nextMap))
2406                         return;
2407         mapvote_maps[mapvote_count] = strzone(nextMap);
2408         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2409
2410         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2411         {
2412                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2413                 pakfile = whichpack(strcat(mapfile, ".tga"));
2414                 if(pakfile == "")
2415                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2416                 if(pakfile == "")
2417                         pakfile = whichpack(strcat(mapfile, ".png"));
2418                 if(pakfile != "")
2419                         break;
2420         }
2421         if(i >= mapvote_screenshot_dirs_count)
2422                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2423         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2424                 pakfile = substring(pakfile, o, -1);
2425
2426         mapvote_maps_screenshot_dir[mapvote_count] = i;
2427         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2428
2429         mapvote_count += 1;
2430 }
2431
2432 void MapVote_Spawn();
2433 void MapVote_Init()
2434 {
2435         float i;
2436         float nmax, smax;
2437
2438         MapVote_ClearAllVotes();
2439
2440         mapvote_count = 0;
2441         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2442         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2443
2444         if(mapvote_abstain)
2445                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2446         else
2447                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2448         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2449
2450         // we need this for AddVotable, as that cycles through the screenshot dirs
2451         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2452         if(mapvote_screenshot_dirs_count == 0)
2453                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2454         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2455         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2456                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2457
2458         if(mapvote_suggestion_ptr)
2459                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2460                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2461
2462         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2463                 MapVote_AddVotable(GetNextMap(), FALSE);
2464
2465         if(mapvote_count == 0)
2466         {
2467                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2468                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2469                 if(autocvar_g_maplist_shuffle)
2470                         ShuffleMaplist();
2471                 localcmd("\nmenu_cmd sync\n");
2472                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2473                         MapVote_AddVotable(GetNextMap(), FALSE);
2474         }
2475
2476         mapvote_count_real = mapvote_count;
2477         if(mapvote_abstain)
2478                 MapVote_AddVotable("don't care", 0);
2479
2480         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2481
2482         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2483         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2484         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2485                 mapvote_keeptwotime = 0;
2486         mapvote_message = "Choose a map and press its key!";
2487
2488         MapVote_Spawn();
2489 }
2490
2491 void MapVote_SendPicture(float id)
2492 {
2493         msg_entity = self;
2494         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2495         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2496         WriteByte(MSG_ONE, id);
2497         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2498 }
2499
2500 float GameCommand_MapVote(string cmd)
2501 {
2502         if(!intermission_running)
2503                 return FALSE;
2504
2505         if(cmd == "mv_getpic")
2506         {
2507                 MapVote_SendPicture(stof(argv(1)));
2508                 return TRUE;
2509         }
2510
2511         return FALSE;
2512 }
2513
2514 float MapVote_GetMapMask()
2515 {
2516         float mask, i, power;
2517         mask = 0;
2518         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2519                 if(mapvote_maps[i] != "")
2520                         mask |= power;
2521         return mask;
2522 }
2523
2524 entity mapvote_ent;
2525 float MapVote_SendEntity(entity to, float sf)
2526 {
2527         float i;
2528
2529         if(sf & 1)
2530                 sf &~= 2; // if we send 1, we don't need to also send 2
2531
2532         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2533         WriteByte(MSG_ENTITY, sf);
2534
2535         if(sf & 1)
2536         {
2537                 // flag 1 == initialization
2538                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2539                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2540                 WriteString(MSG_ENTITY, "");
2541                 WriteByte(MSG_ENTITY, mapvote_count);
2542                 WriteByte(MSG_ENTITY, mapvote_abstain);
2543                 WriteByte(MSG_ENTITY, mapvote_detail);
2544                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2545                 if(mapvote_count <= 8)
2546                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2547                 else
2548                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2549                 for(i = 0; i < mapvote_count; ++i)
2550                         if(mapvote_maps[i] != "")
2551                         {
2552                                 if(mapvote_abstain && i == mapvote_count - 1)
2553                                 {
2554                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2555                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2556                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2557                                 }
2558                                 else
2559                                 {
2560                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2561                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2562                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2563                                 }
2564                         }
2565         }
2566
2567         if(sf & 2)
2568         {
2569                 // flag 2 == update of mask
2570                 if(mapvote_count <= 8)
2571                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2572                 else
2573                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2574         }
2575
2576         if(sf & 4)
2577         {
2578                 if(mapvote_detail)
2579                         for(i = 0; i < mapvote_count; ++i)
2580                                 if(mapvote_maps[i] != "")
2581                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2582
2583                 WriteByte(MSG_ENTITY, to.mapvote);
2584         }
2585
2586         return TRUE;
2587 }
2588
2589 void MapVote_Spawn()
2590 {
2591         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2592 }
2593
2594 void MapVote_TouchMask()
2595 {
2596         mapvote_ent.SendFlags |= 2;
2597 }
2598
2599 void MapVote_TouchVotes(entity voter)
2600 {
2601         mapvote_ent.SendFlags |= 4;
2602 }
2603
2604 float MapVote_Finished(float mappos)
2605 {
2606         string result;
2607         float i;
2608         float didntvote;
2609
2610         if(autocvar_sv_eventlog)
2611         {
2612                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2613                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2614                 didntvote = mapvote_voters;
2615                 for(i = 0; i < mapvote_count; ++i)
2616                         if(mapvote_maps[i] != "")
2617                         {
2618                                 didntvote -= mapvote_votes[i];
2619                                 if(i != mappos)
2620                                 {
2621                                         result = strcat(result, ":", mapvote_maps[i]);
2622                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2623                                 }
2624                         }
2625                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2626
2627                 GameLogEcho(result);
2628                 if(mapvote_maps_suggested[mappos])
2629                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2630         }
2631
2632         FOR_EACH_REALCLIENT(other)
2633                 FixClientCvars(other);
2634
2635         Map_Goto_SetStr(mapvote_maps[mappos]);
2636         Map_Goto(0);
2637         alreadychangedlevel = TRUE;
2638         return TRUE;
2639 }
2640 void MapVote_CheckRules_1()
2641 {
2642         float i;
2643
2644         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2645         {
2646                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2647                 mapvote_votes[i] = 0;
2648         }
2649
2650         mapvote_voters = 0;
2651         FOR_EACH_REALCLIENT(other)
2652         {
2653                 ++mapvote_voters;
2654                 if(other.mapvote)
2655                 {
2656                         i = other.mapvote - 1;
2657                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2658                         mapvote_votes[i] = mapvote_votes[i] + 1;
2659                 }
2660         }
2661 }
2662
2663 float MapVote_CheckRules_2()
2664 {
2665         float i;
2666         float firstPlace, secondPlace;
2667         float firstPlaceVotes, secondPlaceVotes;
2668         float mapvote_voters_real;
2669         string result;
2670
2671         if(mapvote_count_real == 1)
2672                 return MapVote_Finished(0);
2673
2674         mapvote_voters_real = mapvote_voters;
2675         if(mapvote_abstain)
2676                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2677
2678         RandomSelection_Init();
2679         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2680                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2681         firstPlace = RandomSelection_chosen_float;
2682         firstPlaceVotes = RandomSelection_best_priority;
2683         //dprint("First place: ", ftos(firstPlace), "\n");
2684         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2685
2686         RandomSelection_Init();
2687         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2688                 if(i != firstPlace)
2689                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2690         secondPlace = RandomSelection_chosen_float;
2691         secondPlaceVotes = RandomSelection_best_priority;
2692         //dprint("Second place: ", ftos(secondPlace), "\n");
2693         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2694
2695         if(firstPlace == -1)
2696                 error("No first place in map vote... WTF?");
2697
2698         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2699                 return MapVote_Finished(firstPlace);
2700
2701         if(mapvote_keeptwotime)
2702                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2703                 {
2704                         float didntvote;
2705                         MapVote_TouchMask();
2706                         mapvote_message = "Now decide between the TOP TWO!";
2707                         mapvote_keeptwotime = 0;
2708                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2709                         result = strcat(result, ":", ftos(firstPlaceVotes));
2710                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2711                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2712                         didntvote = mapvote_voters;
2713                         for(i = 0; i < mapvote_count; ++i)
2714                                 if(mapvote_maps[i] != "")
2715                                 {
2716                                         didntvote -= mapvote_votes[i];
2717                                         if(i != firstPlace)
2718                                                 if(i != secondPlace)
2719                                                 {
2720                                                         result = strcat(result, ":", mapvote_maps[i]);
2721                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2722                                                         if(i < mapvote_count_real)
2723                                                         {
2724                                                                 strunzone(mapvote_maps[i]);
2725                                                                 mapvote_maps[i] = "";
2726                                                                 strunzone(mapvote_maps_pakfile[i]);
2727                                                                 mapvote_maps_pakfile[i] = "";
2728                                                         }
2729                                                 }
2730                                 }
2731                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2732                         if(autocvar_sv_eventlog)
2733                                 GameLogEcho(result);
2734                 }
2735
2736         return FALSE;
2737 }
2738 void MapVote_Tick()
2739 {
2740         float keeptwo;
2741         float totalvotes;
2742
2743         keeptwo = mapvote_keeptwotime;
2744         MapVote_CheckRules_1(); // count
2745         if(MapVote_CheckRules_2()) // decide
2746                 return;
2747
2748         totalvotes = 0;
2749         FOR_EACH_REALCLIENT(other)
2750         {
2751                 // hide scoreboard again
2752                 if(other.health != 2342)
2753                 {
2754                         other.health = 2342;
2755                         other.impulse = 0;
2756                         if(clienttype(other) == CLIENTTYPE_REAL)
2757                         {
2758                                 msg_entity = other;
2759                                 WriteByte(MSG_ONE, SVC_FINALE);
2760                                 WriteString(MSG_ONE, "");
2761                         }
2762                 }
2763
2764                 // clear possibly invalid votes
2765                 if(mapvote_maps[other.mapvote - 1] == "")
2766                         other.mapvote = 0;
2767                 // use impulses as new vote
2768                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2769                         if(mapvote_maps[other.impulse - 1] != "")
2770                         {
2771                                 other.mapvote = other.impulse;
2772                                 MapVote_TouchVotes(other);
2773                         }
2774                 other.impulse = 0;
2775
2776                 if(other.mapvote)
2777                         ++totalvotes;
2778         }
2779
2780         MapVote_CheckRules_1(); // just count
2781 }
2782 void MapVote_Start()
2783 {
2784         if(mapvote_run)
2785                 return;
2786
2787         // wait for stats to be sent first
2788         if(!playerstats_waitforme)
2789                 return;
2790
2791         MapInfo_Enumerate();
2792         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2793                 mapvote_run = TRUE;
2794 }
2795 void MapVote_Think()
2796 {
2797         if(!mapvote_run)
2798                 return;
2799
2800         if(alreadychangedlevel)
2801                 return;
2802
2803         if(time < mapvote_nextthink)
2804                 return;
2805         //dprint("tick\n");
2806
2807         mapvote_nextthink = time + 0.5;
2808
2809         if(!mapvote_initialized)
2810         {
2811                 if(autocvar_rescan_pending == 1)
2812                 {
2813                         cvar_set("rescan_pending", "2");
2814                         localcmd("fs_rescan\nrescan_pending 3\n");
2815                         return;
2816                 }
2817                 else if(autocvar_rescan_pending == 2)
2818                 {
2819                         return;
2820                 }
2821                 else if(autocvar_rescan_pending == 3)
2822                 {
2823                         // now build missing mapinfo files
2824                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2825                                 return;
2826
2827                         // we're done, start the timer
2828                         cvar_set("rescan_pending", "0");
2829                 }
2830
2831                 mapvote_initialized = TRUE;
2832                 if(DoNextMapOverride(0))
2833                         return;
2834                 if(!autocvar_g_maplist_votable || player_count <= 0)
2835                 {
2836                         GotoNextMap(0);
2837                         return;
2838                 }
2839                 MapVote_Init();
2840         }
2841
2842         MapVote_Tick();
2843 }
2844
2845 string GotoMap(string m)
2846 {
2847         if(!MapInfo_CheckMap(m))
2848                 return "The map you chose is not available on this server.";
2849         cvar_set("nextmap", m);
2850         cvar_set("timelimit", "-1");
2851         if(mapvote_initialized || alreadychangedlevel)
2852         {
2853                 if(DoNextMapOverride(0))
2854                         return "Map switch initiated.";
2855                 else
2856                         return "Hm... no. For some reason I like THIS map more.";
2857         }
2858         else
2859                 return "Map switch will happen after scoreboard.";
2860 }
2861
2862
2863 void EndFrame()
2864 {
2865         float altime;
2866         FOR_EACH_REALCLIENT(self)
2867         {
2868                 if(self.classname == "spectator")
2869                 {
2870                         if(self.enemy.typehitsound)
2871                                 self.typehit_time = time;
2872                         else if(self.enemy.hitsound)
2873                                 self.hit_time = time;
2874                 }
2875                 else
2876                 {
2877                         if(self.typehitsound)
2878                                 self.typehit_time = time;
2879                         else if(self.hitsound)
2880                                 self.hit_time = time;
2881                 }
2882         }
2883         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2884         // add 1 frametime because after this, engine SV_Physics
2885         // increases time by a frametime and then networks the frame
2886         // add another frametime because client shows everything with
2887         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2888         // needed!
2889         FOR_EACH_CLIENT(self)
2890         {
2891                 self.hitsound = FALSE;
2892                 self.typehitsound = FALSE;
2893                 antilag_record(self, altime);
2894         }
2895 }
2896
2897
2898 /*
2899  * RedirectionThink:
2900  * returns TRUE if redirecting
2901  */
2902 float redirection_timeout;
2903 float redirection_nextthink;
2904 float RedirectionThink()
2905 {
2906         float clients_found;
2907
2908         if(redirection_target == "")
2909                 return FALSE;
2910
2911         if(!redirection_timeout)
2912         {
2913                 cvar_set("sv_public", "-2");
2914                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2915                 if(redirection_target == "self")
2916                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2917                 else
2918                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2919         }
2920
2921         if(time < redirection_nextthink)
2922                 return TRUE;
2923
2924         redirection_nextthink = time + 1;
2925
2926         clients_found = 0;
2927         FOR_EACH_REALCLIENT(self)
2928         {
2929                 print("Redirecting: sending connect command to ", self.netname, "\n");
2930                 if(redirection_target == "self")
2931                         stuffcmd(self, "\ndisconnect; reconnect\n");
2932                 else
2933                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2934                 ++clients_found;
2935         }
2936
2937         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2938
2939         if(time > redirection_timeout || clients_found == 0)
2940                 localcmd("\nwait; wait; wait; quit\n");
2941
2942         return TRUE;
2943 }
2944
2945 void TargetMusic_RestoreGame();
2946 void RestoreGame()
2947 {
2948         // Loaded from a save game
2949         // some things then break, so let's work around them...
2950
2951         // Progs DB (capture records)
2952         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2953
2954         // Mapinfo
2955         MapInfo_Shutdown();
2956         MapInfo_Enumerate();
2957         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2958         WeaponStats_Init();
2959
2960         TargetMusic_RestoreGame();
2961 }
2962
2963 void SV_Shutdown()
2964 {
2965         entity e;
2966
2967         if(gameover > 1) // shutting down already?
2968                 return;
2969
2970         gameover = 2; // 2 = server shutting down
2971
2972         if(world_initialized > 0)
2973         {
2974                 world_initialized = 0;
2975                 print("Saving persistent data...\n");
2976                 Ban_SaveBans();
2977
2978                 PlayerStats_EndMatch(0);
2979                 FOR_EACH_CLIENT(e)
2980                         PlayerStats_AddGlobalInfo(e);
2981                 PlayerStats_Shutdown();
2982
2983                 if(!cheatcount_total)
2984                 {
2985                         if(autocvar_sv_db_saveasdump)
2986                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2987                         else
2988                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2989                 }
2990                 if(autocvar_developer)
2991                 {
2992                         if(autocvar_sv_db_saveasdump)
2993                                 db_dump(TemporaryDB, "server-temp.db");
2994                         else
2995                                 db_save(TemporaryDB, "server-temp.db");
2996                 }
2997                 CheatShutdown(); // must be after cheatcount check
2998                 db_close(ServerProgsDB);
2999                 db_close(TemporaryDB);
3000                 print("done!\n");
3001                 // tell the bot system the game is ending now
3002                 bot_endgame();
3003
3004                 WeaponStats_Shutdown();
3005                 MapInfo_Shutdown();
3006         }
3007         else if(world_initialized == 0)
3008         {
3009                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
3010         }
3011 }