qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_assault");
 257                 BADCVAR("g_ca");
 258                 BADCVAR("g_ca_teams");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_freezetag_teams");
 266                 BADCVAR("g_keepaway");
 267                 BADCVAR("g_keyhunt");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_balance_kill_delay");
 307                 BADCVAR("g_ca_point_leadlimit");
 308                 BADCVAR("g_ctf_captimerecord_always");
 309                 BADCVAR("g_ctf_flag_glowtrails");
 310                 BADCVAR("g_ctf_flag_pickup_verbosename");
 311                 BADCVAR("g_domination_point_leadlimit");
 312                 BADCVAR("g_forced_respawn");
 313                 BADCVAR("g_keyhunt_point_leadlimit");
 314                 BADPREFIX("g_mod_");
 315                 BADCVAR("g_nexball_goalleadlimit");
 316                 BADCVAR("leadlimit_and_fraglimit");
 317                 BADCVAR("leadlimit_override");
 318                 BADCVAR("pausable");
 319                 BADCVAR("sv_allow_fullbright");
 320                 BADCVAR("sv_checkforpacketsduringsleep");
 321                 BADCVAR("sv_fraginfo");
 322                 BADCVAR("sv_timeout");
 323                 BADPREFIX("sv_timeout_");
 324                 BADPREFIX("crypto_");
 325                 BADPREFIX("g_chat_");
 326                 BADPREFIX("g_ctf_captimerecord_");
 327                 BADPREFIX("g_maplist_votable_");
 328                 BADPREFIX("net_");
 329                 BADPREFIX("prvm_");
 330                 BADPREFIX("skill_");
 331                 BADPREFIX("sv_cullentities_");
 332                 BADPREFIX("sv_fraginfo_");
 333                 BADPREFIX("sv_maxidle_");
 334                 BADPREFIX("sv_vote_");
 335                 BADPREFIX("timelimit_");
 336                 BADCVAR("gameversion");
 337                 BADPREFIX("gameversion_");
 338                 BADCVAR("sv_namechangetimer");
 339
 340                 // allowed changes to server admins (please sync this to server.cfg)
 341                 // vi commands:
 342                 //   :/"impure"/,$d
 343                 //   :g!,^\/\/[^ /],d
 344                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 345                 //   :%!sort
 346                 // yes, this does contain some redundant stuff, don't really care
 347                 BADCVAR("bot_config_file");
 348                 BADCVAR("bot_number");
 349                 BADCVAR("bot_prefix");
 350                 BADCVAR("bot_suffix");
 351                 BADCVAR("capturelimit_override");
 352                 BADCVAR("fraglimit_override");
 353                 BADCVAR("gametype");
 354                 BADCVAR("g_antilag");
 355                 BADCVAR("g_balance_teams");
 356                 BADCVAR("g_balance_teams_prevent_imbalance");
 357                 BADCVAR("g_balance_teams_scorefactor");
 358                 BADCVAR("g_ban_sync_trusted_servers");
 359                 BADCVAR("g_ban_sync_uri");
 360                 BADCVAR("g_ca_teams_override");
 361                 BADCVAR("g_ctf_ignore_frags");
 362                 BADCVAR("g_domination_point_limit");
 363                 BADCVAR("g_freezetag_teams_override");
 364                 BADCVAR("g_friendlyfire");
 365                 BADCVAR("g_fullbrightitems");
 366                 BADCVAR("g_fullbrightplayers");
 367                 BADCVAR("g_keyhunt_point_limit");
 368                 BADCVAR("g_keyhunt_teams_override");
 369                 BADCVAR("g_lms_lives_override");
 370                 BADCVAR("g_maplist");
 371                 BADCVAR("g_maplist_check_waypoints");
 372                 BADCVAR("g_maplist_mostrecent_count");
 373                 BADCVAR("g_maplist_shuffle");
 374                 BADCVAR("g_maplist_votable");
 375                 BADCVAR("g_maplist_votable_abstain");
 376                 BADCVAR("g_maplist_votable_nodetail");
 377                 BADCVAR("g_maplist_votable_suggestions");
 378                 BADCVAR("g_maxplayers");
 379                 BADCVAR("g_mirrordamage");
 380                 BADCVAR("g_nexball_goallimit");
 381                 BADCVAR("g_powerups");
 382                 BADCVAR("g_start_delay");
 383                 BADCVAR("g_warmup");
 384                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 385                 BADCVAR("hostname");
 386                 BADCVAR("log_file");
 387                 BADCVAR("maxplayers");
 388                 BADCVAR("minplayers");
 389                 BADCVAR("net_address");
 390                 BADCVAR("port");
 391                 BADCVAR("rcon_password");
 392                 BADCVAR("rcon_restricted_commands");
 393                 BADCVAR("rcon_restricted_password");
 394                 BADCVAR("skill");
 395                 BADCVAR("sv_adminnick");
 396                 BADCVAR("sv_autoscreenshot");
 397                 BADCVAR("sv_autotaunt");
 398                 BADCVAR("sv_curl_defaulturl");
 399                 BADCVAR("sv_defaultcharacter");
 400                 BADCVAR("sv_defaultplayercolors");
 401                 BADCVAR("sv_defaultplayermodel");
 402                 BADCVAR("sv_defaultplayerskin");
 403                 BADCVAR("sv_maxidle");
 404                 BADCVAR("sv_maxrate");
 405                 BADCVAR("sv_motd");
 406                 BADCVAR("sv_public");
 407                 BADCVAR("sv_ready_restart");
 408                 BADCVAR("sv_status_privacy");
 409                 BADCVAR("sv_taunt");
 410                 BADCVAR("sv_vote_call");
 411                 BADCVAR("sv_vote_commands");
 412                 BADCVAR("sv_vote_majority_factor");
 413                 BADCVAR("sv_vote_master");
 414                 BADCVAR("sv_vote_master_commands");
 415                 BADCVAR("sv_vote_master_password");
 416                 BADCVAR("sv_vote_simple_majority_factor");
 417                 BADCVAR("teamplay_mode");
 418                 BADCVAR("timelimit_override");
 419                 BADCVAR("g_spawnshieldtime");
 420                 BADPREFIX("g_warmup_");
 421                 BADPREFIX("sv_ready_restart_");
 422
 423                 // mutators that announce themselves properly to the server browser
 424                 BADCVAR("g_minstagib");
 425                 BADCVAR("g_new_toys");
 426                 BADCVAR("g_nix");
 427                 BADCVAR("g_grappling_hook");
 428                 BADCVAR("g_jetpack");
 429
 430 #undef BADPREFIX
 431 #undef BADCVAR
 432
 433                 if(pureadding)
 434                 {
 435                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 436                         if(strlen(cvar_purechanges) > 16384)
 437                         {
 438                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 439                                 pureadding = 0;
 440                         }
 441                 }
 442                 ++cvar_purechanges_count;
 443                 // WARNING: this variable is used for the server list
 444                 // NEVER dare to skip this code!
 445                 // Hacks to intentionally appearing as "pure server" even though you DO have
 446                 // modified settings may be punished by removal from the server list.
 447                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 448                 // though.
 449         }
 450         buf_del(h);
 451         if(cvar_changes == "")
 452                 cvar_changes = "// this server runs at default server settings\n";
 453         else
 454                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 455         cvar_changes = strzone(cvar_changes);
 456         if(cvar_purechanges == "")
 457                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 458         else
 459                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 460         cvar_purechanges = strzone(cvar_purechanges);
 461 }
 462
 463 void detect_maptype()
 464 {
 465 #if 0
 466         vector o, v;
 467         float i;
 468
 469         for(;;)
 470         {
 471                 o = world.mins;
 472                 o_x += random() * (world.maxs_x - world.mins_x);
 473                 o_y += random() * (world.maxs_y - world.mins_y);
 474                 o_z += random() * (world.maxs_z - world.mins_z);
 475
 476                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 477                 if(trace_fraction == 1)
 478                         continue;
 479
 480                 v = trace_endpos;
 481
 482                 for(i = 0; i < 64; i += 4)
 483                 {
 484                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 485         if(trace_fraction == 1)
 486                 continue;
 487                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 488                 }
 489
 490                 break;
 491         }
 492 #endif
 493 }
 494
 495 entity randomseed;
 496 float RandomSeed_Send(entity to, float sf)
 497 {
 498         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 499         WriteShort(MSG_ENTITY, self.cnt);
 500         return TRUE;
 501 }
 502 void RandomSeed_Think()
 503 {
 504         self.cnt = bound(0, floor(random() * 65536), 65535);
 505         self.nextthink = time + 5;
 506
 507         self.SendFlags |= 1;
 508 }
 509 void RandomSeed_Spawn()
 510 {
 511         randomseed = spawn();
 512         randomseed.think = RandomSeed_Think;
 513         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 514
 515         entity oldself;
 516         oldself = self;
 517         self = randomseed;
 518         self.think(); // sets random seed and nextthink
 519         self = oldself;
 520 }
 521
 522 void spawnfunc___init_dedicated_server(void)
 523 {
 524         // handler for _init/_init map (only for dedicated server initialization)
 525
 526         world_initialized = -1; // don't complain
 527         cvar = cvar_normal;
 528         cvar_string = cvar_string_normal;
 529         cvar_set = cvar_set_normal;
 530
 531         remove = remove_unsafely;
 532
 533         entity e;
 534         e = spawn();
 535         e.think = GotoFirstMap;
 536         e.nextthink = time; // this is usually 1 at this point
 537
 538         e = spawn();
 539         e.classname = "info_player_deathmatch"; // safeguard against player joining
 540
 541         self.classname = "worldspawn"; // safeguard against various stuff ;)
 542
 543         // needs to be done so early because of the constants they create
 544         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 545         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 546         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 547         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 548
 549         MapInfo_Enumerate();
 550         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 551 }
 552
 553 void Map_MarkAsRecent(string m);
 554 float world_already_spawned;
 555 void Nagger_Init();
 556 void ClientInit_Spawn();
 557 void WeaponStats_Init();
 558 void WeaponStats_Shutdown();
 559 void spawnfunc_worldspawn (void)
 560 {
 561         float fd, l, i, j, n;
 562         string s;
 563
 564         cvar = cvar_normal;
 565         cvar_string = cvar_string_normal;
 566         cvar_set = cvar_set_normal;
 567
 568         if(world_already_spawned)
 569                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 570         world_already_spawned = TRUE;
 571
 572         remove = remove_safely; // during spawning, watch what you remove!
 573
 574         check_unacceptable_compiler_bugs();
 575
 576         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 577
 578         compressShortVector_init();
 579
 580         entity head;
 581         head = nextent(world);
 582         maxclients = 0;
 583         while(head)
 584         {
 585                 ++maxclients;
 586                 head = nextent(head);
 587         }
 588
 589         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 590
 591         // needs to be done so early because of the constants they create
 592         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 593         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 594         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 595         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 596
 597         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 598
 599         TemporaryDB = db_create();
 600
 601         // 0 normal
 602         lightstyle(0, "m");
 603
 604         // 1 FLICKER (first variety)
 605         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 606
 607         // 2 SLOW STRONG PULSE
 608         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 609
 610         // 3 CANDLE (first variety)
 611         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 612
 613         // 4 FAST STROBE
 614         lightstyle(4, "mamamamamama");
 615
 616         // 5 GENTLE PULSE 1
 617         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 618
 619         // 6 FLICKER (second variety)
 620         lightstyle(6, "nmonqnmomnmomomno");
 621
 622         // 7 CANDLE (second variety)
 623         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 624
 625         // 8 CANDLE (third variety)
 626         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 627
 628         // 9 SLOW STROBE (fourth variety)
 629         lightstyle(9, "aaaaaaaazzzzzzzz");
 630
 631         // 10 FLUORESCENT FLICKER
 632         lightstyle(10, "mmamammmmammamamaaamammma");
 633
 634         // 11 SLOW PULSE NOT FADE TO BLACK
 635         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 636
 637         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 638
 639         // 63 testing
 640         lightstyle(63, "a");
 641
 642         if(autocvar_g_campaign)
 643                 CampaignPreInit();
 644
 645         Map_MarkAsRecent(mapname);
 646
 647         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 648
 649         precache_model ("null"); // we need this one before InitGameplayMode
 650         InitGameplayMode();
 651         readlevelcvars();
 652         GrappleHookInit();
 653         ArcInit();
 654
 655         player_count = 0;
 656         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 657         if(bot_waypoints_for_items == 1)
 658                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 659                         bot_waypoints_for_items = 0;
 660
 661         precache();
 662
 663         WaypointSprite_Init();
 664
 665         GameLogInit(); // prepare everything
 666         // NOTE for matchid:
 667         // changing the logic generating it is okay. But:
 668         // it HAS to stay <= 64 chars
 669         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 670         if(autocvar_sv_eventlog)
 671         {
 672                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 673                 matchid = strzone(s);
 674
 675                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 676                 s = ":gameinfo:mutators:LIST";
 677
 678                 ret_string = s;
 679                 MUTATOR_CALLHOOK(BuildMutatorsString);
 680                 s = ret_string;
 681
 682                 // simple, probably not good in the mutator system
 683                 if(autocvar_g_grappling_hook)
 684                         s = strcat(s, ":grappling_hook");
 685
 686                 // initialiation stuff, not good in the mutator system
 687                 if(!autocvar_g_use_ammunition)
 688                         s = strcat(s, ":no_use_ammunition");
 689
 690                 // initialiation stuff, not good in the mutator system
 691                 if(autocvar_g_pickup_items == 0)
 692                         s = strcat(s, ":no_pickup_items");
 693                 if(autocvar_g_pickup_items > 0)
 694                         s = strcat(s, ":pickup_items");
 695
 696                 // initialiation stuff, not good in the mutator system
 697                 if(autocvar_g_weaponarena != "0")
 698                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 699
 700                 // TODO to mutator system
 701                 if(autocvar_g_norecoil)
 702                         s = strcat(s, ":norecoil");
 703
 704                 // TODO to mutator system
 705                 if(autocvar_g_powerups == 0)
 706                         s = strcat(s, ":no_powerups");
 707                 if(autocvar_g_powerups > 0)
 708                         s = strcat(s, ":powerups");
 709
 710                 GameLogEcho(s);
 711                 GameLogEcho(":gameinfo:end");
 712         }
 713         else
 714                 matchid = strzone(ftos(random()));
 715
 716         cvar_set("nextmap", "");
 717
 718         SetDefaultAlpha();
 719
 720         if(autocvar_g_campaign)
 721                 CampaignPostInit();
 722
 723         fteqcc_testbugs();
 724
 725         Ban_LoadBans();
 726
 727         MapInfo_Enumerate();
 728         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 729
 730         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 731         {
 732                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 733                 if(fd != -1)
 734                 {
 735                         while((s = fgets(fd)))
 736                         {
 737                                 l = tokenize_console(s);
 738                                 if(l < 2)
 739                                         continue;
 740                                 if(argv(0) == "cd")
 741                                 {
 742                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 743                                         print("  cdtrack ", argv(2), "\n");
 744                                 }
 745                                 else if(argv(0) == "fog")
 746                                 {
 747                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 748                                         print("  \"fog\" \"", s, "\"\n");
 749                                 }
 750                                 else if(argv(0) == "set")
 751                                 {
 752                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 753                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 754                                 }
 755                                 else if(argv(0) != "//")
 756                                 {
 757                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 758                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 759                                 }
 760                         }
 761                         fclose(fd);
 762                 }
 763         }
 764
 765         WeaponStats_Init();
 766
 767         WepSet_AddStat();
 768         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 769         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 770         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 771         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 772         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 773         Nagger_Init();
 774
 775         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 776         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 777         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 778         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 779         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 780         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 781         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 782         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 783         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 784         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 785         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 786         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 787         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 788
 789         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 790         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 791
 792         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 793
 794         // g_movementspeed hack
 795         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 796         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 797         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 798         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 799
 800         // secrets
 801         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 802         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 803
 804         // misc
 805         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 806
 807         next_pingtime = time + 5;
 808
 809         detect_maptype();
 810
 811         // set up information replies for clients and server to use
 812         maplist_reply = strzone(getmaplist());
 813         lsmaps_reply = strzone(getlsmaps());
 814         for(i = 0; i < 10; ++i)
 815         {
 816                 s = getrecords(i);
 817                 if (s)
 818                         records_reply[i] = strzone(s);
 819         }
 820         ladder_reply = strzone(getladder());
 821         rankings_reply = strzone(getrankings());
 822
 823         // begin other init
 824         ClientInit_Spawn();
 825         RandomSeed_Spawn();
 826         PingPLReport_Spawn();
 827
 828         CheatInit();
 829
 830         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 831
 832         // fill sv_curl_serverpackages from .serverpackage files
 833         if(autocvar_sv_curl_serverpackages_auto)
 834         {
 835                 s = "";
 836                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 837                 for(i = 0; i < n; ++i)
 838                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 839                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 840                                 s = strcat(s, " ", argv(i));
 841                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 842                 if(fd >= 0)
 843                 {
 844                         j = search_getsize(fd);
 845                         for(i = 0; i < j; ++i)
 846                                 s = strcat(s, " ", search_getfilename(fd, i));
 847                         search_end(fd);
 848                 }
 849                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 850                 if(fd >= 0)
 851                 {
 852                         j = search_getsize(fd);
 853                         for(i = 0; i < j; ++i)
 854                                 s = strcat(s, " ", search_getfilename(fd, i));
 855                         search_end(fd);
 856                 }
 857                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 858         }
 859
 860         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 861         modname = "Xonotic";
 862         // physics/balance/config changes that count as mod
 863         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 864                 modname = cvar_string("g_mod_physics");
 865         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 866                 modname = cvar_string("g_mod_balance");
 867         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 868                 modname = cvar_string("g_mod_config");
 869         // extra mutators that deserve to count as mod
 870         MUTATOR_CALLHOOK(SetModname);
 871
 872         // save it for later
 873         modname = strzone(modname);
 874
 875         WinningConditionHelper(); // set worldstatus
 876
 877         world_initialized = 1;
 878 }
 879
 880 void spawnfunc_light (void)
 881 {
 882         //makestatic (self); // Who the f___ did that?
 883         remove(self);
 884 }
 885
 886 string GetGametype()
 887 {
 888         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 889 }
 890
 891 string getmapname_stored;
 892 string GetMapname()
 893 {
 894         return mapname;
 895 }
 896
 897 float Map_Count, Map_Current;
 898 string Map_Current_Name;
 899
 900 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 901 float GetMaplistPosition()
 902 {
 903         float pos, idx;
 904         string map;
 905
 906         map = GetMapname();
 907         idx = autocvar_g_maplist_index;
 908
 909         if(idx >= 0)
 910                 if(idx < Map_Count)
 911                         if(map == argv(idx))
 912                                 return idx;
 913
 914         for(pos = 0; pos < Map_Count; ++pos)
 915                 if(map == argv(pos))
 916                         return pos;
 917
 918         // resume normal maplist rotation if current map is not in g_maplist
 919         return idx;
 920 }
 921
 922 float MapHasRightSize(string map)
 923 {
 924         float fh;
 925         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 926         if(autocvar_g_maplist_check_waypoints)
 927         {
 928                 dprint("checkwp "); dprint(map);
 929                 if(!fexists(strcat("maps/", map, ".waypoints")))
 930                 {
 931                         dprint(": no waypoints\n");
 932                         return FALSE;
 933                 }
 934                 dprint(": has waypoints\n");
 935         }
 936
 937         // open map size restriction file
 938         dprint("opensize "); dprint(map);
 939         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 940         if(fh >= 0)
 941         {
 942                 float mapmin, mapmax;
 943                 dprint(": ok, ");
 944                 mapmin = stof(fgets(fh));
 945                 mapmax = stof(fgets(fh));
 946                 fclose(fh);
 947                 if(player_count < mapmin)
 948                 {
 949                         dprint("not enough\n");
 950                         return FALSE;
 951                 }
 952                 if(player_count > mapmax)
 953                 {
 954                         dprint("too many\n");
 955                         return FALSE;
 956                 }
 957                 dprint("right size\n");
 958                 return TRUE;
 959         }
 960         dprint(": not found\n");
 961         return TRUE;
 962 }
 963
 964 string Map_Filename(float position)
 965 {
 966         return strcat("maps/", argv(position), ".bsp");
 967 }
 968
 969 string strwords(string s, float w)
 970 {
 971         float endpos;
 972         for(endpos = 0; w && endpos >= 0; --w)
 973                 endpos = strstrofs(s, " ", endpos + 1);
 974         if(endpos < 0)
 975                 return s;
 976         else
 977                 return substring(s, 0, endpos);
 978 }
 979
 980 float strhasword(string s, string w)
 981 {
 982         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 983 }
 984
 985 void Map_MarkAsRecent(string m)
 986 {
 987         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 988 }
 989
 990 float Map_IsRecent(string m)
 991 {
 992         return strhasword(autocvar_g_maplist_mostrecent, m);
 993 }
 994
 995 float Map_Check(float position, float pass)
 996 {
 997         string filename;
 998         string map_next;
 999         map_next = argv(position);
1000         if(pass <= 1)
1001         {
1002                 if(Map_IsRecent(map_next))
1003                         return 0;
1004         }
1005         filename = Map_Filename(position);
1006         if(MapInfo_CheckMap(map_next))
1007         {
1008                 if(pass == 2)
1009                         return 1;
1010                 if(MapHasRightSize(map_next))
1011                         return 1;
1012                 return 0;
1013         }
1014         else
1015                 dprint( "Couldn't select '", filename, "'..\n" );
1016
1017         return 0;
1018 }
1019
1020 void Map_Goto_SetStr(string nextmapname)
1021 {
1022         if(getmapname_stored != "")
1023                 strunzone(getmapname_stored);
1024         if(nextmapname == "")
1025                 getmapname_stored = "";
1026         else
1027                 getmapname_stored = strzone(nextmapname);
1028 }
1029
1030 void Map_Goto_SetFloat(float position)
1031 {
1032         cvar_set("g_maplist_index", ftos(position));
1033         Map_Goto_SetStr(argv(position));
1034 }
1035
1036 void Map_Goto(float reinit)
1037 {
1038         MapInfo_LoadMap(getmapname_stored, reinit);
1039 }
1040
1041 // return codes of map selectors:
1042 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1043 //   -2 = permanent failure
1044 float() MaplistMethod_Iterate = // usual method
1045 {
1046         float pass, i;
1047
1048         dprint("Trying MaplistMethod_Iterate\n");
1049
1050         for(pass = 1; pass <= 2; ++pass)
1051         {
1052                 for(i = 1; i < Map_Count; ++i)
1053                 {
1054                         float mapindex;
1055                         mapindex = mod(i + Map_Current, Map_Count);
1056                         if(Map_Check(mapindex, pass))
1057                                 return mapindex;
1058                 }
1059         }
1060         return -1;
1061 }
1062
1063 float() MaplistMethod_Repeat = // fallback method
1064 {
1065         dprint("Trying MaplistMethod_Repeat\n");
1066
1067         if(Map_Check(Map_Current, 2))
1068                 return Map_Current;
1069         return -2;
1070 }
1071
1072 float() MaplistMethod_Random = // random map selection
1073 {
1074         float i, imax;
1075
1076         dprint("Trying MaplistMethod_Random\n");
1077
1078         imax = 42;
1079
1080         for(i = 0; i <= imax; ++i)
1081         {
1082                 float mapindex;
1083                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1084                 if(Map_Check(mapindex, 1))
1085                         return mapindex;
1086         }
1087         return -1;
1088 }
1089
1090 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1091 // the exponent sets a bias on the map selection:
1092 // the higher the exponent, the less likely "shortly repeated" same maps are
1093 {
1094         float i, j, imax, insertpos;
1095
1096         dprint("Trying MaplistMethod_Shuffle\n");
1097
1098         imax = 42;
1099
1100         for(i = 0; i <= imax; ++i)
1101         {
1102                 string newlist;
1103
1104                 // now reinsert this at another position
1105                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1106                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1107                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1108                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1109
1110                 // insert the current map there
1111                 newlist = "";
1112                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1113                         newlist = strcat(newlist, " ", argv(j));
1114                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1115                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1116                         newlist = strcat(newlist, " ", argv(j));
1117                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1118                 cvar_set("g_maplist", newlist);
1119                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1120
1121                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1122                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1123                 if(Map_Check(Map_Current, 1))
1124                         return Map_Current;
1125         }
1126         return -1;
1127 }
1128
1129 void Maplist_Init()
1130 {
1131         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1132         float i;
1133         for (i = 0; i < Map_Count; ++i)
1134                 if (Map_Check(i, 2))
1135                         break;
1136         if (i == Map_Count)
1137         {
1138                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1139                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1140                 if(autocvar_g_maplist_shuffle)
1141                         ShuffleMaplist();
1142                 localcmd("\nmenu_cmd sync\n");
1143                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1144         }
1145         if(Map_Count == 0)
1146                 error("empty maplist, cannot select a new map");
1147         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1148
1149         if(Map_Current_Name)
1150                 strunzone(Map_Current_Name);
1151         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1152         // this may or may not be correct, but who cares, in the worst case a map
1153         // isn't chosen in the first pass that should have been
1154 }
1155
1156 string GetNextMap()
1157 {
1158         float nextMap;
1159
1160         Maplist_Init();
1161         nextMap = -1;
1162
1163         if(nextMap == -1)
1164                 if(autocvar_g_maplist_shuffle > 0)
1165                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1166
1167         if(nextMap == -1)
1168                 if(autocvar_g_maplist_selectrandom)
1169                         nextMap = MaplistMethod_Random();
1170
1171         if(nextMap == -1)
1172                 nextMap = MaplistMethod_Iterate();
1173
1174         if(nextMap == -1)
1175                 nextMap = MaplistMethod_Repeat();
1176
1177         if(nextMap >= 0)
1178         {
1179                 Map_Goto_SetFloat(nextMap);
1180                 return getmapname_stored;
1181         }
1182
1183         return "";
1184 }
1185
1186 float DoNextMapOverride(float reinit)
1187 {
1188         if(autocvar_g_campaign)
1189         {
1190                 CampaignPostIntermission();
1191                 alreadychangedlevel = TRUE;
1192                 return TRUE;
1193         }
1194         if(autocvar_quit_when_empty)
1195         {
1196                 if(player_count <= currentbots)
1197                 {
1198                         localcmd("quit\n");
1199                         alreadychangedlevel = TRUE;
1200                         return TRUE;
1201                 }
1202         }
1203         if(autocvar_quit_and_redirect != "")
1204         {
1205                 redirection_target = strzone(autocvar_quit_and_redirect);
1206                 alreadychangedlevel = TRUE;
1207                 return TRUE;
1208         }
1209         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1210         {
1211                 localcmd("restart\n");
1212                 alreadychangedlevel = TRUE;
1213                 return TRUE;
1214         }
1215         if(autocvar_nextmap != "")
1216                 if(MapInfo_CheckMap(autocvar_nextmap))
1217                 {
1218                         Map_Goto_SetStr(autocvar_nextmap);
1219                         Map_Goto(reinit);
1220                         alreadychangedlevel = TRUE;
1221                         return TRUE;
1222                 }
1223         if(!reinit && autocvar_lastlevel)
1224         {
1225                 cvar_settemp_restore();
1226                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1227                 alreadychangedlevel = TRUE;
1228                 return TRUE;
1229         }
1230         return FALSE;
1231 }
1232
1233 void GotoNextMap(float reinit)
1234 {
1235         //string nextmap;
1236         //float n, nummaps;
1237         //string s;
1238         if (alreadychangedlevel)
1239                 return;
1240         alreadychangedlevel = TRUE;
1241
1242         string nextMap;
1243
1244         nextMap = GetNextMap();
1245         if(nextMap == "")
1246                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1247         Map_Goto(reinit);
1248 }
1249
1250
1251 /*
1252 ============
1253 IntermissionThink
1254
1255 When the player presses attack or jump, change to the next level
1256 ============
1257 */
1258 .float autoscreenshot;
1259 void() MapVote_Start;
1260 void() MapVote_Think;
1261 float mapvote_initialized;
1262 void IntermissionThink()
1263 {
1264         FixIntermissionClient(self);
1265
1266         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1267         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1268
1269         if( (server_screenshot || client_screenshot)
1270                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1271         {
1272                 self.autoscreenshot = -1;
1273                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1274                 return;
1275         }
1276
1277         if (time < intermission_exittime)
1278                 return;
1279
1280         if(!mapvote_initialized)
1281                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1282                         return;
1283
1284         MapVote_Start();
1285 }
1286
1287 /*
1288 ============
1289 FindIntermission
1290
1291 Returns the entity to view from
1292 ============
1293 */
1294 /*
1295 entity FindIntermission()
1296 {
1297         local   entity spot;
1298         local   float cyc;
1299
1300 // look for info_intermission first
1301         spot = find (world, classname, "info_intermission");
1302         if (spot)
1303         {       // pick a random one
1304                 cyc = random() * 4;
1305                 while (cyc > 1)
1306                 {
1307                         spot = find (spot, classname, "info_intermission");
1308                         if (!spot)
1309                                 spot = find (spot, classname, "info_intermission");
1310                         cyc = cyc - 1;
1311                 }
1312                 return spot;
1313         }
1314
1315 // then look for the start position
1316         spot = find (world, classname, "info_player_start");
1317         if (spot)
1318                 return spot;
1319
1320 // testinfo_player_start is only found in regioned levels
1321         spot = find (world, classname, "testplayerstart");
1322         if (spot)
1323                 return spot;
1324
1325 // then look for the start position
1326         spot = find (world, classname, "info_player_deathmatch");
1327         if (spot)
1328                 return spot;
1329
1330         //objerror ("FindIntermission: no spot");
1331         return world;
1332 }
1333 */
1334
1335 /*
1336 ===============================================================================
1337
1338 RULES
1339
1340 ===============================================================================
1341 */
1342
1343 void DumpStats(float final)
1344 {
1345         float file;
1346         string s;
1347         float to_console;
1348         float to_eventlog;
1349         float to_file;
1350         float i;
1351
1352         to_console = autocvar_sv_logscores_console;
1353         to_eventlog = autocvar_sv_eventlog;
1354         to_file = autocvar_sv_logscores_file;
1355
1356         if(!final)
1357         {
1358                 to_console = TRUE; // always print printstats replies
1359                 to_eventlog = FALSE; // but never print them to the event log
1360         }
1361
1362         if(to_eventlog)
1363                 if(autocvar_sv_eventlog_console)
1364                         to_console = FALSE; // otherwise we get the output twice
1365
1366         if(final)
1367                 s = ":scores:";
1368         else
1369                 s = ":status:";
1370         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1371
1372         if(to_console)
1373                 print(s, "\n");
1374         if(to_eventlog)
1375                 GameLogEcho(s);
1376
1377         file = -1;
1378         if(to_file)
1379         {
1380                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1381                 if(file == -1)
1382                         to_file = FALSE;
1383                 else
1384                         fputs(file, strcat(s, "\n"));
1385         }
1386
1387         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1388         if(to_console)
1389                 print(s, "\n");
1390         if(to_eventlog)
1391                 GameLogEcho(s);
1392         if(to_file)
1393                 fputs(file, strcat(s, "\n"));
1394
1395         FOR_EACH_CLIENT(other)
1396         {
1397                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1398                 {
1399                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1400                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1401                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1402                                 s = strcat(s, ftos(other.team), ":");
1403                         else
1404                                 s = strcat(s, "spectator:");
1405
1406                         if(to_console)
1407                                 print(s, other.netname, "\n");
1408                         if(to_eventlog)
1409                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1410                         if(to_file)
1411                                 fputs(file, strcat(s, other.netname, "\n"));
1412                 }
1413         }
1414
1415         if(teamplay)
1416         {
1417                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1418                 if(to_console)
1419                         print(s, "\n");
1420                 if(to_eventlog)
1421                         GameLogEcho(s);
1422                 if(to_file)
1423                         fputs(file, strcat(s, "\n"));
1424
1425                 for(i = 1; i < 16; ++i)
1426                 {
1427                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1428                         s = strcat(s, ":", ftos(i));
1429                         if(to_console)
1430                                 print(s, "\n");
1431                         if(to_eventlog)
1432                                 GameLogEcho(s);
1433                         if(to_file)
1434                                 fputs(file, strcat(s, "\n"));
1435                 }
1436         }
1437
1438         if(to_console)
1439                 print(":end\n");
1440         if(to_eventlog)
1441                 GameLogEcho(":end");
1442         if(to_file)
1443         {
1444                 fputs(file, ":end\n");
1445                 fclose(file);
1446         }
1447 }
1448
1449 void FixIntermissionClient(entity e)
1450 {
1451         string s;
1452         if(!e.autoscreenshot) // initial call
1453         {
1454                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1455                 e.health = -2342;
1456                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1457                 e.solid = SOLID_NOT;
1458                 e.movetype = MOVETYPE_NONE;
1459                 e.takedamage = DAMAGE_NO;
1460                 if(e.weaponentity)
1461                 {
1462                         e.weaponentity.effects = EF_NODRAW;
1463                         if (e.weaponentity.weaponentity)
1464                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1465                 }
1466                 if(IS_REAL_CLIENT(e))
1467                 {
1468                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1469                         s = autocvar_sv_intermission_cdtrack;
1470                         if(s != "")
1471                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1472                         msg_entity = e;
1473                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1474                 }
1475         }
1476 }
1477
1478 /*
1479 go to the next level for deathmatch
1480 only called if a time or frag limit has expired
1481 */
1482 void NextLevel()
1483 {
1484         gameover = TRUE;
1485
1486         intermission_running = 1;
1487
1488 // enforce a wait time before allowing changelevel
1489         if(player_count > 0)
1490                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1491         else
1492                 intermission_exittime = -1;
1493
1494         /*
1495         WriteByte (MSG_ALL, SVC_CDTRACK);
1496         WriteByte (MSG_ALL, 3);
1497         WriteByte (MSG_ALL, 3);
1498         // done in FixIntermission
1499         */
1500
1501         //pos = FindIntermission ();
1502
1503         VoteReset();
1504
1505         DumpStats(TRUE);
1506
1507         // send statistics
1508         entity e;
1509         PlayerStats_EndMatch(1);
1510         FOR_EACH_CLIENT(e)
1511                 PlayerStats_AddGlobalInfo(e);
1512         PlayerStats_Shutdown();
1513         WeaponStats_Shutdown();
1514
1515         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1516
1517         if(autocvar_sv_eventlog)
1518                 GameLogEcho(":gameover");
1519
1520         GameLogClose();
1521
1522         FOR_EACH_PLAYER(other) {
1523                 FixIntermissionClient(other);
1524                 if(other.winning)
1525                         bprint(other.netname, " ^7wins.\n");
1526         }
1527
1528         if(autocvar_g_campaign)
1529                 CampaignPreIntermission();
1530
1531         MUTATOR_CALLHOOK(MatchEnd);
1532
1533         localcmd("\nsv_hook_gameend\n");
1534 }
1535
1536 /*
1537 ============
1538 CheckRules_Player
1539
1540 Exit deathmatch games upon conditions
1541 ============
1542 */
1543 void CheckRules_Player()
1544 {
1545         if (gameover)   // someone else quit the game already
1546                 return;
1547
1548         if(self.deadflag == DEAD_NO)
1549                 self.play_time += frametime;
1550
1551         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1552         //   (div0: and that in CheckRules_World please)
1553 }
1554
1555 float checkrules_equality;
1556 float checkrules_suddendeathwarning;
1557 float checkrules_suddendeathend;
1558 float checkrules_overtimesadded; //how many overtimes have been already added
1559
1560 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1561 const float WINNING_YES = 1; // winner found
1562 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1563 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1564
1565 float InitiateSuddenDeath()
1566 {
1567         // Check first whether normal overtimes could be added before initiating suddendeath mode
1568         // - for this timelimit_overtime needs to be >0 of course
1569         // - also check the winning condition calculated in the previous frame and only add normal overtime
1570         //   again, if at the point at which timelimit would be extended again, still no winner was found
1571         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1572         {
1573                 return 1; // need to call InitiateOvertime later
1574         }
1575         else
1576         {
1577                 if(!checkrules_suddendeathend)
1578                 {
1579                         if(autocvar_g_campaign)
1580                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1581                         else
1582                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1583                         if(g_race && !g_race_qualifying)
1584                                 race_StartCompleting();
1585                 }
1586                 return 0;
1587         }
1588 }
1589
1590 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1591 {
1592         ++checkrules_overtimesadded;
1593         //add one more overtime by simply extending the timelimit
1594         float tl;
1595         tl = autocvar_timelimit;
1596         tl += autocvar_timelimit_overtime;
1597         cvar_set("timelimit", ftos(tl));
1598
1599         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1600 }
1601
1602 float GetWinningCode(float fraglimitreached, float equality)
1603 {
1604         if(autocvar_g_campaign == 1)
1605                 if(fraglimitreached)
1606                         return WINNING_YES;
1607                 else
1608                         return WINNING_NO;
1609
1610         else
1611                 if(equality)
1612                         if(fraglimitreached)
1613                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1614                         else
1615                                 return WINNING_NEVER;
1616                 else
1617                         if(fraglimitreached)
1618                                 return WINNING_YES;
1619                         else
1620                                 return WINNING_NO;
1621 }
1622
1623 // set the .winning flag for exactly those players with a given field value
1624 void SetWinners(.float field, float value)
1625 {
1626         entity head;
1627         FOR_EACH_PLAYER(head)
1628                 head.winning = (head.field == value);
1629 }
1630
1631 // set the .winning flag for those players with a given field value
1632 void AddWinners(.float field, float value)
1633 {
1634         entity head;
1635         FOR_EACH_PLAYER(head)
1636                 if(head.field == value)
1637                         head.winning = 1;
1638 }
1639
1640 // clear the .winning flags
1641 void ClearWinners(void)
1642 {
1643         entity head;
1644         FOR_EACH_PLAYER(head)
1645                 head.winning = 0;
1646 }
1647
1648 // Onslaught winning condition:
1649 // game terminates if only one team has a working generator (or none)
1650 float WinningCondition_Onslaught()
1651 {
1652         entity head;
1653         float t1, t2, t3, t4;
1654
1655         WinningConditionHelper(); // set worldstatus
1656
1657         if(warmup_stage)
1658                 return WINNING_NO;
1659
1660         // first check if the game has ended
1661         t1 = t2 = t3 = t4 = 0;
1662         head = find(world, classname, "onslaught_generator");
1663         while (head)
1664         {
1665                 if (head.health > 0)
1666                 {
1667                         if (head.team == NUM_TEAM_1) t1 = 1;
1668                         if (head.team == NUM_TEAM_2) t2 = 1;
1669                         if (head.team == NUM_TEAM_3) t3 = 1;
1670                         if (head.team == NUM_TEAM_4) t4 = 1;
1671                 }
1672                 head = find(head, classname, "onslaught_generator");
1673         }
1674         if (t1 + t2 + t3 + t4 < 2)
1675         {
1676                 // game over, only one team remains (or none)
1677                 ClearWinners();
1678                 if (t1) SetWinners(team, NUM_TEAM_1);
1679                 if (t2) SetWinners(team, NUM_TEAM_2);
1680                 if (t3) SetWinners(team, NUM_TEAM_3);
1681                 if (t4) SetWinners(team, NUM_TEAM_4);
1682                 dprint("Have a winner, ending game.\n");
1683                 return WINNING_YES;
1684         }
1685
1686         // Two or more teams remain
1687         return WINNING_NO;
1688 }
1689
1690 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1691 // they win. Otherwise the defending team wins once the timelimit passes.
1692 void assault_new_round();
1693 float WinningCondition_Assault()
1694 {
1695         float status;
1696
1697         WinningConditionHelper(); // set worldstatus
1698
1699         status = WINNING_NO;
1700         // as the timelimit has not yet passed just assume the defending team will win
1701         if(assault_attacker_team == NUM_TEAM_1)
1702         {
1703                 SetWinners(team, NUM_TEAM_2);
1704         }
1705         else
1706         {
1707                 SetWinners(team, NUM_TEAM_1);
1708         }
1709
1710         entity ent;
1711         ent = find(world, classname, "target_assault_roundend");
1712         if(ent)
1713         {
1714                 if(ent.winning) // round end has been triggered by attacking team
1715                 {
1716                         bprint("ASSAULT: round completed...\n");
1717                         SetWinners(team, assault_attacker_team);
1718
1719                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1720
1721                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1722                         {
1723                                 status = WINNING_YES;
1724                         }
1725                         else
1726                         {
1727                                 entity oldself;
1728                                 oldself = self;
1729                                 self = ent;
1730                                 assault_new_round();
1731                                 self = oldself;
1732                         }
1733                 }
1734         }
1735
1736         return status;
1737 }
1738
1739 // LMS winning condition: game terminates if and only if there's at most one
1740 // one player who's living lives. Top two scores being equal cancels the time
1741 // limit.
1742 float WinningCondition_LMS()
1743 {
1744         entity head, head2;
1745         float have_player;
1746         float have_players;
1747         float l;
1748
1749         have_player = FALSE;
1750         have_players = FALSE;
1751         l = LMS_NewPlayerLives();
1752
1753         head = find(world, classname, "player");
1754         if(head)
1755                 have_player = TRUE;
1756         head2 = find(head, classname, "player");
1757         if(head2)
1758                 have_players = TRUE;
1759
1760         if(have_player)
1761         {
1762                 // we have at least one player
1763                 if(have_players)
1764                 {
1765                         // two or more active players - continue with the game
1766                 }
1767                 else
1768                 {
1769                         // exactly one player?
1770
1771                         ClearWinners();
1772                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1773
1774                         if(l)
1775                         {
1776                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1777                                 return WINNING_NO;
1778                         }
1779                         else
1780                         {
1781                                 // a winner!
1782                                 // and assign him his first place
1783                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1784                                 return WINNING_YES;
1785                         }
1786                 }
1787         }
1788         else
1789         {
1790                 // nobody is playing at all...
1791                 if(l)
1792                 {
1793                         // wait for players...
1794                 }
1795                 else
1796                 {
1797                         // SNAFU (maybe a draw game?)
1798                         ClearWinners();
1799                         dprint("No players, ending game.\n");
1800                         return WINNING_YES;
1801                 }
1802         }
1803
1804         // When we get here, we have at least two players who are actually LIVING,
1805         // now check if the top two players have equal score.
1806         WinningConditionHelper();
1807
1808         ClearWinners();
1809         if(WinningConditionHelper_winner)
1810                 WinningConditionHelper_winner.winning = TRUE;
1811         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1812                 return WINNING_NEVER;
1813
1814         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1815         return WINNING_NO;
1816 }
1817
1818 void ShuffleMaplist()
1819 {
1820         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1821 }
1822
1823 float leaderfrags;
1824 float WinningCondition_Scores(float limit, float leadlimit)
1825 {
1826         float limitreached;
1827
1828         // TODO make everything use THIS winning condition (except LMS)
1829         WinningConditionHelper();
1830
1831         if(teamplay)
1832         {
1833                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1834                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1835                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1836                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1837         }
1838
1839         ClearWinners();
1840         if(WinningConditionHelper_winner)
1841                 WinningConditionHelper_winner.winning = 1;
1842         if(WinningConditionHelper_winnerteam >= 0)
1843                 SetWinners(team, WinningConditionHelper_winnerteam);
1844
1845         if(WinningConditionHelper_lowerisbetter)
1846         {
1847                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1848                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1849                 limit = -limit;
1850         }
1851
1852         if(WinningConditionHelper_zeroisworst)
1853                 leadlimit = 0; // not supported in this mode
1854
1855         if(g_dm || g_tdm || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1856         // these modes always score in increments of 1, thus this makes sense
1857         {
1858                 if(leaderfrags != WinningConditionHelper_topscore)
1859                 {
1860                         leaderfrags = WinningConditionHelper_topscore;
1861
1862                         if (limit)
1863                         if (leaderfrags == limit - 1)
1864                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1865                         else if (leaderfrags == limit - 2)
1866                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1867                         else if (leaderfrags == limit - 3)
1868                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1869                 }
1870         }
1871
1872         limitreached = FALSE;
1873         if(limit)
1874                 if(WinningConditionHelper_topscore >= limit)
1875                         limitreached = TRUE;
1876         if(leadlimit)
1877         {
1878                 float leadlimitreached;
1879                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1880                 if(autocvar_leadlimit_and_fraglimit)
1881                         limitreached = (limitreached && leadlimitreached);
1882                 else
1883                         limitreached = (limitreached || leadlimitreached);
1884         }
1885
1886         if(limit)
1887                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1888
1889         return GetWinningCode(
1890                 WinningConditionHelper_topscore && limitreached,
1891                 WinningConditionHelper_equality
1892         );
1893 }
1894
1895 float WinningCondition_Race(float fraglimit)
1896 {
1897         float wc;
1898         entity p;
1899         float n, c;
1900
1901         n = 0;
1902         c = 0;
1903         FOR_EACH_PLAYER(p)
1904         {
1905                 ++n;
1906                 if(p.race_completed)
1907                         ++c;
1908         }
1909         if(n && (n == c))
1910                 return WINNING_YES;
1911         wc = WinningCondition_Scores(fraglimit, 0);
1912
1913         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1914         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1915         // do NOT support equality when the laps are all raced!
1916                 return WINNING_STARTSUDDENDEATHOVERTIME;
1917         else
1918                 return WINNING_NEVER;
1919 }
1920
1921 float WinningCondition_QualifyingThenRace(float limit)
1922 {
1923         float wc;
1924         wc = WinningCondition_Scores(limit, 0);
1925
1926         // NEVER initiate overtime
1927         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1928         {
1929                 return WINNING_YES;
1930         }
1931
1932         return wc;
1933 }
1934
1935 float WinningCondition_RanOutOfSpawns()
1936 {
1937         entity head;
1938
1939         if(have_team_spawns <= 0)
1940                 return WINNING_NO;
1941
1942         if(autocvar_g_spawn_useallspawns <= 0)
1943                 return WINNING_NO;
1944
1945         if(!some_spawn_has_been_used)
1946                 return WINNING_NO;
1947
1948         team1_score = team2_score = team3_score = team4_score = 0;
1949
1950         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1951         {
1952                 if(head.team == NUM_TEAM_1)
1953                         team1_score = 1;
1954                 else if(head.team == NUM_TEAM_2)
1955                         team2_score = 1;
1956                 else if(head.team == NUM_TEAM_3)
1957                         team3_score = 1;
1958                 else if(head.team == NUM_TEAM_4)
1959                         team4_score = 1;
1960         }
1961
1962         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1963         {
1964                 if(head.team == NUM_TEAM_1)
1965                         team1_score = 1;
1966                 else if(head.team == NUM_TEAM_2)
1967                         team2_score = 1;
1968                 else if(head.team == NUM_TEAM_3)
1969                         team3_score = 1;
1970                 else if(head.team == NUM_TEAM_4)
1971                         team4_score = 1;
1972         }
1973
1974         ClearWinners();
1975         if(team1_score + team2_score + team3_score + team4_score == 0)
1976         {
1977                 checkrules_equality = TRUE;
1978                 return WINNING_YES;
1979         }
1980         else if(team1_score + team2_score + team3_score + team4_score == 1)
1981         {
1982                 float t, i;
1983                 if(team1_score)
1984                         t = NUM_TEAM_1;
1985                 else if(team2_score)
1986                         t = NUM_TEAM_2;
1987                 else if(team3_score)
1988                         t = NUM_TEAM_3;
1989                 else // if(team4_score)
1990                         t = NUM_TEAM_4;
1991                 CheckAllowedTeams(world);
1992                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1993                 {
1994                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1995                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1996                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1997                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1998                 }
1999
2000                 AddWinners(team, t);
2001                 return WINNING_YES;
2002         }
2003         else
2004                 return WINNING_NO;
2005 }
2006
2007 /*
2008 ============
2009 CheckRules_World
2010
2011 Exit deathmatch games upon conditions
2012 ============
2013 */
2014 void ReadyRestart();
2015 void CheckRules_World()
2016 {
2017         float timelimit;
2018         float fraglimit;
2019         float leadlimit;
2020
2021         VoteThink();
2022         MapVote_Think();
2023
2024         SetDefaultAlpha();
2025
2026         /*
2027         MapVote_Think should now do that part
2028         if (intermission_running)
2029                 if (time >= intermission_exittime + 60)
2030                 {
2031                         if(!DoNextMapOverride())
2032                                 GotoNextMap();
2033                         return;
2034                 }
2035         */
2036
2037         if (gameover)   // someone else quit the game already
2038         {
2039                 if(player_count == 0) // Nobody there? Then let's go to the next map
2040                         MapVote_Start();
2041                         // this will actually check the player count in the next frame
2042                         // again, but this shouldn't hurt
2043                 return;
2044         }
2045
2046         timelimit = autocvar_timelimit * 60;
2047         fraglimit = autocvar_fraglimit;
2048         leadlimit = autocvar_leadlimit;
2049
2050         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2051         {
2052                 if(timelimit > 0)
2053                         timelimit = 0; // timelimit is not made for warmup
2054                 if(fraglimit > 0)
2055                         fraglimit = 0; // no fraglimit for now
2056                 leadlimit = 0; // no leadlimit for now
2057         }
2058
2059         if(timelimit > 0)
2060         {
2061                 timelimit += game_starttime;
2062         }
2063         else if (timelimit < 0)
2064         {
2065                 // endmatch
2066                 NextLevel();
2067                 return;
2068         }
2069
2070         if(g_onslaught)
2071                 timelimit = 0; // ONS has its own overtime rule
2072
2073         float wantovertime;
2074         wantovertime = 0;
2075
2076         if(timelimit > game_starttime)
2077                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2078         else
2079                 game_completion_ratio = 0;
2080
2081         if(checkrules_suddendeathend)
2082         {
2083                 if(!checkrules_suddendeathwarning)
2084                 {
2085                         checkrules_suddendeathwarning = TRUE;
2086                         if(g_race && !g_race_qualifying)
2087                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2088                         else
2089                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2090                 }
2091         }
2092         else
2093         {
2094                 if (timelimit && time >= timelimit)
2095                 {
2096                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2097                         {
2098                                 float totalplayers;
2099                                 float playerswithlaps;
2100                                 float readyplayers;
2101                                 entity head;
2102                                 totalplayers = playerswithlaps = readyplayers = 0;
2103                                 FOR_EACH_PLAYER(head)
2104                                 {
2105                                         ++totalplayers;
2106                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2107                                                 ++playerswithlaps;
2108                                         if(head.ready)
2109                                                 ++readyplayers;
2110                                 }
2111
2112                                 // at least 2 of the players have completed a lap: start the RACE
2113                                 // otherwise, the players should end the qualifying on their own
2114                                 if(readyplayers || playerswithlaps >= 2)
2115                                 {
2116                                         checkrules_suddendeathend = 0;
2117                                         ReadyRestart(); // go to race
2118                                         return;
2119                                 }
2120                                 else
2121                                         wantovertime |= InitiateSuddenDeath();
2122                         }
2123                         else
2124                                 wantovertime |= InitiateSuddenDeath();
2125                 }
2126         }
2127
2128         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2129         {
2130                 NextLevel();
2131                 return;
2132         }
2133
2134         float checkrules_status;
2135         checkrules_status = WinningCondition_RanOutOfSpawns();
2136         if(checkrules_status == WINNING_YES)
2137         {
2138                 bprint("Hey! Someone ran out of spawns!\n");
2139         }
2140         else if(g_race && !g_race_qualifying && timelimit >= 0)
2141         {
2142                 checkrules_status = WinningCondition_Race(fraglimit);
2143                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2144         }
2145         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2146         {
2147                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2148                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2149         }
2150         else if(g_assault)
2151         {
2152                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2153         }
2154         else if(g_lms)
2155         {
2156                 checkrules_status = WinningCondition_LMS();
2157         }
2158         else if (g_onslaught)
2159         {
2160                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2161         }
2162         else
2163         {
2164                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2165                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2166         }
2167
2168         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2169         {
2170                 checkrules_status = WINNING_NEVER;
2171                 checkrules_overtimesadded = -1;
2172                 wantovertime |= InitiateSuddenDeath();
2173         }
2174
2175         if(checkrules_status == WINNING_NEVER)
2176                 // equality cases! Nobody wins if the overtime ends in a draw.
2177                 ClearWinners();
2178
2179         if(wantovertime)
2180         {
2181                 if(checkrules_status == WINNING_NEVER)
2182                         InitiateOvertime();
2183                 else
2184                         checkrules_status = WINNING_YES;
2185         }
2186
2187         if(checkrules_suddendeathend)
2188                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2189                         checkrules_status = WINNING_YES;
2190
2191         if(checkrules_status == WINNING_YES)
2192         {
2193                 //print("WINNING\n");
2194                 NextLevel();
2195         }
2196 }
2197
2198 float mapvote_nextthink;
2199 float mapvote_initialized;
2200 float mapvote_keeptwotime;
2201 float mapvote_timeout;
2202 string mapvote_message;
2203 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2204 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2205 float mapvote_screenshot_dirs_count;
2206
2207 float mapvote_count;
2208 float mapvote_count_real;
2209 string mapvote_maps[MAPVOTE_COUNT];
2210 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2211 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2212 float mapvote_maps_suggested[MAPVOTE_COUNT];
2213 string mapvote_suggestions[MAPVOTE_COUNT];
2214 float mapvote_suggestion_ptr;
2215 float mapvote_voters;
2216 float mapvote_selections[MAPVOTE_COUNT];
2217 float mapvote_run;
2218 float mapvote_detail;
2219 float mapvote_abstain;
2220 .float mapvote;
2221
2222 void MapVote_ClearAllVotes()
2223 {
2224         FOR_EACH_CLIENT(other)
2225                 other.mapvote = 0;
2226 }
2227
2228 string MapVote_Suggest(string m)
2229 {
2230         float i;
2231         if(m == "")
2232                 return "That's not how to use this command.";
2233         if(!autocvar_g_maplist_votable_suggestions)
2234                 return "Suggestions are not accepted on this server.";
2235         if(mapvote_initialized)
2236                 return "Can't suggest - voting is already in progress!";
2237         m = MapInfo_FixName(m);
2238         if (!m)
2239                 return "The map you suggested is not available on this server.";
2240         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2241                 if(Map_IsRecent(m))
2242                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2243
2244         if(!MapInfo_CheckMap(m))
2245                 return "The map you suggested does not support the current game mode.";
2246         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2247                 if(mapvote_suggestions[i] == m)
2248                         return "This map was already suggested.";
2249         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2250         {
2251                 i = floor(random() * mapvote_suggestion_ptr);
2252         }
2253         else
2254         {
2255                 i = mapvote_suggestion_ptr;
2256                 mapvote_suggestion_ptr += 1;
2257         }
2258         if(mapvote_suggestions[i] != "")
2259                 strunzone(mapvote_suggestions[i]);
2260         mapvote_suggestions[i] = strzone(m);
2261         if(autocvar_sv_eventlog)
2262                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2263         return strcat("Suggestion of ", m, " accepted.");
2264 }
2265
2266 void MapVote_AddVotable(string nextMap, float isSuggestion)
2267 {
2268         float j, i, o;
2269         string pakfile, mapfile;
2270
2271         if(nextMap == "")
2272                 return;
2273         for(j = 0; j < mapvote_count; ++j)
2274                 if(mapvote_maps[j] == nextMap)
2275                         return;
2276         // suggestions might be no longer valid/allowed after gametype switch!
2277         if(isSuggestion)
2278                 if(!MapInfo_CheckMap(nextMap))
2279                         return;
2280         mapvote_maps[mapvote_count] = strzone(nextMap);
2281         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2282
2283         pakfile = string_null;
2284         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2285         {
2286                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2287                 pakfile = whichpack(strcat(mapfile, ".tga"));
2288                 if(pakfile == "")
2289                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2290                 if(pakfile == "")
2291                         pakfile = whichpack(strcat(mapfile, ".png"));
2292                 if(pakfile != "")
2293                         break;
2294         }
2295         if(i >= mapvote_screenshot_dirs_count)
2296                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2297         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2298                 pakfile = substring(pakfile, o, -1);
2299
2300         mapvote_maps_screenshot_dir[mapvote_count] = i;
2301         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2302
2303         mapvote_count += 1;
2304 }
2305
2306 void MapVote_Spawn();
2307 void MapVote_Init()
2308 {
2309         float i;
2310         float nmax, smax;
2311
2312         MapVote_ClearAllVotes();
2313
2314         mapvote_count = 0;
2315         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2316         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2317
2318         if(mapvote_abstain)
2319                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2320         else
2321                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2322         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2323
2324         // we need this for AddVotable, as that cycles through the screenshot dirs
2325         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2326         if(mapvote_screenshot_dirs_count == 0)
2327                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2328         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2329         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2330                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2331
2332         if(mapvote_suggestion_ptr)
2333                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2334                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2335
2336         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2337                 MapVote_AddVotable(GetNextMap(), FALSE);
2338
2339         if(mapvote_count == 0)
2340         {
2341                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2342                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2343                 if(autocvar_g_maplist_shuffle)
2344                         ShuffleMaplist();
2345                 localcmd("\nmenu_cmd sync\n");
2346                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2347                         MapVote_AddVotable(GetNextMap(), FALSE);
2348         }
2349
2350         mapvote_count_real = mapvote_count;
2351         if(mapvote_abstain)
2352                 MapVote_AddVotable("don't care", 0);
2353
2354         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2355
2356         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2357         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2358         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2359                 mapvote_keeptwotime = 0;
2360         mapvote_message = "Choose a map and press its key!";
2361
2362         MapVote_Spawn();
2363 }
2364
2365 void MapVote_SendPicture(float id)
2366 {
2367         msg_entity = self;
2368         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2369         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2370         WriteByte(MSG_ONE, id);
2371         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2372 }
2373
2374 float MapVote_GetMapMask()
2375 {
2376         float mask, i, power;
2377         mask = 0;
2378         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2379                 if(mapvote_maps[i] != "")
2380                         mask |= power;
2381         return mask;
2382 }
2383
2384 entity mapvote_ent;
2385 float MapVote_SendEntity(entity to, float sf)
2386 {
2387         float i;
2388
2389         if(sf & 1)
2390                 sf &= ~2; // if we send 1, we don't need to also send 2
2391
2392         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2393         WriteByte(MSG_ENTITY, sf);
2394
2395         if(sf & 1)
2396         {
2397                 // flag 1 == initialization
2398                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2399                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2400                 WriteString(MSG_ENTITY, "");
2401                 WriteByte(MSG_ENTITY, mapvote_count);
2402                 WriteByte(MSG_ENTITY, mapvote_abstain);
2403                 WriteByte(MSG_ENTITY, mapvote_detail);
2404                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2405                 if(mapvote_count <= 8)
2406                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2407                 else
2408                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2409                 for(i = 0; i < mapvote_count; ++i)
2410                         if(mapvote_maps[i] != "")
2411                         {
2412                                 if(mapvote_abstain && i == mapvote_count - 1)
2413                                 {
2414                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2415                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2416                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2417                                 }
2418                                 else
2419                                 {
2420                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2421                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2422                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2423                                 }
2424                         }
2425         }
2426
2427         if(sf & 2)
2428         {
2429                 // flag 2 == update of mask
2430                 if(mapvote_count <= 8)
2431                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2432                 else
2433                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2434         }
2435
2436         if(sf & 4)
2437         {
2438                 if(mapvote_detail)
2439                         for(i = 0; i < mapvote_count; ++i)
2440                                 if(mapvote_maps[i] != "")
2441                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2442
2443                 WriteByte(MSG_ENTITY, to.mapvote);
2444         }
2445
2446         return TRUE;
2447 }
2448
2449 void MapVote_Spawn()
2450 {
2451         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2452 }
2453
2454 void MapVote_TouchMask()
2455 {
2456         mapvote_ent.SendFlags |= 2;
2457 }
2458
2459 void MapVote_TouchVotes(entity voter)
2460 {
2461         mapvote_ent.SendFlags |= 4;
2462 }
2463
2464 float MapVote_Finished(float mappos)
2465 {
2466         string result;
2467         float i;
2468         float didntvote;
2469
2470         if(autocvar_sv_eventlog)
2471         {
2472                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2473                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2474                 didntvote = mapvote_voters;
2475                 for(i = 0; i < mapvote_count; ++i)
2476                         if(mapvote_maps[i] != "")
2477                         {
2478                                 didntvote -= mapvote_selections[i];
2479                                 if(i != mappos)
2480                                 {
2481                                         result = strcat(result, ":", mapvote_maps[i]);
2482                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2483                                 }
2484                         }
2485                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2486
2487                 GameLogEcho(result);
2488                 if(mapvote_maps_suggested[mappos])
2489                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2490         }
2491
2492         FOR_EACH_REALCLIENT(other)
2493                 FixClientCvars(other);
2494
2495         Map_Goto_SetStr(mapvote_maps[mappos]);
2496         Map_Goto(0);
2497         alreadychangedlevel = TRUE;
2498         return TRUE;
2499 }
2500 void MapVote_CheckRules_1()
2501 {
2502         float i;
2503
2504         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2505         {
2506                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2507                 mapvote_selections[i] = 0;
2508         }
2509
2510         mapvote_voters = 0;
2511         FOR_EACH_REALCLIENT(other)
2512         {
2513                 ++mapvote_voters;
2514                 if(other.mapvote)
2515                 {
2516                         i = other.mapvote - 1;
2517                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2518                         mapvote_selections[i] = mapvote_selections[i] + 1;
2519                 }
2520         }
2521 }
2522
2523 float MapVote_CheckRules_2()
2524 {
2525         float i;
2526         float firstPlace, secondPlace;
2527         float firstPlaceVotes, secondPlaceVotes;
2528         float mapvote_voters_real;
2529         string result;
2530
2531         if(mapvote_count_real == 1)
2532                 return MapVote_Finished(0);
2533
2534         mapvote_voters_real = mapvote_voters;
2535         if(mapvote_abstain)
2536                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2537
2538         RandomSelection_Init();
2539         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2540                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2541         firstPlace = RandomSelection_chosen_float;
2542         firstPlaceVotes = RandomSelection_best_priority;
2543         //dprint("First place: ", ftos(firstPlace), "\n");
2544         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2545
2546         RandomSelection_Init();
2547         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2548                 if(i != firstPlace)
2549                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2550         secondPlace = RandomSelection_chosen_float;
2551         secondPlaceVotes = RandomSelection_best_priority;
2552         //dprint("Second place: ", ftos(secondPlace), "\n");
2553         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2554
2555         if(firstPlace == -1)
2556                 error("No first place in map vote... WTF?");
2557
2558         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2559                 return MapVote_Finished(firstPlace);
2560
2561         if(mapvote_keeptwotime)
2562                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2563                 {
2564                         float didntvote;
2565                         MapVote_TouchMask();
2566                         mapvote_message = "Now decide between the TOP TWO!";
2567                         mapvote_keeptwotime = 0;
2568                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2569                         result = strcat(result, ":", ftos(firstPlaceVotes));
2570                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2571                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2572                         didntvote = mapvote_voters;
2573                         for(i = 0; i < mapvote_count; ++i)
2574                                 if(mapvote_maps[i] != "")
2575                                 {
2576                                         didntvote -= mapvote_selections[i];
2577                                         if(i != firstPlace)
2578                                                 if(i != secondPlace)
2579                                                 {
2580                                                         result = strcat(result, ":", mapvote_maps[i]);
2581                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2582                                                         if(i < mapvote_count_real)
2583                                                         {
2584                                                                 strunzone(mapvote_maps[i]);
2585                                                                 mapvote_maps[i] = "";
2586                                                                 strunzone(mapvote_maps_pakfile[i]);
2587                                                                 mapvote_maps_pakfile[i] = "";
2588                                                         }
2589                                                 }
2590                                 }
2591                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2592                         if(autocvar_sv_eventlog)
2593                                 GameLogEcho(result);
2594                 }
2595
2596         return FALSE;
2597 }
2598 void MapVote_Tick()
2599 {
2600         float keeptwo;
2601         float totalvotes;
2602
2603         keeptwo = mapvote_keeptwotime;
2604         MapVote_CheckRules_1(); // count
2605         if(MapVote_CheckRules_2()) // decide
2606                 return;
2607
2608         totalvotes = 0;
2609         FOR_EACH_REALCLIENT(other)
2610         {
2611                 // hide scoreboard again
2612                 if(other.health != 2342)
2613                 {
2614                         other.health = 2342;
2615                         other.impulse = 0;
2616                         if(IS_REAL_CLIENT(other))
2617                         {
2618                                 msg_entity = other;
2619                                 WriteByte(MSG_ONE, SVC_FINALE);
2620                                 WriteString(MSG_ONE, "");
2621                         }
2622                 }
2623
2624                 // clear possibly invalid votes
2625                 if(mapvote_maps[other.mapvote - 1] == "")
2626                         other.mapvote = 0;
2627                 // use impulses as new vote
2628                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2629                         if(mapvote_maps[other.impulse - 1] != "")
2630                         {
2631                                 other.mapvote = other.impulse;
2632                                 MapVote_TouchVotes(other);
2633                         }
2634                 other.impulse = 0;
2635
2636                 if(other.mapvote)
2637                         ++totalvotes;
2638         }
2639
2640         MapVote_CheckRules_1(); // just count
2641 }
2642 void MapVote_Start()
2643 {
2644         if(mapvote_run)
2645                 return;
2646
2647         // wait for stats to be sent first
2648         if(!playerstats_waitforme)
2649                 return;
2650
2651         MapInfo_Enumerate();
2652         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2653                 mapvote_run = TRUE;
2654 }
2655 void MapVote_Think()
2656 {
2657         if(!mapvote_run)
2658                 return;
2659
2660         if(alreadychangedlevel)
2661                 return;
2662
2663         if(time < mapvote_nextthink)
2664                 return;
2665         //dprint("tick\n");
2666
2667         mapvote_nextthink = time + 0.5;
2668
2669         if(!mapvote_initialized)
2670         {
2671                 if(autocvar_rescan_pending == 1)
2672                 {
2673                         cvar_set("rescan_pending", "2");
2674                         localcmd("fs_rescan\nrescan_pending 3\n");
2675                         return;
2676                 }
2677                 else if(autocvar_rescan_pending == 2)
2678                 {
2679                         return;
2680                 }
2681                 else if(autocvar_rescan_pending == 3)
2682                 {
2683                         // now build missing mapinfo files
2684                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2685                                 return;
2686
2687                         // we're done, start the timer
2688                         cvar_set("rescan_pending", "0");
2689                 }
2690
2691                 mapvote_initialized = TRUE;
2692                 if(DoNextMapOverride(0))
2693                         return;
2694                 if(!autocvar_g_maplist_votable || player_count <= 0)
2695                 {
2696                         GotoNextMap(0);
2697                         return;
2698                 }
2699                 MapVote_Init();
2700         }
2701
2702         MapVote_Tick();
2703 }
2704
2705 string GotoMap(string m)
2706 {
2707         if(!MapInfo_CheckMap(m))
2708                 return "The map you chose is not available on this server.";
2709         cvar_set("nextmap", m);
2710         cvar_set("timelimit", "-1");
2711         if(mapvote_initialized || alreadychangedlevel)
2712         {
2713                 if(DoNextMapOverride(0))
2714                         return "Map switch initiated.";
2715                 else
2716                         return "Hm... no. For some reason I like THIS map more.";
2717         }
2718         else
2719                 return "Map switch will happen after scoreboard.";
2720 }
2721
2722
2723 void EndFrame()
2724 {
2725         float altime;
2726         FOR_EACH_REALCLIENT(self)
2727         {
2728                 if(IS_SPEC(self))
2729                 {
2730                         if(self.enemy.typehitsound)
2731                                 self.typehit_time = time;
2732                         else if(self.enemy.hitsound)
2733                                 self.hit_time = time;
2734                 }
2735                 else
2736                 {
2737                         if(self.typehitsound)
2738                                 self.typehit_time = time;
2739                         else if(self.hitsound)
2740                                 self.hit_time = time;
2741                 }
2742         }
2743         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2744         // add 1 frametime because after this, engine SV_Physics
2745         // increases time by a frametime and then networks the frame
2746         // add another frametime because client shows everything with
2747         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2748         // needed!
2749         FOR_EACH_CLIENT(self)
2750         {
2751                 self.hitsound = FALSE;
2752                 self.typehitsound = FALSE;
2753                 antilag_record(self, altime);
2754         }
2755 }
2756
2757
2758 /*
2759  * RedirectionThink:
2760  * returns TRUE if redirecting
2761  */
2762 float redirection_timeout;
2763 float redirection_nextthink;
2764 float RedirectionThink()
2765 {
2766         float clients_found;
2767
2768         if(redirection_target == "")
2769                 return FALSE;
2770
2771         if(!redirection_timeout)
2772         {
2773                 cvar_set("sv_public", "-2");
2774                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2775                 if(redirection_target == "self")
2776                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2777                 else
2778                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2779         }
2780
2781         if(time < redirection_nextthink)
2782                 return TRUE;
2783
2784         redirection_nextthink = time + 1;
2785
2786         clients_found = 0;
2787         FOR_EACH_REALCLIENT(self)
2788         {
2789                 // TODO add timer
2790                 print("Redirecting: sending connect command to ", self.netname, "\n");
2791                 if(redirection_target == "self")
2792                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2793                 else
2794                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2795                 ++clients_found;
2796         }
2797
2798         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2799
2800         if(time > redirection_timeout || clients_found == 0)
2801                 localcmd("\nwait; wait; wait; quit\n");
2802
2803         return TRUE;
2804 }
2805
2806 void TargetMusic_RestoreGame();
2807 void RestoreGame()
2808 {
2809         // Loaded from a save game
2810         // some things then break, so let's work around them...
2811
2812         // Progs DB (capture records)
2813         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2814
2815         // Mapinfo
2816         MapInfo_Shutdown();
2817         MapInfo_Enumerate();
2818         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2819         WeaponStats_Init();
2820
2821         TargetMusic_RestoreGame();
2822 }
2823
2824 void Shutdown()
2825 {
2826         entity e;
2827
2828         gameover = 2;
2829
2830         if(world_initialized > 0)
2831         {
2832                 world_initialized = 0;
2833                 print("Saving persistent data...\n");
2834                 Ban_SaveBans();
2835
2836                 PlayerStats_EndMatch(0);
2837                 FOR_EACH_CLIENT(e)
2838                         PlayerStats_AddGlobalInfo(e);
2839                 PlayerStats_Shutdown();
2840
2841                 if(!cheatcount_total)
2842                 {
2843                         if(autocvar_sv_db_saveasdump)
2844                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2845                         else
2846                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2847                 }
2848                 if(autocvar_developer)
2849                 {
2850                         if(autocvar_sv_db_saveasdump)
2851                                 db_dump(TemporaryDB, "server-temp.db");
2852                         else
2853                                 db_save(TemporaryDB, "server-temp.db");
2854                 }
2855                 CheatShutdown(); // must be after cheatcount check
2856                 db_close(ServerProgsDB);
2857                 db_close(TemporaryDB);
2858                 print("done!\n");
2859                 // tell the bot system the game is ending now
2860                 bot_endgame();
2861
2862                 WeaponStats_Shutdown();
2863                 MapInfo_Shutdown();
2864         }
2865         else if(world_initialized == 0)
2866         {
2867                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2868         }
2869 }