qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap(float reinit);
  48 void ShuffleMaplist()
  49 float(float reinit) DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 void GotoFirstMap()
  99 {
 100         float n;
 101         if(autocvar__sv_init)
 102         {
 103                 // cvar_set("_sv_init", "0");
 104                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 105                 // to this "init" map on a dedicated server will cause no permanent
 106                 // harm
 107                 if(autocvar_g_maplist_shuffle)
 108                         ShuffleMaplist();
 109                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 110                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 111
 112                 MapInfo_Enumerate();
 113                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 114
 115                 if(!DoNextMapOverride(1))
 116                         GotoNextMap(1);
 117
 118                 return;
 119         }
 120
 121         if(time < 5)
 122         {
 123                 self.nextthink = time;
 124         }
 125         else
 126         {
 127                 self.nextthink = time + 1;
 128                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 129         }
 130 }
 131
 132 void cvar_changes_init()
 133 {
 134         float h;
 135         string k, v, d;
 136         float n, i, adding, pureadding;
 137
 138         if(cvar_changes)
 139                 strunzone(cvar_changes);
 140         cvar_changes = string_null;
 141         if(cvar_purechanges)
 142                 strunzone(cvar_purechanges);
 143         cvar_purechanges = string_null;
 144         cvar_purechanges_count = 0;
 145
 146         h = buf_create();
 147         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 148         n = buf_getsize(h);
 149
 150         adding = TRUE;
 151         pureadding = TRUE;
 152
 153         for(i = 0; i < n; ++i)
 154         {
 155                 k = bufstr_get(h, i);
 156
 157 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 158 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 159 #define BADCVAR(p) if(k == p) continue
 160
 161                 // general excludes and namespaces for server admin used cvars
 162                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 163
 164                 // internal
 165                 BADPREFIX("csqc_");
 166                 BADPREFIX("cvar_check_");
 167                 BADCVAR("gamecfg");
 168                 BADCVAR("g_configversion");
 169                 BADCVAR("g_maplist_index");
 170                 BADCVAR("halflifebsp");
 171                 BADPREFIX("sv_world");
 172
 173                 // client
 174                 BADPREFIX("chase_");
 175                 BADPREFIX("cl_");
 176                 BADPREFIX("con_");
 177                 BADPREFIX("scoreboard_");
 178                 BADPREFIX("g_campaign");
 179                 BADPREFIX("g_waypointsprite_");
 180                 BADPREFIX("gl_");
 181                 BADPREFIX("joy");
 182                 BADPREFIX("hud_");
 183                 BADPREFIX("m_");
 184                 BADPREFIX("menu_");
 185                 BADPREFIX("net_slist_");
 186                 BADPREFIX("r_");
 187                 BADPREFIX("sbar_");
 188                 BADPREFIX("scr_");
 189                 BADPREFIX("snd_");
 190                 BADPREFIX("show");
 191                 BADPREFIX("sensitivity");
 192                 BADPREFIX("userbind");
 193                 BADPREFIX("v_");
 194                 BADPREFIX("vid_");
 195                 BADPREFIX("crosshair");
 196                 BADCVAR("mod_q3bsp_lightmapmergepower");
 197                 BADCVAR("mod_q3bsp_nolightmaps");
 198                 BADCVAR("fov");
 199                 BADCVAR("mastervolume");
 200                 BADCVAR("volume");
 201                 BADCVAR("bgmvolume");
 202
 203                 // private
 204                 BADCVAR("developer");
 205                 BADCVAR("log_dest_udp");
 206                 BADCVAR("log_file");
 207                 BADCVAR("net_address");
 208                 BADCVAR("net_address_ipv6");
 209                 BADCVAR("port");
 210                 BADCVAR("savedgamecfg");
 211                 BADCVAR("serverconfig");
 212                 BADCVAR("sv_autoscreenshot");
 213                 BADCVAR("sv_heartbeatperiod");
 214                 BADCVAR("sv_vote_master_password");
 215                 BADCVAR("sys_colortranslation");
 216                 BADCVAR("sys_specialcharactertranslation");
 217                 BADCVAR("timeformat");
 218                 BADCVAR("timestamps");
 219                 BADPREFIX("developer_");
 220                 BADPREFIX("g_ban_");
 221                 BADPREFIX("g_banned_list");
 222                 BADPREFIX("g_chat_flood_");
 223                 BADPREFIX("g_ghost_items");
 224                 BADPREFIX("g_playerstats_");
 225                 BADPREFIX("g_respawn_ghosts");
 226                 BADPREFIX("g_voice_flood_");
 227                 BADPREFIX("rcon_");
 228                 BADPREFIX("sv_allowdownloads");
 229                 BADPREFIX("sv_autodemo");
 230                 BADPREFIX("sv_curl_");
 231                 BADPREFIX("sv_eventlog");
 232                 BADPREFIX("sv_logscores_");
 233                 BADPREFIX("sv_master");
 234                 BADPREFIX("sv_weaponstats_");
 235                 BADPREFIX("sv_waypointsprite_");
 236                 BADCVAR("rescan_pending");
 237
 238                 // these can contain player IDs, so better hide
 239                 BADPREFIX("g_forced_team_");
 240
 241                 // mapinfo
 242                 BADCVAR("fraglimit");
 243                 BADCVAR("g_arena");
 244                 BADCVAR("g_assault");
 245                 BADCVAR("g_ca");
 246                 BADCVAR("g_ctf");
 247                 BADCVAR("g_cts");
 248                 BADCVAR("g_dm");
 249                 BADCVAR("g_domination");
 250                 BADCVAR("g_domination_default_teams");
 251                 BADCVAR("g_freezetag");
 252                 BADCVAR("g_keepaway");
 253                 BADCVAR("g_keyhunt");
 254                 BADCVAR("g_keyhunt_teams");
 255                 BADCVAR("g_keyhunt_teams");
 256                 BADCVAR("g_lms");
 257                 BADCVAR("g_nexball");
 258                 BADCVAR("g_onslaught");
 259                 BADCVAR("g_race");
 260                 BADCVAR("g_race_qualifying_timelimit");
 261                 BADCVAR("g_runematch");
 262                 BADCVAR("g_tdm");
 263                 BADCVAR("g_tdm_teams");
 264                 BADCVAR("leadlimit");
 265                 BADCVAR("nextmap");
 266                 BADCVAR("teamplay");
 267                 BADCVAR("timelimit");
 268
 269                 // long
 270                 BADCVAR("hostname");
 271                 BADCVAR("g_maplist");
 272                 BADCVAR("g_maplist_mostrecent");
 273                 BADCVAR("sv_motd");
 274
 275                 v = cvar_string(k);
 276                 d = cvar_defstring(k);
 277                 if(v == d)
 278                         continue;
 279
 280                 if(adding)
 281                 {
 282                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 283                         if(strlen(cvar_changes) > 16384)
 284                         {
 285                                 cvar_changes = "// too many settings have been changed to show them here\n";
 286                                 adding = 0;
 287                         }
 288                 }
 289
 290                 // now check if the changes are actually gameplay relevant
 291
 292                 // does nothing visible
 293                 BADCVAR("captureleadlimit_override");
 294                 BADCVAR("g_arena_point_leadlimit");
 295                 BADCVAR("g_balance_kill_delay");
 296                 BADCVAR("g_ca_point_leadlimit");
 297                 BADCVAR("g_ctf_captimerecord_always");
 298                 BADCVAR("g_ctf_flag_capture_effects");
 299                 BADCVAR("g_ctf_flag_glowtrails");
 300                 BADCVAR("g_ctf_flag_pickup_effects");
 301                 BADCVAR("g_domination_point_leadlimit");
 302                 BADCVAR("g_forced_respawn");
 303                 BADCVAR("g_keyhunt_point_leadlimit");
 304                 BADPREFIX("g_mod_");
 305                 BADCVAR("g_nexball_goalleadlimit");
 306                 BADCVAR("g_runematch_point_leadlimit");
 307                 BADCVAR("leadlimit_and_fraglimit");
 308                 BADCVAR("leadlimit_override");
 309                 BADCVAR("pausable");
 310                 BADCVAR("sv_allow_fullbright");
 311                 BADCVAR("sv_checkforpacketsduringsleep");
 312                 BADCVAR("sv_fraginfo");
 313                 BADCVAR("sv_timeout");
 314                 BADPREFIX("sv_timeout_");
 315                 BADCVAR("welcome_message_time");
 316                 BADPREFIX("crypto_");
 317                 BADPREFIX("g_chat_");
 318                 BADPREFIX("g_ctf_captimerecord_");
 319                 BADPREFIX("g_maplist_votable_");
 320                 BADPREFIX("net_");
 321                 BADPREFIX("prvm_");
 322                 BADPREFIX("skill_");
 323                 BADPREFIX("sv_cullentities_");
 324                 BADPREFIX("sv_fraginfo_");
 325                 BADPREFIX("sv_maxidle_");
 326                 BADPREFIX("sv_vote_");
 327                 BADPREFIX("timelimit_");
 328                 BADCVAR("gameversion");
 329                 BADPREFIX("gameversion_");
 330                 BADCVAR("sv_namechangetimer");
 331 #ifndef NO_LEGACY_NETWORKING
 332                 BADCVAR("sv_use_csqc_players"); // transition
 333 #endif
 334
 335                 // allowed changes to server admins (please sync this to server.cfg)
 336                 // vi commands:
 337                 //   :/"impure"/,$d
 338                 //   :g!,^\/\/[^ /],d
 339                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 340                 //   :%!sort
 341                 // yes, this does contain some redundant stuff, don't really care
 342                 BADCVAR("bot_config_file");
 343                 BADCVAR("bot_number");
 344                 BADCVAR("bot_prefix");
 345                 BADCVAR("bot_suffix");
 346                 BADCVAR("capturelimit_override");
 347                 BADCVAR("fraglimit_override");
 348                 BADCVAR("gametype");
 349                 BADCVAR("g_antilag");
 350                 BADCVAR("g_balance_teams");
 351                 BADCVAR("g_balance_teams_force");
 352                 BADCVAR("g_ban_sync_trusted_servers");
 353                 BADCVAR("g_ban_sync_uri");
 354                 BADCVAR("g_ctf_ignore_frags");
 355                 BADCVAR("g_domination_point_limit");
 356                 BADCVAR("g_friendlyfire");
 357                 BADCVAR("g_fullbrightitems");
 358                 BADCVAR("g_fullbrightplayers");
 359                 BADCVAR("g_keyhunt_point_limit");
 360                 BADCVAR("g_keyhunt_teams_override");
 361                 BADCVAR("g_lms_lives_override");
 362                 BADCVAR("g_maplist");
 363                 BADCVAR("g_maplist_check_waypoints");
 364                 BADCVAR("g_maplist_mostrecent_count");
 365                 BADCVAR("g_maplist_shuffle");
 366                 BADCVAR("g_maplist_votable");
 367                 BADCVAR("g_maplist_votable_abstain");
 368                 BADCVAR("g_maplist_votable_nodetail");
 369                 BADCVAR("g_maplist_votable_suggestions");
 370                 BADCVAR("g_maxplayers");
 371                 BADCVAR("g_mirrordamage");
 372                 BADCVAR("g_nexball_goallimit");
 373                 BADCVAR("g_powerups");
 374                 BADCVAR("g_runematch_point_limit");
 375                 BADCVAR("g_start_delay");
 376                 BADCVAR("g_warmup");
 377                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 378                 BADCVAR("hostname");
 379                 BADCVAR("log_file");
 380                 BADCVAR("maxplayers");
 381                 BADCVAR("minplayers");
 382                 BADCVAR("net_address");
 383                 BADCVAR("port");
 384                 BADCVAR("rcon_password");
 385                 BADCVAR("rcon_restricted_commands");
 386                 BADCVAR("rcon_restricted_password");
 387                 BADCVAR("skill");
 388                 BADCVAR("sv_adminnick");
 389                 BADCVAR("sv_autoscreenshot");
 390                 BADCVAR("sv_autotaunt");
 391                 BADCVAR("sv_curl_defaulturl");
 392                 BADCVAR("sv_defaultcharacter");
 393                 BADCVAR("sv_defaultplayercolors");
 394                 BADCVAR("sv_defaultplayermodel");
 395                 BADCVAR("sv_defaultplayerskin");
 396                 BADCVAR("sv_maxidle");
 397                 BADCVAR("sv_maxrate");
 398                 BADCVAR("sv_motd");
 399                 BADCVAR("sv_public");
 400                 BADCVAR("sv_ready_restart");
 401                 BADCVAR("sv_status_privacy");
 402                 BADCVAR("sv_taunt");
 403                 BADCVAR("sv_vote_call");
 404                 BADCVAR("sv_vote_commands");
 405                 BADCVAR("sv_vote_majority_factor");
 406                 BADCVAR("sv_vote_master");
 407                 BADCVAR("sv_vote_master_commands");
 408                 BADCVAR("sv_vote_master_password");
 409                 BADCVAR("sv_vote_simple_majority_factor");
 410                 BADCVAR("sys_ticrate");
 411                 BADCVAR("teamplay_mode");
 412                 BADCVAR("timelimit_override");
 413                 BADCVAR("g_spawnshieldtime");
 414                 BADPREFIX("g_warmup_");
 415                 BADPREFIX("sv_ready_restart_");
 416
 417                 // mutators that announce themselves properly to the server browser
 418                 BADCVAR("g_minstagib");
 419                 BADCVAR("g_new_toys");
 420                 BADCVAR("g_nix");
 421
 422                 if(autocvar_g_minstagib)
 423                 {
 424                         BADCVAR("g_grappling_hook");
 425                         BADCVAR("g_jetpack");
 426                 }
 427 #undef BADPREFIX
 428 #undef BADCVAR
 429
 430                 if(pureadding)
 431                 {
 432                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 433                         if(strlen(cvar_purechanges) > 16384)
 434                         {
 435                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 436                                 pureadding = 0;
 437                         }
 438                 }
 439                 ++cvar_purechanges_count;
 440                 // WARNING: this variable is used for the server list
 441                 // NEVER dare to skip this code!
 442                 // Hacks to intentionally appearing as "pure server" even though you DO have
 443                 // modified settings may be punished by removal from the server list.
 444                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 445                 // though.
 446         }
 447         buf_del(h);
 448         if(cvar_changes == "")
 449                 cvar_changes = "// this server runs at default server settings\n";
 450         else
 451                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 452         cvar_changes = strzone(cvar_changes);
 453         if(cvar_purechanges == "")
 454                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 455         else
 456                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 457         cvar_purechanges = strzone(cvar_purechanges);
 458 }
 459
 460 void detect_maptype()
 461 {
 462 #if 0
 463         vector o, v;
 464         float i;
 465
 466         for(;;)
 467         {
 468                 o = world.mins;
 469                 o_x += random() * (world.maxs_x - world.mins_x);
 470                 o_y += random() * (world.maxs_y - world.mins_y);
 471                 o_z += random() * (world.maxs_z - world.mins_z);
 472
 473                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 474                 if(trace_fraction == 1)
 475                         continue;
 476
 477                 v = trace_endpos;
 478
 479                 for(i = 0; i < 64; i += 4)
 480                 {
 481                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 482         if(trace_fraction == 1)
 483                 continue;
 484                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 485                 }
 486
 487                 break;
 488         }
 489 #endif
 490 }
 491
 492 entity randomseed;
 493 float RandomSeed_Send(entity to, float sf)
 494 {
 495         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 496         WriteShort(MSG_ENTITY, self.cnt);
 497         return TRUE;
 498 }
 499 void RandomSeed_Think()
 500 {
 501         self.cnt = bound(0, floor(random() * 65536), 65535);
 502         self.nextthink = time + 5;
 503
 504         self.SendFlags |= 1;
 505 }
 506 void RandomSeed_Spawn()
 507 {
 508         randomseed = spawn();
 509         randomseed.think = RandomSeed_Think;
 510         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 511
 512         entity oldself;
 513         oldself = self;
 514         self = randomseed;
 515         self.think(); // sets random seed and nextthink
 516         self = oldself;
 517 }
 518
 519 void spawnfunc___init_dedicated_server(void)
 520 {
 521         // handler for _init/_init map (only for dedicated server initialization)
 522
 523         world_initialized = -1; // don't complain
 524         cvar = cvar_normal;
 525         cvar_string = cvar_string_normal;
 526         cvar_set = cvar_set_normal;
 527
 528         remove = remove_unsafely;
 529
 530         entity e;
 531         e = spawn();
 532         e.think = GotoFirstMap;
 533         e.nextthink = time; // this is usually 1 at this point
 534
 535         e = spawn();
 536         e.classname = "info_player_deathmatch"; // safeguard against player joining
 537
 538         self.classname = "worldspawn"; // safeguard against various stuff ;)
 539
 540         // needs to be done so early because of the constants they create
 541         RegisterWeapons();
 542         RegisterGametypes();
 543
 544         MapInfo_Enumerate();
 545         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 546 }
 547
 548 void Map_MarkAsRecent(string m);
 549 float world_already_spawned;
 550 void RegisterWeapons();
 551 void Nagger_Init();
 552 void ClientInit_Spawn();
 553 void WeaponStats_Init();
 554 void WeaponStats_Shutdown();
 555 void spawnfunc_worldspawn (void)
 556 {
 557         float fd, l, i, j, n;
 558         string s, col;
 559
 560         cvar = cvar_normal;
 561         cvar_string = cvar_string_normal;
 562         cvar_set = cvar_set_normal;
 563
 564         if(world_already_spawned)
 565                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 566         world_already_spawned = TRUE;
 567
 568         remove = remove_safely; // during spawning, watch what you remove!
 569
 570         check_unacceptable_compiler_bugs();
 571
 572         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 573
 574         compressShortVector_init();
 575
 576         allowed_to_spawn = TRUE;
 577
 578         entity head;
 579         head = nextent(world);
 580         maxclients = 0;
 581         while(head)
 582         {
 583                 ++maxclients;
 584                 head = nextent(head);
 585         }
 586
 587         // needs to be done so early because of the constants they create
 588         RegisterWeapons();
 589         RegisterGametypes();
 590
 591         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 592
 593         TemporaryDB = db_create();
 594
 595         // 0 normal
 596         lightstyle(0, "m");
 597
 598         // 1 FLICKER (first variety)
 599         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 600
 601         // 2 SLOW STRONG PULSE
 602         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 603
 604         // 3 CANDLE (first variety)
 605         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 606
 607         // 4 FAST STROBE
 608         lightstyle(4, "mamamamamama");
 609
 610         // 5 GENTLE PULSE 1
 611         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 612
 613         // 6 FLICKER (second variety)
 614         lightstyle(6, "nmonqnmomnmomomno");
 615
 616         // 7 CANDLE (second variety)
 617         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 618
 619         // 8 CANDLE (third variety)
 620         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 621
 622         // 9 SLOW STROBE (fourth variety)
 623         lightstyle(9, "aaaaaaaazzzzzzzz");
 624
 625         // 10 FLUORESCENT FLICKER
 626         lightstyle(10, "mmamammmmammamamaaamammma");
 627
 628         // 11 SLOW PULSE NOT FADE TO BLACK
 629         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 630
 631         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 632
 633         // 63 testing
 634         lightstyle(63, "a");
 635
 636         if(autocvar_g_campaign)
 637                 CampaignPreInit();
 638
 639         Map_MarkAsRecent(mapname);
 640
 641         precache_model ("null"); // we need this one before InitGameplayMode
 642         InitGameplayMode();
 643         readlevelcvars();
 644         GrappleHookInit();
 645         ElectroInit();
 646         LaserInit();
 647
 648         player_count = 0;
 649         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 650         if(bot_waypoints_for_items == 1)
 651                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 652                         bot_waypoints_for_items = 0;
 653
 654         precache();
 655
 656         WaypointSprite_Init();
 657
 658         //if (g_domination)
 659         //      dom_init();
 660
 661         GameLogInit(); // prepare everything
 662         // NOTE for matchid:
 663         // changing the logic generating it is okay. But:
 664         // it HAS to stay <= 64 chars
 665         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 666         if(autocvar_sv_eventlog)
 667         {
 668                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 669                 matchid = strzone(s);
 670
 671                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 672                 s = ":gameinfo:mutators:LIST";
 673
 674                 ret_string = s;
 675                 MUTATOR_CALLHOOK(BuildMutatorsString);
 676                 s = ret_string;
 677
 678                 // simple, probably not good in the mutator system
 679                 if(autocvar_g_grappling_hook)
 680                         s = strcat(s, ":grappling_hook");
 681
 682                 // initialiation stuff, not good in the mutator system
 683                 if(!autocvar_g_use_ammunition)
 684                         s = strcat(s, ":no_use_ammunition");
 685
 686                 // initialiation stuff, not good in the mutator system
 687                 if(autocvar_g_pickup_items == 0)
 688                         s = strcat(s, ":no_pickup_items");
 689                 if(autocvar_g_pickup_items > 0)
 690                         s = strcat(s, ":pickup_items");
 691
 692                 // initialiation stuff, not good in the mutator system
 693                 if(autocvar_g_weaponarena != "0")
 694                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 695
 696                 // TODO to mutator system
 697                 if(autocvar_g_norecoil)
 698                         s = strcat(s, ":norecoil");
 699
 700                 // TODO to mutator system
 701                 if(autocvar_g_midair)
 702                         s = strcat(s, ":midair");
 703
 704                 // TODO to mutator system
 705                 if(autocvar_g_minstagib)
 706                         s = strcat(s, ":minstagib");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_powerups == 0)
 710                         s = strcat(s, ":no_powerups");
 711                 if(autocvar_g_powerups > 0)
 712                         s = strcat(s, ":powerups");
 713
 714                 GameLogEcho(s);
 715                 GameLogEcho(":gameinfo:end");
 716         }
 717         else
 718                 matchid = strzone(ftos(random()));
 719
 720         cvar_set("nextmap", "");
 721
 722         SetDefaultAlpha();
 723
 724         if(autocvar_g_campaign)
 725                 CampaignPostInit();
 726
 727         fteqcc_testbugs();
 728
 729         Ban_LoadBans();
 730
 731         MapInfo_Enumerate();
 732         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 733
 734         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 735         {
 736                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 737                 if(fd != -1)
 738                 {
 739                         while((s = fgets(fd)))
 740                         {
 741                                 l = tokenize_console(s);
 742                                 if(l < 2)
 743                                         continue;
 744                                 if(argv(0) == "cd")
 745                                 {
 746                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 747                                         print("  cdtrack ", argv(2), "\n");
 748                                 }
 749                                 else if(argv(0) == "fog")
 750                                 {
 751                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 752                                         print("  \"fog\" \"", s, "\"\n");
 753                                 }
 754                                 else if(argv(0) == "set")
 755                                 {
 756                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 757                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 758                                 }
 759                                 else if(argv(0) != "//")
 760                                 {
 761                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 762                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 763                                 }
 764                         }
 765                         fclose(fd);
 766                 }
 767         }
 768
 769         WeaponStats_Init();
 770
 771         WEPSET_ADDSTAT();
 772         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 773         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 774         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 775         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 776         Nagger_Init();
 777
 778         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 779         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 780         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 781         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 782         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 783         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 784         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 785         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 786         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 787         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 788         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 789         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 790         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 791
 792         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 793         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 794
 795         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 796
 797         if(g_ca || g_freezetag)
 798         {
 799                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 800                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 801                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 802                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 803         }
 804         if(g_freezetag)
 805         {
 806                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 807                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 808         }
 809
 810         // g_movementspeed hack
 811         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 812         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 813         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 814         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 815
 816         // secrets
 817         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 818         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 819
 820         next_pingtime = time + 5;
 821
 822         detect_maptype();
 823
 824         // set up information replies for clients and server to use
 825         lsmaps_reply = "^7Maps available: ";
 826         lsnewmaps_reply = "^7Maps without a record set: ";
 827         for(i = 0, j = 0; i < MapInfo_count; ++i)
 828         {
 829                 if(MapInfo_Get_ByID(i))
 830                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 831                         {
 832                                 if(mod(i, 2))
 833                                         col = "^2";
 834                                 else
 835                                         col = "^3";
 836
 837                                 ++j;
 838
 839                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 840
 841                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 842                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 843                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 844                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 845                         }
 846         }
 847
 848         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 849         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 850
 851         maplist_reply = "^7Maps in list: ";
 852         n = tokenize_console(autocvar_g_maplist);
 853         for(i = 0, j = 0; i < n; ++i)
 854         {
 855                 if(MapInfo_CheckMap(argv(i)))
 856                 {
 857                         if(mod(j, 2))
 858                                 col = "^2";
 859                         else
 860                                 col = "^3";
 861                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 862                         ++j;
 863                 }
 864         }
 865         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 866         MapInfo_ClearTemps();
 867
 868         for(i = 0; i < 10; ++i)
 869         {
 870                 s = getrecords(i);
 871                 if (s)
 872                         records_reply[i] = strzone(s);
 873         }
 874
 875         ladder_reply = strzone(getladder());
 876
 877         rankings_reply = strzone(getrankings());
 878
 879         // begin other init
 880         ClientInit_Spawn();
 881         RandomSeed_Spawn();
 882         PingPLReport_Spawn();
 883
 884         CheatInit();
 885
 886         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 887
 888         // fill sv_curl_serverpackages from .serverpackage files
 889         if(autocvar_sv_curl_serverpackages_auto)
 890         {
 891                 s = "";
 892                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 893                 for(i = 0; i < n; ++i)
 894                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 895                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 896                                 s = strcat(s, " ", argv(i));
 897                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 898                 if(fd >= 0)
 899                 {
 900                         j = search_getsize(fd);
 901                         for(i = 0; i < j; ++i)
 902                                 s = strcat(s, " ", search_getfilename(fd, i));
 903                         search_end(fd);
 904                 }
 905                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 906                 if(fd >= 0)
 907                 {
 908                         j = search_getsize(fd);
 909                         for(i = 0; i < j; ++i)
 910                                 s = strcat(s, " ", search_getfilename(fd, i));
 911                         search_end(fd);
 912                 }
 913                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 914         }
 915
 916         PlayerStats_Init();
 917
 918         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 919         modname = "Xonotic";
 920         // physics/balance/config changes that count as mod
 921         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 922                 modname = cvar_string("g_mod_physics");
 923         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 924                 modname = cvar_string("g_mod_balance");
 925         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 926                 modname = cvar_string("g_mod_config");
 927         // weird mutators that deserve to count as mod
 928         if(autocvar_g_minstagib)
 929                 modname = "MinstaGib";
 930         // extra mutators that deserve to count as mod
 931         MUTATOR_CALLHOOK(SetModname);
 932         // weird game types that deserve to count as mod
 933         if(g_cts)
 934                 modname = "CTS";
 935         // save it for later
 936         modname = strzone(modname);
 937
 938         WinningConditionHelper(); // set worldstatus
 939
 940         world_initialized = 1;
 941 }
 942
 943 void spawnfunc_light (void)
 944 {
 945         //makestatic (self); // Who the f___ did that?
 946         remove(self);
 947 }
 948
 949 string GetGametype()
 950 {
 951         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 952 }
 953
 954 string getmapname_stored;
 955 string GetMapname()
 956 {
 957         return mapname;
 958 }
 959
 960 float Map_Count, Map_Current;
 961 string Map_Current_Name;
 962
 963 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 964 float GetMaplistPosition()
 965 {
 966         float pos, idx;
 967         string map;
 968
 969         map = GetMapname();
 970         idx = autocvar_g_maplist_index;
 971
 972         if(idx >= 0)
 973                 if(idx < Map_Count)
 974                         if(map == argv(idx))
 975                                 return idx;
 976
 977         for(pos = 0; pos < Map_Count; ++pos)
 978                 if(map == argv(pos))
 979                         return pos;
 980
 981         // resume normal maplist rotation if current map is not in g_maplist
 982         return idx;
 983 }
 984
 985 float MapHasRightSize(string map)
 986 {
 987         float fh;
 988         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 989         if(autocvar_g_maplist_check_waypoints)
 990         {
 991                 dprint("checkwp "); dprint(map);
 992                 if(!fexists(strcat("maps/", map, ".waypoints")))
 993                 {
 994                         dprint(": no waypoints\n");
 995                         return FALSE;
 996                 }
 997                 dprint(": has waypoints\n");
 998         }
 999
1000         // open map size restriction file
1001         dprint("opensize "); dprint(map);
1002         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1003         if(fh >= 0)
1004         {
1005                 float mapmin, mapmax;
1006                 dprint(": ok, ");
1007                 mapmin = stof(fgets(fh));
1008                 mapmax = stof(fgets(fh));
1009                 fclose(fh);
1010                 if(player_count < mapmin)
1011                 {
1012                         dprint("not enough\n");
1013                         return FALSE;
1014                 }
1015                 if(player_count > mapmax)
1016                 {
1017                         dprint("too many\n");
1018                         return FALSE;
1019                 }
1020                 dprint("right size\n");
1021                 return TRUE;
1022         }
1023         dprint(": not found\n");
1024         return TRUE;
1025 }
1026
1027 string Map_Filename(float position)
1028 {
1029         return strcat("maps/", argv(position), ".bsp");
1030 }
1031
1032 string strwords(string s, float w)
1033 {
1034         float endpos;
1035         for(endpos = 0; w && endpos >= 0; --w)
1036                 endpos = strstrofs(s, " ", endpos + 1);
1037         if(endpos < 0)
1038                 return s;
1039         else
1040                 return substring(s, 0, endpos);
1041 }
1042
1043 float strhasword(string s, string w)
1044 {
1045         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1046 }
1047
1048 void Map_MarkAsRecent(string m)
1049 {
1050         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1051 }
1052
1053 float Map_IsRecent(string m)
1054 {
1055         return strhasword(autocvar_g_maplist_mostrecent, m);
1056 }
1057
1058 float Map_Check(float position, float pass)
1059 {
1060         string filename;
1061         string map_next;
1062         map_next = argv(position);
1063         if(pass <= 1)
1064         {
1065                 if(Map_IsRecent(map_next))
1066                         return 0;
1067         }
1068         filename = Map_Filename(position);
1069         if(MapInfo_CheckMap(map_next))
1070         {
1071                 if(pass == 2)
1072                         return 1;
1073                 if(MapHasRightSize(map_next))
1074                         return 1;
1075                 return 0;
1076         }
1077         else
1078                 dprint( "Couldn't select '", filename, "'..\n" );
1079
1080         return 0;
1081 }
1082
1083 void Map_Goto_SetStr(string nextmapname)
1084 {
1085         if(getmapname_stored != "")
1086                 strunzone(getmapname_stored);
1087         if(nextmapname == "")
1088                 getmapname_stored = "";
1089         else
1090                 getmapname_stored = strzone(nextmapname);
1091 }
1092
1093 void Map_Goto_SetFloat(float position)
1094 {
1095         cvar_set("g_maplist_index", ftos(position));
1096         Map_Goto_SetStr(argv(position));
1097 }
1098
1099 void Map_Goto(float reinit)
1100 {
1101         MapInfo_LoadMap(getmapname_stored, reinit);
1102 }
1103
1104 // return codes of map selectors:
1105 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1106 //   -2 = permanent failure
1107 float() MaplistMethod_Iterate = // usual method
1108 {
1109         float pass, i;
1110
1111         for(pass = 1; pass <= 2; ++pass)
1112         {
1113                 for(i = 1; i < Map_Count; ++i)
1114                 {
1115                         float mapindex;
1116                         mapindex = mod(i + Map_Current, Map_Count);
1117                         if(Map_Check(mapindex, pass))
1118                                 return mapindex;
1119                 }
1120         }
1121         return -1;
1122 }
1123
1124 float() MaplistMethod_Repeat = // fallback method
1125 {
1126         if(Map_Check(Map_Current, 2))
1127                 return Map_Current;
1128         return -2;
1129 }
1130
1131 float() MaplistMethod_Random = // random map selection
1132 {
1133         float i, imax;
1134
1135         imax = 42;
1136
1137         for(i = 0; i <= imax; ++i)
1138         {
1139                 float mapindex;
1140                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1141                 if(Map_Check(mapindex, 1))
1142                         return mapindex;
1143         }
1144         return -1;
1145 }
1146
1147 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1148 // the exponent sets a bias on the map selection:
1149 // the higher the exponent, the less likely "shortly repeated" same maps are
1150 {
1151         float i, j, imax, insertpos;
1152
1153         imax = 42;
1154
1155         for(i = 0; i <= imax; ++i)
1156         {
1157                 string newlist;
1158
1159                 // now reinsert this at another position
1160                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1161                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1162                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1163                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1164
1165                 // insert the current map there
1166                 newlist = "";
1167                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1168                         newlist = strcat(newlist, " ", argv(j));
1169                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1170                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1171                         newlist = strcat(newlist, " ", argv(j));
1172                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1173                 cvar_set("g_maplist", newlist);
1174                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1175
1176                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1177                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1178                 if(Map_Check(Map_Current, 1))
1179                         return Map_Current;
1180         }
1181         return -1;
1182 }
1183
1184 void Maplist_Init()
1185 {
1186         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1187         if(Map_Count == 0)
1188         {
1189                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1190                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1191                 if(autocvar_g_maplist_shuffle)
1192                         ShuffleMaplist();
1193                 localcmd("\nmenu_cmd sync\n");
1194                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1195         }
1196         if(Map_Count == 0)
1197                 error("empty maplist, cannot select a new map");
1198         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1199
1200         if(Map_Current_Name)
1201                 strunzone(Map_Current_Name);
1202         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1203         // this may or may not be correct, but who cares, in the worst case a map
1204         // isn't chosen in the first pass that should have been
1205 }
1206
1207 string GetNextMap()
1208 {
1209         float nextMap;
1210
1211         Maplist_Init();
1212         nextMap = -1;
1213
1214         if(nextMap == -1)
1215                 if(autocvar_g_maplist_shuffle > 0)
1216                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1217
1218         if(nextMap == -1)
1219                 if(autocvar_g_maplist_selectrandom)
1220                         nextMap = MaplistMethod_Random();
1221
1222         if(nextMap == -1)
1223                 nextMap = MaplistMethod_Iterate();
1224
1225         if(nextMap == -1)
1226                 nextMap = MaplistMethod_Repeat();
1227
1228         if(nextMap >= 0)
1229         {
1230                 Map_Goto_SetFloat(nextMap);
1231                 return getmapname_stored;
1232         }
1233
1234         return "";
1235 }
1236
1237 float DoNextMapOverride(float reinit)
1238 {
1239         if(autocvar_g_campaign)
1240         {
1241                 CampaignPostIntermission();
1242                 alreadychangedlevel = TRUE;
1243                 return TRUE;
1244         }
1245         if(autocvar_quit_when_empty)
1246         {
1247                 if(player_count <= currentbots)
1248                 {
1249                         localcmd("quit\n");
1250                         alreadychangedlevel = TRUE;
1251                         return TRUE;
1252                 }
1253         }
1254         if(autocvar_quit_and_redirect != "")
1255         {
1256                 redirection_target = strzone(autocvar_quit_and_redirect);
1257                 alreadychangedlevel = TRUE;
1258                 return TRUE;
1259         }
1260         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1261         {
1262                 localcmd("restart\n");
1263                 alreadychangedlevel = TRUE;
1264                 return TRUE;
1265         }
1266         if(autocvar_nextmap != "")
1267                 if(MapInfo_CheckMap(autocvar_nextmap))
1268                 {
1269                         Map_Goto_SetStr(autocvar_nextmap);
1270                         Map_Goto(reinit);
1271                         alreadychangedlevel = TRUE;
1272                         return TRUE;
1273                 }
1274         if(!reinit && autocvar_lastlevel)
1275         {
1276                 cvar_settemp_restore();
1277                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1278                 alreadychangedlevel = TRUE;
1279                 return TRUE;
1280         }
1281         return FALSE;
1282 }
1283
1284 void GotoNextMap(float reinit)
1285 {
1286         //string nextmap;
1287         //float n, nummaps;
1288         //string s;
1289         if (alreadychangedlevel)
1290                 return;
1291         alreadychangedlevel = TRUE;
1292
1293         {
1294                 string nextMap;
1295                 float allowReset;
1296
1297                 for(allowReset = 1; allowReset >= 0; --allowReset)
1298                 {
1299                         nextMap = GetNextMap();
1300                         if(nextMap != "")
1301                                 break;
1302
1303                         if(allowReset)
1304                         {
1305                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1306                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1307                                 if(autocvar_g_maplist_shuffle)
1308                                         ShuffleMaplist();
1309                                 localcmd("\nmenu_cmd sync\n");
1310                         }
1311                         else
1312                         {
1313                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1314                         }
1315                 }
1316                 Map_Goto(reinit);
1317         }
1318 }
1319
1320
1321 /*
1322 ============
1323 IntermissionThink
1324
1325 When the player presses attack or jump, change to the next level
1326 ============
1327 */
1328 .float autoscreenshot;
1329 void() MapVote_Start;
1330 void() MapVote_Think;
1331 float mapvote_initialized;
1332 void IntermissionThink()
1333 {
1334         FixIntermissionClient(self);
1335
1336         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1337         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1338
1339         if( (server_screenshot || client_screenshot)
1340                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1341         {
1342                 self.autoscreenshot = -1;
1343                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1344                 return;
1345         }
1346
1347         if (time < intermission_exittime)
1348                 return;
1349
1350         if(!mapvote_initialized)
1351                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1352                         return;
1353
1354         MapVote_Start();
1355 }
1356
1357 /*
1358 ============
1359 FindIntermission
1360
1361 Returns the entity to view from
1362 ============
1363 */
1364 /*
1365 entity FindIntermission()
1366 {
1367         local   entity spot;
1368         local   float cyc;
1369
1370 // look for info_intermission first
1371         spot = find (world, classname, "info_intermission");
1372         if (spot)
1373         {       // pick a random one
1374                 cyc = random() * 4;
1375                 while (cyc > 1)
1376                 {
1377                         spot = find (spot, classname, "info_intermission");
1378                         if (!spot)
1379                                 spot = find (spot, classname, "info_intermission");
1380                         cyc = cyc - 1;
1381                 }
1382                 return spot;
1383         }
1384
1385 // then look for the start position
1386         spot = find (world, classname, "info_player_start");
1387         if (spot)
1388                 return spot;
1389
1390 // testinfo_player_start is only found in regioned levels
1391         spot = find (world, classname, "testplayerstart");
1392         if (spot)
1393                 return spot;
1394
1395 // then look for the start position
1396         spot = find (world, classname, "info_player_deathmatch");
1397         if (spot)
1398                 return spot;
1399
1400         //objerror ("FindIntermission: no spot");
1401         return world;
1402 }
1403 */
1404
1405 /*
1406 ===============================================================================
1407
1408 RULES
1409
1410 ===============================================================================
1411 */
1412
1413 void DumpStats(float final)
1414 {
1415         float file;
1416         string s;
1417         float to_console;
1418         float to_eventlog;
1419         float to_file;
1420         float i;
1421
1422         to_console = autocvar_sv_logscores_console;
1423         to_eventlog = autocvar_sv_eventlog;
1424         to_file = autocvar_sv_logscores_file;
1425
1426         if(!final)
1427         {
1428                 to_console = TRUE; // always print printstats replies
1429                 to_eventlog = FALSE; // but never print them to the event log
1430         }
1431
1432         if(to_eventlog)
1433                 if(autocvar_sv_eventlog_console)
1434                         to_console = FALSE; // otherwise we get the output twice
1435
1436         if(final)
1437                 s = ":scores:";
1438         else
1439                 s = ":status:";
1440         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1441
1442         if(to_console)
1443                 print(s, "\n");
1444         if(to_eventlog)
1445                 GameLogEcho(s);
1446
1447         file = -1;
1448         if(to_file)
1449         {
1450                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1451                 if(file == -1)
1452                         to_file = FALSE;
1453                 else
1454                         fputs(file, strcat(s, "\n"));
1455         }
1456
1457         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1458         if(to_console)
1459                 print(s, "\n");
1460         if(to_eventlog)
1461                 GameLogEcho(s);
1462         if(to_file)
1463                 fputs(file, strcat(s, "\n"));
1464
1465         FOR_EACH_CLIENT(other)
1466         {
1467                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1468                 {
1469                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1470                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1471                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1472                                 s = strcat(s, ftos(other.team), ":");
1473                         else
1474                                 s = strcat(s, "spectator:");
1475
1476                         if(to_console)
1477                                 print(s, other.netname, "\n");
1478                         if(to_eventlog)
1479                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1480                         if(to_file)
1481                                 fputs(file, strcat(s, other.netname, "\n"));
1482                 }
1483         }
1484
1485         if(teamplay)
1486         {
1487                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1488                 if(to_console)
1489                         print(s, "\n");
1490                 if(to_eventlog)
1491                         GameLogEcho(s);
1492                 if(to_file)
1493                         fputs(file, strcat(s, "\n"));
1494
1495                 for(i = 1; i < 16; ++i)
1496                 {
1497                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1498                         s = strcat(s, ":", ftos(i));
1499                         if(to_console)
1500                                 print(s, "\n");
1501                         if(to_eventlog)
1502                                 GameLogEcho(s);
1503                         if(to_file)
1504                                 fputs(file, strcat(s, "\n"));
1505                 }
1506         }
1507
1508         if(to_console)
1509                 print(":end\n");
1510         if(to_eventlog)
1511                 GameLogEcho(":end");
1512         if(to_file)
1513         {
1514                 fputs(file, ":end\n");
1515                 fclose(file);
1516         }
1517 }
1518
1519 void FixIntermissionClient(entity e)
1520 {
1521         string s;
1522         if(!e.autoscreenshot) // initial call
1523         {
1524                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1525                 e.health = -2342;
1526                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1527                 e.solid = SOLID_NOT;
1528                 e.movetype = MOVETYPE_NONE;
1529                 e.takedamage = DAMAGE_NO;
1530                 if(e.weaponentity)
1531                 {
1532                         e.weaponentity.effects = EF_NODRAW;
1533                         if (e.weaponentity.weaponentity)
1534                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1535                 }
1536                 if(clienttype(e) == CLIENTTYPE_REAL)
1537                 {
1538                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1539                         s = autocvar_sv_intermission_cdtrack;
1540                         if(s != "")
1541                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1542                         msg_entity = e;
1543                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1544                 }
1545         }
1546 }
1547
1548 void minstagib_stop_countdown(entity e);
1549 /*
1550 go to the next level for deathmatch
1551 only called if a time or frag limit has expired
1552 */
1553 void NextLevel()
1554 {
1555         gameover = TRUE;
1556
1557         intermission_running = 1;
1558
1559 // enforce a wait time before allowing changelevel
1560         if(player_count > 0)
1561                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1562         else
1563                 intermission_exittime = -1;
1564
1565         /*
1566         WriteByte (MSG_ALL, SVC_CDTRACK);
1567         WriteByte (MSG_ALL, 3);
1568         WriteByte (MSG_ALL, 3);
1569         // done in FixIntermission
1570         */
1571
1572         //pos = FindIntermission ();
1573
1574         VoteReset();
1575
1576         DumpStats(TRUE);
1577
1578         // send statistics
1579         entity e;
1580         PlayerStats_EndMatch(1);
1581         FOR_EACH_CLIENT(e)
1582                 PlayerStats_AddGlobalInfo(e);
1583         PlayerStats_Shutdown();
1584         WeaponStats_Shutdown();
1585
1586         if(autocvar_sv_eventlog)
1587                 GameLogEcho(":gameover");
1588
1589         GameLogClose();
1590
1591         FOR_EACH_PLAYER(other) {
1592                 minstagib_stop_countdown(other);
1593                 FixIntermissionClient(other);
1594                 if(other.winning)
1595                         bprint(other.netname, " ^7wins.\n");
1596         }
1597
1598         if(autocvar_g_campaign)
1599                 CampaignPreIntermission();
1600
1601         localcmd("\nsv_hook_gameend\n");
1602 }
1603
1604 /*
1605 ============
1606 CheckRules_Player
1607
1608 Exit deathmatch games upon conditions
1609 ============
1610 */
1611 void CheckRules_Player()
1612 {
1613         if (gameover)   // someone else quit the game already
1614                 return;
1615
1616         if(self.deadflag == DEAD_NO)
1617                 self.play_time += frametime;
1618
1619         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1620         //   (div0: and that in CheckRules_World please)
1621 }
1622
1623 float checkrules_equality;
1624 float checkrules_suddendeathwarning;
1625 float checkrules_suddendeathend;
1626 float checkrules_overtimesadded; //how many overtimes have been already added
1627
1628 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1629 float WINNING_YES = 1; // winner found
1630 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1631 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1632
1633 float InitiateSuddenDeath()
1634 {
1635         // Check first whether normal overtimes could be added before initiating suddendeath mode
1636         // - for this timelimit_overtime needs to be >0 of course
1637         // - also check the winning condition calculated in the previous frame and only add normal overtime
1638         //   again, if at the point at which timelimit would be extended again, still no winner was found
1639         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1640         {
1641                 return 1; // need to call InitiateOvertime later
1642         }
1643         else
1644         {
1645                 if(!checkrules_suddendeathend)
1646                 {
1647                         if(autocvar_g_campaign)
1648                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1649                         else
1650                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1651                         if(g_race && !g_race_qualifying)
1652                                 race_StartCompleting();
1653                 }
1654                 return 0;
1655         }
1656 }
1657
1658 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1659 {
1660         ++checkrules_overtimesadded;
1661         //add one more overtime by simply extending the timelimit
1662         float tl;
1663         tl = autocvar_timelimit;
1664         tl += autocvar_timelimit_overtime;
1665         cvar_set("timelimit", ftos(tl));
1666         string minutesPlural;
1667         if (autocvar_timelimit_overtime == 1)
1668                 minutesPlural = " ^3minute";
1669         else
1670                 minutesPlural = " ^3minutes";
1671
1672         bcenterprint(
1673                 strcat(
1674                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1675                         ftos(autocvar_timelimit_overtime),
1676                         minutesPlural,
1677                         " to the game!"
1678                 )
1679         );
1680 }
1681
1682 float GetWinningCode(float fraglimitreached, float equality)
1683 {
1684         if(autocvar_g_campaign == 1)
1685                 if(fraglimitreached)
1686                         return WINNING_YES;
1687                 else
1688                         return WINNING_NO;
1689
1690         else
1691                 if(equality)
1692                         if(fraglimitreached)
1693                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1694                         else
1695                                 return WINNING_NEVER;
1696                 else
1697                         if(fraglimitreached)
1698                                 return WINNING_YES;
1699                         else
1700                                 return WINNING_NO;
1701 }
1702
1703 // set the .winning flag for exactly those players with a given field value
1704 void SetWinners(.float field, float value)
1705 {
1706         entity head;
1707         FOR_EACH_PLAYER(head)
1708                 head.winning = (head.field == value);
1709 }
1710
1711 // set the .winning flag for those players with a given field value
1712 void AddWinners(.float field, float value)
1713 {
1714         entity head;
1715         FOR_EACH_PLAYER(head)
1716                 if(head.field == value)
1717                         head.winning = 1;
1718 }
1719
1720 // clear the .winning flags
1721 void ClearWinners(void)
1722 {
1723         entity head;
1724         FOR_EACH_PLAYER(head)
1725                 head.winning = 0;
1726 }
1727
1728 // Onslaught winning condition:
1729 // game terminates if only one team has a working generator (or none)
1730 float WinningCondition_Onslaught()
1731 {
1732         entity head;
1733         float t1, t2, t3, t4;
1734
1735         WinningConditionHelper(); // set worldstatus
1736
1737         if(inWarmupStage)
1738                 return WINNING_NO;
1739
1740         // first check if the game has ended
1741         t1 = t2 = t3 = t4 = 0;
1742         head = find(world, classname, "onslaught_generator");
1743         while (head)
1744         {
1745                 if (head.health > 0)
1746                 {
1747                         if (head.team == COLOR_TEAM1) t1 = 1;
1748                         if (head.team == COLOR_TEAM2) t2 = 1;
1749                         if (head.team == COLOR_TEAM3) t3 = 1;
1750                         if (head.team == COLOR_TEAM4) t4 = 1;
1751                 }
1752                 head = find(head, classname, "onslaught_generator");
1753         }
1754         if (t1 + t2 + t3 + t4 < 2)
1755         {
1756                 // game over, only one team remains (or none)
1757                 ClearWinners();
1758                 if (t1) SetWinners(team, COLOR_TEAM1);
1759                 if (t2) SetWinners(team, COLOR_TEAM2);
1760                 if (t3) SetWinners(team, COLOR_TEAM3);
1761                 if (t4) SetWinners(team, COLOR_TEAM4);
1762                 dprint("Have a winner, ending game.\n");
1763                 return WINNING_YES;
1764         }
1765
1766         // Two or more teams remain
1767         return WINNING_NO;
1768 }
1769
1770 float LMS_NewPlayerLives()
1771 {
1772         float fl;
1773         fl = autocvar_fraglimit;
1774         if(fl == 0)
1775                 fl = 999;
1776
1777         // first player has left the game for dying too much? Nobody else can get in.
1778         if(lms_lowest_lives < 1)
1779                 return 0;
1780
1781         if(!autocvar_g_lms_join_anytime)
1782                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1783                         return 0;
1784
1785         return bound(1, lms_lowest_lives, fl);
1786 }
1787
1788 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1789 // they win. Otherwise the defending team wins once the timelimit passes.
1790 void assault_new_round();
1791 float WinningCondition_Assault()
1792 {
1793         float status;
1794
1795         WinningConditionHelper(); // set worldstatus
1796
1797         status = WINNING_NO;
1798         // as the timelimit has not yet passed just assume the defending team will win
1799         if(assault_attacker_team == COLOR_TEAM1)
1800         {
1801                 SetWinners(team, COLOR_TEAM2);
1802         }
1803         else
1804         {
1805                 SetWinners(team, COLOR_TEAM1);
1806         }
1807
1808         entity ent;
1809         ent = find(world, classname, "target_assault_roundend");
1810         if(ent)
1811         {
1812                 if(ent.winning) // round end has been triggered by attacking team
1813                 {
1814                         bprint("ASSAULT: round completed...\n");
1815                         SetWinners(team, assault_attacker_team);
1816
1817                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1818
1819                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1820                         {
1821                                 status = WINNING_YES;
1822                         }
1823                         else
1824                         {
1825                                 entity oldself;
1826                                 oldself = self;
1827                                 self = ent;
1828                                 assault_new_round();
1829                                 self = oldself;
1830                         }
1831                 }
1832         }
1833
1834         return status;
1835 }
1836
1837 // LMS winning condition: game terminates if and only if there's at most one
1838 // one player who's living lives. Top two scores being equal cancels the time
1839 // limit.
1840 float WinningCondition_LMS()
1841 {
1842         entity head, head2;
1843         float have_player;
1844         float have_players;
1845         float l;
1846
1847         have_player = FALSE;
1848         have_players = FALSE;
1849         l = LMS_NewPlayerLives();
1850
1851         head = find(world, classname, "player");
1852         if(head)
1853                 have_player = TRUE;
1854         head2 = find(head, classname, "player");
1855         if(head2)
1856                 have_players = TRUE;
1857
1858         if(have_player)
1859         {
1860                 // we have at least one player
1861                 if(have_players)
1862                 {
1863                         // two or more active players - continue with the game
1864                 }
1865                 else
1866                 {
1867                         // exactly one player?
1868
1869                         ClearWinners();
1870                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1871
1872                         if(l)
1873                         {
1874                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1875                                 return WINNING_NO;
1876                         }
1877                         else
1878                         {
1879                                 // a winner!
1880                                 // and assign him his first place
1881                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1882                                 return WINNING_YES;
1883                         }
1884                 }
1885         }
1886         else
1887         {
1888                 // nobody is playing at all...
1889                 if(l)
1890                 {
1891                         // wait for players...
1892                 }
1893                 else
1894                 {
1895                         // SNAFU (maybe a draw game?)
1896                         ClearWinners();
1897                         dprint("No players, ending game.\n");
1898                         return WINNING_YES;
1899                 }
1900         }
1901
1902         // When we get here, we have at least two players who are actually LIVING,
1903         // now check if the top two players have equal score.
1904         WinningConditionHelper();
1905
1906         ClearWinners();
1907         if(WinningConditionHelper_winner)
1908                 WinningConditionHelper_winner.winning = TRUE;
1909         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1910                 return WINNING_NEVER;
1911
1912         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1913         return WINNING_NO;
1914 }
1915
1916 void ShuffleMaplist()
1917 {
1918         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1919 }
1920
1921 float leaderfrags;
1922 float WinningCondition_Scores(float limit, float leadlimit)
1923 {
1924         float limitreached;
1925
1926         // TODO make everything use THIS winning condition (except LMS)
1927         WinningConditionHelper();
1928
1929         if(teamplay)
1930         {
1931                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1932                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1933                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1934                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1935         }
1936
1937         ClearWinners();
1938         if(WinningConditionHelper_winner)
1939                 WinningConditionHelper_winner.winning = 1;
1940         if(WinningConditionHelper_winnerteam >= 0)
1941                 SetWinners(team, WinningConditionHelper_winnerteam);
1942
1943         if(WinningConditionHelper_lowerisbetter)
1944         {
1945                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1946                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1947                 limit = -limit;
1948         }
1949
1950         if(WinningConditionHelper_zeroisworst)
1951                 leadlimit = 0; // not supported in this mode
1952
1953         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1954         // these modes always score in increments of 1, thus this makes sense
1955         {
1956                 if(leaderfrags != WinningConditionHelper_topscore)
1957                 {
1958                         leaderfrags = WinningConditionHelper_topscore;
1959
1960                         if (limit)
1961                         if (leaderfrags == limit - 1)
1962                                 Announce("1fragleft");
1963                         else if (leaderfrags == limit - 2)
1964                                 Announce("2fragsleft");
1965                         else if (leaderfrags == limit - 3)
1966                                 Announce("3fragsleft");
1967                 }
1968         }
1969
1970         limitreached = FALSE;
1971         if(limit)
1972                 if(WinningConditionHelper_topscore >= limit)
1973                         limitreached = TRUE;
1974         if(leadlimit)
1975         {
1976                 float leadlimitreached;
1977                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1978                 if(autocvar_leadlimit_and_fraglimit)
1979                         limitreached = (limitreached && leadlimitreached);
1980                 else
1981                         limitreached = (limitreached || leadlimitreached);
1982         }
1983
1984         return GetWinningCode(
1985                 WinningConditionHelper_topscore && limitreached,
1986                 WinningConditionHelper_equality
1987         );
1988 }
1989
1990 float WinningCondition_Race(float fraglimit)
1991 {
1992         float wc;
1993         entity p;
1994         float n, c;
1995
1996         n = 0;
1997         c = 0;
1998         FOR_EACH_PLAYER(p)
1999         {
2000                 ++n;
2001                 if(p.race_completed)
2002                         ++c;
2003         }
2004         if(n && (n == c))
2005                 return WINNING_YES;
2006         wc = WinningCondition_Scores(fraglimit, 0);
2007
2008         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2009         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2010         // do NOT support equality when the laps are all raced!
2011                 return WINNING_STARTSUDDENDEATHOVERTIME;
2012         else
2013                 return WINNING_NEVER;
2014         return wc;
2015 }
2016
2017 float WinningCondition_QualifyingThenRace(float limit)
2018 {
2019         float wc;
2020         wc = WinningCondition_Scores(limit, 0);
2021
2022         // NEVER initiate overtime
2023         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2024         {
2025                 return WINNING_YES;
2026         }
2027
2028         return wc;
2029 }
2030
2031 float WinningCondition_RanOutOfSpawns()
2032 {
2033         entity head;
2034
2035         if(have_team_spawns <= 0)
2036                 return WINNING_NO;
2037
2038         if(autocvar_g_spawn_useallspawns <= 0)
2039                 return WINNING_NO;
2040
2041         if(!some_spawn_has_been_used)
2042                 return WINNING_NO;
2043
2044         team1_score = team2_score = team3_score = team4_score = 0;
2045
2046         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2047         {
2048                 if(head.team == COLOR_TEAM1)
2049                         team1_score = 1;
2050                 else if(head.team == COLOR_TEAM2)
2051                         team2_score = 1;
2052                 else if(head.team == COLOR_TEAM3)
2053                         team3_score = 1;
2054                 else if(head.team == COLOR_TEAM4)
2055                         team4_score = 1;
2056         }
2057
2058         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2059         {
2060                 if(head.team == COLOR_TEAM1)
2061                         team1_score = 1;
2062                 else if(head.team == COLOR_TEAM2)
2063                         team2_score = 1;
2064                 else if(head.team == COLOR_TEAM3)
2065                         team3_score = 1;
2066                 else if(head.team == COLOR_TEAM4)
2067                         team4_score = 1;
2068         }
2069
2070         ClearWinners();
2071         if(team1_score + team2_score + team3_score + team4_score == 0)
2072         {
2073                 checkrules_equality = TRUE;
2074                 return WINNING_YES;
2075         }
2076         else if(team1_score + team2_score + team3_score + team4_score == 1)
2077         {
2078                 float t, i;
2079                 if(team1_score)
2080                         t = COLOR_TEAM1;
2081                 else if(team2_score)
2082                         t = COLOR_TEAM2;
2083                 else if(team3_score)
2084                         t = COLOR_TEAM3;
2085                 else // if(team4_score)
2086                         t = COLOR_TEAM4;
2087                 CheckAllowedTeams(world);
2088                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2089                 {
2090                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2091                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2092                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2093                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2094                 }
2095
2096                 AddWinners(team, t);
2097                 return WINNING_YES;
2098         }
2099         else
2100                 return WINNING_NO;
2101 }
2102
2103 /*
2104 ============
2105 CheckRules_World
2106
2107 Exit deathmatch games upon conditions
2108 ============
2109 */
2110 void ReadyRestart();
2111 void CheckRules_World()
2112 {
2113         float timelimit;
2114         float fraglimit;
2115         float leadlimit;
2116
2117         VoteThink();
2118         MapVote_Think();
2119
2120         SetDefaultAlpha();
2121
2122         /*
2123         MapVote_Think should now do that part
2124         if (intermission_running)
2125                 if (time >= intermission_exittime + 60)
2126                 {
2127                         if(!DoNextMapOverride())
2128                                 GotoNextMap();
2129                         return;
2130                 }
2131         */
2132
2133         if (gameover)   // someone else quit the game already
2134         {
2135                 if(player_count == 0) // Nobody there? Then let's go to the next map
2136                         MapVote_Start();
2137                         // this will actually check the player count in the next frame
2138                         // again, but this shouldn't hurt
2139                 return;
2140         }
2141
2142         timelimit = autocvar_timelimit * 60;
2143         fraglimit = autocvar_fraglimit;
2144         leadlimit = autocvar_leadlimit;
2145
2146         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2147         {
2148                 if(timelimit > 0)
2149                         timelimit = 0; // timelimit is not made for warmup
2150                 if(fraglimit > 0)
2151                         fraglimit = 0; // no fraglimit for now
2152                 leadlimit = 0; // no leadlimit for now
2153         }
2154
2155         if(timelimit > 0)
2156         {
2157                 timelimit += game_starttime;
2158         }
2159         else if (timelimit < 0)
2160         {
2161                 // endmatch
2162                 NextLevel();
2163                 return;
2164         }
2165
2166         if(g_onslaught)
2167                 timelimit = 0; // ONS has its own overtime rule
2168
2169         float wantovertime;
2170         wantovertime = 0;
2171
2172         if(checkrules_suddendeathend)
2173         {
2174                 if(!checkrules_suddendeathwarning)
2175                 {
2176                         checkrules_suddendeathwarning = TRUE;
2177                         if(g_race && !g_race_qualifying)
2178                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2179                         else
2180                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2181                 }
2182         }
2183         else
2184         {
2185                 if (timelimit && time >= timelimit)
2186                 {
2187                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2188                         {
2189                                 float totalplayers;
2190                                 float playerswithlaps;
2191                                 float readyplayers;
2192                                 entity head;
2193                                 totalplayers = playerswithlaps = readyplayers = 0;
2194                                 FOR_EACH_PLAYER(head)
2195                                 {
2196                                         ++totalplayers;
2197                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2198                                                 ++playerswithlaps;
2199                                         if(head.ready)
2200                                                 ++readyplayers;
2201                                 }
2202
2203                                 // at least 2 of the players have completed a lap: start the RACE
2204                                 // otherwise, the players should end the qualifying on their own
2205                                 if(readyplayers || playerswithlaps >= 2)
2206                                 {
2207                                         checkrules_suddendeathend = 0;
2208                                         ReadyRestart(); // go to race
2209                                         return;
2210                                 }
2211                                 else
2212                                         wantovertime |= InitiateSuddenDeath();
2213                         }
2214                         else
2215                                 wantovertime |= InitiateSuddenDeath();
2216                 }
2217         }
2218
2219         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2220         {
2221                 NextLevel();
2222                 return;
2223         }
2224
2225         float checkrules_status;
2226         checkrules_status = WinningCondition_RanOutOfSpawns();
2227         if(checkrules_status == WINNING_YES)
2228         {
2229                 bprint("Hey! Someone ran out of spawns!\n");
2230         }
2231         else if(g_race && !g_race_qualifying && timelimit >= 0)
2232         {
2233                 checkrules_status = WinningCondition_Race(fraglimit);
2234                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2235         }
2236         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2237         {
2238                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2239                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2240         }
2241         else if(g_assault)
2242         {
2243                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2244         }
2245         else if(g_lms)
2246         {
2247                 checkrules_status = WinningCondition_LMS();
2248         }
2249         else if (g_onslaught)
2250         {
2251                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2252         }
2253         else
2254         {
2255                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2256                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2257         }
2258
2259         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2260         {
2261                 checkrules_status = WINNING_NEVER;
2262                 checkrules_overtimesadded = -1;
2263                 wantovertime |= InitiateSuddenDeath();
2264         }
2265
2266         if(checkrules_status == WINNING_NEVER)
2267                 // equality cases! Nobody wins if the overtime ends in a draw.
2268                 ClearWinners();
2269
2270         if(wantovertime)
2271         {
2272                 if(checkrules_status == WINNING_NEVER)
2273                         InitiateOvertime();
2274                 else
2275                         checkrules_status = WINNING_YES;
2276         }
2277
2278         if(checkrules_suddendeathend)
2279                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2280                         checkrules_status = WINNING_YES;
2281
2282         if(checkrules_status == WINNING_YES)
2283         {
2284                 //print("WINNING\n");
2285                 NextLevel();
2286         }
2287 }
2288
2289 float mapvote_nextthink;
2290 float mapvote_initialized;
2291 float mapvote_keeptwotime;
2292 float mapvote_timeout;
2293 string mapvote_message;
2294 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2295 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2296 float mapvote_screenshot_dirs_count;
2297
2298 float mapvote_count;
2299 float mapvote_count_real;
2300 string mapvote_maps[MAPVOTE_COUNT];
2301 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2302 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2303 float mapvote_maps_suggested[MAPVOTE_COUNT];
2304 string mapvote_suggestions[MAPVOTE_COUNT];
2305 float mapvote_suggestion_ptr;
2306 float mapvote_voters;
2307 float mapvote_selections[MAPVOTE_COUNT];
2308 float mapvote_run;
2309 float mapvote_detail;
2310 float mapvote_abstain;
2311 .float mapvote;
2312
2313 void MapVote_ClearAllVotes()
2314 {
2315         FOR_EACH_CLIENT(other)
2316                 other.mapvote = 0;
2317 }
2318
2319 string MapVote_Suggest(string m)
2320 {
2321         float i;
2322         if(m == "")
2323                 return "That's not how to use this command.";
2324         if(!autocvar_g_maplist_votable_suggestions)
2325                 return "Suggestions are not accepted on this server.";
2326         if(mapvote_initialized)
2327                 return "Can't suggest - voting is already in progress!";
2328         m = MapInfo_FixName(m);
2329         if(!m)
2330                 return "The map you suggested is not available on this server.";
2331         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2332                 if(Map_IsRecent(m))
2333                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2334
2335         if(!MapInfo_CheckMap(m))
2336                 return "The map you suggested does not support the current game mode.";
2337         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2338                 if(mapvote_suggestions[i] == m)
2339                         return "This map was already suggested.";
2340         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2341         {
2342                 i = floor(random() * mapvote_suggestion_ptr);
2343         }
2344         else
2345         {
2346                 i = mapvote_suggestion_ptr;
2347                 mapvote_suggestion_ptr += 1;
2348         }
2349         if(mapvote_suggestions[i] != "")
2350                 strunzone(mapvote_suggestions[i]);
2351         mapvote_suggestions[i] = strzone(m);
2352         if(autocvar_sv_eventlog)
2353                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2354         return strcat("Suggestion of ", m, " accepted.");
2355 }
2356
2357 void MapVote_AddVotable(string nextMap, float isSuggestion)
2358 {
2359         float j, i, o;
2360         string pakfile, mapfile;
2361
2362         if(nextMap == "")
2363                 return;
2364         for(j = 0; j < mapvote_count; ++j)
2365                 if(mapvote_maps[j] == nextMap)
2366                         return;
2367         // suggestions might be no longer valid/allowed after gametype switch!
2368         if(isSuggestion)
2369                 if(!MapInfo_CheckMap(nextMap))
2370                         return;
2371         mapvote_maps[mapvote_count] = strzone(nextMap);
2372         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2373
2374         pakfile = string_null;
2375         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2376         {
2377                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2378                 pakfile = whichpack(strcat(mapfile, ".tga"));
2379                 if(pakfile == "")
2380                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2381                 if(pakfile == "")
2382                         pakfile = whichpack(strcat(mapfile, ".png"));
2383                 if(pakfile != "")
2384                         break;
2385         }
2386         if(i >= mapvote_screenshot_dirs_count)
2387                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2388         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2389                 pakfile = substring(pakfile, o, -1);
2390
2391         mapvote_maps_screenshot_dir[mapvote_count] = i;
2392         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2393
2394         mapvote_count += 1;
2395 }
2396
2397 void MapVote_Spawn();
2398 void MapVote_Init()
2399 {
2400         float i;
2401         float nmax, smax;
2402
2403         MapVote_ClearAllVotes();
2404
2405         mapvote_count = 0;
2406         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2407         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2408
2409         if(mapvote_abstain)
2410                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2411         else
2412                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2413         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2414
2415         // we need this for AddVotable, as that cycles through the screenshot dirs
2416         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2417         if(mapvote_screenshot_dirs_count == 0)
2418                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2419         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2420         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2421                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2422
2423         if(mapvote_suggestion_ptr)
2424                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2425                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2426
2427         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2428                 MapVote_AddVotable(GetNextMap(), FALSE);
2429
2430         if(mapvote_count == 0)
2431         {
2432                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2433                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2434                 if(autocvar_g_maplist_shuffle)
2435                         ShuffleMaplist();
2436                 localcmd("\nmenu_cmd sync\n");
2437                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2438                         MapVote_AddVotable(GetNextMap(), FALSE);
2439         }
2440
2441         mapvote_count_real = mapvote_count;
2442         if(mapvote_abstain)
2443                 MapVote_AddVotable("don't care", 0);
2444
2445         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2446
2447         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2448         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2449         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2450                 mapvote_keeptwotime = 0;
2451         mapvote_message = "Choose a map and press its key!";
2452
2453         MapVote_Spawn();
2454 }
2455
2456 void MapVote_SendPicture(float id)
2457 {
2458         msg_entity = self;
2459         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2460         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2461         WriteByte(MSG_ONE, id);
2462         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2463 }
2464
2465 float MapVote_GetMapMask()
2466 {
2467         float mask, i, power;
2468         mask = 0;
2469         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2470                 if(mapvote_maps[i] != "")
2471                         mask |= power;
2472         return mask;
2473 }
2474
2475 entity mapvote_ent;
2476 float MapVote_SendEntity(entity to, float sf)
2477 {
2478         float i;
2479
2480         if(sf & 1)
2481                 sf &~= 2; // if we send 1, we don't need to also send 2
2482
2483         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2484         WriteByte(MSG_ENTITY, sf);
2485
2486         if(sf & 1)
2487         {
2488                 // flag 1 == initialization
2489                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2490                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2491                 WriteString(MSG_ENTITY, "");
2492                 WriteByte(MSG_ENTITY, mapvote_count);
2493                 WriteByte(MSG_ENTITY, mapvote_abstain);
2494                 WriteByte(MSG_ENTITY, mapvote_detail);
2495                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2496                 if(mapvote_count <= 8)
2497                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2498                 else
2499                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2500                 for(i = 0; i < mapvote_count; ++i)
2501                         if(mapvote_maps[i] != "")
2502                         {
2503                                 if(mapvote_abstain && i == mapvote_count - 1)
2504                                 {
2505                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2506                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2507                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2508                                 }
2509                                 else
2510                                 {
2511                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2512                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2513                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2514                                 }
2515                         }
2516         }
2517
2518         if(sf & 2)
2519         {
2520                 // flag 2 == update of mask
2521                 if(mapvote_count <= 8)
2522                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2523                 else
2524                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2525         }
2526
2527         if(sf & 4)
2528         {
2529                 if(mapvote_detail)
2530                         for(i = 0; i < mapvote_count; ++i)
2531                                 if(mapvote_maps[i] != "")
2532                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2533
2534                 WriteByte(MSG_ENTITY, to.mapvote);
2535         }
2536
2537         return TRUE;
2538 }
2539
2540 void MapVote_Spawn()
2541 {
2542         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2543 }
2544
2545 void MapVote_TouchMask()
2546 {
2547         mapvote_ent.SendFlags |= 2;
2548 }
2549
2550 void MapVote_TouchVotes(entity voter)
2551 {
2552         mapvote_ent.SendFlags |= 4;
2553 }
2554
2555 float MapVote_Finished(float mappos)
2556 {
2557         string result;
2558         float i;
2559         float didntvote;
2560
2561         if(autocvar_sv_eventlog)
2562         {
2563                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2564                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2565                 didntvote = mapvote_voters;
2566                 for(i = 0; i < mapvote_count; ++i)
2567                         if(mapvote_maps[i] != "")
2568                         {
2569                                 didntvote -= mapvote_selections[i];
2570                                 if(i != mappos)
2571                                 {
2572                                         result = strcat(result, ":", mapvote_maps[i]);
2573                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2574                                 }
2575                         }
2576                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2577
2578                 GameLogEcho(result);
2579                 if(mapvote_maps_suggested[mappos])
2580                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2581         }
2582
2583         FOR_EACH_REALCLIENT(other)
2584                 FixClientCvars(other);
2585
2586         Map_Goto_SetStr(mapvote_maps[mappos]);
2587         Map_Goto(0);
2588         alreadychangedlevel = TRUE;
2589         return TRUE;
2590 }
2591 void MapVote_CheckRules_1()
2592 {
2593         float i;
2594
2595         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2596         {
2597                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2598                 mapvote_selections[i] = 0;
2599         }
2600
2601         mapvote_voters = 0;
2602         FOR_EACH_REALCLIENT(other)
2603         {
2604                 ++mapvote_voters;
2605                 if(other.mapvote)
2606                 {
2607                         i = other.mapvote - 1;
2608                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2609                         mapvote_selections[i] = mapvote_selections[i] + 1;
2610                 }
2611         }
2612 }
2613
2614 float MapVote_CheckRules_2()
2615 {
2616         float i;
2617         float firstPlace, secondPlace;
2618         float firstPlaceVotes, secondPlaceVotes;
2619         float mapvote_voters_real;
2620         string result;
2621
2622         if(mapvote_count_real == 1)
2623                 return MapVote_Finished(0);
2624
2625         mapvote_voters_real = mapvote_voters;
2626         if(mapvote_abstain)
2627                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2628
2629         RandomSelection_Init();
2630         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2631                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2632         firstPlace = RandomSelection_chosen_float;
2633         firstPlaceVotes = RandomSelection_best_priority;
2634         //dprint("First place: ", ftos(firstPlace), "\n");
2635         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2636
2637         RandomSelection_Init();
2638         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2639                 if(i != firstPlace)
2640                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2641         secondPlace = RandomSelection_chosen_float;
2642         secondPlaceVotes = RandomSelection_best_priority;
2643         //dprint("Second place: ", ftos(secondPlace), "\n");
2644         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2645
2646         if(firstPlace == -1)
2647                 error("No first place in map vote... WTF?");
2648
2649         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2650                 return MapVote_Finished(firstPlace);
2651
2652         if(mapvote_keeptwotime)
2653                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2654                 {
2655                         float didntvote;
2656                         MapVote_TouchMask();
2657                         mapvote_message = "Now decide between the TOP TWO!";
2658                         mapvote_keeptwotime = 0;
2659                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2660                         result = strcat(result, ":", ftos(firstPlaceVotes));
2661                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2662                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2663                         didntvote = mapvote_voters;
2664                         for(i = 0; i < mapvote_count; ++i)
2665                                 if(mapvote_maps[i] != "")
2666                                 {
2667                                         didntvote -= mapvote_selections[i];
2668                                         if(i != firstPlace)
2669                                                 if(i != secondPlace)
2670                                                 {
2671                                                         result = strcat(result, ":", mapvote_maps[i]);
2672                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2673                                                         if(i < mapvote_count_real)
2674                                                         {
2675                                                                 strunzone(mapvote_maps[i]);
2676                                                                 mapvote_maps[i] = "";
2677                                                                 strunzone(mapvote_maps_pakfile[i]);
2678                                                                 mapvote_maps_pakfile[i] = "";
2679                                                         }
2680                                                 }
2681                                 }
2682                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2683                         if(autocvar_sv_eventlog)
2684                                 GameLogEcho(result);
2685                 }
2686
2687         return FALSE;
2688 }
2689 void MapVote_Tick()
2690 {
2691         float keeptwo;
2692         float totalvotes;
2693
2694         keeptwo = mapvote_keeptwotime;
2695         MapVote_CheckRules_1(); // count
2696         if(MapVote_CheckRules_2()) // decide
2697                 return;
2698
2699         totalvotes = 0;
2700         FOR_EACH_REALCLIENT(other)
2701         {
2702                 // hide scoreboard again
2703                 if(other.health != 2342)
2704                 {
2705                         other.health = 2342;
2706                         other.impulse = 0;
2707                         if(clienttype(other) == CLIENTTYPE_REAL)
2708                         {
2709                                 msg_entity = other;
2710                                 WriteByte(MSG_ONE, SVC_FINALE);
2711                                 WriteString(MSG_ONE, "");
2712                         }
2713                 }
2714
2715                 // clear possibly invalid votes
2716                 if(mapvote_maps[other.mapvote - 1] == "")
2717                         other.mapvote = 0;
2718                 // use impulses as new vote
2719                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2720                         if(mapvote_maps[other.impulse - 1] != "")
2721                         {
2722                                 other.mapvote = other.impulse;
2723                                 MapVote_TouchVotes(other);
2724                         }
2725                 other.impulse = 0;
2726
2727                 if(other.mapvote)
2728                         ++totalvotes;
2729         }
2730
2731         MapVote_CheckRules_1(); // just count
2732 }
2733 void MapVote_Start()
2734 {
2735         if(mapvote_run)
2736                 return;
2737
2738         // wait for stats to be sent first
2739         if(!playerstats_waitforme)
2740                 return;
2741
2742         MapInfo_Enumerate();
2743         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2744                 mapvote_run = TRUE;
2745 }
2746 void MapVote_Think()
2747 {
2748         if(!mapvote_run)
2749                 return;
2750
2751         if(alreadychangedlevel)
2752                 return;
2753
2754         if(time < mapvote_nextthink)
2755                 return;
2756         //dprint("tick\n");
2757
2758         mapvote_nextthink = time + 0.5;
2759
2760         if(!mapvote_initialized)
2761         {
2762                 if(autocvar_rescan_pending == 1)
2763                 {
2764                         cvar_set("rescan_pending", "2");
2765                         localcmd("fs_rescan\nrescan_pending 3\n");
2766                         return;
2767                 }
2768                 else if(autocvar_rescan_pending == 2)
2769                 {
2770                         return;
2771                 }
2772                 else if(autocvar_rescan_pending == 3)
2773                 {
2774                         // now build missing mapinfo files
2775                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2776                                 return;
2777
2778                         // we're done, start the timer
2779                         cvar_set("rescan_pending", "0");
2780                 }
2781
2782                 mapvote_initialized = TRUE;
2783                 if(DoNextMapOverride(0))
2784                         return;
2785                 if(!autocvar_g_maplist_votable || player_count <= 0)
2786                 {
2787                         GotoNextMap(0);
2788                         return;
2789                 }
2790                 MapVote_Init();
2791         }
2792
2793         MapVote_Tick();
2794 }
2795
2796 string GotoMap(string m)
2797 {
2798         if(!MapInfo_CheckMap(m))
2799                 return "The map you chose is not available on this server.";
2800         cvar_set("nextmap", m);
2801         cvar_set("timelimit", "-1");
2802         if(mapvote_initialized || alreadychangedlevel)
2803         {
2804                 if(DoNextMapOverride(0))
2805                         return "Map switch initiated.";
2806                 else
2807                         return "Hm... no. For some reason I like THIS map more.";
2808         }
2809         else
2810                 return "Map switch will happen after scoreboard.";
2811 }
2812
2813
2814 void EndFrame()
2815 {
2816         float altime;
2817         FOR_EACH_REALCLIENT(self)
2818         {
2819                 if(self.classname == "spectator")
2820                 {
2821                         if(self.enemy.typehitsound)
2822                                 self.typehit_time = time;
2823                         else if(self.enemy.hitsound)
2824                                 self.hit_time = time;
2825                 }
2826                 else
2827                 {
2828                         if(self.typehitsound)
2829                                 self.typehit_time = time;
2830                         else if(self.hitsound)
2831                                 self.hit_time = time;
2832                 }
2833         }
2834         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2835         // add 1 frametime because after this, engine SV_Physics
2836         // increases time by a frametime and then networks the frame
2837         // add another frametime because client shows everything with
2838         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2839         // needed!
2840         FOR_EACH_CLIENT(self)
2841         {
2842                 self.hitsound = FALSE;
2843                 self.typehitsound = FALSE;
2844                 antilag_record(self, altime);
2845         }
2846 }
2847
2848
2849 /*
2850  * RedirectionThink:
2851  * returns TRUE if redirecting
2852  */
2853 float redirection_timeout;
2854 float redirection_nextthink;
2855 float RedirectionThink()
2856 {
2857         float clients_found;
2858
2859         if(redirection_target == "")
2860                 return FALSE;
2861
2862         if(!redirection_timeout)
2863         {
2864                 cvar_set("sv_public", "-2");
2865                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2866                 if(redirection_target == "self")
2867                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2868                 else
2869                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2870         }
2871
2872         if(time < redirection_nextthink)
2873                 return TRUE;
2874
2875         redirection_nextthink = time + 1;
2876
2877         clients_found = 0;
2878         FOR_EACH_REALCLIENT(self)
2879         {
2880                 // TODO add timer
2881                 print("Redirecting: sending connect command to ", self.netname, "\n");
2882                 if(redirection_target == "self")
2883                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2884                 else
2885                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2886                 ++clients_found;
2887         }
2888
2889         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2890
2891         if(time > redirection_timeout || clients_found == 0)
2892                 localcmd("\nwait; wait; wait; quit\n");
2893
2894         return TRUE;
2895 }
2896
2897 void TargetMusic_RestoreGame();
2898 void RestoreGame()
2899 {
2900         // Loaded from a save game
2901         // some things then break, so let's work around them...
2902
2903         // Progs DB (capture records)
2904         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2905
2906         // Mapinfo
2907         MapInfo_Shutdown();
2908         MapInfo_Enumerate();
2909         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2910         WeaponStats_Init();
2911
2912         TargetMusic_RestoreGame();
2913 }
2914
2915 void Shutdown()
2916 {
2917         entity e;
2918
2919         gameover = 2;
2920
2921         if(world_initialized > 0)
2922         {
2923                 world_initialized = 0;
2924                 print("Saving persistent data...\n");
2925                 Ban_SaveBans();
2926
2927                 PlayerStats_EndMatch(0);
2928                 FOR_EACH_CLIENT(e)
2929                         PlayerStats_AddGlobalInfo(e);
2930                 PlayerStats_Shutdown();
2931
2932                 if(!cheatcount_total)
2933                 {
2934                         if(autocvar_sv_db_saveasdump)
2935                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2936                         else
2937                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2938                 }
2939                 if(autocvar_developer)
2940                 {
2941                         if(autocvar_sv_db_saveasdump)
2942                                 db_dump(TemporaryDB, "server-temp.db");
2943                         else
2944                                 db_save(TemporaryDB, "server-temp.db");
2945                 }
2946                 CheatShutdown(); // must be after cheatcount check
2947                 db_close(ServerProgsDB);
2948                 db_close(TemporaryDB);
2949                 print("done!\n");
2950                 // tell the bot system the game is ending now
2951                 bot_endgame();
2952
2953                 WeaponStats_Shutdown();
2954                 MapInfo_Shutdown();
2955         }
2956         else if(world_initialized == 0)
2957         {
2958                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2959         }
2960 }