qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_td");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_qualifying_timelimit");
 275                 BADCVAR("g_runematch");
 276                 BADCVAR("g_tdm");
 277                 BADCVAR("g_tdm_teams");
 278                 BADCVAR("leadlimit");
 279                 BADCVAR("nextmap");
 280                 BADCVAR("teamplay");
 281                 BADCVAR("timelimit");
 282
 283                 // long
 284                 BADCVAR("hostname");
 285                 BADCVAR("g_maplist");
 286                 BADCVAR("g_maplist_mostrecent");
 287                 BADCVAR("sv_motd");
 288
 289                 v = cvar_string(k);
 290                 d = cvar_defstring(k);
 291                 if(v == d)
 292                         continue;
 293
 294                 if(adding)
 295                 {
 296                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 297                         if(strlen(cvar_changes) > 16384)
 298                         {
 299                                 cvar_changes = "// too many settings have been changed to show them here\n";
 300                                 adding = 0;
 301                         }
 302                 }
 303
 304                 // now check if the changes are actually gameplay relevant
 305
 306                 // does nothing visible
 307                 BADCVAR("captureleadlimit_override");
 308                 BADCVAR("g_arena_point_leadlimit");
 309                 BADCVAR("g_balance_kill_delay");
 310                 BADCVAR("g_ca_point_leadlimit");
 311                 BADCVAR("g_ctf_captimerecord_always");
 312                 BADCVAR("g_ctf_flag_glowtrails");
 313                 BADCVAR("g_ctf_flag_pickup_verbosename");
 314                 BADCVAR("g_domination_point_leadlimit");
 315                 BADCVAR("g_forced_respawn");
 316                 BADCVAR("g_keyhunt_point_leadlimit");
 317                 BADPREFIX("g_mod_");
 318                 BADCVAR("g_nexball_goalleadlimit");
 319                 BADCVAR("g_runematch_point_leadlimit");
 320                 BADCVAR("leadlimit_and_fraglimit");
 321                 BADCVAR("leadlimit_override");
 322                 BADCVAR("pausable");
 323                 BADCVAR("sv_allow_fullbright");
 324                 BADCVAR("sv_checkforpacketsduringsleep");
 325                 BADCVAR("sv_fraginfo");
 326                 BADCVAR("sv_timeout");
 327                 BADPREFIX("sv_timeout_");
 328                 BADCVAR("welcome_message_time");
 329                 BADPREFIX("crypto_");
 330                 BADPREFIX("g_chat_");
 331                 BADPREFIX("g_ctf_captimerecord_");
 332                 BADPREFIX("g_maplist_votable_");
 333                 BADPREFIX("net_");
 334                 BADPREFIX("prvm_");
 335                 BADPREFIX("skill_");
 336                 BADPREFIX("sv_cullentities_");
 337                 BADPREFIX("sv_fraginfo_");
 338                 BADPREFIX("sv_maxidle_");
 339                 BADPREFIX("sv_vote_");
 340                 BADPREFIX("timelimit_");
 341                 BADCVAR("gameversion");
 342                 BADPREFIX("gameversion_");
 343                 BADCVAR("sv_namechangetimer");
 344 #ifndef NO_LEGACY_NETWORKING
 345                 BADCVAR("sv_use_csqc_players"); // transition
 346 #endif
 347
 348                 // allowed changes to server admins (please sync this to server.cfg)
 349                 // vi commands:
 350                 //   :/"impure"/,$d
 351                 //   :g!,^\/\/[^ /],d
 352                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 353                 //   :%!sort
 354                 // yes, this does contain some redundant stuff, don't really care
 355                 BADCVAR("bot_config_file");
 356                 BADCVAR("bot_number");
 357                 BADCVAR("bot_prefix");
 358                 BADCVAR("bot_suffix");
 359                 BADCVAR("capturelimit_override");
 360                 BADCVAR("fraglimit_override");
 361                 BADCVAR("gametype");
 362                 BADCVAR("g_antilag");
 363                 BADCVAR("g_balance_teams");
 364                 BADCVAR("g_balance_teams_prevent_imbalance");
 365                 BADCVAR("g_balance_teams_scorefactor");
 366                 BADCVAR("g_ban_sync_trusted_servers");
 367                 BADCVAR("g_ban_sync_uri");
 368                 BADCVAR("g_ctf_ignore_frags");
 369                 BADCVAR("g_domination_point_limit");
 370                 BADCVAR("g_friendlyfire");
 371                 BADCVAR("g_fullbrightitems");
 372                 BADCVAR("g_fullbrightplayers");
 373                 BADCVAR("g_keyhunt_point_limit");
 374                 BADCVAR("g_keyhunt_teams_override");
 375                 BADCVAR("g_lms_lives_override");
 376                 BADCVAR("g_maplist");
 377                 BADCVAR("g_maplist_check_waypoints");
 378                 BADCVAR("g_maplist_mostrecent_count");
 379                 BADCVAR("g_maplist_shuffle");
 380                 BADCVAR("g_maplist_votable");
 381                 BADCVAR("g_maplist_votable_abstain");
 382                 BADCVAR("g_maplist_votable_nodetail");
 383                 BADCVAR("g_maplist_votable_suggestions");
 384                 BADCVAR("g_maxplayers");
 385                 BADCVAR("g_mirrordamage");
 386                 BADCVAR("g_nexball_goallimit");
 387                 BADCVAR("g_powerups");
 388                 BADCVAR("g_runematch_point_limit");
 389                 BADCVAR("g_start_delay");
 390                 BADCVAR("g_warmup");
 391                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 392                 BADCVAR("hostname");
 393                 BADCVAR("log_file");
 394                 BADCVAR("maxplayers");
 395                 BADCVAR("minplayers");
 396                 BADCVAR("net_address");
 397                 BADCVAR("port");
 398                 BADCVAR("rcon_password");
 399                 BADCVAR("rcon_restricted_commands");
 400                 BADCVAR("rcon_restricted_password");
 401                 BADCVAR("skill");
 402                 BADCVAR("sv_adminnick");
 403                 BADCVAR("sv_autoscreenshot");
 404                 BADCVAR("sv_autotaunt");
 405                 BADCVAR("sv_curl_defaulturl");
 406                 BADCVAR("sv_defaultcharacter");
 407                 BADCVAR("sv_defaultplayercolors");
 408                 BADCVAR("sv_defaultplayermodel");
 409                 BADCVAR("sv_defaultplayerskin");
 410                 BADCVAR("sv_maxidle");
 411                 BADCVAR("sv_maxrate");
 412                 BADCVAR("sv_motd");
 413                 BADCVAR("sv_public");
 414                 BADCVAR("sv_ready_restart");
 415                 BADCVAR("sv_status_privacy");
 416                 BADCVAR("sv_taunt");
 417                 BADCVAR("sv_vote_call");
 418                 BADCVAR("sv_vote_commands");
 419                 BADCVAR("sv_vote_majority_factor");
 420                 BADCVAR("sv_vote_master");
 421                 BADCVAR("sv_vote_master_commands");
 422                 BADCVAR("sv_vote_master_password");
 423                 BADCVAR("sv_vote_simple_majority_factor");
 424                 BADCVAR("sys_ticrate");
 425                 BADCVAR("teamplay_mode");
 426                 BADCVAR("timelimit_override");
 427                 BADCVAR("g_spawnshieldtime");
 428                 BADPREFIX("g_warmup_");
 429                 BADPREFIX("sv_ready_restart_");
 430
 431                 // mutators that announce themselves properly to the server browser
 432                 BADCVAR("g_minstagib");
 433                 BADCVAR("g_new_toys");
 434                 BADCVAR("g_nix");
 435
 436                 if(autocvar_g_minstagib)
 437                 {
 438                         BADCVAR("g_grappling_hook");
 439                         BADCVAR("g_jetpack");
 440                 }
 441 #undef BADPREFIX
 442 #undef BADCVAR
 443
 444                 if(pureadding)
 445                 {
 446                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 447                         if(strlen(cvar_purechanges) > 16384)
 448                         {
 449                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 450                                 pureadding = 0;
 451                         }
 452                 }
 453                 ++cvar_purechanges_count;
 454                 // WARNING: this variable is used for the server list
 455                 // NEVER dare to skip this code!
 456                 // Hacks to intentionally appearing as "pure server" even though you DO have
 457                 // modified settings may be punished by removal from the server list.
 458                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 459                 // though.
 460         }
 461         buf_del(h);
 462         if(cvar_changes == "")
 463                 cvar_changes = "// this server runs at default server settings\n";
 464         else
 465                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 466         cvar_changes = strzone(cvar_changes);
 467         if(cvar_purechanges == "")
 468                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 469         else
 470                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 471         cvar_purechanges = strzone(cvar_purechanges);
 472 }
 473
 474 void detect_maptype()
 475 {
 476 #if 0
 477         vector o, v;
 478         float i;
 479
 480         for(;;)
 481         {
 482                 o = world.mins;
 483                 o_x += random() * (world.maxs_x - world.mins_x);
 484                 o_y += random() * (world.maxs_y - world.mins_y);
 485                 o_z += random() * (world.maxs_z - world.mins_z);
 486
 487                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 488                 if(trace_fraction == 1)
 489                         continue;
 490
 491                 v = trace_endpos;
 492
 493                 for(i = 0; i < 64; i += 4)
 494                 {
 495                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 496         if(trace_fraction == 1)
 497                 continue;
 498                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 499                 }
 500
 501                 break;
 502         }
 503 #endif
 504 }
 505
 506 entity randomseed;
 507 float RandomSeed_Send(entity to, float sf)
 508 {
 509         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 510         WriteShort(MSG_ENTITY, self.cnt);
 511         return TRUE;
 512 }
 513 void RandomSeed_Think()
 514 {
 515         self.cnt = bound(0, floor(random() * 65536), 65535);
 516         self.nextthink = time + 5;
 517
 518         self.SendFlags |= 1;
 519 }
 520 void RandomSeed_Spawn()
 521 {
 522         randomseed = spawn();
 523         randomseed.think = RandomSeed_Think;
 524         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 525
 526         entity oldself;
 527         oldself = self;
 528         self = randomseed;
 529         self.think(); // sets random seed and nextthink
 530         self = oldself;
 531 }
 532
 533 void spawnfunc___init_dedicated_server(void)
 534 {
 535         // handler for _init/_init map (only for dedicated server initialization)
 536
 537         world_initialized = -1; // don't complain
 538         cvar = cvar_normal;
 539         cvar_string = cvar_string_normal;
 540         cvar_set = cvar_set_normal;
 541
 542         remove = remove_unsafely;
 543
 544         entity e;
 545         e = spawn();
 546         e.think = GotoFirstMap;
 547         e.nextthink = time; // this is usually 1 at this point
 548
 549         e = spawn();
 550         e.classname = "info_player_deathmatch"; // safeguard against player joining
 551
 552         self.classname = "worldspawn"; // safeguard against various stuff ;)
 553
 554         // needs to be done so early because of the constants they create
 555         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 556         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 557
 558         MapInfo_Enumerate();
 559         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 560 }
 561
 562 void Map_MarkAsRecent(string m);
 563 float world_already_spawned;
 564 void Nagger_Init();
 565 void ClientInit_Spawn();
 566 void WeaponStats_Init();
 567 void WeaponStats_Shutdown();
 568 void spawnfunc_worldspawn (void)
 569 {
 570         float fd, l, i, j, n;
 571         string s, col;
 572
 573         cvar = cvar_normal;
 574         cvar_string = cvar_string_normal;
 575         cvar_set = cvar_set_normal;
 576
 577         if(world_already_spawned)
 578                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 579         world_already_spawned = TRUE;
 580
 581         remove = remove_safely; // during spawning, watch what you remove!
 582
 583         check_unacceptable_compiler_bugs();
 584
 585         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 586
 587         compressShortVector_init();
 588
 589         allowed_to_spawn = TRUE;
 590
 591         entity head;
 592         head = nextent(world);
 593         maxclients = 0;
 594         while(head)
 595         {
 596                 ++maxclients;
 597                 head = nextent(head);
 598         }
 599
 600         // needs to be done so early because of the constants they create
 601         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 602         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 603
 604         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 605
 606         TemporaryDB = db_create();
 607
 608         // 0 normal
 609         lightstyle(0, "m");
 610
 611         // 1 FLICKER (first variety)
 612         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 613
 614         // 2 SLOW STRONG PULSE
 615         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 616
 617         // 3 CANDLE (first variety)
 618         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 619
 620         // 4 FAST STROBE
 621         lightstyle(4, "mamamamamama");
 622
 623         // 5 GENTLE PULSE 1
 624         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 625
 626         // 6 FLICKER (second variety)
 627         lightstyle(6, "nmonqnmomnmomomno");
 628
 629         // 7 CANDLE (second variety)
 630         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 631
 632         // 8 CANDLE (third variety)
 633         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 634
 635         // 9 SLOW STROBE (fourth variety)
 636         lightstyle(9, "aaaaaaaazzzzzzzz");
 637
 638         // 10 FLUORESCENT FLICKER
 639         lightstyle(10, "mmamammmmammamamaaamammma");
 640
 641         // 11 SLOW PULSE NOT FADE TO BLACK
 642         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 643
 644         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 645
 646         // 63 testing
 647         lightstyle(63, "a");
 648
 649         if(autocvar_g_campaign)
 650                 CampaignPreInit();
 651
 652         Map_MarkAsRecent(mapname);
 653
 654         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 655
 656         precache_model ("null"); // we need this one before InitGameplayMode
 657         InitGameplayMode();
 658         readlevelcvars();
 659         GrappleHookInit();
 660         ElectroInit();
 661         LaserInit();
 662
 663         player_count = 0;
 664         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 665         if(bot_waypoints_for_items == 1)
 666                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 667                         bot_waypoints_for_items = 0;
 668
 669         precache();
 670
 671         WaypointSprite_Init();
 672
 673         //if (g_domination)
 674         //      dom_init();
 675
 676         GameLogInit(); // prepare everything
 677         // NOTE for matchid:
 678         // changing the logic generating it is okay. But:
 679         // it HAS to stay <= 64 chars
 680         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 681         if(autocvar_sv_eventlog)
 682         {
 683                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 684                 matchid = strzone(s);
 685
 686                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 687                 s = ":gameinfo:mutators:LIST";
 688
 689                 ret_string = s;
 690                 MUTATOR_CALLHOOK(BuildMutatorsString);
 691                 s = ret_string;
 692
 693                 // simple, probably not good in the mutator system
 694                 if(autocvar_g_grappling_hook)
 695                         s = strcat(s, ":grappling_hook");
 696
 697                 // initialiation stuff, not good in the mutator system
 698                 if(!autocvar_g_use_ammunition)
 699                         s = strcat(s, ":no_use_ammunition");
 700
 701                 // initialiation stuff, not good in the mutator system
 702                 if(autocvar_g_pickup_items == 0)
 703                         s = strcat(s, ":no_pickup_items");
 704                 if(autocvar_g_pickup_items > 0)
 705                         s = strcat(s, ":pickup_items");
 706
 707                 // initialiation stuff, not good in the mutator system
 708                 if(autocvar_g_weaponarena != "0")
 709                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 710
 711                 // TODO to mutator system
 712                 if(autocvar_g_norecoil)
 713                         s = strcat(s, ":norecoil");
 714
 715                 // TODO to mutator system
 716                 if(autocvar_g_midair)
 717                         s = strcat(s, ":midair");
 718
 719                 // TODO to mutator system
 720                 if(autocvar_g_minstagib)
 721                         s = strcat(s, ":minstagib");
 722
 723                 // TODO to mutator system
 724                 if(autocvar_g_powerups == 0)
 725                         s = strcat(s, ":no_powerups");
 726                 if(autocvar_g_powerups > 0)
 727                         s = strcat(s, ":powerups");
 728
 729                 GameLogEcho(s);
 730                 GameLogEcho(":gameinfo:end");
 731         }
 732         else
 733                 matchid = strzone(ftos(random()));
 734
 735         cvar_set("nextmap", "");
 736
 737         SetDefaultAlpha();
 738
 739         if(autocvar_g_campaign)
 740                 CampaignPostInit();
 741
 742         fteqcc_testbugs();
 743
 744         Ban_LoadBans();
 745
 746         MapInfo_Enumerate();
 747         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 748
 749         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 750         {
 751                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 752                 if(fd != -1)
 753                 {
 754                         while((s = fgets(fd)))
 755                         {
 756                                 l = tokenize_console(s);
 757                                 if(l < 2)
 758                                         continue;
 759                                 if(argv(0) == "cd")
 760                                 {
 761                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 762                                         print("  cdtrack ", argv(2), "\n");
 763                                 }
 764                                 else if(argv(0) == "fog")
 765                                 {
 766                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 767                                         print("  \"fog\" \"", s, "\"\n");
 768                                 }
 769                                 else if(argv(0) == "set")
 770                                 {
 771                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 772                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 773                                 }
 774                                 else if(argv(0) != "//")
 775                                 {
 776                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 777                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 778                                 }
 779                         }
 780                         fclose(fd);
 781                 }
 782         }
 783
 784         WeaponStats_Init();
 785
 786         WEPSET_ADDSTAT();
 787         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 788         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 789         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 790         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 791         Nagger_Init();
 792
 793         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 794         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 795         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 796         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 797         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 798         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 799         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 800         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 801         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 802         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 803         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 804         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 805         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 806
 807         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 808         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 809
 810         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 811
 812         if(g_ca || g_freezetag)
 813         {
 814                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 815                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 816                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 817                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 818         }
 819         if(g_freezetag)
 820         {
 821                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 822                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 823         }
 824
 825         if(g_td)
 826         {
 827                 addstat(STAT_CURRENT_WAVE, AS_FLOAT, stat_current_wave);
 828                 addstat(STAT_TOTALWAVES, AS_FLOAT, stat_totalwaves);
 829         }
 830
 831         // freeze attacks
 832         addstat(STAT_FROZEN, AS_INT, frozen);
 833         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 834
 835         // g_movementspeed hack
 836         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 837         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 838         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 839         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 840
 841         // secrets
 842         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 843         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 844
 845         // monsters
 846         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 847         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 848
 849         // misc
 850         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 851
 852         next_pingtime = time + 5;
 853
 854         detect_maptype();
 855
 856         // set up information replies for clients and server to use
 857         lsmaps_reply = "^7Maps available: ";
 858         lsnewmaps_reply = "^7Maps without a record set: ";
 859         for(i = 0, j = 0; i < MapInfo_count; ++i)
 860         {
 861                 if(MapInfo_Get_ByID(i))
 862                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 863                         {
 864                                 if(mod(i, 2))
 865                                         col = "^2";
 866                                 else
 867                                         col = "^3";
 868
 869                                 ++j;
 870
 871                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 872
 873                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 874                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 875                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 876                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 877                         }
 878         }
 879
 880         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 881         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 882
 883         maplist_reply = "^7Maps in list: ";
 884         n = tokenize_console(autocvar_g_maplist);
 885         for(i = 0, j = 0; i < n; ++i)
 886         {
 887                 if(MapInfo_CheckMap(argv(i)))
 888                 {
 889                         if(mod(j, 2))
 890                                 col = "^2";
 891                         else
 892                                 col = "^3";
 893                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 894                         ++j;
 895                 }
 896         }
 897         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 898         MapInfo_ClearTemps();
 899
 900         for(i = 0; i < 10; ++i)
 901         {
 902                 s = getrecords(i);
 903                 if (s)
 904                         records_reply[i] = strzone(s);
 905         }
 906
 907         ladder_reply = strzone(getladder());
 908
 909         rankings_reply = strzone(getrankings());
 910
 911         // begin other init
 912         ClientInit_Spawn();
 913         RandomSeed_Spawn();
 914         PingPLReport_Spawn();
 915
 916         CheatInit();
 917
 918         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 919
 920         // fill sv_curl_serverpackages from .serverpackage files
 921         if(autocvar_sv_curl_serverpackages_auto)
 922         {
 923                 s = "";
 924                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 925                 for(i = 0; i < n; ++i)
 926                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 927                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 928                                 s = strcat(s, " ", argv(i));
 929                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 930                 if(fd >= 0)
 931                 {
 932                         j = search_getsize(fd);
 933                         for(i = 0; i < j; ++i)
 934                                 s = strcat(s, " ", search_getfilename(fd, i));
 935                         search_end(fd);
 936                 }
 937                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 938                 if(fd >= 0)
 939                 {
 940                         j = search_getsize(fd);
 941                         for(i = 0; i < j; ++i)
 942                                 s = strcat(s, " ", search_getfilename(fd, i));
 943                         search_end(fd);
 944                 }
 945                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 946         }
 947
 948         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 949         modname = "Xonotic";
 950         // physics/balance/config changes that count as mod
 951         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 952                 modname = cvar_string("g_mod_physics");
 953         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 954                 modname = cvar_string("g_mod_balance");
 955         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 956                 modname = cvar_string("g_mod_config");
 957         // weird mutators that deserve to count as mod
 958         if(autocvar_g_minstagib)
 959                 modname = "MinstaGib";
 960         if(autocvar_g_monsters)
 961                 modname = "Monsters";
 962         // extra mutators that deserve to count as mod
 963         MUTATOR_CALLHOOK(SetModname);
 964         // weird game types that deserve to count as mod
 965         if(g_cts)
 966                 modname = "CTS";
 967         // save it for later
 968         modname = strzone(modname);
 969
 970         WinningConditionHelper(); // set worldstatus
 971
 972         world_initialized = 1;
 973 }
 974
 975 void spawnfunc_light (void)
 976 {
 977         //makestatic (self); // Who the f___ did that?
 978         remove(self);
 979 }
 980
 981 string GetGametype()
 982 {
 983         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 984 }
 985
 986 string getmapname_stored;
 987 string GetMapname()
 988 {
 989         return mapname;
 990 }
 991
 992 float Map_Count, Map_Current;
 993 string Map_Current_Name;
 994
 995 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 996 float GetMaplistPosition()
 997 {
 998         float pos, idx;
 999         string map;
1000
1001         map = GetMapname();
1002         idx = autocvar_g_maplist_index;
1003
1004         if(idx >= 0)
1005                 if(idx < Map_Count)
1006                         if(map == argv(idx))
1007                                 return idx;
1008
1009         for(pos = 0; pos < Map_Count; ++pos)
1010                 if(map == argv(pos))
1011                         return pos;
1012
1013         // resume normal maplist rotation if current map is not in g_maplist
1014         return idx;
1015 }
1016
1017 float MapHasRightSize(string map)
1018 {
1019         float fh;
1020         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1021         if(autocvar_g_maplist_check_waypoints)
1022         {
1023                 dprint("checkwp "); dprint(map);
1024                 if(!fexists(strcat("maps/", map, ".waypoints")))
1025                 {
1026                         dprint(": no waypoints\n");
1027                         return FALSE;
1028                 }
1029                 dprint(": has waypoints\n");
1030         }
1031
1032         // open map size restriction file
1033         dprint("opensize "); dprint(map);
1034         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1035         if(fh >= 0)
1036         {
1037                 float mapmin, mapmax;
1038                 dprint(": ok, ");
1039                 mapmin = stof(fgets(fh));
1040                 mapmax = stof(fgets(fh));
1041                 fclose(fh);
1042                 if(player_count < mapmin)
1043                 {
1044                         dprint("not enough\n");
1045                         return FALSE;
1046                 }
1047                 if(player_count > mapmax)
1048                 {
1049                         dprint("too many\n");
1050                         return FALSE;
1051                 }
1052                 dprint("right size\n");
1053                 return TRUE;
1054         }
1055         dprint(": not found\n");
1056         return TRUE;
1057 }
1058
1059 string Map_Filename(float position)
1060 {
1061         return strcat("maps/", argv(position), ".bsp");
1062 }
1063
1064 string strwords(string s, float w)
1065 {
1066         float endpos;
1067         for(endpos = 0; w && endpos >= 0; --w)
1068                 endpos = strstrofs(s, " ", endpos + 1);
1069         if(endpos < 0)
1070                 return s;
1071         else
1072                 return substring(s, 0, endpos);
1073 }
1074
1075 float strhasword(string s, string w)
1076 {
1077         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1078 }
1079
1080 void Map_MarkAsRecent(string m)
1081 {
1082         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1083 }
1084
1085 float Map_IsRecent(string m)
1086 {
1087         return strhasword(autocvar_g_maplist_mostrecent, m);
1088 }
1089
1090 float Map_Check(float position, float pass)
1091 {
1092         string filename;
1093         string map_next;
1094         map_next = argv(position);
1095         if(pass <= 1)
1096         {
1097                 if(Map_IsRecent(map_next))
1098                         return 0;
1099         }
1100         filename = Map_Filename(position);
1101         if(MapInfo_CheckMap(map_next))
1102         {
1103                 if(pass == 2)
1104                         return 1;
1105                 if(MapHasRightSize(map_next))
1106                         return 1;
1107                 return 0;
1108         }
1109         else
1110                 dprint( "Couldn't select '", filename, "'..\n" );
1111
1112         return 0;
1113 }
1114
1115 void Map_Goto_SetStr(string nextmapname)
1116 {
1117         if(getmapname_stored != "")
1118                 strunzone(getmapname_stored);
1119         if(nextmapname == "")
1120                 getmapname_stored = "";
1121         else
1122                 getmapname_stored = strzone(nextmapname);
1123 }
1124
1125 void Map_Goto_SetFloat(float position)
1126 {
1127         cvar_set("g_maplist_index", ftos(position));
1128         Map_Goto_SetStr(argv(position));
1129 }
1130
1131 void Map_Goto(float reinit)
1132 {
1133         MapInfo_LoadMap(getmapname_stored, reinit);
1134 }
1135
1136 // return codes of map selectors:
1137 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1138 //   -2 = permanent failure
1139 float() MaplistMethod_Iterate = // usual method
1140 {
1141         float pass, i;
1142
1143         for(pass = 1; pass <= 2; ++pass)
1144         {
1145                 for(i = 1; i < Map_Count; ++i)
1146                 {
1147                         float mapindex;
1148                         mapindex = mod(i + Map_Current, Map_Count);
1149                         if(Map_Check(mapindex, pass))
1150                                 return mapindex;
1151                 }
1152         }
1153         return -1;
1154 }
1155
1156 float() MaplistMethod_Repeat = // fallback method
1157 {
1158         if(Map_Check(Map_Current, 2))
1159                 return Map_Current;
1160         return -2;
1161 }
1162
1163 float() MaplistMethod_Random = // random map selection
1164 {
1165         float i, imax;
1166
1167         imax = 42;
1168
1169         for(i = 0; i <= imax; ++i)
1170         {
1171                 float mapindex;
1172                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1173                 if(Map_Check(mapindex, 1))
1174                         return mapindex;
1175         }
1176         return -1;
1177 }
1178
1179 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1180 // the exponent sets a bias on the map selection:
1181 // the higher the exponent, the less likely "shortly repeated" same maps are
1182 {
1183         float i, j, imax, insertpos;
1184
1185         imax = 42;
1186
1187         for(i = 0; i <= imax; ++i)
1188         {
1189                 string newlist;
1190
1191                 // now reinsert this at another position
1192                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1193                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1194                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1195                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1196
1197                 // insert the current map there
1198                 newlist = "";
1199                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1200                         newlist = strcat(newlist, " ", argv(j));
1201                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1202                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1203                         newlist = strcat(newlist, " ", argv(j));
1204                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1205                 cvar_set("g_maplist", newlist);
1206                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1207
1208                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1209                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1210                 if(Map_Check(Map_Current, 1))
1211                         return Map_Current;
1212         }
1213         return -1;
1214 }
1215
1216 void Maplist_Init()
1217 {
1218         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1219         if(Map_Count == 0)
1220         {
1221                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1222                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1223                 if(autocvar_g_maplist_shuffle)
1224                         ShuffleMaplist();
1225                 localcmd("\nmenu_cmd sync\n");
1226                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1227         }
1228         if(Map_Count == 0)
1229                 error("empty maplist, cannot select a new map");
1230         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1231
1232         if(Map_Current_Name)
1233                 strunzone(Map_Current_Name);
1234         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1235         // this may or may not be correct, but who cares, in the worst case a map
1236         // isn't chosen in the first pass that should have been
1237 }
1238
1239 string GetNextMap()
1240 {
1241         float nextMap;
1242
1243         Maplist_Init();
1244         nextMap = -1;
1245
1246         if(nextMap == -1)
1247                 if(autocvar_g_maplist_shuffle > 0)
1248                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1249
1250         if(nextMap == -1)
1251                 if(autocvar_g_maplist_selectrandom)
1252                         nextMap = MaplistMethod_Random();
1253
1254         if(nextMap == -1)
1255                 nextMap = MaplistMethod_Iterate();
1256
1257         if(nextMap == -1)
1258                 nextMap = MaplistMethod_Repeat();
1259
1260         if(nextMap >= 0)
1261         {
1262                 Map_Goto_SetFloat(nextMap);
1263                 return getmapname_stored;
1264         }
1265
1266         return "";
1267 }
1268
1269 float DoNextMapOverride(float reinit)
1270 {
1271         if(autocvar_g_campaign)
1272         {
1273                 CampaignPostIntermission();
1274                 alreadychangedlevel = TRUE;
1275                 return TRUE;
1276         }
1277         if(autocvar_quit_when_empty)
1278         {
1279                 if(player_count <= currentbots)
1280                 {
1281                         localcmd("quit\n");
1282                         alreadychangedlevel = TRUE;
1283                         return TRUE;
1284                 }
1285         }
1286         if(autocvar_quit_and_redirect != "")
1287         {
1288                 redirection_target = strzone(autocvar_quit_and_redirect);
1289                 alreadychangedlevel = TRUE;
1290                 return TRUE;
1291         }
1292         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1293         {
1294                 localcmd("restart\n");
1295                 alreadychangedlevel = TRUE;
1296                 return TRUE;
1297         }
1298         if(autocvar_nextmap != "")
1299                 if(MapInfo_CheckMap(autocvar_nextmap))
1300                 {
1301                         Map_Goto_SetStr(autocvar_nextmap);
1302                         Map_Goto(reinit);
1303                         alreadychangedlevel = TRUE;
1304                         return TRUE;
1305                 }
1306         if(!reinit && autocvar_lastlevel)
1307         {
1308                 cvar_settemp_restore();
1309                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1310                 alreadychangedlevel = TRUE;
1311                 return TRUE;
1312         }
1313         return FALSE;
1314 }
1315
1316 void GotoNextMap(float reinit)
1317 {
1318         //string nextmap;
1319         //float n, nummaps;
1320         //string s;
1321         if (alreadychangedlevel)
1322                 return;
1323         alreadychangedlevel = TRUE;
1324
1325         {
1326                 string nextMap;
1327                 float allowReset;
1328
1329                 for(allowReset = 1; allowReset >= 0; --allowReset)
1330                 {
1331                         nextMap = GetNextMap();
1332                         if(nextMap != "")
1333                                 break;
1334
1335                         if(allowReset)
1336                         {
1337                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1338                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1339                                 if(autocvar_g_maplist_shuffle)
1340                                         ShuffleMaplist();
1341                                 localcmd("\nmenu_cmd sync\n");
1342                         }
1343                         else
1344                         {
1345                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1346                         }
1347                 }
1348                 Map_Goto(reinit);
1349         }
1350 }
1351
1352
1353 /*
1354 ============
1355 IntermissionThink
1356
1357 When the player presses attack or jump, change to the next level
1358 ============
1359 */
1360 .float autoscreenshot;
1361 void() MapVote_Start;
1362 void() MapVote_Think;
1363 float mapvote_initialized;
1364 void IntermissionThink()
1365 {
1366         FixIntermissionClient(self);
1367
1368         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1369         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1370
1371         if( (server_screenshot || client_screenshot)
1372                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1373         {
1374                 self.autoscreenshot = -1;
1375                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1376                 return;
1377         }
1378
1379         if (time < intermission_exittime)
1380                 return;
1381
1382         if(!mapvote_initialized)
1383                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1384                         return;
1385
1386         MapVote_Start();
1387 }
1388
1389 /*
1390 ============
1391 FindIntermission
1392
1393 Returns the entity to view from
1394 ============
1395 */
1396 /*
1397 entity FindIntermission()
1398 {
1399         local   entity spot;
1400         local   float cyc;
1401
1402 // look for info_intermission first
1403         spot = find (world, classname, "info_intermission");
1404         if (spot)
1405         {       // pick a random one
1406                 cyc = random() * 4;
1407                 while (cyc > 1)
1408                 {
1409                         spot = find (spot, classname, "info_intermission");
1410                         if (!spot)
1411                                 spot = find (spot, classname, "info_intermission");
1412                         cyc = cyc - 1;
1413                 }
1414                 return spot;
1415         }
1416
1417 // then look for the start position
1418         spot = find (world, classname, "info_player_start");
1419         if (spot)
1420                 return spot;
1421
1422 // testinfo_player_start is only found in regioned levels
1423         spot = find (world, classname, "testplayerstart");
1424         if (spot)
1425                 return spot;
1426
1427 // then look for the start position
1428         spot = find (world, classname, "info_player_deathmatch");
1429         if (spot)
1430                 return spot;
1431
1432         //objerror ("FindIntermission: no spot");
1433         return world;
1434 }
1435 */
1436
1437 /*
1438 ===============================================================================
1439
1440 RULES
1441
1442 ===============================================================================
1443 */
1444
1445 void DumpStats(float final)
1446 {
1447         float file;
1448         string s;
1449         float to_console;
1450         float to_eventlog;
1451         float to_file;
1452         float i;
1453
1454         to_console = autocvar_sv_logscores_console;
1455         to_eventlog = autocvar_sv_eventlog;
1456         to_file = autocvar_sv_logscores_file;
1457
1458         if(!final)
1459         {
1460                 to_console = TRUE; // always print printstats replies
1461                 to_eventlog = FALSE; // but never print them to the event log
1462         }
1463
1464         if(to_eventlog)
1465                 if(autocvar_sv_eventlog_console)
1466                         to_console = FALSE; // otherwise we get the output twice
1467
1468         if(final)
1469                 s = ":scores:";
1470         else
1471                 s = ":status:";
1472         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1473
1474         if(to_console)
1475                 print(s, "\n");
1476         if(to_eventlog)
1477                 GameLogEcho(s);
1478
1479         file = -1;
1480         if(to_file)
1481         {
1482                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1483                 if(file == -1)
1484                         to_file = FALSE;
1485                 else
1486                         fputs(file, strcat(s, "\n"));
1487         }
1488
1489         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1490         if(to_console)
1491                 print(s, "\n");
1492         if(to_eventlog)
1493                 GameLogEcho(s);
1494         if(to_file)
1495                 fputs(file, strcat(s, "\n"));
1496
1497         FOR_EACH_CLIENT(other)
1498         {
1499                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1500                 {
1501                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1502                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1503                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1504                                 s = strcat(s, ftos(other.team), ":");
1505                         else
1506                                 s = strcat(s, "spectator:");
1507
1508                         if(to_console)
1509                                 print(s, other.netname, "\n");
1510                         if(to_eventlog)
1511                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1512                         if(to_file)
1513                                 fputs(file, strcat(s, other.netname, "\n"));
1514                 }
1515         }
1516
1517         if(teamplay)
1518         {
1519                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1520                 if(to_console)
1521                         print(s, "\n");
1522                 if(to_eventlog)
1523                         GameLogEcho(s);
1524                 if(to_file)
1525                         fputs(file, strcat(s, "\n"));
1526
1527                 for(i = 1; i < 16; ++i)
1528                 {
1529                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1530                         s = strcat(s, ":", ftos(i));
1531                         if(to_console)
1532                                 print(s, "\n");
1533                         if(to_eventlog)
1534                                 GameLogEcho(s);
1535                         if(to_file)
1536                                 fputs(file, strcat(s, "\n"));
1537                 }
1538         }
1539
1540         if(to_console)
1541                 print(":end\n");
1542         if(to_eventlog)
1543                 GameLogEcho(":end");
1544         if(to_file)
1545         {
1546                 fputs(file, ":end\n");
1547                 fclose(file);
1548         }
1549 }
1550
1551 void FixIntermissionClient(entity e)
1552 {
1553         string s;
1554         if(!e.autoscreenshot) // initial call
1555         {
1556                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1557                 e.health = -2342;
1558                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1559                 e.solid = SOLID_NOT;
1560                 e.movetype = MOVETYPE_NONE;
1561                 e.takedamage = DAMAGE_NO;
1562                 if(e.weaponentity)
1563                 {
1564                         e.weaponentity.effects = EF_NODRAW;
1565                         if (e.weaponentity.weaponentity)
1566                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1567                 }
1568                 if(clienttype(e) == CLIENTTYPE_REAL)
1569                 {
1570                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1571                         s = autocvar_sv_intermission_cdtrack;
1572                         if(s != "")
1573                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1574                         msg_entity = e;
1575                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1576                 }
1577         }
1578 }
1579
1580 void minstagib_stop_countdown(entity e);
1581 /*
1582 go to the next level for deathmatch
1583 only called if a time or frag limit has expired
1584 */
1585 void NextLevel()
1586 {
1587         gameover = TRUE;
1588
1589         intermission_running = 1;
1590
1591 // enforce a wait time before allowing changelevel
1592         if(player_count > 0)
1593                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1594         else
1595                 intermission_exittime = -1;
1596
1597         /*
1598         WriteByte (MSG_ALL, SVC_CDTRACK);
1599         WriteByte (MSG_ALL, 3);
1600         WriteByte (MSG_ALL, 3);
1601         // done in FixIntermission
1602         */
1603
1604         //pos = FindIntermission ();
1605
1606         VoteReset();
1607
1608         DumpStats(TRUE);
1609
1610         // send statistics
1611         entity e;
1612         PlayerStats_EndMatch(1);
1613         FOR_EACH_CLIENT(e)
1614                 PlayerStats_AddGlobalInfo(e);
1615         PlayerStats_Shutdown();
1616         WeaponStats_Shutdown();
1617
1618         if(autocvar_sv_eventlog)
1619                 GameLogEcho(":gameover");
1620
1621         GameLogClose();
1622
1623         FOR_EACH_PLAYER(other) {
1624                 minstagib_stop_countdown(other);
1625                 FixIntermissionClient(other);
1626                 if(other.winning)
1627                         bprint(other.netname, " ^7wins.\n");
1628         }
1629
1630         if(autocvar_g_campaign)
1631                 CampaignPreIntermission();
1632
1633         MUTATOR_CALLHOOK(MatchEnd);
1634
1635         localcmd("\nsv_hook_gameend\n");
1636 }
1637
1638 /*
1639 ============
1640 CheckRules_Player
1641
1642 Exit deathmatch games upon conditions
1643 ============
1644 */
1645 void CheckRules_Player()
1646 {
1647         if (gameover)   // someone else quit the game already
1648                 return;
1649
1650         if(self.deadflag == DEAD_NO)
1651                 self.play_time += frametime;
1652
1653         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1654         //   (div0: and that in CheckRules_World please)
1655 }
1656
1657 float checkrules_equality;
1658 float checkrules_suddendeathwarning;
1659 float checkrules_suddendeathend;
1660 float checkrules_overtimesadded; //how many overtimes have been already added
1661
1662 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1663 float WINNING_YES = 1; // winner found
1664 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1665 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1666
1667 float InitiateSuddenDeath()
1668 {
1669         // Check first whether normal overtimes could be added before initiating suddendeath mode
1670         // - for this timelimit_overtime needs to be >0 of course
1671         // - also check the winning condition calculated in the previous frame and only add normal overtime
1672         //   again, if at the point at which timelimit would be extended again, still no winner was found
1673         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1674         {
1675                 return 1; // need to call InitiateOvertime later
1676         }
1677         else
1678         {
1679                 if(!checkrules_suddendeathend)
1680                 {
1681                         if(autocvar_g_campaign)
1682                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1683                         else
1684                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1685                         if(g_race && !g_race_qualifying)
1686                                 race_StartCompleting();
1687                 }
1688                 return 0;
1689         }
1690 }
1691
1692 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1693 {
1694         ++checkrules_overtimesadded;
1695         //add one more overtime by simply extending the timelimit
1696         float tl;
1697         tl = autocvar_timelimit;
1698         tl += autocvar_timelimit_overtime;
1699         cvar_set("timelimit", ftos(tl));
1700         string minutesPlural;
1701         if (autocvar_timelimit_overtime == 1)
1702                 minutesPlural = " ^3minute";
1703         else
1704                 minutesPlural = " ^3minutes";
1705
1706         bcenterprint(
1707                 strcat(
1708                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1709                         ftos(autocvar_timelimit_overtime),
1710                         minutesPlural,
1711                         " to the game!"
1712                 )
1713         );
1714 }
1715
1716 float GetWinningCode(float fraglimitreached, float equality)
1717 {
1718         if(autocvar_g_campaign == 1)
1719                 if(fraglimitreached)
1720                         return WINNING_YES;
1721                 else
1722                         return WINNING_NO;
1723
1724         else
1725                 if(equality)
1726                         if(fraglimitreached)
1727                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1728                         else
1729                                 return WINNING_NEVER;
1730                 else
1731                         if(fraglimitreached)
1732                                 return WINNING_YES;
1733                         else
1734                                 return WINNING_NO;
1735 }
1736
1737 // set the .winning flag for exactly those players with a given field value
1738 void SetWinners(.float field, float value)
1739 {
1740         entity head;
1741         FOR_EACH_PLAYER(head)
1742                 head.winning = (head.field == value);
1743 }
1744
1745 // set the .winning flag for those players with a given field value
1746 void AddWinners(.float field, float value)
1747 {
1748         entity head;
1749         FOR_EACH_PLAYER(head)
1750                 if(head.field == value)
1751                         head.winning = 1;
1752 }
1753
1754 // clear the .winning flags
1755 void ClearWinners(void)
1756 {
1757         entity head;
1758         FOR_EACH_PLAYER(head)
1759                 head.winning = 0;
1760 }
1761
1762 // Onslaught winning condition:
1763 // game terminates if only one team has a working generator (or none)
1764 float WinningCondition_Onslaught()
1765 {
1766         entity head;
1767         float t1, t2, t3, t4;
1768
1769         WinningConditionHelper(); // set worldstatus
1770
1771         if(inWarmupStage)
1772                 return WINNING_NO;
1773
1774         // first check if the game has ended
1775         t1 = t2 = t3 = t4 = 0;
1776         head = find(world, classname, "onslaught_generator");
1777         while (head)
1778         {
1779                 if (head.health > 0)
1780                 {
1781                         if (head.team == COLOR_TEAM1) t1 = 1;
1782                         if (head.team == COLOR_TEAM2) t2 = 1;
1783                         if (head.team == COLOR_TEAM3) t3 = 1;
1784                         if (head.team == COLOR_TEAM4) t4 = 1;
1785                 }
1786                 head = find(head, classname, "onslaught_generator");
1787         }
1788         if (t1 + t2 + t3 + t4 < 2)
1789         {
1790                 // game over, only one team remains (or none)
1791                 ClearWinners();
1792                 if (t1) SetWinners(team, COLOR_TEAM1);
1793                 if (t2) SetWinners(team, COLOR_TEAM2);
1794                 if (t3) SetWinners(team, COLOR_TEAM3);
1795                 if (t4) SetWinners(team, COLOR_TEAM4);
1796                 dprint("Have a winner, ending game.\n");
1797                 return WINNING_YES;
1798         }
1799
1800         // Two or more teams remain
1801         return WINNING_NO;
1802 }
1803
1804 float LMS_NewPlayerLives()
1805 {
1806         float fl;
1807         fl = autocvar_fraglimit;
1808         if(fl == 0)
1809                 fl = 999;
1810
1811         // first player has left the game for dying too much? Nobody else can get in.
1812         if(lms_lowest_lives < 1)
1813                 return 0;
1814
1815         if(!autocvar_g_lms_join_anytime)
1816                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1817                         return 0;
1818
1819         return bound(1, lms_lowest_lives, fl);
1820 }
1821
1822 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1823 // they win. Otherwise the defending team wins once the timelimit passes.
1824 void assault_new_round();
1825 float WinningCondition_Assault()
1826 {
1827         float status;
1828
1829         WinningConditionHelper(); // set worldstatus
1830
1831         status = WINNING_NO;
1832         // as the timelimit has not yet passed just assume the defending team will win
1833         if(assault_attacker_team == COLOR_TEAM1)
1834         {
1835                 SetWinners(team, COLOR_TEAM2);
1836         }
1837         else
1838         {
1839                 SetWinners(team, COLOR_TEAM1);
1840         }
1841
1842         entity ent;
1843         ent = find(world, classname, "target_assault_roundend");
1844         if(ent)
1845         {
1846                 if(ent.winning) // round end has been triggered by attacking team
1847                 {
1848                         bprint("ASSAULT: round completed...\n");
1849                         SetWinners(team, assault_attacker_team);
1850
1851                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1852
1853                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1854                         {
1855                                 status = WINNING_YES;
1856                         }
1857                         else
1858                         {
1859                                 entity oldself;
1860                                 oldself = self;
1861                                 self = ent;
1862                                 assault_new_round();
1863                                 self = oldself;
1864                         }
1865                 }
1866         }
1867
1868         return status;
1869 }
1870
1871 // LMS winning condition: game terminates if and only if there's at most one
1872 // one player who's living lives. Top two scores being equal cancels the time
1873 // limit.
1874 float WinningCondition_LMS()
1875 {
1876         entity head, head2;
1877         float have_player;
1878         float have_players;
1879         float l;
1880
1881         have_player = FALSE;
1882         have_players = FALSE;
1883         l = LMS_NewPlayerLives();
1884
1885         head = find(world, classname, "player");
1886         if(head)
1887                 have_player = TRUE;
1888         head2 = find(head, classname, "player");
1889         if(head2)
1890                 have_players = TRUE;
1891
1892         if(have_player)
1893         {
1894                 // we have at least one player
1895                 if(have_players)
1896                 {
1897                         // two or more active players - continue with the game
1898                 }
1899                 else
1900                 {
1901                         // exactly one player?
1902
1903                         ClearWinners();
1904                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1905
1906                         if(l)
1907                         {
1908                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1909                                 return WINNING_NO;
1910                         }
1911                         else
1912                         {
1913                                 // a winner!
1914                                 // and assign him his first place
1915                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1916                                 return WINNING_YES;
1917                         }
1918                 }
1919         }
1920         else
1921         {
1922                 // nobody is playing at all...
1923                 if(l)
1924                 {
1925                         // wait for players...
1926                 }
1927                 else
1928                 {
1929                         // SNAFU (maybe a draw game?)
1930                         ClearWinners();
1931                         dprint("No players, ending game.\n");
1932                         return WINNING_YES;
1933                 }
1934         }
1935
1936         // When we get here, we have at least two players who are actually LIVING,
1937         // now check if the top two players have equal score.
1938         WinningConditionHelper();
1939
1940         ClearWinners();
1941         if(WinningConditionHelper_winner)
1942                 WinningConditionHelper_winner.winning = TRUE;
1943         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1944                 return WINNING_NEVER;
1945
1946         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1947         return WINNING_NO;
1948 }
1949
1950 void ShuffleMaplist()
1951 {
1952         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1953 }
1954
1955 float leaderfrags;
1956 float WinningCondition_Scores(float limit, float leadlimit)
1957 {
1958         float limitreached;
1959
1960         // TODO make everything use THIS winning condition (except LMS)
1961         WinningConditionHelper();
1962
1963         if(teamplay)
1964         {
1965                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1966                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1967                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1968                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1969         }
1970
1971         ClearWinners();
1972         if(WinningConditionHelper_winner)
1973                 WinningConditionHelper_winner.winning = 1;
1974         if(WinningConditionHelper_winnerteam >= 0)
1975                 SetWinners(team, WinningConditionHelper_winnerteam);
1976
1977         if(WinningConditionHelper_lowerisbetter)
1978         {
1979                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1980                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1981                 limit = -limit;
1982         }
1983
1984         if(WinningConditionHelper_zeroisworst)
1985                 leadlimit = 0; // not supported in this mode
1986
1987         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1988         // these modes always score in increments of 1, thus this makes sense
1989         {
1990                 if(leaderfrags != WinningConditionHelper_topscore)
1991                 {
1992                         leaderfrags = WinningConditionHelper_topscore;
1993
1994                         if (limit)
1995                         if (leaderfrags == limit - 1)
1996                                 Announce("1fragleft");
1997                         else if (leaderfrags == limit - 2)
1998                                 Announce("2fragsleft");
1999                         else if (leaderfrags == limit - 3)
2000                                 Announce("3fragsleft");
2001                 }
2002         }
2003
2004         limitreached = FALSE;
2005         if(limit)
2006                 if(WinningConditionHelper_topscore >= limit)
2007                         limitreached = TRUE;
2008         if(leadlimit)
2009         {
2010                 float leadlimitreached;
2011                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
2012                 if(autocvar_leadlimit_and_fraglimit)
2013                         limitreached = (limitreached && leadlimitreached);
2014                 else
2015                         limitreached = (limitreached || leadlimitreached);
2016         }
2017
2018         if(limit)
2019                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
2020
2021         return GetWinningCode(
2022                 WinningConditionHelper_topscore && limitreached,
2023                 WinningConditionHelper_equality
2024         );
2025 }
2026
2027 float WinningCondition_Race(float fraglimit)
2028 {
2029         float wc;
2030         entity p;
2031         float n, c;
2032
2033         n = 0;
2034         c = 0;
2035         FOR_EACH_PLAYER(p)
2036         {
2037                 ++n;
2038                 if(p.race_completed)
2039                         ++c;
2040         }
2041         if(n && (n == c))
2042                 return WINNING_YES;
2043         wc = WinningCondition_Scores(fraglimit, 0);
2044
2045         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2046         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2047         // do NOT support equality when the laps are all raced!
2048                 return WINNING_STARTSUDDENDEATHOVERTIME;
2049         else
2050                 return WINNING_NEVER;
2051 }
2052
2053 float WinningCondition_QualifyingThenRace(float limit)
2054 {
2055         float wc;
2056         wc = WinningCondition_Scores(limit, 0);
2057
2058         // NEVER initiate overtime
2059         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2060         {
2061                 return WINNING_YES;
2062         }
2063
2064         return wc;
2065 }
2066
2067 float WinningCondition_RanOutOfSpawns()
2068 {
2069         entity head;
2070
2071         if(have_team_spawns <= 0)
2072                 return WINNING_NO;
2073
2074         if(autocvar_g_spawn_useallspawns <= 0)
2075                 return WINNING_NO;
2076
2077         if(!some_spawn_has_been_used)
2078                 return WINNING_NO;
2079
2080         team1_score = team2_score = team3_score = team4_score = 0;
2081
2082         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2083         {
2084                 if(head.team == COLOR_TEAM1)
2085                         team1_score = 1;
2086                 else if(head.team == COLOR_TEAM2)
2087                         team2_score = 1;
2088                 else if(head.team == COLOR_TEAM3)
2089                         team3_score = 1;
2090                 else if(head.team == COLOR_TEAM4)
2091                         team4_score = 1;
2092         }
2093
2094         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2095         {
2096                 if(head.team == COLOR_TEAM1)
2097                         team1_score = 1;
2098                 else if(head.team == COLOR_TEAM2)
2099                         team2_score = 1;
2100                 else if(head.team == COLOR_TEAM3)
2101                         team3_score = 1;
2102                 else if(head.team == COLOR_TEAM4)
2103                         team4_score = 1;
2104         }
2105
2106         ClearWinners();
2107         if(team1_score + team2_score + team3_score + team4_score == 0)
2108         {
2109                 checkrules_equality = TRUE;
2110                 return WINNING_YES;
2111         }
2112         else if(team1_score + team2_score + team3_score + team4_score == 1)
2113         {
2114                 float t, i;
2115                 if(team1_score)
2116                         t = COLOR_TEAM1;
2117                 else if(team2_score)
2118                         t = COLOR_TEAM2;
2119                 else if(team3_score)
2120                         t = COLOR_TEAM3;
2121                 else // if(team4_score)
2122                         t = COLOR_TEAM4;
2123                 CheckAllowedTeams(world);
2124                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2125                 {
2126                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2127                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2128                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2129                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2130                 }
2131
2132                 AddWinners(team, t);
2133                 return WINNING_YES;
2134         }
2135         else
2136                 return WINNING_NO;
2137 }
2138
2139 // TD winning condition:
2140 // game terminates if there are no generators (or 1 dies if td_dontend is TRUE)
2141 float gensurvived;
2142 float WinningCondition_TowerDefense()
2143 {
2144         WinningConditionHelper(); // set worldstatus
2145
2146         if(inWarmupStage)
2147                 return WINNING_NO;
2148
2149         // first check if the game has ended
2150         if(gendestroyed == TRUE) // FALSE means either generator hasen't spawned yet, or mapper didn't add one
2151         if(td_gencount < 1 || !td_dont_end)
2152         {
2153                 ClearWinners();
2154                 dprint("Everyone lost, ending game.\n");
2155                 return WINNING_YES;
2156         }
2157
2158         if(gensurvived)
2159         {
2160                 ClearWinners();
2161                 SetWinners(winning, 4);
2162                 return WINNING_YES;
2163         }
2164
2165         // Two or more teams remain
2166         return WINNING_NO;
2167 }
2168
2169 /*
2170 ============
2171 CheckRules_World
2172
2173 Exit deathmatch games upon conditions
2174 ============
2175 */
2176 void ReadyRestart();
2177 void CheckRules_World()
2178 {
2179         float timelimit;
2180         float fraglimit;
2181         float leadlimit;
2182
2183         VoteThink();
2184         MapVote_Think();
2185
2186         SetDefaultAlpha();
2187
2188         /*
2189         MapVote_Think should now do that part
2190         if (intermission_running)
2191                 if (time >= intermission_exittime + 60)
2192                 {
2193                         if(!DoNextMapOverride())
2194                                 GotoNextMap();
2195                         return;
2196                 }
2197         */
2198
2199         if (gameover)   // someone else quit the game already
2200         {
2201                 if(player_count == 0) // Nobody there? Then let's go to the next map
2202                         MapVote_Start();
2203                         // this will actually check the player count in the next frame
2204                         // again, but this shouldn't hurt
2205                 return;
2206         }
2207
2208         timelimit = autocvar_timelimit * 60;
2209         fraglimit = autocvar_fraglimit;
2210         leadlimit = autocvar_leadlimit;
2211
2212         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2213         {
2214                 if(timelimit > 0)
2215                         timelimit = 0; // timelimit is not made for warmup
2216                 if(fraglimit > 0)
2217                         fraglimit = 0; // no fraglimit for now
2218                 leadlimit = 0; // no leadlimit for now
2219         }
2220
2221         if(timelimit > 0)
2222         {
2223                 timelimit += game_starttime;
2224         }
2225         else if (timelimit < 0)
2226         {
2227                 // endmatch
2228                 NextLevel();
2229                 return;
2230         }
2231
2232         if(g_onslaught)
2233                 timelimit = 0; // ONS has its own overtime rule
2234
2235         float wantovertime;
2236         wantovertime = 0;
2237
2238         if(timelimit > game_starttime)
2239                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2240         else
2241                 game_completion_ratio = 0;
2242
2243         if(checkrules_suddendeathend)
2244         {
2245                 if(!checkrules_suddendeathwarning)
2246                 {
2247                         checkrules_suddendeathwarning = TRUE;
2248                         if(g_race && !g_race_qualifying)
2249                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2250                         else
2251                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2252                 }
2253         }
2254         else
2255         {
2256                 if (timelimit && time >= timelimit)
2257                 {
2258                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2259                         {
2260                                 float totalplayers;
2261                                 float playerswithlaps;
2262                                 float readyplayers;
2263                                 entity head;
2264                                 totalplayers = playerswithlaps = readyplayers = 0;
2265                                 FOR_EACH_PLAYER(head)
2266                                 {
2267                                         ++totalplayers;
2268                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2269                                                 ++playerswithlaps;
2270                                         if(head.ready)
2271                                                 ++readyplayers;
2272                                 }
2273
2274                                 // at least 2 of the players have completed a lap: start the RACE
2275                                 // otherwise, the players should end the qualifying on their own
2276                                 if(readyplayers || playerswithlaps >= 2)
2277                                 {
2278                                         checkrules_suddendeathend = 0;
2279                                         ReadyRestart(); // go to race
2280                                         return;
2281                                 }
2282                                 else
2283                                         wantovertime |= InitiateSuddenDeath();
2284                         }
2285                         else
2286                                 wantovertime |= InitiateSuddenDeath();
2287                 }
2288         }
2289
2290         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2291         {
2292                 NextLevel();
2293                 return;
2294         }
2295
2296         float checkrules_status;
2297         checkrules_status = WinningCondition_RanOutOfSpawns();
2298         if(checkrules_status == WINNING_YES)
2299         {
2300                 bprint("Hey! Someone ran out of spawns!\n");
2301         }
2302         else if(g_race && !g_race_qualifying && timelimit >= 0)
2303         {
2304                 checkrules_status = WinningCondition_Race(fraglimit);
2305                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2306         }
2307         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2308         {
2309                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2310                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2311         }
2312         else if(g_assault)
2313         {
2314                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2315         }
2316         else if(g_lms)
2317         {
2318                 checkrules_status = WinningCondition_LMS();
2319         }
2320         else if (g_onslaught)
2321         {
2322                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2323         }
2324         else if(g_td)
2325         {
2326                 checkrules_status = WinningCondition_TowerDefense(); // TODO make these mutator hooks?
2327         }
2328         else
2329         {
2330                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2331                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2332         }
2333
2334         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2335         {
2336                 checkrules_status = WINNING_NEVER;
2337                 checkrules_overtimesadded = -1;
2338                 wantovertime |= InitiateSuddenDeath();
2339         }
2340
2341         if(checkrules_status == WINNING_NEVER)
2342                 // equality cases! Nobody wins if the overtime ends in a draw.
2343                 ClearWinners();
2344
2345         if(wantovertime)
2346         {
2347                 if(checkrules_status == WINNING_NEVER)
2348                         InitiateOvertime();
2349                 else
2350                         checkrules_status = WINNING_YES;
2351         }
2352
2353         if(checkrules_suddendeathend)
2354                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2355                         checkrules_status = WINNING_YES;
2356
2357         if(checkrules_status == WINNING_YES)
2358         {
2359                 //print("WINNING\n");
2360                 NextLevel();
2361         }
2362 }
2363
2364 float mapvote_nextthink;
2365 float mapvote_initialized;
2366 float mapvote_keeptwotime;
2367 float mapvote_timeout;
2368 string mapvote_message;
2369 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2370 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2371 float mapvote_screenshot_dirs_count;
2372
2373 float mapvote_count;
2374 float mapvote_count_real;
2375 string mapvote_maps[MAPVOTE_COUNT];
2376 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2377 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2378 float mapvote_maps_suggested[MAPVOTE_COUNT];
2379 string mapvote_suggestions[MAPVOTE_COUNT];
2380 float mapvote_suggestion_ptr;
2381 float mapvote_voters;
2382 float mapvote_selections[MAPVOTE_COUNT];
2383 float mapvote_run;
2384 float mapvote_detail;
2385 float mapvote_abstain;
2386 .float mapvote;
2387
2388 void MapVote_ClearAllVotes()
2389 {
2390         FOR_EACH_CLIENT(other)
2391                 other.mapvote = 0;
2392 }
2393
2394 string MapVote_Suggest(string m)
2395 {
2396         float i;
2397         if(m == "")
2398                 return "That's not how to use this command.";
2399         if(!autocvar_g_maplist_votable_suggestions)
2400                 return "Suggestions are not accepted on this server.";
2401         if(mapvote_initialized)
2402                 return "Can't suggest - voting is already in progress!";
2403         m = MapInfo_FixName(m);
2404         if not(m)
2405                 return "The map you suggested is not available on this server.";
2406         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2407                 if(Map_IsRecent(m))
2408                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2409
2410         if(!MapInfo_CheckMap(m))
2411                 return "The map you suggested does not support the current game mode.";
2412         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2413                 if(mapvote_suggestions[i] == m)
2414                         return "This map was already suggested.";
2415         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2416         {
2417                 i = floor(random() * mapvote_suggestion_ptr);
2418         }
2419         else
2420         {
2421                 i = mapvote_suggestion_ptr;
2422                 mapvote_suggestion_ptr += 1;
2423         }
2424         if(mapvote_suggestions[i] != "")
2425                 strunzone(mapvote_suggestions[i]);
2426         mapvote_suggestions[i] = strzone(m);
2427         if(autocvar_sv_eventlog)
2428                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2429         return strcat("Suggestion of ", m, " accepted.");
2430 }
2431
2432 void MapVote_AddVotable(string nextMap, float isSuggestion)
2433 {
2434         float j, i, o;
2435         string pakfile, mapfile;
2436
2437         if(nextMap == "")
2438                 return;
2439         for(j = 0; j < mapvote_count; ++j)
2440                 if(mapvote_maps[j] == nextMap)
2441                         return;
2442         // suggestions might be no longer valid/allowed after gametype switch!
2443         if(isSuggestion)
2444                 if(!MapInfo_CheckMap(nextMap))
2445                         return;
2446         mapvote_maps[mapvote_count] = strzone(nextMap);
2447         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2448
2449         pakfile = string_null;
2450         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2451         {
2452                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2453                 pakfile = whichpack(strcat(mapfile, ".tga"));
2454                 if(pakfile == "")
2455                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2456                 if(pakfile == "")
2457                         pakfile = whichpack(strcat(mapfile, ".png"));
2458                 if(pakfile != "")
2459                         break;
2460         }
2461         if(i >= mapvote_screenshot_dirs_count)
2462                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2463         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2464                 pakfile = substring(pakfile, o, -1);
2465
2466         mapvote_maps_screenshot_dir[mapvote_count] = i;
2467         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2468
2469         mapvote_count += 1;
2470 }
2471
2472 void MapVote_Spawn();
2473 void MapVote_Init()
2474 {
2475         float i;
2476         float nmax, smax;
2477
2478         MapVote_ClearAllVotes();
2479
2480         mapvote_count = 0;
2481         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2482         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2483
2484         if(mapvote_abstain)
2485                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2486         else
2487                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2488         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2489
2490         // we need this for AddVotable, as that cycles through the screenshot dirs
2491         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2492         if(mapvote_screenshot_dirs_count == 0)
2493                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2494         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2495         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2496                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2497
2498         if(mapvote_suggestion_ptr)
2499                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2500                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2501
2502         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2503                 MapVote_AddVotable(GetNextMap(), FALSE);
2504
2505         if(mapvote_count == 0)
2506         {
2507                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2508                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2509                 if(autocvar_g_maplist_shuffle)
2510                         ShuffleMaplist();
2511                 localcmd("\nmenu_cmd sync\n");
2512                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2513                         MapVote_AddVotable(GetNextMap(), FALSE);
2514         }
2515
2516         mapvote_count_real = mapvote_count;
2517         if(mapvote_abstain)
2518                 MapVote_AddVotable("don't care", 0);
2519
2520         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2521
2522         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2523         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2524         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2525                 mapvote_keeptwotime = 0;
2526         mapvote_message = "Choose a map and press its key!";
2527
2528         MapVote_Spawn();
2529 }
2530
2531 void MapVote_SendPicture(float id)
2532 {
2533         msg_entity = self;
2534         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2535         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2536         WriteByte(MSG_ONE, id);
2537         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2538 }
2539
2540 float MapVote_GetMapMask()
2541 {
2542         float mask, i, power;
2543         mask = 0;
2544         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2545                 if(mapvote_maps[i] != "")
2546                         mask |= power;
2547         return mask;
2548 }
2549
2550 entity mapvote_ent;
2551 float MapVote_SendEntity(entity to, float sf)
2552 {
2553         float i;
2554
2555         if(sf & 1)
2556                 sf &~= 2; // if we send 1, we don't need to also send 2
2557
2558         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2559         WriteByte(MSG_ENTITY, sf);
2560
2561         if(sf & 1)
2562         {
2563                 // flag 1 == initialization
2564                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2565                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2566                 WriteString(MSG_ENTITY, "");
2567                 WriteByte(MSG_ENTITY, mapvote_count);
2568                 WriteByte(MSG_ENTITY, mapvote_abstain);
2569                 WriteByte(MSG_ENTITY, mapvote_detail);
2570                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2571                 if(mapvote_count <= 8)
2572                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2573                 else
2574                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2575                 for(i = 0; i < mapvote_count; ++i)
2576                         if(mapvote_maps[i] != "")
2577                         {
2578                                 if(mapvote_abstain && i == mapvote_count - 1)
2579                                 {
2580                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2581                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2582                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2583                                 }
2584                                 else
2585                                 {
2586                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2587                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2588                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2589                                 }
2590                         }
2591         }
2592
2593         if(sf & 2)
2594         {
2595                 // flag 2 == update of mask
2596                 if(mapvote_count <= 8)
2597                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2598                 else
2599                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2600         }
2601
2602         if(sf & 4)
2603         {
2604                 if(mapvote_detail)
2605                         for(i = 0; i < mapvote_count; ++i)
2606                                 if(mapvote_maps[i] != "")
2607                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2608
2609                 WriteByte(MSG_ENTITY, to.mapvote);
2610         }
2611
2612         return TRUE;
2613 }
2614
2615 void MapVote_Spawn()
2616 {
2617         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2618 }
2619
2620 void MapVote_TouchMask()
2621 {
2622         mapvote_ent.SendFlags |= 2;
2623 }
2624
2625 void MapVote_TouchVotes(entity voter)
2626 {
2627         mapvote_ent.SendFlags |= 4;
2628 }
2629
2630 float MapVote_Finished(float mappos)
2631 {
2632         string result;
2633         float i;
2634         float didntvote;
2635
2636         if(autocvar_sv_eventlog)
2637         {
2638                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2639                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2640                 didntvote = mapvote_voters;
2641                 for(i = 0; i < mapvote_count; ++i)
2642                         if(mapvote_maps[i] != "")
2643                         {
2644                                 didntvote -= mapvote_selections[i];
2645                                 if(i != mappos)
2646                                 {
2647                                         result = strcat(result, ":", mapvote_maps[i]);
2648                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2649                                 }
2650                         }
2651                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2652
2653                 GameLogEcho(result);
2654                 if(mapvote_maps_suggested[mappos])
2655                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2656         }
2657
2658         FOR_EACH_REALCLIENT(other)
2659                 FixClientCvars(other);
2660
2661         Map_Goto_SetStr(mapvote_maps[mappos]);
2662         Map_Goto(0);
2663         alreadychangedlevel = TRUE;
2664         return TRUE;
2665 }
2666 void MapVote_CheckRules_1()
2667 {
2668         float i;
2669
2670         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2671         {
2672                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2673                 mapvote_selections[i] = 0;
2674         }
2675
2676         mapvote_voters = 0;
2677         FOR_EACH_REALCLIENT(other)
2678         {
2679                 ++mapvote_voters;
2680                 if(other.mapvote)
2681                 {
2682                         i = other.mapvote - 1;
2683                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2684                         mapvote_selections[i] = mapvote_selections[i] + 1;
2685                 }
2686         }
2687 }
2688
2689 float MapVote_CheckRules_2()
2690 {
2691         float i;
2692         float firstPlace, secondPlace;
2693         float firstPlaceVotes, secondPlaceVotes;
2694         float mapvote_voters_real;
2695         string result;
2696
2697         if(mapvote_count_real == 1)
2698                 return MapVote_Finished(0);
2699
2700         mapvote_voters_real = mapvote_voters;
2701         if(mapvote_abstain)
2702                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2703
2704         RandomSelection_Init();
2705         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2706                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2707         firstPlace = RandomSelection_chosen_float;
2708         firstPlaceVotes = RandomSelection_best_priority;
2709         //dprint("First place: ", ftos(firstPlace), "\n");
2710         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2711
2712         RandomSelection_Init();
2713         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2714                 if(i != firstPlace)
2715                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2716         secondPlace = RandomSelection_chosen_float;
2717         secondPlaceVotes = RandomSelection_best_priority;
2718         //dprint("Second place: ", ftos(secondPlace), "\n");
2719         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2720
2721         if(firstPlace == -1)
2722                 error("No first place in map vote... WTF?");
2723
2724         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2725                 return MapVote_Finished(firstPlace);
2726
2727         if(mapvote_keeptwotime)
2728                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2729                 {
2730                         float didntvote;
2731                         MapVote_TouchMask();
2732                         mapvote_message = "Now decide between the TOP TWO!";
2733                         mapvote_keeptwotime = 0;
2734                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2735                         result = strcat(result, ":", ftos(firstPlaceVotes));
2736                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2737                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2738                         didntvote = mapvote_voters;
2739                         for(i = 0; i < mapvote_count; ++i)
2740                                 if(mapvote_maps[i] != "")
2741                                 {
2742                                         didntvote -= mapvote_selections[i];
2743                                         if(i != firstPlace)
2744                                                 if(i != secondPlace)
2745                                                 {
2746                                                         result = strcat(result, ":", mapvote_maps[i]);
2747                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2748                                                         if(i < mapvote_count_real)
2749                                                         {
2750                                                                 strunzone(mapvote_maps[i]);
2751                                                                 mapvote_maps[i] = "";
2752                                                                 strunzone(mapvote_maps_pakfile[i]);
2753                                                                 mapvote_maps_pakfile[i] = "";
2754                                                         }
2755                                                 }
2756                                 }
2757                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2758                         if(autocvar_sv_eventlog)
2759                                 GameLogEcho(result);
2760                 }
2761
2762         return FALSE;
2763 }
2764 void MapVote_Tick()
2765 {
2766         float keeptwo;
2767         float totalvotes;
2768
2769         keeptwo = mapvote_keeptwotime;
2770         MapVote_CheckRules_1(); // count
2771         if(MapVote_CheckRules_2()) // decide
2772                 return;
2773
2774         totalvotes = 0;
2775         FOR_EACH_REALCLIENT(other)
2776         {
2777                 // hide scoreboard again
2778                 if(other.health != 2342)
2779                 {
2780                         other.health = 2342;
2781                         other.impulse = 0;
2782                         if(clienttype(other) == CLIENTTYPE_REAL)
2783                         {
2784                                 msg_entity = other;
2785                                 WriteByte(MSG_ONE, SVC_FINALE);
2786                                 WriteString(MSG_ONE, "");
2787                         }
2788                 }
2789
2790                 // clear possibly invalid votes
2791                 if(mapvote_maps[other.mapvote - 1] == "")
2792                         other.mapvote = 0;
2793                 // use impulses as new vote
2794                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2795                         if(mapvote_maps[other.impulse - 1] != "")
2796                         {
2797                                 other.mapvote = other.impulse;
2798                                 MapVote_TouchVotes(other);
2799                         }
2800                 other.impulse = 0;
2801
2802                 if(other.mapvote)
2803                         ++totalvotes;
2804         }
2805
2806         MapVote_CheckRules_1(); // just count
2807 }
2808 void MapVote_Start()
2809 {
2810         if(mapvote_run)
2811                 return;
2812
2813         // wait for stats to be sent first
2814         if(!playerstats_waitforme)
2815                 return;
2816
2817         MapInfo_Enumerate();
2818         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2819                 mapvote_run = TRUE;
2820 }
2821 void MapVote_Think()
2822 {
2823         if(!mapvote_run)
2824                 return;
2825
2826         if(alreadychangedlevel)
2827                 return;
2828
2829         if(time < mapvote_nextthink)
2830                 return;
2831         //dprint("tick\n");
2832
2833         mapvote_nextthink = time + 0.5;
2834
2835         if(!mapvote_initialized)
2836         {
2837                 if(autocvar_rescan_pending == 1)
2838                 {
2839                         cvar_set("rescan_pending", "2");
2840                         localcmd("fs_rescan\nrescan_pending 3\n");
2841                         return;
2842                 }
2843                 else if(autocvar_rescan_pending == 2)
2844                 {
2845                         return;
2846                 }
2847                 else if(autocvar_rescan_pending == 3)
2848                 {
2849                         // now build missing mapinfo files
2850                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2851                                 return;
2852
2853                         // we're done, start the timer
2854                         cvar_set("rescan_pending", "0");
2855                 }
2856
2857                 mapvote_initialized = TRUE;
2858                 if(DoNextMapOverride(0))
2859                         return;
2860                 if(!autocvar_g_maplist_votable || player_count <= 0)
2861                 {
2862                         GotoNextMap(0);
2863                         return;
2864                 }
2865                 MapVote_Init();
2866         }
2867
2868         MapVote_Tick();
2869 }
2870
2871 string GotoMap(string m)
2872 {
2873         if(!MapInfo_CheckMap(m))
2874                 return "The map you chose is not available on this server.";
2875         cvar_set("nextmap", m);
2876         cvar_set("timelimit", "-1");
2877         if(mapvote_initialized || alreadychangedlevel)
2878         {
2879                 if(DoNextMapOverride(0))
2880                         return "Map switch initiated.";
2881                 else
2882                         return "Hm... no. For some reason I like THIS map more.";
2883         }
2884         else
2885                 return "Map switch will happen after scoreboard.";
2886 }
2887
2888
2889 void EndFrame()
2890 {
2891         float altime;
2892         FOR_EACH_REALCLIENT(self)
2893         {
2894                 if(self.classname == "spectator")
2895                 {
2896                         if(self.enemy.typehitsound)
2897                                 self.typehit_time = time;
2898                         else if(self.enemy.hitsound)
2899                                 self.hit_time = time;
2900                 }
2901                 else
2902                 {
2903                         if(self.typehitsound)
2904                                 self.typehit_time = time;
2905                         else if(self.hitsound)
2906                                 self.hit_time = time;
2907                 }
2908         }
2909         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2910         // add 1 frametime because after this, engine SV_Physics
2911         // increases time by a frametime and then networks the frame
2912         // add another frametime because client shows everything with
2913         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2914         // needed!
2915         FOR_EACH_CLIENT(self)
2916         {
2917                 self.hitsound = FALSE;
2918                 self.typehitsound = FALSE;
2919                 antilag_record(self, altime);
2920         }
2921 }
2922
2923
2924 /*
2925  * RedirectionThink:
2926  * returns TRUE if redirecting
2927  */
2928 float redirection_timeout;
2929 float redirection_nextthink;
2930 float RedirectionThink()
2931 {
2932         float clients_found;
2933
2934         if(redirection_target == "")
2935                 return FALSE;
2936
2937         if(!redirection_timeout)
2938         {
2939                 cvar_set("sv_public", "-2");
2940                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2941                 if(redirection_target == "self")
2942                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2943                 else
2944                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2945         }
2946
2947         if(time < redirection_nextthink)
2948                 return TRUE;
2949
2950         redirection_nextthink = time + 1;
2951
2952         clients_found = 0;
2953         FOR_EACH_REALCLIENT(self)
2954         {
2955                 // TODO add timer
2956                 print("Redirecting: sending connect command to ", self.netname, "\n");
2957                 if(redirection_target == "self")
2958                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2959                 else
2960                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2961                 ++clients_found;
2962         }
2963
2964         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2965
2966         if(time > redirection_timeout || clients_found == 0)
2967                 localcmd("\nwait; wait; wait; quit\n");
2968
2969         return TRUE;
2970 }
2971
2972 void TargetMusic_RestoreGame();
2973 void RestoreGame()
2974 {
2975         // Loaded from a save game
2976         // some things then break, so let's work around them...
2977
2978         // Progs DB (capture records)
2979         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2980
2981         // Mapinfo
2982         MapInfo_Shutdown();
2983         MapInfo_Enumerate();
2984         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2985         WeaponStats_Init();
2986
2987         TargetMusic_RestoreGame();
2988 }
2989
2990 void Shutdown()
2991 {
2992         entity e;
2993
2994         gameover = 2;
2995
2996         if(world_initialized > 0)
2997         {
2998                 world_initialized = 0;
2999                 print("Saving persistent data...\n");
3000                 Ban_SaveBans();
3001
3002                 PlayerStats_EndMatch(0);
3003                 FOR_EACH_CLIENT(e)
3004                         PlayerStats_AddGlobalInfo(e);
3005                 PlayerStats_Shutdown();
3006
3007                 if(!cheatcount_total)
3008                 {
3009                         if(autocvar_sv_db_saveasdump)
3010                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
3011                         else
3012                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
3013                 }
3014                 if(autocvar_developer)
3015                 {
3016                         if(autocvar_sv_db_saveasdump)
3017                                 db_dump(TemporaryDB, "server-temp.db");
3018                         else
3019                                 db_save(TemporaryDB, "server-temp.db");
3020                 }
3021                 CheatShutdown(); // must be after cheatcount check
3022                 db_close(ServerProgsDB);
3023                 db_close(TemporaryDB);
3024                 print("done!\n");
3025                 // tell the bot system the game is ending now
3026                 bot_endgame();
3027
3028                 WeaponStats_Shutdown();
3029                 MapInfo_Shutdown();
3030         }
3031         else if(world_initialized == 0)
3032         {
3033                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
3034         }
3035 }