qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetGametype();
  59 void GotoNextMap(float reinit);
  60 void ShuffleMaplist();
  61 float(float reinit) DoNextMapOverride;
  62
  63 void SetDefaultAlpha()
  64 {
  65         if(autocvar_g_running_guns)
  66         {
  67                 default_player_alpha = -1;
  68                 default_weapon_alpha = +1;
  69         }
  70         else if(g_cloaked)
  71         {
  72                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  73                 default_weapon_alpha = default_player_alpha;
  74         }
  75         else
  76         {
  77                 default_player_alpha = autocvar_g_player_alpha;
  78                 if(default_player_alpha == 0)
  79                         default_player_alpha = 1;
  80                 default_weapon_alpha = default_player_alpha;
  81         }
  82 }
  83
  84 void fteqcc_testbugs()
  85 {
  86         float a, b;
  87
  88         if(!autocvar_developer_fteqccbugs)
  89                 return;
  90
  91         dprint("*** fteqcc test: checking for bugs...\n");
  92
  93         a = 1;
  94         b = 5;
  95         if(sqrt(a) - sqrt(b - a) == 0)
  96                 dprint("*** fteqcc test: found same-function-twice bug\n");
  97         else
  98                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  99
 100         world.cnt = -10;
 101         world.enemy = world;
 102         world.enemy.cnt += 10;
 103         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 104                 dprint("*** fteqcc test: found += bug\n");
 105         else
 106                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 107         world.cnt = 0;
 108 }
 109
 110 void GotoFirstMap()
 111 {
 112         float n;
 113         if(autocvar__sv_init)
 114         {
 115                 // cvar_set("_sv_init", "0");
 116                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 117                 // to this "init" map on a dedicated server will cause no permanent
 118                 // harm
 119                 if(autocvar_g_maplist_shuffle)
 120                         ShuffleMaplist();
 121                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 122                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 123
 124                 MapInfo_Enumerate();
 125                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 126
 127                 if(!DoNextMapOverride(1))
 128                         GotoNextMap(1);
 129
 130                 return;
 131         }
 132
 133         if(time < 5)
 134         {
 135                 self.nextthink = time;
 136         }
 137         else
 138         {
 139                 self.nextthink = time + 1;
 140                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 141         }
 142 }
 143
 144 void cvar_changes_init()
 145 {
 146         float h;
 147         string k, v, d;
 148         float n, i, adding, pureadding;
 149
 150         if(cvar_changes)
 151                 strunzone(cvar_changes);
 152         cvar_changes = string_null;
 153         if(cvar_purechanges)
 154                 strunzone(cvar_purechanges);
 155         cvar_purechanges = string_null;
 156         cvar_purechanges_count = 0;
 157
 158         h = buf_create();
 159         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 160         n = buf_getsize(h);
 161
 162         adding = TRUE;
 163         pureadding = TRUE;
 164
 165         for(i = 0; i < n; ++i)
 166         {
 167                 k = bufstr_get(h, i);
 168
 169 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 170 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 171 #define BADCVAR(p) if(k == p) continue
 172
 173                 // general excludes and namespaces for server admin used cvars
 174                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 175
 176                 // internal
 177                 BADPREFIX("csqc_");
 178                 BADPREFIX("cvar_check_");
 179                 BADCVAR("gamecfg");
 180                 BADCVAR("g_configversion");
 181                 BADCVAR("g_maplist_index");
 182                 BADCVAR("halflifebsp");
 183                 BADPREFIX("sv_world");
 184
 185                 // client
 186                 BADPREFIX("chase_");
 187                 BADPREFIX("cl_");
 188                 BADPREFIX("con_");
 189                 BADPREFIX("scoreboard_");
 190                 BADPREFIX("g_campaign");
 191                 BADPREFIX("g_waypointsprite_");
 192                 BADPREFIX("gl_");
 193                 BADPREFIX("joy");
 194                 BADPREFIX("hud_");
 195                 BADPREFIX("m_");
 196                 BADPREFIX("menu_");
 197                 BADPREFIX("net_slist_");
 198                 BADPREFIX("r_");
 199                 BADPREFIX("sbar_");
 200                 BADPREFIX("scr_");
 201                 BADPREFIX("snd_");
 202                 BADPREFIX("show");
 203                 BADPREFIX("sensitivity");
 204                 BADPREFIX("userbind");
 205                 BADPREFIX("v_");
 206                 BADPREFIX("vid_");
 207                 BADPREFIX("crosshair");
 208                 BADCVAR("mod_q3bsp_lightmapmergepower");
 209                 BADCVAR("mod_q3bsp_nolightmaps");
 210                 BADCVAR("fov");
 211                 BADCVAR("mastervolume");
 212                 BADCVAR("volume");
 213                 BADCVAR("bgmvolume");
 214
 215                 // private
 216                 BADCVAR("developer");
 217                 BADCVAR("log_dest_udp");
 218                 BADCVAR("log_file");
 219                 BADCVAR("net_address");
 220                 BADCVAR("net_address_ipv6");
 221                 BADCVAR("port");
 222                 BADCVAR("savedgamecfg");
 223                 BADCVAR("serverconfig");
 224                 BADCVAR("sv_autoscreenshot");
 225                 BADCVAR("sv_heartbeatperiod");
 226                 BADCVAR("sv_vote_master_password");
 227                 BADCVAR("sys_colortranslation");
 228                 BADCVAR("sys_specialcharactertranslation");
 229                 BADCVAR("timeformat");
 230                 BADCVAR("timestamps");
 231                 BADPREFIX("developer_");
 232                 BADPREFIX("g_ban_");
 233                 BADPREFIX("g_banned_list");
 234                 BADPREFIX("g_chat_flood_");
 235                 BADPREFIX("g_ghost_items");
 236                 BADPREFIX("g_playerstats_");
 237                 BADPREFIX("g_respawn_ghosts");
 238                 BADPREFIX("g_voice_flood_");
 239                 BADPREFIX("rcon_");
 240                 BADPREFIX("sv_allowdownloads");
 241                 BADPREFIX("sv_autodemo");
 242                 BADPREFIX("sv_curl_");
 243                 BADPREFIX("sv_eventlog");
 244                 BADPREFIX("sv_logscores_");
 245                 BADPREFIX("sv_master");
 246                 BADPREFIX("sv_weaponstats_");
 247                 BADPREFIX("sv_waypointsprite_");
 248                 BADCVAR("rescan_pending");
 249
 250                 // these can contain player IDs, so better hide
 251                 BADPREFIX("g_forced_team_");
 252
 253                 // mapinfo
 254                 BADCVAR("fraglimit");
 255                 BADCVAR("g_assault");
 256                 BADCVAR("g_ca");
 257                 BADCVAR("g_ca_teams");
 258                 BADCVAR("g_ctf");
 259                 BADCVAR("g_cts");
 260                 BADCVAR("g_dm");
 261                 BADCVAR("g_domination");
 262                 BADCVAR("g_domination_default_teams");
 263                 BADCVAR("g_freezetag");
 264                 BADCVAR("g_freezetag_teams");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_lms");
 269                 BADCVAR("g_nexball");
 270                 BADCVAR("g_onslaught");
 271                 BADCVAR("g_race");
 272                 BADCVAR("g_race_qualifying_timelimit");
 273                 BADCVAR("g_tdm");
 274                 BADCVAR("g_tdm_teams");
 275                 BADCVAR("leadlimit");
 276                 BADCVAR("nextmap");
 277                 BADCVAR("teamplay");
 278                 BADCVAR("timelimit");
 279
 280                 // long
 281                 BADCVAR("hostname");
 282                 BADCVAR("g_maplist");
 283                 BADCVAR("g_maplist_mostrecent");
 284                 BADCVAR("sv_motd");
 285
 286                 v = cvar_string(k);
 287                 d = cvar_defstring(k);
 288                 if(v == d)
 289                         continue;
 290
 291                 if(adding)
 292                 {
 293                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 294                         if(strlen(cvar_changes) > 16384)
 295                         {
 296                                 cvar_changes = "// too many settings have been changed to show them here\n";
 297                                 adding = 0;
 298                         }
 299                 }
 300
 301                 // now check if the changes are actually gameplay relevant
 302
 303                 // does nothing visible
 304                 BADCVAR("captureleadlimit_override");
 305                 BADCVAR("g_balance_kill_delay");
 306                 BADCVAR("g_ca_point_leadlimit");
 307                 BADCVAR("g_ctf_captimerecord_always");
 308                 BADCVAR("g_ctf_flag_glowtrails");
 309                 BADCVAR("g_ctf_flag_pickup_verbosename");
 310                 BADCVAR("g_domination_point_leadlimit");
 311                 BADCVAR("g_forced_respawn");
 312                 BADCVAR("g_keyhunt_point_leadlimit");
 313                 BADPREFIX("g_mod_");
 314                 BADCVAR("g_nexball_goalleadlimit");
 315                 BADCVAR("leadlimit_and_fraglimit");
 316                 BADCVAR("leadlimit_override");
 317                 BADCVAR("pausable");
 318                 BADCVAR("sv_allow_fullbright");
 319                 BADCVAR("sv_checkforpacketsduringsleep");
 320                 BADCVAR("sv_fraginfo");
 321                 BADCVAR("sv_timeout");
 322                 BADPREFIX("sv_timeout_");
 323                 BADPREFIX("crypto_");
 324                 BADPREFIX("g_chat_");
 325                 BADPREFIX("g_ctf_captimerecord_");
 326                 BADPREFIX("g_maplist_votable_");
 327                 BADPREFIX("net_");
 328                 BADPREFIX("prvm_");
 329                 BADPREFIX("skill_");
 330                 BADPREFIX("sv_cullentities_");
 331                 BADPREFIX("sv_fraginfo_");
 332                 BADPREFIX("sv_maxidle_");
 333                 BADPREFIX("sv_vote_");
 334                 BADPREFIX("timelimit_");
 335                 BADCVAR("gameversion");
 336                 BADPREFIX("gameversion_");
 337                 BADCVAR("sv_namechangetimer");
 338
 339                 // allowed changes to server admins (please sync this to server.cfg)
 340                 // vi commands:
 341                 //   :/"impure"/,$d
 342                 //   :g!,^\/\/[^ /],d
 343                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 344                 //   :%!sort
 345                 // yes, this does contain some redundant stuff, don't really care
 346                 BADCVAR("bot_config_file");
 347                 BADCVAR("bot_number");
 348                 BADCVAR("bot_prefix");
 349                 BADCVAR("bot_suffix");
 350                 BADCVAR("capturelimit_override");
 351                 BADCVAR("fraglimit_override");
 352                 BADCVAR("gametype");
 353                 BADCVAR("g_antilag");
 354                 BADCVAR("g_balance_teams");
 355                 BADCVAR("g_balance_teams_prevent_imbalance");
 356                 BADCVAR("g_balance_teams_scorefactor");
 357                 BADCVAR("g_ban_sync_trusted_servers");
 358                 BADCVAR("g_ban_sync_uri");
 359                 BADCVAR("g_ca_teams_override");
 360                 BADCVAR("g_ctf_ignore_frags");
 361                 BADCVAR("g_domination_point_limit");
 362                 BADCVAR("g_freezetag_teams_override");
 363                 BADCVAR("g_friendlyfire");
 364                 BADCVAR("g_fullbrightitems");
 365                 BADCVAR("g_fullbrightplayers");
 366                 BADCVAR("g_keyhunt_point_limit");
 367                 BADCVAR("g_keyhunt_teams_override");
 368                 BADCVAR("g_lms_lives_override");
 369                 BADCVAR("g_maplist");
 370                 BADCVAR("g_maplist_check_waypoints");
 371                 BADCVAR("g_maplist_mostrecent_count");
 372                 BADCVAR("g_maplist_shuffle");
 373                 BADCVAR("g_maplist_votable");
 374                 BADCVAR("g_maplist_votable_abstain");
 375                 BADCVAR("g_maplist_votable_nodetail");
 376                 BADCVAR("g_maplist_votable_suggestions");
 377                 BADCVAR("g_maxplayers");
 378                 BADCVAR("g_mirrordamage");
 379                 BADCVAR("g_nexball_goallimit");
 380                 BADCVAR("g_powerups");
 381                 BADCVAR("g_start_delay");
 382                 BADCVAR("g_warmup");
 383                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 384                 BADCVAR("hostname");
 385                 BADCVAR("log_file");
 386                 BADCVAR("maxplayers");
 387                 BADCVAR("minplayers");
 388                 BADCVAR("net_address");
 389                 BADCVAR("port");
 390                 BADCVAR("rcon_password");
 391                 BADCVAR("rcon_restricted_commands");
 392                 BADCVAR("rcon_restricted_password");
 393                 BADCVAR("skill");
 394                 BADCVAR("sv_adminnick");
 395                 BADCVAR("sv_autoscreenshot");
 396                 BADCVAR("sv_autotaunt");
 397                 BADCVAR("sv_curl_defaulturl");
 398                 BADCVAR("sv_defaultcharacter");
 399                 BADCVAR("sv_defaultplayercolors");
 400                 BADCVAR("sv_defaultplayermodel");
 401                 BADCVAR("sv_defaultplayerskin");
 402                 BADCVAR("sv_maxidle");
 403                 BADCVAR("sv_maxrate");
 404                 BADCVAR("sv_motd");
 405                 BADCVAR("sv_public");
 406                 BADCVAR("sv_ready_restart");
 407                 BADCVAR("sv_status_privacy");
 408                 BADCVAR("sv_taunt");
 409                 BADCVAR("sv_vote_call");
 410                 BADCVAR("sv_vote_commands");
 411                 BADCVAR("sv_vote_majority_factor");
 412                 BADCVAR("sv_vote_master");
 413                 BADCVAR("sv_vote_master_commands");
 414                 BADCVAR("sv_vote_master_password");
 415                 BADCVAR("sv_vote_simple_majority_factor");
 416                 BADCVAR("teamplay_mode");
 417                 BADCVAR("timelimit_override");
 418                 BADCVAR("g_spawnshieldtime");
 419                 BADPREFIX("g_warmup_");
 420                 BADPREFIX("sv_ready_restart_");
 421
 422                 // mutators that announce themselves properly to the server browser
 423                 BADCVAR("g_minstagib");
 424                 BADCVAR("g_new_toys");
 425                 BADCVAR("g_nix");
 426                 BADCVAR("g_grappling_hook");
 427                 BADCVAR("g_jetpack");
 428
 429 #undef BADPREFIX
 430 #undef BADCVAR
 431
 432                 if(pureadding)
 433                 {
 434                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 435                         if(strlen(cvar_purechanges) > 16384)
 436                         {
 437                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 438                                 pureadding = 0;
 439                         }
 440                 }
 441                 ++cvar_purechanges_count;
 442                 // WARNING: this variable is used for the server list
 443                 // NEVER dare to skip this code!
 444                 // Hacks to intentionally appearing as "pure server" even though you DO have
 445                 // modified settings may be punished by removal from the server list.
 446                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 447                 // though.
 448         }
 449         buf_del(h);
 450         if(cvar_changes == "")
 451                 cvar_changes = "// this server runs at default server settings\n";
 452         else
 453                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 454         cvar_changes = strzone(cvar_changes);
 455         if(cvar_purechanges == "")
 456                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 457         else
 458                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 459         cvar_purechanges = strzone(cvar_purechanges);
 460 }
 461
 462 void detect_maptype()
 463 {
 464 #if 0
 465         vector o, v;
 466         float i;
 467
 468         for(;;)
 469         {
 470                 o = world.mins;
 471                 o_x += random() * (world.maxs_x - world.mins_x);
 472                 o_y += random() * (world.maxs_y - world.mins_y);
 473                 o_z += random() * (world.maxs_z - world.mins_z);
 474
 475                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 476                 if(trace_fraction == 1)
 477                         continue;
 478
 479                 v = trace_endpos;
 480
 481                 for(i = 0; i < 64; i += 4)
 482                 {
 483                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 484         if(trace_fraction == 1)
 485                 continue;
 486                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 487                 }
 488
 489                 break;
 490         }
 491 #endif
 492 }
 493
 494 entity randomseed;
 495 float RandomSeed_Send(entity to, float sf)
 496 {
 497         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 498         WriteShort(MSG_ENTITY, self.cnt);
 499         return TRUE;
 500 }
 501 void RandomSeed_Think()
 502 {
 503         self.cnt = bound(0, floor(random() * 65536), 65535);
 504         self.nextthink = time + 5;
 505
 506         self.SendFlags |= 1;
 507 }
 508 void RandomSeed_Spawn()
 509 {
 510         randomseed = spawn();
 511         randomseed.think = RandomSeed_Think;
 512         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 513
 514         entity oldself;
 515         oldself = self;
 516         self = randomseed;
 517         self.think(); // sets random seed and nextthink
 518         self = oldself;
 519 }
 520
 521 void spawnfunc___init_dedicated_server(void)
 522 {
 523         // handler for _init/_init map (only for dedicated server initialization)
 524
 525         world_initialized = -1; // don't complain
 526         cvar = cvar_normal;
 527         cvar_string = cvar_string_normal;
 528         cvar_set = cvar_set_normal;
 529
 530         remove = remove_unsafely;
 531
 532         entity e;
 533         e = spawn();
 534         e.think = GotoFirstMap;
 535         e.nextthink = time; // this is usually 1 at this point
 536
 537         e = spawn();
 538         e.classname = "info_player_deathmatch"; // safeguard against player joining
 539
 540         self.classname = "worldspawn"; // safeguard against various stuff ;)
 541
 542         // needs to be done so early because of the constants they create
 543         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 544         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 545         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 546         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 547         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 548
 549         MapInfo_Enumerate();
 550         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 551 }
 552
 553 void Map_MarkAsRecent(string m);
 554 float world_already_spawned;
 555 void Nagger_Init();
 556 void ClientInit_Spawn();
 557 void WeaponStats_Init();
 558 void WeaponStats_Shutdown();
 559 void spawnfunc_worldspawn (void)
 560 {
 561         float fd, l, i, j, n;
 562         string s;
 563
 564         cvar = cvar_normal;
 565         cvar_string = cvar_string_normal;
 566         cvar_set = cvar_set_normal;
 567
 568         if(world_already_spawned)
 569                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 570         world_already_spawned = TRUE;
 571
 572         remove = remove_safely; // during spawning, watch what you remove!
 573
 574         check_unacceptable_compiler_bugs();
 575
 576         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 577
 578         compressShortVector_init();
 579
 580         entity head;
 581         head = nextent(world);
 582         maxclients = 0;
 583         while(head)
 584         {
 585                 ++maxclients;
 586                 head = nextent(head);
 587         }
 588
 589         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 590
 591         // needs to be done so early because of the constants they create
 592         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 593         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 594         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 595         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 596         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 597
 598         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 599
 600         TemporaryDB = db_create();
 601
 602         // 0 normal
 603         lightstyle(0, "m");
 604
 605         // 1 FLICKER (first variety)
 606         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 607
 608         // 2 SLOW STRONG PULSE
 609         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 610
 611         // 3 CANDLE (first variety)
 612         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 613
 614         // 4 FAST STROBE
 615         lightstyle(4, "mamamamamama");
 616
 617         // 5 GENTLE PULSE 1
 618         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 619
 620         // 6 FLICKER (second variety)
 621         lightstyle(6, "nmonqnmomnmomomno");
 622
 623         // 7 CANDLE (second variety)
 624         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 625
 626         // 8 CANDLE (third variety)
 627         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 628
 629         // 9 SLOW STROBE (fourth variety)
 630         lightstyle(9, "aaaaaaaazzzzzzzz");
 631
 632         // 10 FLUORESCENT FLICKER
 633         lightstyle(10, "mmamammmmammamamaaamammma");
 634
 635         // 11 SLOW PULSE NOT FADE TO BLACK
 636         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 637
 638         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 639
 640         // 63 testing
 641         lightstyle(63, "a");
 642
 643         if(autocvar_g_campaign)
 644                 CampaignPreInit();
 645
 646         Map_MarkAsRecent(mapname);
 647
 648         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 649
 650         precache_model ("null"); // we need this one before InitGameplayMode
 651         InitGameplayMode();
 652         readlevelcvars();
 653         GrappleHookInit();
 654         ElectroInit();
 655         LaserInit();
 656
 657         player_count = 0;
 658         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 659         if(bot_waypoints_for_items == 1)
 660                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 661                         bot_waypoints_for_items = 0;
 662
 663         precache();
 664
 665         WaypointSprite_Init();
 666
 667         GameLogInit(); // prepare everything
 668         // NOTE for matchid:
 669         // changing the logic generating it is okay. But:
 670         // it HAS to stay <= 64 chars
 671         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 672         if(autocvar_sv_eventlog)
 673         {
 674                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 675                 matchid = strzone(s);
 676
 677                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 678                 s = ":gameinfo:mutators:LIST";
 679
 680                 ret_string = s;
 681                 MUTATOR_CALLHOOK(BuildMutatorsString);
 682                 s = ret_string;
 683
 684                 // simple, probably not good in the mutator system
 685                 if(autocvar_g_grappling_hook)
 686                         s = strcat(s, ":grappling_hook");
 687
 688                 // initialiation stuff, not good in the mutator system
 689                 if(!autocvar_g_use_ammunition)
 690                         s = strcat(s, ":no_use_ammunition");
 691
 692                 // initialiation stuff, not good in the mutator system
 693                 if(autocvar_g_pickup_items == 0)
 694                         s = strcat(s, ":no_pickup_items");
 695                 if(autocvar_g_pickup_items > 0)
 696                         s = strcat(s, ":pickup_items");
 697
 698                 // initialiation stuff, not good in the mutator system
 699                 if(autocvar_g_weaponarena != "0")
 700                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 701
 702                 // TODO to mutator system
 703                 if(autocvar_g_norecoil)
 704                         s = strcat(s, ":norecoil");
 705
 706                 // TODO to mutator system
 707                 if(autocvar_g_powerups == 0)
 708                         s = strcat(s, ":no_powerups");
 709                 if(autocvar_g_powerups > 0)
 710                         s = strcat(s, ":powerups");
 711
 712                 GameLogEcho(s);
 713                 GameLogEcho(":gameinfo:end");
 714         }
 715         else
 716                 matchid = strzone(ftos(random()));
 717
 718         cvar_set("nextmap", "");
 719
 720         SetDefaultAlpha();
 721
 722         if(autocvar_g_campaign)
 723                 CampaignPostInit();
 724
 725         fteqcc_testbugs();
 726
 727         Ban_LoadBans();
 728
 729         MapInfo_Enumerate();
 730         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 731
 732         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 733         {
 734                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 735                 if(fd != -1)
 736                 {
 737                         while((s = fgets(fd)))
 738                         {
 739                                 l = tokenize_console(s);
 740                                 if(l < 2)
 741                                         continue;
 742                                 if(argv(0) == "cd")
 743                                 {
 744                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 745                                         print("  cdtrack ", argv(2), "\n");
 746                                 }
 747                                 else if(argv(0) == "fog")
 748                                 {
 749                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 750                                         print("  \"fog\" \"", s, "\"\n");
 751                                 }
 752                                 else if(argv(0) == "set")
 753                                 {
 754                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 755                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 756                                 }
 757                                 else if(argv(0) != "//")
 758                                 {
 759                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 760                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 761                                 }
 762                         }
 763                         fclose(fd);
 764                 }
 765         }
 766
 767         WeaponStats_Init();
 768
 769         WepSet_AddStat();
 770         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 771         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 772         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 773         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 774         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 775         Nagger_Init();
 776
 777         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 778         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 779         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 780         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 781         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 782         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 783         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 784         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 785         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 786         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 787         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 788         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 789         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 790
 791         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 792         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 793
 794         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 795
 796         // g_movementspeed hack
 797         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 798         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 799         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 800         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 801
 802         // secrets
 803         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 804         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 805
 806         // monsters
 807         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 808         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 809
 810         // misc
 811         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 812
 813         next_pingtime = time + 5;
 814
 815         detect_maptype();
 816
 817         // set up information replies for clients and server to use
 818         maplist_reply = strzone(getmaplist());
 819         lsmaps_reply = strzone(getlsmaps());
 820         monsterlist_reply = strzone(getmonsterlist());
 821         for(i = 0; i < 10; ++i)
 822         {
 823                 s = getrecords(i);
 824                 if (s)
 825                         records_reply[i] = strzone(s);
 826         }
 827         ladder_reply = strzone(getladder());
 828         rankings_reply = strzone(getrankings());
 829
 830         // begin other init
 831         ClientInit_Spawn();
 832         RandomSeed_Spawn();
 833         PingPLReport_Spawn();
 834
 835         CheatInit();
 836
 837         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 838
 839         // fill sv_curl_serverpackages from .serverpackage files
 840         if(autocvar_sv_curl_serverpackages_auto)
 841         {
 842                 s = "";
 843                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 844                 for(i = 0; i < n; ++i)
 845                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 846                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 847                                 s = strcat(s, " ", argv(i));
 848                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 849                 if(fd >= 0)
 850                 {
 851                         j = search_getsize(fd);
 852                         for(i = 0; i < j; ++i)
 853                                 s = strcat(s, " ", search_getfilename(fd, i));
 854                         search_end(fd);
 855                 }
 856                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 857                 if(fd >= 0)
 858                 {
 859                         j = search_getsize(fd);
 860                         for(i = 0; i < j; ++i)
 861                                 s = strcat(s, " ", search_getfilename(fd, i));
 862                         search_end(fd);
 863                 }
 864                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 865         }
 866
 867         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 868         modname = "Xonotic";
 869         // physics/balance/config changes that count as mod
 870         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 871                 modname = cvar_string("g_mod_physics");
 872         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 873                 modname = cvar_string("g_mod_balance");
 874         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 875                 modname = cvar_string("g_mod_config");
 876         // extra mutators that deserve to count as mod
 877         MUTATOR_CALLHOOK(SetModname);
 878
 879         // save it for later
 880         modname = strzone(modname);
 881
 882         WinningConditionHelper(); // set worldstatus
 883
 884         world_initialized = 1;
 885 }
 886
 887 void spawnfunc_light (void)
 888 {
 889         //makestatic (self); // Who the f___ did that?
 890         remove(self);
 891 }
 892
 893 string GetGametype()
 894 {
 895         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 896 }
 897
 898 string GetMapname()
 899 {
 900         return mapname;
 901 }
 902
 903 float Map_Count, Map_Current;
 904 string Map_Current_Name;
 905
 906 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 907 float GetMaplistPosition()
 908 {
 909         float pos, idx;
 910         string map;
 911
 912         map = GetMapname();
 913         idx = autocvar_g_maplist_index;
 914
 915         if(idx >= 0)
 916                 if(idx < Map_Count)
 917                         if(map == argv(idx))
 918                                 return idx;
 919
 920         for(pos = 0; pos < Map_Count; ++pos)
 921                 if(map == argv(pos))
 922                         return pos;
 923
 924         // resume normal maplist rotation if current map is not in g_maplist
 925         return idx;
 926 }
 927
 928 float MapHasRightSize(string map)
 929 {
 930         float fh;
 931         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 932         if(autocvar_g_maplist_check_waypoints)
 933         {
 934                 dprint("checkwp "); dprint(map);
 935                 if(!fexists(strcat("maps/", map, ".waypoints")))
 936                 {
 937                         dprint(": no waypoints\n");
 938                         return FALSE;
 939                 }
 940                 dprint(": has waypoints\n");
 941         }
 942
 943         // open map size restriction file
 944         dprint("opensize "); dprint(map);
 945         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 946         if(fh >= 0)
 947         {
 948                 float mapmin, mapmax;
 949                 dprint(": ok, ");
 950                 mapmin = stof(fgets(fh));
 951                 mapmax = stof(fgets(fh));
 952                 fclose(fh);
 953                 if(player_count < mapmin)
 954                 {
 955                         dprint("not enough\n");
 956                         return FALSE;
 957                 }
 958                 if(player_count > mapmax)
 959                 {
 960                         dprint("too many\n");
 961                         return FALSE;
 962                 }
 963                 dprint("right size\n");
 964                 return TRUE;
 965         }
 966         dprint(": not found\n");
 967         return TRUE;
 968 }
 969
 970 string Map_Filename(float position)
 971 {
 972         return strcat("maps/", argv(position), ".bsp");
 973 }
 974
 975 string strwords(string s, float w)
 976 {
 977         float endpos;
 978         for(endpos = 0; w && endpos >= 0; --w)
 979                 endpos = strstrofs(s, " ", endpos + 1);
 980         if(endpos < 0)
 981                 return s;
 982         else
 983                 return substring(s, 0, endpos);
 984 }
 985
 986 float strhasword(string s, string w)
 987 {
 988         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 989 }
 990
 991 void Map_MarkAsRecent(string m)
 992 {
 993         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 994 }
 995
 996 float Map_IsRecent(string m)
 997 {
 998         return strhasword(autocvar_g_maplist_mostrecent, m);
 999 }
1000
1001 float Map_Check(float position, float pass)
1002 {
1003         string filename;
1004         string map_next;
1005         map_next = argv(position);
1006         if(pass <= 1)
1007         {
1008                 if(Map_IsRecent(map_next))
1009                         return 0;
1010         }
1011         filename = Map_Filename(position);
1012         if(MapInfo_CheckMap(map_next))
1013         {
1014                 if(pass == 2)
1015                         return 1;
1016                 if(MapHasRightSize(map_next))
1017                         return 1;
1018                 return 0;
1019         }
1020         else
1021                 dprint( "Couldn't select '", filename, "'..\n" );
1022
1023         return 0;
1024 }
1025
1026 void Map_Goto_SetStr(string nextmapname)
1027 {
1028         if(getmapname_stored != "")
1029                 strunzone(getmapname_stored);
1030         if(nextmapname == "")
1031                 getmapname_stored = "";
1032         else
1033                 getmapname_stored = strzone(nextmapname);
1034 }
1035
1036 void Map_Goto_SetFloat(float position)
1037 {
1038         cvar_set("g_maplist_index", ftos(position));
1039         Map_Goto_SetStr(argv(position));
1040 }
1041
1042 void Map_Goto(float reinit)
1043 {
1044         MapInfo_LoadMap(getmapname_stored, reinit);
1045 }
1046
1047 // return codes of map selectors:
1048 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1049 //   -2 = permanent failure
1050 float() MaplistMethod_Iterate = // usual method
1051 {
1052         float pass, i;
1053
1054         dprint("Trying MaplistMethod_Iterate\n");
1055
1056         for(pass = 1; pass <= 2; ++pass)
1057         {
1058                 for(i = 1; i < Map_Count; ++i)
1059                 {
1060                         float mapindex;
1061                         mapindex = mod(i + Map_Current, Map_Count);
1062                         if(Map_Check(mapindex, pass))
1063                                 return mapindex;
1064                 }
1065         }
1066         return -1;
1067 }
1068
1069 float() MaplistMethod_Repeat = // fallback method
1070 {
1071         dprint("Trying MaplistMethod_Repeat\n");
1072
1073         if(Map_Check(Map_Current, 2))
1074                 return Map_Current;
1075         return -2;
1076 }
1077
1078 float() MaplistMethod_Random = // random map selection
1079 {
1080         float i, imax;
1081
1082         dprint("Trying MaplistMethod_Random\n");
1083
1084         imax = 42;
1085
1086         for(i = 0; i <= imax; ++i)
1087         {
1088                 float mapindex;
1089                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1090                 if(Map_Check(mapindex, 1))
1091                         return mapindex;
1092         }
1093         return -1;
1094 }
1095
1096 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1097 // the exponent sets a bias on the map selection:
1098 // the higher the exponent, the less likely "shortly repeated" same maps are
1099 {
1100         float i, j, imax, insertpos;
1101
1102         dprint("Trying MaplistMethod_Shuffle\n");
1103
1104         imax = 42;
1105
1106         for(i = 0; i <= imax; ++i)
1107         {
1108                 string newlist;
1109
1110                 // now reinsert this at another position
1111                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1112                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1113                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1114                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1115
1116                 // insert the current map there
1117                 newlist = "";
1118                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1119                         newlist = strcat(newlist, " ", argv(j));
1120                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1121                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1122                         newlist = strcat(newlist, " ", argv(j));
1123                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1124                 cvar_set("g_maplist", newlist);
1125                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1126
1127                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1128                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1129                 if(Map_Check(Map_Current, 1))
1130                         return Map_Current;
1131         }
1132         return -1;
1133 }
1134
1135 void Maplist_Init()
1136 {
1137         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1138         float i;
1139         for (i = 0; i < Map_Count; ++i)
1140                 if (Map_Check(i, 2))
1141                         break;
1142         if (i == Map_Count)
1143         {
1144                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1145                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1146                 if(autocvar_g_maplist_shuffle)
1147                         ShuffleMaplist();
1148                 localcmd("\nmenu_cmd sync\n");
1149                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1150         }
1151         if(Map_Count == 0)
1152                 error("empty maplist, cannot select a new map");
1153         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1154
1155         if(Map_Current_Name)
1156                 strunzone(Map_Current_Name);
1157         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1158         // this may or may not be correct, but who cares, in the worst case a map
1159         // isn't chosen in the first pass that should have been
1160 }
1161
1162 string GetNextMap()
1163 {
1164         float nextMap;
1165
1166         Maplist_Init();
1167         nextMap = -1;
1168
1169         if(nextMap == -1)
1170                 if(autocvar_g_maplist_shuffle > 0)
1171                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1172
1173         if(nextMap == -1)
1174                 if(autocvar_g_maplist_selectrandom)
1175                         nextMap = MaplistMethod_Random();
1176
1177         if(nextMap == -1)
1178                 nextMap = MaplistMethod_Iterate();
1179
1180         if(nextMap == -1)
1181                 nextMap = MaplistMethod_Repeat();
1182
1183         if(nextMap >= 0)
1184         {
1185                 Map_Goto_SetFloat(nextMap);
1186                 return getmapname_stored;
1187         }
1188
1189         return "";
1190 }
1191
1192 float DoNextMapOverride(float reinit)
1193 {
1194         if(autocvar_g_campaign)
1195         {
1196                 CampaignPostIntermission();
1197                 alreadychangedlevel = TRUE;
1198                 return TRUE;
1199         }
1200         if(autocvar_quit_when_empty)
1201         {
1202                 if(player_count <= currentbots)
1203                 {
1204                         localcmd("quit\n");
1205                         alreadychangedlevel = TRUE;
1206                         return TRUE;
1207                 }
1208         }
1209         if(autocvar_quit_and_redirect != "")
1210         {
1211                 redirection_target = strzone(autocvar_quit_and_redirect);
1212                 alreadychangedlevel = TRUE;
1213                 return TRUE;
1214         }
1215         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1216         {
1217                 localcmd("restart\n");
1218                 alreadychangedlevel = TRUE;
1219                 return TRUE;
1220         }
1221         if(autocvar_nextmap != "")
1222         {
1223                 string m;
1224                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1225                 cvar_set("nextmap",m);
1226
1227                 if(!m || gametypevote)
1228                         return FALSE;
1229                 if(autocvar_sv_vote_gametype)
1230                 {
1231                         Map_Goto_SetStr(m);
1232                         return FALSE;
1233                 }
1234
1235                 if(MapInfo_CheckMap(m))
1236                 {
1237                         Map_Goto_SetStr(m);
1238                         Map_Goto(reinit);
1239                         alreadychangedlevel = TRUE;
1240                         return TRUE;
1241                 }
1242         }
1243         if(!reinit && autocvar_lastlevel)
1244         {
1245                 cvar_settemp_restore();
1246                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1247                 alreadychangedlevel = TRUE;
1248                 return TRUE;
1249         }
1250         return FALSE;
1251 }
1252
1253 void GotoNextMap(float reinit)
1254 {
1255         //string nextmap;
1256         //float n, nummaps;
1257         //string s;
1258         if (alreadychangedlevel)
1259                 return;
1260         alreadychangedlevel = TRUE;
1261
1262         string nextMap;
1263
1264         nextMap = GetNextMap();
1265         if(nextMap == "")
1266                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1267         Map_Goto(reinit);
1268 }
1269
1270
1271 /*
1272 ============
1273 IntermissionThink
1274
1275 When the player presses attack or jump, change to the next level
1276 ============
1277 */
1278 .float autoscreenshot;
1279 void IntermissionThink()
1280 {
1281         FixIntermissionClient(self);
1282
1283         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1284         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1285
1286         if( (server_screenshot || client_screenshot)
1287                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1288         {
1289                 self.autoscreenshot = -1;
1290                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1291                 return;
1292         }
1293
1294         if (time < intermission_exittime)
1295                 return;
1296
1297         if(!mapvote_initialized)
1298                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1299                         return;
1300
1301         MapVote_Start();
1302 }
1303
1304 /*
1305 ============
1306 FindIntermission
1307
1308 Returns the entity to view from
1309 ============
1310 */
1311 /*
1312 entity FindIntermission()
1313 {
1314         local   entity spot;
1315         local   float cyc;
1316
1317 // look for info_intermission first
1318         spot = find (world, classname, "info_intermission");
1319         if (spot)
1320         {       // pick a random one
1321                 cyc = random() * 4;
1322                 while (cyc > 1)
1323                 {
1324                         spot = find (spot, classname, "info_intermission");
1325                         if (!spot)
1326                                 spot = find (spot, classname, "info_intermission");
1327                         cyc = cyc - 1;
1328                 }
1329                 return spot;
1330         }
1331
1332 // then look for the start position
1333         spot = find (world, classname, "info_player_start");
1334         if (spot)
1335                 return spot;
1336
1337 // testinfo_player_start is only found in regioned levels
1338         spot = find (world, classname, "testplayerstart");
1339         if (spot)
1340                 return spot;
1341
1342 // then look for the start position
1343         spot = find (world, classname, "info_player_deathmatch");
1344         if (spot)
1345                 return spot;
1346
1347         //objerror ("FindIntermission: no spot");
1348         return world;
1349 }
1350 */
1351
1352 /*
1353 ===============================================================================
1354
1355 RULES
1356
1357 ===============================================================================
1358 */
1359
1360 void DumpStats(float final)
1361 {
1362         float file;
1363         string s;
1364         float to_console;
1365         float to_eventlog;
1366         float to_file;
1367         float i;
1368
1369         to_console = autocvar_sv_logscores_console;
1370         to_eventlog = autocvar_sv_eventlog;
1371         to_file = autocvar_sv_logscores_file;
1372
1373         if(!final)
1374         {
1375                 to_console = TRUE; // always print printstats replies
1376                 to_eventlog = FALSE; // but never print them to the event log
1377         }
1378
1379         if(to_eventlog)
1380                 if(autocvar_sv_eventlog_console)
1381                         to_console = FALSE; // otherwise we get the output twice
1382
1383         if(final)
1384                 s = ":scores:";
1385         else
1386                 s = ":status:";
1387         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1388
1389         if(to_console)
1390                 print(s, "\n");
1391         if(to_eventlog)
1392                 GameLogEcho(s);
1393
1394         file = -1;
1395         if(to_file)
1396         {
1397                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1398                 if(file == -1)
1399                         to_file = FALSE;
1400                 else
1401                         fputs(file, strcat(s, "\n"));
1402         }
1403
1404         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1405         if(to_console)
1406                 print(s, "\n");
1407         if(to_eventlog)
1408                 GameLogEcho(s);
1409         if(to_file)
1410                 fputs(file, strcat(s, "\n"));
1411
1412         FOR_EACH_CLIENT(other)
1413         {
1414                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1415                 {
1416                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1417                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1418                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1419                                 s = strcat(s, ftos(other.team), ":");
1420                         else
1421                                 s = strcat(s, "spectator:");
1422
1423                         if(to_console)
1424                                 print(s, other.netname, "\n");
1425                         if(to_eventlog)
1426                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1427                         if(to_file)
1428                                 fputs(file, strcat(s, other.netname, "\n"));
1429                 }
1430         }
1431
1432         if(teamplay)
1433         {
1434                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1435                 if(to_console)
1436                         print(s, "\n");
1437                 if(to_eventlog)
1438                         GameLogEcho(s);
1439                 if(to_file)
1440                         fputs(file, strcat(s, "\n"));
1441
1442                 for(i = 1; i < 16; ++i)
1443                 {
1444                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1445                         s = strcat(s, ":", ftos(i));
1446                         if(to_console)
1447                                 print(s, "\n");
1448                         if(to_eventlog)
1449                                 GameLogEcho(s);
1450                         if(to_file)
1451                                 fputs(file, strcat(s, "\n"));
1452                 }
1453         }
1454
1455         if(to_console)
1456                 print(":end\n");
1457         if(to_eventlog)
1458                 GameLogEcho(":end");
1459         if(to_file)
1460         {
1461                 fputs(file, ":end\n");
1462                 fclose(file);
1463         }
1464 }
1465
1466 void FixIntermissionClient(entity e)
1467 {
1468         string s;
1469         if(!e.autoscreenshot) // initial call
1470         {
1471                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1472                 e.health = -2342;
1473                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1474                 e.solid = SOLID_NOT;
1475                 e.movetype = MOVETYPE_NONE;
1476                 e.takedamage = DAMAGE_NO;
1477                 if(e.weaponentity)
1478                 {
1479                         e.weaponentity.effects = EF_NODRAW;
1480                         if (e.weaponentity.weaponentity)
1481                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1482                 }
1483                 if(IS_REAL_CLIENT(e))
1484                 {
1485                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1486                         s = autocvar_sv_intermission_cdtrack;
1487                         if(s != "")
1488                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1489                         msg_entity = e;
1490                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1491                 }
1492         }
1493 }
1494
1495 /*
1496 go to the next level for deathmatch
1497 only called if a time or frag limit has expired
1498 */
1499 void NextLevel()
1500 {
1501         gameover = TRUE;
1502
1503         intermission_running = 1;
1504
1505 // enforce a wait time before allowing changelevel
1506         if(player_count > 0)
1507                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1508         else
1509                 intermission_exittime = -1;
1510
1511         /*
1512         WriteByte (MSG_ALL, SVC_CDTRACK);
1513         WriteByte (MSG_ALL, 3);
1514         WriteByte (MSG_ALL, 3);
1515         // done in FixIntermission
1516         */
1517
1518         //pos = FindIntermission ();
1519
1520         VoteReset();
1521
1522         DumpStats(TRUE);
1523
1524         // send statistics
1525         entity e;
1526         PlayerStats_EndMatch(1);
1527         FOR_EACH_CLIENT(e)
1528                 PlayerStats_AddGlobalInfo(e);
1529         PlayerStats_Shutdown();
1530         WeaponStats_Shutdown();
1531
1532         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1533
1534         if(autocvar_sv_eventlog)
1535                 GameLogEcho(":gameover");
1536
1537         GameLogClose();
1538
1539         FOR_EACH_PLAYER(other) {
1540                 FixIntermissionClient(other);
1541                 if(other.winning)
1542                         bprint(other.netname, " ^7wins.\n");
1543         }
1544
1545         if(autocvar_g_campaign)
1546                 CampaignPreIntermission();
1547
1548         MUTATOR_CALLHOOK(MatchEnd);
1549
1550         localcmd("\nsv_hook_gameend\n");
1551 }
1552
1553 /*
1554 ============
1555 CheckRules_Player
1556
1557 Exit deathmatch games upon conditions
1558 ============
1559 */
1560 void CheckRules_Player()
1561 {
1562         if (gameover)   // someone else quit the game already
1563                 return;
1564
1565         if(self.deadflag == DEAD_NO)
1566                 self.play_time += frametime;
1567
1568         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1569         //   (div0: and that in CheckRules_World please)
1570 }
1571
1572 float checkrules_equality;
1573 float checkrules_suddendeathwarning;
1574 float checkrules_suddendeathend;
1575 float checkrules_overtimesadded; //how many overtimes have been already added
1576
1577 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1578 const float WINNING_YES = 1; // winner found
1579 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1580 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1581
1582 float InitiateSuddenDeath()
1583 {
1584         // Check first whether normal overtimes could be added before initiating suddendeath mode
1585         // - for this timelimit_overtime needs to be >0 of course
1586         // - also check the winning condition calculated in the previous frame and only add normal overtime
1587         //   again, if at the point at which timelimit would be extended again, still no winner was found
1588         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1589         {
1590                 return 1; // need to call InitiateOvertime later
1591         }
1592         else
1593         {
1594                 if(!checkrules_suddendeathend)
1595                 {
1596                         if(autocvar_g_campaign)
1597                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1598                         else
1599                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1600                         if(g_race && !g_race_qualifying)
1601                                 race_StartCompleting();
1602                 }
1603                 return 0;
1604         }
1605 }
1606
1607 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1608 {
1609         ++checkrules_overtimesadded;
1610         //add one more overtime by simply extending the timelimit
1611         float tl;
1612         tl = autocvar_timelimit;
1613         tl += autocvar_timelimit_overtime;
1614         cvar_set("timelimit", ftos(tl));
1615
1616         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1617 }
1618
1619 float GetWinningCode(float fraglimitreached, float equality)
1620 {
1621         if(autocvar_g_campaign == 1)
1622                 if(fraglimitreached)
1623                         return WINNING_YES;
1624                 else
1625                         return WINNING_NO;
1626
1627         else
1628                 if(equality)
1629                         if(fraglimitreached)
1630                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1631                         else
1632                                 return WINNING_NEVER;
1633                 else
1634                         if(fraglimitreached)
1635                                 return WINNING_YES;
1636                         else
1637                                 return WINNING_NO;
1638 }
1639
1640 // set the .winning flag for exactly those players with a given field value
1641 void SetWinners(.float field, float value)
1642 {
1643         entity head;
1644         FOR_EACH_PLAYER(head)
1645                 head.winning = (head.field == value);
1646 }
1647
1648 // set the .winning flag for those players with a given field value
1649 void AddWinners(.float field, float value)
1650 {
1651         entity head;
1652         FOR_EACH_PLAYER(head)
1653                 if(head.field == value)
1654                         head.winning = 1;
1655 }
1656
1657 // clear the .winning flags
1658 void ClearWinners(void)
1659 {
1660         entity head;
1661         FOR_EACH_PLAYER(head)
1662                 head.winning = 0;
1663 }
1664
1665 // Onslaught winning condition:
1666 // game terminates if only one team has a working generator (or none)
1667 float WinningCondition_Onslaught()
1668 {
1669         entity head;
1670         float t1, t2, t3, t4;
1671
1672         WinningConditionHelper(); // set worldstatus
1673
1674         if(warmup_stage)
1675                 return WINNING_NO;
1676
1677         // first check if the game has ended
1678         t1 = t2 = t3 = t4 = 0;
1679         head = find(world, classname, "onslaught_generator");
1680         while (head)
1681         {
1682                 if (head.health > 0)
1683                 {
1684                         if (head.team == NUM_TEAM_1) t1 = 1;
1685                         if (head.team == NUM_TEAM_2) t2 = 1;
1686                         if (head.team == NUM_TEAM_3) t3 = 1;
1687                         if (head.team == NUM_TEAM_4) t4 = 1;
1688                 }
1689                 head = find(head, classname, "onslaught_generator");
1690         }
1691         if (t1 + t2 + t3 + t4 < 2)
1692         {
1693                 // game over, only one team remains (or none)
1694                 ClearWinners();
1695                 if (t1) SetWinners(team, NUM_TEAM_1);
1696                 if (t2) SetWinners(team, NUM_TEAM_2);
1697                 if (t3) SetWinners(team, NUM_TEAM_3);
1698                 if (t4) SetWinners(team, NUM_TEAM_4);
1699                 dprint("Have a winner, ending game.\n");
1700                 return WINNING_YES;
1701         }
1702
1703         // Two or more teams remain
1704         return WINNING_NO;
1705 }
1706
1707 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1708 // they win. Otherwise the defending team wins once the timelimit passes.
1709 void assault_new_round();
1710 float WinningCondition_Assault()
1711 {
1712         float status;
1713
1714         WinningConditionHelper(); // set worldstatus
1715
1716         status = WINNING_NO;
1717         // as the timelimit has not yet passed just assume the defending team will win
1718         if(assault_attacker_team == NUM_TEAM_1)
1719         {
1720                 SetWinners(team, NUM_TEAM_2);
1721         }
1722         else
1723         {
1724                 SetWinners(team, NUM_TEAM_1);
1725         }
1726
1727         entity ent;
1728         ent = find(world, classname, "target_assault_roundend");
1729         if(ent)
1730         {
1731                 if(ent.winning) // round end has been triggered by attacking team
1732                 {
1733                         bprint("ASSAULT: round completed...\n");
1734                         SetWinners(team, assault_attacker_team);
1735
1736                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1737
1738                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1739                         {
1740                                 status = WINNING_YES;
1741                         }
1742                         else
1743                         {
1744                                 entity oldself;
1745                                 oldself = self;
1746                                 self = ent;
1747                                 assault_new_round();
1748                                 self = oldself;
1749                         }
1750                 }
1751         }
1752
1753         return status;
1754 }
1755
1756 // LMS winning condition: game terminates if and only if there's at most one
1757 // one player who's living lives. Top two scores being equal cancels the time
1758 // limit.
1759 float WinningCondition_LMS()
1760 {
1761         entity head, head2;
1762         float have_player;
1763         float have_players;
1764         float l;
1765
1766         have_player = FALSE;
1767         have_players = FALSE;
1768         l = LMS_NewPlayerLives();
1769
1770         head = find(world, classname, "player");
1771         if(head)
1772                 have_player = TRUE;
1773         head2 = find(head, classname, "player");
1774         if(head2)
1775                 have_players = TRUE;
1776
1777         if(have_player)
1778         {
1779                 // we have at least one player
1780                 if(have_players)
1781                 {
1782                         // two or more active players - continue with the game
1783                 }
1784                 else
1785                 {
1786                         // exactly one player?
1787
1788                         ClearWinners();
1789                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1790
1791                         if(l)
1792                         {
1793                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1794                                 return WINNING_NO;
1795                         }
1796                         else
1797                         {
1798                                 // a winner!
1799                                 // and assign him his first place
1800                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1801                                 return WINNING_YES;
1802                         }
1803                 }
1804         }
1805         else
1806         {
1807                 // nobody is playing at all...
1808                 if(l)
1809                 {
1810                         // wait for players...
1811                 }
1812                 else
1813                 {
1814                         // SNAFU (maybe a draw game?)
1815                         ClearWinners();
1816                         dprint("No players, ending game.\n");
1817                         return WINNING_YES;
1818                 }
1819         }
1820
1821         // When we get here, we have at least two players who are actually LIVING,
1822         // now check if the top two players have equal score.
1823         WinningConditionHelper();
1824
1825         ClearWinners();
1826         if(WinningConditionHelper_winner)
1827                 WinningConditionHelper_winner.winning = TRUE;
1828         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1829                 return WINNING_NEVER;
1830
1831         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1832         return WINNING_NO;
1833 }
1834
1835 void ShuffleMaplist()
1836 {
1837         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1838 }
1839
1840 float leaderfrags;
1841 float WinningCondition_Scores(float limit, float leadlimit)
1842 {
1843         float limitreached;
1844
1845         // TODO make everything use THIS winning condition (except LMS)
1846         WinningConditionHelper();
1847
1848         if(teamplay)
1849         {
1850                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1851                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1852                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1853                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1854         }
1855
1856         ClearWinners();
1857         if(WinningConditionHelper_winner)
1858                 WinningConditionHelper_winner.winning = 1;
1859         if(WinningConditionHelper_winnerteam >= 0)
1860                 SetWinners(team, WinningConditionHelper_winnerteam);
1861
1862         if(WinningConditionHelper_lowerisbetter)
1863         {
1864                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1865                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1866                 limit = -limit;
1867         }
1868
1869         if(WinningConditionHelper_zeroisworst)
1870                 leadlimit = 0; // not supported in this mode
1871
1872         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1873         // these modes always score in increments of 1, thus this makes sense
1874         {
1875                 if(leaderfrags != WinningConditionHelper_topscore)
1876                 {
1877                         leaderfrags = WinningConditionHelper_topscore;
1878
1879                         if (limit)
1880                         if (leaderfrags == limit - 1)
1881                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1882                         else if (leaderfrags == limit - 2)
1883                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1884                         else if (leaderfrags == limit - 3)
1885                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1886                 }
1887         }
1888
1889         limitreached = FALSE;
1890         if(limit)
1891                 if(WinningConditionHelper_topscore >= limit)
1892                         limitreached = TRUE;
1893         if(leadlimit)
1894         {
1895                 float leadlimitreached;
1896                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1897                 if(autocvar_leadlimit_and_fraglimit)
1898                         limitreached = (limitreached && leadlimitreached);
1899                 else
1900                         limitreached = (limitreached || leadlimitreached);
1901         }
1902
1903         if(limit)
1904                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1905
1906         return GetWinningCode(
1907                 WinningConditionHelper_topscore && limitreached,
1908                 WinningConditionHelper_equality
1909         );
1910 }
1911
1912 float WinningCondition_Race(float fraglimit)
1913 {
1914         float wc;
1915         entity p;
1916         float n, c;
1917
1918         n = 0;
1919         c = 0;
1920         FOR_EACH_PLAYER(p)
1921         {
1922                 ++n;
1923                 if(p.race_completed)
1924                         ++c;
1925         }
1926         if(n && (n == c))
1927                 return WINNING_YES;
1928         wc = WinningCondition_Scores(fraglimit, 0);
1929
1930         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1931         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1932         // do NOT support equality when the laps are all raced!
1933                 return WINNING_STARTSUDDENDEATHOVERTIME;
1934         else
1935                 return WINNING_NEVER;
1936 }
1937
1938 float WinningCondition_QualifyingThenRace(float limit)
1939 {
1940         float wc;
1941         wc = WinningCondition_Scores(limit, 0);
1942
1943         // NEVER initiate overtime
1944         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1945         {
1946                 return WINNING_YES;
1947         }
1948
1949         return wc;
1950 }
1951
1952 float WinningCondition_RanOutOfSpawns()
1953 {
1954         entity head;
1955
1956         if(have_team_spawns <= 0)
1957                 return WINNING_NO;
1958
1959         if(autocvar_g_spawn_useallspawns <= 0)
1960                 return WINNING_NO;
1961
1962         if(!some_spawn_has_been_used)
1963                 return WINNING_NO;
1964
1965         team1_score = team2_score = team3_score = team4_score = 0;
1966
1967         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1968         {
1969                 if(head.team == NUM_TEAM_1)
1970                         team1_score = 1;
1971                 else if(head.team == NUM_TEAM_2)
1972                         team2_score = 1;
1973                 else if(head.team == NUM_TEAM_3)
1974                         team3_score = 1;
1975                 else if(head.team == NUM_TEAM_4)
1976                         team4_score = 1;
1977         }
1978
1979         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1980         {
1981                 if(head.team == NUM_TEAM_1)
1982                         team1_score = 1;
1983                 else if(head.team == NUM_TEAM_2)
1984                         team2_score = 1;
1985                 else if(head.team == NUM_TEAM_3)
1986                         team3_score = 1;
1987                 else if(head.team == NUM_TEAM_4)
1988                         team4_score = 1;
1989         }
1990
1991         ClearWinners();
1992         if(team1_score + team2_score + team3_score + team4_score == 0)
1993         {
1994                 checkrules_equality = TRUE;
1995                 return WINNING_YES;
1996         }
1997         else if(team1_score + team2_score + team3_score + team4_score == 1)
1998         {
1999                 float t, i;
2000                 if(team1_score)
2001                         t = NUM_TEAM_1;
2002                 else if(team2_score)
2003                         t = NUM_TEAM_2;
2004                 else if(team3_score)
2005                         t = NUM_TEAM_3;
2006                 else // if(team4_score)
2007                         t = NUM_TEAM_4;
2008                 CheckAllowedTeams(world);
2009                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2010                 {
2011                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2012                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2013                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2014                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2015                 }
2016
2017                 AddWinners(team, t);
2018                 return WINNING_YES;
2019         }
2020         else
2021                 return WINNING_NO;
2022 }
2023
2024 /*
2025 ============
2026 CheckRules_World
2027
2028 Exit deathmatch games upon conditions
2029 ============
2030 */
2031 void ReadyRestart();
2032 void CheckRules_World()
2033 {
2034         float timelimit;
2035         float fraglimit;
2036         float leadlimit;
2037
2038         VoteThink();
2039         MapVote_Think();
2040
2041         SetDefaultAlpha();
2042
2043         if (gameover)   // someone else quit the game already
2044         {
2045                 if(player_count == 0) // Nobody there? Then let's go to the next map
2046                         MapVote_Start();
2047                         // this will actually check the player count in the next frame
2048                         // again, but this shouldn't hurt
2049                 return;
2050         }
2051
2052         timelimit = autocvar_timelimit * 60;
2053         fraglimit = autocvar_fraglimit;
2054         leadlimit = autocvar_leadlimit;
2055
2056         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2057         {
2058                 if(timelimit > 0)
2059                         timelimit = 0; // timelimit is not made for warmup
2060                 if(fraglimit > 0)
2061                         fraglimit = 0; // no fraglimit for now
2062                 leadlimit = 0; // no leadlimit for now
2063         }
2064
2065         if(timelimit > 0)
2066         {
2067                 timelimit += game_starttime;
2068         }
2069         else if (timelimit < 0)
2070         {
2071                 // endmatch
2072                 NextLevel();
2073                 return;
2074         }
2075
2076         if(g_onslaught)
2077                 timelimit = 0; // ONS has its own overtime rule
2078
2079         float wantovertime;
2080         wantovertime = 0;
2081
2082         if(timelimit > game_starttime)
2083                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2084         else
2085                 game_completion_ratio = 0;
2086
2087         if(checkrules_suddendeathend)
2088         {
2089                 if(!checkrules_suddendeathwarning)
2090                 {
2091                         checkrules_suddendeathwarning = TRUE;
2092                         if(g_race && !g_race_qualifying)
2093                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2094                         else
2095                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2096                 }
2097         }
2098         else
2099         {
2100                 if (timelimit && time >= timelimit)
2101                 {
2102                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2103                         {
2104                                 float totalplayers;
2105                                 float playerswithlaps;
2106                                 float readyplayers;
2107                                 entity head;
2108                                 totalplayers = playerswithlaps = readyplayers = 0;
2109                                 FOR_EACH_PLAYER(head)
2110                                 {
2111                                         ++totalplayers;
2112                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2113                                                 ++playerswithlaps;
2114                                         if(head.ready)
2115                                                 ++readyplayers;
2116                                 }
2117
2118                                 // at least 2 of the players have completed a lap: start the RACE
2119                                 // otherwise, the players should end the qualifying on their own
2120                                 if(readyplayers || playerswithlaps >= 2)
2121                                 {
2122                                         checkrules_suddendeathend = 0;
2123                                         ReadyRestart(); // go to race
2124                                         return;
2125                                 }
2126                                 else
2127                                         wantovertime |= InitiateSuddenDeath();
2128                         }
2129                         else
2130                                 wantovertime |= InitiateSuddenDeath();
2131                 }
2132         }
2133
2134         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2135         {
2136                 NextLevel();
2137                 return;
2138         }
2139
2140         float checkrules_status;
2141         checkrules_status = WinningCondition_RanOutOfSpawns();
2142         if(checkrules_status == WINNING_YES)
2143         {
2144                 bprint("Hey! Someone ran out of spawns!\n");
2145         }
2146         else if(g_race && !g_race_qualifying && timelimit >= 0)
2147         {
2148                 checkrules_status = WinningCondition_Race(fraglimit);
2149                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2150         }
2151         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2152         {
2153                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2154                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2155         }
2156         else if(g_assault)
2157         {
2158                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2159         }
2160         else if(g_lms)
2161         {
2162                 checkrules_status = WinningCondition_LMS();
2163         }
2164         else if (g_onslaught)
2165         {
2166                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2167         }
2168         else
2169         {
2170                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2171                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2172         }
2173
2174         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2175         {
2176                 checkrules_status = WINNING_NEVER;
2177                 checkrules_overtimesadded = -1;
2178                 wantovertime |= InitiateSuddenDeath();
2179         }
2180
2181         if(checkrules_status == WINNING_NEVER)
2182                 // equality cases! Nobody wins if the overtime ends in a draw.
2183                 ClearWinners();
2184
2185         if(wantovertime)
2186         {
2187                 if(checkrules_status == WINNING_NEVER)
2188                         InitiateOvertime();
2189                 else
2190                         checkrules_status = WINNING_YES;
2191         }
2192
2193         if(checkrules_suddendeathend)
2194                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2195                         checkrules_status = WINNING_YES;
2196
2197         if(checkrules_status == WINNING_YES)
2198         {
2199                 //print("WINNING\n");
2200                 NextLevel();
2201         }
2202 }
2203
2204 string GotoMap(string m)
2205 {
2206         m = GameTypeVote_MapInfo_FixName(m);
2207         if (!m)
2208                 return "The map you suggested is not available on this server.";
2209         if (!autocvar_sv_vote_gametype)
2210         if(!MapInfo_CheckMap(m))
2211                 return "The map you suggested does not support the current game mode.";
2212         cvar_set("nextmap", m);
2213         cvar_set("timelimit", "-1");
2214         if(mapvote_initialized || alreadychangedlevel)
2215         {
2216                 if(DoNextMapOverride(0))
2217                         return "Map switch initiated.";
2218                 else
2219                         return "Hm... no. For some reason I like THIS map more.";
2220         }
2221         else
2222                 return "Map switch will happen after scoreboard.";
2223 }
2224
2225
2226 void EndFrame()
2227 {
2228         anticheat_endframe();
2229
2230         float altime;
2231         FOR_EACH_REALCLIENT(self)
2232         {
2233                 if(IS_SPEC(self))
2234                 {
2235                         if(self.enemy.typehitsound)
2236                                 self.typehit_time = time;
2237                         else if(self.enemy.hitsound)
2238                                 self.hit_time = time;
2239                 }
2240                 else
2241                 {
2242                         if(self.typehitsound)
2243                                 self.typehit_time = time;
2244                         else if(self.hitsound)
2245                                 self.hit_time = time;
2246                 }
2247         }
2248         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2249         // add 1 frametime because after this, engine SV_Physics
2250         // increases time by a frametime and then networks the frame
2251         // add another frametime because client shows everything with
2252         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2253         // needed!
2254         FOR_EACH_CLIENT(self)
2255         {
2256                 self.hitsound = FALSE;
2257                 self.typehitsound = FALSE;
2258                 antilag_record(self, altime);
2259         }
2260 }
2261
2262
2263 /*
2264  * RedirectionThink:
2265  * returns TRUE if redirecting
2266  */
2267 float redirection_timeout;
2268 float redirection_nextthink;
2269 float RedirectionThink()
2270 {
2271         float clients_found;
2272
2273         if(redirection_target == "")
2274                 return FALSE;
2275
2276         if(!redirection_timeout)
2277         {
2278                 cvar_set("sv_public", "-2");
2279                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2280                 if(redirection_target == "self")
2281                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2282                 else
2283                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2284         }
2285
2286         if(time < redirection_nextthink)
2287                 return TRUE;
2288
2289         redirection_nextthink = time + 1;
2290
2291         clients_found = 0;
2292         FOR_EACH_REALCLIENT(self)
2293         {
2294                 // TODO add timer
2295                 print("Redirecting: sending connect command to ", self.netname, "\n");
2296                 if(redirection_target == "self")
2297                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2298                 else
2299                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2300                 ++clients_found;
2301         }
2302
2303         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2304
2305         if(time > redirection_timeout || clients_found == 0)
2306                 localcmd("\nwait; wait; wait; quit\n");
2307
2308         return TRUE;
2309 }
2310
2311 void TargetMusic_RestoreGame();
2312 void RestoreGame()
2313 {
2314         // Loaded from a save game
2315         // some things then break, so let's work around them...
2316
2317         // Progs DB (capture records)
2318         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2319
2320         // Mapinfo
2321         MapInfo_Shutdown();
2322         MapInfo_Enumerate();
2323         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2324         WeaponStats_Init();
2325
2326         TargetMusic_RestoreGame();
2327 }
2328
2329 void Shutdown()
2330 {
2331         entity e;
2332
2333         gameover = 2;
2334
2335         if(world_initialized > 0)
2336         {
2337                 world_initialized = 0;
2338                 print("Saving persistent data...\n");
2339                 Ban_SaveBans();
2340
2341                 PlayerStats_EndMatch(0);
2342                 FOR_EACH_CLIENT(e)
2343                         PlayerStats_AddGlobalInfo(e);
2344                 PlayerStats_Shutdown();
2345
2346                 if(!cheatcount_total)
2347                 {
2348                         if(autocvar_sv_db_saveasdump)
2349                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2350                         else
2351                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2352                 }
2353                 if(autocvar_developer)
2354                 {
2355                         if(autocvar_sv_db_saveasdump)
2356                                 db_dump(TemporaryDB, "server-temp.db");
2357                         else
2358                                 db_save(TemporaryDB, "server-temp.db");
2359                 }
2360                 CheatShutdown(); // must be after cheatcount check
2361                 db_close(ServerProgsDB);
2362                 db_close(TemporaryDB);
2363                 print("done!\n");
2364                 // tell the bot system the game is ending now
2365                 bot_endgame();
2366
2367                 WeaponStats_Shutdown();
2368                 MapInfo_Shutdown();
2369         }
2370         else if(world_initialized == 0)
2371         {
2372                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2373         }
2374 }