qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ca_teams");
 260                 BADCVAR("g_ctf");
 261                 BADCVAR("g_cts");
 262                 BADCVAR("g_dm");
 263                 BADCVAR("g_domination");
 264                 BADCVAR("g_domination_default_teams");
 265                 BADCVAR("g_freezetag");
 266                 BADCVAR("g_freezetag_teams");
 267                 BADCVAR("g_keepaway");
 268                 BADCVAR("g_keyhunt");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_qualifying_timelimit");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("leadlimit_and_fraglimit");
 319                 BADCVAR("leadlimit_override");
 320                 BADCVAR("pausable");
 321                 BADCVAR("sv_allow_fullbright");
 322                 BADCVAR("sv_checkforpacketsduringsleep");
 323                 BADCVAR("sv_fraginfo");
 324                 BADCVAR("sv_timeout");
 325                 BADPREFIX("sv_timeout_");
 326                 BADPREFIX("crypto_");
 327                 BADPREFIX("g_chat_");
 328                 BADPREFIX("g_ctf_captimerecord_");
 329                 BADPREFIX("g_maplist_votable_");
 330                 BADPREFIX("net_");
 331                 BADPREFIX("prvm_");
 332                 BADPREFIX("skill_");
 333                 BADPREFIX("sv_cullentities_");
 334                 BADPREFIX("sv_fraginfo_");
 335                 BADPREFIX("sv_maxidle_");
 336                 BADPREFIX("sv_vote_");
 337                 BADPREFIX("timelimit_");
 338                 BADCVAR("gameversion");
 339                 BADPREFIX("gameversion_");
 340                 BADCVAR("sv_namechangetimer");
 341
 342                 // allowed changes to server admins (please sync this to server.cfg)
 343                 // vi commands:
 344                 //   :/"impure"/,$d
 345                 //   :g!,^\/\/[^ /],d
 346                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 347                 //   :%!sort
 348                 // yes, this does contain some redundant stuff, don't really care
 349                 BADCVAR("bot_config_file");
 350                 BADCVAR("bot_number");
 351                 BADCVAR("bot_prefix");
 352                 BADCVAR("bot_suffix");
 353                 BADCVAR("capturelimit_override");
 354                 BADCVAR("fraglimit_override");
 355                 BADCVAR("gametype");
 356                 BADCVAR("g_antilag");
 357                 BADCVAR("g_balance_teams");
 358                 BADCVAR("g_balance_teams_prevent_imbalance");
 359                 BADCVAR("g_balance_teams_scorefactor");
 360                 BADCVAR("g_ban_sync_trusted_servers");
 361                 BADCVAR("g_ban_sync_uri");
 362                 BADCVAR("g_ca_teams_override");
 363                 BADCVAR("g_ctf_ignore_frags");
 364                 BADCVAR("g_domination_point_limit");
 365                 BADCVAR("g_freezetag_teams_override");
 366                 BADCVAR("g_friendlyfire");
 367                 BADCVAR("g_fullbrightitems");
 368                 BADCVAR("g_fullbrightplayers");
 369                 BADCVAR("g_keyhunt_point_limit");
 370                 BADCVAR("g_keyhunt_teams_override");
 371                 BADCVAR("g_lms_lives_override");
 372                 BADCVAR("g_maplist");
 373                 BADCVAR("g_maplist_check_waypoints");
 374                 BADCVAR("g_maplist_mostrecent_count");
 375                 BADCVAR("g_maplist_shuffle");
 376                 BADCVAR("g_maplist_votable");
 377                 BADCVAR("g_maplist_votable_abstain");
 378                 BADCVAR("g_maplist_votable_nodetail");
 379                 BADCVAR("g_maplist_votable_suggestions");
 380                 BADCVAR("g_maxplayers");
 381                 BADCVAR("g_mirrordamage");
 382                 BADCVAR("g_nexball_goallimit");
 383                 BADCVAR("g_powerups");
 384                 BADCVAR("g_start_delay");
 385                 BADCVAR("g_warmup");
 386                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 387                 BADCVAR("hostname");
 388                 BADCVAR("log_file");
 389                 BADCVAR("maxplayers");
 390                 BADCVAR("minplayers");
 391                 BADCVAR("net_address");
 392                 BADCVAR("port");
 393                 BADCVAR("rcon_password");
 394                 BADCVAR("rcon_restricted_commands");
 395                 BADCVAR("rcon_restricted_password");
 396                 BADCVAR("skill");
 397                 BADCVAR("sv_adminnick");
 398                 BADCVAR("sv_autoscreenshot");
 399                 BADCVAR("sv_autotaunt");
 400                 BADCVAR("sv_curl_defaulturl");
 401                 BADCVAR("sv_defaultcharacter");
 402                 BADCVAR("sv_defaultplayercolors");
 403                 BADCVAR("sv_defaultplayermodel");
 404                 BADCVAR("sv_defaultplayerskin");
 405                 BADCVAR("sv_maxidle");
 406                 BADCVAR("sv_maxrate");
 407                 BADCVAR("sv_motd");
 408                 BADCVAR("sv_public");
 409                 BADCVAR("sv_ready_restart");
 410                 BADCVAR("sv_status_privacy");
 411                 BADCVAR("sv_taunt");
 412                 BADCVAR("sv_vote_call");
 413                 BADCVAR("sv_vote_commands");
 414                 BADCVAR("sv_vote_majority_factor");
 415                 BADCVAR("sv_vote_master");
 416                 BADCVAR("sv_vote_master_commands");
 417                 BADCVAR("sv_vote_master_password");
 418                 BADCVAR("sv_vote_simple_majority_factor");
 419                 BADCVAR("teamplay_mode");
 420                 BADCVAR("timelimit_override");
 421                 BADCVAR("g_spawnshieldtime");
 422                 BADPREFIX("g_warmup_");
 423                 BADPREFIX("sv_ready_restart_");
 424
 425                 // mutators that announce themselves properly to the server browser
 426                 BADCVAR("g_minstagib");
 427                 BADCVAR("g_new_toys");
 428                 BADCVAR("g_nix");
 429                 BADCVAR("g_grappling_hook");
 430                 BADCVAR("g_jetpack");
 431
 432 #undef BADPREFIX
 433 #undef BADCVAR
 434
 435                 if(pureadding)
 436                 {
 437                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 438                         if(strlen(cvar_purechanges) > 16384)
 439                         {
 440                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 441                                 pureadding = 0;
 442                         }
 443                 }
 444                 ++cvar_purechanges_count;
 445                 // WARNING: this variable is used for the server list
 446                 // NEVER dare to skip this code!
 447                 // Hacks to intentionally appearing as "pure server" even though you DO have
 448                 // modified settings may be punished by removal from the server list.
 449                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 450                 // though.
 451         }
 452         buf_del(h);
 453         if(cvar_changes == "")
 454                 cvar_changes = "// this server runs at default server settings\n";
 455         else
 456                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 457         cvar_changes = strzone(cvar_changes);
 458         if(cvar_purechanges == "")
 459                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 460         else
 461                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 462         cvar_purechanges = strzone(cvar_purechanges);
 463 }
 464
 465 void detect_maptype()
 466 {
 467 #if 0
 468         vector o, v;
 469         float i;
 470
 471         for(;;)
 472         {
 473                 o = world.mins;
 474                 o_x += random() * (world.maxs_x - world.mins_x);
 475                 o_y += random() * (world.maxs_y - world.mins_y);
 476                 o_z += random() * (world.maxs_z - world.mins_z);
 477
 478                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 479                 if(trace_fraction == 1)
 480                         continue;
 481
 482                 v = trace_endpos;
 483
 484                 for(i = 0; i < 64; i += 4)
 485                 {
 486                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 487         if(trace_fraction == 1)
 488                 continue;
 489                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 490                 }
 491
 492                 break;
 493         }
 494 #endif
 495 }
 496
 497 entity randomseed;
 498 float RandomSeed_Send(entity to, float sf)
 499 {
 500         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 501         WriteShort(MSG_ENTITY, self.cnt);
 502         return TRUE;
 503 }
 504 void RandomSeed_Think()
 505 {
 506         self.cnt = bound(0, floor(random() * 65536), 65535);
 507         self.nextthink = time + 5;
 508
 509         self.SendFlags |= 1;
 510 }
 511 void RandomSeed_Spawn()
 512 {
 513         randomseed = spawn();
 514         randomseed.think = RandomSeed_Think;
 515         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 516
 517         entity oldself;
 518         oldself = self;
 519         self = randomseed;
 520         self.think(); // sets random seed and nextthink
 521         self = oldself;
 522 }
 523
 524 void spawnfunc___init_dedicated_server(void)
 525 {
 526         // handler for _init/_init map (only for dedicated server initialization)
 527
 528         world_initialized = -1; // don't complain
 529         cvar = cvar_normal;
 530         cvar_string = cvar_string_normal;
 531         cvar_set = cvar_set_normal;
 532
 533         remove = remove_unsafely;
 534
 535         entity e;
 536         e = spawn();
 537         e.think = GotoFirstMap;
 538         e.nextthink = time; // this is usually 1 at this point
 539
 540         e = spawn();
 541         e.classname = "info_player_deathmatch"; // safeguard against player joining
 542
 543         self.classname = "worldspawn"; // safeguard against various stuff ;)
 544
 545         // needs to be done so early because of the constants they create
 546         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 547         CALL_ACCUMULATED_FUNCTION(RegisterVehicles);
 548         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 549         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 550         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 551
 552         MapInfo_Enumerate();
 553         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 554 }
 555
 556 void Map_MarkAsRecent(string m);
 557 float world_already_spawned;
 558 void Nagger_Init();
 559 void ClientInit_Spawn();
 560 void WeaponStats_Init();
 561 void WeaponStats_Shutdown();
 562 void spawnfunc_worldspawn (void)
 563 {
 564         float fd, l, i, j, n;
 565         string s;
 566
 567         cvar = cvar_normal;
 568         cvar_string = cvar_string_normal;
 569         cvar_set = cvar_set_normal;
 570
 571         if(world_already_spawned)
 572                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 573         world_already_spawned = TRUE;
 574
 575         remove = remove_safely; // during spawning, watch what you remove!
 576
 577         check_unacceptable_compiler_bugs();
 578
 579         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 580
 581         compressShortVector_init();
 582
 583         entity head;
 584         head = nextent(world);
 585         maxclients = 0;
 586         while(head)
 587         {
 588                 ++maxclients;
 589                 head = nextent(head);
 590         }
 591
 592         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 593
 594         // needs to be done so early because of the constants they create
 595         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 596         CALL_ACCUMULATED_FUNCTION(RegisterVehicles);
 597         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 598         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 599         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 600
 601         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 602
 603         TemporaryDB = db_create();
 604
 605         // 0 normal
 606         lightstyle(0, "m");
 607
 608         // 1 FLICKER (first variety)
 609         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 610
 611         // 2 SLOW STRONG PULSE
 612         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 613
 614         // 3 CANDLE (first variety)
 615         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 616
 617         // 4 FAST STROBE
 618         lightstyle(4, "mamamamamama");
 619
 620         // 5 GENTLE PULSE 1
 621         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 622
 623         // 6 FLICKER (second variety)
 624         lightstyle(6, "nmonqnmomnmomomno");
 625
 626         // 7 CANDLE (second variety)
 627         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 628
 629         // 8 CANDLE (third variety)
 630         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 631
 632         // 9 SLOW STROBE (fourth variety)
 633         lightstyle(9, "aaaaaaaazzzzzzzz");
 634
 635         // 10 FLUORESCENT FLICKER
 636         lightstyle(10, "mmamammmmammamamaaamammma");
 637
 638         // 11 SLOW PULSE NOT FADE TO BLACK
 639         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 640
 641         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 642
 643         // 63 testing
 644         lightstyle(63, "a");
 645
 646         if(autocvar_g_campaign)
 647                 CampaignPreInit();
 648
 649         Map_MarkAsRecent(mapname);
 650
 651         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 652
 653         precache_model ("null"); // we need this one before InitGameplayMode
 654         InitGameplayMode();
 655         readlevelcvars();
 656         GrappleHookInit();
 657         ElectroInit();
 658         LaserInit();
 659
 660         player_count = 0;
 661         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 662         if(bot_waypoints_for_items == 1)
 663                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 664                         bot_waypoints_for_items = 0;
 665
 666         precache();
 667
 668         WaypointSprite_Init();
 669
 670         GameLogInit(); // prepare everything
 671         // NOTE for matchid:
 672         // changing the logic generating it is okay. But:
 673         // it HAS to stay <= 64 chars
 674         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 675         if(autocvar_sv_eventlog)
 676         {
 677                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 678                 matchid = strzone(s);
 679
 680                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 681                 s = ":gameinfo:mutators:LIST";
 682
 683                 ret_string = s;
 684                 MUTATOR_CALLHOOK(BuildMutatorsString);
 685                 s = ret_string;
 686
 687                 // simple, probably not good in the mutator system
 688                 if(autocvar_g_grappling_hook)
 689                         s = strcat(s, ":grappling_hook");
 690
 691                 // initialiation stuff, not good in the mutator system
 692                 if(!autocvar_g_use_ammunition)
 693                         s = strcat(s, ":no_use_ammunition");
 694
 695                 // initialiation stuff, not good in the mutator system
 696                 if(autocvar_g_pickup_items == 0)
 697                         s = strcat(s, ":no_pickup_items");
 698                 if(autocvar_g_pickup_items > 0)
 699                         s = strcat(s, ":pickup_items");
 700
 701                 // initialiation stuff, not good in the mutator system
 702                 if(autocvar_g_weaponarena != "0")
 703                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 704
 705                 // TODO to mutator system
 706                 if(autocvar_g_norecoil)
 707                         s = strcat(s, ":norecoil");
 708
 709                 // TODO to mutator system
 710                 if(autocvar_g_powerups == 0)
 711                         s = strcat(s, ":no_powerups");
 712                 if(autocvar_g_powerups > 0)
 713                         s = strcat(s, ":powerups");
 714
 715                 GameLogEcho(s);
 716                 GameLogEcho(":gameinfo:end");
 717         }
 718         else
 719                 matchid = strzone(ftos(random()));
 720
 721         cvar_set("nextmap", "");
 722
 723         SetDefaultAlpha();
 724
 725         if(autocvar_g_campaign)
 726                 CampaignPostInit();
 727
 728         fteqcc_testbugs();
 729
 730         Ban_LoadBans();
 731
 732         MapInfo_Enumerate();
 733         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 734
 735         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 736         {
 737                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 738                 if(fd != -1)
 739                 {
 740                         while((s = fgets(fd)))
 741                         {
 742                                 l = tokenize_console(s);
 743                                 if(l < 2)
 744                                         continue;
 745                                 if(argv(0) == "cd")
 746                                 {
 747                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 748                                         print("  cdtrack ", argv(2), "\n");
 749                                 }
 750                                 else if(argv(0) == "fog")
 751                                 {
 752                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 753                                         print("  \"fog\" \"", s, "\"\n");
 754                                 }
 755                                 else if(argv(0) == "set")
 756                                 {
 757                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 758                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 759                                 }
 760                                 else if(argv(0) != "//")
 761                                 {
 762                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 763                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 764                                 }
 765                         }
 766                         fclose(fd);
 767                 }
 768         }
 769
 770         WeaponStats_Init();
 771
 772         WepSet_AddStat();
 773         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 774         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 775         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 776         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 777         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 778         Nagger_Init();
 779
 780         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 781         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 782         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 783         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 784         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 785         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 786         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 787         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 788         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 789         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 790         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 791         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 792         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 793
 794         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 795         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 796
 797         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 798
 799         // g_movementspeed hack
 800         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 801         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 802         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 803         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 804
 805         // secrets
 806         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 807         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 808
 809         // misc
 810         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 811
 812         next_pingtime = time + 5;
 813
 814         detect_maptype();
 815
 816         // set up information replies for clients and server to use
 817         maplist_reply = strzone(getmaplist());
 818         lsmaps_reply = strzone(getlsmaps());
 819         for(i = 0; i < 10; ++i)
 820         {
 821                 s = getrecords(i);
 822                 if (s)
 823                         records_reply[i] = strzone(s);
 824         }
 825         ladder_reply = strzone(getladder());
 826         rankings_reply = strzone(getrankings());
 827
 828         // begin other init
 829         ClientInit_Spawn();
 830         RandomSeed_Spawn();
 831         PingPLReport_Spawn();
 832
 833         CheatInit();
 834
 835         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 836
 837         // fill sv_curl_serverpackages from .serverpackage files
 838         if(autocvar_sv_curl_serverpackages_auto)
 839         {
 840                 s = "";
 841                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 842                 for(i = 0; i < n; ++i)
 843                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 844                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 845                                 s = strcat(s, " ", argv(i));
 846                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 847                 if(fd >= 0)
 848                 {
 849                         j = search_getsize(fd);
 850                         for(i = 0; i < j; ++i)
 851                                 s = strcat(s, " ", search_getfilename(fd, i));
 852                         search_end(fd);
 853                 }
 854                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 855                 if(fd >= 0)
 856                 {
 857                         j = search_getsize(fd);
 858                         for(i = 0; i < j; ++i)
 859                                 s = strcat(s, " ", search_getfilename(fd, i));
 860                         search_end(fd);
 861                 }
 862                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 863         }
 864
 865         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 866         modname = "Xonotic";
 867         // physics/balance/config changes that count as mod
 868         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 869                 modname = cvar_string("g_mod_physics");
 870         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 871                 modname = cvar_string("g_mod_balance");
 872         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 873                 modname = cvar_string("g_mod_config");
 874         // extra mutators that deserve to count as mod
 875         MUTATOR_CALLHOOK(SetModname);
 876
 877         // save it for later
 878         modname = strzone(modname);
 879
 880         WinningConditionHelper(); // set worldstatus
 881
 882         world_initialized = 1;
 883 }
 884
 885 void spawnfunc_light (void)
 886 {
 887         //makestatic (self); // Who the f___ did that?
 888         remove(self);
 889 }
 890
 891 string GetGametype()
 892 {
 893         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 894 }
 895
 896 string getmapname_stored;
 897 string GetMapname()
 898 {
 899         return mapname;
 900 }
 901
 902 float Map_Count, Map_Current;
 903 string Map_Current_Name;
 904
 905 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 906 float GetMaplistPosition()
 907 {
 908         float pos, idx;
 909         string map;
 910
 911         map = GetMapname();
 912         idx = autocvar_g_maplist_index;
 913
 914         if(idx >= 0)
 915                 if(idx < Map_Count)
 916                         if(map == argv(idx))
 917                                 return idx;
 918
 919         for(pos = 0; pos < Map_Count; ++pos)
 920                 if(map == argv(pos))
 921                         return pos;
 922
 923         // resume normal maplist rotation if current map is not in g_maplist
 924         return idx;
 925 }
 926
 927 float MapHasRightSize(string map)
 928 {
 929         float fh;
 930         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 931         if(autocvar_g_maplist_check_waypoints)
 932         {
 933                 dprint("checkwp "); dprint(map);
 934                 if(!fexists(strcat("maps/", map, ".waypoints")))
 935                 {
 936                         dprint(": no waypoints\n");
 937                         return FALSE;
 938                 }
 939                 dprint(": has waypoints\n");
 940         }
 941
 942         // open map size restriction file
 943         dprint("opensize "); dprint(map);
 944         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 945         if(fh >= 0)
 946         {
 947                 float mapmin, mapmax;
 948                 dprint(": ok, ");
 949                 mapmin = stof(fgets(fh));
 950                 mapmax = stof(fgets(fh));
 951                 fclose(fh);
 952                 if(player_count < mapmin)
 953                 {
 954                         dprint("not enough\n");
 955                         return FALSE;
 956                 }
 957                 if(player_count > mapmax)
 958                 {
 959                         dprint("too many\n");
 960                         return FALSE;
 961                 }
 962                 dprint("right size\n");
 963                 return TRUE;
 964         }
 965         dprint(": not found\n");
 966         return TRUE;
 967 }
 968
 969 string Map_Filename(float position)
 970 {
 971         return strcat("maps/", argv(position), ".bsp");
 972 }
 973
 974 string strwords(string s, float w)
 975 {
 976         float endpos;
 977         for(endpos = 0; w && endpos >= 0; --w)
 978                 endpos = strstrofs(s, " ", endpos + 1);
 979         if(endpos < 0)
 980                 return s;
 981         else
 982                 return substring(s, 0, endpos);
 983 }
 984
 985 float strhasword(string s, string w)
 986 {
 987         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 988 }
 989
 990 void Map_MarkAsRecent(string m)
 991 {
 992         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 993 }
 994
 995 float Map_IsRecent(string m)
 996 {
 997         return strhasword(autocvar_g_maplist_mostrecent, m);
 998 }
 999
1000 float Map_Check(float position, float pass)
1001 {
1002         string filename;
1003         string map_next;
1004         map_next = argv(position);
1005         if(pass <= 1)
1006         {
1007                 if(Map_IsRecent(map_next))
1008                         return 0;
1009         }
1010         filename = Map_Filename(position);
1011         if(MapInfo_CheckMap(map_next))
1012         {
1013                 if(pass == 2)
1014                         return 1;
1015                 if(MapHasRightSize(map_next))
1016                         return 1;
1017                 return 0;
1018         }
1019         else
1020                 dprint( "Couldn't select '", filename, "'..\n" );
1021
1022         return 0;
1023 }
1024
1025 void Map_Goto_SetStr(string nextmapname)
1026 {
1027         if(getmapname_stored != "")
1028                 strunzone(getmapname_stored);
1029         if(nextmapname == "")
1030                 getmapname_stored = "";
1031         else
1032                 getmapname_stored = strzone(nextmapname);
1033 }
1034
1035 void Map_Goto_SetFloat(float position)
1036 {
1037         cvar_set("g_maplist_index", ftos(position));
1038         Map_Goto_SetStr(argv(position));
1039 }
1040
1041 void Map_Goto(float reinit)
1042 {
1043         MapInfo_LoadMap(getmapname_stored, reinit);
1044 }
1045
1046 // return codes of map selectors:
1047 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1048 //   -2 = permanent failure
1049 float() MaplistMethod_Iterate = // usual method
1050 {
1051         float pass, i;
1052
1053         dprint("Trying MaplistMethod_Iterate\n");
1054
1055         for(pass = 1; pass <= 2; ++pass)
1056         {
1057                 for(i = 1; i < Map_Count; ++i)
1058                 {
1059                         float mapindex;
1060                         mapindex = mod(i + Map_Current, Map_Count);
1061                         if(Map_Check(mapindex, pass))
1062                                 return mapindex;
1063                 }
1064         }
1065         return -1;
1066 }
1067
1068 float() MaplistMethod_Repeat = // fallback method
1069 {
1070         dprint("Trying MaplistMethod_Repeat\n");
1071
1072         if(Map_Check(Map_Current, 2))
1073                 return Map_Current;
1074         return -2;
1075 }
1076
1077 float() MaplistMethod_Random = // random map selection
1078 {
1079         float i, imax;
1080
1081         dprint("Trying MaplistMethod_Random\n");
1082
1083         imax = 42;
1084
1085         for(i = 0; i <= imax; ++i)
1086         {
1087                 float mapindex;
1088                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1089                 if(Map_Check(mapindex, 1))
1090                         return mapindex;
1091         }
1092         return -1;
1093 }
1094
1095 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1096 // the exponent sets a bias on the map selection:
1097 // the higher the exponent, the less likely "shortly repeated" same maps are
1098 {
1099         float i, j, imax, insertpos;
1100
1101         dprint("Trying MaplistMethod_Shuffle\n");
1102
1103         imax = 42;
1104
1105         for(i = 0; i <= imax; ++i)
1106         {
1107                 string newlist;
1108
1109                 // now reinsert this at another position
1110                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1111                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1112                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1113                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1114
1115                 // insert the current map there
1116                 newlist = "";
1117                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1118                         newlist = strcat(newlist, " ", argv(j));
1119                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1120                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1121                         newlist = strcat(newlist, " ", argv(j));
1122                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1123                 cvar_set("g_maplist", newlist);
1124                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1125
1126                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1127                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1128                 if(Map_Check(Map_Current, 1))
1129                         return Map_Current;
1130         }
1131         return -1;
1132 }
1133
1134 void Maplist_Init()
1135 {
1136         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1137         float i;
1138         for (i = 0; i < Map_Count; ++i)
1139                 if (Map_Check(i, 2))
1140                         break;
1141         if (i == Map_Count)
1142         {
1143                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1144                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1145                 if(autocvar_g_maplist_shuffle)
1146                         ShuffleMaplist();
1147                 localcmd("\nmenu_cmd sync\n");
1148                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1149         }
1150         if(Map_Count == 0)
1151                 error("empty maplist, cannot select a new map");
1152         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1153
1154         if(Map_Current_Name)
1155                 strunzone(Map_Current_Name);
1156         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1157         // this may or may not be correct, but who cares, in the worst case a map
1158         // isn't chosen in the first pass that should have been
1159 }
1160
1161 string GetNextMap()
1162 {
1163         float nextMap;
1164
1165         Maplist_Init();
1166         nextMap = -1;
1167
1168         if(nextMap == -1)
1169                 if(autocvar_g_maplist_shuffle > 0)
1170                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1171
1172         if(nextMap == -1)
1173                 if(autocvar_g_maplist_selectrandom)
1174                         nextMap = MaplistMethod_Random();
1175
1176         if(nextMap == -1)
1177                 nextMap = MaplistMethod_Iterate();
1178
1179         if(nextMap == -1)
1180                 nextMap = MaplistMethod_Repeat();
1181
1182         if(nextMap >= 0)
1183         {
1184                 Map_Goto_SetFloat(nextMap);
1185                 return getmapname_stored;
1186         }
1187
1188         return "";
1189 }
1190
1191 float DoNextMapOverride(float reinit)
1192 {
1193         if(autocvar_g_campaign)
1194         {
1195                 CampaignPostIntermission();
1196                 alreadychangedlevel = TRUE;
1197                 return TRUE;
1198         }
1199         if(autocvar_quit_when_empty)
1200         {
1201                 if(player_count <= currentbots)
1202                 {
1203                         localcmd("quit\n");
1204                         alreadychangedlevel = TRUE;
1205                         return TRUE;
1206                 }
1207         }
1208         if(autocvar_quit_and_redirect != "")
1209         {
1210                 redirection_target = strzone(autocvar_quit_and_redirect);
1211                 alreadychangedlevel = TRUE;
1212                 return TRUE;
1213         }
1214         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1215         {
1216                 localcmd("restart\n");
1217                 alreadychangedlevel = TRUE;
1218                 return TRUE;
1219         }
1220         if(autocvar_nextmap != "")
1221                 if(MapInfo_CheckMap(autocvar_nextmap))
1222                 {
1223                         Map_Goto_SetStr(autocvar_nextmap);
1224                         Map_Goto(reinit);
1225                         alreadychangedlevel = TRUE;
1226                         return TRUE;
1227                 }
1228         if(!reinit && autocvar_lastlevel)
1229         {
1230                 cvar_settemp_restore();
1231                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1232                 alreadychangedlevel = TRUE;
1233                 return TRUE;
1234         }
1235         return FALSE;
1236 }
1237
1238 void GotoNextMap(float reinit)
1239 {
1240         //string nextmap;
1241         //float n, nummaps;
1242         //string s;
1243         if (alreadychangedlevel)
1244                 return;
1245         alreadychangedlevel = TRUE;
1246
1247         string nextMap;
1248
1249         nextMap = GetNextMap();
1250         if(nextMap == "")
1251                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1252         Map_Goto(reinit);
1253 }
1254
1255
1256 /*
1257 ============
1258 IntermissionThink
1259
1260 When the player presses attack or jump, change to the next level
1261 ============
1262 */
1263 .float autoscreenshot;
1264 void() MapVote_Start;
1265 void() MapVote_Think;
1266 float mapvote_initialized;
1267 void IntermissionThink()
1268 {
1269         FixIntermissionClient(self);
1270
1271         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1272         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1273
1274         if( (server_screenshot || client_screenshot)
1275                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1276         {
1277                 self.autoscreenshot = -1;
1278                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1279                 return;
1280         }
1281
1282         if (time < intermission_exittime)
1283                 return;
1284
1285         if(!mapvote_initialized)
1286                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1287                         return;
1288
1289         MapVote_Start();
1290 }
1291
1292 /*
1293 ============
1294 FindIntermission
1295
1296 Returns the entity to view from
1297 ============
1298 */
1299 /*
1300 entity FindIntermission()
1301 {
1302         local   entity spot;
1303         local   float cyc;
1304
1305 // look for info_intermission first
1306         spot = find (world, classname, "info_intermission");
1307         if (spot)
1308         {       // pick a random one
1309                 cyc = random() * 4;
1310                 while (cyc > 1)
1311                 {
1312                         spot = find (spot, classname, "info_intermission");
1313                         if (!spot)
1314                                 spot = find (spot, classname, "info_intermission");
1315                         cyc = cyc - 1;
1316                 }
1317                 return spot;
1318         }
1319
1320 // then look for the start position
1321         spot = find (world, classname, "info_player_start");
1322         if (spot)
1323                 return spot;
1324
1325 // testinfo_player_start is only found in regioned levels
1326         spot = find (world, classname, "testplayerstart");
1327         if (spot)
1328                 return spot;
1329
1330 // then look for the start position
1331         spot = find (world, classname, "info_player_deathmatch");
1332         if (spot)
1333                 return spot;
1334
1335         //objerror ("FindIntermission: no spot");
1336         return world;
1337 }
1338 */
1339
1340 /*
1341 ===============================================================================
1342
1343 RULES
1344
1345 ===============================================================================
1346 */
1347
1348 void DumpStats(float final)
1349 {
1350         float file;
1351         string s;
1352         float to_console;
1353         float to_eventlog;
1354         float to_file;
1355         float i;
1356
1357         to_console = autocvar_sv_logscores_console;
1358         to_eventlog = autocvar_sv_eventlog;
1359         to_file = autocvar_sv_logscores_file;
1360
1361         if(!final)
1362         {
1363                 to_console = TRUE; // always print printstats replies
1364                 to_eventlog = FALSE; // but never print them to the event log
1365         }
1366
1367         if(to_eventlog)
1368                 if(autocvar_sv_eventlog_console)
1369                         to_console = FALSE; // otherwise we get the output twice
1370
1371         if(final)
1372                 s = ":scores:";
1373         else
1374                 s = ":status:";
1375         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1376
1377         if(to_console)
1378                 print(s, "\n");
1379         if(to_eventlog)
1380                 GameLogEcho(s);
1381
1382         file = -1;
1383         if(to_file)
1384         {
1385                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1386                 if(file == -1)
1387                         to_file = FALSE;
1388                 else
1389                         fputs(file, strcat(s, "\n"));
1390         }
1391
1392         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1393         if(to_console)
1394                 print(s, "\n");
1395         if(to_eventlog)
1396                 GameLogEcho(s);
1397         if(to_file)
1398                 fputs(file, strcat(s, "\n"));
1399
1400         FOR_EACH_CLIENT(other)
1401         {
1402                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1403                 {
1404                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1405                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1406                         if(IS_PLAYER(other) || g_arena || other.caplayer == 1 || g_lms)
1407                                 s = strcat(s, ftos(other.team), ":");
1408                         else
1409                                 s = strcat(s, "spectator:");
1410
1411                         if(to_console)
1412                                 print(s, other.netname, "\n");
1413                         if(to_eventlog)
1414                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1415                         if(to_file)
1416                                 fputs(file, strcat(s, other.netname, "\n"));
1417                 }
1418         }
1419
1420         if(teamplay)
1421         {
1422                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1423                 if(to_console)
1424                         print(s, "\n");
1425                 if(to_eventlog)
1426                         GameLogEcho(s);
1427                 if(to_file)
1428                         fputs(file, strcat(s, "\n"));
1429
1430                 for(i = 1; i < 16; ++i)
1431                 {
1432                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1433                         s = strcat(s, ":", ftos(i));
1434                         if(to_console)
1435                                 print(s, "\n");
1436                         if(to_eventlog)
1437                                 GameLogEcho(s);
1438                         if(to_file)
1439                                 fputs(file, strcat(s, "\n"));
1440                 }
1441         }
1442
1443         if(to_console)
1444                 print(":end\n");
1445         if(to_eventlog)
1446                 GameLogEcho(":end");
1447         if(to_file)
1448         {
1449                 fputs(file, ":end\n");
1450                 fclose(file);
1451         }
1452 }
1453
1454 void FixIntermissionClient(entity e)
1455 {
1456         string s;
1457         if(!e.autoscreenshot) // initial call
1458         {
1459                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1460                 e.health = -2342;
1461                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1462                 e.solid = SOLID_NOT;
1463                 e.movetype = MOVETYPE_NONE;
1464                 e.takedamage = DAMAGE_NO;
1465                 if(e.weaponentity)
1466                 {
1467                         e.weaponentity.effects = EF_NODRAW;
1468                         if (e.weaponentity.weaponentity)
1469                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1470                 }
1471                 if(IS_REAL_CLIENT(e))
1472                 {
1473                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1474                         s = autocvar_sv_intermission_cdtrack;
1475                         if(s != "")
1476                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1477                         msg_entity = e;
1478                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1479                 }
1480         }
1481 }
1482
1483 /*
1484 go to the next level for deathmatch
1485 only called if a time or frag limit has expired
1486 */
1487 void NextLevel()
1488 {
1489         gameover = TRUE;
1490
1491         intermission_running = 1;
1492
1493 // enforce a wait time before allowing changelevel
1494         if(player_count > 0)
1495                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1496         else
1497                 intermission_exittime = -1;
1498
1499         /*
1500         WriteByte (MSG_ALL, SVC_CDTRACK);
1501         WriteByte (MSG_ALL, 3);
1502         WriteByte (MSG_ALL, 3);
1503         // done in FixIntermission
1504         */
1505
1506         //pos = FindIntermission ();
1507
1508         VoteReset();
1509
1510         DumpStats(TRUE);
1511
1512         // send statistics
1513         entity e;
1514         PlayerStats_EndMatch(1);
1515         FOR_EACH_CLIENT(e)
1516                 PlayerStats_AddGlobalInfo(e);
1517         PlayerStats_Shutdown();
1518         WeaponStats_Shutdown();
1519
1520         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1521
1522         if(autocvar_sv_eventlog)
1523                 GameLogEcho(":gameover");
1524
1525         GameLogClose();
1526
1527         FOR_EACH_PLAYER(other) {
1528                 FixIntermissionClient(other);
1529                 if(other.winning)
1530                         bprint(other.netname, " ^7wins.\n");
1531         }
1532
1533         if(autocvar_g_campaign)
1534                 CampaignPreIntermission();
1535
1536         MUTATOR_CALLHOOK(MatchEnd);
1537
1538         localcmd("\nsv_hook_gameend\n");
1539 }
1540
1541 /*
1542 ============
1543 CheckRules_Player
1544
1545 Exit deathmatch games upon conditions
1546 ============
1547 */
1548 void CheckRules_Player()
1549 {
1550         if (gameover)   // someone else quit the game already
1551                 return;
1552
1553         if(self.deadflag == DEAD_NO)
1554                 self.play_time += frametime;
1555
1556         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1557         //   (div0: and that in CheckRules_World please)
1558 }
1559
1560 float checkrules_equality;
1561 float checkrules_suddendeathwarning;
1562 float checkrules_suddendeathend;
1563 float checkrules_overtimesadded; //how many overtimes have been already added
1564
1565 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1566 const float WINNING_YES = 1; // winner found
1567 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1568 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1569
1570 float InitiateSuddenDeath()
1571 {
1572         // Check first whether normal overtimes could be added before initiating suddendeath mode
1573         // - for this timelimit_overtime needs to be >0 of course
1574         // - also check the winning condition calculated in the previous frame and only add normal overtime
1575         //   again, if at the point at which timelimit would be extended again, still no winner was found
1576         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1577         {
1578                 return 1; // need to call InitiateOvertime later
1579         }
1580         else
1581         {
1582                 if(!checkrules_suddendeathend)
1583                 {
1584                         if(autocvar_g_campaign)
1585                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1586                         else
1587                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1588                         if(g_race && !g_race_qualifying)
1589                                 race_StartCompleting();
1590                 }
1591                 return 0;
1592         }
1593 }
1594
1595 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1596 {
1597         ++checkrules_overtimesadded;
1598         //add one more overtime by simply extending the timelimit
1599         float tl;
1600         tl = autocvar_timelimit;
1601         tl += autocvar_timelimit_overtime;
1602         cvar_set("timelimit", ftos(tl));
1603
1604         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1605 }
1606
1607 float GetWinningCode(float fraglimitreached, float equality)
1608 {
1609         if(autocvar_g_campaign == 1)
1610                 if(fraglimitreached)
1611                         return WINNING_YES;
1612                 else
1613                         return WINNING_NO;
1614
1615         else
1616                 if(equality)
1617                         if(fraglimitreached)
1618                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1619                         else
1620                                 return WINNING_NEVER;
1621                 else
1622                         if(fraglimitreached)
1623                                 return WINNING_YES;
1624                         else
1625                                 return WINNING_NO;
1626 }
1627
1628 // set the .winning flag for exactly those players with a given field value
1629 void SetWinners(.float field, float value)
1630 {
1631         entity head;
1632         FOR_EACH_PLAYER(head)
1633                 head.winning = (head.field == value);
1634 }
1635
1636 // set the .winning flag for those players with a given field value
1637 void AddWinners(.float field, float value)
1638 {
1639         entity head;
1640         FOR_EACH_PLAYER(head)
1641                 if(head.field == value)
1642                         head.winning = 1;
1643 }
1644
1645 // clear the .winning flags
1646 void ClearWinners(void)
1647 {
1648         entity head;
1649         FOR_EACH_PLAYER(head)
1650                 head.winning = 0;
1651 }
1652
1653 // Onslaught winning condition:
1654 // game terminates if only one team has a working generator (or none)
1655 float WinningCondition_Onslaught()
1656 {
1657         entity head;
1658         float t1, t2, t3, t4;
1659
1660         WinningConditionHelper(); // set worldstatus
1661
1662         if(warmup_stage)
1663                 return WINNING_NO;
1664
1665         // first check if the game has ended
1666         t1 = t2 = t3 = t4 = 0;
1667         head = find(world, classname, "onslaught_generator");
1668         while (head)
1669         {
1670                 if (head.health > 0)
1671                 {
1672                         if (head.team == NUM_TEAM_1) t1 = 1;
1673                         if (head.team == NUM_TEAM_2) t2 = 1;
1674                         if (head.team == NUM_TEAM_3) t3 = 1;
1675                         if (head.team == NUM_TEAM_4) t4 = 1;
1676                 }
1677                 head = find(head, classname, "onslaught_generator");
1678         }
1679         if (t1 + t2 + t3 + t4 < 2)
1680         {
1681                 // game over, only one team remains (or none)
1682                 ClearWinners();
1683                 if (t1) SetWinners(team, NUM_TEAM_1);
1684                 if (t2) SetWinners(team, NUM_TEAM_2);
1685                 if (t3) SetWinners(team, NUM_TEAM_3);
1686                 if (t4) SetWinners(team, NUM_TEAM_4);
1687                 dprint("Have a winner, ending game.\n");
1688                 return WINNING_YES;
1689         }
1690
1691         // Two or more teams remain
1692         return WINNING_NO;
1693 }
1694
1695 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1696 // they win. Otherwise the defending team wins once the timelimit passes.
1697 void assault_new_round();
1698 float WinningCondition_Assault()
1699 {
1700         float status;
1701
1702         WinningConditionHelper(); // set worldstatus
1703
1704         status = WINNING_NO;
1705         // as the timelimit has not yet passed just assume the defending team will win
1706         if(assault_attacker_team == NUM_TEAM_1)
1707         {
1708                 SetWinners(team, NUM_TEAM_2);
1709         }
1710         else
1711         {
1712                 SetWinners(team, NUM_TEAM_1);
1713         }
1714
1715         entity ent;
1716         ent = find(world, classname, "target_assault_roundend");
1717         if(ent)
1718         {
1719                 if(ent.winning) // round end has been triggered by attacking team
1720                 {
1721                         bprint("ASSAULT: round completed...\n");
1722                         SetWinners(team, assault_attacker_team);
1723
1724                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1725
1726                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1727                         {
1728                                 status = WINNING_YES;
1729                         }
1730                         else
1731                         {
1732                                 entity oldself;
1733                                 oldself = self;
1734                                 self = ent;
1735                                 assault_new_round();
1736                                 self = oldself;
1737                         }
1738                 }
1739         }
1740
1741         return status;
1742 }
1743
1744 // LMS winning condition: game terminates if and only if there's at most one
1745 // one player who's living lives. Top two scores being equal cancels the time
1746 // limit.
1747 float WinningCondition_LMS()
1748 {
1749         entity head, head2;
1750         float have_player;
1751         float have_players;
1752         float l;
1753
1754         have_player = FALSE;
1755         have_players = FALSE;
1756         l = LMS_NewPlayerLives();
1757
1758         head = find(world, classname, "player");
1759         if(head)
1760                 have_player = TRUE;
1761         head2 = find(head, classname, "player");
1762         if(head2)
1763                 have_players = TRUE;
1764
1765         if(have_player)
1766         {
1767                 // we have at least one player
1768                 if(have_players)
1769                 {
1770                         // two or more active players - continue with the game
1771                 }
1772                 else
1773                 {
1774                         // exactly one player?
1775
1776                         ClearWinners();
1777                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1778
1779                         if(l)
1780                         {
1781                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1782                                 return WINNING_NO;
1783                         }
1784                         else
1785                         {
1786                                 // a winner!
1787                                 // and assign him his first place
1788                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1789                                 return WINNING_YES;
1790                         }
1791                 }
1792         }
1793         else
1794         {
1795                 // nobody is playing at all...
1796                 if(l)
1797                 {
1798                         // wait for players...
1799                 }
1800                 else
1801                 {
1802                         // SNAFU (maybe a draw game?)
1803                         ClearWinners();
1804                         dprint("No players, ending game.\n");
1805                         return WINNING_YES;
1806                 }
1807         }
1808
1809         // When we get here, we have at least two players who are actually LIVING,
1810         // now check if the top two players have equal score.
1811         WinningConditionHelper();
1812
1813         ClearWinners();
1814         if(WinningConditionHelper_winner)
1815                 WinningConditionHelper_winner.winning = TRUE;
1816         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1817                 return WINNING_NEVER;
1818
1819         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1820         return WINNING_NO;
1821 }
1822
1823 void ShuffleMaplist()
1824 {
1825         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1826 }
1827
1828 float leaderfrags;
1829 float WinningCondition_Scores(float limit, float leadlimit)
1830 {
1831         float limitreached;
1832
1833         // TODO make everything use THIS winning condition (except LMS)
1834         WinningConditionHelper();
1835
1836         if(teamplay)
1837         {
1838                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1839                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1840                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1841                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1842         }
1843
1844         ClearWinners();
1845         if(WinningConditionHelper_winner)
1846                 WinningConditionHelper_winner.winning = 1;
1847         if(WinningConditionHelper_winnerteam >= 0)
1848                 SetWinners(team, WinningConditionHelper_winnerteam);
1849
1850         if(WinningConditionHelper_lowerisbetter)
1851         {
1852                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1853                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1854                 limit = -limit;
1855         }
1856
1857         if(WinningConditionHelper_zeroisworst)
1858                 leadlimit = 0; // not supported in this mode
1859
1860         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1861         // these modes always score in increments of 1, thus this makes sense
1862         {
1863                 if(leaderfrags != WinningConditionHelper_topscore)
1864                 {
1865                         leaderfrags = WinningConditionHelper_topscore;
1866
1867                         if (limit)
1868                         if (leaderfrags == limit - 1)
1869                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1870                         else if (leaderfrags == limit - 2)
1871                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1872                         else if (leaderfrags == limit - 3)
1873                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1874                 }
1875         }
1876
1877         limitreached = FALSE;
1878         if(limit)
1879                 if(WinningConditionHelper_topscore >= limit)
1880                         limitreached = TRUE;
1881         if(leadlimit)
1882         {
1883                 float leadlimitreached;
1884                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1885                 if(autocvar_leadlimit_and_fraglimit)
1886                         limitreached = (limitreached && leadlimitreached);
1887                 else
1888                         limitreached = (limitreached || leadlimitreached);
1889         }
1890
1891         if(limit)
1892                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1893
1894         return GetWinningCode(
1895                 WinningConditionHelper_topscore && limitreached,
1896                 WinningConditionHelper_equality
1897         );
1898 }
1899
1900 float WinningCondition_Race(float fraglimit)
1901 {
1902         float wc;
1903         entity p;
1904         float n, c;
1905
1906         n = 0;
1907         c = 0;
1908         FOR_EACH_PLAYER(p)
1909         {
1910                 ++n;
1911                 if(p.race_completed)
1912                         ++c;
1913         }
1914         if(n && (n == c))
1915                 return WINNING_YES;
1916         wc = WinningCondition_Scores(fraglimit, 0);
1917
1918         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1919         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1920         // do NOT support equality when the laps are all raced!
1921                 return WINNING_STARTSUDDENDEATHOVERTIME;
1922         else
1923                 return WINNING_NEVER;
1924 }
1925
1926 float WinningCondition_QualifyingThenRace(float limit)
1927 {
1928         float wc;
1929         wc = WinningCondition_Scores(limit, 0);
1930
1931         // NEVER initiate overtime
1932         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1933         {
1934                 return WINNING_YES;
1935         }
1936
1937         return wc;
1938 }
1939
1940 float WinningCondition_RanOutOfSpawns()
1941 {
1942         entity head;
1943
1944         if(have_team_spawns <= 0)
1945                 return WINNING_NO;
1946
1947         if(autocvar_g_spawn_useallspawns <= 0)
1948                 return WINNING_NO;
1949
1950         if(!some_spawn_has_been_used)
1951                 return WINNING_NO;
1952
1953         team1_score = team2_score = team3_score = team4_score = 0;
1954
1955         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1956         {
1957                 if(head.team == NUM_TEAM_1)
1958                         team1_score = 1;
1959                 else if(head.team == NUM_TEAM_2)
1960                         team2_score = 1;
1961                 else if(head.team == NUM_TEAM_3)
1962                         team3_score = 1;
1963                 else if(head.team == NUM_TEAM_4)
1964                         team4_score = 1;
1965         }
1966
1967         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1968         {
1969                 if(head.team == NUM_TEAM_1)
1970                         team1_score = 1;
1971                 else if(head.team == NUM_TEAM_2)
1972                         team2_score = 1;
1973                 else if(head.team == NUM_TEAM_3)
1974                         team3_score = 1;
1975                 else if(head.team == NUM_TEAM_4)
1976                         team4_score = 1;
1977         }
1978
1979         ClearWinners();
1980         if(team1_score + team2_score + team3_score + team4_score == 0)
1981         {
1982                 checkrules_equality = TRUE;
1983                 return WINNING_YES;
1984         }
1985         else if(team1_score + team2_score + team3_score + team4_score == 1)
1986         {
1987                 float t, i;
1988                 if(team1_score)
1989                         t = NUM_TEAM_1;
1990                 else if(team2_score)
1991                         t = NUM_TEAM_2;
1992                 else if(team3_score)
1993                         t = NUM_TEAM_3;
1994                 else // if(team4_score)
1995                         t = NUM_TEAM_4;
1996                 CheckAllowedTeams(world);
1997                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1998                 {
1999                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2000                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2001                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2002                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2003                 }
2004
2005                 AddWinners(team, t);
2006                 return WINNING_YES;
2007         }
2008         else
2009                 return WINNING_NO;
2010 }
2011
2012 /*
2013 ============
2014 CheckRules_World
2015
2016 Exit deathmatch games upon conditions
2017 ============
2018 */
2019 void ReadyRestart();
2020 void CheckRules_World()
2021 {
2022         float timelimit;
2023         float fraglimit;
2024         float leadlimit;
2025
2026         VoteThink();
2027         MapVote_Think();
2028
2029         SetDefaultAlpha();
2030
2031         /*
2032         MapVote_Think should now do that part
2033         if (intermission_running)
2034                 if (time >= intermission_exittime + 60)
2035                 {
2036                         if(!DoNextMapOverride())
2037                                 GotoNextMap();
2038                         return;
2039                 }
2040         */
2041
2042         if (gameover)   // someone else quit the game already
2043         {
2044                 if(player_count == 0) // Nobody there? Then let's go to the next map
2045                         MapVote_Start();
2046                         // this will actually check the player count in the next frame
2047                         // again, but this shouldn't hurt
2048                 return;
2049         }
2050
2051         timelimit = autocvar_timelimit * 60;
2052         fraglimit = autocvar_fraglimit;
2053         leadlimit = autocvar_leadlimit;
2054
2055         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2056         {
2057                 if(timelimit > 0)
2058                         timelimit = 0; // timelimit is not made for warmup
2059                 if(fraglimit > 0)
2060                         fraglimit = 0; // no fraglimit for now
2061                 leadlimit = 0; // no leadlimit for now
2062         }
2063
2064         if(timelimit > 0)
2065         {
2066                 timelimit += game_starttime;
2067         }
2068         else if (timelimit < 0)
2069         {
2070                 // endmatch
2071                 NextLevel();
2072                 return;
2073         }
2074
2075         if(g_onslaught)
2076                 timelimit = 0; // ONS has its own overtime rule
2077
2078         float wantovertime;
2079         wantovertime = 0;
2080
2081         if(timelimit > game_starttime)
2082                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2083         else
2084                 game_completion_ratio = 0;
2085
2086         if(checkrules_suddendeathend)
2087         {
2088                 if(!checkrules_suddendeathwarning)
2089                 {
2090                         checkrules_suddendeathwarning = TRUE;
2091                         if(g_race && !g_race_qualifying)
2092                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2093                         else
2094                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2095                 }
2096         }
2097         else
2098         {
2099                 if (timelimit && time >= timelimit)
2100                 {
2101                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2102                         {
2103                                 float totalplayers;
2104                                 float playerswithlaps;
2105                                 float readyplayers;
2106                                 entity head;
2107                                 totalplayers = playerswithlaps = readyplayers = 0;
2108                                 FOR_EACH_PLAYER(head)
2109                                 {
2110                                         ++totalplayers;
2111                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2112                                                 ++playerswithlaps;
2113                                         if(head.ready)
2114                                                 ++readyplayers;
2115                                 }
2116
2117                                 // at least 2 of the players have completed a lap: start the RACE
2118                                 // otherwise, the players should end the qualifying on their own
2119                                 if(readyplayers || playerswithlaps >= 2)
2120                                 {
2121                                         checkrules_suddendeathend = 0;
2122                                         ReadyRestart(); // go to race
2123                                         return;
2124                                 }
2125                                 else
2126                                         wantovertime |= InitiateSuddenDeath();
2127                         }
2128                         else
2129                                 wantovertime |= InitiateSuddenDeath();
2130                 }
2131         }
2132
2133         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2134         {
2135                 NextLevel();
2136                 return;
2137         }
2138
2139         float checkrules_status;
2140         checkrules_status = WinningCondition_RanOutOfSpawns();
2141         if(checkrules_status == WINNING_YES)
2142         {
2143                 bprint("Hey! Someone ran out of spawns!\n");
2144         }
2145         else if(g_race && !g_race_qualifying && timelimit >= 0)
2146         {
2147                 checkrules_status = WinningCondition_Race(fraglimit);
2148                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2149         }
2150         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2151         {
2152                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2153                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2154         }
2155         else if(g_assault)
2156         {
2157                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2158         }
2159         else if(g_lms)
2160         {
2161                 checkrules_status = WinningCondition_LMS();
2162         }
2163         else if (g_onslaught)
2164         {
2165                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2166         }
2167         else
2168         {
2169                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2170                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2171         }
2172
2173         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2174         {
2175                 checkrules_status = WINNING_NEVER;
2176                 checkrules_overtimesadded = -1;
2177                 wantovertime |= InitiateSuddenDeath();
2178         }
2179
2180         if(checkrules_status == WINNING_NEVER)
2181                 // equality cases! Nobody wins if the overtime ends in a draw.
2182                 ClearWinners();
2183
2184         if(wantovertime)
2185         {
2186                 if(checkrules_status == WINNING_NEVER)
2187                         InitiateOvertime();
2188                 else
2189                         checkrules_status = WINNING_YES;
2190         }
2191
2192         if(checkrules_suddendeathend)
2193                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2194                         checkrules_status = WINNING_YES;
2195
2196         if(checkrules_status == WINNING_YES)
2197         {
2198                 //print("WINNING\n");
2199                 NextLevel();
2200         }
2201 }
2202
2203 float mapvote_nextthink;
2204 float mapvote_initialized;
2205 float mapvote_keeptwotime;
2206 float mapvote_timeout;
2207 string mapvote_message;
2208 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2209 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2210 float mapvote_screenshot_dirs_count;
2211
2212 float mapvote_count;
2213 float mapvote_count_real;
2214 string mapvote_maps[MAPVOTE_COUNT];
2215 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2216 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2217 float mapvote_maps_suggested[MAPVOTE_COUNT];
2218 string mapvote_suggestions[MAPVOTE_COUNT];
2219 float mapvote_suggestion_ptr;
2220 float mapvote_voters;
2221 float mapvote_selections[MAPVOTE_COUNT];
2222 float mapvote_run;
2223 float mapvote_detail;
2224 float mapvote_abstain;
2225 .float mapvote;
2226
2227 void MapVote_ClearAllVotes()
2228 {
2229         FOR_EACH_CLIENT(other)
2230                 other.mapvote = 0;
2231 }
2232
2233 string MapVote_Suggest(string m)
2234 {
2235         float i;
2236         if(m == "")
2237                 return "That's not how to use this command.";
2238         if(!autocvar_g_maplist_votable_suggestions)
2239                 return "Suggestions are not accepted on this server.";
2240         if(mapvote_initialized)
2241                 return "Can't suggest - voting is already in progress!";
2242         m = MapInfo_FixName(m);
2243         if not(m)
2244                 return "The map you suggested is not available on this server.";
2245         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2246                 if(Map_IsRecent(m))
2247                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2248
2249         if(!MapInfo_CheckMap(m))
2250                 return "The map you suggested does not support the current game mode.";
2251         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2252                 if(mapvote_suggestions[i] == m)
2253                         return "This map was already suggested.";
2254         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2255         {
2256                 i = floor(random() * mapvote_suggestion_ptr);
2257         }
2258         else
2259         {
2260                 i = mapvote_suggestion_ptr;
2261                 mapvote_suggestion_ptr += 1;
2262         }
2263         if(mapvote_suggestions[i] != "")
2264                 strunzone(mapvote_suggestions[i]);
2265         mapvote_suggestions[i] = strzone(m);
2266         if(autocvar_sv_eventlog)
2267                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2268         return strcat("Suggestion of ", m, " accepted.");
2269 }
2270
2271 void MapVote_AddVotable(string nextMap, float isSuggestion)
2272 {
2273         float j, i, o;
2274         string pakfile, mapfile;
2275
2276         if(nextMap == "")
2277                 return;
2278         for(j = 0; j < mapvote_count; ++j)
2279                 if(mapvote_maps[j] == nextMap)
2280                         return;
2281         // suggestions might be no longer valid/allowed after gametype switch!
2282         if(isSuggestion)
2283                 if(!MapInfo_CheckMap(nextMap))
2284                         return;
2285         mapvote_maps[mapvote_count] = strzone(nextMap);
2286         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2287
2288         pakfile = string_null;
2289         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2290         {
2291                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2292                 pakfile = whichpack(strcat(mapfile, ".tga"));
2293                 if(pakfile == "")
2294                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2295                 if(pakfile == "")
2296                         pakfile = whichpack(strcat(mapfile, ".png"));
2297                 if(pakfile != "")
2298                         break;
2299         }
2300         if(i >= mapvote_screenshot_dirs_count)
2301                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2302         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2303                 pakfile = substring(pakfile, o, -1);
2304
2305         mapvote_maps_screenshot_dir[mapvote_count] = i;
2306         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2307
2308         mapvote_count += 1;
2309 }
2310
2311 void MapVote_Spawn();
2312 void MapVote_Init()
2313 {
2314         float i;
2315         float nmax, smax;
2316
2317         MapVote_ClearAllVotes();
2318
2319         mapvote_count = 0;
2320         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2321         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2322
2323         if(mapvote_abstain)
2324                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2325         else
2326                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2327         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2328
2329         // we need this for AddVotable, as that cycles through the screenshot dirs
2330         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2331         if(mapvote_screenshot_dirs_count == 0)
2332                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2333         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2334         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2335                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2336
2337         if(mapvote_suggestion_ptr)
2338                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2339                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2340
2341         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2342                 MapVote_AddVotable(GetNextMap(), FALSE);
2343
2344         if(mapvote_count == 0)
2345         {
2346                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2347                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2348                 if(autocvar_g_maplist_shuffle)
2349                         ShuffleMaplist();
2350                 localcmd("\nmenu_cmd sync\n");
2351                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2352                         MapVote_AddVotable(GetNextMap(), FALSE);
2353         }
2354
2355         mapvote_count_real = mapvote_count;
2356         if(mapvote_abstain)
2357                 MapVote_AddVotable("don't care", 0);
2358
2359         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2360
2361         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2362         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2363         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2364                 mapvote_keeptwotime = 0;
2365         mapvote_message = "Choose a map and press its key!";
2366
2367         MapVote_Spawn();
2368 }
2369
2370 void MapVote_SendPicture(float id)
2371 {
2372         msg_entity = self;
2373         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2374         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2375         WriteByte(MSG_ONE, id);
2376         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2377 }
2378
2379 float MapVote_GetMapMask()
2380 {
2381         float mask, i, power;
2382         mask = 0;
2383         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2384                 if(mapvote_maps[i] != "")
2385                         mask |= power;
2386         return mask;
2387 }
2388
2389 entity mapvote_ent;
2390 float MapVote_SendEntity(entity to, float sf)
2391 {
2392         float i;
2393
2394         if(sf & 1)
2395                 sf &= ~2; // if we send 1, we don't need to also send 2
2396
2397         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2398         WriteByte(MSG_ENTITY, sf);
2399
2400         if(sf & 1)
2401         {
2402                 // flag 1 == initialization
2403                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2404                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2405                 WriteString(MSG_ENTITY, "");
2406                 WriteByte(MSG_ENTITY, mapvote_count);
2407                 WriteByte(MSG_ENTITY, mapvote_abstain);
2408                 WriteByte(MSG_ENTITY, mapvote_detail);
2409                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2410                 if(mapvote_count <= 8)
2411                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2412                 else
2413                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2414                 for(i = 0; i < mapvote_count; ++i)
2415                         if(mapvote_maps[i] != "")
2416                         {
2417                                 if(mapvote_abstain && i == mapvote_count - 1)
2418                                 {
2419                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2420                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2421                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2422                                 }
2423                                 else
2424                                 {
2425                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2426                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2427                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2428                                 }
2429                         }
2430         }
2431
2432         if(sf & 2)
2433         {
2434                 // flag 2 == update of mask
2435                 if(mapvote_count <= 8)
2436                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2437                 else
2438                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2439         }
2440
2441         if(sf & 4)
2442         {
2443                 if(mapvote_detail)
2444                         for(i = 0; i < mapvote_count; ++i)
2445                                 if(mapvote_maps[i] != "")
2446                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2447
2448                 WriteByte(MSG_ENTITY, to.mapvote);
2449         }
2450
2451         return TRUE;
2452 }
2453
2454 void MapVote_Spawn()
2455 {
2456         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2457 }
2458
2459 void MapVote_TouchMask()
2460 {
2461         mapvote_ent.SendFlags |= 2;
2462 }
2463
2464 void MapVote_TouchVotes(entity voter)
2465 {
2466         mapvote_ent.SendFlags |= 4;
2467 }
2468
2469 float MapVote_Finished(float mappos)
2470 {
2471         string result;
2472         float i;
2473         float didntvote;
2474
2475         if(autocvar_sv_eventlog)
2476         {
2477                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2478                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2479                 didntvote = mapvote_voters;
2480                 for(i = 0; i < mapvote_count; ++i)
2481                         if(mapvote_maps[i] != "")
2482                         {
2483                                 didntvote -= mapvote_selections[i];
2484                                 if(i != mappos)
2485                                 {
2486                                         result = strcat(result, ":", mapvote_maps[i]);
2487                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2488                                 }
2489                         }
2490                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2491
2492                 GameLogEcho(result);
2493                 if(mapvote_maps_suggested[mappos])
2494                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2495         }
2496
2497         FOR_EACH_REALCLIENT(other)
2498                 FixClientCvars(other);
2499
2500         Map_Goto_SetStr(mapvote_maps[mappos]);
2501         Map_Goto(0);
2502         alreadychangedlevel = TRUE;
2503         return TRUE;
2504 }
2505 void MapVote_CheckRules_1()
2506 {
2507         float i;
2508
2509         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2510         {
2511                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2512                 mapvote_selections[i] = 0;
2513         }
2514
2515         mapvote_voters = 0;
2516         FOR_EACH_REALCLIENT(other)
2517         {
2518                 ++mapvote_voters;
2519                 if(other.mapvote)
2520                 {
2521                         i = other.mapvote - 1;
2522                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2523                         mapvote_selections[i] = mapvote_selections[i] + 1;
2524                 }
2525         }
2526 }
2527
2528 float MapVote_CheckRules_2()
2529 {
2530         float i;
2531         float firstPlace, secondPlace;
2532         float firstPlaceVotes, secondPlaceVotes;
2533         float mapvote_voters_real;
2534         string result;
2535
2536         if(mapvote_count_real == 1)
2537                 return MapVote_Finished(0);
2538
2539         mapvote_voters_real = mapvote_voters;
2540         if(mapvote_abstain)
2541                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2542
2543         RandomSelection_Init();
2544         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2545                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2546         firstPlace = RandomSelection_chosen_float;
2547         firstPlaceVotes = RandomSelection_best_priority;
2548         //dprint("First place: ", ftos(firstPlace), "\n");
2549         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2550
2551         RandomSelection_Init();
2552         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2553                 if(i != firstPlace)
2554                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2555         secondPlace = RandomSelection_chosen_float;
2556         secondPlaceVotes = RandomSelection_best_priority;
2557         //dprint("Second place: ", ftos(secondPlace), "\n");
2558         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2559
2560         if(firstPlace == -1)
2561                 error("No first place in map vote... WTF?");
2562
2563         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2564                 return MapVote_Finished(firstPlace);
2565
2566         if(mapvote_keeptwotime)
2567                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2568                 {
2569                         float didntvote;
2570                         MapVote_TouchMask();
2571                         mapvote_message = "Now decide between the TOP TWO!";
2572                         mapvote_keeptwotime = 0;
2573                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2574                         result = strcat(result, ":", ftos(firstPlaceVotes));
2575                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2576                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2577                         didntvote = mapvote_voters;
2578                         for(i = 0; i < mapvote_count; ++i)
2579                                 if(mapvote_maps[i] != "")
2580                                 {
2581                                         didntvote -= mapvote_selections[i];
2582                                         if(i != firstPlace)
2583                                                 if(i != secondPlace)
2584                                                 {
2585                                                         result = strcat(result, ":", mapvote_maps[i]);
2586                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2587                                                         if(i < mapvote_count_real)
2588                                                         {
2589                                                                 strunzone(mapvote_maps[i]);
2590                                                                 mapvote_maps[i] = "";
2591                                                                 strunzone(mapvote_maps_pakfile[i]);
2592                                                                 mapvote_maps_pakfile[i] = "";
2593                                                         }
2594                                                 }
2595                                 }
2596                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2597                         if(autocvar_sv_eventlog)
2598                                 GameLogEcho(result);
2599                 }
2600
2601         return FALSE;
2602 }
2603 void MapVote_Tick()
2604 {
2605         float keeptwo;
2606         float totalvotes;
2607
2608         keeptwo = mapvote_keeptwotime;
2609         MapVote_CheckRules_1(); // count
2610         if(MapVote_CheckRules_2()) // decide
2611                 return;
2612
2613         totalvotes = 0;
2614         FOR_EACH_REALCLIENT(other)
2615         {
2616                 // hide scoreboard again
2617                 if(other.health != 2342)
2618                 {
2619                         other.health = 2342;
2620                         other.impulse = 0;
2621                         if(IS_REAL_CLIENT(other))
2622                         {
2623                                 msg_entity = other;
2624                                 WriteByte(MSG_ONE, SVC_FINALE);
2625                                 WriteString(MSG_ONE, "");
2626                         }
2627                 }
2628
2629                 // clear possibly invalid votes
2630                 if(mapvote_maps[other.mapvote - 1] == "")
2631                         other.mapvote = 0;
2632                 // use impulses as new vote
2633                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2634                         if(mapvote_maps[other.impulse - 1] != "")
2635                         {
2636                                 other.mapvote = other.impulse;
2637                                 MapVote_TouchVotes(other);
2638                         }
2639                 other.impulse = 0;
2640
2641                 if(other.mapvote)
2642                         ++totalvotes;
2643         }
2644
2645         MapVote_CheckRules_1(); // just count
2646 }
2647 void MapVote_Start()
2648 {
2649         if(mapvote_run)
2650                 return;
2651
2652         // wait for stats to be sent first
2653         if(!playerstats_waitforme)
2654                 return;
2655
2656         MapInfo_Enumerate();
2657         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2658                 mapvote_run = TRUE;
2659 }
2660 void MapVote_Think()
2661 {
2662         if(!mapvote_run)
2663                 return;
2664
2665         if(alreadychangedlevel)
2666                 return;
2667
2668         if(time < mapvote_nextthink)
2669                 return;
2670         //dprint("tick\n");
2671
2672         mapvote_nextthink = time + 0.5;
2673
2674         if(!mapvote_initialized)
2675         {
2676                 if(autocvar_rescan_pending == 1)
2677                 {
2678                         cvar_set("rescan_pending", "2");
2679                         localcmd("fs_rescan\nrescan_pending 3\n");
2680                         return;
2681                 }
2682                 else if(autocvar_rescan_pending == 2)
2683                 {
2684                         return;
2685                 }
2686                 else if(autocvar_rescan_pending == 3)
2687                 {
2688                         // now build missing mapinfo files
2689                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2690                                 return;
2691
2692                         // we're done, start the timer
2693                         cvar_set("rescan_pending", "0");
2694                 }
2695
2696                 mapvote_initialized = TRUE;
2697                 if(DoNextMapOverride(0))
2698                         return;
2699                 if(!autocvar_g_maplist_votable || player_count <= 0)
2700                 {
2701                         GotoNextMap(0);
2702                         return;
2703                 }
2704                 MapVote_Init();
2705         }
2706
2707         MapVote_Tick();
2708 }
2709
2710 string GotoMap(string m)
2711 {
2712         if(!MapInfo_CheckMap(m))
2713                 return "The map you chose is not available on this server.";
2714         cvar_set("nextmap", m);
2715         cvar_set("timelimit", "-1");
2716         if(mapvote_initialized || alreadychangedlevel)
2717         {
2718                 if(DoNextMapOverride(0))
2719                         return "Map switch initiated.";
2720                 else
2721                         return "Hm... no. For some reason I like THIS map more.";
2722         }
2723         else
2724                 return "Map switch will happen after scoreboard.";
2725 }
2726
2727
2728 void EndFrame()
2729 {
2730         float altime;
2731         FOR_EACH_REALCLIENT(self)
2732         {
2733                 if(IS_SPEC(self))
2734                 {
2735                         if(self.enemy.typehitsound)
2736                                 self.typehit_time = time;
2737                         else if(self.enemy.hitsound)
2738                                 self.hit_time = time;
2739                 }
2740                 else
2741                 {
2742                         if(self.typehitsound)
2743                                 self.typehit_time = time;
2744                         else if(self.hitsound)
2745                                 self.hit_time = time;
2746                 }
2747         }
2748         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2749         // add 1 frametime because after this, engine SV_Physics
2750         // increases time by a frametime and then networks the frame
2751         // add another frametime because client shows everything with
2752         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2753         // needed!
2754         FOR_EACH_CLIENT(self)
2755         {
2756                 self.hitsound = FALSE;
2757                 self.typehitsound = FALSE;
2758                 antilag_record(self, altime);
2759         }
2760 }
2761
2762
2763 /*
2764  * RedirectionThink:
2765  * returns TRUE if redirecting
2766  */
2767 float redirection_timeout;
2768 float redirection_nextthink;
2769 float RedirectionThink()
2770 {
2771         float clients_found;
2772
2773         if(redirection_target == "")
2774                 return FALSE;
2775
2776         if(!redirection_timeout)
2777         {
2778                 cvar_set("sv_public", "-2");
2779                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2780                 if(redirection_target == "self")
2781                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2782                 else
2783                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2784         }
2785
2786         if(time < redirection_nextthink)
2787                 return TRUE;
2788
2789         redirection_nextthink = time + 1;
2790
2791         clients_found = 0;
2792         FOR_EACH_REALCLIENT(self)
2793         {
2794                 // TODO add timer
2795                 print("Redirecting: sending connect command to ", self.netname, "\n");
2796                 if(redirection_target == "self")
2797                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2798                 else
2799                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2800                 ++clients_found;
2801         }
2802
2803         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2804
2805         if(time > redirection_timeout || clients_found == 0)
2806                 localcmd("\nwait; wait; wait; quit\n");
2807
2808         return TRUE;
2809 }
2810
2811 void TargetMusic_RestoreGame();
2812 void RestoreGame()
2813 {
2814         // Loaded from a save game
2815         // some things then break, so let's work around them...
2816
2817         // Progs DB (capture records)
2818         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2819
2820         // Mapinfo
2821         MapInfo_Shutdown();
2822         MapInfo_Enumerate();
2823         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2824         WeaponStats_Init();
2825
2826         TargetMusic_RestoreGame();
2827 }
2828
2829 void Shutdown()
2830 {
2831         entity e;
2832
2833         gameover = 2;
2834
2835         if(world_initialized > 0)
2836         {
2837                 world_initialized = 0;
2838                 print("Saving persistent data...\n");
2839                 Ban_SaveBans();
2840
2841                 PlayerStats_EndMatch(0);
2842                 FOR_EACH_CLIENT(e)
2843                         PlayerStats_AddGlobalInfo(e);
2844                 PlayerStats_Shutdown();
2845
2846                 if(!cheatcount_total)
2847                 {
2848                         if(autocvar_sv_db_saveasdump)
2849                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2850                         else
2851                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2852                 }
2853                 if(autocvar_developer)
2854                 {
2855                         if(autocvar_sv_db_saveasdump)
2856                                 db_dump(TemporaryDB, "server-temp.db");
2857                         else
2858                                 db_save(TemporaryDB, "server-temp.db");
2859                 }
2860                 CheatShutdown(); // must be after cheatcount check
2861                 db_close(ServerProgsDB);
2862                 db_close(TemporaryDB);
2863                 print("done!\n");
2864                 // tell the bot system the game is ending now
2865                 bot_endgame();
2866
2867                 WeaponStats_Shutdown();
2868                 MapInfo_Shutdown();
2869         }
2870         else if(world_initialized == 0)
2871         {
2872                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2873         }
2874 }