qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(cvar("g_running_guns"))
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = cvar("g_player_alpha");
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!cvar("developer_fteqccbugs"))
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(cvar("_sv_init"))
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(cvar("g_maplist_shuffle"))
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADCVAR(p) if(k == p) continue
 239                 // internal
 240                 BADPREFIX("csqc_");
 241                 BADPREFIX("cvar_check_");
 242                 BADCVAR("gamecfg");
 243                 BADCVAR("g_configversion");
 244                 BADCVAR("g_maplist_index");
 245                 BADCVAR("halflifebsp");
 246                 BADPREFIX("sv_world");
 247
 248                 // client
 249                 BADPREFIX("chase_");
 250                 BADPREFIX("cl_");
 251                 BADPREFIX("con_");
 252                 BADPREFIX("scoreboard_");
 253                 BADPREFIX("g_campaign");
 254                 BADPREFIX("gl_");
 255                 BADPREFIX("joy");
 256                 BADPREFIX("hud_");
 257                 BADPREFIX("menu_");
 258                 BADPREFIX("net_slist_");
 259                 BADPREFIX("r_");
 260                 BADPREFIX("sbar_");
 261                 BADPREFIX("scr_");
 262                 BADPREFIX("snd_");
 263                 BADPREFIX("userbind");
 264                 BADPREFIX("v_");
 265                 BADPREFIX("vid_");
 266                 BADPREFIX("crosshair");
 267                 BADCVAR("mod_q3bsp_lightmapmergepower");
 268                 BADCVAR("mod_q3bsp_nolightmaps");
 269                 BADCVAR("fov");
 270                 BADCVAR("mastervolume");
 271                 BADCVAR("volume");
 272                 BADCVAR("bgmvolume");
 273
 274                 // private
 275                 BADCVAR("developer");
 276                 BADCVAR("g_banned_list");
 277                 BADCVAR("log_dest_udp");
 278                 BADCVAR("log_file");
 279                 BADCVAR("net_address");
 280                 BADCVAR("net_address_ipv6");
 281                 BADCVAR("port");
 282                 BADCVAR("savedgamecfg");
 283                 BADCVAR("serverconfig");
 284                 BADCVAR("sv_heartbeatperiod");
 285                 BADCVAR("sv_vote_master_password");
 286                 BADCVAR("sys_colortranslation");
 287                 BADCVAR("sys_specialcharactertranslation");
 288                 BADCVAR("timestamps");
 289                 BADPREFIX("developer_");
 290                 BADPREFIX("g_ban_");
 291                 BADPREFIX("g_chat_flood_");
 292                 BADPREFIX("g_voice_flood_");
 293                 BADPREFIX("rcon_");
 294                 BADPREFIX("settemp_");
 295                 BADPREFIX("sv_allowdownloads_");
 296                 BADPREFIX("sv_autodemo");
 297                 BADPREFIX("sv_curl_");
 298                 BADPREFIX("sv_eventlog");
 299                 BADPREFIX("sv_logscores_");
 300                 BADPREFIX("sv_master");
 301                 BADPREFIX("sv_weaponstats_");
 302
 303                 // these can contain player IDs, so better hide
 304                 BADCVAR("g_forced_team_red");
 305                 BADCVAR("g_forced_team_blue");
 306                 BADCVAR("g_forced_team_yellow");
 307                 BADCVAR("g_forced_team_pink");
 308
 309                 // mapinfo
 310                 BADCVAR("timelimit");
 311                 BADCVAR("fraglimit");
 312                 BADCVAR("leadlimit");
 313                 BADCVAR("g_tdm_teams");
 314                 BADCVAR("g_keyhunt_teams");
 315                 BADCVAR("g_domination_default_teams");
 316                 BADCVAR("g_race_qualifying_timelimit");
 317                 BADCVAR("g_lms");
 318                 BADCVAR("g_arena");
 319                 BADCVAR("g_ca");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ctf");
 322                 BADCVAR("g_dm");
 323                 BADCVAR("g_domination");
 324                 BADCVAR("g_keyhunt");
 325                 BADCVAR("g_keyhunt_teams");
 326                 BADCVAR("g_onslaught");
 327                 BADCVAR("g_race");
 328                 BADCVAR("g_cts");
 329                 BADCVAR("g_runematch");
 330                 BADCVAR("g_tdm");
 331                 BADCVAR("g_nexball");
 332                 BADCVAR("teamplay");
 333
 334                 // long
 335                 BADCVAR("hostname");
 336                 BADCVAR("g_maplist");
 337                 BADCVAR("g_maplist_mostrecent");
 338                 BADCVAR("sv_motd");
 339
 340                 v = cvar_string(k);
 341                 d = cvar_defstring(k);
 342                 if(v == d)
 343                         continue;
 344
 345                 if(adding)
 346                 {
 347                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 348                         if(strlen(cvar_changes) > 16384)
 349                         {
 350                                 cvar_changes = "// too many settings have been changed to show them here\n";
 351                                 adding = 0;
 352                         }
 353                 }
 354
 355                 // now check if the changes are actually gameplay relevant
 356
 357                 // does nothing visible
 358                 BADCVAR("captureleadlimit_override");
 359                 BADCVAR("g_arena_point_leadlimit");
 360                 BADCVAR("g_ca_point_leadlimit");
 361                 BADCVAR("g_ctf_capture_leadlimit");
 362                 BADCVAR("g_domination_point_leadlimit");
 363                 BADCVAR("g_keyhunt_point_leadlimit");
 364                 BADCVAR("g_nexball_goalleadlimit");
 365                 BADCVAR("g_runematch_point_leadlimit");
 366                 BADCVAR("leadlimit_and_fraglimit");
 367                 BADCVAR("leadlimit_override");
 368                 BADCVAR("sv_checkforpacketsduringsleep");
 369                 BADPREFIX("crypto_");
 370                 BADPREFIX("g_chat_");
 371                 BADPREFIX("net_");
 372                 BADPREFIX("prvm_");
 373                 BADPREFIX("sv_fragmessage_");
 374                 BADPREFIX("sv_vote_");
 375                 BADPREFIX("timelimit_");
 376
 377                 // allowed changes to server admins (please sync this to server.cfg)
 378                 // vi commands:
 379                 //   :/"impure"/,$d
 380                 //   :g!,^\/\/[^ /],d
 381                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 382                 //   :%!sort
 383                 // yes, this does contain some redundant stuff, don't really care
 384                 BADCVAR("bot_number");
 385                 BADCVAR("bot_prefix");
 386                 BADCVAR("bot_suffix");
 387                 BADCVAR("capturelimit_override");
 388                 BADCVAR("fraglimit_override");
 389                 BADCVAR("gametype");
 390                 BADCVAR("g_antilag");
 391                 BADCVAR("g_balance_teams");
 392                 BADCVAR("g_balance_teams_force");
 393                 BADCVAR("g_ban_sync_trusted_servers");
 394                 BADCVAR("g_ban_sync_uri");
 395                 BADCVAR("g_ctf_capture_limit");
 396                 BADCVAR("g_ctf_ignore_frags");
 397                 BADCVAR("g_ctf_win_mode");
 398                 BADCVAR("g_domination_point_limit");
 399                 BADCVAR("g_fullbrightitems");
 400                 BADCVAR("g_fullbrightplayers");
 401                 BADCVAR("g_keyhunt_point_limit");
 402                 BADCVAR("g_keyhunt_teams_override");
 403                 BADCVAR("g_lms_lives_override");
 404                 BADCVAR("g_maplist");
 405                 BADCVAR("g_maplist_check_waypoints");
 406                 BADCVAR("g_maplist_mostrecent_count");
 407                 BADCVAR("g_maplist_shuffle");
 408                 BADCVAR("g_maplist_votable");
 409                 BADCVAR("g_maplist_votable_abstain");
 410                 BADCVAR("g_maplist_votable_nodetail");
 411                 BADCVAR("g_maplist_votable_suggestions");
 412                 BADCVAR("g_minstagib");
 413                 BADCVAR("g_nexball_goallimit");
 414                 BADCVAR("g_runematch_point_limit");
 415                 BADCVAR("g_start_delay");
 416                 BADCVAR("hostname");
 417                 BADCVAR("log_file");
 418                 BADCVAR("maxplayers");
 419                 BADCVAR("minplayers");
 420                 BADCVAR("net_address");
 421                 BADCVAR("port");
 422                 BADCVAR("rcon_password");
 423                 BADCVAR("rcon_restricted_commands");
 424                 BADCVAR("rcon_restricted_password");
 425                 BADCVAR("skill");
 426                 BADCVAR("sv_adminnick");
 427                 BADCVAR("sv_autoscreenshot");
 428                 BADCVAR("sv_curl_defaulturl");
 429                 BADCVAR("sv_defaultcharacter");
 430                 BADCVAR("sv_defaultplayercolors");
 431                 BADCVAR("sv_defaultplayermodel");
 432                 BADCVAR("sv_defaultplayerskin");
 433                 BADCVAR("sv_maxidle");
 434                 BADCVAR("sv_maxrate");
 435                 BADCVAR("sv_motd");
 436                 BADCVAR("sv_public");
 437                 BADCVAR("sv_ready_restart");
 438                 BADCVAR("sv_status_privacy");
 439                 BADCVAR("sv_vote_call");
 440                 BADCVAR("sv_vote_commands");
 441                 BADCVAR("sv_vote_majority_factor");
 442                 BADCVAR("sv_vote_master");
 443                 BADCVAR("sv_vote_master_commands");
 444                 BADCVAR("sv_vote_master_password");
 445                 BADCVAR("sv_vote_simple_majority_factor");
 446                 BADCVAR("timelimit_override");
 447
 448                 if(cvar("g_minstagib"))
 449                 {
 450                         BADCVAR("g_grappling_hook");
 451                         BADCVAR("g_jetpack");
 452                 }
 453 #undef BADPREFIX
 454 #undef BADCVAR
 455
 456                 if(pureadding)
 457                 {
 458                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 459                         if(strlen(cvar_purechanges) > 16384)
 460                         {
 461                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 462                                 pureadding = 0;
 463                         }
 464                 }
 465                 ++cvar_purechanges_count;
 466                 // WARNING: this variable is used for the server list
 467                 // NEVER dare to skip this code!
 468                 // Hacks to intentionally appearing as "pure server" even though you DO have
 469                 // modified settings may be punished by removal from the server list.
 470                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 471                 // though.
 472         }
 473         buf_del(h);
 474         if(cvar_changes == "")
 475                 cvar_changes = "// this server runs at default server settings\n";
 476         else
 477                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 478         cvar_changes = strzone(cvar_changes);
 479         if(cvar_purechanges == "")
 480                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 481         else
 482                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 483         cvar_purechanges = strzone(cvar_purechanges);
 484 }
 485
 486 void detect_maptype()
 487 {
 488 #if 0
 489         vector o, v;
 490         float i;
 491
 492         for(;;)
 493         {
 494                 o = world.mins;
 495                 o_x += random() * (world.maxs_x - world.mins_x);
 496                 o_y += random() * (world.maxs_y - world.mins_y);
 497                 o_z += random() * (world.maxs_z - world.mins_z);
 498
 499                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 500                 if(trace_fraction == 1)
 501                         continue;
 502
 503                 v = trace_endpos;
 504
 505                 for(i = 0; i < 64; i += 4)
 506                 {
 507                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 508         if(trace_fraction == 1)
 509                 continue;
 510                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 511                 }
 512
 513                 break;
 514         }
 515 #endif
 516 }
 517
 518 entity randomseed;
 519 float RandomSeed_Send(entity to, float sf)
 520 {
 521         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 522         WriteShort(MSG_ENTITY, self.cnt);
 523         return TRUE;
 524 }
 525 void RandomSeed_Think()
 526 {
 527         self.cnt = bound(0, floor(random() * 65536), 65535);
 528         self.nextthink = time + 5;
 529
 530         self.SendFlags |= 1;
 531 }
 532 void RandomSeed_Spawn()
 533 {
 534         randomseed = spawn();
 535         randomseed.think = RandomSeed_Think;
 536         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 537
 538         entity oldself;
 539         oldself = self;
 540         self = randomseed;
 541         self.think(); // sets random seed and nextthink
 542         self = oldself;
 543 }
 544
 545 void spawnfunc___init_dedicated_server(void)
 546 {
 547         // handler for _init/_init map (only for dedicated server initialization)
 548
 549         world_initialized = -1; // don't complain
 550         cvar = cvar_normal;
 551         cvar_string = cvar_string_normal;
 552         cvar_set = cvar_set_normal;
 553
 554         remove = remove_unsafely;
 555
 556         entity e;
 557         e = spawn();
 558         e.think = GotoFirstMap;
 559         e.nextthink = time; // this is usually 1 at this point
 560
 561         e = spawn();
 562         e.classname = "info_player_deathmatch"; // safeguard against player joining
 563
 564         self.classname = "worldspawn"; // safeguard against various stuff ;)
 565
 566         MapInfo_Enumerate();
 567         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 568 }
 569
 570 void Map_MarkAsRecent(string m);
 571 float world_already_spawned;
 572 void RegisterWeapons();
 573 void Nagger_Init();
 574 void ClientInit_Spawn();
 575 void WeaponStats_Init();
 576 void WeaponStats_Shutdown();
 577 void spawnfunc_worldspawn (void)
 578 {
 579         float fd, l, i, j, n;
 580         string s, col;
 581
 582         cvar = cvar_normal;
 583         cvar_string = cvar_string_normal;
 584         cvar_set = cvar_set_normal;
 585
 586         if(world_already_spawned)
 587                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 588         world_already_spawned = TRUE;
 589
 590         remove = remove_safely; // during spawning, watch what you remove!
 591
 592         check_unacceptable_compiler_bugs();
 593
 594         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 595
 596         compressShortVector_init();
 597
 598         allowed_to_spawn = TRUE;
 599
 600         local entity head;
 601         head = nextent(world);
 602         maxclients = 0;
 603         while(head)
 604         {
 605                 ++maxclients;
 606                 head = nextent(head);
 607         }
 608
 609         // needs to be done so early as they would still spawn
 610         RegisterWeapons();
 611
 612         ServerProgsDB = db_load("server.db");
 613
 614         TemporaryDB = db_create();
 615
 616         /*
 617         TODO sound pack system
 618         // initialize sound pack system
 619         soundpack = cvar_string("g_soundpack");
 620         if(soundpack != "")
 621                 soundpack = strcat(soundpack, "/");
 622         soundpack = strzone(soundpack);
 623         */
 624
 625         // 0 normal
 626         lightstyle(0, "m");
 627
 628         // 1 FLICKER (first variety)
 629         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 630
 631         // 2 SLOW STRONG PULSE
 632         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 633
 634         // 3 CANDLE (first variety)
 635         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 636
 637         // 4 FAST STROBE
 638         lightstyle(4, "mamamamamama");
 639
 640         // 5 GENTLE PULSE 1
 641         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 642
 643         // 6 FLICKER (second variety)
 644         lightstyle(6, "nmonqnmomnmomomno");
 645
 646         // 7 CANDLE (second variety)
 647         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 648
 649         // 8 CANDLE (third variety)
 650         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 651
 652         // 9 SLOW STROBE (fourth variety)
 653         lightstyle(9, "aaaaaaaazzzzzzzz");
 654
 655         // 10 FLUORESCENT FLICKER
 656         lightstyle(10, "mmamammmmammamamaaamammma");
 657
 658         // 11 SLOW PULSE NOT FADE TO BLACK
 659         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 660
 661         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 662
 663         // 63 testing
 664         lightstyle(63, "a");
 665
 666         if(cvar("g_campaign"))
 667                 CampaignPreInit();
 668
 669         Map_MarkAsRecent(mapname);
 670
 671         precache_model ("null"); // we need this one before InitGameplayMode
 672         InitGameplayMode();
 673         readlevelcvars();
 674         GrappleHookInit();
 675         ElectroInit();
 676         LaserInit();
 677
 678         player_count = 0;
 679         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 680         if(bot_waypoints_for_items == 1)
 681                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 682                         bot_waypoints_for_items = 0;
 683
 684         // for setting by mapinfo
 685         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 686         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 687
 688         precache();
 689
 690         WaypointSprite_Init();
 691
 692         //if (g_domination)
 693         //      dom_init();
 694
 695         GameLogInit(); // prepare everything
 696         if(cvar("sv_eventlog"))
 697         {
 698                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 699                 s = strcat(s, ftos(random()));
 700                 matchid = strzone(s);
 701
 702                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 703                 s = ":gameinfo:mutators:LIST";
 704
 705                 ret_string = s;
 706                 MUTATOR_CALLHOOK(BuildMutatorsString);
 707                 s = ret_string;
 708
 709                 // simple, probably not good in the mutator system
 710                 if(cvar("g_grappling_hook"))
 711                         s = strcat(s, ":grappling_hook");
 712
 713                 // initialiation stuff, not good in the mutator system
 714                 if(!cvar("g_use_ammunition"))
 715                         s = strcat(s, ":no_use_ammunition");
 716
 717                 // initialiation stuff, not good in the mutator system
 718                 if(!cvar("g_pickup_items"))
 719                         s = strcat(s, ":no_pickup_items");
 720
 721                 // initialiation stuff, not good in the mutator system
 722                 if(cvar_string("g_weaponarena") != "0")
 723                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 724
 725                 // TODO to mutator system
 726                 if(cvar("g_norecoil"))
 727                         s = strcat(s, ":norecoil");
 728
 729                 // TODO to mutator system
 730                 if(cvar("g_midair"))
 731                         s = strcat(s, ":midair");
 732
 733                 // TODO to mutator system
 734                 if(cvar("g_minstagib"))
 735                         s = strcat(s, ":minstagib");
 736
 737                 GameLogEcho(s);
 738                 GameLogEcho(":gameinfo:end");
 739         }
 740         else
 741                 matchid = strzone(ftos(random()));
 742
 743         cvar_set("nextmap", "");
 744
 745         SetDefaultAlpha();
 746
 747         if(cvar("g_campaign"))
 748                 CampaignPostInit();
 749
 750         fteqcc_testbugs();
 751
 752         Ban_LoadBans();
 753
 754         MapInfo_Enumerate();
 755         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 756
 757         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 758         {
 759                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 760                 if(fd != -1)
 761                 {
 762                         while((s = fgets(fd)))
 763                         {
 764                                 l = tokenize_console(s);
 765                                 if(l < 2)
 766                                         continue;
 767                                 if(argv(0) == "cd")
 768                                 {
 769                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 770                                         print("  cdtrack ", argv(2), "\n");
 771                                 }
 772                                 else if(argv(0) == "fog")
 773                                 {
 774                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 775                                         print("  \"fog\" \"", s, "\"\n");
 776                                 }
 777                                 else if(argv(0) == "set")
 778                                 {
 779                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 780                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 781                                 }
 782                                 else if(argv(0) != "//")
 783                                 {
 784                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 785                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 786                                 }
 787                         }
 788                         fclose(fd);
 789                 }
 790         }
 791
 792         WeaponStats_Init();
 793
 794         addstat(STAT_WEAPONS, AS_INT, weapons);
 795         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 796         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 797         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 798         Nagger_Init();
 799
 800         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 801         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 802         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 803         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 804         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 805         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 806         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 807         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 808
 809         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 810         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_charge_pool_ammo);
 811
 812         if(g_ca)
 813         {
 814                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 815                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 816         }
 817         // g_movementspeed hack
 818         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 819         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 820         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 821         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 822
 823         next_pingtime = time + 5;
 824
 825         detect_maptype();
 826
 827         lsmaps_reply = "^7Maps available: ";
 828         lsnewmaps_reply = "^7Maps without a record set: ";
 829         for(i = 0, j = 0; i < MapInfo_count; ++i)
 830         {
 831                 if(MapInfo_Get_ByID(i))
 832                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 833                         {
 834                                 if(mod(i, 2))
 835                                         col = "^2";
 836                                 else
 837                                         col = "^3";
 838                                 ++j;
 839                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 840                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 841                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 842                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 843                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 844                         }
 845         }
 846         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 847         if (!g_race && !g_cts)
 848                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 849         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 850
 851         maplist_reply = "^7Maps in list: ";
 852         n = tokenize_console(cvar_string("g_maplist"));
 853         for(i = 0, j = 0; i < n; ++i)
 854         {
 855                 if(MapInfo_CheckMap(argv(i)))
 856                 {
 857                         if(mod(j, 2))
 858                                 col = "^2";
 859                         else
 860                                 col = "^3";
 861                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 862                         ++j;
 863                 }
 864         }
 865         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 866         MapInfo_ClearTemps();
 867
 868         for(i = 0; i < 10; ++i)
 869         {
 870                 records_reply[i] = strzone(getrecords(i));
 871         }
 872         if(g_cts)
 873                 ladder_reply = strzone(getladder());
 874
 875         rankings_reply = strzone(getrankings());
 876
 877         ClientInit_Spawn();
 878         RandomSeed_Spawn();
 879         PingPLReport_Spawn();
 880
 881         CheatInit();
 882
 883         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 884
 885         // fill sv_curl_serverpackages from .serverpackage files
 886         if(cvar("sv_curl_serverpackages_auto"))
 887         {
 888                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 889                 s = "";
 890                 if(fd >= 0)
 891                 {
 892                         j = search_getsize(fd);
 893                         for(i = 0; i < j; ++i)
 894                                 s = strcat(s, " ", search_getfilename(fd, i));
 895                         search_end(fd);
 896                 }
 897                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 898         }
 899
 900         world_initialized = 1;
 901 }
 902
 903 void spawnfunc_light (void)
 904 {
 905         //makestatic (self); // Who the f___ did that?
 906         remove(self);
 907 }
 908
 909 float TryFile( string pFilename )
 910 {
 911         local float lHandle;
 912         dprint("TryFile(\"", pFilename, "\")\n");
 913         lHandle = fopen( pFilename, FILE_READ );
 914         if( lHandle != -1 ) {
 915                 fclose( lHandle );
 916                 return TRUE;
 917         } else {
 918                 return FALSE;
 919         }
 920 };
 921
 922 string GetGametype()
 923 {
 924         return GametypeNameFromType(game);
 925 }
 926
 927 string getmapname_stored;
 928 string GetMapname()
 929 {
 930         return mapname;
 931 }
 932
 933 float Map_Count, Map_Current;
 934 string Map_Current_Name;
 935
 936 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 937 float GetMaplistPosition()
 938 {
 939         float pos, idx;
 940         string map;
 941
 942         map = GetMapname();
 943         idx = cvar("g_maplist_index");
 944
 945         if(idx >= 0)
 946                 if(idx < Map_Count)
 947                         if(map == argv(idx))
 948                                 return idx;
 949
 950         for(pos = 0; pos < Map_Count; ++pos)
 951                 if(map == argv(pos))
 952                         return pos;
 953
 954         // resume normal maplist rotation if current map is not in g_maplist
 955         return idx;
 956 }
 957
 958 float MapHasRightSize(string map)
 959 {
 960         float fh;
 961         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 962         if(cvar("g_maplist_check_waypoints"))
 963         {
 964                 dprint("checkwp "); dprint(map);
 965                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 966                 if(fh < 0)
 967                 {
 968                         dprint(": no waypoints\n");
 969                         return FALSE;
 970                 }
 971                 dprint(": has waypoints\n");
 972                 fclose(fh);
 973         }
 974
 975         // open map size restriction file
 976         dprint("opensize "); dprint(map);
 977         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 978         if(fh >= 0)
 979         {
 980                 float mapmin, mapmax;
 981                 dprint(": ok, ");
 982                 mapmin = stof(fgets(fh));
 983                 mapmax = stof(fgets(fh));
 984                 fclose(fh);
 985                 if(player_count < mapmin)
 986                 {
 987                         dprint("not enough\n");
 988                         return FALSE;
 989                 }
 990                 if(player_count > mapmax)
 991                 {
 992                         dprint("too many\n");
 993                         return FALSE;
 994                 }
 995                 dprint("right size\n");
 996                 return TRUE;
 997         }
 998         dprint(": not found\n");
 999         return TRUE;
1000 }
1001
1002 string Map_Filename(float position)
1003 {
1004         return strcat("maps/", argv(position), ".bsp");
1005 }
1006
1007 string strwords(string s, float w)
1008 {
1009         float endpos;
1010         for(endpos = 0; w && endpos >= 0; --w)
1011                 endpos = strstrofs(s, " ", endpos + 1);
1012         if(endpos < 0)
1013                 return s;
1014         else
1015                 return substring(s, 0, endpos);
1016 }
1017
1018 float strhasword(string s, string w)
1019 {
1020         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1021 }
1022
1023 void Map_MarkAsRecent(string m)
1024 {
1025         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
1026 }
1027
1028 float Map_IsRecent(string m)
1029 {
1030         return strhasword(cvar_string("g_maplist_mostrecent"), m);
1031 }
1032
1033 float Map_Check(float position, float pass)
1034 {
1035         string filename;
1036         string map_next;
1037         map_next = argv(position);
1038         if(pass <= 1)
1039         {
1040                 if(Map_IsRecent(map_next))
1041                         return 0;
1042         }
1043         filename = Map_Filename(position);
1044         if(MapInfo_CheckMap(map_next))
1045         {
1046                 if(pass == 2)
1047                         return 1;
1048                 if(MapHasRightSize(map_next))
1049                         return 1;
1050                 return 0;
1051         }
1052         else
1053                 dprint( "Couldn't select '", filename, "'..\n" );
1054
1055         return 0;
1056 }
1057
1058 void Map_Goto_SetStr(string nextmapname)
1059 {
1060         if(getmapname_stored != "")
1061                 strunzone(getmapname_stored);
1062         if(nextmapname == "")
1063                 getmapname_stored = "";
1064         else
1065                 getmapname_stored = strzone(nextmapname);
1066 }
1067
1068 void Map_Goto_SetFloat(float position)
1069 {
1070         cvar_set("g_maplist_index", ftos(position));
1071         Map_Goto_SetStr(argv(position));
1072 }
1073
1074 void GameResetCfg()
1075 {
1076         // settings persist, except...
1077         localcmd("\nsettemp_restore\n");
1078 };
1079
1080 void Map_Goto()
1081 {
1082         GameResetCfg();
1083         MapInfo_LoadMap(getmapname_stored);
1084 }
1085
1086 // return codes of map selectors:
1087 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1088 //   -2 = permanent failure
1089 float() MaplistMethod_Iterate = // usual method
1090 {
1091         float pass, i;
1092
1093         for(pass = 1; pass <= 2; ++pass)
1094         {
1095                 for(i = 1; i < Map_Count; ++i)
1096                 {
1097                         float mapindex;
1098                         mapindex = mod(i + Map_Current, Map_Count);
1099                         if(Map_Check(mapindex, pass))
1100                                 return mapindex;
1101                 }
1102         }
1103         return -1;
1104 }
1105
1106 float() MaplistMethod_Repeat = // fallback method
1107 {
1108         if(Map_Check(Map_Current, 2))
1109                 return Map_Current;
1110         return -2;
1111 }
1112
1113 float() MaplistMethod_Random = // random map selection
1114 {
1115         float i, imax;
1116
1117         imax = 42;
1118
1119         for(i = 0; i <= imax; ++i)
1120         {
1121                 float mapindex;
1122                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1123                 if(Map_Check(mapindex, 1))
1124                         return mapindex;
1125         }
1126         return -1;
1127 }
1128
1129 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1130 // the exponent sets a bias on the map selection:
1131 // the higher the exponent, the less likely "shortly repeated" same maps are
1132 {
1133         float i, j, imax, insertpos;
1134
1135         imax = 42;
1136
1137         for(i = 0; i <= imax; ++i)
1138         {
1139                 string newlist;
1140
1141                 // now reinsert this at another position
1142                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1143                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1144                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1145                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1146
1147                 // insert the current map there
1148                 newlist = "";
1149                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1150                         newlist = strcat(newlist, " ", argv(j));
1151                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1152                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1153                         newlist = strcat(newlist, " ", argv(j));
1154                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1155                 cvar_set("g_maplist", newlist);
1156                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1157
1158                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1159                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1160                 if(Map_Check(Map_Current, 1))
1161                         return Map_Current;
1162         }
1163         return -1;
1164 }
1165
1166 void Maplist_Init()
1167 {
1168         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1169         if(Map_Count == 0)
1170         {
1171                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1172                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1173                 if(cvar("g_maplist_shuffle"))
1174                         ShuffleMaplist();
1175                 localcmd("\nmenu_cmd sync\n");
1176                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1177         }
1178         if(Map_Count == 0)
1179                 error("empty maplist, cannot select a new map");
1180         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1181
1182         if(Map_Current_Name)
1183                 strunzone(Map_Current_Name);
1184         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1185         // this may or may not be correct, but who cares, in the worst case a map
1186         // isn't chosen in the first pass that should have been
1187 }
1188
1189 string GetNextMap()
1190 {
1191         float nextMap;
1192
1193         Maplist_Init();
1194         nextMap = -1;
1195
1196         if(nextMap == -1)
1197                 if(cvar("g_maplist_shuffle") > 0)
1198                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
1199
1200         if(nextMap == -1)
1201                 if(cvar("g_maplist_selectrandom"))
1202                         nextMap = MaplistMethod_Random();
1203
1204         if(nextMap == -1)
1205                 nextMap = MaplistMethod_Iterate();
1206
1207         if(nextMap == -1)
1208                 nextMap = MaplistMethod_Repeat();
1209
1210         if(nextMap >= 0)
1211         {
1212                 Map_Goto_SetFloat(nextMap);
1213                 return getmapname_stored;
1214         }
1215
1216         return "";
1217 };
1218
1219 float DoNextMapOverride()
1220 {
1221         if(cvar("g_campaign"))
1222         {
1223                 CampaignPostIntermission();
1224                 alreadychangedlevel = TRUE;
1225                 return TRUE;
1226         }
1227         if(cvar("quit_when_empty"))
1228         {
1229                 if(player_count <= currentbots)
1230                 {
1231                         localcmd("quit\n");
1232                         alreadychangedlevel = TRUE;
1233                         return TRUE;
1234                 }
1235         }
1236         if(cvar_string("quit_and_redirect") != "")
1237         {
1238                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1239                 alreadychangedlevel = TRUE;
1240                 return TRUE;
1241         }
1242         if (cvar("samelevel")) // if samelevel is set, stay on same level
1243         {
1244                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1245                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1246                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1247                 localcmd("restart\n");
1248                 //changelevel (mapname);
1249                 alreadychangedlevel = TRUE;
1250                 return TRUE;
1251         }
1252         if(cvar_string("nextmap") != "")
1253                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1254                 {
1255                         Map_Goto_SetStr(cvar_string("nextmap"));
1256                         Map_Goto();
1257                         alreadychangedlevel = TRUE;
1258                         return TRUE;
1259                 }
1260         if(cvar("lastlevel"))
1261         {
1262                 GameResetCfg();
1263                 localcmd("set lastlevel 0\ntogglemenu\n");
1264                 alreadychangedlevel = TRUE;
1265                 return TRUE;
1266         }
1267         return FALSE;
1268 };
1269
1270 void GotoNextMap()
1271 {
1272         //local string nextmap;
1273         //local float n, nummaps;
1274         //local string s;
1275         if (alreadychangedlevel)
1276                 return;
1277         alreadychangedlevel = TRUE;
1278
1279         {
1280                 string nextMap;
1281                 float allowReset;
1282
1283                 for(allowReset = 1; allowReset >= 0; --allowReset)
1284                 {
1285                         nextMap = GetNextMap();
1286                         if(nextMap != "")
1287                                 break;
1288
1289                         if(allowReset)
1290                         {
1291                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1292                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1293                                 if(cvar("g_maplist_shuffle"))
1294                                         ShuffleMaplist();
1295                                 localcmd("\nmenu_cmd sync\n");
1296                         }
1297                         else
1298                         {
1299                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1300                         }
1301                 }
1302                 Map_Goto();
1303         }
1304 };
1305
1306
1307 /*
1308 ============
1309 IntermissionThink
1310
1311 When the player presses attack or jump, change to the next level
1312 ============
1313 */
1314 .float autoscreenshot;
1315 void() MapVote_Start;
1316 void() MapVote_Think;
1317 float mapvote_initialized;
1318 void IntermissionThink()
1319 {
1320         FixIntermissionClient(self);
1321
1322         if(cvar("sv_autoscreenshot"))
1323         if(self.autoscreenshot > 0)
1324         if(time > self.autoscreenshot)
1325         {
1326                 self.autoscreenshot = -1;
1327                 if(clienttype(self) == CLIENTTYPE_REAL)
1328                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1329                 return;
1330         }
1331
1332         if (time < intermission_exittime)
1333                 return;
1334
1335         if(!mapvote_initialized)
1336                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1337                         return;
1338
1339         MapVote_Start();
1340 };
1341
1342 /*
1343 ============
1344 FindIntermission
1345
1346 Returns the entity to view from
1347 ============
1348 */
1349 /*
1350 entity FindIntermission()
1351 {
1352         local   entity spot;
1353         local   float cyc;
1354
1355 // look for info_intermission first
1356         spot = find (world, classname, "info_intermission");
1357         if (spot)
1358         {       // pick a random one
1359                 cyc = random() * 4;
1360                 while (cyc > 1)
1361                 {
1362                         spot = find (spot, classname, "info_intermission");
1363                         if (!spot)
1364                                 spot = find (spot, classname, "info_intermission");
1365                         cyc = cyc - 1;
1366                 }
1367                 return spot;
1368         }
1369
1370 // then look for the start position
1371         spot = find (world, classname, "info_player_start");
1372         if (spot)
1373                 return spot;
1374
1375 // testinfo_player_start is only found in regioned levels
1376         spot = find (world, classname, "testplayerstart");
1377         if (spot)
1378                 return spot;
1379
1380 // then look for the start position
1381         spot = find (world, classname, "info_player_deathmatch");
1382         if (spot)
1383                 return spot;
1384
1385         //objerror ("FindIntermission: no spot");
1386         return world;
1387 };
1388 */
1389
1390 /*
1391 ===============================================================================
1392
1393 RULES
1394
1395 ===============================================================================
1396 */
1397
1398 void DumpStats(float final)
1399 {
1400         local float file;
1401         local string s;
1402         local float to_console;
1403         local float to_eventlog;
1404         local float to_file;
1405         local float i;
1406
1407         to_console = cvar("sv_logscores_console");
1408         to_eventlog = cvar("sv_eventlog");
1409         to_file = cvar("sv_logscores_file");
1410
1411         if(!final)
1412         {
1413                 to_console = TRUE; // always print printstats replies
1414                 to_eventlog = FALSE; // but never print them to the event log
1415         }
1416
1417         if(to_eventlog)
1418                 if(cvar("sv_eventlog_console"))
1419                         to_console = FALSE; // otherwise we get the output twice
1420
1421         if(final)
1422                 s = ":scores:";
1423         else
1424                 s = ":status:";
1425         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1426
1427         if(to_console)
1428                 print(s, "\n");
1429         if(to_eventlog)
1430                 GameLogEcho(s);
1431         if(to_file)
1432         {
1433                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1434                 if(file == -1)
1435                         to_file = FALSE;
1436                 else
1437                         fputs(file, strcat(s, "\n"));
1438         }
1439
1440         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1441         if(to_console)
1442                 print(s, "\n");
1443         if(to_eventlog)
1444                 GameLogEcho(s);
1445         if(to_file)
1446                 fputs(file, strcat(s, "\n"));
1447
1448         FOR_EACH_CLIENT(other)
1449         {
1450                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1451                 {
1452                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1453                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1454                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1455                                 s = strcat(s, ftos(other.team), ":");
1456                         else
1457                                 s = strcat(s, "spectator:");
1458
1459                         if(to_console)
1460                                 print(s, other.netname, "\n");
1461                         if(to_eventlog)
1462                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1463                         if(to_file)
1464                                 fputs(file, strcat(s, other.netname, "\n"));
1465                 }
1466         }
1467
1468         if(teams_matter)
1469         {
1470                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1471                 if(to_console)
1472                         print(s, "\n");
1473                 if(to_eventlog)
1474                         GameLogEcho(s);
1475                 if(to_file)
1476                         fputs(file, strcat(s, "\n"));
1477
1478                 for(i = 1; i < 16; ++i)
1479                 {
1480                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1481                         s = strcat(s, ":", ftos(i));
1482                         if(to_console)
1483                                 print(s, "\n");
1484                         if(to_eventlog)
1485                                 GameLogEcho(s);
1486                         if(to_file)
1487                                 fputs(file, strcat(s, "\n"));
1488                 }
1489         }
1490
1491         if(to_console)
1492                 print(":end\n");
1493         if(to_eventlog)
1494                 GameLogEcho(":end");
1495         if(to_file)
1496         {
1497                 fputs(file, ":end\n");
1498                 fclose(file);
1499         }
1500 }
1501
1502 void FixIntermissionClient(entity e)
1503 {
1504         string s;
1505         if(!e.autoscreenshot) // initial call
1506         {
1507                 e.angles = e.v_angle;
1508                 e.angles_x = -e.angles_x;
1509                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1510                 e.health = -2342;
1511                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1512                 e.solid = SOLID_NOT;
1513                 e.movetype = MOVETYPE_NONE;
1514                 e.takedamage = DAMAGE_NO;
1515                 if(e.weaponentity)
1516                 {
1517                         e.weaponentity.effects = EF_NODRAW;
1518                         if (e.weaponentity.weaponentity)
1519                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1520                 }
1521                 if(clienttype(e) == CLIENTTYPE_REAL)
1522                 {
1523                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1524                         s = cvar_string("sv_intermission_cdtrack");
1525                         if(s != "")
1526                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1527                         msg_entity = e;
1528                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1529                 }
1530         }
1531
1532         //e.velocity = '0 0 0';
1533         //e.fixangle = TRUE;
1534
1535         // TODO halt weapon animation
1536 }
1537
1538
1539 /*
1540 go to the next level for deathmatch
1541 only called if a time or frag limit has expired
1542 */
1543 void NextLevel()
1544 {
1545         gameover = TRUE;
1546
1547         intermission_running = 1;
1548
1549 // enforce a wait time before allowing changelevel
1550         if(player_count > 0)
1551                 intermission_exittime = time + cvar("sv_mapchange_delay");
1552         else
1553                 intermission_exittime = -1;
1554
1555         /*
1556         WriteByte (MSG_ALL, SVC_CDTRACK);
1557         WriteByte (MSG_ALL, 3);
1558         WriteByte (MSG_ALL, 3);
1559         // done in FixIntermission
1560         */
1561
1562         //pos = FindIntermission ();
1563
1564         VoteReset();
1565
1566         DumpStats(TRUE);
1567
1568         if(cvar("sv_eventlog"))
1569                 GameLogEcho(":gameover");
1570
1571         GameLogClose();
1572
1573         FOR_EACH_PLAYER(other) {
1574                 FixIntermissionClient(other);
1575                 if(other.winning)
1576                         bprint(other.netname, " ^7wins.\n");
1577         }
1578
1579         if(cvar("g_campaign"))
1580                 CampaignPreIntermission();
1581
1582         localcmd("\nsv_hook_gameend\n");
1583 }
1584
1585 /*
1586 ============
1587 CheckRules_Player
1588
1589 Exit deathmatch games upon conditions
1590 ============
1591 */
1592 void CheckRules_Player()
1593 {
1594         if (gameover)   // someone else quit the game already
1595                 return;
1596
1597         if(self.deadflag == DEAD_NO)
1598                 self.play_time += frametime;
1599
1600         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1601         //   (div0: and that in CheckRules_World please)
1602 };
1603
1604 float checkrules_equality;
1605 float checkrules_suddendeathwarning;
1606 float checkrules_suddendeathend;
1607 float checkrules_overtimesadded; //how many overtimes have been already added
1608
1609 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1610 float WINNING_YES = 1; // winner found
1611 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1612 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1613
1614 float InitiateSuddenDeath()
1615 {
1616         // Check first whether normal overtimes could be added before initiating suddendeath mode
1617         // - for this timelimit_overtime needs to be >0 of course
1618         // - also check the winning condition calculated in the previous frame and only add normal overtime
1619         //   again, if at the point at which timelimit would be extended again, still no winner was found
1620         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1621         {
1622                 return 1; // need to call InitiateOvertime later
1623         }
1624         else
1625         {
1626                 if(!checkrules_suddendeathend)
1627                 {
1628                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1629                         if(g_race && !g_race_qualifying)
1630                                 race_StartCompleting();
1631                 }
1632                 return 0;
1633         }
1634 }
1635
1636 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1637 {
1638         ++checkrules_overtimesadded;
1639         //add one more overtime by simply extending the timelimit
1640         float tl;
1641         tl = cvar("timelimit");
1642         tl += cvar("timelimit_overtime");
1643         cvar_set("timelimit", ftos(tl));
1644         string minutesPlural;
1645         if (cvar("timelimit_overtime") == 1)
1646                 minutesPlural = " ^3minute";
1647         else
1648                 minutesPlural = " ^3minutes";
1649
1650         bcenterprint(
1651                 strcat(
1652                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1653                         ftos(cvar("timelimit_overtime")),
1654                         minutesPlural,
1655                         " to the game!"
1656                 )
1657         );
1658 }
1659
1660 float GetWinningCode(float fraglimitreached, float equality)
1661 {
1662         if(cvar("g_campaign") == 1)
1663                 if(fraglimitreached)
1664                         return WINNING_YES;
1665                 else
1666                         return WINNING_NO;
1667
1668         else
1669                 if(equality)
1670                         if(fraglimitreached)
1671                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1672                         else
1673                                 return WINNING_NEVER;
1674                 else
1675                         if(fraglimitreached)
1676                                 return WINNING_YES;
1677                         else
1678                                 return WINNING_NO;
1679 }
1680
1681 // set the .winning flag for exactly those players with a given field value
1682 void SetWinners(.float field, float value)
1683 {
1684         entity head;
1685         FOR_EACH_PLAYER(head)
1686                 head.winning = (head.field == value);
1687 }
1688
1689 // set the .winning flag for those players with a given field value
1690 void AddWinners(.float field, float value)
1691 {
1692         entity head;
1693         FOR_EACH_PLAYER(head)
1694                 if(head.field == value)
1695                         head.winning = 1;
1696 }
1697
1698 // clear the .winning flags
1699 void ClearWinners(void)
1700 {
1701         entity head;
1702         FOR_EACH_PLAYER(head)
1703                 head.winning = 0;
1704 }
1705
1706 // Onslaught winning condition:
1707 // game terminates if only one team has a working generator (or none)
1708 float WinningCondition_Onslaught()
1709 {
1710         entity head;
1711         local float t1, t2, t3, t4;
1712
1713         WinningConditionHelper(); // set worldstatus
1714
1715         if(inWarmupStage)
1716                 return WINNING_NO;
1717
1718         // first check if the game has ended
1719         t1 = t2 = t3 = t4 = 0;
1720         head = find(world, classname, "onslaught_generator");
1721         while (head)
1722         {
1723                 if (head.health > 0)
1724                 {
1725                         if (head.team == COLOR_TEAM1) t1 = 1;
1726                         if (head.team == COLOR_TEAM2) t2 = 1;
1727                         if (head.team == COLOR_TEAM3) t3 = 1;
1728                         if (head.team == COLOR_TEAM4) t4 = 1;
1729                 }
1730                 head = find(head, classname, "onslaught_generator");
1731         }
1732         if (t1 + t2 + t3 + t4 < 2)
1733         {
1734                 // game over, only one team remains (or none)
1735                 ClearWinners();
1736                 if (t1) SetWinners(team, COLOR_TEAM1);
1737                 if (t2) SetWinners(team, COLOR_TEAM2);
1738                 if (t3) SetWinners(team, COLOR_TEAM3);
1739                 if (t4) SetWinners(team, COLOR_TEAM4);
1740                 dprint("Have a winner, ending game.\n");
1741                 return WINNING_YES;
1742         }
1743
1744         // Two or more teams remain
1745         return WINNING_NO;
1746 }
1747
1748 float LMS_NewPlayerLives()
1749 {
1750         float fl;
1751         fl = cvar("fraglimit");
1752         if(fl == 0)
1753                 fl = 999;
1754
1755         // first player has left the game for dying too much? Nobody else can get in.
1756         if(lms_lowest_lives < 1)
1757                 return 0;
1758
1759         if(!cvar("g_lms_join_anytime"))
1760                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1761                         return 0;
1762
1763         return bound(1, lms_lowest_lives, fl);
1764 }
1765
1766 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1767 // they win. Otherwise the defending team wins once the timelimit passes.
1768 void assault_new_round();
1769 float WinningCondition_Assault()
1770 {
1771         local float status;
1772
1773         WinningConditionHelper(); // set worldstatus
1774
1775         status = WINNING_NO;
1776         // as the timelimit has not yet passed just assume the defending team will win
1777         if(assault_attacker_team == COLOR_TEAM1)
1778         {
1779                 SetWinners(team, COLOR_TEAM2);
1780         }
1781         else
1782         {
1783                 SetWinners(team, COLOR_TEAM1);
1784         }
1785
1786         local entity ent;
1787         ent = find(world, classname, "target_assault_roundend");
1788         if(ent)
1789         {
1790                 if(ent.winning) // round end has been triggered by attacking team
1791                 {
1792                         bprint("ASSAULT: round completed...\n");
1793                         SetWinners(team, assault_attacker_team);
1794
1795                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1796
1797                         if(ent.cnt == 1 || cvar("g_campaign")) // this was the second round
1798                         {
1799                                 status = WINNING_YES;
1800                         }
1801                         else
1802                         {
1803                                 local entity oldself;
1804                                 oldself = self;
1805                                 self = ent;
1806                                 assault_new_round();
1807                                 self = oldself;
1808                         }
1809                 }
1810         }
1811
1812         return status;
1813 }
1814
1815 // LMS winning condition: game terminates if and only if there's at most one
1816 // one player who's living lives. Top two scores being equal cancels the time
1817 // limit.
1818 float WinningCondition_LMS()
1819 {
1820         entity head, head2;
1821         float have_player;
1822         float have_players;
1823         float l;
1824
1825         have_player = FALSE;
1826         have_players = FALSE;
1827         l = LMS_NewPlayerLives();
1828
1829         head = find(world, classname, "player");
1830         if(head)
1831                 have_player = TRUE;
1832         head2 = find(head, classname, "player");
1833         if(head2)
1834                 have_players = TRUE;
1835
1836         if(have_player)
1837         {
1838                 // we have at least one player
1839                 if(have_players)
1840                 {
1841                         // two or more active players - continue with the game
1842                 }
1843                 else
1844                 {
1845                         // exactly one player?
1846
1847                         ClearWinners();
1848                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1849
1850                         if(l)
1851                         {
1852                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1853                                 return WINNING_NO;
1854                         }
1855                         else
1856                         {
1857                                 // a winner!
1858                                 // and assign him his first place
1859                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1860                                 return WINNING_YES;
1861                         }
1862                 }
1863         }
1864         else
1865         {
1866                 // nobody is playing at all...
1867                 if(l)
1868                 {
1869                         // wait for players...
1870                 }
1871                 else
1872                 {
1873                         // SNAFU (maybe a draw game?)
1874                         ClearWinners();
1875                         dprint("No players, ending game.\n");
1876                         return WINNING_YES;
1877                 }
1878         }
1879
1880         // When we get here, we have at least two players who are actually LIVING,
1881         // now check if the top two players have equal score.
1882         WinningConditionHelper();
1883
1884         ClearWinners();
1885         if(WinningConditionHelper_winner)
1886                 WinningConditionHelper_winner.winning = TRUE;
1887         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1888                 return WINNING_NEVER;
1889
1890         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1891         return WINNING_NO;
1892 }
1893
1894 void ShuffleMaplist()
1895 {
1896         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1897 }
1898
1899 float leaderfrags;
1900 float WinningCondition_Scores(float limit, float leadlimit)
1901 {
1902         float limitreached;
1903
1904         // TODO make everything use THIS winning condition (except LMS)
1905         WinningConditionHelper();
1906
1907         if(teams_matter)
1908         {
1909                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1910                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1911                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1912                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1913         }
1914
1915         ClearWinners();
1916         if(WinningConditionHelper_winner)
1917                 WinningConditionHelper_winner.winning = 1;
1918         if(WinningConditionHelper_winnerteam >= 0)
1919                 SetWinners(team, WinningConditionHelper_winnerteam);
1920
1921         if(WinningConditionHelper_lowerisbetter)
1922         {
1923                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1924                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1925                 limit = -limit;
1926         }
1927
1928         if(WinningConditionHelper_zeroisworst)
1929                 leadlimit = 0; // not supported in this mode
1930
1931         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1932         // these modes always score in increments of 1, thus this makes sense
1933         {
1934                 if(leaderfrags != WinningConditionHelper_topscore)
1935                 {
1936                         leaderfrags = WinningConditionHelper_topscore;
1937
1938                         if (limit)
1939                         if (leaderfrags == limit - 1)
1940                                 Announce("1fragleft");
1941                         else if (leaderfrags == limit - 2)
1942                                 Announce("2fragsleft");
1943                         else if (leaderfrags == limit - 3)
1944                                 Announce("3fragsleft");
1945                 }
1946         }
1947
1948         limitreached = FALSE;
1949         if(limit)
1950                 if(WinningConditionHelper_topscore >= limit)
1951                         limitreached = TRUE;
1952         if(leadlimit)
1953         {
1954                 float leadlimitreached;
1955                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1956                 if(cvar("leadlimit_and_fraglimit"))
1957                         limitreached = (limitreached && leadlimitreached);
1958                 else
1959                         limitreached = (limitreached || leadlimitreached);
1960         }
1961
1962         return GetWinningCode(
1963                 WinningConditionHelper_topscore && limitreached,
1964                 WinningConditionHelper_equality
1965         );
1966 }
1967
1968 float WinningCondition_Race(float fraglimit)
1969 {
1970         float wc;
1971         entity p;
1972         float n, c;
1973
1974         n = 0;
1975         c = 0;
1976         FOR_EACH_PLAYER(p)
1977         {
1978                 ++n;
1979                 if(p.race_completed)
1980                         ++c;
1981         }
1982         if(n && (n == c))
1983                 return WINNING_YES;
1984         wc = WinningCondition_Scores(fraglimit, 0);
1985
1986         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1987         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1988         // do NOT support equality when the laps are all raced!
1989                 return WINNING_STARTSUDDENDEATHOVERTIME;
1990         else
1991                 return WINNING_NEVER;
1992         return wc;
1993 }
1994
1995 void ReadyRestart();
1996 float WinningCondition_QualifyingThenRace(float limit)
1997 {
1998         float wc;
1999         wc = WinningCondition_Scores(limit, 0);
2000
2001         // NEVER initiate overtime
2002         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2003         {
2004                 return WINNING_YES;
2005         }
2006
2007         return wc;
2008 }
2009
2010 float WinningCondition_RanOutOfSpawns()
2011 {
2012         entity head;
2013
2014         if(have_team_spawns <= 0)
2015                 return WINNING_NO;
2016
2017         if(!some_spawn_has_been_used)
2018                 return WINNING_NO;
2019
2020         team1_score = team2_score = team3_score = team4_score = 0;
2021
2022         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2023         {
2024                 if(head.team == COLOR_TEAM1)
2025                         team1_score = 1;
2026                 else if(head.team == COLOR_TEAM2)
2027                         team2_score = 1;
2028                 else if(head.team == COLOR_TEAM3)
2029                         team3_score = 1;
2030                 else if(head.team == COLOR_TEAM4)
2031                         team4_score = 1;
2032         }
2033
2034         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2035         {
2036                 if(head.team == COLOR_TEAM1)
2037                         team1_score = 1;
2038                 else if(head.team == COLOR_TEAM2)
2039                         team2_score = 1;
2040                 else if(head.team == COLOR_TEAM3)
2041                         team3_score = 1;
2042                 else if(head.team == COLOR_TEAM4)
2043                         team4_score = 1;
2044         }
2045
2046         ClearWinners();
2047         if(team1_score + team2_score + team3_score + team4_score == 0)
2048         {
2049                 checkrules_equality = TRUE;
2050                 return WINNING_YES;
2051         }
2052         else if(team1_score + team2_score + team3_score + team4_score == 1)
2053         {
2054                 float t, i;
2055                 if(team1_score) t = COLOR_TEAM1;
2056                 if(team2_score) t = COLOR_TEAM2;
2057                 if(team3_score) t = COLOR_TEAM3;
2058                 if(team4_score) t = COLOR_TEAM4;
2059                 CheckAllowedTeams(world);
2060                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2061                 {
2062                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2063                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2064                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2065                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2066                 }
2067
2068                 AddWinners(team, t);
2069                 return WINNING_YES;
2070         }
2071         else
2072                 return WINNING_NO;
2073 }
2074
2075 /*
2076 ============
2077 CheckRules_World
2078
2079 Exit deathmatch games upon conditions
2080 ============
2081 */
2082 void CheckRules_World()
2083 {
2084         float timelimit;
2085         float fraglimit;
2086         float leadlimit;
2087
2088         VoteThink();
2089         MapVote_Think();
2090
2091         SetDefaultAlpha();
2092
2093         /*
2094         MapVote_Think should now do that part
2095         if (intermission_running)
2096                 if (time >= intermission_exittime + 60)
2097                 {
2098                         if(!DoNextMapOverride())
2099                                 GotoNextMap();
2100                         return;
2101                 }
2102         */
2103
2104         if (gameover)   // someone else quit the game already
2105         {
2106                 if(player_count == 0) // Nobody there? Then let's go to the next map
2107                         MapVote_Start();
2108                         // this will actually check the player count in the next frame
2109                         // again, but this shouldn't hurt
2110                 return;
2111         }
2112
2113         timelimit = cvar("timelimit") * 60;
2114         fraglimit = cvar("fraglimit");
2115         leadlimit = cvar("leadlimit");
2116
2117         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2118         {
2119                 if(timelimit > 0)
2120                         timelimit = 0; // timelimit is not made for warmup
2121                 if(fraglimit > 0)
2122                         fraglimit = 0; // no fraglimit for now
2123                 leadlimit = 0; // no leadlimit for now
2124         }
2125
2126         if(g_onslaught)
2127                 timelimit = 0; // ONS has its own overtime rule
2128
2129         if(timelimit > 0)
2130         {
2131                 timelimit += game_starttime;
2132         }
2133         else if (timelimit < 0)
2134         {
2135                 // endmatch
2136                 NextLevel();
2137                 return;
2138         }
2139
2140         float wantovertime;
2141         wantovertime = 0;
2142
2143         if(checkrules_suddendeathend)
2144         {
2145                 if(!checkrules_suddendeathwarning)
2146                 {
2147                         checkrules_suddendeathwarning = TRUE;
2148                         if(g_race && !g_race_qualifying)
2149                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2150                         else
2151                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2152                 }
2153         }
2154         else
2155         {
2156                 if (timelimit && time >= timelimit)
2157                 {
2158                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2159                         {
2160                                 float totalplayers;
2161                                 float playerswithlaps;
2162                                 float readyplayers;
2163                                 entity head;
2164                                 totalplayers = playerswithlaps = readyplayers = 0;
2165                                 FOR_EACH_PLAYER(head)
2166                                 {
2167                                         ++totalplayers;
2168                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2169                                                 ++playerswithlaps;
2170                                         if(head.ready)
2171                                                 ++readyplayers;
2172                                 }
2173
2174                                 // at least 2 of the players have completed a lap: start the RACE
2175                                 // otherwise, the players should end the qualifying on their own
2176                                 if(readyplayers || playerswithlaps >= 2)
2177                                 {
2178                                         checkrules_suddendeathend = 0;
2179                                         ReadyRestart(); // go to race
2180                                         return;
2181                                 }
2182                                 else
2183                                         wantovertime |= InitiateSuddenDeath();
2184                         }
2185                         else
2186                                 wantovertime |= InitiateSuddenDeath();
2187                 }
2188         }
2189
2190         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2191         {
2192                 NextLevel();
2193                 return;
2194         }
2195
2196         float checkrules_status;
2197         checkrules_status = WinningCondition_RanOutOfSpawns();
2198         if(checkrules_status == WINNING_YES)
2199         {
2200                 bprint("Hey! Someone ran out of spawns!\n");
2201         }
2202         else if(g_race && !g_race_qualifying && timelimit >= 0)
2203         {
2204                 checkrules_status = WinningCondition_Race(fraglimit);
2205                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2206         }
2207         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2208         {
2209                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2210                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2211         }
2212         else if(g_assault)
2213         {
2214                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2215         }
2216         else if(g_lms)
2217         {
2218                 checkrules_status = WinningCondition_LMS();
2219         }
2220         else if (g_onslaught)
2221         {
2222                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2223         }
2224         else
2225         {
2226                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2227                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2228         }
2229
2230         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2231         {
2232                 checkrules_status = WINNING_NEVER;
2233                 checkrules_overtimesadded = -1;
2234                 wantovertime |= InitiateSuddenDeath();
2235         }
2236
2237         if(checkrules_status == WINNING_NEVER)
2238                 // equality cases! Nobody wins if the overtime ends in a draw.
2239                 ClearWinners();
2240
2241         if(wantovertime)
2242         {
2243                 if(checkrules_status == WINNING_NEVER)
2244                         InitiateOvertime();
2245                 else
2246                         checkrules_status = WINNING_YES;
2247         }
2248
2249         if(checkrules_suddendeathend)
2250                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2251                         checkrules_status = WINNING_YES;
2252
2253         if(checkrules_status == WINNING_YES)
2254         {
2255                 //print("WINNING\n");
2256                 NextLevel();
2257         }
2258 };
2259
2260 float mapvote_nextthink;
2261 float mapvote_initialized;
2262 float mapvote_keeptwotime;
2263 float mapvote_timeout;
2264 string mapvote_message;
2265 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2266 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2267 float mapvote_screenshot_dirs_count;
2268
2269 float mapvote_count;
2270 float mapvote_count_real;
2271 string mapvote_maps[MAPVOTE_COUNT];
2272 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2273 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2274 float mapvote_maps_suggested[MAPVOTE_COUNT];
2275 string mapvote_suggestions[MAPVOTE_COUNT];
2276 float mapvote_suggestion_ptr;
2277 float mapvote_maxlen;
2278 float mapvote_voters;
2279 float mapvote_votes[MAPVOTE_COUNT];
2280 float mapvote_run;
2281 float mapvote_detail;
2282 float mapvote_abstain;
2283 .float mapvote;
2284
2285 void MapVote_ClearAllVotes()
2286 {
2287         FOR_EACH_CLIENT(other)
2288                 other.mapvote = 0;
2289 }
2290
2291 string MapVote_Suggest(string m)
2292 {
2293         float i;
2294         if(m == "")
2295                 return "That's not how to use this command.";
2296         if(!cvar("g_maplist_votable_suggestions"))
2297                 return "Suggestions are not accepted on this server.";
2298         if(mapvote_initialized)
2299                 return "Can't suggest - voting is already in progress!";
2300         m = MapInfo_FixName(m);
2301         if(!m)
2302                 return "The map you suggested is not available on this server.";
2303         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2304                 if(Map_IsRecent(m))
2305                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2306
2307         if(!MapInfo_CheckMap(m))
2308                 return "The map you suggested does not support the current game mode.";
2309         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2310                 if(mapvote_suggestions[i] == m)
2311                         return "This map was already suggested.";
2312         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2313         {
2314                 i = floor(random() * mapvote_suggestion_ptr);
2315         }
2316         else
2317         {
2318                 i = mapvote_suggestion_ptr;
2319                 mapvote_suggestion_ptr += 1;
2320         }
2321         if(mapvote_suggestions[i] != "")
2322                 strunzone(mapvote_suggestions[i]);
2323         mapvote_suggestions[i] = strzone(m);
2324         if(cvar("sv_eventlog"))
2325                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2326         return strcat("Suggestion of ", m, " accepted.");
2327 }
2328
2329 void MapVote_AddVotable(string nextMap, float isSuggestion)
2330 {
2331         float j, i, o;
2332         string pakfile, mapfile;
2333
2334         if(nextMap == "")
2335                 return;
2336         for(j = 0; j < mapvote_count; ++j)
2337                 if(mapvote_maps[j] == nextMap)
2338                         return;
2339         if(strlen(nextMap) > mapvote_maxlen)
2340                 mapvote_maxlen = strlen(nextMap);
2341         mapvote_maps[mapvote_count] = strzone(nextMap);
2342         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2343
2344         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2345         {
2346                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2347                 pakfile = whichpack(strcat(mapfile, ".tga"));
2348                 if(pakfile == "")
2349                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2350                 if(pakfile == "")
2351                         pakfile = whichpack(strcat(mapfile, ".png"));
2352                 if(pakfile != "")
2353                         break;
2354         }
2355         if(i >= mapvote_screenshot_dirs_count)
2356                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2357         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2358                 pakfile = substring(pakfile, o, -1);
2359
2360         mapvote_maps_screenshot_dir[mapvote_count] = i;
2361         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2362
2363         mapvote_count += 1;
2364 }
2365
2366 void MapVote_Spawn();
2367 void MapVote_Init()
2368 {
2369         float i;
2370         float nmax, smax;
2371
2372         MapVote_ClearAllVotes();
2373
2374         mapvote_count = 0;
2375         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2376         mapvote_abstain = cvar("g_maplist_votable_abstain");
2377
2378         if(mapvote_abstain)
2379                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2380         else
2381                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2382         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2383
2384         // we need this for AddVotable, as that cycles through the screenshot dirs
2385         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2386         if(mapvote_screenshot_dirs_count == 0)
2387                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2388         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2389         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2390                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2391
2392         if(mapvote_suggestion_ptr)
2393                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2394                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2395
2396         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2397                 MapVote_AddVotable(GetNextMap(), FALSE);
2398
2399         if(mapvote_count == 0)
2400         {
2401                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2402                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2403                 if(cvar("g_maplist_shuffle"))
2404                         ShuffleMaplist();
2405                 localcmd("\nmenu_cmd sync\n");
2406                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2407                         MapVote_AddVotable(GetNextMap(), FALSE);
2408         }
2409
2410         mapvote_count_real = mapvote_count;
2411         if(mapvote_abstain)
2412                 MapVote_AddVotable("don't care", 0);
2413
2414         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2415
2416         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2417         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2418         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2419                 mapvote_keeptwotime = 0;
2420         mapvote_message = "Choose a map and press its key!";
2421
2422         MapVote_Spawn();
2423 }
2424
2425 void MapVote_SendPicture(float id)
2426 {
2427         msg_entity = self;
2428         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2429         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2430         WriteByte(MSG_ONE, id);
2431         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2432 }
2433
2434 float GameCommand_MapVote(string cmd)
2435 {
2436         if(!intermission_running)
2437                 return FALSE;
2438
2439         if(cmd == "mv_getpic")
2440         {
2441                 MapVote_SendPicture(stof(argv(1)));
2442                 return TRUE;
2443         }
2444
2445         return FALSE;
2446 }
2447
2448 float MapVote_GetMapMask()
2449 {
2450         float mask, i, power;
2451         mask = 0;
2452         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2453                 if(mapvote_maps[i] != "")
2454                         mask |= power;
2455         return mask;
2456 }
2457
2458 entity mapvote_ent;
2459 float MapVote_SendEntity(entity to, float sf)
2460 {
2461         float i;
2462
2463         if(sf & 1)
2464                 sf &~= 2; // if we send 1, we don't need to also send 2
2465
2466         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2467         WriteByte(MSG_ENTITY, sf);
2468
2469         if(sf & 1)
2470         {
2471                 // flag 1 == initialization
2472                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2473                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2474                 WriteString(MSG_ENTITY, "");
2475                 WriteByte(MSG_ENTITY, mapvote_count);
2476                 WriteByte(MSG_ENTITY, mapvote_abstain);
2477                 WriteByte(MSG_ENTITY, mapvote_detail);
2478                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2479                 if(mapvote_count <= 8)
2480                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2481                 else
2482                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2483                 for(i = 0; i < mapvote_count; ++i)
2484                         if(mapvote_maps[i] != "")
2485                         {
2486                                 if(mapvote_abstain && i == mapvote_count - 1)
2487                                 {
2488                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2489                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2490                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2491                                 }
2492                                 else
2493                                 {
2494                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2495                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2496                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2497                                 }
2498                         }
2499         }
2500
2501         if(sf & 2)
2502         {
2503                 // flag 2 == update of mask
2504                 if(mapvote_count <= 8)
2505                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2506                 else
2507                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2508         }
2509
2510         if(sf & 4)
2511         {
2512                 if(mapvote_detail)
2513                         for(i = 0; i < mapvote_count; ++i)
2514                                 if(mapvote_maps[i] != "")
2515                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2516
2517                 WriteByte(MSG_ENTITY, to.mapvote);
2518         }
2519
2520         return TRUE;
2521 }
2522
2523 void MapVote_Spawn()
2524 {
2525         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2526 }
2527
2528 void MapVote_TouchMask()
2529 {
2530         mapvote_ent.SendFlags |= 2;
2531 }
2532
2533 void MapVote_TouchVotes(entity voter)
2534 {
2535         mapvote_ent.SendFlags |= 4;
2536 }
2537
2538 float MapVote_Finished(float mappos)
2539 {
2540         string result;
2541         float i;
2542         float didntvote;
2543
2544         if(cvar("sv_eventlog"))
2545         {
2546                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2547                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2548                 didntvote = mapvote_voters;
2549                 for(i = 0; i < mapvote_count; ++i)
2550                         if(mapvote_maps[i] != "")
2551                         {
2552                                 didntvote -= mapvote_votes[i];
2553                                 if(i != mappos)
2554                                 {
2555                                         result = strcat(result, ":", mapvote_maps[i]);
2556                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2557                                 }
2558                         }
2559                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2560
2561                 GameLogEcho(result);
2562                 if(mapvote_maps_suggested[mappos])
2563                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2564         }
2565
2566         FOR_EACH_REALCLIENT(other)
2567                 FixClientCvars(other);
2568
2569         Map_Goto_SetStr(mapvote_maps[mappos]);
2570         Map_Goto();
2571         alreadychangedlevel = TRUE;
2572         return TRUE;
2573 }
2574 void MapVote_CheckRules_1()
2575 {
2576         float i;
2577
2578         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2579         {
2580                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2581                 mapvote_votes[i] = 0;
2582         }
2583
2584         mapvote_voters = 0;
2585         FOR_EACH_REALCLIENT(other)
2586         {
2587                 ++mapvote_voters;
2588                 if(other.mapvote)
2589                 {
2590                         i = other.mapvote - 1;
2591                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2592                         mapvote_votes[i] = mapvote_votes[i] + 1;
2593                 }
2594         }
2595 }
2596
2597 float MapVote_CheckRules_2()
2598 {
2599         float i;
2600         float firstPlace, secondPlace;
2601         float firstPlaceVotes, secondPlaceVotes;
2602         float mapvote_voters_real;
2603         string result;
2604
2605         if(mapvote_count_real == 1)
2606                 return MapVote_Finished(0);
2607
2608         mapvote_voters_real = mapvote_voters;
2609         if(mapvote_abstain)
2610                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2611
2612         RandomSelection_Init();
2613         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2614                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2615         firstPlace = RandomSelection_chosen_float;
2616         firstPlaceVotes = RandomSelection_best_priority;
2617         //dprint("First place: ", ftos(firstPlace), "\n");
2618         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2619
2620         RandomSelection_Init();
2621         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2622                 if(i != firstPlace)
2623                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2624         secondPlace = RandomSelection_chosen_float;
2625         secondPlaceVotes = RandomSelection_best_priority;
2626         //dprint("Second place: ", ftos(secondPlace), "\n");
2627         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2628
2629         if(firstPlace == -1)
2630                 error("No first place in map vote... WTF?");
2631
2632         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2633                 return MapVote_Finished(firstPlace);
2634
2635         if(mapvote_keeptwotime)
2636                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2637                 {
2638                         float didntvote;
2639                         MapVote_TouchMask();
2640                         mapvote_message = "Now decide between the TOP TWO!";
2641                         mapvote_keeptwotime = 0;
2642                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2643                         result = strcat(result, ":", ftos(firstPlaceVotes));
2644                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2645                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2646                         didntvote = mapvote_voters;
2647                         for(i = 0; i < mapvote_count; ++i)
2648                                 if(mapvote_maps[i] != "")
2649                                 {
2650                                         didntvote -= mapvote_votes[i];
2651                                         if(i != firstPlace)
2652                                                 if(i != secondPlace)
2653                                                 {
2654                                                         result = strcat(result, ":", mapvote_maps[i]);
2655                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2656                                                         if(i < mapvote_count_real)
2657                                                         {
2658                                                                 strunzone(mapvote_maps[i]);
2659                                                                 mapvote_maps[i] = "";
2660                                                                 strunzone(mapvote_maps_pakfile[i]);
2661                                                                 mapvote_maps_pakfile[i] = "";
2662                                                         }
2663                                                 }
2664                                 }
2665                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2666                         if(cvar("sv_eventlog"))
2667                                 GameLogEcho(result);
2668                 }
2669
2670         return FALSE;
2671 }
2672 void MapVote_Tick()
2673 {
2674         float keeptwo;
2675         float totalvotes;
2676
2677         keeptwo = mapvote_keeptwotime;
2678         MapVote_CheckRules_1(); // count
2679         if(MapVote_CheckRules_2()) // decide
2680                 return;
2681
2682         totalvotes = 0;
2683         FOR_EACH_REALCLIENT(other)
2684         {
2685                 // hide scoreboard again
2686                 if(other.health != 2342)
2687                 {
2688                         other.health = 2342;
2689                         other.impulse = 0;
2690                         if(clienttype(other) == CLIENTTYPE_REAL)
2691                         {
2692                                 msg_entity = other;
2693                                 WriteByte(MSG_ONE, SVC_FINALE);
2694                                 WriteString(MSG_ONE, "");
2695                         }
2696                 }
2697
2698                 // clear possibly invalid votes
2699                 if(mapvote_maps[other.mapvote - 1] == "")
2700                         other.mapvote = 0;
2701                 // use impulses as new vote
2702                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2703                         if(mapvote_maps[other.impulse - 1] != "")
2704                         {
2705                                 other.mapvote = other.impulse;
2706                                 MapVote_TouchVotes(other);
2707                         }
2708                 other.impulse = 0;
2709
2710                 if(other.mapvote)
2711                         ++totalvotes;
2712         }
2713
2714         MapVote_CheckRules_1(); // just count
2715 }
2716 void MapVote_Start()
2717 {
2718         if(mapvote_run)
2719                 return;
2720
2721         MapInfo_Enumerate();
2722         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2723                 mapvote_run = TRUE;
2724 }
2725 void MapVote_Think()
2726 {
2727         if(!mapvote_run)
2728                 return;
2729
2730         if(alreadychangedlevel)
2731                 return;
2732
2733         if(time < mapvote_nextthink)
2734                 return;
2735         //dprint("tick\n");
2736
2737         mapvote_nextthink = time + 0.5;
2738
2739         if(!mapvote_initialized)
2740         {
2741                 if(cvar("rescan_pending") == 1)
2742                 {
2743                         cvar_set("rescan_pending", "2");
2744                         localcmd("fs_rescan\nrescan_pending 3\n");
2745                         return;
2746                 }
2747                 else if(cvar("rescan_pending") == 2)
2748                 {
2749                         return;
2750                 }
2751                 else if(cvar("rescan_pending") == 3)
2752                 {
2753                         // now build missing mapinfo files
2754                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2755                                 return;
2756
2757                         // we're done, start the timer
2758                         cvar_set("rescan_pending", "0");
2759                 }
2760
2761                 mapvote_initialized = TRUE;
2762                 if(DoNextMapOverride())
2763                         return;
2764                 if(!cvar("g_maplist_votable") || player_count <= 0)
2765                 {
2766                         GotoNextMap();
2767                         return;
2768                 }
2769                 MapVote_Init();
2770         }
2771
2772         MapVote_Tick();
2773 };
2774
2775 string GotoMap(string m)
2776 {
2777         if(!MapInfo_CheckMap(m))
2778                 return "The map you chose is not available on this server.";
2779         cvar_set("nextmap", m);
2780         cvar_set("timelimit", "-1");
2781         if(mapvote_initialized || alreadychangedlevel)
2782         {
2783                 if(DoNextMapOverride())
2784                         return "Map switch initiated.";
2785                 else
2786                         return "Hm... no. For some reason I like THIS map more.";
2787         }
2788         else
2789                 return "Map switch will happen after scoreboard.";
2790 }
2791
2792
2793 void EndFrame()
2794 {
2795         float altime;
2796         FOR_EACH_REALCLIENT(self)
2797         {
2798                 if(self.classname == "spectator")
2799                 {
2800                         if(self.enemy.typehitsound)
2801                                 play2(self, "misc/typehit.wav");
2802                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2803                                 play2(self, "misc/hit.wav");
2804                 }
2805                 else
2806                 {
2807                         if(self.typehitsound)
2808                                 play2(self, "misc/typehit.wav");
2809                         else if(self.hitsound && self.cvar_cl_hitsound)
2810                                 play2(self, "misc/hit.wav");
2811                 }
2812         }
2813         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2814         // add 1 frametime because after this, engine SV_Physics
2815         // increases time by a frametime and then networks the frame
2816         // add another frametime because client shows everything with
2817         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2818         // needed!
2819         FOR_EACH_CLIENT(self)
2820         {
2821                 self.hitsound = FALSE;
2822                 self.typehitsound = FALSE;
2823                 antilag_record(self, altime);
2824         }
2825 }
2826
2827
2828 /*
2829  * RedirectionThink:
2830  * returns TRUE if redirecting
2831  */
2832 float redirection_timeout;
2833 float redirection_nextthink;
2834 float RedirectionThink()
2835 {
2836         float clients_found;
2837
2838         if(redirection_target == "")
2839                 return FALSE;
2840
2841         if(!redirection_timeout)
2842         {
2843                 cvar_set("sv_public", "-2");
2844                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2845                 if(redirection_target == "self")
2846                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2847                 else
2848                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2849         }
2850
2851         if(time < redirection_nextthink)
2852                 return TRUE;
2853
2854         redirection_nextthink = time + 1;
2855
2856         clients_found = 0;
2857         FOR_EACH_REALCLIENT(self)
2858         {
2859                 print("Redirecting: sending connect command to ", self.netname, "\n");
2860                 if(redirection_target == "self")
2861                         stuffcmd(self, "\ndisconnect; reconnect\n");
2862                 else
2863                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2864                 ++clients_found;
2865         }
2866
2867         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2868
2869         if(time > redirection_timeout || clients_found == 0)
2870                 localcmd("\nwait; wait; wait; quit\n");
2871
2872         return TRUE;
2873 }
2874
2875 void TargetMusic_RestoreGame();
2876 void RestoreGame()
2877 {
2878         // Loaded from a save game
2879         // some things then break, so let's work around them...
2880
2881         // Progs DB (capture records)
2882         ServerProgsDB = db_load("server.db");
2883
2884         // Mapinfo
2885         MapInfo_Shutdown();
2886         MapInfo_Enumerate();
2887         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2888         WeaponStats_Init();
2889
2890         TargetMusic_RestoreGame();
2891 }
2892
2893 void SV_Shutdown()
2894 {
2895         if(gameover > 1) // shutting down already?
2896                 return;
2897
2898         gameover = 2; // 2 = server shutting down
2899
2900         if(world_initialized > 0)
2901         {
2902                 world_initialized = 0;
2903                 print("Saving persistent data...\n");
2904                 Ban_SaveBans();
2905                 if(!cheatcount_total)
2906                 {
2907                         if(cvar("sv_db_saveasdump"))
2908                                 db_dump(ServerProgsDB, "server.db");
2909                         else
2910                                 db_save(ServerProgsDB, "server.db");
2911                 }
2912                 if(cvar("developer"))
2913                 {
2914                         if(cvar("sv_db_saveasdump"))
2915                                 db_dump(TemporaryDB, "server-temp.db");
2916                         else
2917                                 db_save(TemporaryDB, "server-temp.db");
2918                 }
2919                 CheatShutdown(); // must be after cheatcount check
2920                 db_close(ServerProgsDB);
2921                 db_close(TemporaryDB);
2922                 print("done!\n");
2923                 // tell the bot system the game is ending now
2924                 bot_endgame();
2925
2926                 WeaponStats_Shutdown();
2927                 MapInfo_Shutdown();
2928         }
2929         else if(world_initialized == 0)
2930         {
2931                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2932         }
2933 }