qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(cvar("g_running_guns"))
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = cvar("g_player_alpha");
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!cvar("developer_fteqccbugs"))
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(cvar("_sv_init"))
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(cvar("g_maplist_shuffle"))
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADCVAR(p) if(k == p) continue
 239                 // internal
 240                 BADPREFIX("csqc_");
 241                 BADPREFIX("cvar_check_");
 242                 BADCVAR("gamecfg");
 243                 BADCVAR("g_configversion");
 244                 BADCVAR("g_maplist_index");
 245                 BADCVAR("halflifebsp");
 246                 BADPREFIX("sv_world");
 247
 248                 // client
 249                 BADPREFIX("chase_");
 250                 BADPREFIX("cl_");
 251                 BADPREFIX("con_");
 252                 BADPREFIX("scoreboard_");
 253                 BADPREFIX("g_campaign");
 254                 BADPREFIX("gl_");
 255                 BADPREFIX("joy");
 256                 BADPREFIX("hud_");
 257                 BADPREFIX("menu_");
 258                 BADPREFIX("net_slist_");
 259                 BADPREFIX("r_");
 260                 BADPREFIX("sbar_");
 261                 BADPREFIX("scr_");
 262                 BADPREFIX("snd_");
 263                 BADPREFIX("userbind");
 264                 BADPREFIX("v_");
 265                 BADPREFIX("vid_");
 266                 BADPREFIX("crosshair");
 267                 BADCVAR("mod_q3bsp_lightmapmergepower");
 268                 BADCVAR("mod_q3bsp_nolightmaps");
 269                 BADCVAR("fov");
 270                 BADCVAR("mastervolume");
 271                 BADCVAR("volume");
 272                 BADCVAR("bgmvolume");
 273
 274                 // private
 275                 BADCVAR("developer");
 276                 BADCVAR("g_banned_list");
 277                 BADCVAR("log_dest_udp");
 278                 BADCVAR("log_file");
 279                 BADCVAR("net_address");
 280                 BADCVAR("net_address_ipv6");
 281                 BADCVAR("port");
 282                 BADCVAR("savedgamecfg");
 283                 BADCVAR("serverconfig");
 284                 BADCVAR("sv_heartbeatperiod");
 285                 BADCVAR("sv_vote_master_password");
 286                 BADCVAR("sys_colortranslation");
 287                 BADCVAR("sys_specialcharactertranslation");
 288                 BADCVAR("timestamps");
 289                 BADPREFIX("developer_");
 290                 BADPREFIX("g_ban_");
 291                 BADPREFIX("g_chat_flood_");
 292                 BADPREFIX("g_voice_flood_");
 293                 BADPREFIX("rcon_");
 294                 BADPREFIX("settemp_");
 295                 BADPREFIX("sv_allowdownloads_");
 296                 BADPREFIX("sv_autodemo");
 297                 BADPREFIX("sv_curl_");
 298                 BADPREFIX("sv_eventlog");
 299                 BADPREFIX("sv_logscores_");
 300                 BADPREFIX("sv_master");
 301                 BADPREFIX("sv_weaponstats_");
 302
 303                 // these can contain player IDs, so better hide
 304                 BADCVAR("g_forced_team_red");
 305                 BADCVAR("g_forced_team_blue");
 306                 BADCVAR("g_forced_team_yellow");
 307                 BADCVAR("g_forced_team_pink");
 308
 309                 // mapinfo
 310                 BADCVAR("timelimit");
 311                 BADCVAR("fraglimit");
 312                 BADCVAR("leadlimit");
 313                 BADCVAR("g_tdm_teams");
 314                 BADCVAR("g_keyhunt_teams");
 315                 BADCVAR("g_domination_default_teams");
 316                 BADCVAR("g_race_qualifying_timelimit");
 317                 BADCVAR("g_lms");
 318                 BADCVAR("g_arena");
 319                 BADCVAR("g_ca");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ctf");
 322                 BADCVAR("g_dm");
 323                 BADCVAR("g_domination");
 324                 BADCVAR("g_keyhunt");
 325                 BADCVAR("g_keyhunt_teams");
 326                 BADCVAR("g_onslaught");
 327                 BADCVAR("g_race");
 328                 BADCVAR("g_cts");
 329                 BADCVAR("g_runematch");
 330                 BADCVAR("g_tdm");
 331                 BADCVAR("g_nexball");
 332                 BADCVAR("teamplay");
 333
 334                 // long
 335                 BADCVAR("hostname");
 336                 BADCVAR("g_maplist");
 337                 BADCVAR("g_maplist_mostrecent");
 338                 BADCVAR("sv_motd");
 339
 340                 v = cvar_string(k);
 341                 d = cvar_defstring(k);
 342                 if(v == d)
 343                         continue;
 344
 345                 if(adding)
 346                 {
 347                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 348                         if(strlen(cvar_changes) > 16384)
 349                         {
 350                                 cvar_changes = "// too many settings have been changed to show them here\n";
 351                                 adding = 0;
 352                         }
 353                 }
 354
 355                 // now check if the changes are actually gameplay relevant
 356
 357                 // does nothing visible
 358                 BADCVAR("captureleadlimit_override");
 359                 BADCVAR("g_arena_point_leadlimit");
 360                 BADCVAR("g_ca_point_leadlimit");
 361                 BADCVAR("g_ctf_capture_leadlimit");
 362                 BADCVAR("g_domination_point_leadlimit");
 363                 BADCVAR("g_keyhunt_point_leadlimit");
 364                 BADCVAR("g_nexball_goalleadlimit");
 365                 BADCVAR("g_runematch_point_leadlimit");
 366                 BADCVAR("leadlimit_and_fraglimit");
 367                 BADCVAR("leadlimit_override");
 368                 BADCVAR("sv_checkforpacketsduringsleep");
 369                 BADPREFIX("crypto_");
 370                 BADPREFIX("g_chat_");
 371                 BADPREFIX("net_");
 372                 BADPREFIX("prvm_");
 373                 BADPREFIX("sv_fragmessage_");
 374                 BADPREFIX("sv_vote_");
 375                 BADPREFIX("timelimit_");
 376
 377                 // allowed changes to server admins (please sync this to server.cfg)
 378                 // vi commands:
 379                 //   :/"impure"/,$d
 380                 //   :g!,^\/\/[^ /],d
 381                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 382                 //   :%!sort
 383                 // yes, this does contain some redundant stuff, don't really care
 384                 BADCVAR("bot_number");
 385                 BADCVAR("bot_prefix");
 386                 BADCVAR("bot_suffix");
 387                 BADCVAR("capturelimit_override");
 388                 BADCVAR("fraglimit_override");
 389                 BADCVAR("gametype");
 390                 BADCVAR("g_antilag");
 391                 BADCVAR("g_balance_teams");
 392                 BADCVAR("g_balance_teams_force");
 393                 BADCVAR("g_ban_sync_trusted_servers");
 394                 BADCVAR("g_ban_sync_uri");
 395                 BADCVAR("g_ctf_capture_limit");
 396                 BADCVAR("g_ctf_ignore_frags");
 397                 BADCVAR("g_ctf_win_mode");
 398                 BADCVAR("g_domination_point_limit");
 399                 BADCVAR("g_fullbrightitems");
 400                 BADCVAR("g_fullbrightplayers");
 401                 BADCVAR("g_keyhunt_point_limit");
 402                 BADCVAR("g_keyhunt_teams_override");
 403                 BADCVAR("g_lms_lives_override");
 404                 BADCVAR("g_maplist");
 405                 BADCVAR("g_maplist_check_waypoints");
 406                 BADCVAR("g_maplist_mostrecent_count");
 407                 BADCVAR("g_maplist_shuffle");
 408                 BADCVAR("g_maplist_votable");
 409                 BADCVAR("g_maplist_votable_abstain");
 410                 BADCVAR("g_maplist_votable_nodetail");
 411                 BADCVAR("g_maplist_votable_suggestions");
 412                 BADCVAR("g_minstagib");
 413                 BADCVAR("g_nexball_goallimit");
 414                 BADCVAR("g_runematch_point_limit");
 415                 BADCVAR("g_start_delay");
 416                 BADCVAR("hostname");
 417                 BADCVAR("log_file");
 418                 BADCVAR("maxplayers");
 419                 BADCVAR("minplayers");
 420                 BADCVAR("net_address");
 421                 BADCVAR("port");
 422                 BADCVAR("rcon_password");
 423                 BADCVAR("rcon_restricted_commands");
 424                 BADCVAR("rcon_restricted_password");
 425                 BADCVAR("skill");
 426                 BADCVAR("sv_adminnick");
 427                 BADCVAR("sv_autoscreenshot");
 428                 BADCVAR("sv_curl_defaulturl");
 429                 BADCVAR("sv_defaultcharacter");
 430                 BADCVAR("sv_defaultplayercolors");
 431                 BADCVAR("sv_defaultplayermodel");
 432                 BADCVAR("sv_defaultplayerskin");
 433                 BADCVAR("sv_maxidle");
 434                 BADCVAR("sv_maxrate");
 435                 BADCVAR("sv_motd");
 436                 BADCVAR("sv_public");
 437                 BADCVAR("sv_ready_restart");
 438                 BADCVAR("sv_status_privacy");
 439                 BADCVAR("sv_vote_call");
 440                 BADCVAR("sv_vote_commands");
 441                 BADCVAR("sv_vote_majority_factor");
 442                 BADCVAR("sv_vote_master");
 443                 BADCVAR("sv_vote_master_commands");
 444                 BADCVAR("sv_vote_master_password");
 445                 BADCVAR("sv_vote_simple_majority_factor");
 446                 BADCVAR("timelimit_override");
 447
 448                 if(cvar("g_minstagib"))
 449                 {
 450                         BADCVAR("g_grappling_hook");
 451                         BADCVAR("g_jetpack");
 452                 }
 453 #undef BADPREFIX
 454 #undef BADCVAR
 455
 456                 if(pureadding)
 457                 {
 458                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 459                         if(strlen(cvar_purechanges) > 16384)
 460                         {
 461                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 462                                 pureadding = 0;
 463                         }
 464                 }
 465                 ++cvar_purechanges_count;
 466                 // WARNING: this variable is used for the server list
 467                 // NEVER dare to skip this code!
 468                 // Hacks to intentionally appearing as "pure server" even though you DO have
 469                 // modified settings may be punished by removal from the server list.
 470                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 471                 // though.
 472         }
 473         buf_del(h);
 474         if(cvar_changes == "")
 475                 cvar_changes = "// this server runs at default server settings\n";
 476         else
 477                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 478         cvar_changes = strzone(cvar_changes);
 479         if(cvar_purechanges == "")
 480                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 481         else
 482                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 483         cvar_purechanges = strzone(cvar_purechanges);
 484 }
 485
 486 void detect_maptype()
 487 {
 488 #if 0
 489         vector o, v;
 490         float i;
 491
 492         for(;;)
 493         {
 494                 o = world.mins;
 495                 o_x += random() * (world.maxs_x - world.mins_x);
 496                 o_y += random() * (world.maxs_y - world.mins_y);
 497                 o_z += random() * (world.maxs_z - world.mins_z);
 498
 499                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 500                 if(trace_fraction == 1)
 501                         continue;
 502
 503                 v = trace_endpos;
 504
 505                 for(i = 0; i < 64; i += 4)
 506                 {
 507                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 508         if(trace_fraction == 1)
 509                 continue;
 510                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 511                 }
 512
 513                 break;
 514         }
 515 #endif
 516 }
 517
 518 entity randomseed;
 519 float RandomSeed_Send(entity to, float sf)
 520 {
 521         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 522         WriteShort(MSG_ENTITY, self.cnt);
 523         return TRUE;
 524 }
 525 void RandomSeed_Think()
 526 {
 527         self.cnt = bound(0, floor(random() * 65536), 65535);
 528         self.nextthink = time + 5;
 529
 530         self.SendFlags |= 1;
 531 }
 532 void RandomSeed_Spawn()
 533 {
 534         randomseed = spawn();
 535         randomseed.think = RandomSeed_Think;
 536         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 537
 538         entity oldself;
 539         oldself = self;
 540         self = randomseed;
 541         self.think(); // sets random seed and nextthink
 542         self = oldself;
 543 }
 544
 545 void spawnfunc___init_dedicated_server(void)
 546 {
 547         // handler for _init/_init map (only for dedicated server initialization)
 548
 549         world_initialized = -1; // don't complain
 550         cvar = cvar_normal;
 551         cvar_string = cvar_string_normal;
 552         cvar_set = cvar_set_normal;
 553
 554         remove = remove_unsafely;
 555
 556         entity e;
 557         e = spawn();
 558         e.think = GotoFirstMap;
 559         e.nextthink = time; // this is usually 1 at this point
 560
 561         e = spawn();
 562         e.classname = "info_player_deathmatch"; // safeguard against player joining
 563
 564         self.classname = "worldspawn"; // safeguard against various stuff ;)
 565
 566         MapInfo_Enumerate();
 567         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 568 }
 569
 570 void Map_MarkAsRecent(string m);
 571 float world_already_spawned;
 572 void RegisterWeapons();
 573 void Nagger_Init();
 574 void ClientInit_Spawn();
 575 void WeaponStats_Init();
 576 void WeaponStats_Shutdown();
 577 void spawnfunc_worldspawn (void)
 578 {
 579         float fd, l, i, j, n;
 580         string s, col;
 581
 582         cvar = cvar_normal;
 583         cvar_string = cvar_string_normal;
 584         cvar_set = cvar_set_normal;
 585
 586         if(world_already_spawned)
 587                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 588         world_already_spawned = TRUE;
 589
 590         remove = remove_safely; // during spawning, watch what you remove!
 591
 592         check_unacceptable_compiler_bugs();
 593
 594         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 595
 596         compressShortVector_init();
 597
 598         allowed_to_spawn = TRUE;
 599
 600         local entity head;
 601         head = nextent(world);
 602         maxclients = 0;
 603         while(head)
 604         {
 605                 ++maxclients;
 606                 head = nextent(head);
 607         }
 608
 609         // needs to be done so early as they would still spawn
 610         RegisterWeapons();
 611
 612         ServerProgsDB = db_load("server.db");
 613
 614         TemporaryDB = db_create();
 615
 616         /*
 617         TODO sound pack system
 618         // initialize sound pack system
 619         soundpack = cvar_string("g_soundpack");
 620         if(soundpack != "")
 621                 soundpack = strcat(soundpack, "/");
 622         soundpack = strzone(soundpack);
 623         */
 624
 625         // 0 normal
 626         lightstyle(0, "m");
 627
 628         // 1 FLICKER (first variety)
 629         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 630
 631         // 2 SLOW STRONG PULSE
 632         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 633
 634         // 3 CANDLE (first variety)
 635         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 636
 637         // 4 FAST STROBE
 638         lightstyle(4, "mamamamamama");
 639
 640         // 5 GENTLE PULSE 1
 641         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 642
 643         // 6 FLICKER (second variety)
 644         lightstyle(6, "nmonqnmomnmomomno");
 645
 646         // 7 CANDLE (second variety)
 647         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 648
 649         // 8 CANDLE (third variety)
 650         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 651
 652         // 9 SLOW STROBE (fourth variety)
 653         lightstyle(9, "aaaaaaaazzzzzzzz");
 654
 655         // 10 FLUORESCENT FLICKER
 656         lightstyle(10, "mmamammmmammamamaaamammma");
 657
 658         // 11 SLOW PULSE NOT FADE TO BLACK
 659         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 660
 661         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 662
 663         // 63 testing
 664         lightstyle(63, "a");
 665
 666         if(cvar("g_campaign"))
 667                 CampaignPreInit();
 668
 669         Map_MarkAsRecent(mapname);
 670
 671         precache_model ("null"); // we need this one before InitGameplayMode
 672         InitGameplayMode();
 673         readlevelcvars();
 674         GrappleHookInit();
 675         ElectroInit();
 676         LaserInit();
 677
 678         player_count = 0;
 679         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 680         if(bot_waypoints_for_items == 1)
 681                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 682                         bot_waypoints_for_items = 0;
 683
 684         // for setting by mapinfo
 685         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 686         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 687
 688         precache();
 689
 690         WaypointSprite_Init();
 691
 692         //if (g_domination)
 693         //      dom_init();
 694
 695         GameLogInit(); // prepare everything
 696         if(cvar("sv_eventlog"))
 697         {
 698                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 699                 s = strcat(s, ftos(random()));
 700                 matchid = strzone(s);
 701
 702                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 703                 s = ":gameinfo:mutators:LIST";
 704
 705                 ret_string = s;
 706                 MUTATOR_CALLHOOK(BuildMutatorsString);
 707                 s = ret_string;
 708
 709                 // simple, probably not good in the mutator system
 710                 if(cvar("g_grappling_hook"))
 711                         s = strcat(s, ":grappling_hook");
 712
 713                 // initialiation stuff, not good in the mutator system
 714                 if(!cvar("g_use_ammunition"))
 715                         s = strcat(s, ":no_use_ammunition");
 716
 717                 // initialiation stuff, not good in the mutator system
 718                 if(!cvar("g_pickup_items"))
 719                         s = strcat(s, ":no_pickup_items");
 720
 721                 // initialiation stuff, not good in the mutator system
 722                 if(cvar_string("g_weaponarena") != "0")
 723                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 724
 725                 // TODO to mutator system
 726                 if(cvar("g_norecoil"))
 727                         s = strcat(s, ":norecoil");
 728
 729                 // TODO to mutator system
 730                 if(cvar("g_midair"))
 731                         s = strcat(s, ":midair");
 732
 733                 // TODO to mutator system
 734                 if(cvar("g_minstagib"))
 735                         s = strcat(s, ":minstagib");
 736
 737                 GameLogEcho(s);
 738                 GameLogEcho(":gameinfo:end");
 739         }
 740         else
 741                 matchid = strzone(ftos(random()));
 742
 743         cvar_set("nextmap", "");
 744
 745         SetDefaultAlpha();
 746
 747         if(cvar("g_campaign"))
 748                 CampaignPostInit();
 749
 750         fteqcc_testbugs();
 751
 752         Ban_LoadBans();
 753
 754         MapInfo_Enumerate();
 755         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 756
 757         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 758         {
 759                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 760                 if(fd != -1)
 761                 {
 762                         while((s = fgets(fd)))
 763                         {
 764                                 l = tokenize_console(s);
 765                                 if(l < 2)
 766                                         continue;
 767                                 if(argv(0) == "cd")
 768                                 {
 769                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 770                                         print("  cdtrack ", argv(2), "\n");
 771                                 }
 772                                 else if(argv(0) == "fog")
 773                                 {
 774                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 775                                         print("  \"fog\" \"", s, "\"\n");
 776                                 }
 777                                 else if(argv(0) == "set")
 778                                 {
 779                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 780                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 781                                 }
 782                                 else if(argv(0) != "//")
 783                                 {
 784                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 785                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 786                                 }
 787                         }
 788                         fclose(fd);
 789                 }
 790         }
 791
 792         WeaponStats_Init();
 793
 794         addstat(STAT_WEAPONS, AS_INT, weapons);
 795         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 796         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 797         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 798         Nagger_Init();
 799
 800         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 801         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 802         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 803         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 804         addstat(STAT_DAMAGE_HITS, AS_INT, stat_hit);
 805         addstat(STAT_DAMAGE_FIRED, AS_INT, stat_fired);
 806         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 807         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 808         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 809         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 810
 811         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 812         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_charge_pool_ammo);
 813
 814         if(g_ca)
 815         {
 816                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 817                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 818         }
 819         // g_movementspeed hack
 820         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 821         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 822         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 823         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 824
 825         next_pingtime = time + 5;
 826
 827         detect_maptype();
 828
 829         lsmaps_reply = "^7Maps available: ";
 830         lsnewmaps_reply = "^7Maps without a record set: ";
 831         for(i = 0, j = 0; i < MapInfo_count; ++i)
 832         {
 833                 if(MapInfo_Get_ByID(i))
 834                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 835                         {
 836                                 if(mod(i, 2))
 837                                         col = "^2";
 838                                 else
 839                                         col = "^3";
 840                                 ++j;
 841                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 842                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 843                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 844                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 845                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 846                         }
 847         }
 848         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 849         if (!g_race && !g_cts)
 850                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 851         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 852
 853         maplist_reply = "^7Maps in list: ";
 854         n = tokenize_console(cvar_string("g_maplist"));
 855         for(i = 0, j = 0; i < n; ++i)
 856         {
 857                 if(MapInfo_CheckMap(argv(i)))
 858                 {
 859                         if(mod(j, 2))
 860                                 col = "^2";
 861                         else
 862                                 col = "^3";
 863                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 864                         ++j;
 865                 }
 866         }
 867         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 868         MapInfo_ClearTemps();
 869
 870         for(i = 0; i < 10; ++i)
 871         {
 872                 records_reply[i] = strzone(getrecords(i));
 873         }
 874         if(g_cts)
 875                 ladder_reply = strzone(getladder());
 876
 877         rankings_reply = strzone(getrankings());
 878
 879         ClientInit_Spawn();
 880         RandomSeed_Spawn();
 881         PingPLReport_Spawn();
 882
 883         CheatInit();
 884
 885         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 886
 887         // fill sv_curl_serverpackages from .serverpackage files
 888         if(cvar("sv_curl_serverpackages_auto"))
 889         {
 890                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 891                 s = "";
 892                 if(fd >= 0)
 893                 {
 894                         j = search_getsize(fd);
 895                         for(i = 0; i < j; ++i)
 896                                 s = strcat(s, " ", search_getfilename(fd, i));
 897                         search_end(fd);
 898                 }
 899                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 900         }
 901
 902         world_initialized = 1;
 903 }
 904
 905 void spawnfunc_light (void)
 906 {
 907         //makestatic (self); // Who the f___ did that?
 908         remove(self);
 909 }
 910
 911 float TryFile( string pFilename )
 912 {
 913         local float lHandle;
 914         dprint("TryFile(\"", pFilename, "\")\n");
 915         lHandle = fopen( pFilename, FILE_READ );
 916         if( lHandle != -1 ) {
 917                 fclose( lHandle );
 918                 return TRUE;
 919         } else {
 920                 return FALSE;
 921         }
 922 };
 923
 924 string GetGametype()
 925 {
 926         return GametypeNameFromType(game);
 927 }
 928
 929 string getmapname_stored;
 930 string GetMapname()
 931 {
 932         return mapname;
 933 }
 934
 935 float Map_Count, Map_Current;
 936 string Map_Current_Name;
 937
 938 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 939 float GetMaplistPosition()
 940 {
 941         float pos, idx;
 942         string map;
 943
 944         map = GetMapname();
 945         idx = cvar("g_maplist_index");
 946
 947         if(idx >= 0)
 948                 if(idx < Map_Count)
 949                         if(map == argv(idx))
 950                                 return idx;
 951
 952         for(pos = 0; pos < Map_Count; ++pos)
 953                 if(map == argv(pos))
 954                         return pos;
 955
 956         // resume normal maplist rotation if current map is not in g_maplist
 957         return idx;
 958 }
 959
 960 float MapHasRightSize(string map)
 961 {
 962         float fh;
 963         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 964         if(cvar("g_maplist_check_waypoints"))
 965         {
 966                 dprint("checkwp "); dprint(map);
 967                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 968                 if(fh < 0)
 969                 {
 970                         dprint(": no waypoints\n");
 971                         return FALSE;
 972                 }
 973                 dprint(": has waypoints\n");
 974                 fclose(fh);
 975         }
 976
 977         // open map size restriction file
 978         dprint("opensize "); dprint(map);
 979         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 980         if(fh >= 0)
 981         {
 982                 float mapmin, mapmax;
 983                 dprint(": ok, ");
 984                 mapmin = stof(fgets(fh));
 985                 mapmax = stof(fgets(fh));
 986                 fclose(fh);
 987                 if(player_count < mapmin)
 988                 {
 989                         dprint("not enough\n");
 990                         return FALSE;
 991                 }
 992                 if(player_count > mapmax)
 993                 {
 994                         dprint("too many\n");
 995                         return FALSE;
 996                 }
 997                 dprint("right size\n");
 998                 return TRUE;
 999         }
1000         dprint(": not found\n");
1001         return TRUE;
1002 }
1003
1004 string Map_Filename(float position)
1005 {
1006         return strcat("maps/", argv(position), ".bsp");
1007 }
1008
1009 string strwords(string s, float w)
1010 {
1011         float endpos;
1012         for(endpos = 0; w && endpos >= 0; --w)
1013                 endpos = strstrofs(s, " ", endpos + 1);
1014         if(endpos < 0)
1015                 return s;
1016         else
1017                 return substring(s, 0, endpos);
1018 }
1019
1020 float strhasword(string s, string w)
1021 {
1022         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1023 }
1024
1025 void Map_MarkAsRecent(string m)
1026 {
1027         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
1028 }
1029
1030 float Map_IsRecent(string m)
1031 {
1032         return strhasword(cvar_string("g_maplist_mostrecent"), m);
1033 }
1034
1035 float Map_Check(float position, float pass)
1036 {
1037         string filename;
1038         string map_next;
1039         map_next = argv(position);
1040         if(pass <= 1)
1041         {
1042                 if(Map_IsRecent(map_next))
1043                         return 0;
1044         }
1045         filename = Map_Filename(position);
1046         if(MapInfo_CheckMap(map_next))
1047         {
1048                 if(pass == 2)
1049                         return 1;
1050                 if(MapHasRightSize(map_next))
1051                         return 1;
1052                 return 0;
1053         }
1054         else
1055                 dprint( "Couldn't select '", filename, "'..\n" );
1056
1057         return 0;
1058 }
1059
1060 void Map_Goto_SetStr(string nextmapname)
1061 {
1062         if(getmapname_stored != "")
1063                 strunzone(getmapname_stored);
1064         if(nextmapname == "")
1065                 getmapname_stored = "";
1066         else
1067                 getmapname_stored = strzone(nextmapname);
1068 }
1069
1070 void Map_Goto_SetFloat(float position)
1071 {
1072         cvar_set("g_maplist_index", ftos(position));
1073         Map_Goto_SetStr(argv(position));
1074 }
1075
1076 void GameResetCfg()
1077 {
1078         // settings persist, except...
1079         localcmd("\nsettemp_restore\n");
1080 };
1081
1082 void Map_Goto()
1083 {
1084         GameResetCfg();
1085         MapInfo_LoadMap(getmapname_stored);
1086 }
1087
1088 // return codes of map selectors:
1089 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1090 //   -2 = permanent failure
1091 float() MaplistMethod_Iterate = // usual method
1092 {
1093         float pass, i;
1094
1095         for(pass = 1; pass <= 2; ++pass)
1096         {
1097                 for(i = 1; i < Map_Count; ++i)
1098                 {
1099                         float mapindex;
1100                         mapindex = mod(i + Map_Current, Map_Count);
1101                         if(Map_Check(mapindex, pass))
1102                                 return mapindex;
1103                 }
1104         }
1105         return -1;
1106 }
1107
1108 float() MaplistMethod_Repeat = // fallback method
1109 {
1110         if(Map_Check(Map_Current, 2))
1111                 return Map_Current;
1112         return -2;
1113 }
1114
1115 float() MaplistMethod_Random = // random map selection
1116 {
1117         float i, imax;
1118
1119         imax = 42;
1120
1121         for(i = 0; i <= imax; ++i)
1122         {
1123                 float mapindex;
1124                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1125                 if(Map_Check(mapindex, 1))
1126                         return mapindex;
1127         }
1128         return -1;
1129 }
1130
1131 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1132 // the exponent sets a bias on the map selection:
1133 // the higher the exponent, the less likely "shortly repeated" same maps are
1134 {
1135         float i, j, imax, insertpos;
1136
1137         imax = 42;
1138
1139         for(i = 0; i <= imax; ++i)
1140         {
1141                 string newlist;
1142
1143                 // now reinsert this at another position
1144                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1145                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1146                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1147                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1148
1149                 // insert the current map there
1150                 newlist = "";
1151                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1152                         newlist = strcat(newlist, " ", argv(j));
1153                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1154                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1155                         newlist = strcat(newlist, " ", argv(j));
1156                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1157                 cvar_set("g_maplist", newlist);
1158                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1159
1160                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1161                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1162                 if(Map_Check(Map_Current, 1))
1163                         return Map_Current;
1164         }
1165         return -1;
1166 }
1167
1168 void Maplist_Init()
1169 {
1170         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1171         if(Map_Count == 0)
1172         {
1173                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1174                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1175                 if(cvar("g_maplist_shuffle"))
1176                         ShuffleMaplist();
1177                 localcmd("\nmenu_cmd sync\n");
1178                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1179         }
1180         if(Map_Count == 0)
1181                 error("empty maplist, cannot select a new map");
1182         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1183
1184         if(Map_Current_Name)
1185                 strunzone(Map_Current_Name);
1186         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1187         // this may or may not be correct, but who cares, in the worst case a map
1188         // isn't chosen in the first pass that should have been
1189 }
1190
1191 string GetNextMap()
1192 {
1193         float nextMap;
1194
1195         Maplist_Init();
1196         nextMap = -1;
1197
1198         if(nextMap == -1)
1199                 if(cvar("g_maplist_shuffle") > 0)
1200                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
1201
1202         if(nextMap == -1)
1203                 if(cvar("g_maplist_selectrandom"))
1204                         nextMap = MaplistMethod_Random();
1205
1206         if(nextMap == -1)
1207                 nextMap = MaplistMethod_Iterate();
1208
1209         if(nextMap == -1)
1210                 nextMap = MaplistMethod_Repeat();
1211
1212         if(nextMap >= 0)
1213         {
1214                 Map_Goto_SetFloat(nextMap);
1215                 return getmapname_stored;
1216         }
1217
1218         return "";
1219 };
1220
1221 float DoNextMapOverride()
1222 {
1223         if(cvar("g_campaign"))
1224         {
1225                 CampaignPostIntermission();
1226                 alreadychangedlevel = TRUE;
1227                 return TRUE;
1228         }
1229         if(cvar("quit_when_empty"))
1230         {
1231                 if(player_count <= currentbots)
1232                 {
1233                         localcmd("quit\n");
1234                         alreadychangedlevel = TRUE;
1235                         return TRUE;
1236                 }
1237         }
1238         if(cvar_string("quit_and_redirect") != "")
1239         {
1240                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1241                 alreadychangedlevel = TRUE;
1242                 return TRUE;
1243         }
1244         if (cvar("samelevel")) // if samelevel is set, stay on same level
1245         {
1246                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1247                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1248                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1249                 localcmd("restart\n");
1250                 //changelevel (mapname);
1251                 alreadychangedlevel = TRUE;
1252                 return TRUE;
1253         }
1254         if(cvar_string("nextmap") != "")
1255                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1256                 {
1257                         Map_Goto_SetStr(cvar_string("nextmap"));
1258                         Map_Goto();
1259                         alreadychangedlevel = TRUE;
1260                         return TRUE;
1261                 }
1262         if(cvar("lastlevel"))
1263         {
1264                 GameResetCfg();
1265                 localcmd("set lastlevel 0\ntogglemenu\n");
1266                 alreadychangedlevel = TRUE;
1267                 return TRUE;
1268         }
1269         return FALSE;
1270 };
1271
1272 void GotoNextMap()
1273 {
1274         //local string nextmap;
1275         //local float n, nummaps;
1276         //local string s;
1277         if (alreadychangedlevel)
1278                 return;
1279         alreadychangedlevel = TRUE;
1280
1281         {
1282                 string nextMap;
1283                 float allowReset;
1284
1285                 for(allowReset = 1; allowReset >= 0; --allowReset)
1286                 {
1287                         nextMap = GetNextMap();
1288                         if(nextMap != "")
1289                                 break;
1290
1291                         if(allowReset)
1292                         {
1293                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1294                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1295                                 if(cvar("g_maplist_shuffle"))
1296                                         ShuffleMaplist();
1297                                 localcmd("\nmenu_cmd sync\n");
1298                         }
1299                         else
1300                         {
1301                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1302                         }
1303                 }
1304                 Map_Goto();
1305         }
1306 };
1307
1308
1309 /*
1310 ============
1311 IntermissionThink
1312
1313 When the player presses attack or jump, change to the next level
1314 ============
1315 */
1316 .float autoscreenshot;
1317 void() MapVote_Start;
1318 void() MapVote_Think;
1319 float mapvote_initialized;
1320 void IntermissionThink()
1321 {
1322         FixIntermissionClient(self);
1323
1324         if(cvar("sv_autoscreenshot"))
1325         if(self.autoscreenshot > 0)
1326         if(time > self.autoscreenshot)
1327         {
1328                 self.autoscreenshot = -1;
1329                 if(clienttype(self) == CLIENTTYPE_REAL)
1330                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1331                 return;
1332         }
1333
1334         if (time < intermission_exittime)
1335                 return;
1336
1337         if(!mapvote_initialized)
1338                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1339                         return;
1340
1341         MapVote_Start();
1342 };
1343
1344 /*
1345 ============
1346 FindIntermission
1347
1348 Returns the entity to view from
1349 ============
1350 */
1351 /*
1352 entity FindIntermission()
1353 {
1354         local   entity spot;
1355         local   float cyc;
1356
1357 // look for info_intermission first
1358         spot = find (world, classname, "info_intermission");
1359         if (spot)
1360         {       // pick a random one
1361                 cyc = random() * 4;
1362                 while (cyc > 1)
1363                 {
1364                         spot = find (spot, classname, "info_intermission");
1365                         if (!spot)
1366                                 spot = find (spot, classname, "info_intermission");
1367                         cyc = cyc - 1;
1368                 }
1369                 return spot;
1370         }
1371
1372 // then look for the start position
1373         spot = find (world, classname, "info_player_start");
1374         if (spot)
1375                 return spot;
1376
1377 // testinfo_player_start is only found in regioned levels
1378         spot = find (world, classname, "testplayerstart");
1379         if (spot)
1380                 return spot;
1381
1382 // then look for the start position
1383         spot = find (world, classname, "info_player_deathmatch");
1384         if (spot)
1385                 return spot;
1386
1387         //objerror ("FindIntermission: no spot");
1388         return world;
1389 };
1390 */
1391
1392 /*
1393 ===============================================================================
1394
1395 RULES
1396
1397 ===============================================================================
1398 */
1399
1400 void DumpStats(float final)
1401 {
1402         local float file;
1403         local string s;
1404         local float to_console;
1405         local float to_eventlog;
1406         local float to_file;
1407         local float i;
1408
1409         to_console = cvar("sv_logscores_console");
1410         to_eventlog = cvar("sv_eventlog");
1411         to_file = cvar("sv_logscores_file");
1412
1413         if(!final)
1414         {
1415                 to_console = TRUE; // always print printstats replies
1416                 to_eventlog = FALSE; // but never print them to the event log
1417         }
1418
1419         if(to_eventlog)
1420                 if(cvar("sv_eventlog_console"))
1421                         to_console = FALSE; // otherwise we get the output twice
1422
1423         if(final)
1424                 s = ":scores:";
1425         else
1426                 s = ":status:";
1427         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1428
1429         if(to_console)
1430                 print(s, "\n");
1431         if(to_eventlog)
1432                 GameLogEcho(s);
1433         if(to_file)
1434         {
1435                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1436                 if(file == -1)
1437                         to_file = FALSE;
1438                 else
1439                         fputs(file, strcat(s, "\n"));
1440         }
1441
1442         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1443         if(to_console)
1444                 print(s, "\n");
1445         if(to_eventlog)
1446                 GameLogEcho(s);
1447         if(to_file)
1448                 fputs(file, strcat(s, "\n"));
1449
1450         FOR_EACH_CLIENT(other)
1451         {
1452                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1453                 {
1454                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1455                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1456                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1457                                 s = strcat(s, ftos(other.team), ":");
1458                         else
1459                                 s = strcat(s, "spectator:");
1460
1461                         if(to_console)
1462                                 print(s, other.netname, "\n");
1463                         if(to_eventlog)
1464                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1465                         if(to_file)
1466                                 fputs(file, strcat(s, other.netname, "\n"));
1467                 }
1468         }
1469
1470         if(teams_matter)
1471         {
1472                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1473                 if(to_console)
1474                         print(s, "\n");
1475                 if(to_eventlog)
1476                         GameLogEcho(s);
1477                 if(to_file)
1478                         fputs(file, strcat(s, "\n"));
1479
1480                 for(i = 1; i < 16; ++i)
1481                 {
1482                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1483                         s = strcat(s, ":", ftos(i));
1484                         if(to_console)
1485                                 print(s, "\n");
1486                         if(to_eventlog)
1487                                 GameLogEcho(s);
1488                         if(to_file)
1489                                 fputs(file, strcat(s, "\n"));
1490                 }
1491         }
1492
1493         if(to_console)
1494                 print(":end\n");
1495         if(to_eventlog)
1496                 GameLogEcho(":end");
1497         if(to_file)
1498         {
1499                 fputs(file, ":end\n");
1500                 fclose(file);
1501         }
1502 }
1503
1504 void FixIntermissionClient(entity e)
1505 {
1506         string s;
1507         if(!e.autoscreenshot) // initial call
1508         {
1509                 e.angles = e.v_angle;
1510                 e.angles_x = -e.angles_x;
1511                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1512                 e.health = -2342;
1513                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1514                 e.solid = SOLID_NOT;
1515                 e.movetype = MOVETYPE_NONE;
1516                 e.takedamage = DAMAGE_NO;
1517                 if(e.weaponentity)
1518                 {
1519                         e.weaponentity.effects = EF_NODRAW;
1520                         if (e.weaponentity.weaponentity)
1521                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1522                 }
1523                 if(clienttype(e) == CLIENTTYPE_REAL)
1524                 {
1525                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1526                         s = cvar_string("sv_intermission_cdtrack");
1527                         if(s != "")
1528                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1529                         msg_entity = e;
1530                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1531                 }
1532         }
1533
1534         //e.velocity = '0 0 0';
1535         //e.fixangle = TRUE;
1536
1537         // TODO halt weapon animation
1538 }
1539
1540
1541 /*
1542 go to the next level for deathmatch
1543 only called if a time or frag limit has expired
1544 */
1545 void NextLevel()
1546 {
1547         float i;
1548
1549         gameover = TRUE;
1550
1551         intermission_running = 1;
1552
1553 // enforce a wait time before allowing changelevel
1554         if(player_count > 0)
1555                 intermission_exittime = time + cvar("sv_mapchange_delay");
1556         else
1557                 intermission_exittime = -1;
1558
1559         /*
1560         WriteByte (MSG_ALL, SVC_CDTRACK);
1561         WriteByte (MSG_ALL, 3);
1562         WriteByte (MSG_ALL, 3);
1563         // done in FixIntermission
1564         */
1565
1566         //pos = FindIntermission ();
1567
1568         VoteReset();
1569
1570         DumpStats(TRUE);
1571
1572         if(cvar("sv_eventlog"))
1573                 GameLogEcho(":gameover");
1574
1575         GameLogClose();
1576
1577 // TO DO
1578
1579 // save the stats to a text file on the client
1580 // stuffcmd(other, log_stats "stats/file_name");
1581 // bprint stats
1582 // stuffcmd(other, log_stats "");
1583 // use a filename similar to the demo name
1584         // string file_name;
1585         // file_name = strcat("\nlog_file \"stats/", strftime(TRUE, "%Y-%m-%d_%H-%M"), "_", mapname, ".txt\"");  // open the log file
1586
1587 // write a stats parser for the menu
1588
1589         if(cvar("sv_accuracy_data_send")) {
1590                 string stats_to_send;
1591
1592                 FOR_EACH_CLIENT(other) {  // make the string to send
1593                         FixIntermissionClient(other);
1594
1595                         if(other.cvar_cl_accuracy_data_share) {
1596                                 stats_to_send = strcat(stats_to_send, ":hits:", other.netname);
1597
1598                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1599                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_hit[i-1]));
1600
1601                                 stats_to_send = strcat(stats_to_send, "\n:fired:", other.netname);
1602
1603                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1604                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_fired[i-1]));
1605
1606                                 stats_to_send = strcat(stats_to_send, "\n");
1607                         }
1608                 }
1609
1610                 FOR_EACH_REALCLIENT(other) {  // only spam humans
1611                         Score_NicePrint(other);  // print the score
1612
1613                         if(other.cvar_cl_accuracy_data_receive)  // send the stats string to all the willing clients
1614                                 bprint(stats_to_send);
1615                 }
1616         } else { // ye olde message
1617                 FOR_EACH_PLAYER(other) {
1618                         FixIntermissionClient(other);
1619
1620                         if(other.winning)
1621                                 bprint(other.netname, " ^7wins.\n");
1622                 }
1623         }
1624
1625         if(cvar("g_campaign"))
1626                 CampaignPreIntermission();
1627
1628         localcmd("\nsv_hook_gameend\n");
1629 }
1630
1631 /*
1632 ============
1633 CheckRules_Player
1634
1635 Exit deathmatch games upon conditions
1636 ============
1637 */
1638 void CheckRules_Player()
1639 {
1640         if (gameover)   // someone else quit the game already
1641                 return;
1642
1643         if(self.deadflag == DEAD_NO)
1644                 self.play_time += frametime;
1645
1646         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1647         //   (div0: and that in CheckRules_World please)
1648 };
1649
1650 float checkrules_equality;
1651 float checkrules_suddendeathwarning;
1652 float checkrules_suddendeathend;
1653 float checkrules_overtimesadded; //how many overtimes have been already added
1654
1655 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1656 float WINNING_YES = 1; // winner found
1657 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1658 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1659
1660 float InitiateSuddenDeath()
1661 {
1662         // Check first whether normal overtimes could be added before initiating suddendeath mode
1663         // - for this timelimit_overtime needs to be >0 of course
1664         // - also check the winning condition calculated in the previous frame and only add normal overtime
1665         //   again, if at the point at which timelimit would be extended again, still no winner was found
1666         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1667         {
1668                 return 1; // need to call InitiateOvertime later
1669         }
1670         else
1671         {
1672                 if(!checkrules_suddendeathend)
1673                 {
1674                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1675                         if(g_race && !g_race_qualifying)
1676                                 race_StartCompleting();
1677                 }
1678                 return 0;
1679         }
1680 }
1681
1682 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1683 {
1684         ++checkrules_overtimesadded;
1685         //add one more overtime by simply extending the timelimit
1686         float tl;
1687         tl = cvar("timelimit");
1688         tl += cvar("timelimit_overtime");
1689         cvar_set("timelimit", ftos(tl));
1690         string minutesPlural;
1691         if (cvar("timelimit_overtime") == 1)
1692                 minutesPlural = " ^3minute";
1693         else
1694                 minutesPlural = " ^3minutes";
1695
1696         bcenterprint(
1697                 strcat(
1698                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1699                         ftos(cvar("timelimit_overtime")),
1700                         minutesPlural,
1701                         " to the game!"
1702                 )
1703         );
1704 }
1705
1706 float GetWinningCode(float fraglimitreached, float equality)
1707 {
1708         if(cvar("g_campaign") == 1)
1709                 if(fraglimitreached)
1710                         return WINNING_YES;
1711                 else
1712                         return WINNING_NO;
1713
1714         else
1715                 if(equality)
1716                         if(fraglimitreached)
1717                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1718                         else
1719                                 return WINNING_NEVER;
1720                 else
1721                         if(fraglimitreached)
1722                                 return WINNING_YES;
1723                         else
1724                                 return WINNING_NO;
1725 }
1726
1727 // set the .winning flag for exactly those players with a given field value
1728 void SetWinners(.float field, float value)
1729 {
1730         entity head;
1731         FOR_EACH_PLAYER(head)
1732                 head.winning = (head.field == value);
1733 }
1734
1735 // set the .winning flag for those players with a given field value
1736 void AddWinners(.float field, float value)
1737 {
1738         entity head;
1739         FOR_EACH_PLAYER(head)
1740                 if(head.field == value)
1741                         head.winning = 1;
1742 }
1743
1744 // clear the .winning flags
1745 void ClearWinners(void)
1746 {
1747         entity head;
1748         FOR_EACH_PLAYER(head)
1749                 head.winning = 0;
1750 }
1751
1752 // Onslaught winning condition:
1753 // game terminates if only one team has a working generator (or none)
1754 float WinningCondition_Onslaught()
1755 {
1756         entity head;
1757         local float t1, t2, t3, t4;
1758
1759         WinningConditionHelper(); // set worldstatus
1760
1761         if(inWarmupStage)
1762                 return WINNING_NO;
1763
1764         // first check if the game has ended
1765         t1 = t2 = t3 = t4 = 0;
1766         head = find(world, classname, "onslaught_generator");
1767         while (head)
1768         {
1769                 if (head.health > 0)
1770                 {
1771                         if (head.team == COLOR_TEAM1) t1 = 1;
1772                         if (head.team == COLOR_TEAM2) t2 = 1;
1773                         if (head.team == COLOR_TEAM3) t3 = 1;
1774                         if (head.team == COLOR_TEAM4) t4 = 1;
1775                 }
1776                 head = find(head, classname, "onslaught_generator");
1777         }
1778         if (t1 + t2 + t3 + t4 < 2)
1779         {
1780                 // game over, only one team remains (or none)
1781                 ClearWinners();
1782                 if (t1) SetWinners(team, COLOR_TEAM1);
1783                 if (t2) SetWinners(team, COLOR_TEAM2);
1784                 if (t3) SetWinners(team, COLOR_TEAM3);
1785                 if (t4) SetWinners(team, COLOR_TEAM4);
1786                 dprint("Have a winner, ending game.\n");
1787                 return WINNING_YES;
1788         }
1789
1790         // Two or more teams remain
1791         return WINNING_NO;
1792 }
1793
1794 float LMS_NewPlayerLives()
1795 {
1796         float fl;
1797         fl = cvar("fraglimit");
1798         if(fl == 0)
1799                 fl = 999;
1800
1801         // first player has left the game for dying too much? Nobody else can get in.
1802         if(lms_lowest_lives < 1)
1803                 return 0;
1804
1805         if(!cvar("g_lms_join_anytime"))
1806                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1807                         return 0;
1808
1809         return bound(1, lms_lowest_lives, fl);
1810 }
1811
1812 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1813 // they win. Otherwise the defending team wins once the timelimit passes.
1814 void assault_new_round();
1815 float WinningCondition_Assault()
1816 {
1817         local float status;
1818
1819         WinningConditionHelper(); // set worldstatus
1820
1821         status = WINNING_NO;
1822         // as the timelimit has not yet passed just assume the defending team will win
1823         if(assault_attacker_team == COLOR_TEAM1)
1824         {
1825                 SetWinners(team, COLOR_TEAM2);
1826         }
1827         else
1828         {
1829                 SetWinners(team, COLOR_TEAM1);
1830         }
1831
1832         local entity ent;
1833         ent = find(world, classname, "target_assault_roundend");
1834         if(ent)
1835         {
1836                 if(ent.winning) // round end has been triggered by attacking team
1837                 {
1838                         bprint("ASSAULT: round completed...\n");
1839                         SetWinners(team, assault_attacker_team);
1840
1841                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1842
1843                         if(ent.cnt == 1 || cvar("g_campaign")) // this was the second round
1844                         {
1845                                 status = WINNING_YES;
1846                         }
1847                         else
1848                         {
1849                                 local entity oldself;
1850                                 oldself = self;
1851                                 self = ent;
1852                                 assault_new_round();
1853                                 self = oldself;
1854                         }
1855                 }
1856         }
1857
1858         return status;
1859 }
1860
1861 // LMS winning condition: game terminates if and only if there's at most one
1862 // one player who's living lives. Top two scores being equal cancels the time
1863 // limit.
1864 float WinningCondition_LMS()
1865 {
1866         entity head, head2;
1867         float have_player;
1868         float have_players;
1869         float l;
1870
1871         have_player = FALSE;
1872         have_players = FALSE;
1873         l = LMS_NewPlayerLives();
1874
1875         head = find(world, classname, "player");
1876         if(head)
1877                 have_player = TRUE;
1878         head2 = find(head, classname, "player");
1879         if(head2)
1880                 have_players = TRUE;
1881
1882         if(have_player)
1883         {
1884                 // we have at least one player
1885                 if(have_players)
1886                 {
1887                         // two or more active players - continue with the game
1888                 }
1889                 else
1890                 {
1891                         // exactly one player?
1892
1893                         ClearWinners();
1894                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1895
1896                         if(l)
1897                         {
1898                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1899                                 return WINNING_NO;
1900                         }
1901                         else
1902                         {
1903                                 // a winner!
1904                                 // and assign him his first place
1905                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1906                                 return WINNING_YES;
1907                         }
1908                 }
1909         }
1910         else
1911         {
1912                 // nobody is playing at all...
1913                 if(l)
1914                 {
1915                         // wait for players...
1916                 }
1917                 else
1918                 {
1919                         // SNAFU (maybe a draw game?)
1920                         ClearWinners();
1921                         dprint("No players, ending game.\n");
1922                         return WINNING_YES;
1923                 }
1924         }
1925
1926         // When we get here, we have at least two players who are actually LIVING,
1927         // now check if the top two players have equal score.
1928         WinningConditionHelper();
1929
1930         ClearWinners();
1931         if(WinningConditionHelper_winner)
1932                 WinningConditionHelper_winner.winning = TRUE;
1933         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1934                 return WINNING_NEVER;
1935
1936         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1937         return WINNING_NO;
1938 }
1939
1940 void ShuffleMaplist()
1941 {
1942         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1943 }
1944
1945 float leaderfrags;
1946 float WinningCondition_Scores(float limit, float leadlimit)
1947 {
1948         float limitreached;
1949
1950         // TODO make everything use THIS winning condition (except LMS)
1951         WinningConditionHelper();
1952
1953         if(teams_matter)
1954         {
1955                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1956                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1957                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1958                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1959         }
1960
1961         ClearWinners();
1962         if(WinningConditionHelper_winner)
1963                 WinningConditionHelper_winner.winning = 1;
1964         if(WinningConditionHelper_winnerteam >= 0)
1965                 SetWinners(team, WinningConditionHelper_winnerteam);
1966
1967         if(WinningConditionHelper_lowerisbetter)
1968         {
1969                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1970                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1971                 limit = -limit;
1972         }
1973
1974         if(WinningConditionHelper_zeroisworst)
1975                 leadlimit = 0; // not supported in this mode
1976
1977         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1978         // these modes always score in increments of 1, thus this makes sense
1979         {
1980                 if(leaderfrags != WinningConditionHelper_topscore)
1981                 {
1982                         leaderfrags = WinningConditionHelper_topscore;
1983
1984                         if (limit)
1985                         if (leaderfrags == limit - 1)
1986                                 Announce("1fragleft");
1987                         else if (leaderfrags == limit - 2)
1988                                 Announce("2fragsleft");
1989                         else if (leaderfrags == limit - 3)
1990                                 Announce("3fragsleft");
1991                 }
1992         }
1993
1994         limitreached = FALSE;
1995         if(limit)
1996                 if(WinningConditionHelper_topscore >= limit)
1997                         limitreached = TRUE;
1998         if(leadlimit)
1999         {
2000                 float leadlimitreached;
2001                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
2002                 if(cvar("leadlimit_and_fraglimit"))
2003                         limitreached = (limitreached && leadlimitreached);
2004                 else
2005                         limitreached = (limitreached || leadlimitreached);
2006         }
2007
2008         return GetWinningCode(
2009                 WinningConditionHelper_topscore && limitreached,
2010                 WinningConditionHelper_equality
2011         );
2012 }
2013
2014 float WinningCondition_Race(float fraglimit)
2015 {
2016         float wc;
2017         entity p;
2018         float n, c;
2019
2020         n = 0;
2021         c = 0;
2022         FOR_EACH_PLAYER(p)
2023         {
2024                 ++n;
2025                 if(p.race_completed)
2026                         ++c;
2027         }
2028         if(n && (n == c))
2029                 return WINNING_YES;
2030         wc = WinningCondition_Scores(fraglimit, 0);
2031
2032         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2033         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2034         // do NOT support equality when the laps are all raced!
2035                 return WINNING_STARTSUDDENDEATHOVERTIME;
2036         else
2037                 return WINNING_NEVER;
2038         return wc;
2039 }
2040
2041 void ReadyRestart();
2042 float WinningCondition_QualifyingThenRace(float limit)
2043 {
2044         float wc;
2045         wc = WinningCondition_Scores(limit, 0);
2046
2047         // NEVER initiate overtime
2048         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2049         {
2050                 return WINNING_YES;
2051         }
2052
2053         return wc;
2054 }
2055
2056 float WinningCondition_RanOutOfSpawns()
2057 {
2058         entity head;
2059
2060         if(have_team_spawns <= 0)
2061                 return WINNING_NO;
2062
2063         if(!some_spawn_has_been_used)
2064                 return WINNING_NO;
2065
2066         team1_score = team2_score = team3_score = team4_score = 0;
2067
2068         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2069         {
2070                 if(head.team == COLOR_TEAM1)
2071                         team1_score = 1;
2072                 else if(head.team == COLOR_TEAM2)
2073                         team2_score = 1;
2074                 else if(head.team == COLOR_TEAM3)
2075                         team3_score = 1;
2076                 else if(head.team == COLOR_TEAM4)
2077                         team4_score = 1;
2078         }
2079
2080         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2081         {
2082                 if(head.team == COLOR_TEAM1)
2083                         team1_score = 1;
2084                 else if(head.team == COLOR_TEAM2)
2085                         team2_score = 1;
2086                 else if(head.team == COLOR_TEAM3)
2087                         team3_score = 1;
2088                 else if(head.team == COLOR_TEAM4)
2089                         team4_score = 1;
2090         }
2091
2092         ClearWinners();
2093         if(team1_score + team2_score + team3_score + team4_score == 0)
2094         {
2095                 checkrules_equality = TRUE;
2096                 return WINNING_YES;
2097         }
2098         else if(team1_score + team2_score + team3_score + team4_score == 1)
2099         {
2100                 float t, i;
2101                 if(team1_score) t = COLOR_TEAM1;
2102                 if(team2_score) t = COLOR_TEAM2;
2103                 if(team3_score) t = COLOR_TEAM3;
2104                 if(team4_score) t = COLOR_TEAM4;
2105                 CheckAllowedTeams(world);
2106                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2107                 {
2108                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2109                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2110                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2111                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2112                 }
2113
2114                 AddWinners(team, t);
2115                 return WINNING_YES;
2116         }
2117         else
2118                 return WINNING_NO;
2119 }
2120
2121 /*
2122 ============
2123 CheckRules_World
2124
2125 Exit deathmatch games upon conditions
2126 ============
2127 */
2128 void CheckRules_World()
2129 {
2130         float timelimit;
2131         float fraglimit;
2132         float leadlimit;
2133
2134         VoteThink();
2135         MapVote_Think();
2136
2137         SetDefaultAlpha();
2138
2139         /*
2140         MapVote_Think should now do that part
2141         if (intermission_running)
2142                 if (time >= intermission_exittime + 60)
2143                 {
2144                         if(!DoNextMapOverride())
2145                                 GotoNextMap();
2146                         return;
2147                 }
2148         */
2149
2150         if (gameover)   // someone else quit the game already
2151         {
2152                 if(player_count == 0) // Nobody there? Then let's go to the next map
2153                         MapVote_Start();
2154                         // this will actually check the player count in the next frame
2155                         // again, but this shouldn't hurt
2156                 return;
2157         }
2158
2159         timelimit = cvar("timelimit") * 60;
2160         fraglimit = cvar("fraglimit");
2161         leadlimit = cvar("leadlimit");
2162
2163         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2164         {
2165                 if(timelimit > 0)
2166                         timelimit = 0; // timelimit is not made for warmup
2167                 if(fraglimit > 0)
2168                         fraglimit = 0; // no fraglimit for now
2169                 leadlimit = 0; // no leadlimit for now
2170         }
2171
2172         if(g_onslaught)
2173                 timelimit = 0; // ONS has its own overtime rule
2174
2175         if(timelimit > 0)
2176         {
2177                 timelimit += game_starttime;
2178         }
2179         else if (timelimit < 0)
2180         {
2181                 // endmatch
2182                 NextLevel();
2183                 return;
2184         }
2185
2186         float wantovertime;
2187         wantovertime = 0;
2188
2189         if(checkrules_suddendeathend)
2190         {
2191                 if(!checkrules_suddendeathwarning)
2192                 {
2193                         checkrules_suddendeathwarning = TRUE;
2194                         if(g_race && !g_race_qualifying)
2195                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2196                         else
2197                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2198                 }
2199         }
2200         else
2201         {
2202                 if (timelimit && time >= timelimit)
2203                 {
2204                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2205                         {
2206                                 float totalplayers;
2207                                 float playerswithlaps;
2208                                 float readyplayers;
2209                                 entity head;
2210                                 totalplayers = playerswithlaps = readyplayers = 0;
2211                                 FOR_EACH_PLAYER(head)
2212                                 {
2213                                         ++totalplayers;
2214                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2215                                                 ++playerswithlaps;
2216                                         if(head.ready)
2217                                                 ++readyplayers;
2218                                 }
2219
2220                                 // at least 2 of the players have completed a lap: start the RACE
2221                                 // otherwise, the players should end the qualifying on their own
2222                                 if(readyplayers || playerswithlaps >= 2)
2223                                 {
2224                                         checkrules_suddendeathend = 0;
2225                                         ReadyRestart(); // go to race
2226                                         return;
2227                                 }
2228                                 else
2229                                         wantovertime |= InitiateSuddenDeath();
2230                         }
2231                         else
2232                                 wantovertime |= InitiateSuddenDeath();
2233                 }
2234         }
2235
2236         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2237         {
2238                 NextLevel();
2239                 return;
2240         }
2241
2242         float checkrules_status;
2243         checkrules_status = WinningCondition_RanOutOfSpawns();
2244         if(checkrules_status == WINNING_YES)
2245         {
2246                 bprint("Hey! Someone ran out of spawns!\n");
2247         }
2248         else if(g_race && !g_race_qualifying && timelimit >= 0)
2249         {
2250                 checkrules_status = WinningCondition_Race(fraglimit);
2251                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2252         }
2253         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2254         {
2255                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2256                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2257         }
2258         else if(g_assault)
2259         {
2260                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2261         }
2262         else if(g_lms)
2263         {
2264                 checkrules_status = WinningCondition_LMS();
2265         }
2266         else if (g_onslaught)
2267         {
2268                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2269         }
2270         else
2271         {
2272                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2273                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2274         }
2275
2276         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2277         {
2278                 checkrules_status = WINNING_NEVER;
2279                 checkrules_overtimesadded = -1;
2280                 wantovertime |= InitiateSuddenDeath();
2281         }
2282
2283         if(checkrules_status == WINNING_NEVER)
2284                 // equality cases! Nobody wins if the overtime ends in a draw.
2285                 ClearWinners();
2286
2287         if(wantovertime)
2288         {
2289                 if(checkrules_status == WINNING_NEVER)
2290                         InitiateOvertime();
2291                 else
2292                         checkrules_status = WINNING_YES;
2293         }
2294
2295         if(checkrules_suddendeathend)
2296                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2297                         checkrules_status = WINNING_YES;
2298
2299         if(checkrules_status == WINNING_YES)
2300         {
2301                 //print("WINNING\n");
2302                 NextLevel();
2303         }
2304 };
2305
2306 float mapvote_nextthink;
2307 float mapvote_initialized;
2308 float mapvote_keeptwotime;
2309 float mapvote_timeout;
2310 string mapvote_message;
2311 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2312 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2313 float mapvote_screenshot_dirs_count;
2314
2315 float mapvote_count;
2316 float mapvote_count_real;
2317 string mapvote_maps[MAPVOTE_COUNT];
2318 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2319 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2320 float mapvote_maps_suggested[MAPVOTE_COUNT];
2321 string mapvote_suggestions[MAPVOTE_COUNT];
2322 float mapvote_suggestion_ptr;
2323 float mapvote_maxlen;
2324 float mapvote_voters;
2325 float mapvote_votes[MAPVOTE_COUNT];
2326 float mapvote_run;
2327 float mapvote_detail;
2328 float mapvote_abstain;
2329 .float mapvote;
2330
2331 void MapVote_ClearAllVotes()
2332 {
2333         FOR_EACH_CLIENT(other)
2334                 other.mapvote = 0;
2335 }
2336
2337 string MapVote_Suggest(string m)
2338 {
2339         float i;
2340         if(m == "")
2341                 return "That's not how to use this command.";
2342         if(!cvar("g_maplist_votable_suggestions"))
2343                 return "Suggestions are not accepted on this server.";
2344         if(mapvote_initialized)
2345                 return "Can't suggest - voting is already in progress!";
2346         m = MapInfo_FixName(m);
2347         if(!m)
2348                 return "The map you suggested is not available on this server.";
2349         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2350                 if(Map_IsRecent(m))
2351                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2352
2353         if(!MapInfo_CheckMap(m))
2354                 return "The map you suggested does not support the current game mode.";
2355         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2356                 if(mapvote_suggestions[i] == m)
2357                         return "This map was already suggested.";
2358         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2359         {
2360                 i = floor(random() * mapvote_suggestion_ptr);
2361         }
2362         else
2363         {
2364                 i = mapvote_suggestion_ptr;
2365                 mapvote_suggestion_ptr += 1;
2366         }
2367         if(mapvote_suggestions[i] != "")
2368                 strunzone(mapvote_suggestions[i]);
2369         mapvote_suggestions[i] = strzone(m);
2370         if(cvar("sv_eventlog"))
2371                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2372         return strcat("Suggestion of ", m, " accepted.");
2373 }
2374
2375 void MapVote_AddVotable(string nextMap, float isSuggestion)
2376 {
2377         float j, i, o;
2378         string pakfile, mapfile;
2379
2380         if(nextMap == "")
2381                 return;
2382         for(j = 0; j < mapvote_count; ++j)
2383                 if(mapvote_maps[j] == nextMap)
2384                         return;
2385         if(strlen(nextMap) > mapvote_maxlen)
2386                 mapvote_maxlen = strlen(nextMap);
2387         mapvote_maps[mapvote_count] = strzone(nextMap);
2388         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2389
2390         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2391         {
2392                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2393                 pakfile = whichpack(strcat(mapfile, ".tga"));
2394                 if(pakfile == "")
2395                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2396                 if(pakfile == "")
2397                         pakfile = whichpack(strcat(mapfile, ".png"));
2398                 if(pakfile != "")
2399                         break;
2400         }
2401         if(i >= mapvote_screenshot_dirs_count)
2402                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2403         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2404                 pakfile = substring(pakfile, o, -1);
2405
2406         mapvote_maps_screenshot_dir[mapvote_count] = i;
2407         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2408
2409         mapvote_count += 1;
2410 }
2411
2412 void MapVote_Spawn();
2413 void MapVote_Init()
2414 {
2415         float i;
2416         float nmax, smax;
2417
2418         MapVote_ClearAllVotes();
2419
2420         mapvote_count = 0;
2421         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2422         mapvote_abstain = cvar("g_maplist_votable_abstain");
2423
2424         if(mapvote_abstain)
2425                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2426         else
2427                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2428         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2429
2430         // we need this for AddVotable, as that cycles through the screenshot dirs
2431         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2432         if(mapvote_screenshot_dirs_count == 0)
2433                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2434         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2435         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2436                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2437
2438         if(mapvote_suggestion_ptr)
2439                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2440                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2441
2442         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2443                 MapVote_AddVotable(GetNextMap(), FALSE);
2444
2445         if(mapvote_count == 0)
2446         {
2447                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2448                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2449                 if(cvar("g_maplist_shuffle"))
2450                         ShuffleMaplist();
2451                 localcmd("\nmenu_cmd sync\n");
2452                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2453                         MapVote_AddVotable(GetNextMap(), FALSE);
2454         }
2455
2456         mapvote_count_real = mapvote_count;
2457         if(mapvote_abstain)
2458                 MapVote_AddVotable("don't care", 0);
2459
2460         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2461
2462         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2463         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2464         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2465                 mapvote_keeptwotime = 0;
2466         mapvote_message = "Choose a map and press its key!";
2467
2468         MapVote_Spawn();
2469 }
2470
2471 void MapVote_SendPicture(float id)
2472 {
2473         msg_entity = self;
2474         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2475         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2476         WriteByte(MSG_ONE, id);
2477         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2478 }
2479
2480 float GameCommand_MapVote(string cmd)
2481 {
2482         if(!intermission_running)
2483                 return FALSE;
2484
2485         if(cmd == "mv_getpic")
2486         {
2487                 MapVote_SendPicture(stof(argv(1)));
2488                 return TRUE;
2489         }
2490
2491         return FALSE;
2492 }
2493
2494 float MapVote_GetMapMask()
2495 {
2496         float mask, i, power;
2497         mask = 0;
2498         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2499                 if(mapvote_maps[i] != "")
2500                         mask |= power;
2501         return mask;
2502 }
2503
2504 entity mapvote_ent;
2505 float MapVote_SendEntity(entity to, float sf)
2506 {
2507         float i;
2508
2509         if(sf & 1)
2510                 sf &~= 2; // if we send 1, we don't need to also send 2
2511
2512         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2513         WriteByte(MSG_ENTITY, sf);
2514
2515         if(sf & 1)
2516         {
2517                 // flag 1 == initialization
2518                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2519                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2520                 WriteString(MSG_ENTITY, "");
2521                 WriteByte(MSG_ENTITY, mapvote_count);
2522                 WriteByte(MSG_ENTITY, mapvote_abstain);
2523                 WriteByte(MSG_ENTITY, mapvote_detail);
2524                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2525                 if(mapvote_count <= 8)
2526                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2527                 else
2528                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2529                 for(i = 0; i < mapvote_count; ++i)
2530                         if(mapvote_maps[i] != "")
2531                         {
2532                                 if(mapvote_abstain && i == mapvote_count - 1)
2533                                 {
2534                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2535                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2536                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2537                                 }
2538                                 else
2539                                 {
2540                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2541                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2542                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2543                                 }
2544                         }
2545         }
2546
2547         if(sf & 2)
2548         {
2549                 // flag 2 == update of mask
2550                 if(mapvote_count <= 8)
2551                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2552                 else
2553                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2554         }
2555
2556         if(sf & 4)
2557         {
2558                 if(mapvote_detail)
2559                         for(i = 0; i < mapvote_count; ++i)
2560                                 if(mapvote_maps[i] != "")
2561                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2562
2563                 WriteByte(MSG_ENTITY, to.mapvote);
2564         }
2565
2566         return TRUE;
2567 }
2568
2569 void MapVote_Spawn()
2570 {
2571         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2572 }
2573
2574 void MapVote_TouchMask()
2575 {
2576         mapvote_ent.SendFlags |= 2;
2577 }
2578
2579 void MapVote_TouchVotes(entity voter)
2580 {
2581         mapvote_ent.SendFlags |= 4;
2582 }
2583
2584 float MapVote_Finished(float mappos)
2585 {
2586         string result;
2587         float i;
2588         float didntvote;
2589
2590         if(cvar("sv_eventlog"))
2591         {
2592                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2593                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2594                 didntvote = mapvote_voters;
2595                 for(i = 0; i < mapvote_count; ++i)
2596                         if(mapvote_maps[i] != "")
2597                         {
2598                                 didntvote -= mapvote_votes[i];
2599                                 if(i != mappos)
2600                                 {
2601                                         result = strcat(result, ":", mapvote_maps[i]);
2602                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2603                                 }
2604                         }
2605                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2606
2607                 GameLogEcho(result);
2608                 if(mapvote_maps_suggested[mappos])
2609                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2610         }
2611
2612         FOR_EACH_REALCLIENT(other)
2613                 FixClientCvars(other);
2614
2615         Map_Goto_SetStr(mapvote_maps[mappos]);
2616         Map_Goto();
2617         alreadychangedlevel = TRUE;
2618         return TRUE;
2619 }
2620 void MapVote_CheckRules_1()
2621 {
2622         float i;
2623
2624         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2625         {
2626                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2627                 mapvote_votes[i] = 0;
2628         }
2629
2630         mapvote_voters = 0;
2631         FOR_EACH_REALCLIENT(other)
2632         {
2633                 ++mapvote_voters;
2634                 if(other.mapvote)
2635                 {
2636                         i = other.mapvote - 1;
2637                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2638                         mapvote_votes[i] = mapvote_votes[i] + 1;
2639                 }
2640         }
2641 }
2642
2643 float MapVote_CheckRules_2()
2644 {
2645         float i;
2646         float firstPlace, secondPlace;
2647         float firstPlaceVotes, secondPlaceVotes;
2648         float mapvote_voters_real;
2649         string result;
2650
2651         if(mapvote_count_real == 1)
2652                 return MapVote_Finished(0);
2653
2654         mapvote_voters_real = mapvote_voters;
2655         if(mapvote_abstain)
2656                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2657
2658         RandomSelection_Init();
2659         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2660                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2661         firstPlace = RandomSelection_chosen_float;
2662         firstPlaceVotes = RandomSelection_best_priority;
2663         //dprint("First place: ", ftos(firstPlace), "\n");
2664         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2665
2666         RandomSelection_Init();
2667         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2668                 if(i != firstPlace)
2669                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2670         secondPlace = RandomSelection_chosen_float;
2671         secondPlaceVotes = RandomSelection_best_priority;
2672         //dprint("Second place: ", ftos(secondPlace), "\n");
2673         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2674
2675         if(firstPlace == -1)
2676                 error("No first place in map vote... WTF?");
2677
2678         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2679                 return MapVote_Finished(firstPlace);
2680
2681         if(mapvote_keeptwotime)
2682                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2683                 {
2684                         float didntvote;
2685                         MapVote_TouchMask();
2686                         mapvote_message = "Now decide between the TOP TWO!";
2687                         mapvote_keeptwotime = 0;
2688                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2689                         result = strcat(result, ":", ftos(firstPlaceVotes));
2690                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2691                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2692                         didntvote = mapvote_voters;
2693                         for(i = 0; i < mapvote_count; ++i)
2694                                 if(mapvote_maps[i] != "")
2695                                 {
2696                                         didntvote -= mapvote_votes[i];
2697                                         if(i != firstPlace)
2698                                                 if(i != secondPlace)
2699                                                 {
2700                                                         result = strcat(result, ":", mapvote_maps[i]);
2701                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2702                                                         if(i < mapvote_count_real)
2703                                                         {
2704                                                                 strunzone(mapvote_maps[i]);
2705                                                                 mapvote_maps[i] = "";
2706                                                                 strunzone(mapvote_maps_pakfile[i]);
2707                                                                 mapvote_maps_pakfile[i] = "";
2708                                                         }
2709                                                 }
2710                                 }
2711                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2712                         if(cvar("sv_eventlog"))
2713                                 GameLogEcho(result);
2714                 }
2715
2716         return FALSE;
2717 }
2718 void MapVote_Tick()
2719 {
2720         float keeptwo;
2721         float totalvotes;
2722
2723         keeptwo = mapvote_keeptwotime;
2724         MapVote_CheckRules_1(); // count
2725         if(MapVote_CheckRules_2()) // decide
2726                 return;
2727
2728         totalvotes = 0;
2729         FOR_EACH_REALCLIENT(other)
2730         {
2731                 // hide scoreboard again
2732                 if(other.health != 2342)
2733                 {
2734                         other.health = 2342;
2735                         other.impulse = 0;
2736                         if(clienttype(other) == CLIENTTYPE_REAL)
2737                         {
2738                                 msg_entity = other;
2739                                 WriteByte(MSG_ONE, SVC_FINALE);
2740                                 WriteString(MSG_ONE, "");
2741                         }
2742                 }
2743
2744                 // clear possibly invalid votes
2745                 if(mapvote_maps[other.mapvote - 1] == "")
2746                         other.mapvote = 0;
2747                 // use impulses as new vote
2748                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2749                         if(mapvote_maps[other.impulse - 1] != "")
2750                         {
2751                                 other.mapvote = other.impulse;
2752                                 MapVote_TouchVotes(other);
2753                         }
2754                 other.impulse = 0;
2755
2756                 if(other.mapvote)
2757                         ++totalvotes;
2758         }
2759
2760         MapVote_CheckRules_1(); // just count
2761 }
2762 void MapVote_Start()
2763 {
2764         if(mapvote_run)
2765                 return;
2766
2767         MapInfo_Enumerate();
2768         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2769                 mapvote_run = TRUE;
2770 }
2771 void MapVote_Think()
2772 {
2773         if(!mapvote_run)
2774                 return;
2775
2776         if(alreadychangedlevel)
2777                 return;
2778
2779         if(time < mapvote_nextthink)
2780                 return;
2781         //dprint("tick\n");
2782
2783         mapvote_nextthink = time + 0.5;
2784
2785         if(!mapvote_initialized)
2786         {
2787                 if(cvar("rescan_pending") == 1)
2788                 {
2789                         cvar_set("rescan_pending", "2");
2790                         localcmd("fs_rescan\nrescan_pending 3\n");
2791                         return;
2792                 }
2793                 else if(cvar("rescan_pending") == 2)
2794                 {
2795                         return;
2796                 }
2797                 else if(cvar("rescan_pending") == 3)
2798                 {
2799                         // now build missing mapinfo files
2800                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2801                                 return;
2802
2803                         // we're done, start the timer
2804                         cvar_set("rescan_pending", "0");
2805                 }
2806
2807                 mapvote_initialized = TRUE;
2808                 if(DoNextMapOverride())
2809                         return;
2810                 if(!cvar("g_maplist_votable") || player_count <= 0)
2811                 {
2812                         GotoNextMap();
2813                         return;
2814                 }
2815                 MapVote_Init();
2816         }
2817
2818         MapVote_Tick();
2819 };
2820
2821 string GotoMap(string m)
2822 {
2823         if(!MapInfo_CheckMap(m))
2824                 return "The map you chose is not available on this server.";
2825         cvar_set("nextmap", m);
2826         cvar_set("timelimit", "-1");
2827         if(mapvote_initialized || alreadychangedlevel)
2828         {
2829                 if(DoNextMapOverride())
2830                         return "Map switch initiated.";
2831                 else
2832                         return "Hm... no. For some reason I like THIS map more.";
2833         }
2834         else
2835                 return "Map switch will happen after scoreboard.";
2836 }
2837
2838
2839 void EndFrame()
2840 {
2841         float altime;
2842         FOR_EACH_REALCLIENT(self)
2843         {
2844                 if(self.classname == "spectator")
2845                 {
2846                         if(self.enemy.typehitsound)
2847                                 play2(self, "misc/typehit.wav");
2848                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2849                                 play2(self, "misc/hit.wav");
2850                 }
2851                 else
2852                 {
2853                         if(self.typehitsound)
2854                                 play2(self, "misc/typehit.wav");
2855                         else if(self.hitsound && self.cvar_cl_hitsound)
2856                                 play2(self, "misc/hit.wav");
2857                 }
2858         }
2859         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2860         // add 1 frametime because after this, engine SV_Physics
2861         // increases time by a frametime and then networks the frame
2862         // add another frametime because client shows everything with
2863         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2864         // needed!
2865         FOR_EACH_CLIENT(self)
2866         {
2867                 self.hitsound = FALSE;
2868                 self.typehitsound = FALSE;
2869                 antilag_record(self, altime);
2870         }
2871 }
2872
2873
2874 /*
2875  * RedirectionThink:
2876  * returns TRUE if redirecting
2877  */
2878 float redirection_timeout;
2879 float redirection_nextthink;
2880 float RedirectionThink()
2881 {
2882         float clients_found;
2883
2884         if(redirection_target == "")
2885                 return FALSE;
2886
2887         if(!redirection_timeout)
2888         {
2889                 cvar_set("sv_public", "-2");
2890                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2891                 if(redirection_target == "self")
2892                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2893                 else
2894                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2895         }
2896
2897         if(time < redirection_nextthink)
2898                 return TRUE;
2899
2900         redirection_nextthink = time + 1;
2901
2902         clients_found = 0;
2903         FOR_EACH_REALCLIENT(self)
2904         {
2905                 print("Redirecting: sending connect command to ", self.netname, "\n");
2906                 if(redirection_target == "self")
2907                         stuffcmd(self, "\ndisconnect; reconnect\n");
2908                 else
2909                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2910                 ++clients_found;
2911         }
2912
2913         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2914
2915         if(time > redirection_timeout || clients_found == 0)
2916                 localcmd("\nwait; wait; wait; quit\n");
2917
2918         return TRUE;
2919 }
2920
2921 void TargetMusic_RestoreGame();
2922 void RestoreGame()
2923 {
2924         // Loaded from a save game
2925         // some things then break, so let's work around them...
2926
2927         // Progs DB (capture records)
2928         ServerProgsDB = db_load("server.db");
2929
2930         // Mapinfo
2931         MapInfo_Shutdown();
2932         MapInfo_Enumerate();
2933         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2934         WeaponStats_Init();
2935
2936         TargetMusic_RestoreGame();
2937 }
2938
2939 void SV_Shutdown()
2940 {
2941         if(gameover > 1) // shutting down already?
2942                 return;
2943
2944         gameover = 2; // 2 = server shutting down
2945
2946         if(world_initialized > 0)
2947         {
2948                 world_initialized = 0;
2949                 print("Saving persistent data...\n");
2950                 Ban_SaveBans();
2951                 if(!cheatcount_total)
2952                 {
2953                         if(cvar("sv_db_saveasdump"))
2954                                 db_dump(ServerProgsDB, "server.db");
2955                         else
2956                                 db_save(ServerProgsDB, "server.db");
2957                 }
2958                 if(cvar("developer"))
2959                 {
2960                         if(cvar("sv_db_saveasdump"))
2961                                 db_dump(TemporaryDB, "server-temp.db");
2962                         else
2963                                 db_save(TemporaryDB, "server-temp.db");
2964                 }
2965                 CheatShutdown(); // must be after cheatcount check
2966                 db_close(ServerProgsDB);
2967                 db_close(TemporaryDB);
2968                 print("done!\n");
2969                 // tell the bot system the game is ending now
2970                 bot_endgame();
2971
2972                 WeaponStats_Shutdown();
2973                 MapInfo_Shutdown();
2974         }
2975         else if(world_initialized == 0)
2976         {
2977                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2978         }
2979 }