qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2 #include "_all.qh"
   3
   4 #include "anticheat.qh"
   5 #include "antilag.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/mutators_include.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/buffs/all.qh"
  22 #include "../common/constants.qh"
  23 #include "../common/deathtypes.qh"
  24 #include "../common/effects/effects.qh"
  25 #include "../common/mapinfo.qh"
  26 #include "../common/monsters/all.qh"
  27 #include "../common/monsters/sv_monsters.qh"
  28 #include "../common/vehicles/all.qh"
  29 #include "../common/notifications.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/util.qh"
  34 #include "../common/items/all.qh"
  35 #include "../common/weapons/all.qh"
  36
  37 const float LATENCY_THINKRATE = 10;
  38 .float latency_sum;
  39 .float latency_cnt;
  40 .float latency_time;
  41 entity pingplreport;
  42 void PingPLReport_Think()
  43 {SELFPARAM();
  44         float delta;
  45         entity e;
  46
  47         delta = 3 / maxclients;
  48         if(delta < sys_frametime)
  49                 delta = 0;
  50         self.nextthink = time + delta;
  51
  52         e = edict_num(self.cnt + 1);
  53         if(IS_REAL_CLIENT(e))
  54         {
  55                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  56                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  57                 WriteByte(MSG_BROADCAST, self.cnt);
  58                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  59                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  61
  62                 // record latency times for clients throughout the match so we can report it to playerstats
  63                 if(time > (e.latency_time + LATENCY_THINKRATE))
  64                 {
  65                         e.latency_sum += e.ping;
  66                         e.latency_cnt += 1;
  67                         e.latency_time = time;
  68                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  69                 }
  70         }
  71         else
  72         {
  73                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  74                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = spawn();
  85         pingplreport.classname = "pingplreport";
  86         pingplreport.think = PingPLReport_Think;
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if(autocvar_g_running_guns)
 100         {
 101                 default_player_alpha = -1;
 102                 default_weapon_alpha = +1;
 103         }
 104         else if(g_cloaked)
 105         {
 106                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 107                 default_weapon_alpha = default_player_alpha;
 108         }
 109         else
 110         {
 111                 default_player_alpha = autocvar_g_player_alpha;
 112                 if(default_player_alpha == 0)
 113                         default_player_alpha = 1;
 114                 default_weapon_alpha = default_player_alpha;
 115         }
 116 }
 117
 118 void GotoFirstMap()
 119 {SELFPARAM();
 120         float n;
 121         if(autocvar__sv_init)
 122         {
 123                 // cvar_set("_sv_init", "0");
 124                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 125                 // to this "init" map on a dedicated server will cause no permanent
 126                 // harm
 127                 if(autocvar_g_maplist_shuffle)
 128                         ShuffleMaplist();
 129                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 130                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 131
 132                 MapInfo_Enumerate();
 133                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 134
 135                 if(!DoNextMapOverride(1))
 136                         GotoNextMap(1);
 137
 138                 return;
 139         }
 140
 141         if(time < 5)
 142         {
 143                 self.nextthink = time;
 144         }
 145         else
 146         {
 147                 self.nextthink = time + 1;
 148                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 149         }
 150 }
 151
 152 void cvar_changes_init()
 153 {
 154         float h;
 155         string k, v, d;
 156         float n, i, adding, pureadding;
 157
 158         if(cvar_changes)
 159                 strunzone(cvar_changes);
 160         cvar_changes = string_null;
 161         if(cvar_purechanges)
 162                 strunzone(cvar_purechanges);
 163         cvar_purechanges = string_null;
 164         cvar_purechanges_count = 0;
 165
 166         h = buf_create();
 167         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 168         n = buf_getsize(h);
 169
 170         adding = true;
 171         pureadding = true;
 172
 173         for(i = 0; i < n; ++i)
 174         {
 175                 k = bufstr_get(h, i);
 176
 177 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 178 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 179 #define BADCVAR(p) if(k == p) continue
 180
 181                 // general excludes and namespaces for server admin used cvars
 182                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 183
 184                 // internal
 185                 BADPREFIX("csqc_");
 186                 BADPREFIX("cvar_check_");
 187                 BADCVAR("gamecfg");
 188                 BADCVAR("g_configversion");
 189                 BADCVAR("g_maplist_index");
 190                 BADCVAR("halflifebsp");
 191                 BADCVAR("sv_mapformat_is_quake2");
 192                 BADCVAR("sv_mapformat_is_quake3");
 193                 BADPREFIX("sv_world");
 194
 195                 // client
 196                 BADPREFIX("chase_");
 197                 BADPREFIX("cl_");
 198                 BADPREFIX("con_");
 199                 BADPREFIX("scoreboard_");
 200                 BADPREFIX("g_campaign");
 201                 BADPREFIX("g_waypointsprite_");
 202                 BADPREFIX("gl_");
 203                 BADPREFIX("joy");
 204                 BADPREFIX("hud_");
 205                 BADPREFIX("m_");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("snd_");
 212                 BADPREFIX("show");
 213                 BADPREFIX("sensitivity");
 214                 BADPREFIX("userbind");
 215                 BADPREFIX("v_");
 216                 BADPREFIX("vid_");
 217                 BADPREFIX("crosshair");
 218                 BADCVAR("mod_q3bsp_lightmapmergepower");
 219                 BADCVAR("mod_q3bsp_nolightmaps");
 220                 BADCVAR("fov");
 221                 BADCVAR("mastervolume");
 222                 BADCVAR("volume");
 223                 BADCVAR("bgmvolume");
 224
 225                 // private
 226                 BADCVAR("developer");
 227                 BADCVAR("log_dest_udp");
 228                 BADCVAR("net_address");
 229                 BADCVAR("net_address_ipv6");
 230                 BADCVAR("port");
 231                 BADCVAR("savedgamecfg");
 232                 BADCVAR("serverconfig");
 233                 BADCVAR("sv_autoscreenshot");
 234                 BADCVAR("sv_heartbeatperiod");
 235                 BADCVAR("sv_vote_master_password");
 236                 BADCVAR("sys_colortranslation");
 237                 BADCVAR("sys_specialcharactertranslation");
 238                 BADCVAR("timeformat");
 239                 BADCVAR("timestamps");
 240                 BADPREFIX("developer_");
 241                 BADPREFIX("g_ban_");
 242                 BADPREFIX("g_banned_list");
 243                 BADPREFIX("g_chat_flood_");
 244                 BADPREFIX("g_ghost_items");
 245                 BADPREFIX("g_playerstats_");
 246                 BADPREFIX("g_respawn_ghosts");
 247                 BADPREFIX("g_voice_flood_");
 248                 BADPREFIX("log_file");
 249                 BADPREFIX("rcon_");
 250                 BADPREFIX("sv_allowdownloads");
 251                 BADPREFIX("sv_autodemo");
 252                 BADPREFIX("sv_curl_");
 253                 BADPREFIX("sv_eventlog");
 254                 BADPREFIX("sv_logscores_");
 255                 BADPREFIX("sv_master");
 256                 BADPREFIX("sv_weaponstats_");
 257                 BADPREFIX("sv_waypointsprite_");
 258                 BADCVAR("rescan_pending");
 259
 260                 // these can contain player IDs, so better hide
 261                 BADPREFIX("g_forced_team_");
 262
 263                 // mapinfo
 264                 BADCVAR("fraglimit");
 265                 BADCVAR("g_assault");
 266                 BADCVAR("g_ca");
 267                 BADCVAR("g_ca_teams");
 268                 BADCVAR("g_ctf");
 269                 BADCVAR("g_cts");
 270                 BADCVAR("g_dm");
 271                 BADCVAR("g_domination");
 272                 BADCVAR("g_domination_default_teams");
 273                 BADCVAR("g_freezetag");
 274                 BADCVAR("g_freezetag_teams");
 275                 BADCVAR("g_invasion_teams");
 276                 BADCVAR("g_keepaway");
 277                 BADCVAR("g_keyhunt");
 278                 BADCVAR("g_keyhunt_teams");
 279                 BADCVAR("g_lms");
 280                 BADCVAR("g_nexball");
 281                 BADCVAR("g_onslaught");
 282                 BADCVAR("g_race");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_tdm");
 285                 BADCVAR("g_tdm_teams");
 286                 BADCVAR("leadlimit");
 287                 BADCVAR("nextmap");
 288                 BADCVAR("teamplay");
 289                 BADCVAR("timelimit");
 290
 291                 // long
 292                 BADCVAR("hostname");
 293                 BADCVAR("g_maplist");
 294                 BADCVAR("g_maplist_mostrecent");
 295                 BADCVAR("sv_motd");
 296
 297                 v = cvar_string(k);
 298                 d = cvar_defstring(k);
 299                 if(v == d)
 300                         continue;
 301
 302                 if(adding)
 303                 {
 304                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 305                         if(strlen(cvar_changes) > 16384)
 306                         {
 307                                 cvar_changes = "// too many settings have been changed to show them here\n";
 308                                 adding = 0;
 309                         }
 310                 }
 311
 312                 // now check if the changes are actually gameplay relevant
 313
 314                 // does nothing visible
 315                 BADCVAR("captureleadlimit_override");
 316                 BADCVAR("g_balance_kill_delay");
 317                 BADCVAR("g_ca_point_limit");
 318                 BADCVAR("g_ca_point_leadlimit");
 319                 BADCVAR("g_ctf_captimerecord_always");
 320                 BADCVAR("g_ctf_flag_glowtrails");
 321                 BADCVAR("g_ctf_flag_pickup_verbosename");
 322                 BADCVAR("g_domination_point_leadlimit");
 323                 BADCVAR("g_forced_respawn");
 324                 BADCVAR("g_freezetag_point_limit");
 325                 BADCVAR("g_freezetag_point_leadlimit");
 326                 BADCVAR("g_keyhunt_point_leadlimit");
 327                 BADPREFIX("g_mod_");
 328                 BADCVAR("g_invasion_point_limit");
 329                 BADCVAR("g_nexball_goalleadlimit");
 330                 BADCVAR("g_tdm_point_limit");
 331                 BADCVAR("g_tdm_point_leadlimit");
 332                 BADCVAR("leadlimit_and_fraglimit");
 333                 BADCVAR("leadlimit_override");
 334                 BADCVAR("pausable");
 335                 BADCVAR("sv_allow_fullbright");
 336                 BADCVAR("sv_checkforpacketsduringsleep");
 337                 BADCVAR("sv_timeout");
 338                 BADPREFIX("sv_timeout_");
 339                 BADPREFIX("crypto_");
 340                 BADPREFIX("g_chat_");
 341                 BADPREFIX("g_ctf_captimerecord_");
 342                 BADPREFIX("g_maplist_votable_");
 343                 BADPREFIX("net_");
 344                 BADPREFIX("prvm_");
 345                 BADPREFIX("skill_");
 346                 BADPREFIX("sv_cullentities_");
 347                 BADPREFIX("sv_maxidle_");
 348                 BADPREFIX("sv_vote_");
 349                 BADPREFIX("timelimit_");
 350                 BADCVAR("gameversion");
 351                 BADPREFIX("gameversion_");
 352                 BADCVAR("sv_minigames");
 353                 BADPREFIX("sv_minigames_");
 354                 BADCVAR("sv_namechangetimer");
 355
 356                 // allowed changes to server admins (please sync this to server.cfg)
 357                 // vi commands:
 358                 //   :/"impure"/,$d
 359                 //   :g!,^\/\/[^ /],d
 360                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 361                 //   :%!sort
 362                 // yes, this does contain some redundant stuff, don't really care
 363                 BADCVAR("bot_config_file");
 364                 BADCVAR("bot_number");
 365                 BADCVAR("bot_prefix");
 366                 BADCVAR("bot_suffix");
 367                 BADCVAR("capturelimit_override");
 368                 BADCVAR("fraglimit_override");
 369                 BADCVAR("gametype");
 370                 BADCVAR("g_antilag");
 371                 BADCVAR("g_balance_teams");
 372                 BADCVAR("g_balance_teams_prevent_imbalance");
 373                 BADCVAR("g_balance_teams_scorefactor");
 374                 BADCVAR("g_ban_sync_trusted_servers");
 375                 BADCVAR("g_ban_sync_uri");
 376                 BADCVAR("g_ca_teams_override");
 377                 BADCVAR("g_ctf_ignore_frags");
 378                 BADCVAR("g_domination_point_limit");
 379                 BADCVAR("g_domination_teams_override");
 380                 BADCVAR("g_freezetag_teams_override");
 381                 BADCVAR("g_friendlyfire");
 382                 BADCVAR("g_fullbrightitems");
 383                 BADCVAR("g_fullbrightplayers");
 384                 BADCVAR("g_keyhunt_point_limit");
 385                 BADCVAR("g_keyhunt_teams_override");
 386                 BADCVAR("g_lms_lives_override");
 387                 BADCVAR("g_maplist");
 388                 BADCVAR("g_maplist_check_waypoints");
 389                 BADCVAR("g_maplist_mostrecent_count");
 390                 BADCVAR("g_maplist_shuffle");
 391                 BADCVAR("g_maplist_votable");
 392                 BADCVAR("g_maplist_votable_abstain");
 393                 BADCVAR("g_maplist_votable_nodetail");
 394                 BADCVAR("g_maplist_votable_suggestions");
 395                 BADCVAR("g_maxplayers");
 396                 BADCVAR("g_mirrordamage");
 397                 BADCVAR("g_nexball_goallimit");
 398                 BADCVAR("g_powerups");
 399                 BADCVAR("g_start_delay");
 400                 BADCVAR("g_tdm_teams_override");
 401                 BADCVAR("g_warmup");
 402                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 403                 BADCVAR("hostname");
 404                 BADCVAR("log_file");
 405                 BADCVAR("maxplayers");
 406                 BADCVAR("minplayers");
 407                 BADCVAR("net_address");
 408                 BADCVAR("port");
 409                 BADCVAR("rcon_password");
 410                 BADCVAR("rcon_restricted_commands");
 411                 BADCVAR("rcon_restricted_password");
 412                 BADCVAR("skill");
 413                 BADCVAR("sv_adminnick");
 414                 BADCVAR("sv_autoscreenshot");
 415                 BADCVAR("sv_autotaunt");
 416                 BADCVAR("sv_curl_defaulturl");
 417                 BADCVAR("sv_defaultcharacter");
 418                 BADCVAR("sv_defaultplayercolors");
 419                 BADCVAR("sv_defaultplayermodel");
 420                 BADCVAR("sv_defaultplayerskin");
 421                 BADCVAR("sv_maxidle");
 422                 BADCVAR("sv_maxrate");
 423                 BADCVAR("sv_motd");
 424                 BADCVAR("sv_public");
 425                 BADCVAR("sv_ready_restart");
 426                 BADCVAR("sv_status_privacy");
 427                 BADCVAR("sv_taunt");
 428                 BADCVAR("sv_vote_call");
 429                 BADCVAR("sv_vote_commands");
 430                 BADCVAR("sv_vote_majority_factor");
 431                 BADCVAR("sv_vote_master");
 432                 BADCVAR("sv_vote_master_commands");
 433                 BADCVAR("sv_vote_master_password");
 434                 BADCVAR("sv_vote_simple_majority_factor");
 435                 BADCVAR("teamplay_mode");
 436                 BADCVAR("timelimit_override");
 437                 BADCVAR("g_spawnshieldtime");
 438                 BADPREFIX("g_warmup_");
 439                 BADPREFIX("sv_ready_restart_");
 440
 441                 // mutators that announce themselves properly to the server browser
 442                 BADCVAR("g_instagib");
 443                 BADCVAR("g_new_toys");
 444                 BADCVAR("g_nix");
 445                 BADCVAR("g_grappling_hook");
 446                 BADCVAR("g_jetpack");
 447
 448 #undef BADPREFIX
 449 #undef BADCVAR
 450
 451                 if(pureadding)
 452                 {
 453                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 454                         if(strlen(cvar_purechanges) > 16384)
 455                         {
 456                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 457                                 pureadding = 0;
 458                         }
 459                 }
 460                 ++cvar_purechanges_count;
 461                 // WARNING: this variable is used for the server list
 462                 // NEVER dare to skip this code!
 463                 // Hacks to intentionally appearing as "pure server" even though you DO have
 464                 // modified settings may be punished by removal from the server list.
 465                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 466                 // though.
 467         }
 468         buf_del(h);
 469         if(cvar_changes == "")
 470                 cvar_changes = "// this server runs at default server settings\n";
 471         else
 472                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 473         cvar_changes = strzone(cvar_changes);
 474         if(cvar_purechanges == "")
 475                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 476         else
 477                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 478         cvar_purechanges = strzone(cvar_purechanges);
 479 }
 480
 481 void detect_maptype()
 482 {
 483 #if 0
 484         vector o, v;
 485         float i;
 486
 487         for (;;)
 488         {
 489                 o = world.mins;
 490                 o.x += random() * (world.maxs.x - world.mins.x);
 491                 o.y += random() * (world.maxs.y - world.mins.y);
 492                 o.z += random() * (world.maxs.z - world.mins.z);
 493
 494                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 495                 if(trace_fraction == 1)
 496                         continue;
 497
 498                 v = trace_endpos;
 499
 500                 for(i = 0; i < 64; i += 4)
 501                 {
 502                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 503         if(trace_fraction == 1)
 504                 continue;
 505                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 506                 }
 507
 508                 break;
 509         }
 510 #endif
 511 }
 512
 513 entity randomseed;
 514 bool RandomSeed_Send(entity this, entity to, int sf)
 515 {
 516         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 517         WriteShort(MSG_ENTITY, self.cnt);
 518         return true;
 519 }
 520 void RandomSeed_Think()
 521 {SELFPARAM();
 522         self.cnt = bound(0, floor(random() * 65536), 65535);
 523         self.nextthink = time + 5;
 524
 525         self.SendFlags |= 1;
 526 }
 527 void RandomSeed_Spawn()
 528 {SELFPARAM();
 529         randomseed = spawn();
 530         randomseed.think = RandomSeed_Think;
 531         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 532
 533         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 534 }
 535
 536 spawnfunc(__init_dedicated_server)
 537 {
 538         // handler for _init/_init map (only for dedicated server initialization)
 539
 540         world_initialized = -1; // don't complain
 541         cvar = cvar_normal;
 542         cvar_string = cvar_string_normal;
 543         cvar_set = cvar_set_normal;
 544
 545         remove = remove_unsafely;
 546
 547         entity e;
 548         e = spawn();
 549         e.think = GotoFirstMap;
 550         e.nextthink = time; // this is usually 1 at this point
 551
 552         e = spawn();
 553         e.classname = "info_player_deathmatch"; // safeguard against player joining
 554
 555         self.classname = "worldspawn"; // safeguard against various stuff ;)
 556
 557         // needs to be done so early because of the constants they create
 558         static_init();
 559         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 560         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 561
 562         MapInfo_Enumerate();
 563         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 564 }
 565
 566 void Map_MarkAsRecent(string m);
 567 float world_already_spawned;
 568 void Nagger_Init();
 569 void ClientInit_Spawn();
 570 void WeaponStats_Init();
 571 void WeaponStats_Shutdown();
 572 void Physics_AddStats();
 573 spawnfunc(worldspawn)
 574 {
 575         float fd, l, j, n;
 576         string s;
 577
 578         cvar = cvar_normal;
 579         cvar_string = cvar_string_normal;
 580         cvar_set = cvar_set_normal;
 581
 582         if(world_already_spawned)
 583                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 584         world_already_spawned = true;
 585
 586         remove = remove_safely; // during spawning, watch what you remove!
 587
 588         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 589
 590         compressShortVector_init();
 591
 592         entity head;
 593         head = nextent(world);
 594         maxclients = 0;
 595         while(head)
 596         {
 597                 ++maxclients;
 598                 head = nextent(head);
 599         }
 600
 601         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 602
 603         // needs to be done so early because of the constants they create
 604         static_init();
 605         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 606         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 607
 608         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 609
 610         TemporaryDB = db_create();
 611
 612         // 0 normal
 613         lightstyle(0, "m");
 614
 615         // 1 FLICKER (first variety)
 616         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 617
 618         // 2 SLOW STRONG PULSE
 619         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 620
 621         // 3 CANDLE (first variety)
 622         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 623
 624         // 4 FAST STROBE
 625         lightstyle(4, "mamamamamama");
 626
 627         // 5 GENTLE PULSE 1
 628         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 629
 630         // 6 FLICKER (second variety)
 631         lightstyle(6, "nmonqnmomnmomomno");
 632
 633         // 7 CANDLE (second variety)
 634         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 635
 636         // 8 CANDLE (third variety)
 637         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 638
 639         // 9 SLOW STROBE (fourth variety)
 640         lightstyle(9, "aaaaaaaazzzzzzzz");
 641
 642         // 10 FLUORESCENT FLICKER
 643         lightstyle(10, "mmamammmmammamamaaamammma");
 644
 645         // 11 SLOW PULSE NOT FADE TO BLACK
 646         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 647
 648         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 649
 650         // 63 testing
 651         lightstyle(63, "a");
 652
 653         if(autocvar_g_campaign)
 654                 CampaignPreInit();
 655
 656         Map_MarkAsRecent(mapname);
 657
 658         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 659
 660         InitGameplayMode();
 661         readlevelcvars();
 662         GrappleHookInit();
 663
 664         player_count = 0;
 665         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 666         if(bot_waypoints_for_items == 1)
 667                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 668                         bot_waypoints_for_items = 0;
 669
 670         precache();
 671
 672         WaypointSprite_Init();
 673
 674         GameLogInit(); // prepare everything
 675         // NOTE for matchid:
 676         // changing the logic generating it is okay. But:
 677         // it HAS to stay <= 64 chars
 678         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 679         if(autocvar_sv_eventlog)
 680         {
 681                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 682                 matchid = strzone(s);
 683
 684                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 685                 s = ":gameinfo:mutators:LIST";
 686
 687                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 688                 s = ret_string;
 689
 690                 // initialiation stuff, not good in the mutator system
 691                 if(!autocvar_g_use_ammunition)
 692                         s = strcat(s, ":no_use_ammunition");
 693
 694                 // initialiation stuff, not good in the mutator system
 695                 if(autocvar_g_pickup_items == 0)
 696                         s = strcat(s, ":no_pickup_items");
 697                 if(autocvar_g_pickup_items > 0)
 698                         s = strcat(s, ":pickup_items");
 699
 700                 // initialiation stuff, not good in the mutator system
 701                 if(autocvar_g_weaponarena != "0")
 702                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 703
 704                 // TODO to mutator system
 705                 if(autocvar_g_norecoil)
 706                         s = strcat(s, ":norecoil");
 707
 708                 // TODO to mutator system
 709                 if(autocvar_g_powerups == 0)
 710                         s = strcat(s, ":no_powerups");
 711                 if(autocvar_g_powerups > 0)
 712                         s = strcat(s, ":powerups");
 713
 714                 GameLogEcho(s);
 715                 GameLogEcho(":gameinfo:end");
 716         }
 717         else
 718                 matchid = strzone(ftos(random()));
 719
 720         cvar_set("nextmap", "");
 721
 722         SetDefaultAlpha();
 723
 724         if(autocvar_g_campaign)
 725                 CampaignPostInit();
 726
 727         Ban_LoadBans();
 728
 729         MapInfo_Enumerate();
 730         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 731
 732         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 733         {
 734                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 735                 if(fd != -1)
 736                 {
 737                         while((s = fgets(fd)))
 738                         {
 739                                 l = tokenize_console(s);
 740                                 if(l < 2)
 741                                         continue;
 742                                 if(argv(0) == "cd")
 743                                 {
 744                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 745                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 746                                 }
 747                                 else if(argv(0) == "fog")
 748                                 {
 749                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 750                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 751                                 }
 752                                 else if(argv(0) == "set")
 753                                 {
 754                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 755                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 756                                 }
 757                                 else if(argv(0) != "//")
 758                                 {
 759                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 760                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 761                                 }
 762                         }
 763                         fclose(fd);
 764                 }
 765         }
 766
 767         WeaponStats_Init();
 768
 769         WepSet_AddStat();
 770         WepSet_AddStat_InMap();
 771         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 772         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 773         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 774         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 775         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 776         Nagger_Init();
 777
 778         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 779         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 780         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 781         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 782         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 783         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 784         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 785         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 786         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 787         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 788         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 789         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 790         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 791         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 792         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 793
 794         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 795         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 796
 797         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 798
 799         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 800
 801         // freeze attacks
 802         addstat(STAT_FROZEN, AS_INT, frozen);
 803         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 804
 805         // physics
 806         Physics_AddStats();
 807
 808         // new properties
 809         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_sv_jumpvelocity);
 810         addstat(STAT_MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, AS_FLOAT, stat_sv_airaccel_qw_stretchfactor);
 811         addstat(STAT_MOVEVARS_MAXAIRSTRAFESPEED, AS_FLOAT, stat_sv_maxairstrafespeed);
 812         addstat(STAT_MOVEVARS_MAXAIRSPEED, AS_FLOAT, stat_sv_maxairspeed);
 813         addstat(STAT_MOVEVARS_AIRSTRAFEACCELERATE, AS_FLOAT, stat_sv_airstrafeaccelerate);
 814         addstat(STAT_MOVEVARS_WARSOWBUNNY_TURNACCEL, AS_FLOAT, stat_sv_warsowbunny_turnaccel);
 815         addstat(STAT_MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, AS_FLOAT, stat_sv_airaccel_sideways_friction);
 816         addstat(STAT_MOVEVARS_AIRCONTROL, AS_FLOAT, stat_sv_aircontrol);
 817         addstat(STAT_MOVEVARS_AIRCONTROL_POWER, AS_FLOAT, stat_sv_aircontrol_power);
 818         addstat(STAT_MOVEVARS_AIRCONTROL_PENALTY, AS_FLOAT, stat_sv_aircontrol_penalty);
 819         addstat(STAT_MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, AS_FLOAT, stat_sv_warsowbunny_airforwardaccel);
 820         addstat(STAT_MOVEVARS_WARSOWBUNNY_TOPSPEED, AS_FLOAT, stat_sv_warsowbunny_topspeed);
 821         addstat(STAT_MOVEVARS_WARSOWBUNNY_ACCEL, AS_FLOAT, stat_sv_warsowbunny_accel);
 822         addstat(STAT_MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, AS_FLOAT, stat_sv_warsowbunny_backtosideratio);
 823         addstat(STAT_MOVEVARS_FRICTION, AS_FLOAT, stat_sv_friction);
 824         addstat(STAT_MOVEVARS_ACCELERATE, AS_FLOAT, stat_sv_accelerate);
 825         addstat(STAT_MOVEVARS_STOPSPEED, AS_FLOAT, stat_sv_stopspeed);
 826         addstat(STAT_MOVEVARS_AIRACCELERATE, AS_FLOAT, stat_sv_airaccelerate);
 827         addstat(STAT_MOVEVARS_AIRSTOPACCELERATE, AS_FLOAT, stat_sv_airstopaccelerate);
 828
 829         // secrets
 830         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 831         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 832
 833         // monsters
 834         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 835         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 836
 837         // misc
 838         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 839
 840         next_pingtime = time + 5;
 841
 842         detect_maptype();
 843
 844         // set up information replies for clients and server to use
 845         maplist_reply = strzone(getmaplist());
 846         lsmaps_reply = strzone(getlsmaps());
 847         monsterlist_reply = strzone(getmonsterlist());
 848         for(int i = 0; i < 10; ++i)
 849         {
 850                 s = getrecords(i);
 851                 if (s)
 852                         records_reply[i] = strzone(s);
 853         }
 854         ladder_reply = strzone(getladder());
 855         rankings_reply = strzone(getrankings());
 856
 857         // begin other init
 858         ClientInit_Spawn();
 859         RandomSeed_Spawn();
 860         PingPLReport_Spawn();
 861
 862         CheatInit();
 863
 864         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 865
 866         // fill sv_curl_serverpackages from .serverpackage files
 867         if(autocvar_sv_curl_serverpackages_auto)
 868         {
 869                 s = "";
 870                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 871                 for(int i = 0; i < n; ++i)
 872                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 873                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 874                                 s = strcat(s, " ", argv(i));
 875                 fd = search_begin("*-serverpackage.txt", true, false);
 876                 if(fd >= 0)
 877                 {
 878                         j = search_getsize(fd);
 879                         for(int i = 0; i < j; ++i)
 880                                 s = strcat(s, " ", search_getfilename(fd, i));
 881                         search_end(fd);
 882                 }
 883                 fd = search_begin("*.serverpackage", true, false);
 884                 if(fd >= 0)
 885                 {
 886                         j = search_getsize(fd);
 887                         for(int i = 0; i < j; ++i)
 888                                 s = strcat(s, " ", search_getfilename(fd, i));
 889                         search_end(fd);
 890                 }
 891                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 892         }
 893
 894         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 895         modname = "Xonotic";
 896         // physics/balance/config changes that count as mod
 897         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 898                 modname = cvar_string("g_mod_physics");
 899         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 900                 modname = cvar_string("g_mod_balance");
 901         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 902                 modname = cvar_string("g_mod_config");
 903         // extra mutators that deserve to count as mod
 904         MUTATOR_CALLHOOK(SetModname);
 905
 906         // save it for later
 907         modname = strzone(modname);
 908
 909         WinningConditionHelper(); // set worldstatus
 910
 911         world_initialized = 1;
 912 }
 913
 914 spawnfunc(light)
 915 {
 916         //makestatic (self); // Who the f___ did that?
 917         remove(self);
 918 }
 919
 920 string GetGametype()
 921 {
 922         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 923 }
 924
 925 string GetMapname()
 926 {
 927         return mapname;
 928 }
 929
 930 float Map_Count, Map_Current;
 931 string Map_Current_Name;
 932
 933 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 934 float GetMaplistPosition()
 935 {
 936         float pos, idx;
 937         string map;
 938
 939         map = GetMapname();
 940         idx = autocvar_g_maplist_index;
 941
 942         if(idx >= 0)
 943                 if(idx < Map_Count)
 944                         if(map == argv(idx))
 945                                 return idx;
 946
 947         for(pos = 0; pos < Map_Count; ++pos)
 948                 if(map == argv(pos))
 949                         return pos;
 950
 951         // resume normal maplist rotation if current map is not in g_maplist
 952         return idx;
 953 }
 954
 955 float MapHasRightSize(string map)
 956 {
 957         float fh;
 958         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 959         if(autocvar_g_maplist_check_waypoints)
 960         {
 961                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 962                 if(!fexists(strcat("maps/", map, ".waypoints")))
 963                 {
 964                         LOG_TRACE(": no waypoints\n");
 965                         return false;
 966                 }
 967                 LOG_TRACE(": has waypoints\n");
 968         }
 969
 970         // open map size restriction file
 971         LOG_TRACE("opensize "); LOG_TRACE(map);
 972         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 973         if(fh >= 0)
 974         {
 975                 float mapmin, mapmax;
 976                 LOG_TRACE(": ok, ");
 977                 mapmin = stof(fgets(fh));
 978                 mapmax = stof(fgets(fh));
 979                 fclose(fh);
 980                 if(player_count < mapmin)
 981                 {
 982                         LOG_TRACE("not enough\n");
 983                         return false;
 984                 }
 985                 if(player_count > mapmax)
 986                 {
 987                         LOG_TRACE("too many\n");
 988                         return false;
 989                 }
 990                 LOG_TRACE("right size\n");
 991                 return true;
 992         }
 993         LOG_TRACE(": not found\n");
 994         return true;
 995 }
 996
 997 string Map_Filename(float position)
 998 {
 999         return strcat("maps/", argv(position), ".bsp");
1000 }
1001
1002 string strwords(string s, float w)
1003 {
1004         float endpos;
1005         for(endpos = 0; w && endpos >= 0; --w)
1006                 endpos = strstrofs(s, " ", endpos + 1);
1007         if(endpos < 0)
1008                 return s;
1009         else
1010                 return substring(s, 0, endpos);
1011 }
1012
1013 float strhasword(string s, string w)
1014 {
1015         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1016 }
1017
1018 void Map_MarkAsRecent(string m)
1019 {
1020         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1021 }
1022
1023 float Map_IsRecent(string m)
1024 {
1025         return strhasword(autocvar_g_maplist_mostrecent, m);
1026 }
1027
1028 float Map_Check(float position, float pass)
1029 {
1030         string filename;
1031         string map_next;
1032         map_next = argv(position);
1033         if(pass <= 1)
1034         {
1035                 if(Map_IsRecent(map_next))
1036                         return 0;
1037         }
1038         filename = Map_Filename(position);
1039         if(MapInfo_CheckMap(map_next))
1040         {
1041                 if(pass == 2)
1042                         return 1;
1043                 if(MapHasRightSize(map_next))
1044                         return 1;
1045                 return 0;
1046         }
1047         else
1048                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1049
1050         return 0;
1051 }
1052
1053 void Map_Goto_SetStr(string nextmapname)
1054 {
1055         if(getmapname_stored != "")
1056                 strunzone(getmapname_stored);
1057         if(nextmapname == "")
1058                 getmapname_stored = "";
1059         else
1060                 getmapname_stored = strzone(nextmapname);
1061 }
1062
1063 void Map_Goto_SetFloat(float position)
1064 {
1065         cvar_set("g_maplist_index", ftos(position));
1066         Map_Goto_SetStr(argv(position));
1067 }
1068
1069 void Map_Goto(float reinit)
1070 {
1071         MapInfo_LoadMap(getmapname_stored, reinit);
1072 }
1073
1074 // return codes of map selectors:
1075 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1076 //   -2 = permanent failure
1077 float() MaplistMethod_Iterate = // usual method
1078 {
1079         float pass, i;
1080
1081         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1082
1083         for(pass = 1; pass <= 2; ++pass)
1084         {
1085                 for(i = 1; i < Map_Count; ++i)
1086                 {
1087                         float mapindex;
1088                         mapindex = (i + Map_Current) % Map_Count;
1089                         if(Map_Check(mapindex, pass))
1090                                 return mapindex;
1091                 }
1092         }
1093         return -1;
1094 }
1095
1096 float() MaplistMethod_Repeat = // fallback method
1097 {
1098         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1099
1100         if(Map_Check(Map_Current, 2))
1101                 return Map_Current;
1102         return -2;
1103 }
1104
1105 float() MaplistMethod_Random = // random map selection
1106 {
1107         float i, imax;
1108
1109         LOG_TRACE("Trying MaplistMethod_Random\n");
1110
1111         imax = 42;
1112
1113         for(i = 0; i <= imax; ++i)
1114         {
1115                 float mapindex;
1116                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1117                 if(Map_Check(mapindex, 1))
1118                         return mapindex;
1119         }
1120         return -1;
1121 }
1122
1123 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1124 // the exponent sets a bias on the map selection:
1125 // the higher the exponent, the less likely "shortly repeated" same maps are
1126 {
1127         float i, j, imax, insertpos;
1128
1129         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1130
1131         imax = 42;
1132
1133         for(i = 0; i <= imax; ++i)
1134         {
1135                 string newlist;
1136
1137                 // now reinsert this at another position
1138                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1139                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1140                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1141                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1142
1143                 // insert the current map there
1144                 newlist = "";
1145                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1146                         newlist = strcat(newlist, " ", argv(j));
1147                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1148                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1149                         newlist = strcat(newlist, " ", argv(j));
1150                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1151                 cvar_set("g_maplist", newlist);
1152                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1153
1154                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1155                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1156                 if(Map_Check(Map_Current, 1))
1157                         return Map_Current;
1158         }
1159         return -1;
1160 }
1161
1162 void Maplist_Init()
1163 {
1164         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1165         float i;
1166         for (i = 0; i < Map_Count; ++i)
1167                 if (Map_Check(i, 2))
1168                         break;
1169         if (i == Map_Count)
1170         {
1171                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1172                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1173                 if(autocvar_g_maplist_shuffle)
1174                         ShuffleMaplist();
1175                 localcmd("\nmenu_cmd sync\n");
1176                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1177         }
1178         if(Map_Count == 0)
1179                 error("empty maplist, cannot select a new map");
1180         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1181
1182         if(Map_Current_Name)
1183                 strunzone(Map_Current_Name);
1184         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1185         // this may or may not be correct, but who cares, in the worst case a map
1186         // isn't chosen in the first pass that should have been
1187 }
1188
1189 string GetNextMap()
1190 {
1191         float nextMap;
1192
1193         Maplist_Init();
1194         nextMap = -1;
1195
1196         if(nextMap == -1)
1197                 if(autocvar_g_maplist_shuffle > 0)
1198                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1199
1200         if(nextMap == -1)
1201                 if(autocvar_g_maplist_selectrandom)
1202                         nextMap = MaplistMethod_Random();
1203
1204         if(nextMap == -1)
1205                 nextMap = MaplistMethod_Iterate();
1206
1207         if(nextMap == -1)
1208                 nextMap = MaplistMethod_Repeat();
1209
1210         if(nextMap >= 0)
1211         {
1212                 Map_Goto_SetFloat(nextMap);
1213                 return getmapname_stored;
1214         }
1215
1216         return "";
1217 }
1218
1219 float DoNextMapOverride(float reinit)
1220 {
1221         if(autocvar_g_campaign)
1222         {
1223                 CampaignPostIntermission();
1224                 alreadychangedlevel = true;
1225                 return true;
1226         }
1227         if(autocvar_quit_when_empty)
1228         {
1229                 if(player_count <= currentbots)
1230                 {
1231                         localcmd("quit\n");
1232                         alreadychangedlevel = true;
1233                         return true;
1234                 }
1235         }
1236         if(autocvar_quit_and_redirect != "")
1237         {
1238                 redirection_target = strzone(autocvar_quit_and_redirect);
1239                 alreadychangedlevel = true;
1240                 return true;
1241         }
1242         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1243         {
1244                 localcmd("restart\n");
1245                 alreadychangedlevel = true;
1246                 return true;
1247         }
1248         if(autocvar_nextmap != "")
1249         {
1250                 string m;
1251                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1252                 cvar_set("nextmap",m);
1253
1254                 if(!m || gametypevote)
1255                         return false;
1256                 if(autocvar_sv_vote_gametype)
1257                 {
1258                         Map_Goto_SetStr(m);
1259                         return false;
1260                 }
1261
1262                 if(MapInfo_CheckMap(m))
1263                 {
1264                         Map_Goto_SetStr(m);
1265                         Map_Goto(reinit);
1266                         alreadychangedlevel = true;
1267                         return true;
1268                 }
1269         }
1270         if(!reinit && autocvar_lastlevel)
1271         {
1272                 cvar_settemp_restore();
1273                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1274                 alreadychangedlevel = true;
1275                 return true;
1276         }
1277         return false;
1278 }
1279
1280 void GotoNextMap(float reinit)
1281 {
1282         //string nextmap;
1283         //float n, nummaps;
1284         //string s;
1285         if (alreadychangedlevel)
1286                 return;
1287         alreadychangedlevel = true;
1288
1289         string nextMap;
1290
1291         nextMap = GetNextMap();
1292         if(nextMap == "")
1293                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1294         Map_Goto(reinit);
1295 }
1296
1297
1298 /*
1299 ============
1300 IntermissionThink
1301
1302 When the player presses attack or jump, change to the next level
1303 ============
1304 */
1305 .float autoscreenshot;
1306 void IntermissionThink()
1307 {SELFPARAM();
1308         FixIntermissionClient(self);
1309
1310         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1311         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1312
1313         if( (server_screenshot || client_screenshot)
1314                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1315         {
1316                 self.autoscreenshot = -1;
1317                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1318                 return;
1319         }
1320
1321         if (time < intermission_exittime)
1322                 return;
1323
1324         if(!mapvote_initialized)
1325                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1326                         return;
1327
1328         MapVote_Start();
1329 }
1330
1331 /*
1332 ============
1333 FindIntermission
1334
1335 Returns the entity to view from
1336 ============
1337 */
1338 /*
1339 entity FindIntermission()
1340 {
1341         local   entity spot;
1342         local   float cyc;
1343
1344 // look for info_intermission first
1345         spot = find (world, classname, "info_intermission");
1346         if (spot)
1347         {       // pick a random one
1348                 cyc = random() * 4;
1349                 while (cyc > 1)
1350                 {
1351                         spot = find (spot, classname, "info_intermission");
1352                         if (!spot)
1353                                 spot = find (spot, classname, "info_intermission");
1354                         cyc = cyc - 1;
1355                 }
1356                 return spot;
1357         }
1358
1359 // then look for the start position
1360         spot = find (world, classname, "info_player_start");
1361         if (spot)
1362                 return spot;
1363
1364 // testinfo_player_start is only found in regioned levels
1365         spot = find (world, classname, "testplayerstart");
1366         if (spot)
1367                 return spot;
1368
1369 // then look for the start position
1370         spot = find (world, classname, "info_player_deathmatch");
1371         if (spot)
1372                 return spot;
1373
1374         //objerror ("FindIntermission: no spot");
1375         return world;
1376 }
1377 */
1378
1379 /*
1380 ===============================================================================
1381
1382 RULES
1383
1384 ===============================================================================
1385 */
1386
1387 void DumpStats(float final)
1388 {
1389         float file;
1390         string s;
1391         float to_console;
1392         float to_eventlog;
1393         float to_file;
1394         float i;
1395
1396         to_console = autocvar_sv_logscores_console;
1397         to_eventlog = autocvar_sv_eventlog;
1398         to_file = autocvar_sv_logscores_file;
1399
1400         if(!final)
1401         {
1402                 to_console = true; // always print printstats replies
1403                 to_eventlog = false; // but never print them to the event log
1404         }
1405
1406         if(to_eventlog)
1407                 if(autocvar_sv_eventlog_console)
1408                         to_console = false; // otherwise we get the output twice
1409
1410         if(final)
1411                 s = ":scores:";
1412         else
1413                 s = ":status:";
1414         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1415
1416         if(to_console)
1417                 LOG_INFO(s, "\n");
1418         if(to_eventlog)
1419                 GameLogEcho(s);
1420
1421         file = -1;
1422         if(to_file)
1423         {
1424                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1425                 if(file == -1)
1426                         to_file = false;
1427                 else
1428                         fputs(file, strcat(s, "\n"));
1429         }
1430
1431         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1432         if(to_console)
1433                 LOG_INFO(s, "\n");
1434         if(to_eventlog)
1435                 GameLogEcho(s);
1436         if(to_file)
1437                 fputs(file, strcat(s, "\n"));
1438
1439         FOR_EACH_CLIENT(other)
1440         {
1441                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1442                 {
1443                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1444                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1445                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1446                                 s = strcat(s, ftos(other.team), ":");
1447                         else
1448                                 s = strcat(s, "spectator:");
1449
1450                         if(to_console)
1451                                 LOG_INFO(s, other.netname, "\n");
1452                         if(to_eventlog)
1453                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1454                         if(to_file)
1455                                 fputs(file, strcat(s, other.netname, "\n"));
1456                 }
1457         }
1458
1459         if(teamplay)
1460         {
1461                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1462                 if(to_console)
1463                         LOG_INFO(s, "\n");
1464                 if(to_eventlog)
1465                         GameLogEcho(s);
1466                 if(to_file)
1467                         fputs(file, strcat(s, "\n"));
1468
1469                 for(i = 1; i < 16; ++i)
1470                 {
1471                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1472                         s = strcat(s, ":", ftos(i));
1473                         if(to_console)
1474                                 LOG_INFO(s, "\n");
1475                         if(to_eventlog)
1476                                 GameLogEcho(s);
1477                         if(to_file)
1478                                 fputs(file, strcat(s, "\n"));
1479                 }
1480         }
1481
1482         if(to_console)
1483                 LOG_INFO(":end\n");
1484         if(to_eventlog)
1485                 GameLogEcho(":end");
1486         if(to_file)
1487         {
1488                 fputs(file, ":end\n");
1489                 fclose(file);
1490         }
1491 }
1492
1493 void FixIntermissionClient(entity e)
1494 {
1495         string s;
1496         if(!e.autoscreenshot) // initial call
1497         {
1498                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1499                 e.health = -2342;
1500                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1501                 e.solid = SOLID_NOT;
1502                 e.movetype = MOVETYPE_NONE;
1503                 e.takedamage = DAMAGE_NO;
1504                 if(e.weaponentity)
1505                 {
1506                         e.weaponentity.effects = EF_NODRAW;
1507                         if (e.weaponentity.weaponentity)
1508                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1509                 }
1510                 if(IS_REAL_CLIENT(e))
1511                 {
1512                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1513                         s = autocvar_sv_intermission_cdtrack;
1514                         if(s != "")
1515                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1516                         msg_entity = e;
1517                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1518                 }
1519         }
1520 }
1521
1522 /*
1523 go to the next level for deathmatch
1524 only called if a time or frag limit has expired
1525 */
1526 void NextLevel()
1527 {
1528         gameover = true;
1529
1530         intermission_running = 1;
1531
1532 // enforce a wait time before allowing changelevel
1533         if(player_count > 0)
1534                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1535         else
1536                 intermission_exittime = -1;
1537
1538         /*
1539         WriteByte (MSG_ALL, SVC_CDTRACK);
1540         WriteByte (MSG_ALL, 3);
1541         WriteByte (MSG_ALL, 3);
1542         // done in FixIntermission
1543         */
1544
1545         //pos = FindIntermission ();
1546
1547         VoteReset();
1548
1549         DumpStats(true);
1550
1551         // send statistics
1552         PlayerStats_GameReport(true);
1553         WeaponStats_Shutdown();
1554
1555         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1556
1557         if(autocvar_sv_eventlog)
1558                 GameLogEcho(":gameover");
1559
1560         GameLogClose();
1561
1562         FOR_EACH_PLAYER(other) {
1563                 FixIntermissionClient(other);
1564                 if(other.winning)
1565                         bprint(other.netname, " ^7wins.\n");
1566         }
1567
1568         if(autocvar_g_campaign)
1569                 CampaignPreIntermission();
1570
1571         MUTATOR_CALLHOOK(MatchEnd);
1572
1573         localcmd("\nsv_hook_gameend\n");
1574 }
1575
1576 /*
1577 ============
1578 CheckRules_Player
1579
1580 Exit deathmatch games upon conditions
1581 ============
1582 */
1583 void CheckRules_Player()
1584 {SELFPARAM();
1585         if (gameover)   // someone else quit the game already
1586                 return;
1587
1588         if(self.deadflag == DEAD_NO)
1589                 self.play_time += frametime;
1590
1591         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1592         //   (div0: and that in CheckRules_World please)
1593 }
1594
1595
1596 float InitiateSuddenDeath()
1597 {
1598         // Check first whether normal overtimes could be added before initiating suddendeath mode
1599         // - for this timelimit_overtime needs to be >0 of course
1600         // - also check the winning condition calculated in the previous frame and only add normal overtime
1601         //   again, if at the point at which timelimit would be extended again, still no winner was found
1602         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1603         {
1604                 return 1; // need to call InitiateOvertime later
1605         }
1606         else
1607         {
1608                 if(!checkrules_suddendeathend)
1609                 {
1610                         if(autocvar_g_campaign)
1611                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1612                         else
1613                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1614                         if(g_race && !g_race_qualifying)
1615                                 race_StartCompleting();
1616                 }
1617                 return 0;
1618         }
1619 }
1620
1621 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1622 {
1623         ++checkrules_overtimesadded;
1624         //add one more overtime by simply extending the timelimit
1625         float tl;
1626         tl = autocvar_timelimit;
1627         tl += autocvar_timelimit_overtime;
1628         cvar_set("timelimit", ftos(tl));
1629
1630         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1631 }
1632
1633 float GetWinningCode(float fraglimitreached, float equality)
1634 {
1635         if(autocvar_g_campaign == 1)
1636                 if(fraglimitreached)
1637                         return WINNING_YES;
1638                 else
1639                         return WINNING_NO;
1640
1641         else
1642                 if(equality)
1643                         if(fraglimitreached)
1644                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1645                         else
1646                                 return WINNING_NEVER;
1647                 else
1648                         if(fraglimitreached)
1649                                 return WINNING_YES;
1650                         else
1651                                 return WINNING_NO;
1652 }
1653
1654 // set the .winning flag for exactly those players with a given field value
1655 void SetWinners(.float field, float value)
1656 {
1657         entity head;
1658         FOR_EACH_PLAYER(head)
1659                 head.winning = (head.(field) == value);
1660 }
1661
1662 // set the .winning flag for those players with a given field value
1663 void AddWinners(.float field, float value)
1664 {
1665         entity head;
1666         FOR_EACH_PLAYER(head)
1667                 if (head.(field) == value)
1668                         head.winning = 1;
1669 }
1670
1671 // clear the .winning flags
1672 void ClearWinners(void)
1673 {
1674         entity head;
1675         FOR_EACH_PLAYER(head)
1676                 head.winning = 0;
1677 }
1678
1679 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1680 // they win. Otherwise the defending team wins once the timelimit passes.
1681 void assault_new_round();
1682 float WinningCondition_Assault()
1683 {SELFPARAM();
1684         float status;
1685
1686         WinningConditionHelper(); // set worldstatus
1687
1688         status = WINNING_NO;
1689         // as the timelimit has not yet passed just assume the defending team will win
1690         if(assault_attacker_team == NUM_TEAM_1)
1691         {
1692                 SetWinners(team, NUM_TEAM_2);
1693         }
1694         else
1695         {
1696                 SetWinners(team, NUM_TEAM_1);
1697         }
1698
1699         entity ent;
1700         ent = find(world, classname, "target_assault_roundend");
1701         if(ent)
1702         {
1703                 if(ent.winning) // round end has been triggered by attacking team
1704                 {
1705                         bprint("ASSAULT: round completed...\n");
1706                         SetWinners(team, assault_attacker_team);
1707
1708                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1709
1710                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1711                         {
1712                                 status = WINNING_YES;
1713                         }
1714                         else
1715                         {
1716                                 WITH(entity, self, ent, assault_new_round());
1717                         }
1718                 }
1719         }
1720
1721         return status;
1722 }
1723
1724 // LMS winning condition: game terminates if and only if there's at most one
1725 // one player who's living lives. Top two scores being equal cancels the time
1726 // limit.
1727 float WinningCondition_LMS()
1728 {
1729         entity head, head2;
1730         float have_player;
1731         float have_players;
1732         float l;
1733
1734         have_player = false;
1735         have_players = false;
1736         l = LMS_NewPlayerLives();
1737
1738         head = find(world, classname, "player");
1739         if(head)
1740                 have_player = true;
1741         head2 = find(head, classname, "player");
1742         if(head2)
1743                 have_players = true;
1744
1745         if(have_player)
1746         {
1747                 // we have at least one player
1748                 if(have_players)
1749                 {
1750                         // two or more active players - continue with the game
1751                 }
1752                 else
1753                 {
1754                         // exactly one player?
1755
1756                         ClearWinners();
1757                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1758
1759                         if(l)
1760                         {
1761                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1762                                 return WINNING_NO;
1763                         }
1764                         else
1765                         {
1766                                 // a winner!
1767                                 // and assign him his first place
1768                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1769                                 return WINNING_YES;
1770                         }
1771                 }
1772         }
1773         else
1774         {
1775                 // nobody is playing at all...
1776                 if(l)
1777                 {
1778                         // wait for players...
1779                 }
1780                 else
1781                 {
1782                         // SNAFU (maybe a draw game?)
1783                         ClearWinners();
1784                         LOG_TRACE("No players, ending game.\n");
1785                         return WINNING_YES;
1786                 }
1787         }
1788
1789         // When we get here, we have at least two players who are actually LIVING,
1790         // now check if the top two players have equal score.
1791         WinningConditionHelper();
1792
1793         ClearWinners();
1794         if(WinningConditionHelper_winner)
1795                 WinningConditionHelper_winner.winning = true;
1796         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1797                 return WINNING_NEVER;
1798
1799         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1800         return WINNING_NO;
1801 }
1802
1803 void ShuffleMaplist()
1804 {
1805         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1806 }
1807
1808 float leaderfrags;
1809 float WinningCondition_Scores(float limit, float leadlimit)
1810 {
1811         float limitreached;
1812
1813         // TODO make everything use THIS winning condition (except LMS)
1814         WinningConditionHelper();
1815
1816         if(teamplay)
1817         {
1818                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1819                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1820                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1821                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1822         }
1823
1824         ClearWinners();
1825         if(WinningConditionHelper_winner)
1826                 WinningConditionHelper_winner.winning = 1;
1827         if(WinningConditionHelper_winnerteam >= 0)
1828                 SetWinners(team, WinningConditionHelper_winnerteam);
1829
1830         if(WinningConditionHelper_lowerisbetter)
1831         {
1832                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1833                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1834                 limit = -limit;
1835         }
1836
1837         if(WinningConditionHelper_zeroisworst)
1838                 leadlimit = 0; // not supported in this mode
1839
1840         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1841         // these modes always score in increments of 1, thus this makes sense
1842         {
1843                 if(leaderfrags != WinningConditionHelper_topscore)
1844                 {
1845                         leaderfrags = WinningConditionHelper_topscore;
1846
1847                         if (limit)
1848                         if (leaderfrags == limit - 1)
1849                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1850                         else if (leaderfrags == limit - 2)
1851                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1852                         else if (leaderfrags == limit - 3)
1853                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1854                 }
1855         }
1856
1857         limitreached = false;
1858         if(limit)
1859                 if(WinningConditionHelper_topscore >= limit)
1860                         limitreached = true;
1861         if(leadlimit)
1862         {
1863                 float leadlimitreached;
1864                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1865                 if(autocvar_leadlimit_and_fraglimit)
1866                         limitreached = (limitreached && leadlimitreached);
1867                 else
1868                         limitreached = (limitreached || leadlimitreached);
1869         }
1870
1871         if(limit)
1872                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1873
1874         return GetWinningCode(
1875                 WinningConditionHelper_topscore && limitreached,
1876                 WinningConditionHelper_equality
1877         );
1878 }
1879
1880 float WinningCondition_Race(float fraglimit)
1881 {
1882         float wc;
1883         entity p;
1884         float n, c;
1885
1886         n = 0;
1887         c = 0;
1888         FOR_EACH_PLAYER(p)
1889         {
1890                 ++n;
1891                 if(p.race_completed)
1892                         ++c;
1893         }
1894         if(n && (n == c))
1895                 return WINNING_YES;
1896         wc = WinningCondition_Scores(fraglimit, 0);
1897
1898         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1899         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1900         // do NOT support equality when the laps are all raced!
1901                 return WINNING_STARTSUDDENDEATHOVERTIME;
1902         else
1903                 return WINNING_NEVER;
1904 }
1905
1906 float WinningCondition_QualifyingThenRace(float limit)
1907 {
1908         float wc;
1909         wc = WinningCondition_Scores(limit, 0);
1910
1911         // NEVER initiate overtime
1912         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1913         {
1914                 return WINNING_YES;
1915         }
1916
1917         return wc;
1918 }
1919
1920 float WinningCondition_RanOutOfSpawns()
1921 {
1922         entity head;
1923
1924         if(have_team_spawns <= 0)
1925                 return WINNING_NO;
1926
1927         if(!autocvar_g_spawn_useallspawns)
1928                 return WINNING_NO;
1929
1930         if(!some_spawn_has_been_used)
1931                 return WINNING_NO;
1932
1933         team1_score = team2_score = team3_score = team4_score = 0;
1934
1935         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1936         {
1937                 if(head.team == NUM_TEAM_1)
1938                         team1_score = 1;
1939                 else if(head.team == NUM_TEAM_2)
1940                         team2_score = 1;
1941                 else if(head.team == NUM_TEAM_3)
1942                         team3_score = 1;
1943                 else if(head.team == NUM_TEAM_4)
1944                         team4_score = 1;
1945         }
1946
1947         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1948         {
1949                 if(head.team == NUM_TEAM_1)
1950                         team1_score = 1;
1951                 else if(head.team == NUM_TEAM_2)
1952                         team2_score = 1;
1953                 else if(head.team == NUM_TEAM_3)
1954                         team3_score = 1;
1955                 else if(head.team == NUM_TEAM_4)
1956                         team4_score = 1;
1957         }
1958
1959         ClearWinners();
1960         if(team1_score + team2_score + team3_score + team4_score == 0)
1961         {
1962                 checkrules_equality = true;
1963                 return WINNING_YES;
1964         }
1965         else if(team1_score + team2_score + team3_score + team4_score == 1)
1966         {
1967                 float t, i;
1968                 if(team1_score)
1969                         t = NUM_TEAM_1;
1970                 else if(team2_score)
1971                         t = NUM_TEAM_2;
1972                 else if(team3_score)
1973                         t = NUM_TEAM_3;
1974                 else // if(team4_score)
1975                         t = NUM_TEAM_4;
1976                 CheckAllowedTeams(world);
1977                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1978                 {
1979                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1980                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1981                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1982                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1983                 }
1984
1985                 AddWinners(team, t);
1986                 return WINNING_YES;
1987         }
1988         else
1989                 return WINNING_NO;
1990 }
1991
1992 /*
1993 ============
1994 CheckRules_World
1995
1996 Exit deathmatch games upon conditions
1997 ============
1998 */
1999 void CheckRules_World()
2000 {
2001         float timelimit;
2002         float fraglimit;
2003         float leadlimit;
2004
2005         VoteThink();
2006         MapVote_Think();
2007
2008         SetDefaultAlpha();
2009
2010         if (gameover)   // someone else quit the game already
2011         {
2012                 if(player_count == 0) // Nobody there? Then let's go to the next map
2013                         MapVote_Start();
2014                         // this will actually check the player count in the next frame
2015                         // again, but this shouldn't hurt
2016                 return;
2017         }
2018
2019         timelimit = autocvar_timelimit * 60;
2020         fraglimit = autocvar_fraglimit;
2021         leadlimit = autocvar_leadlimit;
2022
2023         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2024         {
2025                 if(timelimit > 0)
2026                         timelimit = 0; // timelimit is not made for warmup
2027                 if(fraglimit > 0)
2028                         fraglimit = 0; // no fraglimit for now
2029                 leadlimit = 0; // no leadlimit for now
2030         }
2031
2032         if(timelimit > 0)
2033         {
2034                 timelimit += game_starttime;
2035         }
2036         else if (timelimit < 0)
2037         {
2038                 // endmatch
2039                 NextLevel();
2040                 return;
2041         }
2042
2043         float wantovertime;
2044         wantovertime = 0;
2045
2046         if(timelimit > game_starttime)
2047                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2048         else
2049                 game_completion_ratio = 0;
2050
2051         if(checkrules_suddendeathend)
2052         {
2053                 if(!checkrules_suddendeathwarning)
2054                 {
2055                         checkrules_suddendeathwarning = true;
2056                         if(g_race && !g_race_qualifying)
2057                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2058                         else
2059                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2060                 }
2061         }
2062         else
2063         {
2064                 if (timelimit && time >= timelimit)
2065                 {
2066                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2067                         {
2068                                 float totalplayers;
2069                                 float playerswithlaps;
2070                                 float readyplayers;
2071                                 entity head;
2072                                 totalplayers = playerswithlaps = readyplayers = 0;
2073                                 FOR_EACH_PLAYER(head)
2074                                 {
2075                                         ++totalplayers;
2076                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2077                                                 ++playerswithlaps;
2078                                         if(head.ready)
2079                                                 ++readyplayers;
2080                                 }
2081
2082                                 // at least 2 of the players have completed a lap: start the RACE
2083                                 // otherwise, the players should end the qualifying on their own
2084                                 if(readyplayers || playerswithlaps >= 2)
2085                                 {
2086                                         checkrules_suddendeathend = 0;
2087                                         ReadyRestart(); // go to race
2088                                         return;
2089                                 }
2090                                 else
2091                                         wantovertime |= InitiateSuddenDeath();
2092                         }
2093                         else
2094                                 wantovertime |= InitiateSuddenDeath();
2095                 }
2096         }
2097
2098         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2099         {
2100                 NextLevel();
2101                 return;
2102         }
2103
2104         float checkrules_status;
2105         checkrules_status = WinningCondition_RanOutOfSpawns();
2106         if(checkrules_status == WINNING_YES)
2107         {
2108                 bprint("Hey! Someone ran out of spawns!\n");
2109         }
2110         else if(g_race && !g_race_qualifying && timelimit >= 0)
2111         {
2112                 checkrules_status = WinningCondition_Race(fraglimit);
2113                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2114         }
2115         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2116         {
2117                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2118                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2119         }
2120         else if(g_assault)
2121         {
2122                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2123         }
2124         else if(g_lms)
2125         {
2126                 checkrules_status = WinningCondition_LMS();
2127         }
2128         else
2129         {
2130                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2131                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2132         }
2133
2134         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2135         {
2136                 checkrules_status = WINNING_NEVER;
2137                 checkrules_overtimesadded = -1;
2138                 wantovertime |= InitiateSuddenDeath();
2139         }
2140
2141         if(checkrules_status == WINNING_NEVER)
2142                 // equality cases! Nobody wins if the overtime ends in a draw.
2143                 ClearWinners();
2144
2145         if(wantovertime)
2146         {
2147                 if(checkrules_status == WINNING_NEVER)
2148                         InitiateOvertime();
2149                 else
2150                         checkrules_status = WINNING_YES;
2151         }
2152
2153         if(checkrules_suddendeathend)
2154                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2155                         checkrules_status = WINNING_YES;
2156
2157         if(checkrules_status == WINNING_YES)
2158         {
2159                 //print("WINNING\n");
2160                 NextLevel();
2161         }
2162 }
2163
2164 string GotoMap(string m)
2165 {
2166         m = GameTypeVote_MapInfo_FixName(m);
2167         if (!m)
2168                 return "The map you suggested is not available on this server.";
2169         if (!autocvar_sv_vote_gametype)
2170         if(!MapInfo_CheckMap(m))
2171                 return "The map you suggested does not support the current game mode.";
2172         cvar_set("nextmap", m);
2173         cvar_set("timelimit", "-1");
2174         if(mapvote_initialized || alreadychangedlevel)
2175         {
2176                 if(DoNextMapOverride(0))
2177                         return "Map switch initiated.";
2178                 else
2179                         return "Hm... no. For some reason I like THIS map more.";
2180         }
2181         else
2182                 return "Map switch will happen after scoreboard.";
2183 }
2184
2185
2186 void EndFrame()
2187 {SELFPARAM();
2188         anticheat_endframe();
2189
2190         float altime;
2191         entity e_;
2192         FOR_EACH_REALCLIENT(e_)
2193         {
2194                 entity e = IS_SPEC(e_) ? e_.enemy : e_;
2195                 if(e.typehitsound)
2196                         e_.typehit_time = time;
2197                 else if(e.damage_dealt)
2198                 {
2199                         e_.hit_time = time;
2200                         e_.damage_dealt_total += ceil(e.damage_dealt);
2201                 }
2202         }
2203         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2204         // add 1 frametime because after this, engine SV_Physics
2205         // increases time by a frametime and then networks the frame
2206         // add another frametime because client shows everything with
2207         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2208         // needed!
2209         FOR_EACH_CLIENT(e_)
2210         {
2211                 e_.typehitsound = false;
2212                 e_.damage_dealt = 0;
2213                 setself(e_);
2214                 antilag_record(e_, altime);
2215         }
2216         FOR_EACH_MONSTER(e_)
2217         {
2218                 setself(e_);
2219                 antilag_record(e_, altime);
2220         }
2221 }
2222
2223
2224 /*
2225  * RedirectionThink:
2226  * returns true if redirecting
2227  */
2228 float redirection_timeout;
2229 float redirection_nextthink;
2230 float RedirectionThink()
2231 {SELFPARAM();
2232         float clients_found;
2233
2234         if(redirection_target == "")
2235                 return false;
2236
2237         if(!redirection_timeout)
2238         {
2239                 cvar_set("sv_public", "-2");
2240                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2241                 if(redirection_target == "self")
2242                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2243                 else
2244                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2245         }
2246
2247         if(time < redirection_nextthink)
2248                 return true;
2249
2250         redirection_nextthink = time + 1;
2251
2252         clients_found = 0;
2253         entity e;
2254         FOR_EACH_REALCLIENT(e)
2255         {
2256                 setself(e);
2257                 // TODO add timer
2258                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2259                 if(redirection_target == "self")
2260                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2261                 else
2262                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2263                 ++clients_found;
2264         }
2265
2266         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2267
2268         if(time > redirection_timeout || clients_found == 0)
2269                 localcmd("\nwait; wait; wait; quit\n");
2270
2271         return true;
2272 }
2273
2274 void TargetMusic_RestoreGame();
2275 void RestoreGame()
2276 {
2277         // Loaded from a save game
2278         // some things then break, so let's work around them...
2279
2280         // Progs DB (capture records)
2281         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2282
2283         // Mapinfo
2284         MapInfo_Shutdown();
2285         MapInfo_Enumerate();
2286         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2287         WeaponStats_Init();
2288
2289         TargetMusic_RestoreGame();
2290 }
2291
2292 void Shutdown()
2293 {
2294         gameover = 2;
2295
2296         if(world_initialized > 0)
2297         {
2298                 world_initialized = 0;
2299                 LOG_INFO("Saving persistent data...\n");
2300                 Ban_SaveBans();
2301
2302                 // playerstats with unfinished match
2303                 PlayerStats_GameReport(false);
2304
2305                 if(!cheatcount_total)
2306                 {
2307                         if(autocvar_sv_db_saveasdump)
2308                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2309                         else
2310                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2311                 }
2312                 if(autocvar_developer)
2313                 {
2314                         if(autocvar_sv_db_saveasdump)
2315                                 db_dump(TemporaryDB, "server-temp.db");
2316                         else
2317                                 db_save(TemporaryDB, "server-temp.db");
2318                 }
2319                 CheatShutdown(); // must be after cheatcount check
2320                 db_close(ServerProgsDB);
2321                 db_close(TemporaryDB);
2322                 LOG_INFO("done!\n");
2323                 // tell the bot system the game is ending now
2324                 bot_endgame();
2325
2326                 WeaponStats_Shutdown();
2327                 MapInfo_Shutdown();
2328         }
2329         else if(world_initialized == 0)
2330         {
2331                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2332         }
2333 }