qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(clienttype(e) == CLIENTTYPE_REAL)
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ctf");
 260                 BADCVAR("g_cts");
 261                 BADCVAR("g_dm");
 262                 BADCVAR("g_domination");
 263                 BADCVAR("g_domination_default_teams");
 264                 BADCVAR("g_freezetag");
 265                 BADCVAR("g_keepaway");
 266                 BADCVAR("g_keyhunt");
 267                 BADCVAR("g_keyhunt_teams");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_runematch");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("g_runematch_point_leadlimit");
 319                 BADCVAR("leadlimit_and_fraglimit");
 320                 BADCVAR("leadlimit_override");
 321                 BADCVAR("pausable");
 322                 BADCVAR("sv_allow_fullbright");
 323                 BADCVAR("sv_checkforpacketsduringsleep");
 324                 BADCVAR("sv_fraginfo");
 325                 BADCVAR("sv_timeout");
 326                 BADPREFIX("sv_timeout_");
 327                 BADCVAR("welcome_message_time");
 328                 BADPREFIX("crypto_");
 329                 BADPREFIX("g_chat_");
 330                 BADPREFIX("g_ctf_captimerecord_");
 331                 BADPREFIX("g_maplist_votable_");
 332                 BADPREFIX("net_");
 333                 BADPREFIX("prvm_");
 334                 BADPREFIX("skill_");
 335                 BADPREFIX("sv_cullentities_");
 336                 BADPREFIX("sv_fraginfo_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_namechangetimer");
 343
 344                 // allowed changes to server admins (please sync this to server.cfg)
 345                 // vi commands:
 346                 //   :/"impure"/,$d
 347                 //   :g!,^\/\/[^ /],d
 348                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 349                 //   :%!sort
 350                 // yes, this does contain some redundant stuff, don't really care
 351                 BADCVAR("bot_config_file");
 352                 BADCVAR("bot_number");
 353                 BADCVAR("bot_prefix");
 354                 BADCVAR("bot_suffix");
 355                 BADCVAR("capturelimit_override");
 356                 BADCVAR("fraglimit_override");
 357                 BADCVAR("gametype");
 358                 BADCVAR("g_antilag");
 359                 BADCVAR("g_balance_teams");
 360                 BADCVAR("g_balance_teams_prevent_imbalance");
 361                 BADCVAR("g_balance_teams_scorefactor");
 362                 BADCVAR("g_ban_sync_trusted_servers");
 363                 BADCVAR("g_ban_sync_uri");
 364                 BADCVAR("g_ctf_ignore_frags");
 365                 BADCVAR("g_domination_point_limit");
 366                 BADCVAR("g_friendlyfire");
 367                 BADCVAR("g_fullbrightitems");
 368                 BADCVAR("g_fullbrightplayers");
 369                 BADCVAR("g_keyhunt_point_limit");
 370                 BADCVAR("g_keyhunt_teams_override");
 371                 BADCVAR("g_lms_lives_override");
 372                 BADCVAR("g_maplist");
 373                 BADCVAR("g_maplist_check_waypoints");
 374                 BADCVAR("g_maplist_mostrecent_count");
 375                 BADCVAR("g_maplist_shuffle");
 376                 BADCVAR("g_maplist_votable");
 377                 BADCVAR("g_maplist_votable_abstain");
 378                 BADCVAR("g_maplist_votable_nodetail");
 379                 BADCVAR("g_maplist_votable_suggestions");
 380                 BADCVAR("g_maxplayers");
 381                 BADCVAR("g_mirrordamage");
 382                 BADCVAR("g_nexball_goallimit");
 383                 BADCVAR("g_powerups");
 384                 BADCVAR("g_runematch_point_limit");
 385                 BADCVAR("g_start_delay");
 386                 BADCVAR("g_warmup");
 387                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 388                 BADCVAR("hostname");
 389                 BADCVAR("log_file");
 390                 BADCVAR("maxplayers");
 391                 BADCVAR("minplayers");
 392                 BADCVAR("net_address");
 393                 BADCVAR("port");
 394                 BADCVAR("rcon_password");
 395                 BADCVAR("rcon_restricted_commands");
 396                 BADCVAR("rcon_restricted_password");
 397                 BADCVAR("skill");
 398                 BADCVAR("sv_adminnick");
 399                 BADCVAR("sv_autoscreenshot");
 400                 BADCVAR("sv_autotaunt");
 401                 BADCVAR("sv_curl_defaulturl");
 402                 BADCVAR("sv_defaultcharacter");
 403                 BADCVAR("sv_defaultplayercolors");
 404                 BADCVAR("sv_defaultplayermodel");
 405                 BADCVAR("sv_defaultplayerskin");
 406                 BADCVAR("sv_maxidle");
 407                 BADCVAR("sv_maxrate");
 408                 BADCVAR("sv_motd");
 409                 BADCVAR("sv_public");
 410                 BADCVAR("sv_ready_restart");
 411                 BADCVAR("sv_status_privacy");
 412                 BADCVAR("sv_taunt");
 413                 BADCVAR("sv_vote_call");
 414                 BADCVAR("sv_vote_commands");
 415                 BADCVAR("sv_vote_majority_factor");
 416                 BADCVAR("sv_vote_master");
 417                 BADCVAR("sv_vote_master_commands");
 418                 BADCVAR("sv_vote_master_password");
 419                 BADCVAR("sv_vote_simple_majority_factor");
 420                 BADCVAR("sys_ticrate");
 421                 BADCVAR("teamplay_mode");
 422                 BADCVAR("timelimit_override");
 423                 BADCVAR("g_spawnshieldtime");
 424                 BADPREFIX("g_warmup_");
 425                 BADPREFIX("sv_ready_restart_");
 426
 427                 // mutators that announce themselves properly to the server browser
 428                 BADCVAR("g_minstagib");
 429                 BADCVAR("g_new_toys");
 430                 BADCVAR("g_nix");
 431
 432                 if(autocvar_g_minstagib)
 433                 {
 434                         BADCVAR("g_grappling_hook");
 435                         BADCVAR("g_jetpack");
 436                 }
 437 #undef BADPREFIX
 438 #undef BADCVAR
 439
 440                 if(pureadding)
 441                 {
 442                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 443                         if(strlen(cvar_purechanges) > 16384)
 444                         {
 445                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 446                                 pureadding = 0;
 447                         }
 448                 }
 449                 ++cvar_purechanges_count;
 450                 // WARNING: this variable is used for the server list
 451                 // NEVER dare to skip this code!
 452                 // Hacks to intentionally appearing as "pure server" even though you DO have
 453                 // modified settings may be punished by removal from the server list.
 454                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 455                 // though.
 456         }
 457         buf_del(h);
 458         if(cvar_changes == "")
 459                 cvar_changes = "// this server runs at default server settings\n";
 460         else
 461                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 462         cvar_changes = strzone(cvar_changes);
 463         if(cvar_purechanges == "")
 464                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 465         else
 466                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 467         cvar_purechanges = strzone(cvar_purechanges);
 468 }
 469
 470 void detect_maptype()
 471 {
 472 #if 0
 473         vector o, v;
 474         float i;
 475
 476         for(;;)
 477         {
 478                 o = world.mins;
 479                 o_x += random() * (world.maxs_x - world.mins_x);
 480                 o_y += random() * (world.maxs_y - world.mins_y);
 481                 o_z += random() * (world.maxs_z - world.mins_z);
 482
 483                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 484                 if(trace_fraction == 1)
 485                         continue;
 486
 487                 v = trace_endpos;
 488
 489                 for(i = 0; i < 64; i += 4)
 490                 {
 491                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 492         if(trace_fraction == 1)
 493                 continue;
 494                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 495                 }
 496
 497                 break;
 498         }
 499 #endif
 500 }
 501
 502 entity randomseed;
 503 float RandomSeed_Send(entity to, float sf)
 504 {
 505         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 506         WriteShort(MSG_ENTITY, self.cnt);
 507         return TRUE;
 508 }
 509 void RandomSeed_Think()
 510 {
 511         self.cnt = bound(0, floor(random() * 65536), 65535);
 512         self.nextthink = time + 5;
 513
 514         self.SendFlags |= 1;
 515 }
 516 void RandomSeed_Spawn()
 517 {
 518         randomseed = spawn();
 519         randomseed.think = RandomSeed_Think;
 520         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 521
 522         entity oldself;
 523         oldself = self;
 524         self = randomseed;
 525         self.think(); // sets random seed and nextthink
 526         self = oldself;
 527 }
 528
 529 void spawnfunc___init_dedicated_server(void)
 530 {
 531         // handler for _init/_init map (only for dedicated server initialization)
 532
 533         world_initialized = -1; // don't complain
 534         cvar = cvar_normal;
 535         cvar_string = cvar_string_normal;
 536         cvar_set = cvar_set_normal;
 537
 538         remove = remove_unsafely;
 539
 540         entity e;
 541         e = spawn();
 542         e.think = GotoFirstMap;
 543         e.nextthink = time; // this is usually 1 at this point
 544
 545         e = spawn();
 546         e.classname = "info_player_deathmatch"; // safeguard against player joining
 547
 548         self.classname = "worldspawn"; // safeguard against various stuff ;)
 549
 550         // needs to be done so early because of the constants they create
 551         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 552         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 553         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 554         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 555
 556         MapInfo_Enumerate();
 557         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 558 }
 559
 560 void Map_MarkAsRecent(string m);
 561 float world_already_spawned;
 562 void Nagger_Init();
 563 void ClientInit_Spawn();
 564 void WeaponStats_Init();
 565 void WeaponStats_Shutdown();
 566 void spawnfunc_worldspawn (void)
 567 {
 568         float fd, l, i, j, n;
 569         string s, col;
 570
 571         cvar = cvar_normal;
 572         cvar_string = cvar_string_normal;
 573         cvar_set = cvar_set_normal;
 574
 575         if(world_already_spawned)
 576                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 577         world_already_spawned = TRUE;
 578
 579         remove = remove_safely; // during spawning, watch what you remove!
 580
 581         check_unacceptable_compiler_bugs();
 582
 583         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 584
 585         compressShortVector_init();
 586
 587         allowed_to_spawn = TRUE;
 588
 589         entity head;
 590         head = nextent(world);
 591         maxclients = 0;
 592         while(head)
 593         {
 594                 ++maxclients;
 595                 head = nextent(head);
 596         }
 597
 598         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 599
 600         // needs to be done so early because of the constants they create
 601         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 602         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 603         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 604         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 605
 606         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 607
 608         TemporaryDB = db_create();
 609
 610         // 0 normal
 611         lightstyle(0, "m");
 612
 613         // 1 FLICKER (first variety)
 614         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 615
 616         // 2 SLOW STRONG PULSE
 617         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 618
 619         // 3 CANDLE (first variety)
 620         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 621
 622         // 4 FAST STROBE
 623         lightstyle(4, "mamamamamama");
 624
 625         // 5 GENTLE PULSE 1
 626         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 627
 628         // 6 FLICKER (second variety)
 629         lightstyle(6, "nmonqnmomnmomomno");
 630
 631         // 7 CANDLE (second variety)
 632         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 633
 634         // 8 CANDLE (third variety)
 635         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 636
 637         // 9 SLOW STROBE (fourth variety)
 638         lightstyle(9, "aaaaaaaazzzzzzzz");
 639
 640         // 10 FLUORESCENT FLICKER
 641         lightstyle(10, "mmamammmmammamamaaamammma");
 642
 643         // 11 SLOW PULSE NOT FADE TO BLACK
 644         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 645
 646         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 647
 648         // 63 testing
 649         lightstyle(63, "a");
 650
 651         if(autocvar_g_campaign)
 652                 CampaignPreInit();
 653
 654         Map_MarkAsRecent(mapname);
 655
 656         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 657
 658         precache_model ("null"); // we need this one before InitGameplayMode
 659         InitGameplayMode();
 660         readlevelcvars();
 661         GrappleHookInit();
 662         ElectroInit();
 663         LaserInit();
 664
 665         player_count = 0;
 666         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 667         if(bot_waypoints_for_items == 1)
 668                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 669                         bot_waypoints_for_items = 0;
 670
 671         precache();
 672
 673         WaypointSprite_Init();
 674
 675         GameLogInit(); // prepare everything
 676         // NOTE for matchid:
 677         // changing the logic generating it is okay. But:
 678         // it HAS to stay <= 64 chars
 679         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 680         if(autocvar_sv_eventlog)
 681         {
 682                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 683                 matchid = strzone(s);
 684
 685                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 686                 s = ":gameinfo:mutators:LIST";
 687
 688                 ret_string = s;
 689                 MUTATOR_CALLHOOK(BuildMutatorsString);
 690                 s = ret_string;
 691
 692                 // simple, probably not good in the mutator system
 693                 if(autocvar_g_grappling_hook)
 694                         s = strcat(s, ":grappling_hook");
 695
 696                 // initialiation stuff, not good in the mutator system
 697                 if(!autocvar_g_use_ammunition)
 698                         s = strcat(s, ":no_use_ammunition");
 699
 700                 // initialiation stuff, not good in the mutator system
 701                 if(autocvar_g_pickup_items == 0)
 702                         s = strcat(s, ":no_pickup_items");
 703                 if(autocvar_g_pickup_items > 0)
 704                         s = strcat(s, ":pickup_items");
 705
 706                 // initialiation stuff, not good in the mutator system
 707                 if(autocvar_g_weaponarena != "0")
 708                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 709
 710                 // TODO to mutator system
 711                 if(autocvar_g_norecoil)
 712                         s = strcat(s, ":norecoil");
 713
 714                 // TODO to mutator system
 715                 if(autocvar_g_midair)
 716                         s = strcat(s, ":midair");
 717
 718                 // TODO to mutator system
 719                 if(autocvar_g_minstagib)
 720                         s = strcat(s, ":minstagib");
 721
 722                 // TODO to mutator system
 723                 if(autocvar_g_powerups == 0)
 724                         s = strcat(s, ":no_powerups");
 725                 if(autocvar_g_powerups > 0)
 726                         s = strcat(s, ":powerups");
 727
 728                 GameLogEcho(s);
 729                 GameLogEcho(":gameinfo:end");
 730         }
 731         else
 732                 matchid = strzone(ftos(random()));
 733
 734         cvar_set("nextmap", "");
 735
 736         SetDefaultAlpha();
 737
 738         if(autocvar_g_campaign)
 739                 CampaignPostInit();
 740
 741         fteqcc_testbugs();
 742
 743         Ban_LoadBans();
 744
 745         MapInfo_Enumerate();
 746         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 747
 748         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 749         {
 750                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 751                 if(fd != -1)
 752                 {
 753                         while((s = fgets(fd)))
 754                         {
 755                                 l = tokenize_console(s);
 756                                 if(l < 2)
 757                                         continue;
 758                                 if(argv(0) == "cd")
 759                                 {
 760                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 761                                         print("  cdtrack ", argv(2), "\n");
 762                                 }
 763                                 else if(argv(0) == "fog")
 764                                 {
 765                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 766                                         print("  \"fog\" \"", s, "\"\n");
 767                                 }
 768                                 else if(argv(0) == "set")
 769                                 {
 770                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 771                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 772                                 }
 773                                 else if(argv(0) != "//")
 774                                 {
 775                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 776                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 777                                 }
 778                         }
 779                         fclose(fd);
 780                 }
 781         }
 782
 783         WeaponStats_Init();
 784
 785         WEPSET_ADDSTAT();
 786         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 787         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 788         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 789         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 790         Nagger_Init();
 791
 792         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 793         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 794         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 795         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 796         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 797         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 798         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 799         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 800         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 801         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 802         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 803         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 804         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 805
 806         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 807         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 808
 809         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 810
 811         if(g_ca || g_freezetag)
 812         {
 813                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 814                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 815                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 816                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 817         }
 818         if(g_freezetag)
 819         {
 820                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 821                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 822         }
 823
 824         // g_movementspeed hack
 825         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 826         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 827         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 828         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 829
 830         // secrets
 831         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 832         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 833
 834         // misc
 835         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 836
 837         next_pingtime = time + 5;
 838
 839         detect_maptype();
 840
 841         // set up information replies for clients and server to use
 842         lsmaps_reply = "^7Maps available: ";
 843         lsnewmaps_reply = "^7Maps without a record set: ";
 844         for(i = 0, j = 0; i < MapInfo_count; ++i)
 845         {
 846                 if(MapInfo_Get_ByID(i))
 847                         if not(MapInfo_Map_flags & MapInfo_ForbiddenFlags())
 848                         {
 849                                 if(mod(i, 2))
 850                                         col = "^2";
 851                                 else
 852                                         col = "^3";
 853
 854                                 ++j;
 855
 856                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 857
 858                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 859                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 860                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 861                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 862                         }
 863         }
 864
 865         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 866         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 867
 868         maplist_reply = "^7Maps in list: ";
 869         n = tokenize_console(autocvar_g_maplist);
 870         for(i = 0, j = 0; i < n; ++i)
 871         {
 872                 if(MapInfo_CheckMap(argv(i)))
 873                 {
 874                         if(mod(j, 2))
 875                                 col = "^2";
 876                         else
 877                                 col = "^3";
 878                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 879                         ++j;
 880                 }
 881         }
 882         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 883         MapInfo_ClearTemps();
 884
 885         for(i = 0; i < 10; ++i)
 886         {
 887                 s = getrecords(i);
 888                 if (s)
 889                         records_reply[i] = strzone(s);
 890         }
 891
 892         ladder_reply = strzone(getladder());
 893
 894         rankings_reply = strzone(getrankings());
 895
 896         // begin other init
 897         ClientInit_Spawn();
 898         RandomSeed_Spawn();
 899         PingPLReport_Spawn();
 900
 901         CheatInit();
 902
 903         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 904
 905         // fill sv_curl_serverpackages from .serverpackage files
 906         if(autocvar_sv_curl_serverpackages_auto)
 907         {
 908                 s = "";
 909                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 910                 for(i = 0; i < n; ++i)
 911                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 912                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 913                                 s = strcat(s, " ", argv(i));
 914                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 915                 if(fd >= 0)
 916                 {
 917                         j = search_getsize(fd);
 918                         for(i = 0; i < j; ++i)
 919                                 s = strcat(s, " ", search_getfilename(fd, i));
 920                         search_end(fd);
 921                 }
 922                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 923                 if(fd >= 0)
 924                 {
 925                         j = search_getsize(fd);
 926                         for(i = 0; i < j; ++i)
 927                                 s = strcat(s, " ", search_getfilename(fd, i));
 928                         search_end(fd);
 929                 }
 930                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 931         }
 932
 933         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 934         modname = "Xonotic";
 935         // physics/balance/config changes that count as mod
 936         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 937                 modname = cvar_string("g_mod_physics");
 938         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 939                 modname = cvar_string("g_mod_balance");
 940         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 941                 modname = cvar_string("g_mod_config");
 942         // weird mutators that deserve to count as mod
 943         if(autocvar_g_minstagib)
 944                 modname = "MinstaGib";
 945         // extra mutators that deserve to count as mod
 946         MUTATOR_CALLHOOK(SetModname);
 947
 948         // save it for later
 949         modname = strzone(modname);
 950
 951         WinningConditionHelper(); // set worldstatus
 952
 953         world_initialized = 1;
 954 }
 955
 956 void spawnfunc_light (void)
 957 {
 958         //makestatic (self); // Who the f___ did that?
 959         remove(self);
 960 }
 961
 962 string GetGametype()
 963 {
 964         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 965 }
 966
 967 string getmapname_stored;
 968 string GetMapname()
 969 {
 970         return mapname;
 971 }
 972
 973 float Map_Count, Map_Current;
 974 string Map_Current_Name;
 975
 976 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 977 float GetMaplistPosition()
 978 {
 979         float pos, idx;
 980         string map;
 981
 982         map = GetMapname();
 983         idx = autocvar_g_maplist_index;
 984
 985         if(idx >= 0)
 986                 if(idx < Map_Count)
 987                         if(map == argv(idx))
 988                                 return idx;
 989
 990         for(pos = 0; pos < Map_Count; ++pos)
 991                 if(map == argv(pos))
 992                         return pos;
 993
 994         // resume normal maplist rotation if current map is not in g_maplist
 995         return idx;
 996 }
 997
 998 float MapHasRightSize(string map)
 999 {
1000         float fh;
1001         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1002         if(autocvar_g_maplist_check_waypoints)
1003         {
1004                 dprint("checkwp "); dprint(map);
1005                 if(!fexists(strcat("maps/", map, ".waypoints")))
1006                 {
1007                         dprint(": no waypoints\n");
1008                         return FALSE;
1009                 }
1010                 dprint(": has waypoints\n");
1011         }
1012
1013         // open map size restriction file
1014         dprint("opensize "); dprint(map);
1015         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1016         if(fh >= 0)
1017         {
1018                 float mapmin, mapmax;
1019                 dprint(": ok, ");
1020                 mapmin = stof(fgets(fh));
1021                 mapmax = stof(fgets(fh));
1022                 fclose(fh);
1023                 if(player_count < mapmin)
1024                 {
1025                         dprint("not enough\n");
1026                         return FALSE;
1027                 }
1028                 if(player_count > mapmax)
1029                 {
1030                         dprint("too many\n");
1031                         return FALSE;
1032                 }
1033                 dprint("right size\n");
1034                 return TRUE;
1035         }
1036         dprint(": not found\n");
1037         return TRUE;
1038 }
1039
1040 string Map_Filename(float position)
1041 {
1042         return strcat("maps/", argv(position), ".bsp");
1043 }
1044
1045 string strwords(string s, float w)
1046 {
1047         float endpos;
1048         for(endpos = 0; w && endpos >= 0; --w)
1049                 endpos = strstrofs(s, " ", endpos + 1);
1050         if(endpos < 0)
1051                 return s;
1052         else
1053                 return substring(s, 0, endpos);
1054 }
1055
1056 float strhasword(string s, string w)
1057 {
1058         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1059 }
1060
1061 void Map_MarkAsRecent(string m)
1062 {
1063         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1064 }
1065
1066 float Map_IsRecent(string m)
1067 {
1068         return strhasword(autocvar_g_maplist_mostrecent, m);
1069 }
1070
1071 float Map_Check(float position, float pass)
1072 {
1073         string filename;
1074         string map_next;
1075         map_next = argv(position);
1076         if(pass <= 1)
1077         {
1078                 if(Map_IsRecent(map_next))
1079                         return 0;
1080         }
1081         filename = Map_Filename(position);
1082         if(MapInfo_CheckMap(map_next))
1083         {
1084                 if(pass == 2)
1085                         return 1;
1086                 if(MapHasRightSize(map_next))
1087                         return 1;
1088                 return 0;
1089         }
1090         else
1091                 dprint( "Couldn't select '", filename, "'..\n" );
1092
1093         return 0;
1094 }
1095
1096 void Map_Goto_SetStr(string nextmapname)
1097 {
1098         if(getmapname_stored != "")
1099                 strunzone(getmapname_stored);
1100         if(nextmapname == "")
1101                 getmapname_stored = "";
1102         else
1103                 getmapname_stored = strzone(nextmapname);
1104 }
1105
1106 void Map_Goto_SetFloat(float position)
1107 {
1108         cvar_set("g_maplist_index", ftos(position));
1109         Map_Goto_SetStr(argv(position));
1110 }
1111
1112 void Map_Goto(float reinit)
1113 {
1114         MapInfo_LoadMap(getmapname_stored, reinit);
1115 }
1116
1117 // return codes of map selectors:
1118 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1119 //   -2 = permanent failure
1120 float() MaplistMethod_Iterate = // usual method
1121 {
1122         float pass, i;
1123
1124         for(pass = 1; pass <= 2; ++pass)
1125         {
1126                 for(i = 1; i < Map_Count; ++i)
1127                 {
1128                         float mapindex;
1129                         mapindex = mod(i + Map_Current, Map_Count);
1130                         if(Map_Check(mapindex, pass))
1131                                 return mapindex;
1132                 }
1133         }
1134         return -1;
1135 }
1136
1137 float() MaplistMethod_Repeat = // fallback method
1138 {
1139         if(Map_Check(Map_Current, 2))
1140                 return Map_Current;
1141         return -2;
1142 }
1143
1144 float() MaplistMethod_Random = // random map selection
1145 {
1146         float i, imax;
1147
1148         imax = 42;
1149
1150         for(i = 0; i <= imax; ++i)
1151         {
1152                 float mapindex;
1153                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1154                 if(Map_Check(mapindex, 1))
1155                         return mapindex;
1156         }
1157         return -1;
1158 }
1159
1160 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1161 // the exponent sets a bias on the map selection:
1162 // the higher the exponent, the less likely "shortly repeated" same maps are
1163 {
1164         float i, j, imax, insertpos;
1165
1166         imax = 42;
1167
1168         for(i = 0; i <= imax; ++i)
1169         {
1170                 string newlist;
1171
1172                 // now reinsert this at another position
1173                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1174                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1175                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1176                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1177
1178                 // insert the current map there
1179                 newlist = "";
1180                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1181                         newlist = strcat(newlist, " ", argv(j));
1182                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1183                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1184                         newlist = strcat(newlist, " ", argv(j));
1185                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1186                 cvar_set("g_maplist", newlist);
1187                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1188
1189                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1190                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1191                 if(Map_Check(Map_Current, 1))
1192                         return Map_Current;
1193         }
1194         return -1;
1195 }
1196
1197 void Maplist_Init()
1198 {
1199         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1200         if(Map_Count == 0)
1201         {
1202                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1203                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1204                 if(autocvar_g_maplist_shuffle)
1205                         ShuffleMaplist();
1206                 localcmd("\nmenu_cmd sync\n");
1207                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1208         }
1209         if(Map_Count == 0)
1210                 error("empty maplist, cannot select a new map");
1211         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1212
1213         if(Map_Current_Name)
1214                 strunzone(Map_Current_Name);
1215         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1216         // this may or may not be correct, but who cares, in the worst case a map
1217         // isn't chosen in the first pass that should have been
1218 }
1219
1220 string GetNextMap()
1221 {
1222         float nextMap;
1223
1224         Maplist_Init();
1225         nextMap = -1;
1226
1227         if(nextMap == -1)
1228                 if(autocvar_g_maplist_shuffle > 0)
1229                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1230
1231         if(nextMap == -1)
1232                 if(autocvar_g_maplist_selectrandom)
1233                         nextMap = MaplistMethod_Random();
1234
1235         if(nextMap == -1)
1236                 nextMap = MaplistMethod_Iterate();
1237
1238         if(nextMap == -1)
1239                 nextMap = MaplistMethod_Repeat();
1240
1241         if(nextMap >= 0)
1242         {
1243                 Map_Goto_SetFloat(nextMap);
1244                 return getmapname_stored;
1245         }
1246
1247         return "";
1248 }
1249
1250 float DoNextMapOverride(float reinit)
1251 {
1252         if(autocvar_g_campaign)
1253         {
1254                 CampaignPostIntermission();
1255                 alreadychangedlevel = TRUE;
1256                 return TRUE;
1257         }
1258         if(autocvar_quit_when_empty)
1259         {
1260                 if(player_count <= currentbots)
1261                 {
1262                         localcmd("quit\n");
1263                         alreadychangedlevel = TRUE;
1264                         return TRUE;
1265                 }
1266         }
1267         if(autocvar_quit_and_redirect != "")
1268         {
1269                 redirection_target = strzone(autocvar_quit_and_redirect);
1270                 alreadychangedlevel = TRUE;
1271                 return TRUE;
1272         }
1273         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1274         {
1275                 localcmd("restart\n");
1276                 alreadychangedlevel = TRUE;
1277                 return TRUE;
1278         }
1279         if(autocvar_nextmap != "")
1280                 if(MapInfo_CheckMap(autocvar_nextmap))
1281                 {
1282                         Map_Goto_SetStr(autocvar_nextmap);
1283                         Map_Goto(reinit);
1284                         alreadychangedlevel = TRUE;
1285                         return TRUE;
1286                 }
1287         if(!reinit && autocvar_lastlevel)
1288         {
1289                 cvar_settemp_restore();
1290                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1291                 alreadychangedlevel = TRUE;
1292                 return TRUE;
1293         }
1294         return FALSE;
1295 }
1296
1297 void GotoNextMap(float reinit)
1298 {
1299         //string nextmap;
1300         //float n, nummaps;
1301         //string s;
1302         if (alreadychangedlevel)
1303                 return;
1304         alreadychangedlevel = TRUE;
1305
1306         {
1307                 string nextMap;
1308                 float allowReset;
1309
1310                 for(allowReset = 1; allowReset >= 0; --allowReset)
1311                 {
1312                         nextMap = GetNextMap();
1313                         if(nextMap != "")
1314                                 break;
1315
1316                         if(allowReset)
1317                         {
1318                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1319                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1320                                 if(autocvar_g_maplist_shuffle)
1321                                         ShuffleMaplist();
1322                                 localcmd("\nmenu_cmd sync\n");
1323                         }
1324                         else
1325                         {
1326                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1327                         }
1328                 }
1329                 Map_Goto(reinit);
1330         }
1331 }
1332
1333
1334 /*
1335 ============
1336 IntermissionThink
1337
1338 When the player presses attack or jump, change to the next level
1339 ============
1340 */
1341 .float autoscreenshot;
1342 void() MapVote_Start;
1343 void() MapVote_Think;
1344 float mapvote_initialized;
1345 void IntermissionThink()
1346 {
1347         FixIntermissionClient(self);
1348
1349         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1350         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1351
1352         if( (server_screenshot || client_screenshot)
1353                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1354         {
1355                 self.autoscreenshot = -1;
1356                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"", GetMapname(), strftime(FALSE, "%s"))); }
1357                 return;
1358         }
1359
1360         if (time < intermission_exittime)
1361                 return;
1362
1363         if(!mapvote_initialized)
1364                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1365                         return;
1366
1367         MapVote_Start();
1368 }
1369
1370 /*
1371 ============
1372 FindIntermission
1373
1374 Returns the entity to view from
1375 ============
1376 */
1377 /*
1378 entity FindIntermission()
1379 {
1380         local   entity spot;
1381         local   float cyc;
1382
1383 // look for info_intermission first
1384         spot = find (world, classname, "info_intermission");
1385         if (spot)
1386         {       // pick a random one
1387                 cyc = random() * 4;
1388                 while (cyc > 1)
1389                 {
1390                         spot = find (spot, classname, "info_intermission");
1391                         if (!spot)
1392                                 spot = find (spot, classname, "info_intermission");
1393                         cyc = cyc - 1;
1394                 }
1395                 return spot;
1396         }
1397
1398 // then look for the start position
1399         spot = find (world, classname, "info_player_start");
1400         if (spot)
1401                 return spot;
1402
1403 // testinfo_player_start is only found in regioned levels
1404         spot = find (world, classname, "testplayerstart");
1405         if (spot)
1406                 return spot;
1407
1408 // then look for the start position
1409         spot = find (world, classname, "info_player_deathmatch");
1410         if (spot)
1411                 return spot;
1412
1413         //objerror ("FindIntermission: no spot");
1414         return world;
1415 }
1416 */
1417
1418 /*
1419 ===============================================================================
1420
1421 RULES
1422
1423 ===============================================================================
1424 */
1425
1426 void DumpStats(float final)
1427 {
1428         float file;
1429         string s;
1430         float to_console;
1431         float to_eventlog;
1432         float to_file;
1433         float i;
1434
1435         to_console = autocvar_sv_logscores_console;
1436         to_eventlog = autocvar_sv_eventlog;
1437         to_file = autocvar_sv_logscores_file;
1438
1439         if(!final)
1440         {
1441                 to_console = TRUE; // always print printstats replies
1442                 to_eventlog = FALSE; // but never print them to the event log
1443         }
1444
1445         if(to_eventlog)
1446                 if(autocvar_sv_eventlog_console)
1447                         to_console = FALSE; // otherwise we get the output twice
1448
1449         if(final)
1450                 s = ":scores:";
1451         else
1452                 s = ":status:";
1453         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1454
1455         if(to_console)
1456                 print(s, "\n");
1457         if(to_eventlog)
1458                 GameLogEcho(s);
1459
1460         file = -1;
1461         if(to_file)
1462         {
1463                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1464                 if(file == -1)
1465                         to_file = FALSE;
1466                 else
1467                         fputs(file, strcat(s, "\n"));
1468         }
1469
1470         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1471         if(to_console)
1472                 print(s, "\n");
1473         if(to_eventlog)
1474                 GameLogEcho(s);
1475         if(to_file)
1476                 fputs(file, strcat(s, "\n"));
1477
1478         FOR_EACH_CLIENT(other)
1479         {
1480                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1481                 {
1482                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1483                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1484                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1485                                 s = strcat(s, ftos(other.team), ":");
1486                         else
1487                                 s = strcat(s, "spectator:");
1488
1489                         if(to_console)
1490                                 print(s, other.netname, "\n");
1491                         if(to_eventlog)
1492                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1493                         if(to_file)
1494                                 fputs(file, strcat(s, other.netname, "\n"));
1495                 }
1496         }
1497
1498         if(teamplay)
1499         {
1500                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1501                 if(to_console)
1502                         print(s, "\n");
1503                 if(to_eventlog)
1504                         GameLogEcho(s);
1505                 if(to_file)
1506                         fputs(file, strcat(s, "\n"));
1507
1508                 for(i = 1; i < 16; ++i)
1509                 {
1510                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1511                         s = strcat(s, ":", ftos(i));
1512                         if(to_console)
1513                                 print(s, "\n");
1514                         if(to_eventlog)
1515                                 GameLogEcho(s);
1516                         if(to_file)
1517                                 fputs(file, strcat(s, "\n"));
1518                 }
1519         }
1520
1521         if(to_console)
1522                 print(":end\n");
1523         if(to_eventlog)
1524                 GameLogEcho(":end");
1525         if(to_file)
1526         {
1527                 fputs(file, ":end\n");
1528                 fclose(file);
1529         }
1530 }
1531
1532 void FixIntermissionClient(entity e)
1533 {
1534         string s;
1535         if(!e.autoscreenshot) // initial call
1536         {
1537                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1538                 e.health = -2342;
1539                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1540                 e.solid = SOLID_NOT;
1541                 e.movetype = MOVETYPE_NONE;
1542                 e.takedamage = DAMAGE_NO;
1543                 if(e.weaponentity)
1544                 {
1545                         e.weaponentity.effects = EF_NODRAW;
1546                         if (e.weaponentity.weaponentity)
1547                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1548                 }
1549                 if(clienttype(e) == CLIENTTYPE_REAL)
1550                 {
1551                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1552                         s = autocvar_sv_intermission_cdtrack;
1553                         if(s != "")
1554                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1555                         msg_entity = e;
1556                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1557                 }
1558         }
1559 }
1560
1561 void minstagib_stop_countdown(entity e);
1562 /*
1563 go to the next level for deathmatch
1564 only called if a time or frag limit has expired
1565 */
1566 void NextLevel()
1567 {
1568         gameover = TRUE;
1569
1570         intermission_running = 1;
1571
1572 // enforce a wait time before allowing changelevel
1573         if(player_count > 0)
1574                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1575         else
1576                 intermission_exittime = -1;
1577
1578         /*
1579         WriteByte (MSG_ALL, SVC_CDTRACK);
1580         WriteByte (MSG_ALL, 3);
1581         WriteByte (MSG_ALL, 3);
1582         // done in FixIntermission
1583         */
1584
1585         //pos = FindIntermission ();
1586
1587         VoteReset();
1588
1589         DumpStats(TRUE);
1590
1591         // send statistics
1592         entity e;
1593         PlayerStats_EndMatch(1);
1594         FOR_EACH_CLIENT(e)
1595                 PlayerStats_AddGlobalInfo(e);
1596         PlayerStats_Shutdown();
1597         WeaponStats_Shutdown();
1598
1599         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1600
1601         if(autocvar_sv_eventlog)
1602                 GameLogEcho(":gameover");
1603
1604         GameLogClose();
1605
1606         FOR_EACH_PLAYER(other) {
1607                 minstagib_stop_countdown(other);
1608                 FixIntermissionClient(other);
1609                 if(other.winning)
1610                         bprint(other.netname, " ^7wins.\n");
1611         }
1612
1613         if(autocvar_g_campaign)
1614                 CampaignPreIntermission();
1615
1616         MUTATOR_CALLHOOK(MatchEnd);
1617
1618         localcmd("\nsv_hook_gameend\n");
1619 }
1620
1621 /*
1622 ============
1623 CheckRules_Player
1624
1625 Exit deathmatch games upon conditions
1626 ============
1627 */
1628 void CheckRules_Player()
1629 {
1630         if (gameover)   // someone else quit the game already
1631                 return;
1632
1633         if(self.deadflag == DEAD_NO)
1634                 self.play_time += frametime;
1635
1636         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1637         //   (div0: and that in CheckRules_World please)
1638 }
1639
1640 float checkrules_equality;
1641 float checkrules_suddendeathwarning;
1642 float checkrules_suddendeathend;
1643 float checkrules_overtimesadded; //how many overtimes have been already added
1644
1645 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1646 float WINNING_YES = 1; // winner found
1647 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1648 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1649
1650 float InitiateSuddenDeath()
1651 {
1652         // Check first whether normal overtimes could be added before initiating suddendeath mode
1653         // - for this timelimit_overtime needs to be >0 of course
1654         // - also check the winning condition calculated in the previous frame and only add normal overtime
1655         //   again, if at the point at which timelimit would be extended again, still no winner was found
1656         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1657         {
1658                 return 1; // need to call InitiateOvertime later
1659         }
1660         else
1661         {
1662                 if(!checkrules_suddendeathend)
1663                 {
1664                         if(autocvar_g_campaign)
1665                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1666                         else
1667                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1668                         if(g_race && !g_race_qualifying)
1669                                 race_StartCompleting();
1670                 }
1671                 return 0;
1672         }
1673 }
1674
1675 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1676 {
1677         ++checkrules_overtimesadded;
1678         //add one more overtime by simply extending the timelimit
1679         float tl;
1680         tl = autocvar_timelimit;
1681         tl += autocvar_timelimit_overtime;
1682         cvar_set("timelimit", ftos(tl));
1683
1684         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime);
1685 }
1686
1687 float GetWinningCode(float fraglimitreached, float equality)
1688 {
1689         if(autocvar_g_campaign == 1)
1690                 if(fraglimitreached)
1691                         return WINNING_YES;
1692                 else
1693                         return WINNING_NO;
1694
1695         else
1696                 if(equality)
1697                         if(fraglimitreached)
1698                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1699                         else
1700                                 return WINNING_NEVER;
1701                 else
1702                         if(fraglimitreached)
1703                                 return WINNING_YES;
1704                         else
1705                                 return WINNING_NO;
1706 }
1707
1708 // set the .winning flag for exactly those players with a given field value
1709 void SetWinners(.float field, float value)
1710 {
1711         entity head;
1712         FOR_EACH_PLAYER(head)
1713                 head.winning = (head.field == value);
1714 }
1715
1716 // set the .winning flag for those players with a given field value
1717 void AddWinners(.float field, float value)
1718 {
1719         entity head;
1720         FOR_EACH_PLAYER(head)
1721                 if(head.field == value)
1722                         head.winning = 1;
1723 }
1724
1725 // clear the .winning flags
1726 void ClearWinners(void)
1727 {
1728         entity head;
1729         FOR_EACH_PLAYER(head)
1730                 head.winning = 0;
1731 }
1732
1733 // Onslaught winning condition:
1734 // game terminates if only one team has a working generator (or none)
1735 float WinningCondition_Onslaught()
1736 {
1737         entity head;
1738         float t1, t2, t3, t4;
1739
1740         WinningConditionHelper(); // set worldstatus
1741
1742         if(inWarmupStage)
1743                 return WINNING_NO;
1744
1745         // first check if the game has ended
1746         t1 = t2 = t3 = t4 = 0;
1747         head = find(world, classname, "onslaught_generator");
1748         while (head)
1749         {
1750                 if (head.health > 0)
1751                 {
1752                         if (head.team == FL_TEAM_1) t1 = 1;
1753                         if (head.team == FL_TEAM_2) t2 = 1;
1754                         if (head.team == FL_TEAM_3) t3 = 1;
1755                         if (head.team == FL_TEAM_4) t4 = 1;
1756                 }
1757                 head = find(head, classname, "onslaught_generator");
1758         }
1759         if (t1 + t2 + t3 + t4 < 2)
1760         {
1761                 // game over, only one team remains (or none)
1762                 ClearWinners();
1763                 if (t1) SetWinners(team, FL_TEAM_1);
1764                 if (t2) SetWinners(team, FL_TEAM_2);
1765                 if (t3) SetWinners(team, FL_TEAM_3);
1766                 if (t4) SetWinners(team, FL_TEAM_4);
1767                 dprint("Have a winner, ending game.\n");
1768                 return WINNING_YES;
1769         }
1770
1771         // Two or more teams remain
1772         return WINNING_NO;
1773 }
1774
1775 float LMS_NewPlayerLives()
1776 {
1777         float fl;
1778         fl = autocvar_fraglimit;
1779         if(fl == 0)
1780                 fl = 999;
1781
1782         // first player has left the game for dying too much? Nobody else can get in.
1783         if(lms_lowest_lives < 1)
1784                 return 0;
1785
1786         if(!autocvar_g_lms_join_anytime)
1787                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1788                         return 0;
1789
1790         return bound(1, lms_lowest_lives, fl);
1791 }
1792
1793 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1794 // they win. Otherwise the defending team wins once the timelimit passes.
1795 void assault_new_round();
1796 float WinningCondition_Assault()
1797 {
1798         float status;
1799
1800         WinningConditionHelper(); // set worldstatus
1801
1802         status = WINNING_NO;
1803         // as the timelimit has not yet passed just assume the defending team will win
1804         if(assault_attacker_team == FL_TEAM_1)
1805         {
1806                 SetWinners(team, FL_TEAM_2);
1807         }
1808         else
1809         {
1810                 SetWinners(team, FL_TEAM_1);
1811         }
1812
1813         entity ent;
1814         ent = find(world, classname, "target_assault_roundend");
1815         if(ent)
1816         {
1817                 if(ent.winning) // round end has been triggered by attacking team
1818                 {
1819                         bprint("ASSAULT: round completed...\n");
1820                         SetWinners(team, assault_attacker_team);
1821
1822                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1823
1824                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1825                         {
1826                                 status = WINNING_YES;
1827                         }
1828                         else
1829                         {
1830                                 entity oldself;
1831                                 oldself = self;
1832                                 self = ent;
1833                                 assault_new_round();
1834                                 self = oldself;
1835                         }
1836                 }
1837         }
1838
1839         return status;
1840 }
1841
1842 // LMS winning condition: game terminates if and only if there's at most one
1843 // one player who's living lives. Top two scores being equal cancels the time
1844 // limit.
1845 float WinningCondition_LMS()
1846 {
1847         entity head, head2;
1848         float have_player;
1849         float have_players;
1850         float l;
1851
1852         have_player = FALSE;
1853         have_players = FALSE;
1854         l = LMS_NewPlayerLives();
1855
1856         head = find(world, classname, "player");
1857         if(head)
1858                 have_player = TRUE;
1859         head2 = find(head, classname, "player");
1860         if(head2)
1861                 have_players = TRUE;
1862
1863         if(have_player)
1864         {
1865                 // we have at least one player
1866                 if(have_players)
1867                 {
1868                         // two or more active players - continue with the game
1869                 }
1870                 else
1871                 {
1872                         // exactly one player?
1873
1874                         ClearWinners();
1875                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1876
1877                         if(l)
1878                         {
1879                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1880                                 return WINNING_NO;
1881                         }
1882                         else
1883                         {
1884                                 // a winner!
1885                                 // and assign him his first place
1886                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1887                                 return WINNING_YES;
1888                         }
1889                 }
1890         }
1891         else
1892         {
1893                 // nobody is playing at all...
1894                 if(l)
1895                 {
1896                         // wait for players...
1897                 }
1898                 else
1899                 {
1900                         // SNAFU (maybe a draw game?)
1901                         ClearWinners();
1902                         dprint("No players, ending game.\n");
1903                         return WINNING_YES;
1904                 }
1905         }
1906
1907         // When we get here, we have at least two players who are actually LIVING,
1908         // now check if the top two players have equal score.
1909         WinningConditionHelper();
1910
1911         ClearWinners();
1912         if(WinningConditionHelper_winner)
1913                 WinningConditionHelper_winner.winning = TRUE;
1914         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1915                 return WINNING_NEVER;
1916
1917         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1918         return WINNING_NO;
1919 }
1920
1921 void ShuffleMaplist()
1922 {
1923         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1924 }
1925
1926 float leaderfrags;
1927 float WinningCondition_Scores(float limit, float leadlimit)
1928 {
1929         float limitreached;
1930
1931         // TODO make everything use THIS winning condition (except LMS)
1932         WinningConditionHelper();
1933
1934         if(teamplay)
1935         {
1936                 team1_score = TeamScore_GetCompareValue(FL_TEAM_1);
1937                 team2_score = TeamScore_GetCompareValue(FL_TEAM_2);
1938                 team3_score = TeamScore_GetCompareValue(FL_TEAM_3);
1939                 team4_score = TeamScore_GetCompareValue(FL_TEAM_4);
1940         }
1941
1942         ClearWinners();
1943         if(WinningConditionHelper_winner)
1944                 WinningConditionHelper_winner.winning = 1;
1945         if(WinningConditionHelper_winnerteam >= 0)
1946                 SetWinners(team, WinningConditionHelper_winnerteam);
1947
1948         if(WinningConditionHelper_lowerisbetter)
1949         {
1950                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1951                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1952                 limit = -limit;
1953         }
1954
1955         if(WinningConditionHelper_zeroisworst)
1956                 leadlimit = 0; // not supported in this mode
1957
1958         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1959         // these modes always score in increments of 1, thus this makes sense
1960         {
1961                 if(leaderfrags != WinningConditionHelper_topscore)
1962                 {
1963                         leaderfrags = WinningConditionHelper_topscore;
1964
1965                         if (limit)
1966                         if (leaderfrags == limit - 1)
1967                                 Announce("1fragleft");
1968                         else if (leaderfrags == limit - 2)
1969                                 Announce("2fragsleft");
1970                         else if (leaderfrags == limit - 3)
1971                                 Announce("3fragsleft");
1972                 }
1973         }
1974
1975         limitreached = FALSE;
1976         if(limit)
1977                 if(WinningConditionHelper_topscore >= limit)
1978                         limitreached = TRUE;
1979         if(leadlimit)
1980         {
1981                 float leadlimitreached;
1982                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1983                 if(autocvar_leadlimit_and_fraglimit)
1984                         limitreached = (limitreached && leadlimitreached);
1985                 else
1986                         limitreached = (limitreached || leadlimitreached);
1987         }
1988
1989         if(limit)
1990                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1991
1992         return GetWinningCode(
1993                 WinningConditionHelper_topscore && limitreached,
1994                 WinningConditionHelper_equality
1995         );
1996 }
1997
1998 float WinningCondition_Race(float fraglimit)
1999 {
2000         float wc;
2001         entity p;
2002         float n, c;
2003
2004         n = 0;
2005         c = 0;
2006         FOR_EACH_PLAYER(p)
2007         {
2008                 ++n;
2009                 if(p.race_completed)
2010                         ++c;
2011         }
2012         if(n && (n == c))
2013                 return WINNING_YES;
2014         wc = WinningCondition_Scores(fraglimit, 0);
2015
2016         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2017         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2018         // do NOT support equality when the laps are all raced!
2019                 return WINNING_STARTSUDDENDEATHOVERTIME;
2020         else
2021                 return WINNING_NEVER;
2022 }
2023
2024 float WinningCondition_QualifyingThenRace(float limit)
2025 {
2026         float wc;
2027         wc = WinningCondition_Scores(limit, 0);
2028
2029         // NEVER initiate overtime
2030         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2031         {
2032                 return WINNING_YES;
2033         }
2034
2035         return wc;
2036 }
2037
2038 float WinningCondition_RanOutOfSpawns()
2039 {
2040         entity head;
2041
2042         if(have_team_spawns <= 0)
2043                 return WINNING_NO;
2044
2045         if(autocvar_g_spawn_useallspawns <= 0)
2046                 return WINNING_NO;
2047
2048         if(!some_spawn_has_been_used)
2049                 return WINNING_NO;
2050
2051         team1_score = team2_score = team3_score = team4_score = 0;
2052
2053         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2054         {
2055                 if(head.team == FL_TEAM_1)
2056                         team1_score = 1;
2057                 else if(head.team == FL_TEAM_2)
2058                         team2_score = 1;
2059                 else if(head.team == FL_TEAM_3)
2060                         team3_score = 1;
2061                 else if(head.team == FL_TEAM_4)
2062                         team4_score = 1;
2063         }
2064
2065         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2066         {
2067                 if(head.team == FL_TEAM_1)
2068                         team1_score = 1;
2069                 else if(head.team == FL_TEAM_2)
2070                         team2_score = 1;
2071                 else if(head.team == FL_TEAM_3)
2072                         team3_score = 1;
2073                 else if(head.team == FL_TEAM_4)
2074                         team4_score = 1;
2075         }
2076
2077         ClearWinners();
2078         if(team1_score + team2_score + team3_score + team4_score == 0)
2079         {
2080                 checkrules_equality = TRUE;
2081                 return WINNING_YES;
2082         }
2083         else if(team1_score + team2_score + team3_score + team4_score == 1)
2084         {
2085                 float t, i;
2086                 if(team1_score)
2087                         t = FL_TEAM_1;
2088                 else if(team2_score)
2089                         t = FL_TEAM_2;
2090                 else if(team3_score)
2091                         t = FL_TEAM_3;
2092                 else // if(team4_score)
2093                         t = FL_TEAM_4;
2094                 CheckAllowedTeams(world);
2095                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2096                 {
2097                         if(t != FL_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(FL_TEAM_1, i, -1000);
2098                         if(t != FL_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(FL_TEAM_2, i, -1000);
2099                         if(t != FL_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(FL_TEAM_3, i, -1000);
2100                         if(t != FL_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(FL_TEAM_4, i, -1000);
2101                 }
2102
2103                 AddWinners(team, t);
2104                 return WINNING_YES;
2105         }
2106         else
2107                 return WINNING_NO;
2108 }
2109
2110 /*
2111 ============
2112 CheckRules_World
2113
2114 Exit deathmatch games upon conditions
2115 ============
2116 */
2117 void ReadyRestart();
2118 void CheckRules_World()
2119 {
2120         float timelimit;
2121         float fraglimit;
2122         float leadlimit;
2123
2124         VoteThink();
2125         MapVote_Think();
2126
2127         SetDefaultAlpha();
2128
2129         /*
2130         MapVote_Think should now do that part
2131         if (intermission_running)
2132                 if (time >= intermission_exittime + 60)
2133                 {
2134                         if(!DoNextMapOverride())
2135                                 GotoNextMap();
2136                         return;
2137                 }
2138         */
2139
2140         if (gameover)   // someone else quit the game already
2141         {
2142                 if(player_count == 0) // Nobody there? Then let's go to the next map
2143                         MapVote_Start();
2144                         // this will actually check the player count in the next frame
2145                         // again, but this shouldn't hurt
2146                 return;
2147         }
2148
2149         timelimit = autocvar_timelimit * 60;
2150         fraglimit = autocvar_fraglimit;
2151         leadlimit = autocvar_leadlimit;
2152
2153         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2154         {
2155                 if(timelimit > 0)
2156                         timelimit = 0; // timelimit is not made for warmup
2157                 if(fraglimit > 0)
2158                         fraglimit = 0; // no fraglimit for now
2159                 leadlimit = 0; // no leadlimit for now
2160         }
2161
2162         if(timelimit > 0)
2163         {
2164                 timelimit += game_starttime;
2165         }
2166         else if (timelimit < 0)
2167         {
2168                 // endmatch
2169                 NextLevel();
2170                 return;
2171         }
2172
2173         if(g_onslaught)
2174                 timelimit = 0; // ONS has its own overtime rule
2175
2176         float wantovertime;
2177         wantovertime = 0;
2178
2179         if(timelimit > game_starttime)
2180                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2181         else
2182                 game_completion_ratio = 0;
2183
2184         if(checkrules_suddendeathend)
2185         {
2186                 if(!checkrules_suddendeathwarning)
2187                 {
2188                         checkrules_suddendeathwarning = TRUE;
2189                         if(g_race && !g_race_qualifying)
2190                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2191                         else
2192                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2193                 }
2194         }
2195         else
2196         {
2197                 if (timelimit && time >= timelimit)
2198                 {
2199                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2200                         {
2201                                 float totalplayers;
2202                                 float playerswithlaps;
2203                                 float readyplayers;
2204                                 entity head;
2205                                 totalplayers = playerswithlaps = readyplayers = 0;
2206                                 FOR_EACH_PLAYER(head)
2207                                 {
2208                                         ++totalplayers;
2209                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2210                                                 ++playerswithlaps;
2211                                         if(head.ready)
2212                                                 ++readyplayers;
2213                                 }
2214
2215                                 // at least 2 of the players have completed a lap: start the RACE
2216                                 // otherwise, the players should end the qualifying on their own
2217                                 if(readyplayers || playerswithlaps >= 2)
2218                                 {
2219                                         checkrules_suddendeathend = 0;
2220                                         ReadyRestart(); // go to race
2221                                         return;
2222                                 }
2223                                 else
2224                                         wantovertime |= InitiateSuddenDeath();
2225                         }
2226                         else
2227                                 wantovertime |= InitiateSuddenDeath();
2228                 }
2229         }
2230
2231         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2232         {
2233                 NextLevel();
2234                 return;
2235         }
2236
2237         float checkrules_status;
2238         checkrules_status = WinningCondition_RanOutOfSpawns();
2239         if(checkrules_status == WINNING_YES)
2240         {
2241                 bprint("Hey! Someone ran out of spawns!\n");
2242         }
2243         else if(g_race && !g_race_qualifying && timelimit >= 0)
2244         {
2245                 checkrules_status = WinningCondition_Race(fraglimit);
2246                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2247         }
2248         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2249         {
2250                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2251                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2252         }
2253         else if(g_assault)
2254         {
2255                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2256         }
2257         else if(g_lms)
2258         {
2259                 checkrules_status = WinningCondition_LMS();
2260         }
2261         else if (g_onslaught)
2262         {
2263                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2264         }
2265         else
2266         {
2267                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2268                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2269         }
2270
2271         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2272         {
2273                 checkrules_status = WINNING_NEVER;
2274                 checkrules_overtimesadded = -1;
2275                 wantovertime |= InitiateSuddenDeath();
2276         }
2277
2278         if(checkrules_status == WINNING_NEVER)
2279                 // equality cases! Nobody wins if the overtime ends in a draw.
2280                 ClearWinners();
2281
2282         if(wantovertime)
2283         {
2284                 if(checkrules_status == WINNING_NEVER)
2285                         InitiateOvertime();
2286                 else
2287                         checkrules_status = WINNING_YES;
2288         }
2289
2290         if(checkrules_suddendeathend)
2291                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2292                         checkrules_status = WINNING_YES;
2293
2294         if(checkrules_status == WINNING_YES)
2295         {
2296                 //print("WINNING\n");
2297                 NextLevel();
2298         }
2299 }
2300
2301 float mapvote_nextthink;
2302 float mapvote_initialized;
2303 float mapvote_keeptwotime;
2304 float mapvote_timeout;
2305 string mapvote_message;
2306 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2307 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2308 float mapvote_screenshot_dirs_count;
2309
2310 float mapvote_count;
2311 float mapvote_count_real;
2312 string mapvote_maps[MAPVOTE_COUNT];
2313 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2314 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2315 float mapvote_maps_suggested[MAPVOTE_COUNT];
2316 string mapvote_suggestions[MAPVOTE_COUNT];
2317 float mapvote_suggestion_ptr;
2318 float mapvote_voters;
2319 float mapvote_selections[MAPVOTE_COUNT];
2320 float mapvote_run;
2321 float mapvote_detail;
2322 float mapvote_abstain;
2323 .float mapvote;
2324
2325 void MapVote_ClearAllVotes()
2326 {
2327         FOR_EACH_CLIENT(other)
2328                 other.mapvote = 0;
2329 }
2330
2331 string MapVote_Suggest(string m)
2332 {
2333         float i;
2334         if(m == "")
2335                 return "That's not how to use this command.";
2336         if(!autocvar_g_maplist_votable_suggestions)
2337                 return "Suggestions are not accepted on this server.";
2338         if(mapvote_initialized)
2339                 return "Can't suggest - voting is already in progress!";
2340         m = MapInfo_FixName(m);
2341         if not(m)
2342                 return "The map you suggested is not available on this server.";
2343         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2344                 if(Map_IsRecent(m))
2345                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2346
2347         if(!MapInfo_CheckMap(m))
2348                 return "The map you suggested does not support the current game mode.";
2349         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2350                 if(mapvote_suggestions[i] == m)
2351                         return "This map was already suggested.";
2352         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2353         {
2354                 i = floor(random() * mapvote_suggestion_ptr);
2355         }
2356         else
2357         {
2358                 i = mapvote_suggestion_ptr;
2359                 mapvote_suggestion_ptr += 1;
2360         }
2361         if(mapvote_suggestions[i] != "")
2362                 strunzone(mapvote_suggestions[i]);
2363         mapvote_suggestions[i] = strzone(m);
2364         if(autocvar_sv_eventlog)
2365                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2366         return strcat("Suggestion of ", m, " accepted.");
2367 }
2368
2369 void MapVote_AddVotable(string nextMap, float isSuggestion)
2370 {
2371         float j, i, o;
2372         string pakfile, mapfile;
2373
2374         if(nextMap == "")
2375                 return;
2376         for(j = 0; j < mapvote_count; ++j)
2377                 if(mapvote_maps[j] == nextMap)
2378                         return;
2379         // suggestions might be no longer valid/allowed after gametype switch!
2380         if(isSuggestion)
2381                 if(!MapInfo_CheckMap(nextMap))
2382                         return;
2383         mapvote_maps[mapvote_count] = strzone(nextMap);
2384         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2385
2386         pakfile = string_null;
2387         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2388         {
2389                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2390                 pakfile = whichpack(strcat(mapfile, ".tga"));
2391                 if(pakfile == "")
2392                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2393                 if(pakfile == "")
2394                         pakfile = whichpack(strcat(mapfile, ".png"));
2395                 if(pakfile != "")
2396                         break;
2397         }
2398         if(i >= mapvote_screenshot_dirs_count)
2399                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2400         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2401                 pakfile = substring(pakfile, o, -1);
2402
2403         mapvote_maps_screenshot_dir[mapvote_count] = i;
2404         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2405
2406         mapvote_count += 1;
2407 }
2408
2409 void MapVote_Spawn();
2410 void MapVote_Init()
2411 {
2412         float i;
2413         float nmax, smax;
2414
2415         MapVote_ClearAllVotes();
2416
2417         mapvote_count = 0;
2418         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2419         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2420
2421         if(mapvote_abstain)
2422                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2423         else
2424                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2425         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2426
2427         // we need this for AddVotable, as that cycles through the screenshot dirs
2428         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2429         if(mapvote_screenshot_dirs_count == 0)
2430                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2431         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2432         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2433                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2434
2435         if(mapvote_suggestion_ptr)
2436                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2437                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2438
2439         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2440                 MapVote_AddVotable(GetNextMap(), FALSE);
2441
2442         if(mapvote_count == 0)
2443         {
2444                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2445                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2446                 if(autocvar_g_maplist_shuffle)
2447                         ShuffleMaplist();
2448                 localcmd("\nmenu_cmd sync\n");
2449                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2450                         MapVote_AddVotable(GetNextMap(), FALSE);
2451         }
2452
2453         mapvote_count_real = mapvote_count;
2454         if(mapvote_abstain)
2455                 MapVote_AddVotable("don't care", 0);
2456
2457         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2458
2459         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2460         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2461         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2462                 mapvote_keeptwotime = 0;
2463         mapvote_message = "Choose a map and press its key!";
2464
2465         MapVote_Spawn();
2466 }
2467
2468 void MapVote_SendPicture(float id)
2469 {
2470         msg_entity = self;
2471         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2472         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2473         WriteByte(MSG_ONE, id);
2474         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2475 }
2476
2477 float MapVote_GetMapMask()
2478 {
2479         float mask, i, power;
2480         mask = 0;
2481         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2482                 if(mapvote_maps[i] != "")
2483                         mask |= power;
2484         return mask;
2485 }
2486
2487 entity mapvote_ent;
2488 float MapVote_SendEntity(entity to, float sf)
2489 {
2490         float i;
2491
2492         if(sf & 1)
2493                 sf &~= 2; // if we send 1, we don't need to also send 2
2494
2495         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2496         WriteByte(MSG_ENTITY, sf);
2497
2498         if(sf & 1)
2499         {
2500                 // flag 1 == initialization
2501                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2502                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2503                 WriteString(MSG_ENTITY, "");
2504                 WriteByte(MSG_ENTITY, mapvote_count);
2505                 WriteByte(MSG_ENTITY, mapvote_abstain);
2506                 WriteByte(MSG_ENTITY, mapvote_detail);
2507                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2508                 if(mapvote_count <= 8)
2509                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2510                 else
2511                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2512                 for(i = 0; i < mapvote_count; ++i)
2513                         if(mapvote_maps[i] != "")
2514                         {
2515                                 if(mapvote_abstain && i == mapvote_count - 1)
2516                                 {
2517                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2518                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2519                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2520                                 }
2521                                 else
2522                                 {
2523                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2524                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2525                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2526                                 }
2527                         }
2528         }
2529
2530         if(sf & 2)
2531         {
2532                 // flag 2 == update of mask
2533                 if(mapvote_count <= 8)
2534                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2535                 else
2536                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2537         }
2538
2539         if(sf & 4)
2540         {
2541                 if(mapvote_detail)
2542                         for(i = 0; i < mapvote_count; ++i)
2543                                 if(mapvote_maps[i] != "")
2544                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2545
2546                 WriteByte(MSG_ENTITY, to.mapvote);
2547         }
2548
2549         return TRUE;
2550 }
2551
2552 void MapVote_Spawn()
2553 {
2554         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2555 }
2556
2557 void MapVote_TouchMask()
2558 {
2559         mapvote_ent.SendFlags |= 2;
2560 }
2561
2562 void MapVote_TouchVotes(entity voter)
2563 {
2564         mapvote_ent.SendFlags |= 4;
2565 }
2566
2567 float MapVote_Finished(float mappos)
2568 {
2569         string result;
2570         float i;
2571         float didntvote;
2572
2573         if(autocvar_sv_eventlog)
2574         {
2575                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2576                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2577                 didntvote = mapvote_voters;
2578                 for(i = 0; i < mapvote_count; ++i)
2579                         if(mapvote_maps[i] != "")
2580                         {
2581                                 didntvote -= mapvote_selections[i];
2582                                 if(i != mappos)
2583                                 {
2584                                         result = strcat(result, ":", mapvote_maps[i]);
2585                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2586                                 }
2587                         }
2588                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2589
2590                 GameLogEcho(result);
2591                 if(mapvote_maps_suggested[mappos])
2592                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2593         }
2594
2595         FOR_EACH_REALCLIENT(other)
2596                 FixClientCvars(other);
2597
2598         Map_Goto_SetStr(mapvote_maps[mappos]);
2599         Map_Goto(0);
2600         alreadychangedlevel = TRUE;
2601         return TRUE;
2602 }
2603 void MapVote_CheckRules_1()
2604 {
2605         float i;
2606
2607         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2608         {
2609                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2610                 mapvote_selections[i] = 0;
2611         }
2612
2613         mapvote_voters = 0;
2614         FOR_EACH_REALCLIENT(other)
2615         {
2616                 ++mapvote_voters;
2617                 if(other.mapvote)
2618                 {
2619                         i = other.mapvote - 1;
2620                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2621                         mapvote_selections[i] = mapvote_selections[i] + 1;
2622                 }
2623         }
2624 }
2625
2626 float MapVote_CheckRules_2()
2627 {
2628         float i;
2629         float firstPlace, secondPlace;
2630         float firstPlaceVotes, secondPlaceVotes;
2631         float mapvote_voters_real;
2632         string result;
2633
2634         if(mapvote_count_real == 1)
2635                 return MapVote_Finished(0);
2636
2637         mapvote_voters_real = mapvote_voters;
2638         if(mapvote_abstain)
2639                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2640
2641         RandomSelection_Init();
2642         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2643                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2644         firstPlace = RandomSelection_chosen_float;
2645         firstPlaceVotes = RandomSelection_best_priority;
2646         //dprint("First place: ", ftos(firstPlace), "\n");
2647         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2648
2649         RandomSelection_Init();
2650         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2651                 if(i != firstPlace)
2652                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2653         secondPlace = RandomSelection_chosen_float;
2654         secondPlaceVotes = RandomSelection_best_priority;
2655         //dprint("Second place: ", ftos(secondPlace), "\n");
2656         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2657
2658         if(firstPlace == -1)
2659                 error("No first place in map vote... WTF?");
2660
2661         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2662                 return MapVote_Finished(firstPlace);
2663
2664         if(mapvote_keeptwotime)
2665                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2666                 {
2667                         float didntvote;
2668                         MapVote_TouchMask();
2669                         mapvote_message = "Now decide between the TOP TWO!";
2670                         mapvote_keeptwotime = 0;
2671                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2672                         result = strcat(result, ":", ftos(firstPlaceVotes));
2673                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2674                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2675                         didntvote = mapvote_voters;
2676                         for(i = 0; i < mapvote_count; ++i)
2677                                 if(mapvote_maps[i] != "")
2678                                 {
2679                                         didntvote -= mapvote_selections[i];
2680                                         if(i != firstPlace)
2681                                                 if(i != secondPlace)
2682                                                 {
2683                                                         result = strcat(result, ":", mapvote_maps[i]);
2684                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2685                                                         if(i < mapvote_count_real)
2686                                                         {
2687                                                                 strunzone(mapvote_maps[i]);
2688                                                                 mapvote_maps[i] = "";
2689                                                                 strunzone(mapvote_maps_pakfile[i]);
2690                                                                 mapvote_maps_pakfile[i] = "";
2691                                                         }
2692                                                 }
2693                                 }
2694                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2695                         if(autocvar_sv_eventlog)
2696                                 GameLogEcho(result);
2697                 }
2698
2699         return FALSE;
2700 }
2701 void MapVote_Tick()
2702 {
2703         float keeptwo;
2704         float totalvotes;
2705
2706         keeptwo = mapvote_keeptwotime;
2707         MapVote_CheckRules_1(); // count
2708         if(MapVote_CheckRules_2()) // decide
2709                 return;
2710
2711         totalvotes = 0;
2712         FOR_EACH_REALCLIENT(other)
2713         {
2714                 // hide scoreboard again
2715                 if(other.health != 2342)
2716                 {
2717                         other.health = 2342;
2718                         other.impulse = 0;
2719                         if(clienttype(other) == CLIENTTYPE_REAL)
2720                         {
2721                                 msg_entity = other;
2722                                 WriteByte(MSG_ONE, SVC_FINALE);
2723                                 WriteString(MSG_ONE, "");
2724                         }
2725                 }
2726
2727                 // clear possibly invalid votes
2728                 if(mapvote_maps[other.mapvote - 1] == "")
2729                         other.mapvote = 0;
2730                 // use impulses as new vote
2731                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2732                         if(mapvote_maps[other.impulse - 1] != "")
2733                         {
2734                                 other.mapvote = other.impulse;
2735                                 MapVote_TouchVotes(other);
2736                         }
2737                 other.impulse = 0;
2738
2739                 if(other.mapvote)
2740                         ++totalvotes;
2741         }
2742
2743         MapVote_CheckRules_1(); // just count
2744 }
2745 void MapVote_Start()
2746 {
2747         if(mapvote_run)
2748                 return;
2749
2750         // wait for stats to be sent first
2751         if(!playerstats_waitforme)
2752                 return;
2753
2754         MapInfo_Enumerate();
2755         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2756                 mapvote_run = TRUE;
2757 }
2758 void MapVote_Think()
2759 {
2760         if(!mapvote_run)
2761                 return;
2762
2763         if(alreadychangedlevel)
2764                 return;
2765
2766         if(time < mapvote_nextthink)
2767                 return;
2768         //dprint("tick\n");
2769
2770         mapvote_nextthink = time + 0.5;
2771
2772         if(!mapvote_initialized)
2773         {
2774                 if(autocvar_rescan_pending == 1)
2775                 {
2776                         cvar_set("rescan_pending", "2");
2777                         localcmd("fs_rescan\nrescan_pending 3\n");
2778                         return;
2779                 }
2780                 else if(autocvar_rescan_pending == 2)
2781                 {
2782                         return;
2783                 }
2784                 else if(autocvar_rescan_pending == 3)
2785                 {
2786                         // now build missing mapinfo files
2787                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2788                                 return;
2789
2790                         // we're done, start the timer
2791                         cvar_set("rescan_pending", "0");
2792                 }
2793
2794                 mapvote_initialized = TRUE;
2795                 if(DoNextMapOverride(0))
2796                         return;
2797                 if(!autocvar_g_maplist_votable || player_count <= 0)
2798                 {
2799                         GotoNextMap(0);
2800                         return;
2801                 }
2802                 MapVote_Init();
2803         }
2804
2805         MapVote_Tick();
2806 }
2807
2808 string GotoMap(string m)
2809 {
2810         if(!MapInfo_CheckMap(m))
2811                 return "The map you chose is not available on this server.";
2812         cvar_set("nextmap", m);
2813         cvar_set("timelimit", "-1");
2814         if(mapvote_initialized || alreadychangedlevel)
2815         {
2816                 if(DoNextMapOverride(0))
2817                         return "Map switch initiated.";
2818                 else
2819                         return "Hm... no. For some reason I like THIS map more.";
2820         }
2821         else
2822                 return "Map switch will happen after scoreboard.";
2823 }
2824
2825
2826 void EndFrame()
2827 {
2828         float altime;
2829         FOR_EACH_REALCLIENT(self)
2830         {
2831                 if(self.classname == "spectator")
2832                 {
2833                         if(self.enemy.typehitsound)
2834                                 self.typehit_time = time;
2835                         else if(self.enemy.hitsound)
2836                                 self.hit_time = time;
2837                 }
2838                 else
2839                 {
2840                         if(self.typehitsound)
2841                                 self.typehit_time = time;
2842                         else if(self.hitsound)
2843                                 self.hit_time = time;
2844                 }
2845         }
2846         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2847         // add 1 frametime because after this, engine SV_Physics
2848         // increases time by a frametime and then networks the frame
2849         // add another frametime because client shows everything with
2850         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2851         // needed!
2852         FOR_EACH_CLIENT(self)
2853         {
2854                 self.hitsound = FALSE;
2855                 self.typehitsound = FALSE;
2856                 antilag_record(self, altime);
2857         }
2858 }
2859
2860
2861 /*
2862  * RedirectionThink:
2863  * returns TRUE if redirecting
2864  */
2865 float redirection_timeout;
2866 float redirection_nextthink;
2867 float RedirectionThink()
2868 {
2869         float clients_found;
2870
2871         if(redirection_target == "")
2872                 return FALSE;
2873
2874         if(!redirection_timeout)
2875         {
2876                 cvar_set("sv_public", "-2");
2877                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2878                 if(redirection_target == "self")
2879                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2880                 else
2881                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2882         }
2883
2884         if(time < redirection_nextthink)
2885                 return TRUE;
2886
2887         redirection_nextthink = time + 1;
2888
2889         clients_found = 0;
2890         FOR_EACH_REALCLIENT(self)
2891         {
2892                 // TODO add timer
2893                 print("Redirecting: sending connect command to ", self.netname, "\n");
2894                 if(redirection_target == "self")
2895                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2896                 else
2897                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2898                 ++clients_found;
2899         }
2900
2901         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2902
2903         if(time > redirection_timeout || clients_found == 0)
2904                 localcmd("\nwait; wait; wait; quit\n");
2905
2906         return TRUE;
2907 }
2908
2909 void TargetMusic_RestoreGame();
2910 void RestoreGame()
2911 {
2912         // Loaded from a save game
2913         // some things then break, so let's work around them...
2914
2915         // Progs DB (capture records)
2916         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2917
2918         // Mapinfo
2919         MapInfo_Shutdown();
2920         MapInfo_Enumerate();
2921         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2922         WeaponStats_Init();
2923
2924         TargetMusic_RestoreGame();
2925 }
2926
2927 void Shutdown()
2928 {
2929         entity e;
2930
2931         gameover = 2;
2932
2933         if(world_initialized > 0)
2934         {
2935                 world_initialized = 0;
2936                 print("Saving persistent data...\n");
2937                 Ban_SaveBans();
2938
2939                 PlayerStats_EndMatch(0);
2940                 FOR_EACH_CLIENT(e)
2941                         PlayerStats_AddGlobalInfo(e);
2942                 PlayerStats_Shutdown();
2943
2944                 if(!cheatcount_total)
2945                 {
2946                         if(autocvar_sv_db_saveasdump)
2947                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2948                         else
2949                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2950                 }
2951                 if(autocvar_developer)
2952                 {
2953                         if(autocvar_sv_db_saveasdump)
2954                                 db_dump(TemporaryDB, "server-temp.db");
2955                         else
2956                                 db_save(TemporaryDB, "server-temp.db");
2957                 }
2958                 CheatShutdown(); // must be after cheatcount check
2959                 db_close(ServerProgsDB);
2960                 db_close(TemporaryDB);
2961                 print("done!\n");
2962                 // tell the bot system the game is ending now
2963                 bot_endgame();
2964
2965                 WeaponStats_Shutdown();
2966                 MapInfo_Shutdown();
2967         }
2968         else if(world_initialized == 0)
2969         {
2970                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2971         }
2972 }