qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(autocvar__sv_init)
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(autocvar_g_maplist_shuffle)
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 239 #define BADCVAR(p) if(k == p) continue
 240                 // internal
 241                 BADPREFIX("csqc_");
 242                 BADPREFIX("cvar_check_");
 243                 BADCVAR("gamecfg");
 244                 BADCVAR("g_configversion");
 245                 BADCVAR("g_maplist_index");
 246                 BADCVAR("halflifebsp");
 247                 BADPREFIX("sv_world");
 248
 249                 // client
 250                 BADPREFIX("chase_");
 251                 BADPREFIX("cl_");
 252                 BADPREFIX("con_");
 253                 BADPREFIX("scoreboard_");
 254                 BADPREFIX("g_campaign");
 255                 BADPREFIX("gl_");
 256                 BADPREFIX("joy");
 257                 BADPREFIX("hud_");
 258                 BADPREFIX("m_");
 259                 BADPREFIX("menu_");
 260                 BADPREFIX("net_slist_");
 261                 BADPREFIX("r_");
 262                 BADPREFIX("sbar_");
 263                 BADPREFIX("scr_");
 264                 BADPREFIX("snd_");
 265                 BADPREFIX("show");
 266                 BADPREFIX("sensitivity");
 267                 BADPREFIX("userbind");
 268                 BADPREFIX("v_");
 269                 BADPREFIX("vid_");
 270                 BADPREFIX("crosshair");
 271                 BADCVAR("mod_q3bsp_lightmapmergepower");
 272                 BADCVAR("mod_q3bsp_nolightmaps");
 273                 BADCVAR("fov");
 274                 BADCVAR("mastervolume");
 275                 BADCVAR("volume");
 276                 BADCVAR("bgmvolume");
 277
 278                 // private
 279                 BADCVAR("developer");
 280                 BADCVAR("g_banned_list");
 281                 BADCVAR("log_dest_udp");
 282                 BADCVAR("log_file");
 283                 BADCVAR("net_address");
 284                 BADCVAR("net_address_ipv6");
 285                 BADCVAR("port");
 286                 BADCVAR("savedgamecfg");
 287                 BADCVAR("serverconfig");
 288                 BADCVAR("sv_heartbeatperiod");
 289                 BADCVAR("sv_vote_master_password");
 290                 BADCVAR("sys_colortranslation");
 291                 BADCVAR("sys_specialcharactertranslation");
 292                 BADCVAR("timestamps");
 293                 BADPREFIX("developer_");
 294                 BADPREFIX("g_ban_");
 295                 BADPREFIX("g_chat_flood_");
 296                 BADPREFIX("g_voice_flood_");
 297                 BADPREFIX("rcon_");
 298                 BADPREFIX("settemp_");
 299                 BADPREFIX("sv_allowdownloads_");
 300                 BADPREFIX("sv_autodemo");
 301                 BADPREFIX("sv_curl_");
 302                 BADPREFIX("sv_eventlog");
 303                 BADPREFIX("sv_logscores_");
 304                 BADPREFIX("sv_master");
 305                 BADPREFIX("sv_weaponstats_");
 306
 307                 // these can contain player IDs, so better hide
 308                 BADCVAR("g_forced_team_red");
 309                 BADCVAR("g_forced_team_blue");
 310                 BADCVAR("g_forced_team_yellow");
 311                 BADCVAR("g_forced_team_pink");
 312
 313                 // mapinfo
 314                 BADCVAR("timelimit");
 315                 BADCVAR("fraglimit");
 316                 BADCVAR("leadlimit");
 317                 BADCVAR("g_tdm_teams");
 318                 BADCVAR("g_keyhunt_teams");
 319                 BADCVAR("g_domination_default_teams");
 320                 BADCVAR("g_race_qualifying_timelimit");
 321                 BADCVAR("g_lms");
 322                 BADCVAR("g_arena");
 323                 BADCVAR("g_ca");
 324                 BADCVAR("g_assault");
 325                 BADCVAR("g_ctf");
 326                 BADCVAR("g_dm");
 327                 BADCVAR("g_domination");
 328                 BADCVAR("g_freezetag");
 329                 BADCVAR("g_keyhunt");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_onslaught");
 332                 BADCVAR("g_race");
 333                 BADCVAR("g_cts");
 334                 BADCVAR("g_runematch");
 335                 BADCVAR("g_tdm");
 336                 BADCVAR("g_nexball");
 337                 BADCVAR("g_keepaway");
 338                 BADCVAR("teamplay");
 339
 340                 // long
 341                 BADCVAR("hostname");
 342                 BADCVAR("g_maplist");
 343                 BADCVAR("g_maplist_mostrecent");
 344                 BADCVAR("sv_motd");
 345
 346                 v = cvar_string(k);
 347                 d = cvar_defstring(k);
 348                 if(v == d)
 349                         continue;
 350
 351                 if(adding)
 352                 {
 353                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 354                         if(strlen(cvar_changes) > 16384)
 355                         {
 356                                 cvar_changes = "// too many settings have been changed to show them here\n";
 357                                 adding = 0;
 358                         }
 359                 }
 360
 361                 // now check if the changes are actually gameplay relevant
 362
 363                 // does nothing visible
 364                 BADCVAR("captureleadlimit_override");
 365                 BADCVAR("g_arena_point_leadlimit");
 366                 BADCVAR("g_balance_kill_delay");
 367                 BADCVAR("g_ca_point_leadlimit");
 368                 BADCVAR("g_ctf_captimerecord_always");
 369                 BADCVAR("g_ctf_capture_leadlimit");
 370                 BADCVAR("g_ctf_flag_capture_effects");
 371                 BADCVAR("g_ctf_flag_glowtrails");
 372                 BADCVAR("g_ctf_flag_pickup_effects");
 373                 BADCVAR("g_domination_point_leadlimit");
 374                 BADCVAR("g_forced_respawn");
 375                 BADCVAR("g_keyhunt_point_leadlimit");
 376                 BADCVAR("g_nexball_goalleadlimit");
 377                 BADCVAR("g_runematch_point_leadlimit");
 378                 BADCVAR("leadlimit_and_fraglimit");
 379                 BADCVAR("leadlimit_override");
 380                 BADCVAR("pausable");
 381                 BADCVAR("sv_checkforpacketsduringsleep");
 382                 BADCVAR("sv_timeout");
 383                 BADCVAR("welcome_message_time");
 384                 BADPREFIX("crypto_");
 385                 BADPREFIX("g_chat_");
 386                 BADPREFIX("g_ctf_captimerecord_");
 387                 BADPREFIX("g_maplist_votable_");
 388                 BADPREFIX("net_");
 389                 BADPREFIX("prvm_");
 390                 BADPREFIX("skill_");
 391                 BADPREFIX("sv_fragmessage_");
 392                 BADPREFIX("sv_maxidle_");
 393                 BADPREFIX("sv_vote_");
 394                 BADPREFIX("timelimit_");
 395
 396                 // allowed changes to server admins (please sync this to server.cfg)
 397                 // vi commands:
 398                 //   :/"impure"/,$d
 399                 //   :g!,^\/\/[^ /],d
 400                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 401                 //   :%!sort
 402                 // yes, this does contain some redundant stuff, don't really care
 403                 BADCVAR("bot_number");
 404                 BADCVAR("bot_prefix");
 405                 BADCVAR("bot_suffix");
 406                 BADCVAR("capturelimit_override");
 407                 BADCVAR("fraglimit_override");
 408                 BADCVAR("gametype");
 409                 BADCVAR("g_antilag");
 410                 BADCVAR("g_balance_teams");
 411                 BADCVAR("g_balance_teams_force");
 412                 BADCVAR("g_ban_sync_trusted_servers");
 413                 BADCVAR("g_ban_sync_uri");
 414                 BADCVAR("g_ctf_capture_limit");
 415                 BADCVAR("g_ctf_ignore_frags");
 416                 BADCVAR("g_ctf_win_mode");
 417                 BADCVAR("g_domination_point_limit");
 418                 BADCVAR("g_fullbrightitems");
 419                 BADCVAR("g_fullbrightplayers");
 420                 BADCVAR("g_keyhunt_point_limit");
 421                 BADCVAR("g_keyhunt_teams_override");
 422                 BADCVAR("g_lms_lives_override");
 423                 BADCVAR("g_maplist");
 424                 BADCVAR("g_maplist_check_waypoints");
 425                 BADCVAR("g_maplist_mostrecent_count");
 426                 BADCVAR("g_maplist_shuffle");
 427                 BADCVAR("g_maplist_votable");
 428                 BADCVAR("g_maplist_votable_abstain");
 429                 BADCVAR("g_maplist_votable_nodetail");
 430                 BADCVAR("g_maplist_votable_suggestions");
 431                 BADCVAR("g_minstagib");
 432                 BADCVAR("g_nexball_goallimit");
 433                 BADCVAR("g_runematch_point_limit");
 434                 BADCVAR("g_start_delay");
 435                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 436                 BADCVAR("hostname");
 437                 BADCVAR("log_file");
 438                 BADCVAR("maxplayers");
 439                 BADCVAR("minplayers");
 440                 BADCVAR("net_address");
 441                 BADCVAR("port");
 442                 BADCVAR("rcon_password");
 443                 BADCVAR("rcon_restricted_commands");
 444                 BADCVAR("rcon_restricted_password");
 445                 BADCVAR("skill");
 446                 BADCVAR("sv_adminnick");
 447                 BADCVAR("sv_autoscreenshot");
 448                 BADCVAR("sv_curl_defaulturl");
 449                 BADCVAR("sv_defaultcharacter");
 450                 BADCVAR("sv_defaultplayercolors");
 451                 BADCVAR("sv_defaultplayermodel");
 452                 BADCVAR("sv_defaultplayerskin");
 453                 BADCVAR("sv_maxidle");
 454                 BADCVAR("sv_maxrate");
 455                 BADCVAR("sv_motd");
 456                 BADCVAR("sv_public");
 457                 BADCVAR("sv_ready_restart");
 458                 BADCVAR("sv_status_privacy");
 459                 BADCVAR("sv_vote_call");
 460                 BADCVAR("sv_vote_commands");
 461                 BADCVAR("sv_vote_majority_factor");
 462                 BADCVAR("sv_vote_master");
 463                 BADCVAR("sv_vote_master_commands");
 464                 BADCVAR("sv_vote_master_password");
 465                 BADCVAR("sv_vote_simple_majority_factor");
 466                 BADCVAR("timelimit_override");
 467                 BADCVAR("g_warmup");
 468                 BADPREFIX("g_warmup_");
 469
 470                 if(autocvar_g_minstagib)
 471                 {
 472                         BADCVAR("g_grappling_hook");
 473                         BADCVAR("g_jetpack");
 474                 }
 475 #undef BADPREFIX
 476 #undef BADCVAR
 477
 478                 if(pureadding)
 479                 {
 480                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 481                         if(strlen(cvar_purechanges) > 16384)
 482                         {
 483                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 484                                 pureadding = 0;
 485                         }
 486                 }
 487                 ++cvar_purechanges_count;
 488                 // WARNING: this variable is used for the server list
 489                 // NEVER dare to skip this code!
 490                 // Hacks to intentionally appearing as "pure server" even though you DO have
 491                 // modified settings may be punished by removal from the server list.
 492                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 493                 // though.
 494         }
 495         buf_del(h);
 496         if(cvar_changes == "")
 497                 cvar_changes = "// this server runs at default server settings\n";
 498         else
 499                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 500         cvar_changes = strzone(cvar_changes);
 501         if(cvar_purechanges == "")
 502                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 503         else
 504                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 505         cvar_purechanges = strzone(cvar_purechanges);
 506 }
 507
 508 void detect_maptype()
 509 {
 510 #if 0
 511         vector o, v;
 512         float i;
 513
 514         for(;;)
 515         {
 516                 o = world.mins;
 517                 o_x += random() * (world.maxs_x - world.mins_x);
 518                 o_y += random() * (world.maxs_y - world.mins_y);
 519                 o_z += random() * (world.maxs_z - world.mins_z);
 520
 521                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 522                 if(trace_fraction == 1)
 523                         continue;
 524
 525                 v = trace_endpos;
 526
 527                 for(i = 0; i < 64; i += 4)
 528                 {
 529                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 530         if(trace_fraction == 1)
 531                 continue;
 532                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 533                 }
 534
 535                 break;
 536         }
 537 #endif
 538 }
 539
 540 entity randomseed;
 541 float RandomSeed_Send(entity to, float sf)
 542 {
 543         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 544         WriteShort(MSG_ENTITY, self.cnt);
 545         return TRUE;
 546 }
 547 void RandomSeed_Think()
 548 {
 549         self.cnt = bound(0, floor(random() * 65536), 65535);
 550         self.nextthink = time + 5;
 551
 552         self.SendFlags |= 1;
 553 }
 554 void RandomSeed_Spawn()
 555 {
 556         randomseed = spawn();
 557         randomseed.think = RandomSeed_Think;
 558         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 559
 560         entity oldself;
 561         oldself = self;
 562         self = randomseed;
 563         self.think(); // sets random seed and nextthink
 564         self = oldself;
 565 }
 566
 567 void spawnfunc___init_dedicated_server(void)
 568 {
 569         // handler for _init/_init map (only for dedicated server initialization)
 570
 571         world_initialized = -1; // don't complain
 572         cvar = cvar_normal;
 573         cvar_string = cvar_string_normal;
 574         cvar_set = cvar_set_normal;
 575
 576         remove = remove_unsafely;
 577
 578         entity e;
 579         e = spawn();
 580         e.think = GotoFirstMap;
 581         e.nextthink = time; // this is usually 1 at this point
 582
 583         e = spawn();
 584         e.classname = "info_player_deathmatch"; // safeguard against player joining
 585
 586         self.classname = "worldspawn"; // safeguard against various stuff ;)
 587
 588         MapInfo_Enumerate();
 589         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 590 }
 591
 592 void Map_MarkAsRecent(string m);
 593 float world_already_spawned;
 594 void RegisterWeapons();
 595 void Nagger_Init();
 596 void ClientInit_Spawn();
 597 void WeaponStats_Init();
 598 void WeaponStats_Shutdown();
 599 void spawnfunc_worldspawn (void)
 600 {
 601         float fd, l, i, j, n;
 602         string s, col;
 603
 604         cvar = cvar_normal;
 605         cvar_string = cvar_string_normal;
 606         cvar_set = cvar_set_normal;
 607
 608         if(world_already_spawned)
 609                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 610         world_already_spawned = TRUE;
 611
 612         remove = remove_safely; // during spawning, watch what you remove!
 613
 614         check_unacceptable_compiler_bugs();
 615
 616         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 617
 618         compressShortVector_init();
 619
 620         allowed_to_spawn = TRUE;
 621
 622         local entity head;
 623         head = nextent(world);
 624         maxclients = 0;
 625         while(head)
 626         {
 627                 ++maxclients;
 628                 head = nextent(head);
 629         }
 630
 631         // needs to be done so early as they would still spawn
 632         RegisterWeapons();
 633
 634         ServerProgsDB = db_load("server.db");
 635
 636         TemporaryDB = db_create();
 637
 638         // 0 normal
 639         lightstyle(0, "m");
 640
 641         // 1 FLICKER (first variety)
 642         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 643
 644         // 2 SLOW STRONG PULSE
 645         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 646
 647         // 3 CANDLE (first variety)
 648         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 649
 650         // 4 FAST STROBE
 651         lightstyle(4, "mamamamamama");
 652
 653         // 5 GENTLE PULSE 1
 654         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 655
 656         // 6 FLICKER (second variety)
 657         lightstyle(6, "nmonqnmomnmomomno");
 658
 659         // 7 CANDLE (second variety)
 660         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 661
 662         // 8 CANDLE (third variety)
 663         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 664
 665         // 9 SLOW STROBE (fourth variety)
 666         lightstyle(9, "aaaaaaaazzzzzzzz");
 667
 668         // 10 FLUORESCENT FLICKER
 669         lightstyle(10, "mmamammmmammamamaaamammma");
 670
 671         // 11 SLOW PULSE NOT FADE TO BLACK
 672         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 673
 674         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 675
 676         // 63 testing
 677         lightstyle(63, "a");
 678
 679         if(autocvar_g_campaign)
 680                 CampaignPreInit();
 681
 682         Map_MarkAsRecent(mapname);
 683
 684         precache_model ("null"); // we need this one before InitGameplayMode
 685         InitGameplayMode();
 686         readlevelcvars();
 687         GrappleHookInit();
 688         ElectroInit();
 689         LaserInit();
 690
 691         player_count = 0;
 692         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 693         if(bot_waypoints_for_items == 1)
 694                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 695                         bot_waypoints_for_items = 0;
 696
 697         // for setting by mapinfo
 698         q3acompat_machineshotgunswap = autocvar_sv_q3acompat_machineshotgunswap;
 699         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 700
 701         precache();
 702
 703         WaypointSprite_Init();
 704
 705         //if (g_domination)
 706         //      dom_init();
 707
 708         GameLogInit(); // prepare everything
 709         if(autocvar_sv_eventlog)
 710         {
 711                 s = strcat(ftos(autocvar_sv_eventlog_files_counter), ".");
 712                 s = strcat(s, ftos(random()));
 713                 matchid = strzone(s);
 714
 715                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 716                 s = ":gameinfo:mutators:LIST";
 717
 718                 ret_string = s;
 719                 MUTATOR_CALLHOOK(BuildMutatorsString);
 720                 s = ret_string;
 721
 722                 // simple, probably not good in the mutator system
 723                 if(autocvar_g_grappling_hook)
 724                         s = strcat(s, ":grappling_hook");
 725
 726                 // initialiation stuff, not good in the mutator system
 727                 if(!autocvar_g_use_ammunition)
 728                         s = strcat(s, ":no_use_ammunition");
 729
 730                 // initialiation stuff, not good in the mutator system
 731                 if(!autocvar_g_pickup_items)
 732                         s = strcat(s, ":no_pickup_items");
 733
 734                 // initialiation stuff, not good in the mutator system
 735                 if(autocvar_g_weaponarena != "0")
 736                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 737
 738                 // TODO to mutator system
 739                 if(autocvar_g_norecoil)
 740                         s = strcat(s, ":norecoil");
 741
 742                 // TODO to mutator system
 743                 if(autocvar_g_midair)
 744                         s = strcat(s, ":midair");
 745
 746                 // TODO to mutator system
 747                 if(autocvar_g_minstagib)
 748                         s = strcat(s, ":minstagib");
 749
 750                 GameLogEcho(s);
 751                 GameLogEcho(":gameinfo:end");
 752         }
 753         else
 754                 matchid = strzone(ftos(random()));
 755
 756         cvar_set("nextmap", "");
 757
 758         SetDefaultAlpha();
 759
 760         if(autocvar_g_campaign)
 761                 CampaignPostInit();
 762
 763         fteqcc_testbugs();
 764
 765         Ban_LoadBans();
 766
 767         MapInfo_Enumerate();
 768         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 769
 770         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 771         {
 772                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 773                 if(fd != -1)
 774                 {
 775                         while((s = fgets(fd)))
 776                         {
 777                                 l = tokenize_console(s);
 778                                 if(l < 2)
 779                                         continue;
 780                                 if(argv(0) == "cd")
 781                                 {
 782                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 783                                         print("  cdtrack ", argv(2), "\n");
 784                                 }
 785                                 else if(argv(0) == "fog")
 786                                 {
 787                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 788                                         print("  \"fog\" \"", s, "\"\n");
 789                                 }
 790                                 else if(argv(0) == "set")
 791                                 {
 792                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 793                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 794                                 }
 795                                 else if(argv(0) != "//")
 796                                 {
 797                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 798                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 799                                 }
 800                         }
 801                         fclose(fd);
 802                 }
 803         }
 804
 805         WeaponStats_Init();
 806
 807         addstat(STAT_WEAPONS, AS_INT, weapons);
 808         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 809         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 810         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 811         Nagger_Init();
 812
 813         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 814         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 815         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 816         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 817         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 818         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 819         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 820         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 821
 822         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 823         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 824
 825         if(g_ca || g_freezetag)
 826         {
 827                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 828                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 829                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 830                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 831         }
 832         if(g_freezetag)
 833         {
 834                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 835                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 836         }
 837
 838         // g_movementspeed hack
 839         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 840         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 841         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 842         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 843
 844         next_pingtime = time + 5;
 845
 846         detect_maptype();
 847
 848         lsmaps_reply = "^7Maps available: ";
 849         lsnewmaps_reply = "^7Maps without a record set: ";
 850         for(i = 0, j = 0; i < MapInfo_count; ++i)
 851         {
 852                 if(MapInfo_Get_ByID(i))
 853                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 854                         {
 855                                 if(mod(i, 2))
 856                                         col = "^2";
 857                                 else
 858                                         col = "^3";
 859                                 ++j;
 860                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 861                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 862                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 863                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 864                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 865                         }
 866         }
 867         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 868         if (!g_race && !g_cts)
 869                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 870         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 871
 872         maplist_reply = "^7Maps in list: ";
 873         n = tokenize_console(autocvar_g_maplist);
 874         for(i = 0, j = 0; i < n; ++i)
 875         {
 876                 if(MapInfo_CheckMap(argv(i)))
 877                 {
 878                         if(mod(j, 2))
 879                                 col = "^2";
 880                         else
 881                                 col = "^3";
 882                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 883                         ++j;
 884                 }
 885         }
 886         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 887         MapInfo_ClearTemps();
 888
 889         for(i = 0; i < 10; ++i)
 890         {
 891                 records_reply[i] = strzone(getrecords(i));
 892         }
 893         if(g_cts)
 894                 ladder_reply = strzone(getladder());
 895
 896         rankings_reply = strzone(getrankings());
 897
 898         ClientInit_Spawn();
 899         RandomSeed_Spawn();
 900         PingPLReport_Spawn();
 901
 902         CheatInit();
 903
 904         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 905
 906         // fill sv_curl_serverpackages from .serverpackage files
 907         if(autocvar_sv_curl_serverpackages_auto)
 908         {
 909                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 910                 s = "";
 911                 if(fd >= 0)
 912                 {
 913                         j = search_getsize(fd);
 914                         for(i = 0; i < j; ++i)
 915                                 s = strcat(s, " ", search_getfilename(fd, i));
 916                         search_end(fd);
 917                 }
 918                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 919         }
 920
 921         PlayerStats_Init();
 922
 923         world_initialized = 1;
 924 }
 925
 926 void spawnfunc_light (void)
 927 {
 928         //makestatic (self); // Who the f___ did that?
 929         remove(self);
 930 }
 931
 932 float TryFile( string pFilename )
 933 {
 934         local float lHandle;
 935         dprint("TryFile(\"", pFilename, "\")\n");
 936         lHandle = fopen( pFilename, FILE_READ );
 937         if( lHandle != -1 ) {
 938                 fclose( lHandle );
 939                 return TRUE;
 940         } else {
 941                 return FALSE;
 942         }
 943 };
 944
 945 string GetGametype()
 946 {
 947         return GametypeNameFromType(game);
 948 }
 949
 950 string getmapname_stored;
 951 string GetMapname()
 952 {
 953         return mapname;
 954 }
 955
 956 float Map_Count, Map_Current;
 957 string Map_Current_Name;
 958
 959 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 960 float GetMaplistPosition()
 961 {
 962         float pos, idx;
 963         string map;
 964
 965         map = GetMapname();
 966         idx = autocvar_g_maplist_index;
 967
 968         if(idx >= 0)
 969                 if(idx < Map_Count)
 970                         if(map == argv(idx))
 971                                 return idx;
 972
 973         for(pos = 0; pos < Map_Count; ++pos)
 974                 if(map == argv(pos))
 975                         return pos;
 976
 977         // resume normal maplist rotation if current map is not in g_maplist
 978         return idx;
 979 }
 980
 981 float MapHasRightSize(string map)
 982 {
 983         float fh;
 984         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 985         if(autocvar_g_maplist_check_waypoints)
 986         {
 987                 dprint("checkwp "); dprint(map);
 988                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 989                 if(fh < 0)
 990                 {
 991                         dprint(": no waypoints\n");
 992                         return FALSE;
 993                 }
 994                 dprint(": has waypoints\n");
 995                 fclose(fh);
 996         }
 997
 998         // open map size restriction file
 999         dprint("opensize "); dprint(map);
1000         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1001         if(fh >= 0)
1002         {
1003                 float mapmin, mapmax;
1004                 dprint(": ok, ");
1005                 mapmin = stof(fgets(fh));
1006                 mapmax = stof(fgets(fh));
1007                 fclose(fh);
1008                 if(player_count < mapmin)
1009                 {
1010                         dprint("not enough\n");
1011                         return FALSE;
1012                 }
1013                 if(player_count > mapmax)
1014                 {
1015                         dprint("too many\n");
1016                         return FALSE;
1017                 }
1018                 dprint("right size\n");
1019                 return TRUE;
1020         }
1021         dprint(": not found\n");
1022         return TRUE;
1023 }
1024
1025 string Map_Filename(float position)
1026 {
1027         return strcat("maps/", argv(position), ".bsp");
1028 }
1029
1030 string strwords(string s, float w)
1031 {
1032         float endpos;
1033         for(endpos = 0; w && endpos >= 0; --w)
1034                 endpos = strstrofs(s, " ", endpos + 1);
1035         if(endpos < 0)
1036                 return s;
1037         else
1038                 return substring(s, 0, endpos);
1039 }
1040
1041 float strhasword(string s, string w)
1042 {
1043         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1044 }
1045
1046 void Map_MarkAsRecent(string m)
1047 {
1048         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1049 }
1050
1051 float Map_IsRecent(string m)
1052 {
1053         return strhasword(autocvar_g_maplist_mostrecent, m);
1054 }
1055
1056 float Map_Check(float position, float pass)
1057 {
1058         string filename;
1059         string map_next;
1060         map_next = argv(position);
1061         if(pass <= 1)
1062         {
1063                 if(Map_IsRecent(map_next))
1064                         return 0;
1065         }
1066         filename = Map_Filename(position);
1067         if(MapInfo_CheckMap(map_next))
1068         {
1069                 if(pass == 2)
1070                         return 1;
1071                 if(MapHasRightSize(map_next))
1072                         return 1;
1073                 return 0;
1074         }
1075         else
1076                 dprint( "Couldn't select '", filename, "'..\n" );
1077
1078         return 0;
1079 }
1080
1081 void Map_Goto_SetStr(string nextmapname)
1082 {
1083         if(getmapname_stored != "")
1084                 strunzone(getmapname_stored);
1085         if(nextmapname == "")
1086                 getmapname_stored = "";
1087         else
1088                 getmapname_stored = strzone(nextmapname);
1089 }
1090
1091 void Map_Goto_SetFloat(float position)
1092 {
1093         cvar_set("g_maplist_index", ftos(position));
1094         Map_Goto_SetStr(argv(position));
1095 }
1096
1097 void GameResetCfg()
1098 {
1099         // settings persist, except...
1100         localcmd("\nsettemp_restore\n");
1101 };
1102
1103 void Map_Goto()
1104 {
1105         GameResetCfg();
1106         MapInfo_LoadMap(getmapname_stored);
1107 }
1108
1109 // return codes of map selectors:
1110 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1111 //   -2 = permanent failure
1112 float() MaplistMethod_Iterate = // usual method
1113 {
1114         float pass, i;
1115
1116         for(pass = 1; pass <= 2; ++pass)
1117         {
1118                 for(i = 1; i < Map_Count; ++i)
1119                 {
1120                         float mapindex;
1121                         mapindex = mod(i + Map_Current, Map_Count);
1122                         if(Map_Check(mapindex, pass))
1123                                 return mapindex;
1124                 }
1125         }
1126         return -1;
1127 }
1128
1129 float() MaplistMethod_Repeat = // fallback method
1130 {
1131         if(Map_Check(Map_Current, 2))
1132                 return Map_Current;
1133         return -2;
1134 }
1135
1136 float() MaplistMethod_Random = // random map selection
1137 {
1138         float i, imax;
1139
1140         imax = 42;
1141
1142         for(i = 0; i <= imax; ++i)
1143         {
1144                 float mapindex;
1145                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1146                 if(Map_Check(mapindex, 1))
1147                         return mapindex;
1148         }
1149         return -1;
1150 }
1151
1152 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1153 // the exponent sets a bias on the map selection:
1154 // the higher the exponent, the less likely "shortly repeated" same maps are
1155 {
1156         float i, j, imax, insertpos;
1157
1158         imax = 42;
1159
1160         for(i = 0; i <= imax; ++i)
1161         {
1162                 string newlist;
1163
1164                 // now reinsert this at another position
1165                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1166                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1167                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1168                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1169
1170                 // insert the current map there
1171                 newlist = "";
1172                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1173                         newlist = strcat(newlist, " ", argv(j));
1174                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1175                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1176                         newlist = strcat(newlist, " ", argv(j));
1177                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1178                 cvar_set("g_maplist", newlist);
1179                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1180
1181                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1182                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1183                 if(Map_Check(Map_Current, 1))
1184                         return Map_Current;
1185         }
1186         return -1;
1187 }
1188
1189 void Maplist_Init()
1190 {
1191         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1192         if(Map_Count == 0)
1193         {
1194                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1195                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1196                 if(autocvar_g_maplist_shuffle)
1197                         ShuffleMaplist();
1198                 localcmd("\nmenu_cmd sync\n");
1199                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1200         }
1201         if(Map_Count == 0)
1202                 error("empty maplist, cannot select a new map");
1203         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1204
1205         if(Map_Current_Name)
1206                 strunzone(Map_Current_Name);
1207         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1208         // this may or may not be correct, but who cares, in the worst case a map
1209         // isn't chosen in the first pass that should have been
1210 }
1211
1212 string GetNextMap()
1213 {
1214         float nextMap;
1215
1216         Maplist_Init();
1217         nextMap = -1;
1218
1219         if(nextMap == -1)
1220                 if(autocvar_g_maplist_shuffle > 0)
1221                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1222
1223         if(nextMap == -1)
1224                 if(autocvar_g_maplist_selectrandom)
1225                         nextMap = MaplistMethod_Random();
1226
1227         if(nextMap == -1)
1228                 nextMap = MaplistMethod_Iterate();
1229
1230         if(nextMap == -1)
1231                 nextMap = MaplistMethod_Repeat();
1232
1233         if(nextMap >= 0)
1234         {
1235                 Map_Goto_SetFloat(nextMap);
1236                 return getmapname_stored;
1237         }
1238
1239         return "";
1240 };
1241
1242 float DoNextMapOverride()
1243 {
1244         if(autocvar_g_campaign)
1245         {
1246                 CampaignPostIntermission();
1247                 alreadychangedlevel = TRUE;
1248                 return TRUE;
1249         }
1250         if(autocvar_quit_when_empty)
1251         {
1252                 if(player_count <= currentbots)
1253                 {
1254                         localcmd("quit\n");
1255                         alreadychangedlevel = TRUE;
1256                         return TRUE;
1257                 }
1258         }
1259         if(autocvar_quit_and_redirect != "")
1260         {
1261                 redirection_target = strzone(autocvar_quit_and_redirect);
1262                 alreadychangedlevel = TRUE;
1263                 return TRUE;
1264         }
1265         if (autocvar_samelevel) // if samelevel is set, stay on same level
1266         {
1267                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1268                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1269                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1270                 localcmd("restart\n");
1271                 //changelevel (mapname);
1272                 alreadychangedlevel = TRUE;
1273                 return TRUE;
1274         }
1275         if(autocvar_nextmap != "")
1276                 if(MapInfo_CheckMap(autocvar_nextmap))
1277                 {
1278                         Map_Goto_SetStr(autocvar_nextmap);
1279                         Map_Goto();
1280                         alreadychangedlevel = TRUE;
1281                         return TRUE;
1282                 }
1283         if(autocvar_lastlevel)
1284         {
1285                 GameResetCfg();
1286                 localcmd("set lastlevel 0\ntogglemenu\n");
1287                 alreadychangedlevel = TRUE;
1288                 return TRUE;
1289         }
1290         return FALSE;
1291 };
1292
1293 void GotoNextMap()
1294 {
1295         //local string nextmap;
1296         //local float n, nummaps;
1297         //local string s;
1298         if (alreadychangedlevel)
1299                 return;
1300         alreadychangedlevel = TRUE;
1301
1302         {
1303                 string nextMap;
1304                 float allowReset;
1305
1306                 for(allowReset = 1; allowReset >= 0; --allowReset)
1307                 {
1308                         nextMap = GetNextMap();
1309                         if(nextMap != "")
1310                                 break;
1311
1312                         if(allowReset)
1313                         {
1314                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1315                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1316                                 if(autocvar_g_maplist_shuffle)
1317                                         ShuffleMaplist();
1318                                 localcmd("\nmenu_cmd sync\n");
1319                         }
1320                         else
1321                         {
1322                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1323                         }
1324                 }
1325                 Map_Goto();
1326         }
1327 };
1328
1329
1330 /*
1331 ============
1332 IntermissionThink
1333
1334 When the player presses attack or jump, change to the next level
1335 ============
1336 */
1337 .float autoscreenshot;
1338 void() MapVote_Start;
1339 void() MapVote_Think;
1340 float mapvote_initialized;
1341 void IntermissionThink()
1342 {
1343         FixIntermissionClient(self);
1344
1345         if(autocvar_sv_autoscreenshot)
1346         if(self.autoscreenshot > 0)
1347         if(time > self.autoscreenshot)
1348         {
1349                 self.autoscreenshot = -1;
1350                 if(clienttype(self) == CLIENTTYPE_REAL)
1351                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1352                 return;
1353         }
1354
1355         if (time < intermission_exittime)
1356                 return;
1357
1358         if(!mapvote_initialized)
1359                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1360                         return;
1361
1362         MapVote_Start();
1363 };
1364
1365 /*
1366 ============
1367 FindIntermission
1368
1369 Returns the entity to view from
1370 ============
1371 */
1372 /*
1373 entity FindIntermission()
1374 {
1375         local   entity spot;
1376         local   float cyc;
1377
1378 // look for info_intermission first
1379         spot = find (world, classname, "info_intermission");
1380         if (spot)
1381         {       // pick a random one
1382                 cyc = random() * 4;
1383                 while (cyc > 1)
1384                 {
1385                         spot = find (spot, classname, "info_intermission");
1386                         if (!spot)
1387                                 spot = find (spot, classname, "info_intermission");
1388                         cyc = cyc - 1;
1389                 }
1390                 return spot;
1391         }
1392
1393 // then look for the start position
1394         spot = find (world, classname, "info_player_start");
1395         if (spot)
1396                 return spot;
1397
1398 // testinfo_player_start is only found in regioned levels
1399         spot = find (world, classname, "testplayerstart");
1400         if (spot)
1401                 return spot;
1402
1403 // then look for the start position
1404         spot = find (world, classname, "info_player_deathmatch");
1405         if (spot)
1406                 return spot;
1407
1408         //objerror ("FindIntermission: no spot");
1409         return world;
1410 };
1411 */
1412
1413 /*
1414 ===============================================================================
1415
1416 RULES
1417
1418 ===============================================================================
1419 */
1420
1421 void DumpStats(float final)
1422 {
1423         float file;
1424         string s;
1425         float to_console;
1426         float to_eventlog;
1427         float to_file;
1428         float i;
1429         entity e;
1430
1431         to_console = autocvar_sv_logscores_console;
1432         to_eventlog = autocvar_sv_eventlog;
1433         to_file = autocvar_sv_logscores_file;
1434
1435         if(!final)
1436         {
1437                 to_console = TRUE; // always print printstats replies
1438                 to_eventlog = FALSE; // but never print them to the event log
1439         }
1440
1441         if(to_eventlog)
1442                 if(autocvar_sv_eventlog_console)
1443                         to_console = FALSE; // otherwise we get the output twice
1444
1445         if(final)
1446                 s = ":scores:";
1447         else
1448                 s = ":status:";
1449         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1450
1451         if(to_console)
1452                 print(s, "\n");
1453         if(to_eventlog)
1454                 GameLogEcho(s);
1455         if(to_file)
1456         {
1457                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1458                 if(file == -1)
1459                         to_file = FALSE;
1460                 else
1461                         fputs(file, strcat(s, "\n"));
1462         }
1463
1464         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1465         if(to_console)
1466                 print(s, "\n");
1467         if(to_eventlog)
1468                 GameLogEcho(s);
1469         if(to_file)
1470                 fputs(file, strcat(s, "\n"));
1471
1472         FOR_EACH_CLIENT(other)
1473         {
1474                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1475                 {
1476                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1477                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1478                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1479                                 s = strcat(s, ftos(other.team), ":");
1480                         else
1481                                 s = strcat(s, "spectator:");
1482
1483                         if(to_console)
1484                                 print(s, other.netname, "\n");
1485                         if(to_eventlog)
1486                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1487                         if(to_file)
1488                                 fputs(file, strcat(s, other.netname, "\n"));
1489                 }
1490         }
1491
1492         if(teams_matter)
1493         {
1494                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1495                 if(to_console)
1496                         print(s, "\n");
1497                 if(to_eventlog)
1498                         GameLogEcho(s);
1499                 if(to_file)
1500                         fputs(file, strcat(s, "\n"));
1501
1502                 for(i = 1; i < 16; ++i)
1503                 {
1504                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1505                         s = strcat(s, ":", ftos(i));
1506                         if(to_console)
1507                                 print(s, "\n");
1508                         if(to_eventlog)
1509                                 GameLogEcho(s);
1510                         if(to_file)
1511                                 fputs(file, strcat(s, "\n"));
1512                 }
1513         }
1514
1515         if(to_console)
1516                 print(":end\n");
1517         if(to_eventlog)
1518                 GameLogEcho(":end");
1519         if(to_file)
1520         {
1521                 fputs(file, ":end\n");
1522                 fclose(file);
1523         }
1524
1525         // send statistics
1526         FOR_EACH_CLIENT(e)
1527                 PlayerStats_AddGlobalInfo(e);
1528         PlayerStats_Shutdown();
1529 }
1530
1531 void FixIntermissionClient(entity e)
1532 {
1533         string s;
1534         if(!e.autoscreenshot) // initial call
1535         {
1536                 e.angles = e.v_angle;
1537                 e.angles_x = -e.angles_x;
1538                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1539                 e.health = -2342;
1540                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1541                 e.solid = SOLID_NOT;
1542                 e.movetype = MOVETYPE_NONE;
1543                 e.takedamage = DAMAGE_NO;
1544                 if(e.weaponentity)
1545                 {
1546                         e.weaponentity.effects = EF_NODRAW;
1547                         if (e.weaponentity.weaponentity)
1548                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1549                 }
1550                 if(clienttype(e) == CLIENTTYPE_REAL)
1551                 {
1552                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1553                         s = autocvar_sv_intermission_cdtrack;
1554                         if(s != "")
1555                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1556                         msg_entity = e;
1557                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1558                 }
1559         }
1560
1561         //e.velocity = '0 0 0';
1562         //e.fixangle = TRUE;
1563
1564         // TODO halt weapon animation
1565 }
1566
1567
1568 /*
1569 go to the next level for deathmatch
1570 only called if a time or frag limit has expired
1571 */
1572 void NextLevel()
1573 {
1574         gameover = TRUE;
1575
1576         intermission_running = 1;
1577
1578 // enforce a wait time before allowing changelevel
1579         if(player_count > 0)
1580                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1581         else
1582                 intermission_exittime = -1;
1583
1584         /*
1585         WriteByte (MSG_ALL, SVC_CDTRACK);
1586         WriteByte (MSG_ALL, 3);
1587         WriteByte (MSG_ALL, 3);
1588         // done in FixIntermission
1589         */
1590
1591         //pos = FindIntermission ();
1592
1593         VoteReset();
1594
1595         DumpStats(TRUE);
1596
1597         if(autocvar_sv_eventlog)
1598                 GameLogEcho(":gameover");
1599
1600         GameLogClose();
1601
1602         FOR_EACH_PLAYER(other) {
1603                 FixIntermissionClient(other);
1604                 if(other.winning)
1605                         bprint(other.netname, " ^7wins.\n");
1606         }
1607
1608         if(autocvar_g_campaign)
1609                 CampaignPreIntermission();
1610
1611         localcmd("\nsv_hook_gameend\n");
1612 }
1613
1614 /*
1615 ============
1616 CheckRules_Player
1617
1618 Exit deathmatch games upon conditions
1619 ============
1620 */
1621 void CheckRules_Player()
1622 {
1623         if (gameover)   // someone else quit the game already
1624                 return;
1625
1626         if(self.deadflag == DEAD_NO)
1627                 self.play_time += frametime;
1628
1629         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1630         //   (div0: and that in CheckRules_World please)
1631 };
1632
1633 float checkrules_equality;
1634 float checkrules_suddendeathwarning;
1635 float checkrules_suddendeathend;
1636 float checkrules_overtimesadded; //how many overtimes have been already added
1637
1638 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1639 float WINNING_YES = 1; // winner found
1640 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1641 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1642
1643 float InitiateSuddenDeath()
1644 {
1645         // Check first whether normal overtimes could be added before initiating suddendeath mode
1646         // - for this timelimit_overtime needs to be >0 of course
1647         // - also check the winning condition calculated in the previous frame and only add normal overtime
1648         //   again, if at the point at which timelimit would be extended again, still no winner was found
1649         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1650         {
1651                 return 1; // need to call InitiateOvertime later
1652         }
1653         else
1654         {
1655                 if(!checkrules_suddendeathend)
1656                 {
1657                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1658                         if(g_race && !g_race_qualifying)
1659                                 race_StartCompleting();
1660                 }
1661                 return 0;
1662         }
1663 }
1664
1665 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1666 {
1667         ++checkrules_overtimesadded;
1668         //add one more overtime by simply extending the timelimit
1669         float tl;
1670         tl = autocvar_timelimit;
1671         tl += autocvar_timelimit_overtime;
1672         cvar_set("timelimit", ftos(tl));
1673         string minutesPlural;
1674         if (autocvar_timelimit_overtime == 1)
1675                 minutesPlural = " ^3minute";
1676         else
1677                 minutesPlural = " ^3minutes";
1678
1679         bcenterprint(
1680                 strcat(
1681                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1682                         ftos(autocvar_timelimit_overtime),
1683                         minutesPlural,
1684                         " to the game!"
1685                 )
1686         );
1687 }
1688
1689 float GetWinningCode(float fraglimitreached, float equality)
1690 {
1691         if(autocvar_g_campaign == 1)
1692                 if(fraglimitreached)
1693                         return WINNING_YES;
1694                 else
1695                         return WINNING_NO;
1696
1697         else
1698                 if(equality)
1699                         if(fraglimitreached)
1700                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1701                         else
1702                                 return WINNING_NEVER;
1703                 else
1704                         if(fraglimitreached)
1705                                 return WINNING_YES;
1706                         else
1707                                 return WINNING_NO;
1708 }
1709
1710 // set the .winning flag for exactly those players with a given field value
1711 void SetWinners(.float field, float value)
1712 {
1713         entity head;
1714         FOR_EACH_PLAYER(head)
1715                 head.winning = (head.field == value);
1716 }
1717
1718 // set the .winning flag for those players with a given field value
1719 void AddWinners(.float field, float value)
1720 {
1721         entity head;
1722         FOR_EACH_PLAYER(head)
1723                 if(head.field == value)
1724                         head.winning = 1;
1725 }
1726
1727 // clear the .winning flags
1728 void ClearWinners(void)
1729 {
1730         entity head;
1731         FOR_EACH_PLAYER(head)
1732                 head.winning = 0;
1733 }
1734
1735 // Onslaught winning condition:
1736 // game terminates if only one team has a working generator (or none)
1737 float WinningCondition_Onslaught()
1738 {
1739         entity head;
1740         local float t1, t2, t3, t4;
1741
1742         WinningConditionHelper(); // set worldstatus
1743
1744         if(inWarmupStage)
1745                 return WINNING_NO;
1746
1747         // first check if the game has ended
1748         t1 = t2 = t3 = t4 = 0;
1749         head = find(world, classname, "onslaught_generator");
1750         while (head)
1751         {
1752                 if (head.health > 0)
1753                 {
1754                         if (head.team == COLOR_TEAM1) t1 = 1;
1755                         if (head.team == COLOR_TEAM2) t2 = 1;
1756                         if (head.team == COLOR_TEAM3) t3 = 1;
1757                         if (head.team == COLOR_TEAM4) t4 = 1;
1758                 }
1759                 head = find(head, classname, "onslaught_generator");
1760         }
1761         if (t1 + t2 + t3 + t4 < 2)
1762         {
1763                 // game over, only one team remains (or none)
1764                 ClearWinners();
1765                 if (t1) SetWinners(team, COLOR_TEAM1);
1766                 if (t2) SetWinners(team, COLOR_TEAM2);
1767                 if (t3) SetWinners(team, COLOR_TEAM3);
1768                 if (t4) SetWinners(team, COLOR_TEAM4);
1769                 dprint("Have a winner, ending game.\n");
1770                 return WINNING_YES;
1771         }
1772
1773         // Two or more teams remain
1774         return WINNING_NO;
1775 }
1776
1777 float LMS_NewPlayerLives()
1778 {
1779         float fl;
1780         fl = autocvar_fraglimit;
1781         if(fl == 0)
1782                 fl = 999;
1783
1784         // first player has left the game for dying too much? Nobody else can get in.
1785         if(lms_lowest_lives < 1)
1786                 return 0;
1787
1788         if(!autocvar_g_lms_join_anytime)
1789                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1790                         return 0;
1791
1792         return bound(1, lms_lowest_lives, fl);
1793 }
1794
1795 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1796 // they win. Otherwise the defending team wins once the timelimit passes.
1797 void assault_new_round();
1798 float WinningCondition_Assault()
1799 {
1800         local float status;
1801
1802         WinningConditionHelper(); // set worldstatus
1803
1804         status = WINNING_NO;
1805         // as the timelimit has not yet passed just assume the defending team will win
1806         if(assault_attacker_team == COLOR_TEAM1)
1807         {
1808                 SetWinners(team, COLOR_TEAM2);
1809         }
1810         else
1811         {
1812                 SetWinners(team, COLOR_TEAM1);
1813         }
1814
1815         local entity ent;
1816         ent = find(world, classname, "target_assault_roundend");
1817         if(ent)
1818         {
1819                 if(ent.winning) // round end has been triggered by attacking team
1820                 {
1821                         bprint("ASSAULT: round completed...\n");
1822                         SetWinners(team, assault_attacker_team);
1823
1824                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1825
1826                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1827                         {
1828                                 status = WINNING_YES;
1829                         }
1830                         else
1831                         {
1832                                 local entity oldself;
1833                                 oldself = self;
1834                                 self = ent;
1835                                 assault_new_round();
1836                                 self = oldself;
1837                         }
1838                 }
1839         }
1840
1841         return status;
1842 }
1843
1844 // LMS winning condition: game terminates if and only if there's at most one
1845 // one player who's living lives. Top two scores being equal cancels the time
1846 // limit.
1847 float WinningCondition_LMS()
1848 {
1849         entity head, head2;
1850         float have_player;
1851         float have_players;
1852         float l;
1853
1854         have_player = FALSE;
1855         have_players = FALSE;
1856         l = LMS_NewPlayerLives();
1857
1858         head = find(world, classname, "player");
1859         if(head)
1860                 have_player = TRUE;
1861         head2 = find(head, classname, "player");
1862         if(head2)
1863                 have_players = TRUE;
1864
1865         if(have_player)
1866         {
1867                 // we have at least one player
1868                 if(have_players)
1869                 {
1870                         // two or more active players - continue with the game
1871                 }
1872                 else
1873                 {
1874                         // exactly one player?
1875
1876                         ClearWinners();
1877                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1878
1879                         if(l)
1880                         {
1881                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1882                                 return WINNING_NO;
1883                         }
1884                         else
1885                         {
1886                                 // a winner!
1887                                 // and assign him his first place
1888                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1889                                 return WINNING_YES;
1890                         }
1891                 }
1892         }
1893         else
1894         {
1895                 // nobody is playing at all...
1896                 if(l)
1897                 {
1898                         // wait for players...
1899                 }
1900                 else
1901                 {
1902                         // SNAFU (maybe a draw game?)
1903                         ClearWinners();
1904                         dprint("No players, ending game.\n");
1905                         return WINNING_YES;
1906                 }
1907         }
1908
1909         // When we get here, we have at least two players who are actually LIVING,
1910         // now check if the top two players have equal score.
1911         WinningConditionHelper();
1912
1913         ClearWinners();
1914         if(WinningConditionHelper_winner)
1915                 WinningConditionHelper_winner.winning = TRUE;
1916         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1917                 return WINNING_NEVER;
1918
1919         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1920         return WINNING_NO;
1921 }
1922
1923 void ShuffleMaplist()
1924 {
1925         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1926 }
1927
1928 float leaderfrags;
1929 float WinningCondition_Scores(float limit, float leadlimit)
1930 {
1931         float limitreached;
1932
1933         // TODO make everything use THIS winning condition (except LMS)
1934         WinningConditionHelper();
1935
1936         if(teams_matter)
1937         {
1938                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1939                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1940                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1941                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1942         }
1943
1944         ClearWinners();
1945         if(WinningConditionHelper_winner)
1946                 WinningConditionHelper_winner.winning = 1;
1947         if(WinningConditionHelper_winnerteam >= 0)
1948                 SetWinners(team, WinningConditionHelper_winnerteam);
1949
1950         if(WinningConditionHelper_lowerisbetter)
1951         {
1952                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1953                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1954                 limit = -limit;
1955         }
1956
1957         if(WinningConditionHelper_zeroisworst)
1958                 leadlimit = 0; // not supported in this mode
1959
1960         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1961         // these modes always score in increments of 1, thus this makes sense
1962         {
1963                 if(leaderfrags != WinningConditionHelper_topscore)
1964                 {
1965                         leaderfrags = WinningConditionHelper_topscore;
1966
1967                         if (limit)
1968                         if (leaderfrags == limit - 1)
1969                                 Announce("1fragleft");
1970                         else if (leaderfrags == limit - 2)
1971                                 Announce("2fragsleft");
1972                         else if (leaderfrags == limit - 3)
1973                                 Announce("3fragsleft");
1974                 }
1975         }
1976
1977         limitreached = FALSE;
1978         if(limit)
1979                 if(WinningConditionHelper_topscore >= limit)
1980                         limitreached = TRUE;
1981         if(leadlimit)
1982         {
1983                 float leadlimitreached;
1984                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1985                 if(autocvar_leadlimit_and_fraglimit)
1986                         limitreached = (limitreached && leadlimitreached);
1987                 else
1988                         limitreached = (limitreached || leadlimitreached);
1989         }
1990
1991         return GetWinningCode(
1992                 WinningConditionHelper_topscore && limitreached,
1993                 WinningConditionHelper_equality
1994         );
1995 }
1996
1997 float WinningCondition_Race(float fraglimit)
1998 {
1999         float wc;
2000         entity p;
2001         float n, c;
2002
2003         n = 0;
2004         c = 0;
2005         FOR_EACH_PLAYER(p)
2006         {
2007                 ++n;
2008                 if(p.race_completed)
2009                         ++c;
2010         }
2011         if(n && (n == c))
2012                 return WINNING_YES;
2013         wc = WinningCondition_Scores(fraglimit, 0);
2014
2015         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2016         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2017         // do NOT support equality when the laps are all raced!
2018                 return WINNING_STARTSUDDENDEATHOVERTIME;
2019         else
2020                 return WINNING_NEVER;
2021         return wc;
2022 }
2023
2024 void ReadyRestart();
2025 float WinningCondition_QualifyingThenRace(float limit)
2026 {
2027         float wc;
2028         wc = WinningCondition_Scores(limit, 0);
2029
2030         // NEVER initiate overtime
2031         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2032         {
2033                 return WINNING_YES;
2034         }
2035
2036         return wc;
2037 }
2038
2039 float WinningCondition_RanOutOfSpawns()
2040 {
2041         entity head;
2042
2043         if(have_team_spawns <= 0)
2044                 return WINNING_NO;
2045
2046         if(!some_spawn_has_been_used)
2047                 return WINNING_NO;
2048
2049         team1_score = team2_score = team3_score = team4_score = 0;
2050
2051         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2052         {
2053                 if(head.team == COLOR_TEAM1)
2054                         team1_score = 1;
2055                 else if(head.team == COLOR_TEAM2)
2056                         team2_score = 1;
2057                 else if(head.team == COLOR_TEAM3)
2058                         team3_score = 1;
2059                 else if(head.team == COLOR_TEAM4)
2060                         team4_score = 1;
2061         }
2062
2063         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2064         {
2065                 if(head.team == COLOR_TEAM1)
2066                         team1_score = 1;
2067                 else if(head.team == COLOR_TEAM2)
2068                         team2_score = 1;
2069                 else if(head.team == COLOR_TEAM3)
2070                         team3_score = 1;
2071                 else if(head.team == COLOR_TEAM4)
2072                         team4_score = 1;
2073         }
2074
2075         ClearWinners();
2076         if(team1_score + team2_score + team3_score + team4_score == 0)
2077         {
2078                 checkrules_equality = TRUE;
2079                 return WINNING_YES;
2080         }
2081         else if(team1_score + team2_score + team3_score + team4_score == 1)
2082         {
2083                 float t, i;
2084                 if(team1_score) t = COLOR_TEAM1;
2085                 if(team2_score) t = COLOR_TEAM2;
2086                 if(team3_score) t = COLOR_TEAM3;
2087                 if(team4_score) t = COLOR_TEAM4;
2088                 CheckAllowedTeams(world);
2089                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2090                 {
2091                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2092                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2093                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2094                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2095                 }
2096
2097                 AddWinners(team, t);
2098                 return WINNING_YES;
2099         }
2100         else
2101                 return WINNING_NO;
2102 }
2103
2104 /*
2105 ============
2106 CheckRules_World
2107
2108 Exit deathmatch games upon conditions
2109 ============
2110 */
2111 void CheckRules_World()
2112 {
2113         float timelimit;
2114         float fraglimit;
2115         float leadlimit;
2116
2117         VoteThink();
2118         MapVote_Think();
2119
2120         SetDefaultAlpha();
2121
2122         /*
2123         MapVote_Think should now do that part
2124         if (intermission_running)
2125                 if (time >= intermission_exittime + 60)
2126                 {
2127                         if(!DoNextMapOverride())
2128                                 GotoNextMap();
2129                         return;
2130                 }
2131         */
2132
2133         if (gameover)   // someone else quit the game already
2134         {
2135                 if(player_count == 0) // Nobody there? Then let's go to the next map
2136                         MapVote_Start();
2137                         // this will actually check the player count in the next frame
2138                         // again, but this shouldn't hurt
2139                 return;
2140         }
2141
2142         timelimit = autocvar_timelimit * 60;
2143         fraglimit = autocvar_fraglimit;
2144         leadlimit = autocvar_leadlimit;
2145
2146         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2147         {
2148                 if(timelimit > 0)
2149                         timelimit = 0; // timelimit is not made for warmup
2150                 if(fraglimit > 0)
2151                         fraglimit = 0; // no fraglimit for now
2152                 leadlimit = 0; // no leadlimit for now
2153         }
2154
2155         if(g_onslaught)
2156                 timelimit = 0; // ONS has its own overtime rule
2157
2158         if(timelimit > 0)
2159         {
2160                 timelimit += game_starttime;
2161         }
2162         else if (timelimit < 0)
2163         {
2164                 // endmatch
2165                 NextLevel();
2166                 return;
2167         }
2168
2169         float wantovertime;
2170         wantovertime = 0;
2171
2172         if(checkrules_suddendeathend)
2173         {
2174                 if(!checkrules_suddendeathwarning)
2175                 {
2176                         checkrules_suddendeathwarning = TRUE;
2177                         if(g_race && !g_race_qualifying)
2178                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2179                         else
2180                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2181                 }
2182         }
2183         else
2184         {
2185                 if (timelimit && time >= timelimit)
2186                 {
2187                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2188                         {
2189                                 float totalplayers;
2190                                 float playerswithlaps;
2191                                 float readyplayers;
2192                                 entity head;
2193                                 totalplayers = playerswithlaps = readyplayers = 0;
2194                                 FOR_EACH_PLAYER(head)
2195                                 {
2196                                         ++totalplayers;
2197                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2198                                                 ++playerswithlaps;
2199                                         if(head.ready)
2200                                                 ++readyplayers;
2201                                 }
2202
2203                                 // at least 2 of the players have completed a lap: start the RACE
2204                                 // otherwise, the players should end the qualifying on their own
2205                                 if(readyplayers || playerswithlaps >= 2)
2206                                 {
2207                                         checkrules_suddendeathend = 0;
2208                                         ReadyRestart(); // go to race
2209                                         return;
2210                                 }
2211                                 else
2212                                         wantovertime |= InitiateSuddenDeath();
2213                         }
2214                         else
2215                                 wantovertime |= InitiateSuddenDeath();
2216                 }
2217         }
2218
2219         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2220         {
2221                 NextLevel();
2222                 return;
2223         }
2224
2225         float checkrules_status;
2226         checkrules_status = WinningCondition_RanOutOfSpawns();
2227         if(checkrules_status == WINNING_YES)
2228         {
2229                 bprint("Hey! Someone ran out of spawns!\n");
2230         }
2231         else if(g_race && !g_race_qualifying && timelimit >= 0)
2232         {
2233                 checkrules_status = WinningCondition_Race(fraglimit);
2234                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2235         }
2236         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2237         {
2238                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2239                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2240         }
2241         else if(g_assault)
2242         {
2243                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2244         }
2245         else if(g_lms)
2246         {
2247                 checkrules_status = WinningCondition_LMS();
2248         }
2249         else if (g_onslaught)
2250         {
2251                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2252         }
2253         else
2254         {
2255                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2256                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2257         }
2258
2259         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2260         {
2261                 checkrules_status = WINNING_NEVER;
2262                 checkrules_overtimesadded = -1;
2263                 wantovertime |= InitiateSuddenDeath();
2264         }
2265
2266         if(checkrules_status == WINNING_NEVER)
2267                 // equality cases! Nobody wins if the overtime ends in a draw.
2268                 ClearWinners();
2269
2270         if(wantovertime)
2271         {
2272                 if(checkrules_status == WINNING_NEVER)
2273                         InitiateOvertime();
2274                 else
2275                         checkrules_status = WINNING_YES;
2276         }
2277
2278         if(checkrules_suddendeathend)
2279                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2280                         checkrules_status = WINNING_YES;
2281
2282         if(checkrules_status == WINNING_YES)
2283         {
2284                 //print("WINNING\n");
2285                 NextLevel();
2286         }
2287 };
2288
2289 float mapvote_nextthink;
2290 float mapvote_initialized;
2291 float mapvote_keeptwotime;
2292 float mapvote_timeout;
2293 string mapvote_message;
2294 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2295 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2296 float mapvote_screenshot_dirs_count;
2297
2298 float mapvote_count;
2299 float mapvote_count_real;
2300 string mapvote_maps[MAPVOTE_COUNT];
2301 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2302 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2303 float mapvote_maps_suggested[MAPVOTE_COUNT];
2304 string mapvote_suggestions[MAPVOTE_COUNT];
2305 float mapvote_suggestion_ptr;
2306 float mapvote_maxlen;
2307 float mapvote_voters;
2308 float mapvote_votes[MAPVOTE_COUNT];
2309 float mapvote_run;
2310 float mapvote_detail;
2311 float mapvote_abstain;
2312 .float mapvote;
2313
2314 void MapVote_ClearAllVotes()
2315 {
2316         FOR_EACH_CLIENT(other)
2317                 other.mapvote = 0;
2318 }
2319
2320 string MapVote_Suggest(string m)
2321 {
2322         float i;
2323         if(m == "")
2324                 return "That's not how to use this command.";
2325         if(!autocvar_g_maplist_votable_suggestions)
2326                 return "Suggestions are not accepted on this server.";
2327         if(mapvote_initialized)
2328                 return "Can't suggest - voting is already in progress!";
2329         m = MapInfo_FixName(m);
2330         if(!m)
2331                 return "The map you suggested is not available on this server.";
2332         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2333                 if(Map_IsRecent(m))
2334                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2335
2336         if(!MapInfo_CheckMap(m))
2337                 return "The map you suggested does not support the current game mode.";
2338         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2339                 if(mapvote_suggestions[i] == m)
2340                         return "This map was already suggested.";
2341         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2342         {
2343                 i = floor(random() * mapvote_suggestion_ptr);
2344         }
2345         else
2346         {
2347                 i = mapvote_suggestion_ptr;
2348                 mapvote_suggestion_ptr += 1;
2349         }
2350         if(mapvote_suggestions[i] != "")
2351                 strunzone(mapvote_suggestions[i]);
2352         mapvote_suggestions[i] = strzone(m);
2353         if(autocvar_sv_eventlog)
2354                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2355         return strcat("Suggestion of ", m, " accepted.");
2356 }
2357
2358 void MapVote_AddVotable(string nextMap, float isSuggestion)
2359 {
2360         float j, i, o;
2361         string pakfile, mapfile;
2362
2363         if(nextMap == "")
2364                 return;
2365         for(j = 0; j < mapvote_count; ++j)
2366                 if(mapvote_maps[j] == nextMap)
2367                         return;
2368         if(strlen(nextMap) > mapvote_maxlen)
2369                 mapvote_maxlen = strlen(nextMap);
2370         mapvote_maps[mapvote_count] = strzone(nextMap);
2371         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2372
2373         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2374         {
2375                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2376                 pakfile = whichpack(strcat(mapfile, ".tga"));
2377                 if(pakfile == "")
2378                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2379                 if(pakfile == "")
2380                         pakfile = whichpack(strcat(mapfile, ".png"));
2381                 if(pakfile != "")
2382                         break;
2383         }
2384         if(i >= mapvote_screenshot_dirs_count)
2385                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2386         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2387                 pakfile = substring(pakfile, o, -1);
2388
2389         mapvote_maps_screenshot_dir[mapvote_count] = i;
2390         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2391
2392         mapvote_count += 1;
2393 }
2394
2395 void MapVote_Spawn();
2396 void MapVote_Init()
2397 {
2398         float i;
2399         float nmax, smax;
2400
2401         MapVote_ClearAllVotes();
2402
2403         mapvote_count = 0;
2404         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2405         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2406
2407         if(mapvote_abstain)
2408                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2409         else
2410                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2411         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2412
2413         // we need this for AddVotable, as that cycles through the screenshot dirs
2414         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2415         if(mapvote_screenshot_dirs_count == 0)
2416                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2417         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2418         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2419                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2420
2421         if(mapvote_suggestion_ptr)
2422                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2423                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2424
2425         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2426                 MapVote_AddVotable(GetNextMap(), FALSE);
2427
2428         if(mapvote_count == 0)
2429         {
2430                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2431                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2432                 if(autocvar_g_maplist_shuffle)
2433                         ShuffleMaplist();
2434                 localcmd("\nmenu_cmd sync\n");
2435                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2436                         MapVote_AddVotable(GetNextMap(), FALSE);
2437         }
2438
2439         mapvote_count_real = mapvote_count;
2440         if(mapvote_abstain)
2441                 MapVote_AddVotable("don't care", 0);
2442
2443         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2444
2445         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2446         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2447         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2448                 mapvote_keeptwotime = 0;
2449         mapvote_message = "Choose a map and press its key!";
2450
2451         MapVote_Spawn();
2452 }
2453
2454 void MapVote_SendPicture(float id)
2455 {
2456         msg_entity = self;
2457         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2458         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2459         WriteByte(MSG_ONE, id);
2460         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2461 }
2462
2463 float GameCommand_MapVote(string cmd)
2464 {
2465         if(!intermission_running)
2466                 return FALSE;
2467
2468         if(cmd == "mv_getpic")
2469         {
2470                 MapVote_SendPicture(stof(argv(1)));
2471                 return TRUE;
2472         }
2473
2474         return FALSE;
2475 }
2476
2477 float MapVote_GetMapMask()
2478 {
2479         float mask, i, power;
2480         mask = 0;
2481         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2482                 if(mapvote_maps[i] != "")
2483                         mask |= power;
2484         return mask;
2485 }
2486
2487 entity mapvote_ent;
2488 float MapVote_SendEntity(entity to, float sf)
2489 {
2490         float i;
2491
2492         if(sf & 1)
2493                 sf &~= 2; // if we send 1, we don't need to also send 2
2494
2495         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2496         WriteByte(MSG_ENTITY, sf);
2497
2498         if(sf & 1)
2499         {
2500                 // flag 1 == initialization
2501                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2502                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2503                 WriteString(MSG_ENTITY, "");
2504                 WriteByte(MSG_ENTITY, mapvote_count);
2505                 WriteByte(MSG_ENTITY, mapvote_abstain);
2506                 WriteByte(MSG_ENTITY, mapvote_detail);
2507                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2508                 if(mapvote_count <= 8)
2509                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2510                 else
2511                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2512                 for(i = 0; i < mapvote_count; ++i)
2513                         if(mapvote_maps[i] != "")
2514                         {
2515                                 if(mapvote_abstain && i == mapvote_count - 1)
2516                                 {
2517                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2518                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2519                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2520                                 }
2521                                 else
2522                                 {
2523                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2524                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2525                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2526                                 }
2527                         }
2528         }
2529
2530         if(sf & 2)
2531         {
2532                 // flag 2 == update of mask
2533                 if(mapvote_count <= 8)
2534                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2535                 else
2536                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2537         }
2538
2539         if(sf & 4)
2540         {
2541                 if(mapvote_detail)
2542                         for(i = 0; i < mapvote_count; ++i)
2543                                 if(mapvote_maps[i] != "")
2544                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2545
2546                 WriteByte(MSG_ENTITY, to.mapvote);
2547         }
2548
2549         return TRUE;
2550 }
2551
2552 void MapVote_Spawn()
2553 {
2554         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2555 }
2556
2557 void MapVote_TouchMask()
2558 {
2559         mapvote_ent.SendFlags |= 2;
2560 }
2561
2562 void MapVote_TouchVotes(entity voter)
2563 {
2564         mapvote_ent.SendFlags |= 4;
2565 }
2566
2567 float MapVote_Finished(float mappos)
2568 {
2569         string result;
2570         float i;
2571         float didntvote;
2572
2573         if(autocvar_sv_eventlog)
2574         {
2575                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2576                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2577                 didntvote = mapvote_voters;
2578                 for(i = 0; i < mapvote_count; ++i)
2579                         if(mapvote_maps[i] != "")
2580                         {
2581                                 didntvote -= mapvote_votes[i];
2582                                 if(i != mappos)
2583                                 {
2584                                         result = strcat(result, ":", mapvote_maps[i]);
2585                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2586                                 }
2587                         }
2588                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2589
2590                 GameLogEcho(result);
2591                 if(mapvote_maps_suggested[mappos])
2592                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2593         }
2594
2595         FOR_EACH_REALCLIENT(other)
2596                 FixClientCvars(other);
2597
2598         Map_Goto_SetStr(mapvote_maps[mappos]);
2599         Map_Goto();
2600         alreadychangedlevel = TRUE;
2601         return TRUE;
2602 }
2603 void MapVote_CheckRules_1()
2604 {
2605         float i;
2606
2607         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2608         {
2609                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2610                 mapvote_votes[i] = 0;
2611         }
2612
2613         mapvote_voters = 0;
2614         FOR_EACH_REALCLIENT(other)
2615         {
2616                 ++mapvote_voters;
2617                 if(other.mapvote)
2618                 {
2619                         i = other.mapvote - 1;
2620                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2621                         mapvote_votes[i] = mapvote_votes[i] + 1;
2622                 }
2623         }
2624 }
2625
2626 float MapVote_CheckRules_2()
2627 {
2628         float i;
2629         float firstPlace, secondPlace;
2630         float firstPlaceVotes, secondPlaceVotes;
2631         float mapvote_voters_real;
2632         string result;
2633
2634         if(mapvote_count_real == 1)
2635                 return MapVote_Finished(0);
2636
2637         mapvote_voters_real = mapvote_voters;
2638         if(mapvote_abstain)
2639                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2640
2641         RandomSelection_Init();
2642         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2643                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2644         firstPlace = RandomSelection_chosen_float;
2645         firstPlaceVotes = RandomSelection_best_priority;
2646         //dprint("First place: ", ftos(firstPlace), "\n");
2647         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2648
2649         RandomSelection_Init();
2650         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2651                 if(i != firstPlace)
2652                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2653         secondPlace = RandomSelection_chosen_float;
2654         secondPlaceVotes = RandomSelection_best_priority;
2655         //dprint("Second place: ", ftos(secondPlace), "\n");
2656         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2657
2658         if(firstPlace == -1)
2659                 error("No first place in map vote... WTF?");
2660
2661         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2662                 return MapVote_Finished(firstPlace);
2663
2664         if(mapvote_keeptwotime)
2665                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2666                 {
2667                         float didntvote;
2668                         MapVote_TouchMask();
2669                         mapvote_message = "Now decide between the TOP TWO!";
2670                         mapvote_keeptwotime = 0;
2671                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2672                         result = strcat(result, ":", ftos(firstPlaceVotes));
2673                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2674                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2675                         didntvote = mapvote_voters;
2676                         for(i = 0; i < mapvote_count; ++i)
2677                                 if(mapvote_maps[i] != "")
2678                                 {
2679                                         didntvote -= mapvote_votes[i];
2680                                         if(i != firstPlace)
2681                                                 if(i != secondPlace)
2682                                                 {
2683                                                         result = strcat(result, ":", mapvote_maps[i]);
2684                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2685                                                         if(i < mapvote_count_real)
2686                                                         {
2687                                                                 strunzone(mapvote_maps[i]);
2688                                                                 mapvote_maps[i] = "";
2689                                                                 strunzone(mapvote_maps_pakfile[i]);
2690                                                                 mapvote_maps_pakfile[i] = "";
2691                                                         }
2692                                                 }
2693                                 }
2694                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2695                         if(autocvar_sv_eventlog)
2696                                 GameLogEcho(result);
2697                 }
2698
2699         return FALSE;
2700 }
2701 void MapVote_Tick()
2702 {
2703         float keeptwo;
2704         float totalvotes;
2705
2706         keeptwo = mapvote_keeptwotime;
2707         MapVote_CheckRules_1(); // count
2708         if(MapVote_CheckRules_2()) // decide
2709                 return;
2710
2711         totalvotes = 0;
2712         FOR_EACH_REALCLIENT(other)
2713         {
2714                 // hide scoreboard again
2715                 if(other.health != 2342)
2716                 {
2717                         other.health = 2342;
2718                         other.impulse = 0;
2719                         if(clienttype(other) == CLIENTTYPE_REAL)
2720                         {
2721                                 msg_entity = other;
2722                                 WriteByte(MSG_ONE, SVC_FINALE);
2723                                 WriteString(MSG_ONE, "");
2724                         }
2725                 }
2726
2727                 // clear possibly invalid votes
2728                 if(mapvote_maps[other.mapvote - 1] == "")
2729                         other.mapvote = 0;
2730                 // use impulses as new vote
2731                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2732                         if(mapvote_maps[other.impulse - 1] != "")
2733                         {
2734                                 other.mapvote = other.impulse;
2735                                 MapVote_TouchVotes(other);
2736                         }
2737                 other.impulse = 0;
2738
2739                 if(other.mapvote)
2740                         ++totalvotes;
2741         }
2742
2743         MapVote_CheckRules_1(); // just count
2744 }
2745 void MapVote_Start()
2746 {
2747         if(mapvote_run)
2748                 return;
2749
2750         // wait for stats to be sent first
2751         if(!playerstats_waitforme)
2752                 return;
2753
2754         MapInfo_Enumerate();
2755         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2756                 mapvote_run = TRUE;
2757 }
2758 void MapVote_Think()
2759 {
2760         if(!mapvote_run)
2761                 return;
2762
2763         if(alreadychangedlevel)
2764                 return;
2765
2766         if(time < mapvote_nextthink)
2767                 return;
2768         //dprint("tick\n");
2769
2770         mapvote_nextthink = time + 0.5;
2771
2772         if(!mapvote_initialized)
2773         {
2774                 if(autocvar_rescan_pending == 1)
2775                 {
2776                         cvar_set("rescan_pending", "2");
2777                         localcmd("fs_rescan\nrescan_pending 3\n");
2778                         return;
2779                 }
2780                 else if(autocvar_rescan_pending == 2)
2781                 {
2782                         return;
2783                 }
2784                 else if(autocvar_rescan_pending == 3)
2785                 {
2786                         // now build missing mapinfo files
2787                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2788                                 return;
2789
2790                         // we're done, start the timer
2791                         cvar_set("rescan_pending", "0");
2792                 }
2793
2794                 mapvote_initialized = TRUE;
2795                 if(DoNextMapOverride())
2796                         return;
2797                 if(!autocvar_g_maplist_votable || player_count <= 0)
2798                 {
2799                         GotoNextMap();
2800                         return;
2801                 }
2802                 MapVote_Init();
2803         }
2804
2805         MapVote_Tick();
2806 };
2807
2808 string GotoMap(string m)
2809 {
2810         if(!MapInfo_CheckMap(m))
2811                 return "The map you chose is not available on this server.";
2812         cvar_set("nextmap", m);
2813         cvar_set("timelimit", "-1");
2814         if(mapvote_initialized || alreadychangedlevel)
2815         {
2816                 if(DoNextMapOverride())
2817                         return "Map switch initiated.";
2818                 else
2819                         return "Hm... no. For some reason I like THIS map more.";
2820         }
2821         else
2822                 return "Map switch will happen after scoreboard.";
2823 }
2824
2825
2826 void EndFrame()
2827 {
2828         float altime;
2829         FOR_EACH_REALCLIENT(self)
2830         {
2831                 if(self.classname == "spectator")
2832                 {
2833                         if(self.enemy.typehitsound)
2834                                 play2(self, "misc/typehit.wav");
2835                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2836                                 play2(self, "misc/hit.wav");
2837                 }
2838                 else
2839                 {
2840                         if(self.typehitsound)
2841                                 play2(self, "misc/typehit.wav");
2842                         else if(self.hitsound && self.cvar_cl_hitsound)
2843                                 play2(self, "misc/hit.wav");
2844                 }
2845         }
2846         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2847         // add 1 frametime because after this, engine SV_Physics
2848         // increases time by a frametime and then networks the frame
2849         // add another frametime because client shows everything with
2850         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2851         // needed!
2852         FOR_EACH_CLIENT(self)
2853         {
2854                 self.hitsound = FALSE;
2855                 self.typehitsound = FALSE;
2856                 antilag_record(self, altime);
2857         }
2858 }
2859
2860
2861 /*
2862  * RedirectionThink:
2863  * returns TRUE if redirecting
2864  */
2865 float redirection_timeout;
2866 float redirection_nextthink;
2867 float RedirectionThink()
2868 {
2869         float clients_found;
2870
2871         if(redirection_target == "")
2872                 return FALSE;
2873
2874         if(!redirection_timeout)
2875         {
2876                 cvar_set("sv_public", "-2");
2877                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2878                 if(redirection_target == "self")
2879                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2880                 else
2881                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2882         }
2883
2884         if(time < redirection_nextthink)
2885                 return TRUE;
2886
2887         redirection_nextthink = time + 1;
2888
2889         clients_found = 0;
2890         FOR_EACH_REALCLIENT(self)
2891         {
2892                 print("Redirecting: sending connect command to ", self.netname, "\n");
2893                 if(redirection_target == "self")
2894                         stuffcmd(self, "\ndisconnect; reconnect\n");
2895                 else
2896                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2897                 ++clients_found;
2898         }
2899
2900         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2901
2902         if(time > redirection_timeout || clients_found == 0)
2903                 localcmd("\nwait; wait; wait; quit\n");
2904
2905         return TRUE;
2906 }
2907
2908 void TargetMusic_RestoreGame();
2909 void RestoreGame()
2910 {
2911         // Loaded from a save game
2912         // some things then break, so let's work around them...
2913
2914         // Progs DB (capture records)
2915         ServerProgsDB = db_load("server.db");
2916
2917         // Mapinfo
2918         MapInfo_Shutdown();
2919         MapInfo_Enumerate();
2920         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2921         WeaponStats_Init();
2922
2923         TargetMusic_RestoreGame();
2924 }
2925
2926 void SV_Shutdown()
2927 {
2928         entity e;
2929
2930         if(gameover > 1) // shutting down already?
2931                 return;
2932
2933         gameover = 2; // 2 = server shutting down
2934
2935         if(world_initialized > 0)
2936         {
2937                 world_initialized = 0;
2938                 print("Saving persistent data...\n");
2939                 Ban_SaveBans();
2940
2941                 FOR_EACH_CLIENT(e)
2942                         PlayerStats_AddGlobalInfo(e);
2943                 PlayerStats_Shutdown();
2944
2945                 if(!cheatcount_total)
2946                 {
2947                         if(autocvar_sv_db_saveasdump)
2948                                 db_dump(ServerProgsDB, "server.db");
2949                         else
2950                                 db_save(ServerProgsDB, "server.db");
2951                 }
2952                 if(autocvar_developer)
2953                 {
2954                         if(autocvar_sv_db_saveasdump)
2955                                 db_dump(TemporaryDB, "server-temp.db");
2956                         else
2957                                 db_save(TemporaryDB, "server-temp.db");
2958                 }
2959                 CheatShutdown(); // must be after cheatcount check
2960                 db_close(ServerProgsDB);
2961                 db_close(TemporaryDB);
2962                 print("done!\n");
2963                 // tell the bot system the game is ending now
2964                 bot_endgame();
2965
2966                 WeaponStats_Shutdown();
2967                 MapInfo_Shutdown();
2968         }
2969         else if(world_initialized == 0)
2970         {
2971                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2972         }
2973 }