qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride())
 193                         GotoNextMap();
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_playerstats_");
 301                 BADPREFIX("g_voice_flood_");
 302                 BADPREFIX("rcon_");
 303                 BADPREFIX("settemp_");
 304                 BADPREFIX("sv_allowdownloads_");
 305                 BADPREFIX("sv_autodemo");
 306                 BADPREFIX("sv_curl_");
 307                 BADPREFIX("sv_eventlog");
 308                 BADPREFIX("sv_logscores_");
 309                 BADPREFIX("sv_master");
 310                 BADPREFIX("sv_weaponstats_");
 311                 BADPREFIX("sv_waypointsprite_");
 312                 BADCVAR("rescan_pending");
 313
 314                 // these can contain player IDs, so better hide
 315                 BADPREFIX("g_forced_team_");
 316
 317                 // mapinfo
 318                 BADCVAR("fraglimit");
 319                 BADCVAR("g_arena");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ca");
 322                 BADCVAR("g_ctf");
 323                 BADCVAR("g_cts");
 324                 BADCVAR("g_dm");
 325                 BADCVAR("g_domination");
 326                 BADCVAR("g_domination_default_teams");
 327                 BADCVAR("g_freezetag");
 328                 BADCVAR("g_keepaway");
 329                 BADCVAR("g_keyhunt");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_keyhunt_teams");
 332                 BADCVAR("g_lms");
 333                 BADCVAR("g_nexball");
 334                 BADCVAR("g_onslaught");
 335                 BADCVAR("g_race");
 336                 BADCVAR("g_race_qualifying_timelimit");
 337                 BADCVAR("g_runematch");
 338                 BADCVAR("g_tdm");
 339                 BADCVAR("g_tdm_teams");
 340                 BADCVAR("leadlimit");
 341                 BADCVAR("nextmap");
 342                 BADCVAR("teamplay");
 343                 BADCVAR("timelimit");
 344
 345                 // long
 346                 BADCVAR("hostname");
 347                 BADCVAR("g_maplist");
 348                 BADCVAR("g_maplist_mostrecent");
 349                 BADCVAR("sv_motd");
 350
 351                 v = cvar_string(k);
 352                 d = cvar_defstring(k);
 353                 if(v == d)
 354                         continue;
 355
 356                 if(adding)
 357                 {
 358                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 359                         if(strlen(cvar_changes) > 16384)
 360                         {
 361                                 cvar_changes = "// too many settings have been changed to show them here\n";
 362                                 adding = 0;
 363                         }
 364                 }
 365
 366                 // now check if the changes are actually gameplay relevant
 367
 368                 // does nothing visible
 369                 BADCVAR("captureleadlimit_override");
 370                 BADCVAR("g_arena_point_leadlimit");
 371                 BADCVAR("g_balance_kill_delay");
 372                 BADCVAR("g_ca_point_leadlimit");
 373                 BADCVAR("g_ctf_captimerecord_always");
 374                 BADCVAR("g_ctf_capture_leadlimit");
 375                 BADCVAR("g_ctf_flag_capture_effects");
 376                 BADCVAR("g_ctf_flag_glowtrails");
 377                 BADCVAR("g_ctf_flag_pickup_effects");
 378                 BADCVAR("g_domination_point_leadlimit");
 379                 BADCVAR("g_forced_respawn");
 380                 BADCVAR("g_keyhunt_point_leadlimit");
 381                 BADCVAR("g_nexball_goalleadlimit");
 382                 BADCVAR("g_runematch_point_leadlimit");
 383                 BADCVAR("leadlimit_and_fraglimit");
 384                 BADCVAR("leadlimit_override");
 385                 BADCVAR("pausable");
 386                 BADCVAR("sv_allow_fullbright");
 387                 BADCVAR("sv_checkforpacketsduringsleep");
 388                 BADCVAR("sv_timeout");
 389                 BADCVAR("welcome_message_time");
 390                 BADPREFIX("crypto_");
 391                 BADPREFIX("g_chat_");
 392                 BADPREFIX("g_ctf_captimerecord_");
 393                 BADPREFIX("g_maplist_votable_");
 394                 BADPREFIX("net_");
 395                 BADPREFIX("prvm_");
 396                 BADPREFIX("skill_");
 397                 BADPREFIX("sv_cullentities_");
 398                 BADPREFIX("sv_fraginfo_");
 399                 BADPREFIX("sv_maxidle_");
 400                 BADPREFIX("sv_vote_");
 401                 BADPREFIX("timelimit_");
 402                 BADCVAR("gameversion");
 403                 BADPREFIX("gameversion_");
 404                 BADCVAR("sv_namechangetimer");
 405
 406                 // allowed changes to server admins (please sync this to server.cfg)
 407                 // vi commands:
 408                 //   :/"impure"/,$d
 409                 //   :g!,^\/\/[^ /],d
 410                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 411                 //   :%!sort
 412                 // yes, this does contain some redundant stuff, don't really care
 413                 BADCVAR("bot_config_file");
 414                 BADCVAR("bot_number");
 415                 BADCVAR("bot_prefix");
 416                 BADCVAR("bot_suffix");
 417                 BADCVAR("capturelimit_override");
 418                 BADCVAR("fraglimit_override");
 419                 BADCVAR("gametype");
 420                 BADCVAR("g_antilag");
 421                 BADCVAR("g_balance_teams");
 422                 BADCVAR("g_balance_teams_force");
 423                 BADCVAR("g_ban_sync_trusted_servers");
 424                 BADCVAR("g_ban_sync_uri");
 425                 BADCVAR("g_ctf_capture_limit");
 426                 BADCVAR("g_ctf_ignore_frags");
 427                 BADCVAR("g_ctf_win_mode");
 428                 BADCVAR("g_domination_point_limit");
 429                 BADCVAR("g_friendlyfire");
 430                 BADCVAR("g_fullbrightitems");
 431                 BADCVAR("g_fullbrightplayers");
 432                 BADCVAR("g_keyhunt_point_limit");
 433                 BADCVAR("g_keyhunt_teams_override");
 434                 BADCVAR("g_lms_lives_override");
 435                 BADCVAR("g_maplist");
 436                 BADCVAR("g_maplist_check_waypoints");
 437                 BADCVAR("g_maplist_mostrecent_count");
 438                 BADCVAR("g_maplist_shuffle");
 439                 BADCVAR("g_maplist_votable");
 440                 BADCVAR("g_maplist_votable_abstain");
 441                 BADCVAR("g_maplist_votable_nodetail");
 442                 BADCVAR("g_maplist_votable_suggestions");
 443                 BADCVAR("g_maxplayers");
 444                 BADCVAR("g_minstagib");
 445                 BADCVAR("g_mirrordamage");
 446                 BADCVAR("g_nexball_goallimit");
 447                 BADCVAR("g_powerups");
 448                 BADCVAR("g_runematch_point_limit");
 449                 BADCVAR("g_start_delay");
 450                 BADCVAR("g_warmup");
 451                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 452                 BADCVAR("hostname");
 453                 BADCVAR("log_file");
 454                 BADCVAR("maxplayers");
 455                 BADCVAR("minplayers");
 456                 BADCVAR("net_address");
 457                 BADCVAR("port");
 458                 BADCVAR("rcon_password");
 459                 BADCVAR("rcon_restricted_commands");
 460                 BADCVAR("rcon_restricted_password");
 461                 BADCVAR("skill");
 462                 BADCVAR("sv_adminnick");
 463                 BADCVAR("sv_autoscreenshot");
 464                 BADCVAR("sv_autotaunt");
 465                 BADCVAR("sv_curl_defaulturl");
 466                 BADCVAR("sv_defaultcharacter");
 467                 BADCVAR("sv_defaultplayercolors");
 468                 BADCVAR("sv_defaultplayermodel");
 469                 BADCVAR("sv_defaultplayerskin");
 470                 BADCVAR("sv_maxidle");
 471                 BADCVAR("sv_maxrate");
 472                 BADCVAR("sv_motd");
 473                 BADCVAR("sv_public");
 474                 BADCVAR("sv_ready_restart");
 475                 BADCVAR("sv_status_privacy");
 476                 BADCVAR("sv_taunt");
 477                 BADCVAR("sv_vote_call");
 478                 BADCVAR("sv_vote_commands");
 479                 BADCVAR("sv_vote_majority_factor");
 480                 BADCVAR("sv_vote_master");
 481                 BADCVAR("sv_vote_master_commands");
 482                 BADCVAR("sv_vote_master_password");
 483                 BADCVAR("sv_vote_simple_majority_factor");
 484                 BADCVAR("sys_ticrate");
 485                 BADCVAR("teamplay_mode");
 486                 BADCVAR("timelimit_override");
 487                 BADPREFIX("g_warmup_");
 488                 BADPREFIX("sv_ready_restart_");
 489
 490                 if(autocvar_g_minstagib)
 491                 {
 492                         BADCVAR("g_grappling_hook");
 493                         BADCVAR("g_jetpack");
 494                 }
 495 #undef BADPREFIX
 496 #undef BADCVAR
 497
 498                 if(pureadding)
 499                 {
 500                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 501                         if(strlen(cvar_purechanges) > 16384)
 502                         {
 503                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 504                                 pureadding = 0;
 505                         }
 506                 }
 507                 ++cvar_purechanges_count;
 508                 // WARNING: this variable is used for the server list
 509                 // NEVER dare to skip this code!
 510                 // Hacks to intentionally appearing as "pure server" even though you DO have
 511                 // modified settings may be punished by removal from the server list.
 512                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 513                 // though.
 514         }
 515         buf_del(h);
 516         if(cvar_changes == "")
 517                 cvar_changes = "// this server runs at default server settings\n";
 518         else
 519                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 520         cvar_changes = strzone(cvar_changes);
 521         if(cvar_purechanges == "")
 522                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 523         else
 524                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 525         cvar_purechanges = strzone(cvar_purechanges);
 526 }
 527
 528 void detect_maptype()
 529 {
 530 #if 0
 531         vector o, v;
 532         float i;
 533
 534         for(;;)
 535         {
 536                 o = world.mins;
 537                 o_x += random() * (world.maxs_x - world.mins_x);
 538                 o_y += random() * (world.maxs_y - world.mins_y);
 539                 o_z += random() * (world.maxs_z - world.mins_z);
 540
 541                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 542                 if(trace_fraction == 1)
 543                         continue;
 544
 545                 v = trace_endpos;
 546
 547                 for(i = 0; i < 64; i += 4)
 548                 {
 549                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 550         if(trace_fraction == 1)
 551                 continue;
 552                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 553                 }
 554
 555                 break;
 556         }
 557 #endif
 558 }
 559
 560 entity randomseed;
 561 float RandomSeed_Send(entity to, float sf)
 562 {
 563         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 564         WriteShort(MSG_ENTITY, self.cnt);
 565         return TRUE;
 566 }
 567 void RandomSeed_Think()
 568 {
 569         self.cnt = bound(0, floor(random() * 65536), 65535);
 570         self.nextthink = time + 5;
 571
 572         self.SendFlags |= 1;
 573 }
 574 void RandomSeed_Spawn()
 575 {
 576         randomseed = spawn();
 577         randomseed.think = RandomSeed_Think;
 578         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 579
 580         entity oldself;
 581         oldself = self;
 582         self = randomseed;
 583         self.think(); // sets random seed and nextthink
 584         self = oldself;
 585 }
 586
 587 void spawnfunc___init_dedicated_server(void)
 588 {
 589         // handler for _init/_init map (only for dedicated server initialization)
 590
 591         world_initialized = -1; // don't complain
 592         cvar = cvar_normal;
 593         cvar_string = cvar_string_normal;
 594         cvar_set = cvar_set_normal;
 595
 596         remove = remove_unsafely;
 597
 598         entity e;
 599         e = spawn();
 600         e.think = GotoFirstMap;
 601         e.nextthink = time; // this is usually 1 at this point
 602
 603         e = spawn();
 604         e.classname = "info_player_deathmatch"; // safeguard against player joining
 605
 606         self.classname = "worldspawn"; // safeguard against various stuff ;)
 607
 608         MapInfo_Enumerate();
 609         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 610 }
 611
 612 void Map_MarkAsRecent(string m);
 613 float world_already_spawned;
 614 void RegisterWeapons();
 615 void Nagger_Init();
 616 void ClientInit_Spawn();
 617 void WeaponStats_Init();
 618 void WeaponStats_Shutdown();
 619 void spawnfunc_worldspawn (void)
 620 {
 621         float fd, l, i, j, n;
 622         string s, col;
 623
 624         cvar = cvar_normal;
 625         cvar_string = cvar_string_normal;
 626         cvar_set = cvar_set_normal;
 627
 628         if(world_already_spawned)
 629                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 630         world_already_spawned = TRUE;
 631
 632         remove = remove_safely; // during spawning, watch what you remove!
 633
 634         check_unacceptable_compiler_bugs();
 635
 636         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 637
 638         compressShortVector_init();
 639
 640         allowed_to_spawn = TRUE;
 641
 642         entity head;
 643         head = nextent(world);
 644         maxclients = 0;
 645         while(head)
 646         {
 647                 ++maxclients;
 648                 head = nextent(head);
 649         }
 650
 651         // needs to be done so early as they would still spawn
 652         RegisterWeapons();
 653
 654         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 655
 656         TemporaryDB = db_create();
 657
 658         // 0 normal
 659         lightstyle(0, "m");
 660
 661         // 1 FLICKER (first variety)
 662         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 663
 664         // 2 SLOW STRONG PULSE
 665         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 666
 667         // 3 CANDLE (first variety)
 668         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 669
 670         // 4 FAST STROBE
 671         lightstyle(4, "mamamamamama");
 672
 673         // 5 GENTLE PULSE 1
 674         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 675
 676         // 6 FLICKER (second variety)
 677         lightstyle(6, "nmonqnmomnmomomno");
 678
 679         // 7 CANDLE (second variety)
 680         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 681
 682         // 8 CANDLE (third variety)
 683         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 684
 685         // 9 SLOW STROBE (fourth variety)
 686         lightstyle(9, "aaaaaaaazzzzzzzz");
 687
 688         // 10 FLUORESCENT FLICKER
 689         lightstyle(10, "mmamammmmammamamaaamammma");
 690
 691         // 11 SLOW PULSE NOT FADE TO BLACK
 692         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 693
 694         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 695
 696         // 63 testing
 697         lightstyle(63, "a");
 698
 699         if(autocvar_g_campaign)
 700                 CampaignPreInit();
 701
 702         Map_MarkAsRecent(mapname);
 703
 704         precache_model ("null"); // we need this one before InitGameplayMode
 705         InitGameplayMode();
 706         readlevelcvars();
 707         GrappleHookInit();
 708         ElectroInit();
 709         LaserInit();
 710
 711         player_count = 0;
 712         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 713         if(bot_waypoints_for_items == 1)
 714                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 715                         bot_waypoints_for_items = 0;
 716
 717         precache();
 718
 719         WaypointSprite_Init();
 720
 721         //if (g_domination)
 722         //      dom_init();
 723
 724         GameLogInit(); // prepare everything
 725         // NOTE for matchid:
 726         // changing the logic generating it is okay. But:
 727         // it HAS to stay <= 64 chars
 728         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 729         if(autocvar_sv_eventlog)
 730         {
 731                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 732                 matchid = strzone(s);
 733
 734                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 735                 s = ":gameinfo:mutators:LIST";
 736
 737                 ret_string = s;
 738                 MUTATOR_CALLHOOK(BuildMutatorsString);
 739                 s = ret_string;
 740
 741                 // simple, probably not good in the mutator system
 742                 if(autocvar_g_grappling_hook)
 743                         s = strcat(s, ":grappling_hook");
 744
 745                 // initialiation stuff, not good in the mutator system
 746                 if(!autocvar_g_use_ammunition)
 747                         s = strcat(s, ":no_use_ammunition");
 748
 749                 // initialiation stuff, not good in the mutator system
 750                 if(autocvar_g_pickup_items == 0)
 751                         s = strcat(s, ":no_pickup_items");
 752                 if(autocvar_g_pickup_items > 0)
 753                         s = strcat(s, ":pickup_items");
 754
 755                 // initialiation stuff, not good in the mutator system
 756                 if(autocvar_g_weaponarena != "0")
 757                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 758
 759                 // TODO to mutator system
 760                 if(autocvar_g_norecoil)
 761                         s = strcat(s, ":norecoil");
 762
 763                 // TODO to mutator system
 764                 if(autocvar_g_midair)
 765                         s = strcat(s, ":midair");
 766
 767                 // TODO to mutator system
 768                 if(autocvar_g_minstagib)
 769                         s = strcat(s, ":minstagib");
 770
 771                 // TODO to mutator system
 772                 if(autocvar_g_powerups == 0)
 773                         s = strcat(s, ":no_powerups");
 774                 if(autocvar_g_powerups > 0)
 775                         s = strcat(s, ":powerups");
 776
 777                 GameLogEcho(s);
 778                 GameLogEcho(":gameinfo:end");
 779         }
 780         else
 781                 matchid = strzone(ftos(random()));
 782
 783         cvar_set("nextmap", "");
 784
 785         SetDefaultAlpha();
 786
 787         if(autocvar_g_campaign)
 788                 CampaignPostInit();
 789
 790         fteqcc_testbugs();
 791
 792         Ban_LoadBans();
 793
 794         MapInfo_Enumerate();
 795         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 796
 797         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 798         {
 799                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 800                 if(fd != -1)
 801                 {
 802                         while((s = fgets(fd)))
 803                         {
 804                                 l = tokenize_console(s);
 805                                 if(l < 2)
 806                                         continue;
 807                                 if(argv(0) == "cd")
 808                                 {
 809                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 810                                         print("  cdtrack ", argv(2), "\n");
 811                                 }
 812                                 else if(argv(0) == "fog")
 813                                 {
 814                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 815                                         print("  \"fog\" \"", s, "\"\n");
 816                                 }
 817                                 else if(argv(0) == "set")
 818                                 {
 819                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 820                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 821                                 }
 822                                 else if(argv(0) != "//")
 823                                 {
 824                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 825                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 826                                 }
 827                         }
 828                         fclose(fd);
 829                 }
 830         }
 831
 832         WeaponStats_Init();
 833
 834         addstat(STAT_WEAPONS, AS_INT, weapons);
 835         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 836         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 837         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 838         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 839         Nagger_Init();
 840
 841         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 842         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 843         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 844         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 845         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 846         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 847         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 848         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 849         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 850         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 851         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 852         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 853
 854         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 855         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 856
 857         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 858
 859         if(g_ca || g_freezetag)
 860         {
 861                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 862                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 863                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 864                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 865         }
 866         if(g_freezetag)
 867         {
 868                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 869                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 870         }
 871
 872         // g_movementspeed hack
 873         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 874         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 875         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 876         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 877
 878         // secrets
 879         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 880         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 881
 882         next_pingtime = time + 5;
 883
 884         detect_maptype();
 885
 886         lsmaps_reply = "^7Maps available: ";
 887         lsnewmaps_reply = "^7Maps without a record set: ";
 888         for(i = 0, j = 0; i < MapInfo_count; ++i)
 889         {
 890                 if(MapInfo_Get_ByID(i))
 891                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 892                         {
 893                                 if(mod(i, 2))
 894                                         col = "^2";
 895                                 else
 896                                         col = "^3";
 897                                 ++j;
 898                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 899                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 900                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 901                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 902                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 903                         }
 904         }
 905         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 906         if (!g_race && !g_cts)
 907                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 908         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 909
 910         maplist_reply = "^7Maps in list: ";
 911         n = tokenize_console(autocvar_g_maplist);
 912         for(i = 0, j = 0; i < n; ++i)
 913         {
 914                 if(MapInfo_CheckMap(argv(i)))
 915                 {
 916                         if(mod(j, 2))
 917                                 col = "^2";
 918                         else
 919                                 col = "^3";
 920                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 921                         ++j;
 922                 }
 923         }
 924         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 925         MapInfo_ClearTemps();
 926
 927         for(i = 0; i < 10; ++i)
 928         {
 929                 records_reply[i] = strzone(getrecords(i));
 930         }
 931         if(g_cts)
 932                 ladder_reply = strzone(getladder());
 933
 934         rankings_reply = strzone(getrankings());
 935
 936         ClientInit_Spawn();
 937         RandomSeed_Spawn();
 938         PingPLReport_Spawn();
 939
 940         CheatInit();
 941
 942         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 943
 944         // fill sv_curl_serverpackages from .serverpackage files
 945         if(autocvar_sv_curl_serverpackages_auto)
 946         {
 947                 s = "";
 948                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 949                 for(i = 0; i < n; ++i)
 950                         if(substring(argv(i), -14, -1) != ".serverpackage")
 951                                 s = strcat(s, " ", argv(i));
 952                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 953                 if(fd >= 0)
 954                 {
 955                         j = search_getsize(fd);
 956                         for(i = 0; i < j; ++i)
 957                                 s = strcat(s, " ", search_getfilename(fd, i));
 958                         search_end(fd);
 959                 }
 960                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 961         }
 962
 963         PlayerStats_Init();
 964
 965         world_initialized = 1;
 966 }
 967
 968 void spawnfunc_light (void)
 969 {
 970         //makestatic (self); // Who the f___ did that?
 971         remove(self);
 972 }
 973
 974 string GetGametype()
 975 {
 976         return GametypeNameFromType(game);
 977 }
 978
 979 string getmapname_stored;
 980 string GetMapname()
 981 {
 982         return mapname;
 983 }
 984
 985 float Map_Count, Map_Current;
 986 string Map_Current_Name;
 987
 988 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 989 float GetMaplistPosition()
 990 {
 991         float pos, idx;
 992         string map;
 993
 994         map = GetMapname();
 995         idx = autocvar_g_maplist_index;
 996
 997         if(idx >= 0)
 998                 if(idx < Map_Count)
 999                         if(map == argv(idx))
1000                                 return idx;
1001
1002         for(pos = 0; pos < Map_Count; ++pos)
1003                 if(map == argv(pos))
1004                         return pos;
1005
1006         // resume normal maplist rotation if current map is not in g_maplist
1007         return idx;
1008 }
1009
1010 float MapHasRightSize(string map)
1011 {
1012         float fh;
1013         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1014         if(autocvar_g_maplist_check_waypoints)
1015         {
1016                 dprint("checkwp "); dprint(map);
1017                 if(!fexists(strcat("maps/", map, ".waypoints")))
1018                 {
1019                         dprint(": no waypoints\n");
1020                         return FALSE;
1021                 }
1022                 dprint(": has waypoints\n");
1023         }
1024
1025         // open map size restriction file
1026         dprint("opensize "); dprint(map);
1027         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1028         if(fh >= 0)
1029         {
1030                 float mapmin, mapmax;
1031                 dprint(": ok, ");
1032                 mapmin = stof(fgets(fh));
1033                 mapmax = stof(fgets(fh));
1034                 fclose(fh);
1035                 if(player_count < mapmin)
1036                 {
1037                         dprint("not enough\n");
1038                         return FALSE;
1039                 }
1040                 if(player_count > mapmax)
1041                 {
1042                         dprint("too many\n");
1043                         return FALSE;
1044                 }
1045                 dprint("right size\n");
1046                 return TRUE;
1047         }
1048         dprint(": not found\n");
1049         return TRUE;
1050 }
1051
1052 string Map_Filename(float position)
1053 {
1054         return strcat("maps/", argv(position), ".bsp");
1055 }
1056
1057 string strwords(string s, float w)
1058 {
1059         float endpos;
1060         for(endpos = 0; w && endpos >= 0; --w)
1061                 endpos = strstrofs(s, " ", endpos + 1);
1062         if(endpos < 0)
1063                 return s;
1064         else
1065                 return substring(s, 0, endpos);
1066 }
1067
1068 float strhasword(string s, string w)
1069 {
1070         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1071 }
1072
1073 void Map_MarkAsRecent(string m)
1074 {
1075         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1076 }
1077
1078 float Map_IsRecent(string m)
1079 {
1080         return strhasword(autocvar_g_maplist_mostrecent, m);
1081 }
1082
1083 float Map_Check(float position, float pass)
1084 {
1085         string filename;
1086         string map_next;
1087         map_next = argv(position);
1088         if(pass <= 1)
1089         {
1090                 if(Map_IsRecent(map_next))
1091                         return 0;
1092         }
1093         filename = Map_Filename(position);
1094         if(MapInfo_CheckMap(map_next))
1095         {
1096                 if(pass == 2)
1097                         return 1;
1098                 if(MapHasRightSize(map_next))
1099                         return 1;
1100                 return 0;
1101         }
1102         else
1103                 dprint( "Couldn't select '", filename, "'..\n" );
1104
1105         return 0;
1106 }
1107
1108 void Map_Goto_SetStr(string nextmapname)
1109 {
1110         if(getmapname_stored != "")
1111                 strunzone(getmapname_stored);
1112         if(nextmapname == "")
1113                 getmapname_stored = "";
1114         else
1115                 getmapname_stored = strzone(nextmapname);
1116 }
1117
1118 void Map_Goto_SetFloat(float position)
1119 {
1120         cvar_set("g_maplist_index", ftos(position));
1121         Map_Goto_SetStr(argv(position));
1122 }
1123
1124 void GameResetCfg()
1125 {
1126         // settings persist, except...
1127         localcmd("\nsettemp_restore\n");
1128 }
1129
1130 void Map_Goto()
1131 {
1132         GameResetCfg();
1133         MapInfo_LoadMap(getmapname_stored);
1134 }
1135
1136 // return codes of map selectors:
1137 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1138 //   -2 = permanent failure
1139 float() MaplistMethod_Iterate = // usual method
1140 {
1141         float pass, i;
1142
1143         for(pass = 1; pass <= 2; ++pass)
1144         {
1145                 for(i = 1; i < Map_Count; ++i)
1146                 {
1147                         float mapindex;
1148                         mapindex = mod(i + Map_Current, Map_Count);
1149                         if(Map_Check(mapindex, pass))
1150                                 return mapindex;
1151                 }
1152         }
1153         return -1;
1154 }
1155
1156 float() MaplistMethod_Repeat = // fallback method
1157 {
1158         if(Map_Check(Map_Current, 2))
1159                 return Map_Current;
1160         return -2;
1161 }
1162
1163 float() MaplistMethod_Random = // random map selection
1164 {
1165         float i, imax;
1166
1167         imax = 42;
1168
1169         for(i = 0; i <= imax; ++i)
1170         {
1171                 float mapindex;
1172                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1173                 if(Map_Check(mapindex, 1))
1174                         return mapindex;
1175         }
1176         return -1;
1177 }
1178
1179 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1180 // the exponent sets a bias on the map selection:
1181 // the higher the exponent, the less likely "shortly repeated" same maps are
1182 {
1183         float i, j, imax, insertpos;
1184
1185         imax = 42;
1186
1187         for(i = 0; i <= imax; ++i)
1188         {
1189                 string newlist;
1190
1191                 // now reinsert this at another position
1192                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1193                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1194                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1195                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1196
1197                 // insert the current map there
1198                 newlist = "";
1199                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1200                         newlist = strcat(newlist, " ", argv(j));
1201                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1202                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1203                         newlist = strcat(newlist, " ", argv(j));
1204                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1205                 cvar_set("g_maplist", newlist);
1206                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1207
1208                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1209                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1210                 if(Map_Check(Map_Current, 1))
1211                         return Map_Current;
1212         }
1213         return -1;
1214 }
1215
1216 void Maplist_Init()
1217 {
1218         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1219         if(Map_Count == 0)
1220         {
1221                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1222                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1223                 if(autocvar_g_maplist_shuffle)
1224                         ShuffleMaplist();
1225                 localcmd("\nmenu_cmd sync\n");
1226                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1227         }
1228         if(Map_Count == 0)
1229                 error("empty maplist, cannot select a new map");
1230         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1231
1232         if(Map_Current_Name)
1233                 strunzone(Map_Current_Name);
1234         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1235         // this may or may not be correct, but who cares, in the worst case a map
1236         // isn't chosen in the first pass that should have been
1237 }
1238
1239 string GetNextMap()
1240 {
1241         float nextMap;
1242
1243         Maplist_Init();
1244         nextMap = -1;
1245
1246         if(nextMap == -1)
1247                 if(autocvar_g_maplist_shuffle > 0)
1248                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1249
1250         if(nextMap == -1)
1251                 if(autocvar_g_maplist_selectrandom)
1252                         nextMap = MaplistMethod_Random();
1253
1254         if(nextMap == -1)
1255                 nextMap = MaplistMethod_Iterate();
1256
1257         if(nextMap == -1)
1258                 nextMap = MaplistMethod_Repeat();
1259
1260         if(nextMap >= 0)
1261         {
1262                 Map_Goto_SetFloat(nextMap);
1263                 return getmapname_stored;
1264         }
1265
1266         return "";
1267 }
1268
1269 float DoNextMapOverride()
1270 {
1271         if(autocvar_g_campaign)
1272         {
1273                 CampaignPostIntermission();
1274                 alreadychangedlevel = TRUE;
1275                 return TRUE;
1276         }
1277         if(autocvar_quit_when_empty)
1278         {
1279                 if(player_count <= currentbots)
1280                 {
1281                         localcmd("quit\n");
1282                         alreadychangedlevel = TRUE;
1283                         return TRUE;
1284                 }
1285         }
1286         if(autocvar_quit_and_redirect != "")
1287         {
1288                 redirection_target = strzone(autocvar_quit_and_redirect);
1289                 alreadychangedlevel = TRUE;
1290                 return TRUE;
1291         }
1292         if (autocvar_samelevel) // if samelevel is set, stay on same level
1293         {
1294                 localcmd("restart\n");
1295                 alreadychangedlevel = TRUE;
1296                 return TRUE;
1297         }
1298         if(autocvar_nextmap != "")
1299                 if(MapInfo_CheckMap(autocvar_nextmap))
1300                 {
1301                         Map_Goto_SetStr(autocvar_nextmap);
1302                         Map_Goto();
1303                         alreadychangedlevel = TRUE;
1304                         return TRUE;
1305                 }
1306         if(autocvar_lastlevel)
1307         {
1308                 GameResetCfg();
1309                 localcmd("set lastlevel 0\ntogglemenu\n");
1310                 alreadychangedlevel = TRUE;
1311                 return TRUE;
1312         }
1313         return FALSE;
1314 }
1315
1316 void GotoNextMap()
1317 {
1318         //string nextmap;
1319         //float n, nummaps;
1320         //string s;
1321         if (alreadychangedlevel)
1322                 return;
1323         alreadychangedlevel = TRUE;
1324
1325         {
1326                 string nextMap;
1327                 float allowReset;
1328
1329                 for(allowReset = 1; allowReset >= 0; --allowReset)
1330                 {
1331                         nextMap = GetNextMap();
1332                         if(nextMap != "")
1333                                 break;
1334
1335                         if(allowReset)
1336                         {
1337                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1338                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1339                                 if(autocvar_g_maplist_shuffle)
1340                                         ShuffleMaplist();
1341                                 localcmd("\nmenu_cmd sync\n");
1342                         }
1343                         else
1344                         {
1345                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1346                         }
1347                 }
1348                 Map_Goto();
1349         }
1350 }
1351
1352
1353 /*
1354 ============
1355 IntermissionThink
1356
1357 When the player presses attack or jump, change to the next level
1358 ============
1359 */
1360 .float autoscreenshot;
1361 void() MapVote_Start;
1362 void() MapVote_Think;
1363 float mapvote_initialized;
1364 void IntermissionThink()
1365 {
1366         FixIntermissionClient(self);
1367
1368         if( (autocvar_sv_autoscreenshot || self.cvar_cl_autoscreenshot)
1369                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1370         {
1371                 self.autoscreenshot = -1;
1372                 if(clienttype(self) == CLIENTTYPE_REAL)
1373                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1374                 return;
1375         }
1376
1377         if (time < intermission_exittime)
1378                 return;
1379
1380         if(!mapvote_initialized)
1381                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1382                         return;
1383
1384         MapVote_Start();
1385 }
1386
1387 /*
1388 ============
1389 FindIntermission
1390
1391 Returns the entity to view from
1392 ============
1393 */
1394 /*
1395 entity FindIntermission()
1396 {
1397         local   entity spot;
1398         local   float cyc;
1399
1400 // look for info_intermission first
1401         spot = find (world, classname, "info_intermission");
1402         if (spot)
1403         {       // pick a random one
1404                 cyc = random() * 4;
1405                 while (cyc > 1)
1406                 {
1407                         spot = find (spot, classname, "info_intermission");
1408                         if (!spot)
1409                                 spot = find (spot, classname, "info_intermission");
1410                         cyc = cyc - 1;
1411                 }
1412                 return spot;
1413         }
1414
1415 // then look for the start position
1416         spot = find (world, classname, "info_player_start");
1417         if (spot)
1418                 return spot;
1419
1420 // testinfo_player_start is only found in regioned levels
1421         spot = find (world, classname, "testplayerstart");
1422         if (spot)
1423                 return spot;
1424
1425 // then look for the start position
1426         spot = find (world, classname, "info_player_deathmatch");
1427         if (spot)
1428                 return spot;
1429
1430         //objerror ("FindIntermission: no spot");
1431         return world;
1432 }
1433 */
1434
1435 /*
1436 ===============================================================================
1437
1438 RULES
1439
1440 ===============================================================================
1441 */
1442
1443 void DumpStats(float final)
1444 {
1445         float file;
1446         string s;
1447         float to_console;
1448         float to_eventlog;
1449         float to_file;
1450         float i;
1451
1452         to_console = autocvar_sv_logscores_console;
1453         to_eventlog = autocvar_sv_eventlog;
1454         to_file = autocvar_sv_logscores_file;
1455
1456         if(!final)
1457         {
1458                 to_console = TRUE; // always print printstats replies
1459                 to_eventlog = FALSE; // but never print them to the event log
1460         }
1461
1462         if(to_eventlog)
1463                 if(autocvar_sv_eventlog_console)
1464                         to_console = FALSE; // otherwise we get the output twice
1465
1466         if(final)
1467                 s = ":scores:";
1468         else
1469                 s = ":status:";
1470         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1471
1472         if(to_console)
1473                 print(s, "\n");
1474         if(to_eventlog)
1475                 GameLogEcho(s);
1476         if(to_file)
1477         {
1478                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1479                 if(file == -1)
1480                         to_file = FALSE;
1481                 else
1482                         fputs(file, strcat(s, "\n"));
1483         }
1484
1485         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1486         if(to_console)
1487                 print(s, "\n");
1488         if(to_eventlog)
1489                 GameLogEcho(s);
1490         if(to_file)
1491                 fputs(file, strcat(s, "\n"));
1492
1493         FOR_EACH_CLIENT(other)
1494         {
1495                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1496                 {
1497                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1498                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1499                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1500                                 s = strcat(s, ftos(other.team), ":");
1501                         else
1502                                 s = strcat(s, "spectator:");
1503
1504                         if(to_console)
1505                                 print(s, other.netname, "\n");
1506                         if(to_eventlog)
1507                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1508                         if(to_file)
1509                                 fputs(file, strcat(s, other.netname, "\n"));
1510                 }
1511         }
1512
1513         if(teamplay)
1514         {
1515                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1516                 if(to_console)
1517                         print(s, "\n");
1518                 if(to_eventlog)
1519                         GameLogEcho(s);
1520                 if(to_file)
1521                         fputs(file, strcat(s, "\n"));
1522
1523                 for(i = 1; i < 16; ++i)
1524                 {
1525                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1526                         s = strcat(s, ":", ftos(i));
1527                         if(to_console)
1528                                 print(s, "\n");
1529                         if(to_eventlog)
1530                                 GameLogEcho(s);
1531                         if(to_file)
1532                                 fputs(file, strcat(s, "\n"));
1533                 }
1534         }
1535
1536         if(to_console)
1537                 print(":end\n");
1538         if(to_eventlog)
1539                 GameLogEcho(":end");
1540         if(to_file)
1541         {
1542                 fputs(file, ":end\n");
1543                 fclose(file);
1544         }
1545 }
1546
1547 void FixIntermissionClient(entity e)
1548 {
1549         string s;
1550         if(!e.autoscreenshot) // initial call
1551         {
1552                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1553                 e.health = -2342;
1554                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1555                 e.solid = SOLID_NOT;
1556                 e.movetype = MOVETYPE_NONE;
1557                 e.takedamage = DAMAGE_NO;
1558                 if(e.weaponentity)
1559                 {
1560                         e.weaponentity.effects = EF_NODRAW;
1561                         if (e.weaponentity.weaponentity)
1562                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1563                 }
1564                 if(clienttype(e) == CLIENTTYPE_REAL)
1565                 {
1566                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1567                         s = autocvar_sv_intermission_cdtrack;
1568                         if(s != "")
1569                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1570                         msg_entity = e;
1571                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1572                 }
1573         }
1574 }
1575
1576
1577 /*
1578 go to the next level for deathmatch
1579 only called if a time or frag limit has expired
1580 */
1581 void NextLevel()
1582 {
1583         gameover = TRUE;
1584
1585         intermission_running = 1;
1586
1587 // enforce a wait time before allowing changelevel
1588         if(player_count > 0)
1589                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1590         else
1591                 intermission_exittime = -1;
1592
1593         /*
1594         WriteByte (MSG_ALL, SVC_CDTRACK);
1595         WriteByte (MSG_ALL, 3);
1596         WriteByte (MSG_ALL, 3);
1597         // done in FixIntermission
1598         */
1599
1600         //pos = FindIntermission ();
1601
1602         VoteReset();
1603
1604         DumpStats(TRUE);
1605
1606         // send statistics
1607         entity e;
1608         PlayerStats_EndMatch(1);
1609         FOR_EACH_CLIENT(e)
1610                 PlayerStats_AddGlobalInfo(e);
1611         PlayerStats_Shutdown();
1612         WeaponStats_Shutdown();
1613
1614         if(autocvar_sv_eventlog)
1615                 GameLogEcho(":gameover");
1616
1617         GameLogClose();
1618
1619         FOR_EACH_PLAYER(other) {
1620                 FixIntermissionClient(other);
1621                 if(other.winning)
1622                         bprint(other.netname, " ^7wins.\n");
1623         }
1624
1625         if(autocvar_g_campaign)
1626                 CampaignPreIntermission();
1627
1628         localcmd("\nsv_hook_gameend\n");
1629 }
1630
1631 /*
1632 ============
1633 CheckRules_Player
1634
1635 Exit deathmatch games upon conditions
1636 ============
1637 */
1638 void CheckRules_Player()
1639 {
1640         if (gameover)   // someone else quit the game already
1641                 return;
1642
1643         if(self.deadflag == DEAD_NO)
1644                 self.play_time += frametime;
1645
1646         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1647         //   (div0: and that in CheckRules_World please)
1648 }
1649
1650 float checkrules_equality;
1651 float checkrules_suddendeathwarning;
1652 float checkrules_suddendeathend;
1653 float checkrules_overtimesadded; //how many overtimes have been already added
1654
1655 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1656 float WINNING_YES = 1; // winner found
1657 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1658 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1659
1660 float InitiateSuddenDeath()
1661 {
1662         // Check first whether normal overtimes could be added before initiating suddendeath mode
1663         // - for this timelimit_overtime needs to be >0 of course
1664         // - also check the winning condition calculated in the previous frame and only add normal overtime
1665         //   again, if at the point at which timelimit would be extended again, still no winner was found
1666         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1667         {
1668                 return 1; // need to call InitiateOvertime later
1669         }
1670         else
1671         {
1672                 if(!checkrules_suddendeathend)
1673                 {
1674                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1675                         if(g_race && !g_race_qualifying)
1676                                 race_StartCompleting();
1677                 }
1678                 return 0;
1679         }
1680 }
1681
1682 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1683 {
1684         ++checkrules_overtimesadded;
1685         //add one more overtime by simply extending the timelimit
1686         float tl;
1687         tl = autocvar_timelimit;
1688         tl += autocvar_timelimit_overtime;
1689         cvar_set("timelimit", ftos(tl));
1690         string minutesPlural;
1691         if (autocvar_timelimit_overtime == 1)
1692                 minutesPlural = " ^3minute";
1693         else
1694                 minutesPlural = " ^3minutes";
1695
1696         bcenterprint(
1697                 strcat(
1698                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1699                         ftos(autocvar_timelimit_overtime),
1700                         minutesPlural,
1701                         " to the game!"
1702                 )
1703         );
1704 }
1705
1706 float GetWinningCode(float fraglimitreached, float equality)
1707 {
1708         if(autocvar_g_campaign == 1)
1709                 if(fraglimitreached)
1710                         return WINNING_YES;
1711                 else
1712                         return WINNING_NO;
1713
1714         else
1715                 if(equality)
1716                         if(fraglimitreached)
1717                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1718                         else
1719                                 return WINNING_NEVER;
1720                 else
1721                         if(fraglimitreached)
1722                                 return WINNING_YES;
1723                         else
1724                                 return WINNING_NO;
1725 }
1726
1727 // set the .winning flag for exactly those players with a given field value
1728 void SetWinners(.float field, float value)
1729 {
1730         entity head;
1731         FOR_EACH_PLAYER(head)
1732                 head.winning = (head.field == value);
1733 }
1734
1735 // set the .winning flag for those players with a given field value
1736 void AddWinners(.float field, float value)
1737 {
1738         entity head;
1739         FOR_EACH_PLAYER(head)
1740                 if(head.field == value)
1741                         head.winning = 1;
1742 }
1743
1744 // clear the .winning flags
1745 void ClearWinners(void)
1746 {
1747         entity head;
1748         FOR_EACH_PLAYER(head)
1749                 head.winning = 0;
1750 }
1751
1752 // Onslaught winning condition:
1753 // game terminates if only one team has a working generator (or none)
1754 float WinningCondition_Onslaught()
1755 {
1756         entity head;
1757         float t1, t2, t3, t4;
1758
1759         WinningConditionHelper(); // set worldstatus
1760
1761         if(inWarmupStage)
1762                 return WINNING_NO;
1763
1764         // first check if the game has ended
1765         t1 = t2 = t3 = t4 = 0;
1766         head = find(world, classname, "onslaught_generator");
1767         while (head)
1768         {
1769                 if (head.health > 0)
1770                 {
1771                         if (head.team == COLOR_TEAM1) t1 = 1;
1772                         if (head.team == COLOR_TEAM2) t2 = 1;
1773                         if (head.team == COLOR_TEAM3) t3 = 1;
1774                         if (head.team == COLOR_TEAM4) t4 = 1;
1775                 }
1776                 head = find(head, classname, "onslaught_generator");
1777         }
1778         if (t1 + t2 + t3 + t4 < 2)
1779         {
1780                 // game over, only one team remains (or none)
1781                 ClearWinners();
1782                 if (t1) SetWinners(team, COLOR_TEAM1);
1783                 if (t2) SetWinners(team, COLOR_TEAM2);
1784                 if (t3) SetWinners(team, COLOR_TEAM3);
1785                 if (t4) SetWinners(team, COLOR_TEAM4);
1786                 dprint("Have a winner, ending game.\n");
1787                 return WINNING_YES;
1788         }
1789
1790         // Two or more teams remain
1791         return WINNING_NO;
1792 }
1793
1794 float LMS_NewPlayerLives()
1795 {
1796         float fl;
1797         fl = autocvar_fraglimit;
1798         if(fl == 0)
1799                 fl = 999;
1800
1801         // first player has left the game for dying too much? Nobody else can get in.
1802         if(lms_lowest_lives < 1)
1803                 return 0;
1804
1805         if(!autocvar_g_lms_join_anytime)
1806                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1807                         return 0;
1808
1809         return bound(1, lms_lowest_lives, fl);
1810 }
1811
1812 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1813 // they win. Otherwise the defending team wins once the timelimit passes.
1814 void assault_new_round();
1815 float WinningCondition_Assault()
1816 {
1817         float status;
1818
1819         WinningConditionHelper(); // set worldstatus
1820
1821         status = WINNING_NO;
1822         // as the timelimit has not yet passed just assume the defending team will win
1823         if(assault_attacker_team == COLOR_TEAM1)
1824         {
1825                 SetWinners(team, COLOR_TEAM2);
1826         }
1827         else
1828         {
1829                 SetWinners(team, COLOR_TEAM1);
1830         }
1831
1832         entity ent;
1833         ent = find(world, classname, "target_assault_roundend");
1834         if(ent)
1835         {
1836                 if(ent.winning) // round end has been triggered by attacking team
1837                 {
1838                         bprint("ASSAULT: round completed...\n");
1839                         SetWinners(team, assault_attacker_team);
1840
1841                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1842
1843                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1844                         {
1845                                 status = WINNING_YES;
1846                         }
1847                         else
1848                         {
1849                                 entity oldself;
1850                                 oldself = self;
1851                                 self = ent;
1852                                 assault_new_round();
1853                                 self = oldself;
1854                         }
1855                 }
1856         }
1857
1858         return status;
1859 }
1860
1861 // LMS winning condition: game terminates if and only if there's at most one
1862 // one player who's living lives. Top two scores being equal cancels the time
1863 // limit.
1864 float WinningCondition_LMS()
1865 {
1866         entity head, head2;
1867         float have_player;
1868         float have_players;
1869         float l;
1870
1871         have_player = FALSE;
1872         have_players = FALSE;
1873         l = LMS_NewPlayerLives();
1874
1875         head = find(world, classname, "player");
1876         if(head)
1877                 have_player = TRUE;
1878         head2 = find(head, classname, "player");
1879         if(head2)
1880                 have_players = TRUE;
1881
1882         if(have_player)
1883         {
1884                 // we have at least one player
1885                 if(have_players)
1886                 {
1887                         // two or more active players - continue with the game
1888                 }
1889                 else
1890                 {
1891                         // exactly one player?
1892
1893                         ClearWinners();
1894                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1895
1896                         if(l)
1897                         {
1898                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1899                                 return WINNING_NO;
1900                         }
1901                         else
1902                         {
1903                                 // a winner!
1904                                 // and assign him his first place
1905                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1906                                 return WINNING_YES;
1907                         }
1908                 }
1909         }
1910         else
1911         {
1912                 // nobody is playing at all...
1913                 if(l)
1914                 {
1915                         // wait for players...
1916                 }
1917                 else
1918                 {
1919                         // SNAFU (maybe a draw game?)
1920                         ClearWinners();
1921                         dprint("No players, ending game.\n");
1922                         return WINNING_YES;
1923                 }
1924         }
1925
1926         // When we get here, we have at least two players who are actually LIVING,
1927         // now check if the top two players have equal score.
1928         WinningConditionHelper();
1929
1930         ClearWinners();
1931         if(WinningConditionHelper_winner)
1932                 WinningConditionHelper_winner.winning = TRUE;
1933         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1934                 return WINNING_NEVER;
1935
1936         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1937         return WINNING_NO;
1938 }
1939
1940 void ShuffleMaplist()
1941 {
1942         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1943 }
1944
1945 float leaderfrags;
1946 float WinningCondition_Scores(float limit, float leadlimit)
1947 {
1948         float limitreached;
1949
1950         // TODO make everything use THIS winning condition (except LMS)
1951         WinningConditionHelper();
1952
1953         if(teamplay)
1954         {
1955                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1956                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1957                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1958                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1959         }
1960
1961         ClearWinners();
1962         if(WinningConditionHelper_winner)
1963                 WinningConditionHelper_winner.winning = 1;
1964         if(WinningConditionHelper_winnerteam >= 0)
1965                 SetWinners(team, WinningConditionHelper_winnerteam);
1966
1967         if(WinningConditionHelper_lowerisbetter)
1968         {
1969                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1970                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1971                 limit = -limit;
1972         }
1973
1974         if(WinningConditionHelper_zeroisworst)
1975                 leadlimit = 0; // not supported in this mode
1976
1977         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1978         // these modes always score in increments of 1, thus this makes sense
1979         {
1980                 if(leaderfrags != WinningConditionHelper_topscore)
1981                 {
1982                         leaderfrags = WinningConditionHelper_topscore;
1983
1984                         if (limit)
1985                         if (leaderfrags == limit - 1)
1986                                 Announce("1fragleft");
1987                         else if (leaderfrags == limit - 2)
1988                                 Announce("2fragsleft");
1989                         else if (leaderfrags == limit - 3)
1990                                 Announce("3fragsleft");
1991                 }
1992         }
1993
1994         limitreached = FALSE;
1995         if(limit)
1996                 if(WinningConditionHelper_topscore >= limit)
1997                         limitreached = TRUE;
1998         if(leadlimit)
1999         {
2000                 float leadlimitreached;
2001                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
2002                 if(autocvar_leadlimit_and_fraglimit)
2003                         limitreached = (limitreached && leadlimitreached);
2004                 else
2005                         limitreached = (limitreached || leadlimitreached);
2006         }
2007
2008         return GetWinningCode(
2009                 WinningConditionHelper_topscore && limitreached,
2010                 WinningConditionHelper_equality
2011         );
2012 }
2013
2014 float WinningCondition_Race(float fraglimit)
2015 {
2016         float wc;
2017         entity p;
2018         float n, c;
2019
2020         n = 0;
2021         c = 0;
2022         FOR_EACH_PLAYER(p)
2023         {
2024                 ++n;
2025                 if(p.race_completed)
2026                         ++c;
2027         }
2028         if(n && (n == c))
2029                 return WINNING_YES;
2030         wc = WinningCondition_Scores(fraglimit, 0);
2031
2032         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2033         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2034         // do NOT support equality when the laps are all raced!
2035                 return WINNING_STARTSUDDENDEATHOVERTIME;
2036         else
2037                 return WINNING_NEVER;
2038         return wc;
2039 }
2040
2041 float WinningCondition_QualifyingThenRace(float limit)
2042 {
2043         float wc;
2044         wc = WinningCondition_Scores(limit, 0);
2045
2046         // NEVER initiate overtime
2047         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2048         {
2049                 return WINNING_YES;
2050         }
2051
2052         return wc;
2053 }
2054
2055 float WinningCondition_RanOutOfSpawns()
2056 {
2057         entity head;
2058
2059         if(have_team_spawns <= 0)
2060                 return WINNING_NO;
2061
2062         if(autocvar_g_spawn_useallspawns <= 0)
2063                 return WINNING_NO;
2064
2065         if(!some_spawn_has_been_used)
2066                 return WINNING_NO;
2067
2068         team1_score = team2_score = team3_score = team4_score = 0;
2069
2070         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2071         {
2072                 if(head.team == COLOR_TEAM1)
2073                         team1_score = 1;
2074                 else if(head.team == COLOR_TEAM2)
2075                         team2_score = 1;
2076                 else if(head.team == COLOR_TEAM3)
2077                         team3_score = 1;
2078                 else if(head.team == COLOR_TEAM4)
2079                         team4_score = 1;
2080         }
2081
2082         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2083         {
2084                 if(head.team == COLOR_TEAM1)
2085                         team1_score = 1;
2086                 else if(head.team == COLOR_TEAM2)
2087                         team2_score = 1;
2088                 else if(head.team == COLOR_TEAM3)
2089                         team3_score = 1;
2090                 else if(head.team == COLOR_TEAM4)
2091                         team4_score = 1;
2092         }
2093
2094         ClearWinners();
2095         if(team1_score + team2_score + team3_score + team4_score == 0)
2096         {
2097                 checkrules_equality = TRUE;
2098                 return WINNING_YES;
2099         }
2100         else if(team1_score + team2_score + team3_score + team4_score == 1)
2101         {
2102                 float t, i;
2103                 if(team1_score) t = COLOR_TEAM1;
2104                 if(team2_score) t = COLOR_TEAM2;
2105                 if(team3_score) t = COLOR_TEAM3;
2106                 if(team4_score) t = COLOR_TEAM4;
2107                 CheckAllowedTeams(world);
2108                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2109                 {
2110                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2111                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2112                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2113                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2114                 }
2115
2116                 AddWinners(team, t);
2117                 return WINNING_YES;
2118         }
2119         else
2120                 return WINNING_NO;
2121 }
2122
2123 /*
2124 ============
2125 CheckRules_World
2126
2127 Exit deathmatch games upon conditions
2128 ============
2129 */
2130 void ReadyRestart();
2131 void CheckRules_World()
2132 {
2133         float timelimit;
2134         float fraglimit;
2135         float leadlimit;
2136
2137         VoteThink();
2138         MapVote_Think();
2139
2140         SetDefaultAlpha();
2141
2142         /*
2143         MapVote_Think should now do that part
2144         if (intermission_running)
2145                 if (time >= intermission_exittime + 60)
2146                 {
2147                         if(!DoNextMapOverride())
2148                                 GotoNextMap();
2149                         return;
2150                 }
2151         */
2152
2153         if (gameover)   // someone else quit the game already
2154         {
2155                 if(player_count == 0) // Nobody there? Then let's go to the next map
2156                         MapVote_Start();
2157                         // this will actually check the player count in the next frame
2158                         // again, but this shouldn't hurt
2159                 return;
2160         }
2161
2162         timelimit = autocvar_timelimit * 60;
2163         fraglimit = autocvar_fraglimit;
2164         leadlimit = autocvar_leadlimit;
2165
2166         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2167         {
2168                 if(timelimit > 0)
2169                         timelimit = 0; // timelimit is not made for warmup
2170                 if(fraglimit > 0)
2171                         fraglimit = 0; // no fraglimit for now
2172                 leadlimit = 0; // no leadlimit for now
2173         }
2174
2175         if(g_onslaught)
2176                 timelimit = 0; // ONS has its own overtime rule
2177
2178         if(timelimit > 0)
2179         {
2180                 timelimit += game_starttime;
2181         }
2182         else if (timelimit < 0)
2183         {
2184                 // endmatch
2185                 NextLevel();
2186                 return;
2187         }
2188
2189         float wantovertime;
2190         wantovertime = 0;
2191
2192         if(checkrules_suddendeathend)
2193         {
2194                 if(!checkrules_suddendeathwarning)
2195                 {
2196                         checkrules_suddendeathwarning = TRUE;
2197                         if(g_race && !g_race_qualifying)
2198                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2199                         else
2200                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2201                 }
2202         }
2203         else
2204         {
2205                 if (timelimit && time >= timelimit)
2206                 {
2207                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2208                         {
2209                                 float totalplayers;
2210                                 float playerswithlaps;
2211                                 float readyplayers;
2212                                 entity head;
2213                                 totalplayers = playerswithlaps = readyplayers = 0;
2214                                 FOR_EACH_PLAYER(head)
2215                                 {
2216                                         ++totalplayers;
2217                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2218                                                 ++playerswithlaps;
2219                                         if(head.ready)
2220                                                 ++readyplayers;
2221                                 }
2222
2223                                 // at least 2 of the players have completed a lap: start the RACE
2224                                 // otherwise, the players should end the qualifying on their own
2225                                 if(readyplayers || playerswithlaps >= 2)
2226                                 {
2227                                         checkrules_suddendeathend = 0;
2228                                         ReadyRestart(); // go to race
2229                                         return;
2230                                 }
2231                                 else
2232                                         wantovertime |= InitiateSuddenDeath();
2233                         }
2234                         else
2235                                 wantovertime |= InitiateSuddenDeath();
2236                 }
2237         }
2238
2239         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2240         {
2241                 NextLevel();
2242                 return;
2243         }
2244
2245         float checkrules_status;
2246         checkrules_status = WinningCondition_RanOutOfSpawns();
2247         if(checkrules_status == WINNING_YES)
2248         {
2249                 bprint("Hey! Someone ran out of spawns!\n");
2250         }
2251         else if(g_race && !g_race_qualifying && timelimit >= 0)
2252         {
2253                 checkrules_status = WinningCondition_Race(fraglimit);
2254                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2255         }
2256         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2257         {
2258                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2259                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2260         }
2261         else if(g_assault)
2262         {
2263                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2264         }
2265         else if(g_lms)
2266         {
2267                 checkrules_status = WinningCondition_LMS();
2268         }
2269         else if (g_onslaught)
2270         {
2271                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2272         }
2273         else
2274         {
2275                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2276                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2277         }
2278
2279         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2280         {
2281                 checkrules_status = WINNING_NEVER;
2282                 checkrules_overtimesadded = -1;
2283                 wantovertime |= InitiateSuddenDeath();
2284         }
2285
2286         if(checkrules_status == WINNING_NEVER)
2287                 // equality cases! Nobody wins if the overtime ends in a draw.
2288                 ClearWinners();
2289
2290         if(wantovertime)
2291         {
2292                 if(checkrules_status == WINNING_NEVER)
2293                         InitiateOvertime();
2294                 else
2295                         checkrules_status = WINNING_YES;
2296         }
2297
2298         if(checkrules_suddendeathend)
2299                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2300                         checkrules_status = WINNING_YES;
2301
2302         if(checkrules_status == WINNING_YES)
2303         {
2304                 //print("WINNING\n");
2305                 NextLevel();
2306         }
2307 }
2308
2309 float mapvote_nextthink;
2310 float mapvote_initialized;
2311 float mapvote_keeptwotime;
2312 float mapvote_timeout;
2313 string mapvote_message;
2314 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2315 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2316 float mapvote_screenshot_dirs_count;
2317
2318 float mapvote_count;
2319 float mapvote_count_real;
2320 string mapvote_maps[MAPVOTE_COUNT];
2321 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2322 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2323 float mapvote_maps_suggested[MAPVOTE_COUNT];
2324 string mapvote_suggestions[MAPVOTE_COUNT];
2325 float mapvote_suggestion_ptr;
2326 float mapvote_voters;
2327 float mapvote_selections[MAPVOTE_COUNT];
2328 float mapvote_run;
2329 float mapvote_detail;
2330 float mapvote_abstain;
2331 .float mapvote;
2332
2333 void MapVote_ClearAllVotes()
2334 {
2335         FOR_EACH_CLIENT(other)
2336                 other.mapvote = 0;
2337 }
2338
2339 string MapVote_Suggest(string m)
2340 {
2341         float i;
2342         if(m == "")
2343                 return "That's not how to use this command.";
2344         if(!autocvar_g_maplist_votable_suggestions)
2345                 return "Suggestions are not accepted on this server.";
2346         if(mapvote_initialized)
2347                 return "Can't suggest - voting is already in progress!";
2348         m = MapInfo_FixName(m);
2349         if(!m)
2350                 return "The map you suggested is not available on this server.";
2351         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2352                 if(Map_IsRecent(m))
2353                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2354
2355         if(!MapInfo_CheckMap(m))
2356                 return "The map you suggested does not support the current game mode.";
2357         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2358                 if(mapvote_suggestions[i] == m)
2359                         return "This map was already suggested.";
2360         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2361         {
2362                 i = floor(random() * mapvote_suggestion_ptr);
2363         }
2364         else
2365         {
2366                 i = mapvote_suggestion_ptr;
2367                 mapvote_suggestion_ptr += 1;
2368         }
2369         if(mapvote_suggestions[i] != "")
2370                 strunzone(mapvote_suggestions[i]);
2371         mapvote_suggestions[i] = strzone(m);
2372         if(autocvar_sv_eventlog)
2373                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2374         return strcat("Suggestion of ", m, " accepted.");
2375 }
2376
2377 void MapVote_AddVotable(string nextMap, float isSuggestion)
2378 {
2379         float j, i, o;
2380         string pakfile, mapfile;
2381
2382         if(nextMap == "")
2383                 return;
2384         for(j = 0; j < mapvote_count; ++j)
2385                 if(mapvote_maps[j] == nextMap)
2386                         return;
2387         // suggestions might be no longer valid/allowed after gametype switch!
2388         if(isSuggestion)
2389                 if(!MapInfo_CheckMap(nextMap))
2390                         return;
2391         mapvote_maps[mapvote_count] = strzone(nextMap);
2392         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2393
2394         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2395         {
2396                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2397                 pakfile = whichpack(strcat(mapfile, ".tga"));
2398                 if(pakfile == "")
2399                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2400                 if(pakfile == "")
2401                         pakfile = whichpack(strcat(mapfile, ".png"));
2402                 if(pakfile != "")
2403                         break;
2404         }
2405         if(i >= mapvote_screenshot_dirs_count)
2406                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2407         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2408                 pakfile = substring(pakfile, o, -1);
2409
2410         mapvote_maps_screenshot_dir[mapvote_count] = i;
2411         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2412
2413         mapvote_count += 1;
2414 }
2415
2416 void MapVote_Spawn();
2417 void MapVote_Init()
2418 {
2419         float i;
2420         float nmax, smax;
2421
2422         MapVote_ClearAllVotes();
2423
2424         mapvote_count = 0;
2425         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2426         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2427
2428         if(mapvote_abstain)
2429                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2430         else
2431                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2432         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2433
2434         // we need this for AddVotable, as that cycles through the screenshot dirs
2435         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2436         if(mapvote_screenshot_dirs_count == 0)
2437                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2438         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2439         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2440                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2441
2442         if(mapvote_suggestion_ptr)
2443                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2444                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2445
2446         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2447                 MapVote_AddVotable(GetNextMap(), FALSE);
2448
2449         if(mapvote_count == 0)
2450         {
2451                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2452                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2453                 if(autocvar_g_maplist_shuffle)
2454                         ShuffleMaplist();
2455                 localcmd("\nmenu_cmd sync\n");
2456                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2457                         MapVote_AddVotable(GetNextMap(), FALSE);
2458         }
2459
2460         mapvote_count_real = mapvote_count;
2461         if(mapvote_abstain)
2462                 MapVote_AddVotable("don't care", 0);
2463
2464         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2465
2466         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2467         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2468         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2469                 mapvote_keeptwotime = 0;
2470         mapvote_message = "Choose a map and press its key!";
2471
2472         MapVote_Spawn();
2473 }
2474
2475 void MapVote_SendPicture(float id)
2476 {
2477         msg_entity = self;
2478         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2479         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2480         WriteByte(MSG_ONE, id);
2481         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2482 }
2483
2484 float MapVote_GetMapMask()
2485 {
2486         float mask, i, power;
2487         mask = 0;
2488         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2489                 if(mapvote_maps[i] != "")
2490                         mask |= power;
2491         return mask;
2492 }
2493
2494 entity mapvote_ent;
2495 float MapVote_SendEntity(entity to, float sf)
2496 {
2497         float i;
2498
2499         if(sf & 1)
2500                 sf &~= 2; // if we send 1, we don't need to also send 2
2501
2502         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2503         WriteByte(MSG_ENTITY, sf);
2504
2505         if(sf & 1)
2506         {
2507                 // flag 1 == initialization
2508                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2509                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2510                 WriteString(MSG_ENTITY, "");
2511                 WriteByte(MSG_ENTITY, mapvote_count);
2512                 WriteByte(MSG_ENTITY, mapvote_abstain);
2513                 WriteByte(MSG_ENTITY, mapvote_detail);
2514                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2515                 if(mapvote_count <= 8)
2516                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2517                 else
2518                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2519                 for(i = 0; i < mapvote_count; ++i)
2520                         if(mapvote_maps[i] != "")
2521                         {
2522                                 if(mapvote_abstain && i == mapvote_count - 1)
2523                                 {
2524                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2525                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2526                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2527                                 }
2528                                 else
2529                                 {
2530                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2531                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2532                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2533                                 }
2534                         }
2535         }
2536
2537         if(sf & 2)
2538         {
2539                 // flag 2 == update of mask
2540                 if(mapvote_count <= 8)
2541                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2542                 else
2543                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2544         }
2545
2546         if(sf & 4)
2547         {
2548                 if(mapvote_detail)
2549                         for(i = 0; i < mapvote_count; ++i)
2550                                 if(mapvote_maps[i] != "")
2551                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2552
2553                 WriteByte(MSG_ENTITY, to.mapvote);
2554         }
2555
2556         return TRUE;
2557 }
2558
2559 void MapVote_Spawn()
2560 {
2561         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2562 }
2563
2564 void MapVote_TouchMask()
2565 {
2566         mapvote_ent.SendFlags |= 2;
2567 }
2568
2569 void MapVote_TouchVotes(entity voter)
2570 {
2571         mapvote_ent.SendFlags |= 4;
2572 }
2573
2574 float MapVote_Finished(float mappos)
2575 {
2576         string result;
2577         float i;
2578         float didntvote;
2579
2580         if(autocvar_sv_eventlog)
2581         {
2582                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2583                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2584                 didntvote = mapvote_voters;
2585                 for(i = 0; i < mapvote_count; ++i)
2586                         if(mapvote_maps[i] != "")
2587                         {
2588                                 didntvote -= mapvote_selections[i];
2589                                 if(i != mappos)
2590                                 {
2591                                         result = strcat(result, ":", mapvote_maps[i]);
2592                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2593                                 }
2594                         }
2595                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2596
2597                 GameLogEcho(result);
2598                 if(mapvote_maps_suggested[mappos])
2599                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2600         }
2601
2602         FOR_EACH_REALCLIENT(other)
2603                 FixClientCvars(other);
2604
2605         Map_Goto_SetStr(mapvote_maps[mappos]);
2606         Map_Goto();
2607         alreadychangedlevel = TRUE;
2608         return TRUE;
2609 }
2610 void MapVote_CheckRules_1()
2611 {
2612         float i;
2613
2614         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2615         {
2616                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2617                 mapvote_selections[i] = 0;
2618         }
2619
2620         mapvote_voters = 0;
2621         FOR_EACH_REALCLIENT(other)
2622         {
2623                 ++mapvote_voters;
2624                 if(other.mapvote)
2625                 {
2626                         i = other.mapvote - 1;
2627                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2628                         mapvote_selections[i] = mapvote_selections[i] + 1;
2629                 }
2630         }
2631 }
2632
2633 float MapVote_CheckRules_2()
2634 {
2635         float i;
2636         float firstPlace, secondPlace;
2637         float firstPlaceVotes, secondPlaceVotes;
2638         float mapvote_voters_real;
2639         string result;
2640
2641         if(mapvote_count_real == 1)
2642                 return MapVote_Finished(0);
2643
2644         mapvote_voters_real = mapvote_voters;
2645         if(mapvote_abstain)
2646                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2647
2648         RandomSelection_Init();
2649         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2650                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2651         firstPlace = RandomSelection_chosen_float;
2652         firstPlaceVotes = RandomSelection_best_priority;
2653         //dprint("First place: ", ftos(firstPlace), "\n");
2654         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2655
2656         RandomSelection_Init();
2657         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2658                 if(i != firstPlace)
2659                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2660         secondPlace = RandomSelection_chosen_float;
2661         secondPlaceVotes = RandomSelection_best_priority;
2662         //dprint("Second place: ", ftos(secondPlace), "\n");
2663         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2664
2665         if(firstPlace == -1)
2666                 error("No first place in map vote... WTF?");
2667
2668         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2669                 return MapVote_Finished(firstPlace);
2670
2671         if(mapvote_keeptwotime)
2672                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2673                 {
2674                         float didntvote;
2675                         MapVote_TouchMask();
2676                         mapvote_message = "Now decide between the TOP TWO!";
2677                         mapvote_keeptwotime = 0;
2678                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2679                         result = strcat(result, ":", ftos(firstPlaceVotes));
2680                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2681                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2682                         didntvote = mapvote_voters;
2683                         for(i = 0; i < mapvote_count; ++i)
2684                                 if(mapvote_maps[i] != "")
2685                                 {
2686                                         didntvote -= mapvote_selections[i];
2687                                         if(i != firstPlace)
2688                                                 if(i != secondPlace)
2689                                                 {
2690                                                         result = strcat(result, ":", mapvote_maps[i]);
2691                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2692                                                         if(i < mapvote_count_real)
2693                                                         {
2694                                                                 strunzone(mapvote_maps[i]);
2695                                                                 mapvote_maps[i] = "";
2696                                                                 strunzone(mapvote_maps_pakfile[i]);
2697                                                                 mapvote_maps_pakfile[i] = "";
2698                                                         }
2699                                                 }
2700                                 }
2701                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2702                         if(autocvar_sv_eventlog)
2703                                 GameLogEcho(result);
2704                 }
2705
2706         return FALSE;
2707 }
2708 void MapVote_Tick()
2709 {
2710         float keeptwo;
2711         float totalvotes;
2712
2713         keeptwo = mapvote_keeptwotime;
2714         MapVote_CheckRules_1(); // count
2715         if(MapVote_CheckRules_2()) // decide
2716                 return;
2717
2718         totalvotes = 0;
2719         FOR_EACH_REALCLIENT(other)
2720         {
2721                 // hide scoreboard again
2722                 if(other.health != 2342)
2723                 {
2724                         other.health = 2342;
2725                         other.impulse = 0;
2726                         if(clienttype(other) == CLIENTTYPE_REAL)
2727                         {
2728                                 msg_entity = other;
2729                                 WriteByte(MSG_ONE, SVC_FINALE);
2730                                 WriteString(MSG_ONE, "");
2731                         }
2732                 }
2733
2734                 // clear possibly invalid votes
2735                 if(mapvote_maps[other.mapvote - 1] == "")
2736                         other.mapvote = 0;
2737                 // use impulses as new vote
2738                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2739                         if(mapvote_maps[other.impulse - 1] != "")
2740                         {
2741                                 other.mapvote = other.impulse;
2742                                 MapVote_TouchVotes(other);
2743                         }
2744                 other.impulse = 0;
2745
2746                 if(other.mapvote)
2747                         ++totalvotes;
2748         }
2749
2750         MapVote_CheckRules_1(); // just count
2751 }
2752 void MapVote_Start()
2753 {
2754         if(mapvote_run)
2755                 return;
2756
2757         // wait for stats to be sent first
2758         if(!playerstats_waitforme)
2759                 return;
2760
2761         MapInfo_Enumerate();
2762         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2763                 mapvote_run = TRUE;
2764 }
2765 void MapVote_Think()
2766 {
2767         if(!mapvote_run)
2768                 return;
2769
2770         if(alreadychangedlevel)
2771                 return;
2772
2773         if(time < mapvote_nextthink)
2774                 return;
2775         //dprint("tick\n");
2776
2777         mapvote_nextthink = time + 0.5;
2778
2779         if(!mapvote_initialized)
2780         {
2781                 if(autocvar_rescan_pending == 1)
2782                 {
2783                         cvar_set("rescan_pending", "2");
2784                         localcmd("fs_rescan\nrescan_pending 3\n");
2785                         return;
2786                 }
2787                 else if(autocvar_rescan_pending == 2)
2788                 {
2789                         return;
2790                 }
2791                 else if(autocvar_rescan_pending == 3)
2792                 {
2793                         // now build missing mapinfo files
2794                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2795                                 return;
2796
2797                         // we're done, start the timer
2798                         cvar_set("rescan_pending", "0");
2799                 }
2800
2801                 mapvote_initialized = TRUE;
2802                 if(DoNextMapOverride())
2803                         return;
2804                 if(!autocvar_g_maplist_votable || player_count <= 0)
2805                 {
2806                         GotoNextMap();
2807                         return;
2808                 }
2809                 MapVote_Init();
2810         }
2811
2812         MapVote_Tick();
2813 }
2814
2815 string GotoMap(string m)
2816 {
2817         if(!MapInfo_CheckMap(m))
2818                 return "The map you chose is not available on this server.";
2819         cvar_set("nextmap", m);
2820         cvar_set("timelimit", "-1");
2821         if(mapvote_initialized || alreadychangedlevel)
2822         {
2823                 if(DoNextMapOverride())
2824                         return "Map switch initiated.";
2825                 else
2826                         return "Hm... no. For some reason I like THIS map more.";
2827         }
2828         else
2829                 return "Map switch will happen after scoreboard.";
2830 }
2831
2832
2833 void EndFrame()
2834 {
2835         float altime;
2836         FOR_EACH_REALCLIENT(self)
2837         {
2838                 if(self.classname == "spectator")
2839                 {
2840                         if(self.enemy.typehitsound)
2841                                 self.typehit_time = time;
2842                         else if(self.enemy.hitsound)
2843                                 self.hit_time = time;
2844                 }
2845                 else
2846                 {
2847                         if(self.typehitsound)
2848                                 self.typehit_time = time;
2849                         else if(self.hitsound)
2850                                 self.hit_time = time;
2851                 }
2852         }
2853         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2854         // add 1 frametime because after this, engine SV_Physics
2855         // increases time by a frametime and then networks the frame
2856         // add another frametime because client shows everything with
2857         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2858         // needed!
2859         FOR_EACH_CLIENT(self)
2860         {
2861                 self.hitsound = FALSE;
2862                 self.typehitsound = FALSE;
2863                 antilag_record(self, altime);
2864         }
2865 }
2866
2867
2868 /*
2869  * RedirectionThink:
2870  * returns TRUE if redirecting
2871  */
2872 float redirection_timeout;
2873 float redirection_nextthink;
2874 float RedirectionThink()
2875 {
2876         float clients_found;
2877
2878         if(redirection_target == "")
2879                 return FALSE;
2880
2881         if(!redirection_timeout)
2882         {
2883                 cvar_set("sv_public", "-2");
2884                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2885                 if(redirection_target == "self")
2886                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2887                 else
2888                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2889         }
2890
2891         if(time < redirection_nextthink)
2892                 return TRUE;
2893
2894         redirection_nextthink = time + 1;
2895
2896         clients_found = 0;
2897         FOR_EACH_REALCLIENT(self)
2898         {
2899                 print("Redirecting: sending connect command to ", self.netname, "\n");
2900                 if(redirection_target == "self")
2901                         stuffcmd(self, "\ndisconnect; reconnect\n");
2902                 else
2903                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2904                 ++clients_found;
2905         }
2906
2907         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2908
2909         if(time > redirection_timeout || clients_found == 0)
2910                 localcmd("\nwait; wait; wait; quit\n");
2911
2912         return TRUE;
2913 }
2914
2915 void TargetMusic_RestoreGame();
2916 void RestoreGame()
2917 {
2918         // Loaded from a save game
2919         // some things then break, so let's work around them...
2920
2921         // Progs DB (capture records)
2922         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2923
2924         // Mapinfo
2925         MapInfo_Shutdown();
2926         MapInfo_Enumerate();
2927         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2928         WeaponStats_Init();
2929
2930         TargetMusic_RestoreGame();
2931 }
2932
2933 void SV_Shutdown()
2934 {
2935         entity e;
2936
2937         if(gameover > 1) // shutting down already?
2938                 return;
2939
2940         gameover = 2; // 2 = server shutting down
2941
2942         if(world_initialized > 0)
2943         {
2944                 world_initialized = 0;
2945                 print("Saving persistent data...\n");
2946                 Ban_SaveBans();
2947
2948                 PlayerStats_EndMatch(0);
2949                 FOR_EACH_CLIENT(e)
2950                         PlayerStats_AddGlobalInfo(e);
2951                 PlayerStats_Shutdown();
2952
2953                 if(!cheatcount_total)
2954                 {
2955                         if(autocvar_sv_db_saveasdump)
2956                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2957                         else
2958                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2959                 }
2960                 if(autocvar_developer)
2961                 {
2962                         if(autocvar_sv_db_saveasdump)
2963                                 db_dump(TemporaryDB, "server-temp.db");
2964                         else
2965                                 db_save(TemporaryDB, "server-temp.db");
2966                 }
2967                 CheatShutdown(); // must be after cheatcount check
2968                 db_close(ServerProgsDB);
2969                 db_close(TemporaryDB);
2970                 print("done!\n");
2971                 // tell the bot system the game is ending now
2972                 bot_endgame();
2973
2974                 WeaponStats_Shutdown();
2975                 MapInfo_Shutdown();
2976         }
2977         else if(world_initialized == 0)
2978         {
2979                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2980         }
2981 }