qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetGametype();
  59 void GotoNextMap(float reinit);
  60 void ShuffleMaplist();
  61 float(float reinit) DoNextMapOverride;
  62
  63 void SetDefaultAlpha()
  64 {
  65         if(autocvar_g_running_guns)
  66         {
  67                 default_player_alpha = -1;
  68                 default_weapon_alpha = +1;
  69         }
  70         else if(g_cloaked)
  71         {
  72                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  73                 default_weapon_alpha = default_player_alpha;
  74         }
  75         else
  76         {
  77                 default_player_alpha = autocvar_g_player_alpha;
  78                 if(default_player_alpha == 0)
  79                         default_player_alpha = 1;
  80                 default_weapon_alpha = default_player_alpha;
  81         }
  82 }
  83
  84 void GotoFirstMap()
  85 {
  86         float n;
  87         if(autocvar__sv_init)
  88         {
  89                 // cvar_set("_sv_init", "0");
  90                 // we do NOT set this to 0 any more, so someone "accidentally" changing
  91                 // to this "init" map on a dedicated server will cause no permanent
  92                 // harm
  93                 if(autocvar_g_maplist_shuffle)
  94                         ShuffleMaplist();
  95                 n = tokenizebyseparator(autocvar_g_maplist, " ");
  96                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
  97
  98                 MapInfo_Enumerate();
  99                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 100
 101                 if(!DoNextMapOverride(1))
 102                         GotoNextMap(1);
 103
 104                 return;
 105         }
 106
 107         if(time < 5)
 108         {
 109                 self.nextthink = time;
 110         }
 111         else
 112         {
 113                 self.nextthink = time + 1;
 114                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 115         }
 116 }
 117
 118 void cvar_changes_init()
 119 {
 120         float h;
 121         string k, v, d;
 122         float n, i, adding, pureadding;
 123
 124         if(cvar_changes)
 125                 strunzone(cvar_changes);
 126         cvar_changes = string_null;
 127         if(cvar_purechanges)
 128                 strunzone(cvar_purechanges);
 129         cvar_purechanges = string_null;
 130         cvar_purechanges_count = 0;
 131
 132         h = buf_create();
 133         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 134         n = buf_getsize(h);
 135
 136         adding = TRUE;
 137         pureadding = TRUE;
 138
 139         for(i = 0; i < n; ++i)
 140         {
 141                 k = bufstr_get(h, i);
 142
 143 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 144 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 145 #define BADCVAR(p) if(k == p) continue
 146
 147                 // general excludes and namespaces for server admin used cvars
 148                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 149
 150                 // internal
 151                 BADPREFIX("csqc_");
 152                 BADPREFIX("cvar_check_");
 153                 BADCVAR("gamecfg");
 154                 BADCVAR("g_configversion");
 155                 BADCVAR("g_maplist_index");
 156                 BADCVAR("halflifebsp");
 157                 BADPREFIX("sv_world");
 158
 159                 // client
 160                 BADPREFIX("chase_");
 161                 BADPREFIX("cl_");
 162                 BADPREFIX("con_");
 163                 BADPREFIX("scoreboard_");
 164                 BADPREFIX("g_campaign");
 165                 BADPREFIX("g_waypointsprite_");
 166                 BADPREFIX("gl_");
 167                 BADPREFIX("joy");
 168                 BADPREFIX("hud_");
 169                 BADPREFIX("m_");
 170                 BADPREFIX("menu_");
 171                 BADPREFIX("net_slist_");
 172                 BADPREFIX("r_");
 173                 BADPREFIX("sbar_");
 174                 BADPREFIX("scr_");
 175                 BADPREFIX("snd_");
 176                 BADPREFIX("show");
 177                 BADPREFIX("sensitivity");
 178                 BADPREFIX("userbind");
 179                 BADPREFIX("v_");
 180                 BADPREFIX("vid_");
 181                 BADPREFIX("crosshair");
 182                 BADCVAR("mod_q3bsp_lightmapmergepower");
 183                 BADCVAR("mod_q3bsp_nolightmaps");
 184                 BADCVAR("fov");
 185                 BADCVAR("mastervolume");
 186                 BADCVAR("volume");
 187                 BADCVAR("bgmvolume");
 188
 189                 // private
 190                 BADCVAR("developer");
 191                 BADCVAR("log_dest_udp");
 192                 BADCVAR("net_address");
 193                 BADCVAR("net_address_ipv6");
 194                 BADCVAR("port");
 195                 BADCVAR("savedgamecfg");
 196                 BADCVAR("serverconfig");
 197                 BADCVAR("sv_autoscreenshot");
 198                 BADCVAR("sv_heartbeatperiod");
 199                 BADCVAR("sv_vote_master_password");
 200                 BADCVAR("sys_colortranslation");
 201                 BADCVAR("sys_specialcharactertranslation");
 202                 BADCVAR("timeformat");
 203                 BADCVAR("timestamps");
 204                 BADPREFIX("developer_");
 205                 BADPREFIX("g_ban_");
 206                 BADPREFIX("g_banned_list");
 207                 BADPREFIX("g_chat_flood_");
 208                 BADPREFIX("g_ghost_items");
 209                 BADPREFIX("g_playerstats_");
 210                 BADPREFIX("g_respawn_ghosts");
 211                 BADPREFIX("g_voice_flood_");
 212                 BADPREFIX("log_file");
 213                 BADPREFIX("rcon_");
 214                 BADPREFIX("sv_allowdownloads");
 215                 BADPREFIX("sv_autodemo");
 216                 BADPREFIX("sv_curl_");
 217                 BADPREFIX("sv_eventlog");
 218                 BADPREFIX("sv_logscores_");
 219                 BADPREFIX("sv_master");
 220                 BADPREFIX("sv_weaponstats_");
 221                 BADPREFIX("sv_waypointsprite_");
 222                 BADCVAR("rescan_pending");
 223
 224                 // these can contain player IDs, so better hide
 225                 BADPREFIX("g_forced_team_");
 226
 227                 // mapinfo
 228                 BADCVAR("fraglimit");
 229                 BADCVAR("g_assault");
 230                 BADCVAR("g_ca");
 231                 BADCVAR("g_ca_teams");
 232                 BADCVAR("g_ctf");
 233                 BADCVAR("g_cts");
 234                 BADCVAR("g_dm");
 235                 BADCVAR("g_domination");
 236                 BADCVAR("g_domination_default_teams");
 237                 BADCVAR("g_freezetag");
 238                 BADCVAR("g_freezetag_teams");
 239                 BADCVAR("g_keepaway");
 240                 BADCVAR("g_keyhunt");
 241                 BADCVAR("g_keyhunt_teams");
 242                 BADCVAR("g_lms");
 243                 BADCVAR("g_nexball");
 244                 BADCVAR("g_onslaught");
 245                 BADCVAR("g_race");
 246                 BADCVAR("g_race_qualifying_timelimit");
 247                 BADCVAR("g_tdm");
 248                 BADCVAR("g_tdm_teams");
 249                 BADCVAR("leadlimit");
 250                 BADCVAR("nextmap");
 251                 BADCVAR("teamplay");
 252                 BADCVAR("timelimit");
 253
 254                 // long
 255                 BADCVAR("hostname");
 256                 BADCVAR("g_maplist");
 257                 BADCVAR("g_maplist_mostrecent");
 258                 BADCVAR("sv_motd");
 259
 260                 v = cvar_string(k);
 261                 d = cvar_defstring(k);
 262                 if(v == d)
 263                         continue;
 264
 265                 if(adding)
 266                 {
 267                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 268                         if(strlen(cvar_changes) > 16384)
 269                         {
 270                                 cvar_changes = "// too many settings have been changed to show them here\n";
 271                                 adding = 0;
 272                         }
 273                 }
 274
 275                 // now check if the changes are actually gameplay relevant
 276
 277                 // does nothing visible
 278                 BADCVAR("captureleadlimit_override");
 279                 BADCVAR("g_balance_kill_delay");
 280                 BADCVAR("g_ca_point_leadlimit");
 281                 BADCVAR("g_ctf_captimerecord_always");
 282                 BADCVAR("g_ctf_flag_glowtrails");
 283                 BADCVAR("g_ctf_flag_pickup_verbosename");
 284                 BADCVAR("g_domination_point_leadlimit");
 285                 BADCVAR("g_forced_respawn");
 286                 BADCVAR("g_keyhunt_point_leadlimit");
 287                 BADPREFIX("g_mod_");
 288                 BADCVAR("g_nexball_goalleadlimit");
 289                 BADCVAR("leadlimit_and_fraglimit");
 290                 BADCVAR("leadlimit_override");
 291                 BADCVAR("pausable");
 292                 BADCVAR("sv_allow_fullbright");
 293                 BADCVAR("sv_checkforpacketsduringsleep");
 294                 BADCVAR("sv_fraginfo");
 295                 BADCVAR("sv_timeout");
 296                 BADPREFIX("sv_timeout_");
 297                 BADPREFIX("crypto_");
 298                 BADPREFIX("g_chat_");
 299                 BADPREFIX("g_ctf_captimerecord_");
 300                 BADPREFIX("g_maplist_votable_");
 301                 BADPREFIX("net_");
 302                 BADPREFIX("prvm_");
 303                 BADPREFIX("skill_");
 304                 BADPREFIX("sv_cullentities_");
 305                 BADPREFIX("sv_fraginfo_");
 306                 BADPREFIX("sv_maxidle_");
 307                 BADPREFIX("sv_vote_");
 308                 BADPREFIX("timelimit_");
 309                 BADCVAR("gameversion");
 310                 BADPREFIX("gameversion_");
 311                 BADCVAR("sv_namechangetimer");
 312
 313                 // allowed changes to server admins (please sync this to server.cfg)
 314                 // vi commands:
 315                 //   :/"impure"/,$d
 316                 //   :g!,^\/\/[^ /],d
 317                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 318                 //   :%!sort
 319                 // yes, this does contain some redundant stuff, don't really care
 320                 BADCVAR("bot_config_file");
 321                 BADCVAR("bot_number");
 322                 BADCVAR("bot_prefix");
 323                 BADCVAR("bot_suffix");
 324                 BADCVAR("capturelimit_override");
 325                 BADCVAR("fraglimit_override");
 326                 BADCVAR("gametype");
 327                 BADCVAR("g_antilag");
 328                 BADCVAR("g_balance_teams");
 329                 BADCVAR("g_balance_teams_prevent_imbalance");
 330                 BADCVAR("g_balance_teams_scorefactor");
 331                 BADCVAR("g_ban_sync_trusted_servers");
 332                 BADCVAR("g_ban_sync_uri");
 333                 BADCVAR("g_ca_teams_override");
 334                 BADCVAR("g_ctf_ignore_frags");
 335                 BADCVAR("g_domination_point_limit");
 336                 BADCVAR("g_freezetag_teams_override");
 337                 BADCVAR("g_friendlyfire");
 338                 BADCVAR("g_fullbrightitems");
 339                 BADCVAR("g_fullbrightplayers");
 340                 BADCVAR("g_keyhunt_point_limit");
 341                 BADCVAR("g_keyhunt_teams_override");
 342                 BADCVAR("g_lms_lives_override");
 343                 BADCVAR("g_maplist");
 344                 BADCVAR("g_maplist_check_waypoints");
 345                 BADCVAR("g_maplist_mostrecent_count");
 346                 BADCVAR("g_maplist_shuffle");
 347                 BADCVAR("g_maplist_votable");
 348                 BADCVAR("g_maplist_votable_abstain");
 349                 BADCVAR("g_maplist_votable_nodetail");
 350                 BADCVAR("g_maplist_votable_suggestions");
 351                 BADCVAR("g_maxplayers");
 352                 BADCVAR("g_mirrordamage");
 353                 BADCVAR("g_nexball_goallimit");
 354                 BADCVAR("g_powerups");
 355                 BADCVAR("g_start_delay");
 356                 BADCVAR("g_warmup");
 357                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 358                 BADCVAR("hostname");
 359                 BADCVAR("log_file");
 360                 BADCVAR("maxplayers");
 361                 BADCVAR("minplayers");
 362                 BADCVAR("net_address");
 363                 BADCVAR("port");
 364                 BADCVAR("rcon_password");
 365                 BADCVAR("rcon_restricted_commands");
 366                 BADCVAR("rcon_restricted_password");
 367                 BADCVAR("skill");
 368                 BADCVAR("sv_adminnick");
 369                 BADCVAR("sv_autoscreenshot");
 370                 BADCVAR("sv_autotaunt");
 371                 BADCVAR("sv_curl_defaulturl");
 372                 BADCVAR("sv_defaultcharacter");
 373                 BADCVAR("sv_defaultplayercolors");
 374                 BADCVAR("sv_defaultplayermodel");
 375                 BADCVAR("sv_defaultplayerskin");
 376                 BADCVAR("sv_maxidle");
 377                 BADCVAR("sv_maxrate");
 378                 BADCVAR("sv_motd");
 379                 BADCVAR("sv_public");
 380                 BADCVAR("sv_ready_restart");
 381                 BADCVAR("sv_status_privacy");
 382                 BADCVAR("sv_taunt");
 383                 BADCVAR("sv_vote_call");
 384                 BADCVAR("sv_vote_commands");
 385                 BADCVAR("sv_vote_majority_factor");
 386                 BADCVAR("sv_vote_master");
 387                 BADCVAR("sv_vote_master_commands");
 388                 BADCVAR("sv_vote_master_password");
 389                 BADCVAR("sv_vote_simple_majority_factor");
 390                 BADCVAR("teamplay_mode");
 391                 BADCVAR("timelimit_override");
 392                 BADCVAR("g_spawnshieldtime");
 393                 BADPREFIX("g_warmup_");
 394                 BADPREFIX("sv_ready_restart_");
 395
 396                 // mutators that announce themselves properly to the server browser
 397                 BADCVAR("g_instagib");
 398                 BADCVAR("g_new_toys");
 399                 BADCVAR("g_nix");
 400                 BADCVAR("g_grappling_hook");
 401                 BADCVAR("g_jetpack");
 402
 403 #undef BADPREFIX
 404 #undef BADCVAR
 405
 406                 if(pureadding)
 407                 {
 408                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 409                         if(strlen(cvar_purechanges) > 16384)
 410                         {
 411                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 412                                 pureadding = 0;
 413                         }
 414                 }
 415                 ++cvar_purechanges_count;
 416                 // WARNING: this variable is used for the server list
 417                 // NEVER dare to skip this code!
 418                 // Hacks to intentionally appearing as "pure server" even though you DO have
 419                 // modified settings may be punished by removal from the server list.
 420                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 421                 // though.
 422         }
 423         buf_del(h);
 424         if(cvar_changes == "")
 425                 cvar_changes = "// this server runs at default server settings\n";
 426         else
 427                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 428         cvar_changes = strzone(cvar_changes);
 429         if(cvar_purechanges == "")
 430                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 431         else
 432                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 433         cvar_purechanges = strzone(cvar_purechanges);
 434 }
 435
 436 void detect_maptype()
 437 {
 438 #if 0
 439         vector o, v;
 440         float i;
 441
 442         for(;;)
 443         {
 444                 o = world.mins;
 445                 o_x += random() * (world.maxs_x - world.mins_x);
 446                 o_y += random() * (world.maxs_y - world.mins_y);
 447                 o_z += random() * (world.maxs_z - world.mins_z);
 448
 449                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 450                 if(trace_fraction == 1)
 451                         continue;
 452
 453                 v = trace_endpos;
 454
 455                 for(i = 0; i < 64; i += 4)
 456                 {
 457                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 458         if(trace_fraction == 1)
 459                 continue;
 460                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 461                 }
 462
 463                 break;
 464         }
 465 #endif
 466 }
 467
 468 entity randomseed;
 469 float RandomSeed_Send(entity to, float sf)
 470 {
 471         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 472         WriteShort(MSG_ENTITY, self.cnt);
 473         return TRUE;
 474 }
 475 void RandomSeed_Think()
 476 {
 477         self.cnt = bound(0, floor(random() * 65536), 65535);
 478         self.nextthink = time + 5;
 479
 480         self.SendFlags |= 1;
 481 }
 482 void RandomSeed_Spawn()
 483 {
 484         randomseed = spawn();
 485         randomseed.think = RandomSeed_Think;
 486         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 487
 488         entity oldself;
 489         oldself = self;
 490         self = randomseed;
 491         self.think(); // sets random seed and nextthink
 492         self = oldself;
 493 }
 494
 495 void spawnfunc___init_dedicated_server(void)
 496 {
 497         // handler for _init/_init map (only for dedicated server initialization)
 498
 499         world_initialized = -1; // don't complain
 500         cvar = cvar_normal;
 501         cvar_string = cvar_string_normal;
 502         cvar_set = cvar_set_normal;
 503
 504         remove = remove_unsafely;
 505
 506         entity e;
 507         e = spawn();
 508         e.think = GotoFirstMap;
 509         e.nextthink = time; // this is usually 1 at this point
 510
 511         e = spawn();
 512         e.classname = "info_player_deathmatch"; // safeguard against player joining
 513
 514         self.classname = "worldspawn"; // safeguard against various stuff ;)
 515
 516         // needs to be done so early because of the constants they create
 517         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 518         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 519         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 520         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 521         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 522         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 523
 524         MapInfo_Enumerate();
 525         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 526 }
 527
 528 void Map_MarkAsRecent(string m);
 529 float world_already_spawned;
 530 void Nagger_Init();
 531 void ClientInit_Spawn();
 532 void WeaponStats_Init();
 533 void WeaponStats_Shutdown();
 534 void spawnfunc_worldspawn (void)
 535 {
 536         float fd, l, i, j, n;
 537         string s;
 538
 539         cvar = cvar_normal;
 540         cvar_string = cvar_string_normal;
 541         cvar_set = cvar_set_normal;
 542
 543         if(world_already_spawned)
 544                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 545         world_already_spawned = TRUE;
 546
 547         remove = remove_safely; // during spawning, watch what you remove!
 548
 549         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 550
 551         compressShortVector_init();
 552
 553         entity head;
 554         head = nextent(world);
 555         maxclients = 0;
 556         while(head)
 557         {
 558                 ++maxclients;
 559                 head = nextent(head);
 560         }
 561
 562         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 563
 564         // needs to be done so early because of the constants they create
 565         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 566         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 567         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 568         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 569         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 570         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 571
 572         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 573
 574         TemporaryDB = db_create();
 575
 576         // 0 normal
 577         lightstyle(0, "m");
 578
 579         // 1 FLICKER (first variety)
 580         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 581
 582         // 2 SLOW STRONG PULSE
 583         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 584
 585         // 3 CANDLE (first variety)
 586         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 587
 588         // 4 FAST STROBE
 589         lightstyle(4, "mamamamamama");
 590
 591         // 5 GENTLE PULSE 1
 592         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 593
 594         // 6 FLICKER (second variety)
 595         lightstyle(6, "nmonqnmomnmomomno");
 596
 597         // 7 CANDLE (second variety)
 598         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 599
 600         // 8 CANDLE (third variety)
 601         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 602
 603         // 9 SLOW STROBE (fourth variety)
 604         lightstyle(9, "aaaaaaaazzzzzzzz");
 605
 606         // 10 FLUORESCENT FLICKER
 607         lightstyle(10, "mmamammmmammamamaaamammma");
 608
 609         // 11 SLOW PULSE NOT FADE TO BLACK
 610         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 611
 612         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 613
 614         // 63 testing
 615         lightstyle(63, "a");
 616
 617         if(autocvar_g_campaign)
 618                 CampaignPreInit();
 619
 620         Map_MarkAsRecent(mapname);
 621
 622         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 623
 624         precache_model ("null"); // we need this one before InitGameplayMode
 625         InitGameplayMode();
 626         readlevelcvars();
 627         GrappleHookInit();
 628
 629         player_count = 0;
 630         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 631         if(bot_waypoints_for_items == 1)
 632                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 633                         bot_waypoints_for_items = 0;
 634
 635         precache();
 636
 637         WaypointSprite_Init();
 638
 639         GameLogInit(); // prepare everything
 640         // NOTE for matchid:
 641         // changing the logic generating it is okay. But:
 642         // it HAS to stay <= 64 chars
 643         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 644         if(autocvar_sv_eventlog)
 645         {
 646                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 647                 matchid = strzone(s);
 648
 649                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 650                 s = ":gameinfo:mutators:LIST";
 651
 652                 ret_string = s;
 653                 MUTATOR_CALLHOOK(BuildMutatorsString);
 654                 s = ret_string;
 655
 656                 // simple, probably not good in the mutator system
 657                 if(autocvar_g_grappling_hook)
 658                         s = strcat(s, ":grappling_hook");
 659
 660                 // initialiation stuff, not good in the mutator system
 661                 if(!autocvar_g_use_ammunition)
 662                         s = strcat(s, ":no_use_ammunition");
 663
 664                 // initialiation stuff, not good in the mutator system
 665                 if(autocvar_g_pickup_items == 0)
 666                         s = strcat(s, ":no_pickup_items");
 667                 if(autocvar_g_pickup_items > 0)
 668                         s = strcat(s, ":pickup_items");
 669
 670                 // initialiation stuff, not good in the mutator system
 671                 if(autocvar_g_weaponarena != "0")
 672                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 673
 674                 // TODO to mutator system
 675                 if(autocvar_g_norecoil)
 676                         s = strcat(s, ":norecoil");
 677
 678                 // TODO to mutator system
 679                 if(autocvar_g_powerups == 0)
 680                         s = strcat(s, ":no_powerups");
 681                 if(autocvar_g_powerups > 0)
 682                         s = strcat(s, ":powerups");
 683
 684                 GameLogEcho(s);
 685                 GameLogEcho(":gameinfo:end");
 686         }
 687         else
 688                 matchid = strzone(ftos(random()));
 689
 690         cvar_set("nextmap", "");
 691
 692         SetDefaultAlpha();
 693
 694         if(autocvar_g_campaign)
 695                 CampaignPostInit();
 696
 697         Ban_LoadBans();
 698
 699         MapInfo_Enumerate();
 700         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 701
 702         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 703         {
 704                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 705                 if(fd != -1)
 706                 {
 707                         while((s = fgets(fd)))
 708                         {
 709                                 l = tokenize_console(s);
 710                                 if(l < 2)
 711                                         continue;
 712                                 if(argv(0) == "cd")
 713                                 {
 714                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 715                                         print("  cdtrack ", argv(2), "\n");
 716                                 }
 717                                 else if(argv(0) == "fog")
 718                                 {
 719                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 720                                         print("  \"fog\" \"", s, "\"\n");
 721                                 }
 722                                 else if(argv(0) == "set")
 723                                 {
 724                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 725                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 726                                 }
 727                                 else if(argv(0) != "//")
 728                                 {
 729                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 730                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 731                                 }
 732                         }
 733                         fclose(fd);
 734                 }
 735         }
 736
 737         WeaponStats_Init();
 738
 739         WepSet_AddStat();
 740         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 741         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 742         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 743         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 744         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 745         Nagger_Init();
 746
 747         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 748         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 749         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 750         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 751         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 752         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 753         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 754         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 755         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 756         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 757         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 758         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 759         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 760         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 761
 762         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 763         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 764
 765         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 766
 767         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 768
 769         // freeze attacks
 770         addstat(STAT_FROZEN, AS_INT, frozen);
 771         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 772
 773         // g_movementspeed hack
 774         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 775         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 776         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 777         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 778
 779         // secrets
 780         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 781         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 782
 783         // monsters
 784         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 785         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 786
 787         // misc
 788         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 789
 790         next_pingtime = time + 5;
 791
 792         detect_maptype();
 793
 794         // set up information replies for clients and server to use
 795         maplist_reply = strzone(getmaplist());
 796         lsmaps_reply = strzone(getlsmaps());
 797         monsterlist_reply = strzone(getmonsterlist());
 798         for(i = 0; i < 10; ++i)
 799         {
 800                 s = getrecords(i);
 801                 if (s)
 802                         records_reply[i] = strzone(s);
 803         }
 804         ladder_reply = strzone(getladder());
 805         rankings_reply = strzone(getrankings());
 806
 807         // begin other init
 808         ClientInit_Spawn();
 809         RandomSeed_Spawn();
 810         PingPLReport_Spawn();
 811
 812         CheatInit();
 813
 814         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 815
 816         // fill sv_curl_serverpackages from .serverpackage files
 817         if(autocvar_sv_curl_serverpackages_auto)
 818         {
 819                 s = "";
 820                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 821                 for(i = 0; i < n; ++i)
 822                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 823                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 824                                 s = strcat(s, " ", argv(i));
 825                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 826                 if(fd >= 0)
 827                 {
 828                         j = search_getsize(fd);
 829                         for(i = 0; i < j; ++i)
 830                                 s = strcat(s, " ", search_getfilename(fd, i));
 831                         search_end(fd);
 832                 }
 833                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 834                 if(fd >= 0)
 835                 {
 836                         j = search_getsize(fd);
 837                         for(i = 0; i < j; ++i)
 838                                 s = strcat(s, " ", search_getfilename(fd, i));
 839                         search_end(fd);
 840                 }
 841                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 842         }
 843
 844         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 845         modname = "Xonotic";
 846         // physics/balance/config changes that count as mod
 847         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 848                 modname = cvar_string("g_mod_physics");
 849         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 850                 modname = cvar_string("g_mod_balance");
 851         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 852                 modname = cvar_string("g_mod_config");
 853         // extra mutators that deserve to count as mod
 854         MUTATOR_CALLHOOK(SetModname);
 855
 856         // save it for later
 857         modname = strzone(modname);
 858
 859         WinningConditionHelper(); // set worldstatus
 860
 861         world_initialized = 1;
 862 }
 863
 864 void spawnfunc_light (void)
 865 {
 866         //makestatic (self); // Who the f___ did that?
 867         remove(self);
 868 }
 869
 870 string GetGametype()
 871 {
 872         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 873 }
 874
 875 string GetMapname()
 876 {
 877         return mapname;
 878 }
 879
 880 float Map_Count, Map_Current;
 881 string Map_Current_Name;
 882
 883 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 884 float GetMaplistPosition()
 885 {
 886         float pos, idx;
 887         string map;
 888
 889         map = GetMapname();
 890         idx = autocvar_g_maplist_index;
 891
 892         if(idx >= 0)
 893                 if(idx < Map_Count)
 894                         if(map == argv(idx))
 895                                 return idx;
 896
 897         for(pos = 0; pos < Map_Count; ++pos)
 898                 if(map == argv(pos))
 899                         return pos;
 900
 901         // resume normal maplist rotation if current map is not in g_maplist
 902         return idx;
 903 }
 904
 905 float MapHasRightSize(string map)
 906 {
 907         float fh;
 908         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 909         if(autocvar_g_maplist_check_waypoints)
 910         {
 911                 dprint("checkwp "); dprint(map);
 912                 if(!fexists(strcat("maps/", map, ".waypoints")))
 913                 {
 914                         dprint(": no waypoints\n");
 915                         return FALSE;
 916                 }
 917                 dprint(": has waypoints\n");
 918         }
 919
 920         // open map size restriction file
 921         dprint("opensize "); dprint(map);
 922         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 923         if(fh >= 0)
 924         {
 925                 float mapmin, mapmax;
 926                 dprint(": ok, ");
 927                 mapmin = stof(fgets(fh));
 928                 mapmax = stof(fgets(fh));
 929                 fclose(fh);
 930                 if(player_count < mapmin)
 931                 {
 932                         dprint("not enough\n");
 933                         return FALSE;
 934                 }
 935                 if(player_count > mapmax)
 936                 {
 937                         dprint("too many\n");
 938                         return FALSE;
 939                 }
 940                 dprint("right size\n");
 941                 return TRUE;
 942         }
 943         dprint(": not found\n");
 944         return TRUE;
 945 }
 946
 947 string Map_Filename(float position)
 948 {
 949         return strcat("maps/", argv(position), ".bsp");
 950 }
 951
 952 string strwords(string s, float w)
 953 {
 954         float endpos;
 955         for(endpos = 0; w && endpos >= 0; --w)
 956                 endpos = strstrofs(s, " ", endpos + 1);
 957         if(endpos < 0)
 958                 return s;
 959         else
 960                 return substring(s, 0, endpos);
 961 }
 962
 963 float strhasword(string s, string w)
 964 {
 965         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 966 }
 967
 968 void Map_MarkAsRecent(string m)
 969 {
 970         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 971 }
 972
 973 float Map_IsRecent(string m)
 974 {
 975         return strhasword(autocvar_g_maplist_mostrecent, m);
 976 }
 977
 978 float Map_Check(float position, float pass)
 979 {
 980         string filename;
 981         string map_next;
 982         map_next = argv(position);
 983         if(pass <= 1)
 984         {
 985                 if(Map_IsRecent(map_next))
 986                         return 0;
 987         }
 988         filename = Map_Filename(position);
 989         if(MapInfo_CheckMap(map_next))
 990         {
 991                 if(pass == 2)
 992                         return 1;
 993                 if(MapHasRightSize(map_next))
 994                         return 1;
 995                 return 0;
 996         }
 997         else
 998                 dprint( "Couldn't select '", filename, "'..\n" );
 999
1000         return 0;
1001 }
1002
1003 void Map_Goto_SetStr(string nextmapname)
1004 {
1005         if(getmapname_stored != "")
1006                 strunzone(getmapname_stored);
1007         if(nextmapname == "")
1008                 getmapname_stored = "";
1009         else
1010                 getmapname_stored = strzone(nextmapname);
1011 }
1012
1013 void Map_Goto_SetFloat(float position)
1014 {
1015         cvar_set("g_maplist_index", ftos(position));
1016         Map_Goto_SetStr(argv(position));
1017 }
1018
1019 void Map_Goto(float reinit)
1020 {
1021         MapInfo_LoadMap(getmapname_stored, reinit);
1022 }
1023
1024 // return codes of map selectors:
1025 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1026 //   -2 = permanent failure
1027 float() MaplistMethod_Iterate = // usual method
1028 {
1029         float pass, i;
1030
1031         dprint("Trying MaplistMethod_Iterate\n");
1032
1033         for(pass = 1; pass <= 2; ++pass)
1034         {
1035                 for(i = 1; i < Map_Count; ++i)
1036                 {
1037                         float mapindex;
1038                         mapindex = mod(i + Map_Current, Map_Count);
1039                         if(Map_Check(mapindex, pass))
1040                                 return mapindex;
1041                 }
1042         }
1043         return -1;
1044 }
1045
1046 float() MaplistMethod_Repeat = // fallback method
1047 {
1048         dprint("Trying MaplistMethod_Repeat\n");
1049
1050         if(Map_Check(Map_Current, 2))
1051                 return Map_Current;
1052         return -2;
1053 }
1054
1055 float() MaplistMethod_Random = // random map selection
1056 {
1057         float i, imax;
1058
1059         dprint("Trying MaplistMethod_Random\n");
1060
1061         imax = 42;
1062
1063         for(i = 0; i <= imax; ++i)
1064         {
1065                 float mapindex;
1066                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1067                 if(Map_Check(mapindex, 1))
1068                         return mapindex;
1069         }
1070         return -1;
1071 }
1072
1073 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1074 // the exponent sets a bias on the map selection:
1075 // the higher the exponent, the less likely "shortly repeated" same maps are
1076 {
1077         float i, j, imax, insertpos;
1078
1079         dprint("Trying MaplistMethod_Shuffle\n");
1080
1081         imax = 42;
1082
1083         for(i = 0; i <= imax; ++i)
1084         {
1085                 string newlist;
1086
1087                 // now reinsert this at another position
1088                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1089                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1090                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1091                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1092
1093                 // insert the current map there
1094                 newlist = "";
1095                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1096                         newlist = strcat(newlist, " ", argv(j));
1097                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1098                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1099                         newlist = strcat(newlist, " ", argv(j));
1100                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1101                 cvar_set("g_maplist", newlist);
1102                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1103
1104                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1105                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1106                 if(Map_Check(Map_Current, 1))
1107                         return Map_Current;
1108         }
1109         return -1;
1110 }
1111
1112 void Maplist_Init()
1113 {
1114         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1115         float i;
1116         for (i = 0; i < Map_Count; ++i)
1117                 if (Map_Check(i, 2))
1118                         break;
1119         if (i == Map_Count)
1120         {
1121                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1122                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1123                 if(autocvar_g_maplist_shuffle)
1124                         ShuffleMaplist();
1125                 localcmd("\nmenu_cmd sync\n");
1126                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1127         }
1128         if(Map_Count == 0)
1129                 error("empty maplist, cannot select a new map");
1130         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1131
1132         if(Map_Current_Name)
1133                 strunzone(Map_Current_Name);
1134         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1135         // this may or may not be correct, but who cares, in the worst case a map
1136         // isn't chosen in the first pass that should have been
1137 }
1138
1139 string GetNextMap()
1140 {
1141         float nextMap;
1142
1143         Maplist_Init();
1144         nextMap = -1;
1145
1146         if(nextMap == -1)
1147                 if(autocvar_g_maplist_shuffle > 0)
1148                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1149
1150         if(nextMap == -1)
1151                 if(autocvar_g_maplist_selectrandom)
1152                         nextMap = MaplistMethod_Random();
1153
1154         if(nextMap == -1)
1155                 nextMap = MaplistMethod_Iterate();
1156
1157         if(nextMap == -1)
1158                 nextMap = MaplistMethod_Repeat();
1159
1160         if(nextMap >= 0)
1161         {
1162                 Map_Goto_SetFloat(nextMap);
1163                 return getmapname_stored;
1164         }
1165
1166         return "";
1167 }
1168
1169 float DoNextMapOverride(float reinit)
1170 {
1171         if(autocvar_g_campaign)
1172         {
1173                 CampaignPostIntermission();
1174                 alreadychangedlevel = TRUE;
1175                 return TRUE;
1176         }
1177         if(autocvar_quit_when_empty)
1178         {
1179                 if(player_count <= currentbots)
1180                 {
1181                         localcmd("quit\n");
1182                         alreadychangedlevel = TRUE;
1183                         return TRUE;
1184                 }
1185         }
1186         if(autocvar_quit_and_redirect != "")
1187         {
1188                 redirection_target = strzone(autocvar_quit_and_redirect);
1189                 alreadychangedlevel = TRUE;
1190                 return TRUE;
1191         }
1192         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1193         {
1194                 localcmd("restart\n");
1195                 alreadychangedlevel = TRUE;
1196                 return TRUE;
1197         }
1198         if(autocvar_nextmap != "")
1199         {
1200                 string m;
1201                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1202                 cvar_set("nextmap",m);
1203
1204                 if(!m || gametypevote)
1205                         return FALSE;
1206                 if(autocvar_sv_vote_gametype)
1207                 {
1208                         Map_Goto_SetStr(m);
1209                         return FALSE;
1210                 }
1211
1212                 if(MapInfo_CheckMap(m))
1213                 {
1214                         Map_Goto_SetStr(m);
1215                         Map_Goto(reinit);
1216                         alreadychangedlevel = TRUE;
1217                         return TRUE;
1218                 }
1219         }
1220         if(!reinit && autocvar_lastlevel)
1221         {
1222                 cvar_settemp_restore();
1223                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1224                 alreadychangedlevel = TRUE;
1225                 return TRUE;
1226         }
1227         return FALSE;
1228 }
1229
1230 void GotoNextMap(float reinit)
1231 {
1232         //string nextmap;
1233         //float n, nummaps;
1234         //string s;
1235         if (alreadychangedlevel)
1236                 return;
1237         alreadychangedlevel = TRUE;
1238
1239         string nextMap;
1240
1241         nextMap = GetNextMap();
1242         if(nextMap == "")
1243                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1244         Map_Goto(reinit);
1245 }
1246
1247
1248 /*
1249 ============
1250 IntermissionThink
1251
1252 When the player presses attack or jump, change to the next level
1253 ============
1254 */
1255 .float autoscreenshot;
1256 void IntermissionThink()
1257 {
1258         FixIntermissionClient(self);
1259
1260         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1261         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1262
1263         if( (server_screenshot || client_screenshot)
1264                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1265         {
1266                 self.autoscreenshot = -1;
1267                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1268                 return;
1269         }
1270
1271         if (time < intermission_exittime)
1272                 return;
1273
1274         if(!mapvote_initialized)
1275                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1276                         return;
1277
1278         MapVote_Start();
1279 }
1280
1281 /*
1282 ============
1283 FindIntermission
1284
1285 Returns the entity to view from
1286 ============
1287 */
1288 /*
1289 entity FindIntermission()
1290 {
1291         local   entity spot;
1292         local   float cyc;
1293
1294 // look for info_intermission first
1295         spot = find (world, classname, "info_intermission");
1296         if (spot)
1297         {       // pick a random one
1298                 cyc = random() * 4;
1299                 while (cyc > 1)
1300                 {
1301                         spot = find (spot, classname, "info_intermission");
1302                         if (!spot)
1303                                 spot = find (spot, classname, "info_intermission");
1304                         cyc = cyc - 1;
1305                 }
1306                 return spot;
1307         }
1308
1309 // then look for the start position
1310         spot = find (world, classname, "info_player_start");
1311         if (spot)
1312                 return spot;
1313
1314 // testinfo_player_start is only found in regioned levels
1315         spot = find (world, classname, "testplayerstart");
1316         if (spot)
1317                 return spot;
1318
1319 // then look for the start position
1320         spot = find (world, classname, "info_player_deathmatch");
1321         if (spot)
1322                 return spot;
1323
1324         //objerror ("FindIntermission: no spot");
1325         return world;
1326 }
1327 */
1328
1329 /*
1330 ===============================================================================
1331
1332 RULES
1333
1334 ===============================================================================
1335 */
1336
1337 void DumpStats(float final)
1338 {
1339         float file;
1340         string s;
1341         float to_console;
1342         float to_eventlog;
1343         float to_file;
1344         float i;
1345
1346         to_console = autocvar_sv_logscores_console;
1347         to_eventlog = autocvar_sv_eventlog;
1348         to_file = autocvar_sv_logscores_file;
1349
1350         if(!final)
1351         {
1352                 to_console = TRUE; // always print printstats replies
1353                 to_eventlog = FALSE; // but never print them to the event log
1354         }
1355
1356         if(to_eventlog)
1357                 if(autocvar_sv_eventlog_console)
1358                         to_console = FALSE; // otherwise we get the output twice
1359
1360         if(final)
1361                 s = ":scores:";
1362         else
1363                 s = ":status:";
1364         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1365
1366         if(to_console)
1367                 print(s, "\n");
1368         if(to_eventlog)
1369                 GameLogEcho(s);
1370
1371         file = -1;
1372         if(to_file)
1373         {
1374                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1375                 if(file == -1)
1376                         to_file = FALSE;
1377                 else
1378                         fputs(file, strcat(s, "\n"));
1379         }
1380
1381         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1382         if(to_console)
1383                 print(s, "\n");
1384         if(to_eventlog)
1385                 GameLogEcho(s);
1386         if(to_file)
1387                 fputs(file, strcat(s, "\n"));
1388
1389         FOR_EACH_CLIENT(other)
1390         {
1391                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1392                 {
1393                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1394                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1395                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1396                                 s = strcat(s, ftos(other.team), ":");
1397                         else
1398                                 s = strcat(s, "spectator:");
1399
1400                         if(to_console)
1401                                 print(s, other.netname, "\n");
1402                         if(to_eventlog)
1403                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1404                         if(to_file)
1405                                 fputs(file, strcat(s, other.netname, "\n"));
1406                 }
1407         }
1408
1409         if(teamplay)
1410         {
1411                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1412                 if(to_console)
1413                         print(s, "\n");
1414                 if(to_eventlog)
1415                         GameLogEcho(s);
1416                 if(to_file)
1417                         fputs(file, strcat(s, "\n"));
1418
1419                 for(i = 1; i < 16; ++i)
1420                 {
1421                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1422                         s = strcat(s, ":", ftos(i));
1423                         if(to_console)
1424                                 print(s, "\n");
1425                         if(to_eventlog)
1426                                 GameLogEcho(s);
1427                         if(to_file)
1428                                 fputs(file, strcat(s, "\n"));
1429                 }
1430         }
1431
1432         if(to_console)
1433                 print(":end\n");
1434         if(to_eventlog)
1435                 GameLogEcho(":end");
1436         if(to_file)
1437         {
1438                 fputs(file, ":end\n");
1439                 fclose(file);
1440         }
1441 }
1442
1443 void FixIntermissionClient(entity e)
1444 {
1445         string s;
1446         if(!e.autoscreenshot) // initial call
1447         {
1448                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1449                 e.health = -2342;
1450                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1451                 e.solid = SOLID_NOT;
1452                 e.movetype = MOVETYPE_NONE;
1453                 e.takedamage = DAMAGE_NO;
1454                 if(e.weaponentity)
1455                 {
1456                         e.weaponentity.effects = EF_NODRAW;
1457                         if (e.weaponentity.weaponentity)
1458                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1459                 }
1460                 if(IS_REAL_CLIENT(e))
1461                 {
1462                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1463                         s = autocvar_sv_intermission_cdtrack;
1464                         if(s != "")
1465                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1466                         msg_entity = e;
1467                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1468                 }
1469         }
1470 }
1471
1472 /*
1473 go to the next level for deathmatch
1474 only called if a time or frag limit has expired
1475 */
1476 void NextLevel()
1477 {
1478         gameover = TRUE;
1479
1480         intermission_running = 1;
1481
1482 // enforce a wait time before allowing changelevel
1483         if(player_count > 0)
1484                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1485         else
1486                 intermission_exittime = -1;
1487
1488         /*
1489         WriteByte (MSG_ALL, SVC_CDTRACK);
1490         WriteByte (MSG_ALL, 3);
1491         WriteByte (MSG_ALL, 3);
1492         // done in FixIntermission
1493         */
1494
1495         //pos = FindIntermission ();
1496
1497         VoteReset();
1498
1499         DumpStats(TRUE);
1500
1501         // send statistics
1502         PlayerStats_GameReport(TRUE);
1503         WeaponStats_Shutdown();
1504
1505         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1506
1507         if(autocvar_sv_eventlog)
1508                 GameLogEcho(":gameover");
1509
1510         GameLogClose();
1511
1512         FOR_EACH_PLAYER(other) {
1513                 FixIntermissionClient(other);
1514                 if(other.winning)
1515                         bprint(other.netname, " ^7wins.\n");
1516         }
1517
1518         if(autocvar_g_campaign)
1519                 CampaignPreIntermission();
1520
1521         MUTATOR_CALLHOOK(MatchEnd);
1522
1523         localcmd("\nsv_hook_gameend\n");
1524 }
1525
1526 /*
1527 ============
1528 CheckRules_Player
1529
1530 Exit deathmatch games upon conditions
1531 ============
1532 */
1533 void CheckRules_Player()
1534 {
1535         if (gameover)   // someone else quit the game already
1536                 return;
1537
1538         if(self.deadflag == DEAD_NO)
1539                 self.play_time += frametime;
1540
1541         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1542         //   (div0: and that in CheckRules_World please)
1543 }
1544
1545 float checkrules_equality;
1546 float checkrules_suddendeathwarning;
1547 float checkrules_suddendeathend;
1548 float checkrules_overtimesadded; //how many overtimes have been already added
1549
1550 const float WINNING_NO = 0; // no winner, but time limits may terminate the game
1551 const float WINNING_YES = 1; // winner found
1552 const float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1553 const float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1554
1555 float InitiateSuddenDeath()
1556 {
1557         // Check first whether normal overtimes could be added before initiating suddendeath mode
1558         // - for this timelimit_overtime needs to be >0 of course
1559         // - also check the winning condition calculated in the previous frame and only add normal overtime
1560         //   again, if at the point at which timelimit would be extended again, still no winner was found
1561         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1562         {
1563                 return 1; // need to call InitiateOvertime later
1564         }
1565         else
1566         {
1567                 if(!checkrules_suddendeathend)
1568                 {
1569                         if(autocvar_g_campaign)
1570                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1571                         else
1572                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1573                         if(g_race && !g_race_qualifying)
1574                                 race_StartCompleting();
1575                 }
1576                 return 0;
1577         }
1578 }
1579
1580 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1581 {
1582         ++checkrules_overtimesadded;
1583         //add one more overtime by simply extending the timelimit
1584         float tl;
1585         tl = autocvar_timelimit;
1586         tl += autocvar_timelimit_overtime;
1587         cvar_set("timelimit", ftos(tl));
1588
1589         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1590 }
1591
1592 float GetWinningCode(float fraglimitreached, float equality)
1593 {
1594         if(autocvar_g_campaign == 1)
1595                 if(fraglimitreached)
1596                         return WINNING_YES;
1597                 else
1598                         return WINNING_NO;
1599
1600         else
1601                 if(equality)
1602                         if(fraglimitreached)
1603                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1604                         else
1605                                 return WINNING_NEVER;
1606                 else
1607                         if(fraglimitreached)
1608                                 return WINNING_YES;
1609                         else
1610                                 return WINNING_NO;
1611 }
1612
1613 // set the .winning flag for exactly those players with a given field value
1614 void SetWinners(.float field, float value)
1615 {
1616         entity head;
1617         FOR_EACH_PLAYER(head)
1618                 head.winning = (head.field == value);
1619 }
1620
1621 // set the .winning flag for those players with a given field value
1622 void AddWinners(.float field, float value)
1623 {
1624         entity head;
1625         FOR_EACH_PLAYER(head)
1626                 if(head.field == value)
1627                         head.winning = 1;
1628 }
1629
1630 // clear the .winning flags
1631 void ClearWinners(void)
1632 {
1633         entity head;
1634         FOR_EACH_PLAYER(head)
1635                 head.winning = 0;
1636 }
1637
1638 // Onslaught winning condition:
1639 // game terminates if only one team has a working generator (or none)
1640 float WinningCondition_Onslaught()
1641 {
1642         entity head;
1643         float t1, t2, t3, t4;
1644
1645         WinningConditionHelper(); // set worldstatus
1646
1647         if(warmup_stage)
1648                 return WINNING_NO;
1649
1650         // first check if the game has ended
1651         t1 = t2 = t3 = t4 = 0;
1652         head = find(world, classname, "onslaught_generator");
1653         while (head)
1654         {
1655                 if (head.health > 0)
1656                 {
1657                         if (head.team == NUM_TEAM_1) t1 = 1;
1658                         if (head.team == NUM_TEAM_2) t2 = 1;
1659                         if (head.team == NUM_TEAM_3) t3 = 1;
1660                         if (head.team == NUM_TEAM_4) t4 = 1;
1661                 }
1662                 head = find(head, classname, "onslaught_generator");
1663         }
1664         if (t1 + t2 + t3 + t4 < 2)
1665         {
1666                 // game over, only one team remains (or none)
1667                 ClearWinners();
1668                 if (t1) SetWinners(team, NUM_TEAM_1);
1669                 if (t2) SetWinners(team, NUM_TEAM_2);
1670                 if (t3) SetWinners(team, NUM_TEAM_3);
1671                 if (t4) SetWinners(team, NUM_TEAM_4);
1672                 dprint("Have a winner, ending game.\n");
1673                 return WINNING_YES;
1674         }
1675
1676         // Two or more teams remain
1677         return WINNING_NO;
1678 }
1679
1680 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1681 // they win. Otherwise the defending team wins once the timelimit passes.
1682 void assault_new_round();
1683 float WinningCondition_Assault()
1684 {
1685         float status;
1686
1687         WinningConditionHelper(); // set worldstatus
1688
1689         status = WINNING_NO;
1690         // as the timelimit has not yet passed just assume the defending team will win
1691         if(assault_attacker_team == NUM_TEAM_1)
1692         {
1693                 SetWinners(team, NUM_TEAM_2);
1694         }
1695         else
1696         {
1697                 SetWinners(team, NUM_TEAM_1);
1698         }
1699
1700         entity ent;
1701         ent = find(world, classname, "target_assault_roundend");
1702         if(ent)
1703         {
1704                 if(ent.winning) // round end has been triggered by attacking team
1705                 {
1706                         bprint("ASSAULT: round completed...\n");
1707                         SetWinners(team, assault_attacker_team);
1708
1709                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1710
1711                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1712                         {
1713                                 status = WINNING_YES;
1714                         }
1715                         else
1716                         {
1717                                 entity oldself;
1718                                 oldself = self;
1719                                 self = ent;
1720                                 assault_new_round();
1721                                 self = oldself;
1722                         }
1723                 }
1724         }
1725
1726         return status;
1727 }
1728
1729 // LMS winning condition: game terminates if and only if there's at most one
1730 // one player who's living lives. Top two scores being equal cancels the time
1731 // limit.
1732 float WinningCondition_LMS()
1733 {
1734         entity head, head2;
1735         float have_player;
1736         float have_players;
1737         float l;
1738
1739         have_player = FALSE;
1740         have_players = FALSE;
1741         l = LMS_NewPlayerLives();
1742
1743         head = find(world, classname, "player");
1744         if(head)
1745                 have_player = TRUE;
1746         head2 = find(head, classname, "player");
1747         if(head2)
1748                 have_players = TRUE;
1749
1750         if(have_player)
1751         {
1752                 // we have at least one player
1753                 if(have_players)
1754                 {
1755                         // two or more active players - continue with the game
1756                 }
1757                 else
1758                 {
1759                         // exactly one player?
1760
1761                         ClearWinners();
1762                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1763
1764                         if(l)
1765                         {
1766                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1767                                 return WINNING_NO;
1768                         }
1769                         else
1770                         {
1771                                 // a winner!
1772                                 // and assign him his first place
1773                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1774                                 return WINNING_YES;
1775                         }
1776                 }
1777         }
1778         else
1779         {
1780                 // nobody is playing at all...
1781                 if(l)
1782                 {
1783                         // wait for players...
1784                 }
1785                 else
1786                 {
1787                         // SNAFU (maybe a draw game?)
1788                         ClearWinners();
1789                         dprint("No players, ending game.\n");
1790                         return WINNING_YES;
1791                 }
1792         }
1793
1794         // When we get here, we have at least two players who are actually LIVING,
1795         // now check if the top two players have equal score.
1796         WinningConditionHelper();
1797
1798         ClearWinners();
1799         if(WinningConditionHelper_winner)
1800                 WinningConditionHelper_winner.winning = TRUE;
1801         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1802                 return WINNING_NEVER;
1803
1804         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1805         return WINNING_NO;
1806 }
1807
1808 void ShuffleMaplist()
1809 {
1810         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1811 }
1812
1813 float leaderfrags;
1814 float WinningCondition_Scores(float limit, float leadlimit)
1815 {
1816         float limitreached;
1817
1818         // TODO make everything use THIS winning condition (except LMS)
1819         WinningConditionHelper();
1820
1821         if(teamplay)
1822         {
1823                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1824                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1825                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1826                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1827         }
1828
1829         ClearWinners();
1830         if(WinningConditionHelper_winner)
1831                 WinningConditionHelper_winner.winning = 1;
1832         if(WinningConditionHelper_winnerteam >= 0)
1833                 SetWinners(team, WinningConditionHelper_winnerteam);
1834
1835         if(WinningConditionHelper_lowerisbetter)
1836         {
1837                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1838                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1839                 limit = -limit;
1840         }
1841
1842         if(WinningConditionHelper_zeroisworst)
1843                 leadlimit = 0; // not supported in this mode
1844
1845         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1846         // these modes always score in increments of 1, thus this makes sense
1847         {
1848                 if(leaderfrags != WinningConditionHelper_topscore)
1849                 {
1850                         leaderfrags = WinningConditionHelper_topscore;
1851
1852                         if (limit)
1853                         if (leaderfrags == limit - 1)
1854                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1855                         else if (leaderfrags == limit - 2)
1856                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1857                         else if (leaderfrags == limit - 3)
1858                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1859                 }
1860         }
1861
1862         limitreached = FALSE;
1863         if(limit)
1864                 if(WinningConditionHelper_topscore >= limit)
1865                         limitreached = TRUE;
1866         if(leadlimit)
1867         {
1868                 float leadlimitreached;
1869                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1870                 if(autocvar_leadlimit_and_fraglimit)
1871                         limitreached = (limitreached && leadlimitreached);
1872                 else
1873                         limitreached = (limitreached || leadlimitreached);
1874         }
1875
1876         if(limit)
1877                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1878
1879         return GetWinningCode(
1880                 WinningConditionHelper_topscore && limitreached,
1881                 WinningConditionHelper_equality
1882         );
1883 }
1884
1885 float WinningCondition_Race(float fraglimit)
1886 {
1887         float wc;
1888         entity p;
1889         float n, c;
1890
1891         n = 0;
1892         c = 0;
1893         FOR_EACH_PLAYER(p)
1894         {
1895                 ++n;
1896                 if(p.race_completed)
1897                         ++c;
1898         }
1899         if(n && (n == c))
1900                 return WINNING_YES;
1901         wc = WinningCondition_Scores(fraglimit, 0);
1902
1903         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1904         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1905         // do NOT support equality when the laps are all raced!
1906                 return WINNING_STARTSUDDENDEATHOVERTIME;
1907         else
1908                 return WINNING_NEVER;
1909 }
1910
1911 float WinningCondition_QualifyingThenRace(float limit)
1912 {
1913         float wc;
1914         wc = WinningCondition_Scores(limit, 0);
1915
1916         // NEVER initiate overtime
1917         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1918         {
1919                 return WINNING_YES;
1920         }
1921
1922         return wc;
1923 }
1924
1925 float WinningCondition_RanOutOfSpawns()
1926 {
1927         entity head;
1928
1929         if(have_team_spawns <= 0)
1930                 return WINNING_NO;
1931
1932         if(autocvar_g_spawn_useallspawns <= 0)
1933                 return WINNING_NO;
1934
1935         if(!some_spawn_has_been_used)
1936                 return WINNING_NO;
1937
1938         team1_score = team2_score = team3_score = team4_score = 0;
1939
1940         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1941         {
1942                 if(head.team == NUM_TEAM_1)
1943                         team1_score = 1;
1944                 else if(head.team == NUM_TEAM_2)
1945                         team2_score = 1;
1946                 else if(head.team == NUM_TEAM_3)
1947                         team3_score = 1;
1948                 else if(head.team == NUM_TEAM_4)
1949                         team4_score = 1;
1950         }
1951
1952         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1953         {
1954                 if(head.team == NUM_TEAM_1)
1955                         team1_score = 1;
1956                 else if(head.team == NUM_TEAM_2)
1957                         team2_score = 1;
1958                 else if(head.team == NUM_TEAM_3)
1959                         team3_score = 1;
1960                 else if(head.team == NUM_TEAM_4)
1961                         team4_score = 1;
1962         }
1963
1964         ClearWinners();
1965         if(team1_score + team2_score + team3_score + team4_score == 0)
1966         {
1967                 checkrules_equality = TRUE;
1968                 return WINNING_YES;
1969         }
1970         else if(team1_score + team2_score + team3_score + team4_score == 1)
1971         {
1972                 float t, i;
1973                 if(team1_score)
1974                         t = NUM_TEAM_1;
1975                 else if(team2_score)
1976                         t = NUM_TEAM_2;
1977                 else if(team3_score)
1978                         t = NUM_TEAM_3;
1979                 else // if(team4_score)
1980                         t = NUM_TEAM_4;
1981                 CheckAllowedTeams(world);
1982                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1983                 {
1984                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1985                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1986                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1987                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1988                 }
1989
1990                 AddWinners(team, t);
1991                 return WINNING_YES;
1992         }
1993         else
1994                 return WINNING_NO;
1995 }
1996
1997 /*
1998 ============
1999 CheckRules_World
2000
2001 Exit deathmatch games upon conditions
2002 ============
2003 */
2004 void ReadyRestart();
2005 void CheckRules_World()
2006 {
2007         float timelimit;
2008         float fraglimit;
2009         float leadlimit;
2010
2011         VoteThink();
2012         MapVote_Think();
2013
2014         SetDefaultAlpha();
2015
2016         if (gameover)   // someone else quit the game already
2017         {
2018                 if(player_count == 0) // Nobody there? Then let's go to the next map
2019                         MapVote_Start();
2020                         // this will actually check the player count in the next frame
2021                         // again, but this shouldn't hurt
2022                 return;
2023         }
2024
2025         timelimit = autocvar_timelimit * 60;
2026         fraglimit = autocvar_fraglimit;
2027         leadlimit = autocvar_leadlimit;
2028
2029         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2030         {
2031                 if(timelimit > 0)
2032                         timelimit = 0; // timelimit is not made for warmup
2033                 if(fraglimit > 0)
2034                         fraglimit = 0; // no fraglimit for now
2035                 leadlimit = 0; // no leadlimit for now
2036         }
2037
2038         if(timelimit > 0)
2039         {
2040                 timelimit += game_starttime;
2041         }
2042         else if (timelimit < 0)
2043         {
2044                 // endmatch
2045                 NextLevel();
2046                 return;
2047         }
2048
2049         if(g_onslaught)
2050                 timelimit = 0; // ONS has its own overtime rule
2051
2052         float wantovertime;
2053         wantovertime = 0;
2054
2055         if(timelimit > game_starttime)
2056                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2057         else
2058                 game_completion_ratio = 0;
2059
2060         if(checkrules_suddendeathend)
2061         {
2062                 if(!checkrules_suddendeathwarning)
2063                 {
2064                         checkrules_suddendeathwarning = TRUE;
2065                         if(g_race && !g_race_qualifying)
2066                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2067                         else
2068                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2069                 }
2070         }
2071         else
2072         {
2073                 if (timelimit && time >= timelimit)
2074                 {
2075                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2076                         {
2077                                 float totalplayers;
2078                                 float playerswithlaps;
2079                                 float readyplayers;
2080                                 entity head;
2081                                 totalplayers = playerswithlaps = readyplayers = 0;
2082                                 FOR_EACH_PLAYER(head)
2083                                 {
2084                                         ++totalplayers;
2085                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2086                                                 ++playerswithlaps;
2087                                         if(head.ready)
2088                                                 ++readyplayers;
2089                                 }
2090
2091                                 // at least 2 of the players have completed a lap: start the RACE
2092                                 // otherwise, the players should end the qualifying on their own
2093                                 if(readyplayers || playerswithlaps >= 2)
2094                                 {
2095                                         checkrules_suddendeathend = 0;
2096                                         ReadyRestart(); // go to race
2097                                         return;
2098                                 }
2099                                 else
2100                                         wantovertime |= InitiateSuddenDeath();
2101                         }
2102                         else
2103                                 wantovertime |= InitiateSuddenDeath();
2104                 }
2105         }
2106
2107         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2108         {
2109                 NextLevel();
2110                 return;
2111         }
2112
2113         float checkrules_status;
2114         checkrules_status = WinningCondition_RanOutOfSpawns();
2115         if(checkrules_status == WINNING_YES)
2116         {
2117                 bprint("Hey! Someone ran out of spawns!\n");
2118         }
2119         else if(g_race && !g_race_qualifying && timelimit >= 0)
2120         {
2121                 checkrules_status = WinningCondition_Race(fraglimit);
2122                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2123         }
2124         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2125         {
2126                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2127                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2128         }
2129         else if(g_assault)
2130         {
2131                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2132         }
2133         else if(g_lms)
2134         {
2135                 checkrules_status = WinningCondition_LMS();
2136         }
2137         else if (g_onslaught)
2138         {
2139                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2140         }
2141         else
2142         {
2143                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2144                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2145         }
2146
2147         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2148         {
2149                 checkrules_status = WINNING_NEVER;
2150                 checkrules_overtimesadded = -1;
2151                 wantovertime |= InitiateSuddenDeath();
2152         }
2153
2154         if(checkrules_status == WINNING_NEVER)
2155                 // equality cases! Nobody wins if the overtime ends in a draw.
2156                 ClearWinners();
2157
2158         if(wantovertime)
2159         {
2160                 if(checkrules_status == WINNING_NEVER)
2161                         InitiateOvertime();
2162                 else
2163                         checkrules_status = WINNING_YES;
2164         }
2165
2166         if(checkrules_suddendeathend)
2167                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2168                         checkrules_status = WINNING_YES;
2169
2170         if(checkrules_status == WINNING_YES)
2171         {
2172                 //print("WINNING\n");
2173                 NextLevel();
2174         }
2175 }
2176
2177 string GotoMap(string m)
2178 {
2179         m = GameTypeVote_MapInfo_FixName(m);
2180         if (!m)
2181                 return "The map you suggested is not available on this server.";
2182         if (!autocvar_sv_vote_gametype)
2183         if(!MapInfo_CheckMap(m))
2184                 return "The map you suggested does not support the current game mode.";
2185         cvar_set("nextmap", m);
2186         cvar_set("timelimit", "-1");
2187         if(mapvote_initialized || alreadychangedlevel)
2188         {
2189                 if(DoNextMapOverride(0))
2190                         return "Map switch initiated.";
2191                 else
2192                         return "Hm... no. For some reason I like THIS map more.";
2193         }
2194         else
2195                 return "Map switch will happen after scoreboard.";
2196 }
2197
2198
2199 void EndFrame()
2200 {
2201         anticheat_endframe();
2202
2203         float altime;
2204         FOR_EACH_REALCLIENT(self)
2205         {
2206                 self.damage_dealt_total = 0;
2207
2208                 if(IS_SPEC(self))
2209                 {
2210                         if(self.enemy.typehitsound)
2211                                 self.typehit_time = time;
2212                         else if(self.enemy.damage_dealt)
2213                                 self.damage_dealt_total = ceil(self.enemy.damage_dealt);
2214                 }
2215                 else
2216                 {
2217                         if(self.typehitsound)
2218                                 self.typehit_time = time;
2219                         else if(self.damage_dealt)
2220                                 self.damage_dealt_total = ceil(self.damage_dealt);
2221                 }
2222         }
2223         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2224         // add 1 frametime because after this, engine SV_Physics
2225         // increases time by a frametime and then networks the frame
2226         // add another frametime because client shows everything with
2227         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2228         // needed!
2229         FOR_EACH_CLIENT(self)
2230         {
2231                 self.typehitsound = FALSE;
2232                 self.damage_dealt = 0;
2233                 antilag_record(self, altime);
2234         }
2235         FOR_EACH_MONSTER(self)
2236                 antilag_record(self, altime);
2237 }
2238
2239
2240 /*
2241  * RedirectionThink:
2242  * returns TRUE if redirecting
2243  */
2244 float redirection_timeout;
2245 float redirection_nextthink;
2246 float RedirectionThink()
2247 {
2248         float clients_found;
2249
2250         if(redirection_target == "")
2251                 return FALSE;
2252
2253         if(!redirection_timeout)
2254         {
2255                 cvar_set("sv_public", "-2");
2256                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2257                 if(redirection_target == "self")
2258                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2259                 else
2260                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2261         }
2262
2263         if(time < redirection_nextthink)
2264                 return TRUE;
2265
2266         redirection_nextthink = time + 1;
2267
2268         clients_found = 0;
2269         FOR_EACH_REALCLIENT(self)
2270         {
2271                 // TODO add timer
2272                 print("Redirecting: sending connect command to ", self.netname, "\n");
2273                 if(redirection_target == "self")
2274                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2275                 else
2276                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2277                 ++clients_found;
2278         }
2279
2280         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2281
2282         if(time > redirection_timeout || clients_found == 0)
2283                 localcmd("\nwait; wait; wait; quit\n");
2284
2285         return TRUE;
2286 }
2287
2288 void TargetMusic_RestoreGame();
2289 void RestoreGame()
2290 {
2291         // Loaded from a save game
2292         // some things then break, so let's work around them...
2293
2294         // Progs DB (capture records)
2295         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2296
2297         // Mapinfo
2298         MapInfo_Shutdown();
2299         MapInfo_Enumerate();
2300         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2301         WeaponStats_Init();
2302
2303         TargetMusic_RestoreGame();
2304 }
2305
2306 void Shutdown()
2307 {
2308         gameover = 2;
2309
2310         if(world_initialized > 0)
2311         {
2312                 world_initialized = 0;
2313                 print("Saving persistent data...\n");
2314                 Ban_SaveBans();
2315
2316                 // playerstats with unfinished match
2317                 PlayerStats_GameReport(FALSE);
2318
2319                 if(!cheatcount_total)
2320                 {
2321                         if(autocvar_sv_db_saveasdump)
2322                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2323                         else
2324                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2325                 }
2326                 if(autocvar_developer)
2327                 {
2328                         if(autocvar_sv_db_saveasdump)
2329                                 db_dump(TemporaryDB, "server-temp.db");
2330                         else
2331                                 db_save(TemporaryDB, "server-temp.db");
2332                 }
2333                 CheatShutdown(); // must be after cheatcount check
2334                 db_close(ServerProgsDB);
2335                 db_close(TemporaryDB);
2336                 print("done!\n");
2337                 // tell the bot system the game is ending now
2338                 bot_endgame();
2339
2340                 WeaponStats_Shutdown();
2341                 MapInfo_Shutdown();
2342         }
2343         else if(world_initialized == 0)
2344         {
2345                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2346         }
2347 }