qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride())
 193                         GotoNextMap();
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_playerstats_");
 301                 BADPREFIX("g_voice_flood_");
 302                 BADPREFIX("rcon_");
 303                 BADPREFIX("settemp_");
 304                 BADPREFIX("sv_allowdownloads_");
 305                 BADPREFIX("sv_autodemo");
 306                 BADPREFIX("sv_curl_");
 307                 BADPREFIX("sv_eventlog");
 308                 BADPREFIX("sv_logscores_");
 309                 BADPREFIX("sv_master");
 310                 BADPREFIX("sv_weaponstats_");
 311                 BADPREFIX("sv_waypointsprite_");
 312                 BADCVAR("rescan_pending");
 313
 314                 // these can contain player IDs, so better hide
 315                 BADPREFIX("g_forced_team_");
 316
 317                 // mapinfo
 318                 BADCVAR("fraglimit");
 319                 BADCVAR("g_arena");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ca");
 322                 BADCVAR("g_ctf");
 323                 BADCVAR("g_cts");
 324                 BADCVAR("g_dm");
 325                 BADCVAR("g_domination");
 326                 BADCVAR("g_domination_default_teams");
 327                 BADCVAR("g_freezetag");
 328                 BADCVAR("g_keepaway");
 329                 BADCVAR("g_keyhunt");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_keyhunt_teams");
 332                 BADCVAR("g_lms");
 333                 BADCVAR("g_nexball");
 334                 BADCVAR("g_onslaught");
 335                 BADCVAR("g_race");
 336                 BADCVAR("g_race_qualifying_timelimit");
 337                 BADCVAR("g_runematch");
 338                 BADCVAR("g_tdm");
 339                 BADCVAR("g_tdm_teams");
 340                 BADCVAR("leadlimit");
 341                 BADCVAR("nextmap");
 342                 BADCVAR("teamplay");
 343                 BADCVAR("timelimit");
 344
 345                 // long
 346                 BADCVAR("hostname");
 347                 BADCVAR("g_maplist");
 348                 BADCVAR("g_maplist_mostrecent");
 349                 BADCVAR("sv_motd");
 350
 351                 v = cvar_string(k);
 352                 d = cvar_defstring(k);
 353                 if(v == d)
 354                         continue;
 355
 356                 if(adding)
 357                 {
 358                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 359                         if(strlen(cvar_changes) > 16384)
 360                         {
 361                                 cvar_changes = "// too many settings have been changed to show them here\n";
 362                                 adding = 0;
 363                         }
 364                 }
 365
 366                 // now check if the changes are actually gameplay relevant
 367
 368                 // does nothing visible
 369                 BADCVAR("captureleadlimit_override");
 370                 BADCVAR("g_arena_point_leadlimit");
 371                 BADCVAR("g_balance_kill_delay");
 372                 BADCVAR("g_ca_point_leadlimit");
 373                 BADCVAR("g_ctf_captimerecord_always");
 374                 BADCVAR("g_ctf_capture_leadlimit");
 375                 BADCVAR("g_ctf_flag_capture_effects");
 376                 BADCVAR("g_ctf_flag_glowtrails");
 377                 BADCVAR("g_ctf_flag_pickup_effects");
 378                 BADCVAR("g_domination_point_leadlimit");
 379                 BADCVAR("g_forced_respawn");
 380                 BADCVAR("g_keyhunt_point_leadlimit");
 381                 BADCVAR("g_nexball_goalleadlimit");
 382                 BADCVAR("g_runematch_point_leadlimit");
 383                 BADCVAR("leadlimit_and_fraglimit");
 384                 BADCVAR("leadlimit_override");
 385                 BADCVAR("pausable");
 386                 BADCVAR("sv_allow_fullbright");
 387                 BADCVAR("sv_checkforpacketsduringsleep");
 388                 BADCVAR("sv_timeout");
 389                 BADCVAR("welcome_message_time");
 390                 BADPREFIX("crypto_");
 391                 BADPREFIX("g_chat_");
 392                 BADPREFIX("g_ctf_captimerecord_");
 393                 BADPREFIX("g_maplist_votable_");
 394                 BADPREFIX("net_");
 395                 BADPREFIX("prvm_");
 396                 BADPREFIX("skill_");
 397                 BADPREFIX("sv_cullentities_");
 398                 BADPREFIX("sv_fraginfo_");
 399                 BADPREFIX("sv_maxidle_");
 400                 BADPREFIX("sv_vote_");
 401                 BADPREFIX("timelimit_");
 402                 BADCVAR("gameversion");
 403                 BADPREFIX("gameversion_");
 404                 BADCVAR("sv_namechangetimer");
 405 #ifndef NO_LEGACY_NETWORKING
 406                 BADCVAR("sv_use_csqc_players"); // transition
 407 #endif
 408
 409                 // allowed changes to server admins (please sync this to server.cfg)
 410                 // vi commands:
 411                 //   :/"impure"/,$d
 412                 //   :g!,^\/\/[^ /],d
 413                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 414                 //   :%!sort
 415                 // yes, this does contain some redundant stuff, don't really care
 416                 BADCVAR("bot_config_file");
 417                 BADCVAR("bot_number");
 418                 BADCVAR("bot_prefix");
 419                 BADCVAR("bot_suffix");
 420                 BADCVAR("capturelimit_override");
 421                 BADCVAR("fraglimit_override");
 422                 BADCVAR("gametype");
 423                 BADCVAR("g_antilag");
 424                 BADCVAR("g_balance_teams");
 425                 BADCVAR("g_balance_teams_force");
 426                 BADCVAR("g_ban_sync_trusted_servers");
 427                 BADCVAR("g_ban_sync_uri");
 428                 BADCVAR("g_ctf_capture_limit");
 429                 BADCVAR("g_ctf_ignore_frags");
 430                 BADCVAR("g_ctf_win_mode");
 431                 BADCVAR("g_domination_point_limit");
 432                 BADCVAR("g_friendlyfire");
 433                 BADCVAR("g_fullbrightitems");
 434                 BADCVAR("g_fullbrightplayers");
 435                 BADCVAR("g_keyhunt_point_limit");
 436                 BADCVAR("g_keyhunt_teams_override");
 437                 BADCVAR("g_lms_lives_override");
 438                 BADCVAR("g_maplist");
 439                 BADCVAR("g_maplist_check_waypoints");
 440                 BADCVAR("g_maplist_mostrecent_count");
 441                 BADCVAR("g_maplist_shuffle");
 442                 BADCVAR("g_maplist_votable");
 443                 BADCVAR("g_maplist_votable_abstain");
 444                 BADCVAR("g_maplist_votable_nodetail");
 445                 BADCVAR("g_maplist_votable_suggestions");
 446                 BADCVAR("g_maxplayers");
 447                 BADCVAR("g_minstagib");
 448                 BADCVAR("g_mirrordamage");
 449                 BADCVAR("g_nexball_goallimit");
 450                 BADCVAR("g_powerups");
 451                 BADCVAR("g_runematch_point_limit");
 452                 BADCVAR("g_start_delay");
 453                 BADCVAR("g_warmup");
 454                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 455                 BADCVAR("hostname");
 456                 BADCVAR("log_file");
 457                 BADCVAR("maxplayers");
 458                 BADCVAR("minplayers");
 459                 BADCVAR("net_address");
 460                 BADCVAR("port");
 461                 BADCVAR("rcon_password");
 462                 BADCVAR("rcon_restricted_commands");
 463                 BADCVAR("rcon_restricted_password");
 464                 BADCVAR("skill");
 465                 BADCVAR("sv_adminnick");
 466                 BADCVAR("sv_autoscreenshot");
 467                 BADCVAR("sv_autotaunt");
 468                 BADCVAR("sv_curl_defaulturl");
 469                 BADCVAR("sv_defaultcharacter");
 470                 BADCVAR("sv_defaultplayercolors");
 471                 BADCVAR("sv_defaultplayermodel");
 472                 BADCVAR("sv_defaultplayerskin");
 473                 BADCVAR("sv_maxidle");
 474                 BADCVAR("sv_maxrate");
 475                 BADCVAR("sv_motd");
 476                 BADCVAR("sv_public");
 477                 BADCVAR("sv_ready_restart");
 478                 BADCVAR("sv_status_privacy");
 479                 BADCVAR("sv_taunt");
 480                 BADCVAR("sv_vote_call");
 481                 BADCVAR("sv_vote_commands");
 482                 BADCVAR("sv_vote_majority_factor");
 483                 BADCVAR("sv_vote_master");
 484                 BADCVAR("sv_vote_master_commands");
 485                 BADCVAR("sv_vote_master_password");
 486                 BADCVAR("sv_vote_simple_majority_factor");
 487                 BADCVAR("sys_ticrate");
 488                 BADCVAR("teamplay_mode");
 489                 BADCVAR("timelimit_override");
 490                 BADPREFIX("g_warmup_");
 491                 BADPREFIX("sv_ready_restart_");
 492
 493                 if(autocvar_g_minstagib)
 494                 {
 495                         BADCVAR("g_grappling_hook");
 496                         BADCVAR("g_jetpack");
 497                 }
 498 #undef BADPREFIX
 499 #undef BADCVAR
 500
 501                 if(pureadding)
 502                 {
 503                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 504                         if(strlen(cvar_purechanges) > 16384)
 505                         {
 506                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 507                                 pureadding = 0;
 508                         }
 509                 }
 510                 ++cvar_purechanges_count;
 511                 // WARNING: this variable is used for the server list
 512                 // NEVER dare to skip this code!
 513                 // Hacks to intentionally appearing as "pure server" even though you DO have
 514                 // modified settings may be punished by removal from the server list.
 515                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 516                 // though.
 517         }
 518         buf_del(h);
 519         if(cvar_changes == "")
 520                 cvar_changes = "// this server runs at default server settings\n";
 521         else
 522                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 523         cvar_changes = strzone(cvar_changes);
 524         if(cvar_purechanges == "")
 525                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 526         else
 527                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 528         cvar_purechanges = strzone(cvar_purechanges);
 529 }
 530
 531 void detect_maptype()
 532 {
 533 #if 0
 534         vector o, v;
 535         float i;
 536
 537         for(;;)
 538         {
 539                 o = world.mins;
 540                 o_x += random() * (world.maxs_x - world.mins_x);
 541                 o_y += random() * (world.maxs_y - world.mins_y);
 542                 o_z += random() * (world.maxs_z - world.mins_z);
 543
 544                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 545                 if(trace_fraction == 1)
 546                         continue;
 547
 548                 v = trace_endpos;
 549
 550                 for(i = 0; i < 64; i += 4)
 551                 {
 552                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 553         if(trace_fraction == 1)
 554                 continue;
 555                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 556                 }
 557
 558                 break;
 559         }
 560 #endif
 561 }
 562
 563 entity randomseed;
 564 float RandomSeed_Send(entity to, float sf)
 565 {
 566         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 567         WriteShort(MSG_ENTITY, self.cnt);
 568         return TRUE;
 569 }
 570 void RandomSeed_Think()
 571 {
 572         self.cnt = bound(0, floor(random() * 65536), 65535);
 573         self.nextthink = time + 5;
 574
 575         self.SendFlags |= 1;
 576 }
 577 void RandomSeed_Spawn()
 578 {
 579         randomseed = spawn();
 580         randomseed.think = RandomSeed_Think;
 581         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 582
 583         entity oldself;
 584         oldself = self;
 585         self = randomseed;
 586         self.think(); // sets random seed and nextthink
 587         self = oldself;
 588 }
 589
 590 void spawnfunc___init_dedicated_server(void)
 591 {
 592         // handler for _init/_init map (only for dedicated server initialization)
 593
 594         world_initialized = -1; // don't complain
 595         cvar = cvar_normal;
 596         cvar_string = cvar_string_normal;
 597         cvar_set = cvar_set_normal;
 598
 599         remove = remove_unsafely;
 600
 601         entity e;
 602         e = spawn();
 603         e.think = GotoFirstMap;
 604         e.nextthink = time; // this is usually 1 at this point
 605
 606         e = spawn();
 607         e.classname = "info_player_deathmatch"; // safeguard against player joining
 608
 609         self.classname = "worldspawn"; // safeguard against various stuff ;)
 610
 611         MapInfo_Enumerate();
 612         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 613 }
 614
 615 void Map_MarkAsRecent(string m);
 616 float world_already_spawned;
 617 void RegisterWeapons();
 618 void Nagger_Init();
 619 void ClientInit_Spawn();
 620 void WeaponStats_Init();
 621 void WeaponStats_Shutdown();
 622 void spawnfunc_worldspawn (void)
 623 {
 624         float fd, l, i, j, n;
 625         string s, col;
 626
 627         cvar = cvar_normal;
 628         cvar_string = cvar_string_normal;
 629         cvar_set = cvar_set_normal;
 630
 631         if(world_already_spawned)
 632                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 633         world_already_spawned = TRUE;
 634
 635         remove = remove_safely; // during spawning, watch what you remove!
 636
 637         check_unacceptable_compiler_bugs();
 638
 639         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 640
 641         compressShortVector_init();
 642
 643         allowed_to_spawn = TRUE;
 644
 645         entity head;
 646         head = nextent(world);
 647         maxclients = 0;
 648         while(head)
 649         {
 650                 ++maxclients;
 651                 head = nextent(head);
 652         }
 653
 654         // needs to be done so early as they would still spawn
 655         RegisterWeapons();
 656
 657         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 658
 659         TemporaryDB = db_create();
 660
 661         // 0 normal
 662         lightstyle(0, "m");
 663
 664         // 1 FLICKER (first variety)
 665         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 666
 667         // 2 SLOW STRONG PULSE
 668         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 669
 670         // 3 CANDLE (first variety)
 671         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 672
 673         // 4 FAST STROBE
 674         lightstyle(4, "mamamamamama");
 675
 676         // 5 GENTLE PULSE 1
 677         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 678
 679         // 6 FLICKER (second variety)
 680         lightstyle(6, "nmonqnmomnmomomno");
 681
 682         // 7 CANDLE (second variety)
 683         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 684
 685         // 8 CANDLE (third variety)
 686         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 687
 688         // 9 SLOW STROBE (fourth variety)
 689         lightstyle(9, "aaaaaaaazzzzzzzz");
 690
 691         // 10 FLUORESCENT FLICKER
 692         lightstyle(10, "mmamammmmammamamaaamammma");
 693
 694         // 11 SLOW PULSE NOT FADE TO BLACK
 695         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 696
 697         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 698
 699         // 63 testing
 700         lightstyle(63, "a");
 701
 702         if(autocvar_g_campaign)
 703                 CampaignPreInit();
 704
 705         Map_MarkAsRecent(mapname);
 706
 707         precache_model ("null"); // we need this one before InitGameplayMode
 708         InitGameplayMode();
 709         readlevelcvars();
 710         GrappleHookInit();
 711         ElectroInit();
 712         LaserInit();
 713
 714         player_count = 0;
 715         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 716         if(bot_waypoints_for_items == 1)
 717                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 718                         bot_waypoints_for_items = 0;
 719
 720         precache();
 721
 722         WaypointSprite_Init();
 723
 724         //if (g_domination)
 725         //      dom_init();
 726
 727         GameLogInit(); // prepare everything
 728         // NOTE for matchid:
 729         // changing the logic generating it is okay. But:
 730         // it HAS to stay <= 64 chars
 731         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 732         if(autocvar_sv_eventlog)
 733         {
 734                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 735                 matchid = strzone(s);
 736
 737                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 738                 s = ":gameinfo:mutators:LIST";
 739
 740                 ret_string = s;
 741                 MUTATOR_CALLHOOK(BuildMutatorsString);
 742                 s = ret_string;
 743
 744                 // simple, probably not good in the mutator system
 745                 if(autocvar_g_grappling_hook)
 746                         s = strcat(s, ":grappling_hook");
 747
 748                 // initialiation stuff, not good in the mutator system
 749                 if(!autocvar_g_use_ammunition)
 750                         s = strcat(s, ":no_use_ammunition");
 751
 752                 // initialiation stuff, not good in the mutator system
 753                 if(autocvar_g_pickup_items == 0)
 754                         s = strcat(s, ":no_pickup_items");
 755                 if(autocvar_g_pickup_items > 0)
 756                         s = strcat(s, ":pickup_items");
 757
 758                 // initialiation stuff, not good in the mutator system
 759                 if(autocvar_g_weaponarena != "0")
 760                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 761
 762                 // TODO to mutator system
 763                 if(autocvar_g_norecoil)
 764                         s = strcat(s, ":norecoil");
 765
 766                 // TODO to mutator system
 767                 if(autocvar_g_midair)
 768                         s = strcat(s, ":midair");
 769
 770                 // TODO to mutator system
 771                 if(autocvar_g_minstagib)
 772                         s = strcat(s, ":minstagib");
 773
 774                 // TODO to mutator system
 775                 if(autocvar_g_powerups == 0)
 776                         s = strcat(s, ":no_powerups");
 777                 if(autocvar_g_powerups > 0)
 778                         s = strcat(s, ":powerups");
 779
 780                 GameLogEcho(s);
 781                 GameLogEcho(":gameinfo:end");
 782         }
 783         else
 784                 matchid = strzone(ftos(random()));
 785
 786         cvar_set("nextmap", "");
 787
 788         SetDefaultAlpha();
 789
 790         if(autocvar_g_campaign)
 791                 CampaignPostInit();
 792
 793         fteqcc_testbugs();
 794
 795         Ban_LoadBans();
 796
 797         MapInfo_Enumerate();
 798         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 799
 800         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 801         {
 802                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 803                 if(fd != -1)
 804                 {
 805                         while((s = fgets(fd)))
 806                         {
 807                                 l = tokenize_console(s);
 808                                 if(l < 2)
 809                                         continue;
 810                                 if(argv(0) == "cd")
 811                                 {
 812                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 813                                         print("  cdtrack ", argv(2), "\n");
 814                                 }
 815                                 else if(argv(0) == "fog")
 816                                 {
 817                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 818                                         print("  \"fog\" \"", s, "\"\n");
 819                                 }
 820                                 else if(argv(0) == "set")
 821                                 {
 822                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 823                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 824                                 }
 825                                 else if(argv(0) != "//")
 826                                 {
 827                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 828                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 829                                 }
 830                         }
 831                         fclose(fd);
 832                 }
 833         }
 834
 835         WeaponStats_Init();
 836
 837         addstat(STAT_WEAPONS, AS_INT, weapons);
 838         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 839         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 840         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 841         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 842         Nagger_Init();
 843
 844         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 845         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 846         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 847         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 848         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 849         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 850         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 851         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 852         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 853         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 854         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 855         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 856
 857         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 858         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 859
 860         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 861
 862         if(g_ca || g_freezetag)
 863         {
 864                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 865                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 866                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 867                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 868         }
 869         if(g_freezetag)
 870         {
 871                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 872                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 873         }
 874
 875         // g_movementspeed hack
 876         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 877         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 878         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 879         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 880
 881         // secrets
 882         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 883         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 884
 885         next_pingtime = time + 5;
 886
 887         detect_maptype();
 888
 889         lsmaps_reply = "^7Maps available: ";
 890         lsnewmaps_reply = "^7Maps without a record set: ";
 891         for(i = 0, j = 0; i < MapInfo_count; ++i)
 892         {
 893                 if(MapInfo_Get_ByID(i))
 894                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 895                         {
 896                                 if(mod(i, 2))
 897                                         col = "^2";
 898                                 else
 899                                         col = "^3";
 900                                 ++j;
 901                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 902                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 903                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 904                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 905                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 906                         }
 907         }
 908         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 909         if (!g_race && !g_cts)
 910                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 911         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 912
 913         maplist_reply = "^7Maps in list: ";
 914         n = tokenize_console(autocvar_g_maplist);
 915         for(i = 0, j = 0; i < n; ++i)
 916         {
 917                 if(MapInfo_CheckMap(argv(i)))
 918                 {
 919                         if(mod(j, 2))
 920                                 col = "^2";
 921                         else
 922                                 col = "^3";
 923                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 924                         ++j;
 925                 }
 926         }
 927         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 928         MapInfo_ClearTemps();
 929
 930         for(i = 0; i < 10; ++i)
 931         {
 932                 records_reply[i] = strzone(getrecords(i));
 933         }
 934         if(g_cts)
 935                 ladder_reply = strzone(getladder());
 936
 937         rankings_reply = strzone(getrankings());
 938
 939         ClientInit_Spawn();
 940         RandomSeed_Spawn();
 941         PingPLReport_Spawn();
 942
 943         CheatInit();
 944
 945         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 946
 947         // fill sv_curl_serverpackages from .serverpackage files
 948         if(autocvar_sv_curl_serverpackages_auto)
 949         {
 950                 s = "";
 951                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 952                 for(i = 0; i < n; ++i)
 953                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 954                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 955                                 s = strcat(s, " ", argv(i));
 956                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 957                 if(fd >= 0)
 958                 {
 959                         j = search_getsize(fd);
 960                         for(i = 0; i < j; ++i)
 961                                 s = strcat(s, " ", search_getfilename(fd, i));
 962                         search_end(fd);
 963                 }
 964                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 965                 if(fd >= 0)
 966                 {
 967                         j = search_getsize(fd);
 968                         for(i = 0; i < j; ++i)
 969                                 s = strcat(s, " ", search_getfilename(fd, i));
 970                         search_end(fd);
 971                 }
 972                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 973         }
 974
 975         PlayerStats_Init();
 976
 977         world_initialized = 1;
 978 }
 979
 980 void spawnfunc_light (void)
 981 {
 982         //makestatic (self); // Who the f___ did that?
 983         remove(self);
 984 }
 985
 986 string GetGametype()
 987 {
 988         return GametypeNameFromType(game);
 989 }
 990
 991 string getmapname_stored;
 992 string GetMapname()
 993 {
 994         return mapname;
 995 }
 996
 997 float Map_Count, Map_Current;
 998 string Map_Current_Name;
 999
1000 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1001 float GetMaplistPosition()
1002 {
1003         float pos, idx;
1004         string map;
1005
1006         map = GetMapname();
1007         idx = autocvar_g_maplist_index;
1008
1009         if(idx >= 0)
1010                 if(idx < Map_Count)
1011                         if(map == argv(idx))
1012                                 return idx;
1013
1014         for(pos = 0; pos < Map_Count; ++pos)
1015                 if(map == argv(pos))
1016                         return pos;
1017
1018         // resume normal maplist rotation if current map is not in g_maplist
1019         return idx;
1020 }
1021
1022 float MapHasRightSize(string map)
1023 {
1024         float fh;
1025         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1026         if(autocvar_g_maplist_check_waypoints)
1027         {
1028                 dprint("checkwp "); dprint(map);
1029                 if(!fexists(strcat("maps/", map, ".waypoints")))
1030                 {
1031                         dprint(": no waypoints\n");
1032                         return FALSE;
1033                 }
1034                 dprint(": has waypoints\n");
1035         }
1036
1037         // open map size restriction file
1038         dprint("opensize "); dprint(map);
1039         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1040         if(fh >= 0)
1041         {
1042                 float mapmin, mapmax;
1043                 dprint(": ok, ");
1044                 mapmin = stof(fgets(fh));
1045                 mapmax = stof(fgets(fh));
1046                 fclose(fh);
1047                 if(player_count < mapmin)
1048                 {
1049                         dprint("not enough\n");
1050                         return FALSE;
1051                 }
1052                 if(player_count > mapmax)
1053                 {
1054                         dprint("too many\n");
1055                         return FALSE;
1056                 }
1057                 dprint("right size\n");
1058                 return TRUE;
1059         }
1060         dprint(": not found\n");
1061         return TRUE;
1062 }
1063
1064 string Map_Filename(float position)
1065 {
1066         return strcat("maps/", argv(position), ".bsp");
1067 }
1068
1069 string strwords(string s, float w)
1070 {
1071         float endpos;
1072         for(endpos = 0; w && endpos >= 0; --w)
1073                 endpos = strstrofs(s, " ", endpos + 1);
1074         if(endpos < 0)
1075                 return s;
1076         else
1077                 return substring(s, 0, endpos);
1078 }
1079
1080 float strhasword(string s, string w)
1081 {
1082         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1083 }
1084
1085 void Map_MarkAsRecent(string m)
1086 {
1087         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1088 }
1089
1090 float Map_IsRecent(string m)
1091 {
1092         return strhasword(autocvar_g_maplist_mostrecent, m);
1093 }
1094
1095 float Map_Check(float position, float pass)
1096 {
1097         string filename;
1098         string map_next;
1099         map_next = argv(position);
1100         if(pass <= 1)
1101         {
1102                 if(Map_IsRecent(map_next))
1103                         return 0;
1104         }
1105         filename = Map_Filename(position);
1106         if(MapInfo_CheckMap(map_next))
1107         {
1108                 if(pass == 2)
1109                         return 1;
1110                 if(MapHasRightSize(map_next))
1111                         return 1;
1112                 return 0;
1113         }
1114         else
1115                 dprint( "Couldn't select '", filename, "'..\n" );
1116
1117         return 0;
1118 }
1119
1120 void Map_Goto_SetStr(string nextmapname)
1121 {
1122         if(getmapname_stored != "")
1123                 strunzone(getmapname_stored);
1124         if(nextmapname == "")
1125                 getmapname_stored = "";
1126         else
1127                 getmapname_stored = strzone(nextmapname);
1128 }
1129
1130 void Map_Goto_SetFloat(float position)
1131 {
1132         cvar_set("g_maplist_index", ftos(position));
1133         Map_Goto_SetStr(argv(position));
1134 }
1135
1136 void GameResetCfg()
1137 {
1138         // settings persist, except...
1139         localcmd("\nsettemp_restore\n");
1140 }
1141
1142 void Map_Goto()
1143 {
1144         GameResetCfg();
1145         MapInfo_LoadMap(getmapname_stored);
1146 }
1147
1148 // return codes of map selectors:
1149 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1150 //   -2 = permanent failure
1151 float() MaplistMethod_Iterate = // usual method
1152 {
1153         float pass, i;
1154
1155         for(pass = 1; pass <= 2; ++pass)
1156         {
1157                 for(i = 1; i < Map_Count; ++i)
1158                 {
1159                         float mapindex;
1160                         mapindex = mod(i + Map_Current, Map_Count);
1161                         if(Map_Check(mapindex, pass))
1162                                 return mapindex;
1163                 }
1164         }
1165         return -1;
1166 }
1167
1168 float() MaplistMethod_Repeat = // fallback method
1169 {
1170         if(Map_Check(Map_Current, 2))
1171                 return Map_Current;
1172         return -2;
1173 }
1174
1175 float() MaplistMethod_Random = // random map selection
1176 {
1177         float i, imax;
1178
1179         imax = 42;
1180
1181         for(i = 0; i <= imax; ++i)
1182         {
1183                 float mapindex;
1184                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1185                 if(Map_Check(mapindex, 1))
1186                         return mapindex;
1187         }
1188         return -1;
1189 }
1190
1191 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1192 // the exponent sets a bias on the map selection:
1193 // the higher the exponent, the less likely "shortly repeated" same maps are
1194 {
1195         float i, j, imax, insertpos;
1196
1197         imax = 42;
1198
1199         for(i = 0; i <= imax; ++i)
1200         {
1201                 string newlist;
1202
1203                 // now reinsert this at another position
1204                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1205                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1206                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1207                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1208
1209                 // insert the current map there
1210                 newlist = "";
1211                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1212                         newlist = strcat(newlist, " ", argv(j));
1213                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1214                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1215                         newlist = strcat(newlist, " ", argv(j));
1216                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1217                 cvar_set("g_maplist", newlist);
1218                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1219
1220                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1221                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1222                 if(Map_Check(Map_Current, 1))
1223                         return Map_Current;
1224         }
1225         return -1;
1226 }
1227
1228 void Maplist_Init()
1229 {
1230         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1231         if(Map_Count == 0)
1232         {
1233                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1234                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1235                 if(autocvar_g_maplist_shuffle)
1236                         ShuffleMaplist();
1237                 localcmd("\nmenu_cmd sync\n");
1238                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1239         }
1240         if(Map_Count == 0)
1241                 error("empty maplist, cannot select a new map");
1242         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1243
1244         if(Map_Current_Name)
1245                 strunzone(Map_Current_Name);
1246         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1247         // this may or may not be correct, but who cares, in the worst case a map
1248         // isn't chosen in the first pass that should have been
1249 }
1250
1251 string GetNextMap()
1252 {
1253         float nextMap;
1254
1255         Maplist_Init();
1256         nextMap = -1;
1257
1258         if(nextMap == -1)
1259                 if(autocvar_g_maplist_shuffle > 0)
1260                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1261
1262         if(nextMap == -1)
1263                 if(autocvar_g_maplist_selectrandom)
1264                         nextMap = MaplistMethod_Random();
1265
1266         if(nextMap == -1)
1267                 nextMap = MaplistMethod_Iterate();
1268
1269         if(nextMap == -1)
1270                 nextMap = MaplistMethod_Repeat();
1271
1272         if(nextMap >= 0)
1273         {
1274                 Map_Goto_SetFloat(nextMap);
1275                 return getmapname_stored;
1276         }
1277
1278         return "";
1279 }
1280
1281 float DoNextMapOverride()
1282 {
1283         if(autocvar_g_campaign)
1284         {
1285                 CampaignPostIntermission();
1286                 alreadychangedlevel = TRUE;
1287                 return TRUE;
1288         }
1289         if(autocvar_quit_when_empty)
1290         {
1291                 if(player_count <= currentbots)
1292                 {
1293                         localcmd("quit\n");
1294                         alreadychangedlevel = TRUE;
1295                         return TRUE;
1296                 }
1297         }
1298         if(autocvar_quit_and_redirect != "")
1299         {
1300                 redirection_target = strzone(autocvar_quit_and_redirect);
1301                 alreadychangedlevel = TRUE;
1302                 return TRUE;
1303         }
1304         if (autocvar_samelevel) // if samelevel is set, stay on same level
1305         {
1306                 localcmd("restart\n");
1307                 alreadychangedlevel = TRUE;
1308                 return TRUE;
1309         }
1310         if(autocvar_nextmap != "")
1311                 if(MapInfo_CheckMap(autocvar_nextmap))
1312                 {
1313                         Map_Goto_SetStr(autocvar_nextmap);
1314                         Map_Goto();
1315                         alreadychangedlevel = TRUE;
1316                         return TRUE;
1317                 }
1318         if(autocvar_lastlevel)
1319         {
1320                 GameResetCfg();
1321                 localcmd("set lastlevel 0\ntogglemenu\n");
1322                 alreadychangedlevel = TRUE;
1323                 return TRUE;
1324         }
1325         return FALSE;
1326 }
1327
1328 void GotoNextMap()
1329 {
1330         //string nextmap;
1331         //float n, nummaps;
1332         //string s;
1333         if (alreadychangedlevel)
1334                 return;
1335         alreadychangedlevel = TRUE;
1336
1337         {
1338                 string nextMap;
1339                 float allowReset;
1340
1341                 for(allowReset = 1; allowReset >= 0; --allowReset)
1342                 {
1343                         nextMap = GetNextMap();
1344                         if(nextMap != "")
1345                                 break;
1346
1347                         if(allowReset)
1348                         {
1349                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1350                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1351                                 if(autocvar_g_maplist_shuffle)
1352                                         ShuffleMaplist();
1353                                 localcmd("\nmenu_cmd sync\n");
1354                         }
1355                         else
1356                         {
1357                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1358                         }
1359                 }
1360                 Map_Goto();
1361         }
1362 }
1363
1364
1365 /*
1366 ============
1367 IntermissionThink
1368
1369 When the player presses attack or jump, change to the next level
1370 ============
1371 */
1372 .float autoscreenshot;
1373 void() MapVote_Start;
1374 void() MapVote_Think;
1375 float mapvote_initialized;
1376 void IntermissionThink()
1377 {
1378         FixIntermissionClient(self);
1379
1380         if( (autocvar_sv_autoscreenshot || self.cvar_cl_autoscreenshot)
1381                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1382         {
1383                 self.autoscreenshot = -1;
1384                 if(clienttype(self) == CLIENTTYPE_REAL)
1385                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1386                 return;
1387         }
1388
1389         if (time < intermission_exittime)
1390                 return;
1391
1392         if(!mapvote_initialized)
1393                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1394                         return;
1395
1396         MapVote_Start();
1397 }
1398
1399 /*
1400 ============
1401 FindIntermission
1402
1403 Returns the entity to view from
1404 ============
1405 */
1406 /*
1407 entity FindIntermission()
1408 {
1409         local   entity spot;
1410         local   float cyc;
1411
1412 // look for info_intermission first
1413         spot = find (world, classname, "info_intermission");
1414         if (spot)
1415         {       // pick a random one
1416                 cyc = random() * 4;
1417                 while (cyc > 1)
1418                 {
1419                         spot = find (spot, classname, "info_intermission");
1420                         if (!spot)
1421                                 spot = find (spot, classname, "info_intermission");
1422                         cyc = cyc - 1;
1423                 }
1424                 return spot;
1425         }
1426
1427 // then look for the start position
1428         spot = find (world, classname, "info_player_start");
1429         if (spot)
1430                 return spot;
1431
1432 // testinfo_player_start is only found in regioned levels
1433         spot = find (world, classname, "testplayerstart");
1434         if (spot)
1435                 return spot;
1436
1437 // then look for the start position
1438         spot = find (world, classname, "info_player_deathmatch");
1439         if (spot)
1440                 return spot;
1441
1442         //objerror ("FindIntermission: no spot");
1443         return world;
1444 }
1445 */
1446
1447 /*
1448 ===============================================================================
1449
1450 RULES
1451
1452 ===============================================================================
1453 */
1454
1455 void DumpStats(float final)
1456 {
1457         float file;
1458         string s;
1459         float to_console;
1460         float to_eventlog;
1461         float to_file;
1462         float i;
1463
1464         to_console = autocvar_sv_logscores_console;
1465         to_eventlog = autocvar_sv_eventlog;
1466         to_file = autocvar_sv_logscores_file;
1467
1468         if(!final)
1469         {
1470                 to_console = TRUE; // always print printstats replies
1471                 to_eventlog = FALSE; // but never print them to the event log
1472         }
1473
1474         if(to_eventlog)
1475                 if(autocvar_sv_eventlog_console)
1476                         to_console = FALSE; // otherwise we get the output twice
1477
1478         if(final)
1479                 s = ":scores:";
1480         else
1481                 s = ":status:";
1482         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1483
1484         if(to_console)
1485                 print(s, "\n");
1486         if(to_eventlog)
1487                 GameLogEcho(s);
1488         if(to_file)
1489         {
1490                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1491                 if(file == -1)
1492                         to_file = FALSE;
1493                 else
1494                         fputs(file, strcat(s, "\n"));
1495         }
1496
1497         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1498         if(to_console)
1499                 print(s, "\n");
1500         if(to_eventlog)
1501                 GameLogEcho(s);
1502         if(to_file)
1503                 fputs(file, strcat(s, "\n"));
1504
1505         FOR_EACH_CLIENT(other)
1506         {
1507                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1508                 {
1509                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1510                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1511                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1512                                 s = strcat(s, ftos(other.team), ":");
1513                         else
1514                                 s = strcat(s, "spectator:");
1515
1516                         if(to_console)
1517                                 print(s, other.netname, "\n");
1518                         if(to_eventlog)
1519                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1520                         if(to_file)
1521                                 fputs(file, strcat(s, other.netname, "\n"));
1522                 }
1523         }
1524
1525         if(teamplay)
1526         {
1527                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1528                 if(to_console)
1529                         print(s, "\n");
1530                 if(to_eventlog)
1531                         GameLogEcho(s);
1532                 if(to_file)
1533                         fputs(file, strcat(s, "\n"));
1534
1535                 for(i = 1; i < 16; ++i)
1536                 {
1537                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1538                         s = strcat(s, ":", ftos(i));
1539                         if(to_console)
1540                                 print(s, "\n");
1541                         if(to_eventlog)
1542                                 GameLogEcho(s);
1543                         if(to_file)
1544                                 fputs(file, strcat(s, "\n"));
1545                 }
1546         }
1547
1548         if(to_console)
1549                 print(":end\n");
1550         if(to_eventlog)
1551                 GameLogEcho(":end");
1552         if(to_file)
1553         {
1554                 fputs(file, ":end\n");
1555                 fclose(file);
1556         }
1557 }
1558
1559 void FixIntermissionClient(entity e)
1560 {
1561         string s;
1562         if(!e.autoscreenshot) // initial call
1563         {
1564                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1565                 e.health = -2342;
1566                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1567                 e.solid = SOLID_NOT;
1568                 e.movetype = MOVETYPE_NONE;
1569                 e.takedamage = DAMAGE_NO;
1570                 if(e.weaponentity)
1571                 {
1572                         e.weaponentity.effects = EF_NODRAW;
1573                         if (e.weaponentity.weaponentity)
1574                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1575                 }
1576                 if(clienttype(e) == CLIENTTYPE_REAL)
1577                 {
1578                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1579                         s = autocvar_sv_intermission_cdtrack;
1580                         if(s != "")
1581                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1582                         msg_entity = e;
1583                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1584                 }
1585         }
1586 }
1587
1588
1589 /*
1590 go to the next level for deathmatch
1591 only called if a time or frag limit has expired
1592 */
1593 void NextLevel()
1594 {
1595         gameover = TRUE;
1596
1597         intermission_running = 1;
1598
1599 // enforce a wait time before allowing changelevel
1600         if(player_count > 0)
1601                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1602         else
1603                 intermission_exittime = -1;
1604
1605         /*
1606         WriteByte (MSG_ALL, SVC_CDTRACK);
1607         WriteByte (MSG_ALL, 3);
1608         WriteByte (MSG_ALL, 3);
1609         // done in FixIntermission
1610         */
1611
1612         //pos = FindIntermission ();
1613
1614         VoteReset();
1615
1616         DumpStats(TRUE);
1617
1618         // send statistics
1619         entity e;
1620         PlayerStats_EndMatch(1);
1621         FOR_EACH_CLIENT(e)
1622                 PlayerStats_AddGlobalInfo(e);
1623         PlayerStats_Shutdown();
1624         WeaponStats_Shutdown();
1625
1626         if(autocvar_sv_eventlog)
1627                 GameLogEcho(":gameover");
1628
1629         GameLogClose();
1630
1631         FOR_EACH_PLAYER(other) {
1632                 FixIntermissionClient(other);
1633                 if(other.winning)
1634                         bprint(other.netname, " ^7wins.\n");
1635         }
1636
1637         if(autocvar_g_campaign)
1638                 CampaignPreIntermission();
1639
1640         localcmd("\nsv_hook_gameend\n");
1641 }
1642
1643 /*
1644 ============
1645 CheckRules_Player
1646
1647 Exit deathmatch games upon conditions
1648 ============
1649 */
1650 void CheckRules_Player()
1651 {
1652         if (gameover)   // someone else quit the game already
1653                 return;
1654
1655         if(self.deadflag == DEAD_NO)
1656                 self.play_time += frametime;
1657
1658         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1659         //   (div0: and that in CheckRules_World please)
1660 }
1661
1662 float checkrules_equality;
1663 float checkrules_suddendeathwarning;
1664 float checkrules_suddendeathend;
1665 float checkrules_overtimesadded; //how many overtimes have been already added
1666
1667 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1668 float WINNING_YES = 1; // winner found
1669 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1670 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1671
1672 float InitiateSuddenDeath()
1673 {
1674         // Check first whether normal overtimes could be added before initiating suddendeath mode
1675         // - for this timelimit_overtime needs to be >0 of course
1676         // - also check the winning condition calculated in the previous frame and only add normal overtime
1677         //   again, if at the point at which timelimit would be extended again, still no winner was found
1678         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1679         {
1680                 return 1; // need to call InitiateOvertime later
1681         }
1682         else
1683         {
1684                 if(!checkrules_suddendeathend)
1685                 {
1686                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1687                         if(g_race && !g_race_qualifying)
1688                                 race_StartCompleting();
1689                 }
1690                 return 0;
1691         }
1692 }
1693
1694 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1695 {
1696         ++checkrules_overtimesadded;
1697         //add one more overtime by simply extending the timelimit
1698         float tl;
1699         tl = autocvar_timelimit;
1700         tl += autocvar_timelimit_overtime;
1701         cvar_set("timelimit", ftos(tl));
1702         string minutesPlural;
1703         if (autocvar_timelimit_overtime == 1)
1704                 minutesPlural = " ^3minute";
1705         else
1706                 minutesPlural = " ^3minutes";
1707
1708         bcenterprint(
1709                 strcat(
1710                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1711                         ftos(autocvar_timelimit_overtime),
1712                         minutesPlural,
1713                         " to the game!"
1714                 )
1715         );
1716 }
1717
1718 float GetWinningCode(float fraglimitreached, float equality)
1719 {
1720         if(autocvar_g_campaign == 1)
1721                 if(fraglimitreached)
1722                         return WINNING_YES;
1723                 else
1724                         return WINNING_NO;
1725
1726         else
1727                 if(equality)
1728                         if(fraglimitreached)
1729                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1730                         else
1731                                 return WINNING_NEVER;
1732                 else
1733                         if(fraglimitreached)
1734                                 return WINNING_YES;
1735                         else
1736                                 return WINNING_NO;
1737 }
1738
1739 // set the .winning flag for exactly those players with a given field value
1740 void SetWinners(.float field, float value)
1741 {
1742         entity head;
1743         FOR_EACH_PLAYER(head)
1744                 head.winning = (head.field == value);
1745 }
1746
1747 // set the .winning flag for those players with a given field value
1748 void AddWinners(.float field, float value)
1749 {
1750         entity head;
1751         FOR_EACH_PLAYER(head)
1752                 if(head.field == value)
1753                         head.winning = 1;
1754 }
1755
1756 // clear the .winning flags
1757 void ClearWinners(void)
1758 {
1759         entity head;
1760         FOR_EACH_PLAYER(head)
1761                 head.winning = 0;
1762 }
1763
1764 // Onslaught winning condition:
1765 // game terminates if only one team has a working generator (or none)
1766 float WinningCondition_Onslaught()
1767 {
1768         entity head;
1769         float t1, t2, t3, t4;
1770
1771         WinningConditionHelper(); // set worldstatus
1772
1773         if(inWarmupStage)
1774                 return WINNING_NO;
1775
1776         // first check if the game has ended
1777         t1 = t2 = t3 = t4 = 0;
1778         head = find(world, classname, "onslaught_generator");
1779         while (head)
1780         {
1781                 if (head.health > 0)
1782                 {
1783                         if (head.team == COLOR_TEAM1) t1 = 1;
1784                         if (head.team == COLOR_TEAM2) t2 = 1;
1785                         if (head.team == COLOR_TEAM3) t3 = 1;
1786                         if (head.team == COLOR_TEAM4) t4 = 1;
1787                 }
1788                 head = find(head, classname, "onslaught_generator");
1789         }
1790         if (t1 + t2 + t3 + t4 < 2)
1791         {
1792                 // game over, only one team remains (or none)
1793                 ClearWinners();
1794                 if (t1) SetWinners(team, COLOR_TEAM1);
1795                 if (t2) SetWinners(team, COLOR_TEAM2);
1796                 if (t3) SetWinners(team, COLOR_TEAM3);
1797                 if (t4) SetWinners(team, COLOR_TEAM4);
1798                 dprint("Have a winner, ending game.\n");
1799                 return WINNING_YES;
1800         }
1801
1802         // Two or more teams remain
1803         return WINNING_NO;
1804 }
1805
1806 float LMS_NewPlayerLives()
1807 {
1808         float fl;
1809         fl = autocvar_fraglimit;
1810         if(fl == 0)
1811                 fl = 999;
1812
1813         // first player has left the game for dying too much? Nobody else can get in.
1814         if(lms_lowest_lives < 1)
1815                 return 0;
1816
1817         if(!autocvar_g_lms_join_anytime)
1818                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1819                         return 0;
1820
1821         return bound(1, lms_lowest_lives, fl);
1822 }
1823
1824 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1825 // they win. Otherwise the defending team wins once the timelimit passes.
1826 void assault_new_round();
1827 float WinningCondition_Assault()
1828 {
1829         float status;
1830
1831         WinningConditionHelper(); // set worldstatus
1832
1833         status = WINNING_NO;
1834         // as the timelimit has not yet passed just assume the defending team will win
1835         if(assault_attacker_team == COLOR_TEAM1)
1836         {
1837                 SetWinners(team, COLOR_TEAM2);
1838         }
1839         else
1840         {
1841                 SetWinners(team, COLOR_TEAM1);
1842         }
1843
1844         entity ent;
1845         ent = find(world, classname, "target_assault_roundend");
1846         if(ent)
1847         {
1848                 if(ent.winning) // round end has been triggered by attacking team
1849                 {
1850                         bprint("ASSAULT: round completed...\n");
1851                         SetWinners(team, assault_attacker_team);
1852
1853                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1854
1855                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1856                         {
1857                                 status = WINNING_YES;
1858                         }
1859                         else
1860                         {
1861                                 entity oldself;
1862                                 oldself = self;
1863                                 self = ent;
1864                                 assault_new_round();
1865                                 self = oldself;
1866                         }
1867                 }
1868         }
1869
1870         return status;
1871 }
1872
1873 // LMS winning condition: game terminates if and only if there's at most one
1874 // one player who's living lives. Top two scores being equal cancels the time
1875 // limit.
1876 float WinningCondition_LMS()
1877 {
1878         entity head, head2;
1879         float have_player;
1880         float have_players;
1881         float l;
1882
1883         have_player = FALSE;
1884         have_players = FALSE;
1885         l = LMS_NewPlayerLives();
1886
1887         head = find(world, classname, "player");
1888         if(head)
1889                 have_player = TRUE;
1890         head2 = find(head, classname, "player");
1891         if(head2)
1892                 have_players = TRUE;
1893
1894         if(have_player)
1895         {
1896                 // we have at least one player
1897                 if(have_players)
1898                 {
1899                         // two or more active players - continue with the game
1900                 }
1901                 else
1902                 {
1903                         // exactly one player?
1904
1905                         ClearWinners();
1906                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1907
1908                         if(l)
1909                         {
1910                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1911                                 return WINNING_NO;
1912                         }
1913                         else
1914                         {
1915                                 // a winner!
1916                                 // and assign him his first place
1917                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1918                                 return WINNING_YES;
1919                         }
1920                 }
1921         }
1922         else
1923         {
1924                 // nobody is playing at all...
1925                 if(l)
1926                 {
1927                         // wait for players...
1928                 }
1929                 else
1930                 {
1931                         // SNAFU (maybe a draw game?)
1932                         ClearWinners();
1933                         dprint("No players, ending game.\n");
1934                         return WINNING_YES;
1935                 }
1936         }
1937
1938         // When we get here, we have at least two players who are actually LIVING,
1939         // now check if the top two players have equal score.
1940         WinningConditionHelper();
1941
1942         ClearWinners();
1943         if(WinningConditionHelper_winner)
1944                 WinningConditionHelper_winner.winning = TRUE;
1945         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1946                 return WINNING_NEVER;
1947
1948         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1949         return WINNING_NO;
1950 }
1951
1952 void ShuffleMaplist()
1953 {
1954         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1955 }
1956
1957 float leaderfrags;
1958 float WinningCondition_Scores(float limit, float leadlimit)
1959 {
1960         float limitreached;
1961
1962         // TODO make everything use THIS winning condition (except LMS)
1963         WinningConditionHelper();
1964
1965         if(teamplay)
1966         {
1967                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1968                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1969                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1970                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1971         }
1972
1973         ClearWinners();
1974         if(WinningConditionHelper_winner)
1975                 WinningConditionHelper_winner.winning = 1;
1976         if(WinningConditionHelper_winnerteam >= 0)
1977                 SetWinners(team, WinningConditionHelper_winnerteam);
1978
1979         if(WinningConditionHelper_lowerisbetter)
1980         {
1981                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1982                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1983                 limit = -limit;
1984         }
1985
1986         if(WinningConditionHelper_zeroisworst)
1987                 leadlimit = 0; // not supported in this mode
1988
1989         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1990         // these modes always score in increments of 1, thus this makes sense
1991         {
1992                 if(leaderfrags != WinningConditionHelper_topscore)
1993                 {
1994                         leaderfrags = WinningConditionHelper_topscore;
1995
1996                         if (limit)
1997                         if (leaderfrags == limit - 1)
1998                                 Announce("1fragleft");
1999                         else if (leaderfrags == limit - 2)
2000                                 Announce("2fragsleft");
2001                         else if (leaderfrags == limit - 3)
2002                                 Announce("3fragsleft");
2003                 }
2004         }
2005
2006         limitreached = FALSE;
2007         if(limit)
2008                 if(WinningConditionHelper_topscore >= limit)
2009                         limitreached = TRUE;
2010         if(leadlimit)
2011         {
2012                 float leadlimitreached;
2013                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
2014                 if(autocvar_leadlimit_and_fraglimit)
2015                         limitreached = (limitreached && leadlimitreached);
2016                 else
2017                         limitreached = (limitreached || leadlimitreached);
2018         }
2019
2020         return GetWinningCode(
2021                 WinningConditionHelper_topscore && limitreached,
2022                 WinningConditionHelper_equality
2023         );
2024 }
2025
2026 float WinningCondition_Race(float fraglimit)
2027 {
2028         float wc;
2029         entity p;
2030         float n, c;
2031
2032         n = 0;
2033         c = 0;
2034         FOR_EACH_PLAYER(p)
2035         {
2036                 ++n;
2037                 if(p.race_completed)
2038                         ++c;
2039         }
2040         if(n && (n == c))
2041                 return WINNING_YES;
2042         wc = WinningCondition_Scores(fraglimit, 0);
2043
2044         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2045         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2046         // do NOT support equality when the laps are all raced!
2047                 return WINNING_STARTSUDDENDEATHOVERTIME;
2048         else
2049                 return WINNING_NEVER;
2050         return wc;
2051 }
2052
2053 void ReadyRestart();
2054 float WinningCondition_QualifyingThenRace(float limit)
2055 {
2056         float wc;
2057         wc = WinningCondition_Scores(limit, 0);
2058
2059         // NEVER initiate overtime
2060         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2061         {
2062                 return WINNING_YES;
2063         }
2064
2065         return wc;
2066 }
2067
2068 float WinningCondition_RanOutOfSpawns()
2069 {
2070         entity head;
2071
2072         if(have_team_spawns <= 0)
2073                 return WINNING_NO;
2074
2075         if(autocvar_g_spawn_useallspawns <= 0)
2076                 return WINNING_NO;
2077
2078         if(!some_spawn_has_been_used)
2079                 return WINNING_NO;
2080
2081         team1_score = team2_score = team3_score = team4_score = 0;
2082
2083         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2084         {
2085                 if(head.team == COLOR_TEAM1)
2086                         team1_score = 1;
2087                 else if(head.team == COLOR_TEAM2)
2088                         team2_score = 1;
2089                 else if(head.team == COLOR_TEAM3)
2090                         team3_score = 1;
2091                 else if(head.team == COLOR_TEAM4)
2092                         team4_score = 1;
2093         }
2094
2095         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2096         {
2097                 if(head.team == COLOR_TEAM1)
2098                         team1_score = 1;
2099                 else if(head.team == COLOR_TEAM2)
2100                         team2_score = 1;
2101                 else if(head.team == COLOR_TEAM3)
2102                         team3_score = 1;
2103                 else if(head.team == COLOR_TEAM4)
2104                         team4_score = 1;
2105         }
2106
2107         ClearWinners();
2108         if(team1_score + team2_score + team3_score + team4_score == 0)
2109         {
2110                 checkrules_equality = TRUE;
2111                 return WINNING_YES;
2112         }
2113         else if(team1_score + team2_score + team3_score + team4_score == 1)
2114         {
2115                 float t, i;
2116                 if(team1_score) t = COLOR_TEAM1;
2117                 if(team2_score) t = COLOR_TEAM2;
2118                 if(team3_score) t = COLOR_TEAM3;
2119                 if(team4_score) t = COLOR_TEAM4;
2120                 CheckAllowedTeams(world);
2121                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2122                 {
2123                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2124                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2125                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2126                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2127                 }
2128
2129                 AddWinners(team, t);
2130                 return WINNING_YES;
2131         }
2132         else
2133                 return WINNING_NO;
2134 }
2135
2136 /*
2137 ============
2138 CheckRules_World
2139
2140 Exit deathmatch games upon conditions
2141 ============
2142 */
2143 void CheckRules_World()
2144 {
2145         float timelimit;
2146         float fraglimit;
2147         float leadlimit;
2148
2149         VoteThink();
2150         MapVote_Think();
2151
2152         SetDefaultAlpha();
2153
2154         /*
2155         MapVote_Think should now do that part
2156         if (intermission_running)
2157                 if (time >= intermission_exittime + 60)
2158                 {
2159                         if(!DoNextMapOverride())
2160                                 GotoNextMap();
2161                         return;
2162                 }
2163         */
2164
2165         if (gameover)   // someone else quit the game already
2166         {
2167                 if(player_count == 0) // Nobody there? Then let's go to the next map
2168                         MapVote_Start();
2169                         // this will actually check the player count in the next frame
2170                         // again, but this shouldn't hurt
2171                 return;
2172         }
2173
2174         timelimit = autocvar_timelimit * 60;
2175         fraglimit = autocvar_fraglimit;
2176         leadlimit = autocvar_leadlimit;
2177
2178         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2179         {
2180                 if(timelimit > 0)
2181                         timelimit = 0; // timelimit is not made for warmup
2182                 if(fraglimit > 0)
2183                         fraglimit = 0; // no fraglimit for now
2184                 leadlimit = 0; // no leadlimit for now
2185         }
2186
2187         if(g_onslaught)
2188                 timelimit = 0; // ONS has its own overtime rule
2189
2190         if(timelimit > 0)
2191         {
2192                 timelimit += game_starttime;
2193         }
2194         else if (timelimit < 0)
2195         {
2196                 // endmatch
2197                 NextLevel();
2198                 return;
2199         }
2200
2201         float wantovertime;
2202         wantovertime = 0;
2203
2204         if(checkrules_suddendeathend)
2205         {
2206                 if(!checkrules_suddendeathwarning)
2207                 {
2208                         checkrules_suddendeathwarning = TRUE;
2209                         if(g_race && !g_race_qualifying)
2210                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2211                         else
2212                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2213                 }
2214         }
2215         else
2216         {
2217                 if (timelimit && time >= timelimit)
2218                 {
2219                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2220                         {
2221                                 float totalplayers;
2222                                 float playerswithlaps;
2223                                 float readyplayers;
2224                                 entity head;
2225                                 totalplayers = playerswithlaps = readyplayers = 0;
2226                                 FOR_EACH_PLAYER(head)
2227                                 {
2228                                         ++totalplayers;
2229                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2230                                                 ++playerswithlaps;
2231                                         if(head.ready)
2232                                                 ++readyplayers;
2233                                 }
2234
2235                                 // at least 2 of the players have completed a lap: start the RACE
2236                                 // otherwise, the players should end the qualifying on their own
2237                                 if(readyplayers || playerswithlaps >= 2)
2238                                 {
2239                                         checkrules_suddendeathend = 0;
2240                                         ReadyRestart(); // go to race
2241                                         return;
2242                                 }
2243                                 else
2244                                         wantovertime |= InitiateSuddenDeath();
2245                         }
2246                         else
2247                                 wantovertime |= InitiateSuddenDeath();
2248                 }
2249         }
2250
2251         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2252         {
2253                 NextLevel();
2254                 return;
2255         }
2256
2257         float checkrules_status;
2258         checkrules_status = WinningCondition_RanOutOfSpawns();
2259         if(checkrules_status == WINNING_YES)
2260         {
2261                 bprint("Hey! Someone ran out of spawns!\n");
2262         }
2263         else if(g_race && !g_race_qualifying && timelimit >= 0)
2264         {
2265                 checkrules_status = WinningCondition_Race(fraglimit);
2266                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2267         }
2268         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2269         {
2270                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2271                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2272         }
2273         else if(g_assault)
2274         {
2275                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2276         }
2277         else if(g_lms)
2278         {
2279                 checkrules_status = WinningCondition_LMS();
2280         }
2281         else if (g_onslaught)
2282         {
2283                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2284         }
2285         else
2286         {
2287                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2288                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2289         }
2290
2291         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2292         {
2293                 checkrules_status = WINNING_NEVER;
2294                 checkrules_overtimesadded = -1;
2295                 wantovertime |= InitiateSuddenDeath();
2296         }
2297
2298         if(checkrules_status == WINNING_NEVER)
2299                 // equality cases! Nobody wins if the overtime ends in a draw.
2300                 ClearWinners();
2301
2302         if(wantovertime)
2303         {
2304                 if(checkrules_status == WINNING_NEVER)
2305                         InitiateOvertime();
2306                 else
2307                         checkrules_status = WINNING_YES;
2308         }
2309
2310         if(checkrules_suddendeathend)
2311                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2312                         checkrules_status = WINNING_YES;
2313
2314         if(checkrules_status == WINNING_YES)
2315         {
2316                 //print("WINNING\n");
2317                 NextLevel();
2318         }
2319 }
2320
2321 float mapvote_nextthink;
2322 float mapvote_initialized;
2323 float mapvote_keeptwotime;
2324 float mapvote_timeout;
2325 string mapvote_message;
2326 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2327 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2328 float mapvote_screenshot_dirs_count;
2329
2330 float mapvote_count;
2331 float mapvote_count_real;
2332 string mapvote_maps[MAPVOTE_COUNT];
2333 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2334 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2335 float mapvote_maps_suggested[MAPVOTE_COUNT];
2336 string mapvote_suggestions[MAPVOTE_COUNT];
2337 float mapvote_suggestion_ptr;
2338 float mapvote_voters;
2339 float mapvote_votes[MAPVOTE_COUNT];
2340 float mapvote_run;
2341 float mapvote_detail;
2342 float mapvote_abstain;
2343 .float mapvote;
2344
2345 void MapVote_ClearAllVotes()
2346 {
2347         FOR_EACH_CLIENT(other)
2348                 other.mapvote = 0;
2349 }
2350
2351 string MapVote_Suggest(string m)
2352 {
2353         float i;
2354         if(m == "")
2355                 return "That's not how to use this command.";
2356         if(!autocvar_g_maplist_votable_suggestions)
2357                 return "Suggestions are not accepted on this server.";
2358         if(mapvote_initialized)
2359                 return "Can't suggest - voting is already in progress!";
2360         m = MapInfo_FixName(m);
2361         if(!m)
2362                 return "The map you suggested is not available on this server.";
2363         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2364                 if(Map_IsRecent(m))
2365                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2366
2367         if(!MapInfo_CheckMap(m))
2368                 return "The map you suggested does not support the current game mode.";
2369         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2370                 if(mapvote_suggestions[i] == m)
2371                         return "This map was already suggested.";
2372         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2373         {
2374                 i = floor(random() * mapvote_suggestion_ptr);
2375         }
2376         else
2377         {
2378                 i = mapvote_suggestion_ptr;
2379                 mapvote_suggestion_ptr += 1;
2380         }
2381         if(mapvote_suggestions[i] != "")
2382                 strunzone(mapvote_suggestions[i]);
2383         mapvote_suggestions[i] = strzone(m);
2384         if(autocvar_sv_eventlog)
2385                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2386         return strcat("Suggestion of ", m, " accepted.");
2387 }
2388
2389 void MapVote_AddVotable(string nextMap, float isSuggestion)
2390 {
2391         float j, i, o;
2392         string pakfile, mapfile;
2393
2394         if(nextMap == "")
2395                 return;
2396         for(j = 0; j < mapvote_count; ++j)
2397                 if(mapvote_maps[j] == nextMap)
2398                         return;
2399         // suggestions might be no longer valid/allowed after gametype switch!
2400         if(isSuggestion)
2401                 if(!MapInfo_CheckMap(nextMap))
2402                         return;
2403         mapvote_maps[mapvote_count] = strzone(nextMap);
2404         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2405
2406         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2407         {
2408                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2409                 pakfile = whichpack(strcat(mapfile, ".tga"));
2410                 if(pakfile == "")
2411                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2412                 if(pakfile == "")
2413                         pakfile = whichpack(strcat(mapfile, ".png"));
2414                 if(pakfile != "")
2415                         break;
2416         }
2417         if(i >= mapvote_screenshot_dirs_count)
2418                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2419         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2420                 pakfile = substring(pakfile, o, -1);
2421
2422         mapvote_maps_screenshot_dir[mapvote_count] = i;
2423         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2424
2425         mapvote_count += 1;
2426 }
2427
2428 void MapVote_Spawn();
2429 void MapVote_Init()
2430 {
2431         float i;
2432         float nmax, smax;
2433
2434         MapVote_ClearAllVotes();
2435
2436         mapvote_count = 0;
2437         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2438         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2439
2440         if(mapvote_abstain)
2441                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2442         else
2443                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2444         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2445
2446         // we need this for AddVotable, as that cycles through the screenshot dirs
2447         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2448         if(mapvote_screenshot_dirs_count == 0)
2449                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2450         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2451         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2452                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2453
2454         if(mapvote_suggestion_ptr)
2455                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2456                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2457
2458         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2459                 MapVote_AddVotable(GetNextMap(), FALSE);
2460
2461         if(mapvote_count == 0)
2462         {
2463                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2464                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2465                 if(autocvar_g_maplist_shuffle)
2466                         ShuffleMaplist();
2467                 localcmd("\nmenu_cmd sync\n");
2468                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2469                         MapVote_AddVotable(GetNextMap(), FALSE);
2470         }
2471
2472         mapvote_count_real = mapvote_count;
2473         if(mapvote_abstain)
2474                 MapVote_AddVotable("don't care", 0);
2475
2476         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2477
2478         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2479         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2480         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2481                 mapvote_keeptwotime = 0;
2482         mapvote_message = "Choose a map and press its key!";
2483
2484         MapVote_Spawn();
2485 }
2486
2487 void MapVote_SendPicture(float id)
2488 {
2489         msg_entity = self;
2490         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2491         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2492         WriteByte(MSG_ONE, id);
2493         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2494 }
2495
2496 float GameCommand_MapVote(string cmd)
2497 {
2498         if(!intermission_running)
2499                 return FALSE;
2500
2501         if(cmd == "mv_getpic")
2502         {
2503                 MapVote_SendPicture(stof(argv(1)));
2504                 return TRUE;
2505         }
2506
2507         return FALSE;
2508 }
2509
2510 float MapVote_GetMapMask()
2511 {
2512         float mask, i, power;
2513         mask = 0;
2514         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2515                 if(mapvote_maps[i] != "")
2516                         mask |= power;
2517         return mask;
2518 }
2519
2520 entity mapvote_ent;
2521 float MapVote_SendEntity(entity to, float sf)
2522 {
2523         float i;
2524
2525         if(sf & 1)
2526                 sf &~= 2; // if we send 1, we don't need to also send 2
2527
2528         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2529         WriteByte(MSG_ENTITY, sf);
2530
2531         if(sf & 1)
2532         {
2533                 // flag 1 == initialization
2534                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2535                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2536                 WriteString(MSG_ENTITY, "");
2537                 WriteByte(MSG_ENTITY, mapvote_count);
2538                 WriteByte(MSG_ENTITY, mapvote_abstain);
2539                 WriteByte(MSG_ENTITY, mapvote_detail);
2540                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2541                 if(mapvote_count <= 8)
2542                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2543                 else
2544                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2545                 for(i = 0; i < mapvote_count; ++i)
2546                         if(mapvote_maps[i] != "")
2547                         {
2548                                 if(mapvote_abstain && i == mapvote_count - 1)
2549                                 {
2550                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2551                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2552                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2553                                 }
2554                                 else
2555                                 {
2556                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2557                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2558                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2559                                 }
2560                         }
2561         }
2562
2563         if(sf & 2)
2564         {
2565                 // flag 2 == update of mask
2566                 if(mapvote_count <= 8)
2567                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2568                 else
2569                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2570         }
2571
2572         if(sf & 4)
2573         {
2574                 if(mapvote_detail)
2575                         for(i = 0; i < mapvote_count; ++i)
2576                                 if(mapvote_maps[i] != "")
2577                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2578
2579                 WriteByte(MSG_ENTITY, to.mapvote);
2580         }
2581
2582         return TRUE;
2583 }
2584
2585 void MapVote_Spawn()
2586 {
2587         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2588 }
2589
2590 void MapVote_TouchMask()
2591 {
2592         mapvote_ent.SendFlags |= 2;
2593 }
2594
2595 void MapVote_TouchVotes(entity voter)
2596 {
2597         mapvote_ent.SendFlags |= 4;
2598 }
2599
2600 float MapVote_Finished(float mappos)
2601 {
2602         string result;
2603         float i;
2604         float didntvote;
2605
2606         if(autocvar_sv_eventlog)
2607         {
2608                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2609                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2610                 didntvote = mapvote_voters;
2611                 for(i = 0; i < mapvote_count; ++i)
2612                         if(mapvote_maps[i] != "")
2613                         {
2614                                 didntvote -= mapvote_votes[i];
2615                                 if(i != mappos)
2616                                 {
2617                                         result = strcat(result, ":", mapvote_maps[i]);
2618                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2619                                 }
2620                         }
2621                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2622
2623                 GameLogEcho(result);
2624                 if(mapvote_maps_suggested[mappos])
2625                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2626         }
2627
2628         FOR_EACH_REALCLIENT(other)
2629                 FixClientCvars(other);
2630
2631         Map_Goto_SetStr(mapvote_maps[mappos]);
2632         Map_Goto();
2633         alreadychangedlevel = TRUE;
2634         return TRUE;
2635 }
2636 void MapVote_CheckRules_1()
2637 {
2638         float i;
2639
2640         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2641         {
2642                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2643                 mapvote_votes[i] = 0;
2644         }
2645
2646         mapvote_voters = 0;
2647         FOR_EACH_REALCLIENT(other)
2648         {
2649                 ++mapvote_voters;
2650                 if(other.mapvote)
2651                 {
2652                         i = other.mapvote - 1;
2653                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2654                         mapvote_votes[i] = mapvote_votes[i] + 1;
2655                 }
2656         }
2657 }
2658
2659 float MapVote_CheckRules_2()
2660 {
2661         float i;
2662         float firstPlace, secondPlace;
2663         float firstPlaceVotes, secondPlaceVotes;
2664         float mapvote_voters_real;
2665         string result;
2666
2667         if(mapvote_count_real == 1)
2668                 return MapVote_Finished(0);
2669
2670         mapvote_voters_real = mapvote_voters;
2671         if(mapvote_abstain)
2672                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2673
2674         RandomSelection_Init();
2675         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2676                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2677         firstPlace = RandomSelection_chosen_float;
2678         firstPlaceVotes = RandomSelection_best_priority;
2679         //dprint("First place: ", ftos(firstPlace), "\n");
2680         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2681
2682         RandomSelection_Init();
2683         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2684                 if(i != firstPlace)
2685                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2686         secondPlace = RandomSelection_chosen_float;
2687         secondPlaceVotes = RandomSelection_best_priority;
2688         //dprint("Second place: ", ftos(secondPlace), "\n");
2689         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2690
2691         if(firstPlace == -1)
2692                 error("No first place in map vote... WTF?");
2693
2694         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2695                 return MapVote_Finished(firstPlace);
2696
2697         if(mapvote_keeptwotime)
2698                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2699                 {
2700                         float didntvote;
2701                         MapVote_TouchMask();
2702                         mapvote_message = "Now decide between the TOP TWO!";
2703                         mapvote_keeptwotime = 0;
2704                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2705                         result = strcat(result, ":", ftos(firstPlaceVotes));
2706                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2707                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2708                         didntvote = mapvote_voters;
2709                         for(i = 0; i < mapvote_count; ++i)
2710                                 if(mapvote_maps[i] != "")
2711                                 {
2712                                         didntvote -= mapvote_votes[i];
2713                                         if(i != firstPlace)
2714                                                 if(i != secondPlace)
2715                                                 {
2716                                                         result = strcat(result, ":", mapvote_maps[i]);
2717                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2718                                                         if(i < mapvote_count_real)
2719                                                         {
2720                                                                 strunzone(mapvote_maps[i]);
2721                                                                 mapvote_maps[i] = "";
2722                                                                 strunzone(mapvote_maps_pakfile[i]);
2723                                                                 mapvote_maps_pakfile[i] = "";
2724                                                         }
2725                                                 }
2726                                 }
2727                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2728                         if(autocvar_sv_eventlog)
2729                                 GameLogEcho(result);
2730                 }
2731
2732         return FALSE;
2733 }
2734 void MapVote_Tick()
2735 {
2736         float keeptwo;
2737         float totalvotes;
2738
2739         keeptwo = mapvote_keeptwotime;
2740         MapVote_CheckRules_1(); // count
2741         if(MapVote_CheckRules_2()) // decide
2742                 return;
2743
2744         totalvotes = 0;
2745         FOR_EACH_REALCLIENT(other)
2746         {
2747                 // hide scoreboard again
2748                 if(other.health != 2342)
2749                 {
2750                         other.health = 2342;
2751                         other.impulse = 0;
2752                         if(clienttype(other) == CLIENTTYPE_REAL)
2753                         {
2754                                 msg_entity = other;
2755                                 WriteByte(MSG_ONE, SVC_FINALE);
2756                                 WriteString(MSG_ONE, "");
2757                         }
2758                 }
2759
2760                 // clear possibly invalid votes
2761                 if(mapvote_maps[other.mapvote - 1] == "")
2762                         other.mapvote = 0;
2763                 // use impulses as new vote
2764                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2765                         if(mapvote_maps[other.impulse - 1] != "")
2766                         {
2767                                 other.mapvote = other.impulse;
2768                                 MapVote_TouchVotes(other);
2769                         }
2770                 other.impulse = 0;
2771
2772                 if(other.mapvote)
2773                         ++totalvotes;
2774         }
2775
2776         MapVote_CheckRules_1(); // just count
2777 }
2778 void MapVote_Start()
2779 {
2780         if(mapvote_run)
2781                 return;
2782
2783         // wait for stats to be sent first
2784         if(!playerstats_waitforme)
2785                 return;
2786
2787         MapInfo_Enumerate();
2788         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2789                 mapvote_run = TRUE;
2790 }
2791 void MapVote_Think()
2792 {
2793         if(!mapvote_run)
2794                 return;
2795
2796         if(alreadychangedlevel)
2797                 return;
2798
2799         if(time < mapvote_nextthink)
2800                 return;
2801         //dprint("tick\n");
2802
2803         mapvote_nextthink = time + 0.5;
2804
2805         if(!mapvote_initialized)
2806         {
2807                 if(autocvar_rescan_pending == 1)
2808                 {
2809                         cvar_set("rescan_pending", "2");
2810                         localcmd("fs_rescan\nrescan_pending 3\n");
2811                         return;
2812                 }
2813                 else if(autocvar_rescan_pending == 2)
2814                 {
2815                         return;
2816                 }
2817                 else if(autocvar_rescan_pending == 3)
2818                 {
2819                         // now build missing mapinfo files
2820                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2821                                 return;
2822
2823                         // we're done, start the timer
2824                         cvar_set("rescan_pending", "0");
2825                 }
2826
2827                 mapvote_initialized = TRUE;
2828                 if(DoNextMapOverride())
2829                         return;
2830                 if(!autocvar_g_maplist_votable || player_count <= 0)
2831                 {
2832                         GotoNextMap();
2833                         return;
2834                 }
2835                 MapVote_Init();
2836         }
2837
2838         MapVote_Tick();
2839 }
2840
2841 string GotoMap(string m)
2842 {
2843         if(!MapInfo_CheckMap(m))
2844                 return "The map you chose is not available on this server.";
2845         cvar_set("nextmap", m);
2846         cvar_set("timelimit", "-1");
2847         if(mapvote_initialized || alreadychangedlevel)
2848         {
2849                 if(DoNextMapOverride())
2850                         return "Map switch initiated.";
2851                 else
2852                         return "Hm... no. For some reason I like THIS map more.";
2853         }
2854         else
2855                 return "Map switch will happen after scoreboard.";
2856 }
2857
2858
2859 void EndFrame()
2860 {
2861         float altime;
2862         FOR_EACH_REALCLIENT(self)
2863         {
2864                 if(self.classname == "spectator")
2865                 {
2866                         if(self.enemy.typehitsound)
2867                                 self.typehit_time = time;
2868                         else if(self.enemy.hitsound)
2869                                 self.hit_time = time;
2870                 }
2871                 else
2872                 {
2873                         if(self.typehitsound)
2874                                 self.typehit_time = time;
2875                         else if(self.hitsound)
2876                                 self.hit_time = time;
2877                 }
2878         }
2879         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2880         // add 1 frametime because after this, engine SV_Physics
2881         // increases time by a frametime and then networks the frame
2882         // add another frametime because client shows everything with
2883         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2884         // needed!
2885         FOR_EACH_CLIENT(self)
2886         {
2887                 self.hitsound = FALSE;
2888                 self.typehitsound = FALSE;
2889                 antilag_record(self, altime);
2890         }
2891 }
2892
2893
2894 /*
2895  * RedirectionThink:
2896  * returns TRUE if redirecting
2897  */
2898 float redirection_timeout;
2899 float redirection_nextthink;
2900 float RedirectionThink()
2901 {
2902         float clients_found;
2903
2904         if(redirection_target == "")
2905                 return FALSE;
2906
2907         if(!redirection_timeout)
2908         {
2909                 cvar_set("sv_public", "-2");
2910                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2911                 if(redirection_target == "self")
2912                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2913                 else
2914                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2915         }
2916
2917         if(time < redirection_nextthink)
2918                 return TRUE;
2919
2920         redirection_nextthink = time + 1;
2921
2922         clients_found = 0;
2923         FOR_EACH_REALCLIENT(self)
2924         {
2925                 print("Redirecting: sending connect command to ", self.netname, "\n");
2926                 if(redirection_target == "self")
2927                         stuffcmd(self, "\ndisconnect; reconnect\n");
2928                 else
2929                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2930                 ++clients_found;
2931         }
2932
2933         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2934
2935         if(time > redirection_timeout || clients_found == 0)
2936                 localcmd("\nwait; wait; wait; quit\n");
2937
2938         return TRUE;
2939 }
2940
2941 void TargetMusic_RestoreGame();
2942 void RestoreGame()
2943 {
2944         // Loaded from a save game
2945         // some things then break, so let's work around them...
2946
2947         // Progs DB (capture records)
2948         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2949
2950         // Mapinfo
2951         MapInfo_Shutdown();
2952         MapInfo_Enumerate();
2953         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2954         WeaponStats_Init();
2955
2956         TargetMusic_RestoreGame();
2957 }
2958
2959 void SV_Shutdown()
2960 {
2961         entity e;
2962
2963         if(gameover > 1) // shutting down already?
2964                 return;
2965
2966         gameover = 2; // 2 = server shutting down
2967
2968         if(world_initialized > 0)
2969         {
2970                 world_initialized = 0;
2971                 print("Saving persistent data...\n");
2972                 Ban_SaveBans();
2973
2974                 PlayerStats_EndMatch(0);
2975                 FOR_EACH_CLIENT(e)
2976                         PlayerStats_AddGlobalInfo(e);
2977                 PlayerStats_Shutdown();
2978
2979                 if(!cheatcount_total)
2980                 {
2981                         if(autocvar_sv_db_saveasdump)
2982                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2983                         else
2984                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2985                 }
2986                 if(autocvar_developer)
2987                 {
2988                         if(autocvar_sv_db_saveasdump)
2989                                 db_dump(TemporaryDB, "server-temp.db");
2990                         else
2991                                 db_save(TemporaryDB, "server-temp.db");
2992                 }
2993                 CheatShutdown(); // must be after cheatcount check
2994                 db_close(ServerProgsDB);
2995                 db_close(TemporaryDB);
2996                 print("done!\n");
2997                 // tell the bot system the game is ending now
2998                 bot_endgame();
2999
3000                 WeaponStats_Shutdown();
3001                 MapInfo_Shutdown();
3002         }
3003         else if(world_initialized == 0)
3004         {
3005                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
3006         }
3007 }