qcsrc/server/g_world.qc

   1 #define LATENCY_THINKRATE 10
   2 .float latency_sum;
   3 .float latency_cnt;
   4 .float latency_time;
   5 entity pingplreport;
   6 void PingPLReport_Think()
   7 {
   8         float delta;
   9         entity e;
  10
  11         delta = 3 / maxclients;
  12         if(delta < sys_frametime)
  13                 delta = 0;
  14         self.nextthink = time + delta;
  15
  16         e = edict_num(self.cnt + 1);
  17         if(IS_REAL_CLIENT(e))
  18         {
  19                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  20                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  21                 WriteByte(MSG_BROADCAST, self.cnt);
  22                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  23                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  24                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  25
  26                 // record latency times for clients throughout the match so we can report it to playerstats
  27                 if(time > (e.latency_time + LATENCY_THINKRATE))
  28                 {
  29                         e.latency_sum += e.ping;
  30                         e.latency_cnt += 1;
  31                         e.latency_time = time;
  32                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  33                 }
  34         }
  35         else
  36         {
  37                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  38                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  39                 WriteByte(MSG_BROADCAST, self.cnt);
  40                 WriteShort(MSG_BROADCAST, 0);
  41                 WriteByte(MSG_BROADCAST, 0);
  42                 WriteByte(MSG_BROADCAST, 0);
  43         }
  44         self.cnt = mod(self.cnt + 1, maxclients);
  45 }
  46 void PingPLReport_Spawn()
  47 {
  48         pingplreport = spawn();
  49         pingplreport.classname = "pingplreport";
  50         pingplreport.think = PingPLReport_Think;
  51         pingplreport.nextthink = time;
  52 }
  53
  54 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  55 string redirection_target;
  56 float world_initialized;
  57
  58 string GetMapname();
  59 string GetGametype();
  60 void GotoNextMap(float reinit);
  61 void ShuffleMaplist();
  62 float(float reinit) DoNextMapOverride;
  63
  64 void SetDefaultAlpha()
  65 {
  66         if(autocvar_g_running_guns)
  67         {
  68                 default_player_alpha = -1;
  69                 default_weapon_alpha = +1;
  70         }
  71         else if(g_cloaked)
  72         {
  73                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  74                 default_weapon_alpha = default_player_alpha;
  75         }
  76         else
  77         {
  78                 default_player_alpha = autocvar_g_player_alpha;
  79                 if(default_player_alpha == 0)
  80                         default_player_alpha = 1;
  81                 default_weapon_alpha = default_player_alpha;
  82         }
  83 }
  84
  85 void fteqcc_testbugs()
  86 {
  87         float a, b;
  88
  89         if(!autocvar_developer_fteqccbugs)
  90                 return;
  91
  92         dprint("*** fteqcc test: checking for bugs...\n");
  93
  94         a = 1;
  95         b = 5;
  96         if(sqrt(a) - sqrt(b - a) == 0)
  97                 dprint("*** fteqcc test: found same-function-twice bug\n");
  98         else
  99                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
 100
 101         world.cnt = -10;
 102         world.enemy = world;
 103         world.enemy.cnt += 10;
 104         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
 105                 dprint("*** fteqcc test: found += bug\n");
 106         else
 107                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
 108         world.cnt = 0;
 109 }
 110
 111 void GotoFirstMap()
 112 {
 113         float n;
 114         if(autocvar__sv_init)
 115         {
 116                 // cvar_set("_sv_init", "0");
 117                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 118                 // to this "init" map on a dedicated server will cause no permanent
 119                 // harm
 120                 if(autocvar_g_maplist_shuffle)
 121                         ShuffleMaplist();
 122                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 123                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 124
 125                 MapInfo_Enumerate();
 126                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 127
 128                 if(!DoNextMapOverride(1))
 129                         GotoNextMap(1);
 130
 131                 return;
 132         }
 133
 134         if(time < 5)
 135         {
 136                 self.nextthink = time;
 137         }
 138         else
 139         {
 140                 self.nextthink = time + 1;
 141                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 142         }
 143 }
 144
 145 void cvar_changes_init()
 146 {
 147         float h;
 148         string k, v, d;
 149         float n, i, adding, pureadding;
 150
 151         if(cvar_changes)
 152                 strunzone(cvar_changes);
 153         cvar_changes = string_null;
 154         if(cvar_purechanges)
 155                 strunzone(cvar_purechanges);
 156         cvar_purechanges = string_null;
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = TRUE;
 164         pureadding = TRUE;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173
 174                 // general excludes and namespaces for server admin used cvars
 175                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 176
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("log_file");
 220                 BADCVAR("net_address");
 221                 BADCVAR("net_address_ipv6");
 222                 BADCVAR("port");
 223                 BADCVAR("savedgamecfg");
 224                 BADCVAR("serverconfig");
 225                 BADCVAR("sv_autoscreenshot");
 226                 BADCVAR("sv_heartbeatperiod");
 227                 BADCVAR("sv_vote_master_password");
 228                 BADCVAR("sys_colortranslation");
 229                 BADCVAR("sys_specialcharactertranslation");
 230                 BADCVAR("timeformat");
 231                 BADCVAR("timestamps");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_chat_flood_");
 236                 BADPREFIX("g_ghost_items");
 237                 BADPREFIX("g_playerstats_");
 238                 BADPREFIX("g_respawn_ghosts");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("rcon_");
 241                 BADPREFIX("sv_allowdownloads");
 242                 BADPREFIX("sv_autodemo");
 243                 BADPREFIX("sv_curl_");
 244                 BADPREFIX("sv_eventlog");
 245                 BADPREFIX("sv_logscores_");
 246                 BADPREFIX("sv_master");
 247                 BADPREFIX("sv_weaponstats_");
 248                 BADPREFIX("sv_waypointsprite_");
 249                 BADCVAR("rescan_pending");
 250
 251                 // these can contain player IDs, so better hide
 252                 BADPREFIX("g_forced_team_");
 253
 254                 // mapinfo
 255                 BADCVAR("fraglimit");
 256                 BADCVAR("g_arena");
 257                 BADCVAR("g_assault");
 258                 BADCVAR("g_ca");
 259                 BADCVAR("g_ca_teams");
 260                 BADCVAR("g_ctf");
 261                 BADCVAR("g_cts");
 262                 BADCVAR("g_dm");
 263                 BADCVAR("g_domination");
 264                 BADCVAR("g_domination_default_teams");
 265                 BADCVAR("g_freezetag");
 266                 BADCVAR("g_freezetag_teams");
 267                 BADCVAR("g_keepaway");
 268                 BADCVAR("g_keyhunt");
 269                 BADCVAR("g_keyhunt_teams");
 270                 BADCVAR("g_lms");
 271                 BADCVAR("g_nexball");
 272                 BADCVAR("g_onslaught");
 273                 BADCVAR("g_race");
 274                 BADCVAR("g_race_qualifying_timelimit");
 275                 BADCVAR("g_tdm");
 276                 BADCVAR("g_tdm_teams");
 277                 BADCVAR("leadlimit");
 278                 BADCVAR("nextmap");
 279                 BADCVAR("teamplay");
 280                 BADCVAR("timelimit");
 281
 282                 // long
 283                 BADCVAR("hostname");
 284                 BADCVAR("g_maplist");
 285                 BADCVAR("g_maplist_mostrecent");
 286                 BADCVAR("sv_motd");
 287
 288                 v = cvar_string(k);
 289                 d = cvar_defstring(k);
 290                 if(v == d)
 291                         continue;
 292
 293                 if(adding)
 294                 {
 295                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 296                         if(strlen(cvar_changes) > 16384)
 297                         {
 298                                 cvar_changes = "// too many settings have been changed to show them here\n";
 299                                 adding = 0;
 300                         }
 301                 }
 302
 303                 // now check if the changes are actually gameplay relevant
 304
 305                 // does nothing visible
 306                 BADCVAR("captureleadlimit_override");
 307                 BADCVAR("g_arena_point_leadlimit");
 308                 BADCVAR("g_balance_kill_delay");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ctf_captimerecord_always");
 311                 BADCVAR("g_ctf_flag_glowtrails");
 312                 BADCVAR("g_ctf_flag_pickup_verbosename");
 313                 BADCVAR("g_domination_point_leadlimit");
 314                 BADCVAR("g_forced_respawn");
 315                 BADCVAR("g_keyhunt_point_leadlimit");
 316                 BADPREFIX("g_mod_");
 317                 BADCVAR("g_nexball_goalleadlimit");
 318                 BADCVAR("leadlimit_and_fraglimit");
 319                 BADCVAR("leadlimit_override");
 320                 BADCVAR("pausable");
 321                 BADCVAR("sv_allow_fullbright");
 322                 BADCVAR("sv_checkforpacketsduringsleep");
 323                 BADCVAR("sv_fraginfo");
 324                 BADCVAR("sv_timeout");
 325                 BADPREFIX("sv_timeout_");
 326                 BADCVAR("welcome_message_time");
 327                 BADPREFIX("crypto_");
 328                 BADPREFIX("g_chat_");
 329                 BADPREFIX("g_ctf_captimerecord_");
 330                 BADPREFIX("g_maplist_votable_");
 331                 BADPREFIX("net_");
 332                 BADPREFIX("prvm_");
 333                 BADPREFIX("skill_");
 334                 BADPREFIX("sv_cullentities_");
 335                 BADPREFIX("sv_fraginfo_");
 336                 BADPREFIX("sv_maxidle_");
 337                 BADPREFIX("sv_vote_");
 338                 BADPREFIX("timelimit_");
 339                 BADCVAR("gameversion");
 340                 BADPREFIX("gameversion_");
 341                 BADCVAR("sv_namechangetimer");
 342
 343                 // allowed changes to server admins (please sync this to server.cfg)
 344                 // vi commands:
 345                 //   :/"impure"/,$d
 346                 //   :g!,^\/\/[^ /],d
 347                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 348                 //   :%!sort
 349                 // yes, this does contain some redundant stuff, don't really care
 350                 BADCVAR("bot_config_file");
 351                 BADCVAR("bot_number");
 352                 BADCVAR("bot_prefix");
 353                 BADCVAR("bot_suffix");
 354                 BADCVAR("capturelimit_override");
 355                 BADCVAR("fraglimit_override");
 356                 BADCVAR("gametype");
 357                 BADCVAR("g_antilag");
 358                 BADCVAR("g_balance_teams");
 359                 BADCVAR("g_balance_teams_prevent_imbalance");
 360                 BADCVAR("g_balance_teams_scorefactor");
 361                 BADCVAR("g_ban_sync_trusted_servers");
 362                 BADCVAR("g_ban_sync_uri");
 363                 BADCVAR("g_ca_teams_override");
 364                 BADCVAR("g_ctf_ignore_frags");
 365                 BADCVAR("g_domination_point_limit");
 366                 BADCVAR("g_freezetag_teams_override");
 367                 BADCVAR("g_friendlyfire");
 368                 BADCVAR("g_fullbrightitems");
 369                 BADCVAR("g_fullbrightplayers");
 370                 BADCVAR("g_keyhunt_point_limit");
 371                 BADCVAR("g_keyhunt_teams_override");
 372                 BADCVAR("g_lms_lives_override");
 373                 BADCVAR("g_maplist");
 374                 BADCVAR("g_maplist_check_waypoints");
 375                 BADCVAR("g_maplist_mostrecent_count");
 376                 BADCVAR("g_maplist_shuffle");
 377                 BADCVAR("g_maplist_votable");
 378                 BADCVAR("g_maplist_votable_abstain");
 379                 BADCVAR("g_maplist_votable_nodetail");
 380                 BADCVAR("g_maplist_votable_suggestions");
 381                 BADCVAR("g_maxplayers");
 382                 BADCVAR("g_mirrordamage");
 383                 BADCVAR("g_nexball_goallimit");
 384                 BADCVAR("g_powerups");
 385                 BADCVAR("g_start_delay");
 386                 BADCVAR("g_warmup");
 387                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 388                 BADCVAR("hostname");
 389                 BADCVAR("log_file");
 390                 BADCVAR("maxplayers");
 391                 BADCVAR("minplayers");
 392                 BADCVAR("net_address");
 393                 BADCVAR("port");
 394                 BADCVAR("rcon_password");
 395                 BADCVAR("rcon_restricted_commands");
 396                 BADCVAR("rcon_restricted_password");
 397                 BADCVAR("skill");
 398                 BADCVAR("sv_adminnick");
 399                 BADCVAR("sv_autoscreenshot");
 400                 BADCVAR("sv_autotaunt");
 401                 BADCVAR("sv_curl_defaulturl");
 402                 BADCVAR("sv_defaultcharacter");
 403                 BADCVAR("sv_defaultplayercolors");
 404                 BADCVAR("sv_defaultplayermodel");
 405                 BADCVAR("sv_defaultplayerskin");
 406                 BADCVAR("sv_maxidle");
 407                 BADCVAR("sv_maxrate");
 408                 BADCVAR("sv_motd");
 409                 BADCVAR("sv_public");
 410                 BADCVAR("sv_ready_restart");
 411                 BADCVAR("sv_status_privacy");
 412                 BADCVAR("sv_taunt");
 413                 BADCVAR("sv_vote_call");
 414                 BADCVAR("sv_vote_commands");
 415                 BADCVAR("sv_vote_majority_factor");
 416                 BADCVAR("sv_vote_master");
 417                 BADCVAR("sv_vote_master_commands");
 418                 BADCVAR("sv_vote_master_password");
 419                 BADCVAR("sv_vote_simple_majority_factor");
 420                 BADCVAR("sys_ticrate");
 421                 BADCVAR("teamplay_mode");
 422                 BADCVAR("timelimit_override");
 423                 BADCVAR("g_spawnshieldtime");
 424                 BADPREFIX("g_warmup_");
 425                 BADPREFIX("sv_ready_restart_");
 426
 427                 // mutators that announce themselves properly to the server browser
 428                 BADCVAR("g_minstagib");
 429                 BADCVAR("g_new_toys");
 430                 BADCVAR("g_nix");
 431                 BADCVAR("g_grappling_hook");
 432                 BADCVAR("g_jetpack");
 433
 434 #undef BADPREFIX
 435 #undef BADCVAR
 436
 437                 if(pureadding)
 438                 {
 439                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 440                         if(strlen(cvar_purechanges) > 16384)
 441                         {
 442                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 443                                 pureadding = 0;
 444                         }
 445                 }
 446                 ++cvar_purechanges_count;
 447                 // WARNING: this variable is used for the server list
 448                 // NEVER dare to skip this code!
 449                 // Hacks to intentionally appearing as "pure server" even though you DO have
 450                 // modified settings may be punished by removal from the server list.
 451                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 452                 // though.
 453         }
 454         buf_del(h);
 455         if(cvar_changes == "")
 456                 cvar_changes = "// this server runs at default server settings\n";
 457         else
 458                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 459         cvar_changes = strzone(cvar_changes);
 460         if(cvar_purechanges == "")
 461                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 462         else
 463                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 464         cvar_purechanges = strzone(cvar_purechanges);
 465 }
 466
 467 void detect_maptype()
 468 {
 469 #if 0
 470         vector o, v;
 471         float i;
 472
 473         for(;;)
 474         {
 475                 o = world.mins;
 476                 o_x += random() * (world.maxs_x - world.mins_x);
 477                 o_y += random() * (world.maxs_y - world.mins_y);
 478                 o_z += random() * (world.maxs_z - world.mins_z);
 479
 480                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 481                 if(trace_fraction == 1)
 482                         continue;
 483
 484                 v = trace_endpos;
 485
 486                 for(i = 0; i < 64; i += 4)
 487                 {
 488                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 489         if(trace_fraction == 1)
 490                 continue;
 491                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 492                 }
 493
 494                 break;
 495         }
 496 #endif
 497 }
 498
 499 entity randomseed;
 500 float RandomSeed_Send(entity to, float sf)
 501 {
 502         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 503         WriteShort(MSG_ENTITY, self.cnt);
 504         return TRUE;
 505 }
 506 void RandomSeed_Think()
 507 {
 508         self.cnt = bound(0, floor(random() * 65536), 65535);
 509         self.nextthink = time + 5;
 510
 511         self.SendFlags |= 1;
 512 }
 513 void RandomSeed_Spawn()
 514 {
 515         randomseed = spawn();
 516         randomseed.think = RandomSeed_Think;
 517         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 518
 519         entity oldself;
 520         oldself = self;
 521         self = randomseed;
 522         self.think(); // sets random seed and nextthink
 523         self = oldself;
 524 }
 525
 526 void spawnfunc___init_dedicated_server(void)
 527 {
 528         // handler for _init/_init map (only for dedicated server initialization)
 529
 530         world_initialized = -1; // don't complain
 531         cvar = cvar_normal;
 532         cvar_string = cvar_string_normal;
 533         cvar_set = cvar_set_normal;
 534
 535         remove = remove_unsafely;
 536
 537         entity e;
 538         e = spawn();
 539         e.think = GotoFirstMap;
 540         e.nextthink = time; // this is usually 1 at this point
 541
 542         e = spawn();
 543         e.classname = "info_player_deathmatch"; // safeguard against player joining
 544
 545         self.classname = "worldspawn"; // safeguard against various stuff ;)
 546
 547         // needs to be done so early because of the constants they create
 548         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 549         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 550         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 551         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 552
 553         MapInfo_Enumerate();
 554         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 555 }
 556
 557 void Map_MarkAsRecent(string m);
 558 float world_already_spawned;
 559 void Nagger_Init();
 560 void ClientInit_Spawn();
 561 void WeaponStats_Init();
 562 void WeaponStats_Shutdown();
 563 void spawnfunc_worldspawn (void)
 564 {
 565         float fd, l, i, j, n;
 566         string s, col;
 567
 568         cvar = cvar_normal;
 569         cvar_string = cvar_string_normal;
 570         cvar_set = cvar_set_normal;
 571
 572         if(world_already_spawned)
 573                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 574         world_already_spawned = TRUE;
 575
 576         remove = remove_safely; // during spawning, watch what you remove!
 577
 578         check_unacceptable_compiler_bugs();
 579
 580         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 581
 582         compressShortVector_init();
 583
 584         entity head;
 585         head = nextent(world);
 586         maxclients = 0;
 587         while(head)
 588         {
 589                 ++maxclients;
 590                 head = nextent(head);
 591         }
 592
 593         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? TRUE : FALSE);
 594
 595         // needs to be done so early because of the constants they create
 596         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 597         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 598         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 599         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 600
 601         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 602
 603         TemporaryDB = db_create();
 604
 605         // 0 normal
 606         lightstyle(0, "m");
 607
 608         // 1 FLICKER (first variety)
 609         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 610
 611         // 2 SLOW STRONG PULSE
 612         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 613
 614         // 3 CANDLE (first variety)
 615         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 616
 617         // 4 FAST STROBE
 618         lightstyle(4, "mamamamamama");
 619
 620         // 5 GENTLE PULSE 1
 621         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 622
 623         // 6 FLICKER (second variety)
 624         lightstyle(6, "nmonqnmomnmomomno");
 625
 626         // 7 CANDLE (second variety)
 627         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 628
 629         // 8 CANDLE (third variety)
 630         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 631
 632         // 9 SLOW STROBE (fourth variety)
 633         lightstyle(9, "aaaaaaaazzzzzzzz");
 634
 635         // 10 FLUORESCENT FLICKER
 636         lightstyle(10, "mmamammmmammamamaaamammma");
 637
 638         // 11 SLOW PULSE NOT FADE TO BLACK
 639         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 640
 641         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 642
 643         // 63 testing
 644         lightstyle(63, "a");
 645
 646         if(autocvar_g_campaign)
 647                 CampaignPreInit();
 648
 649         Map_MarkAsRecent(mapname);
 650
 651         PlayerStats_Init(); // we need this to be initiated before InitGameplayMode
 652
 653         precache_model ("null"); // we need this one before InitGameplayMode
 654         InitGameplayMode();
 655         readlevelcvars();
 656         GrappleHookInit();
 657         ElectroInit();
 658         LaserInit();
 659
 660         player_count = 0;
 661         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 662         if(bot_waypoints_for_items == 1)
 663                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 664                         bot_waypoints_for_items = 0;
 665
 666         precache();
 667
 668         WaypointSprite_Init();
 669
 670         GameLogInit(); // prepare everything
 671         // NOTE for matchid:
 672         // changing the logic generating it is okay. But:
 673         // it HAS to stay <= 64 chars
 674         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 675         if(autocvar_sv_eventlog)
 676         {
 677                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 678                 matchid = strzone(s);
 679
 680                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 681                 s = ":gameinfo:mutators:LIST";
 682
 683                 ret_string = s;
 684                 MUTATOR_CALLHOOK(BuildMutatorsString);
 685                 s = ret_string;
 686
 687                 // simple, probably not good in the mutator system
 688                 if(autocvar_g_grappling_hook)
 689                         s = strcat(s, ":grappling_hook");
 690
 691                 // initialiation stuff, not good in the mutator system
 692                 if(!autocvar_g_use_ammunition)
 693                         s = strcat(s, ":no_use_ammunition");
 694
 695                 // initialiation stuff, not good in the mutator system
 696                 if(autocvar_g_pickup_items == 0)
 697                         s = strcat(s, ":no_pickup_items");
 698                 if(autocvar_g_pickup_items > 0)
 699                         s = strcat(s, ":pickup_items");
 700
 701                 // initialiation stuff, not good in the mutator system
 702                 if(autocvar_g_weaponarena != "0")
 703                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 704
 705                 // TODO to mutator system
 706                 if(autocvar_g_powerups == 0)
 707                         s = strcat(s, ":no_powerups");
 708                 if(autocvar_g_powerups > 0)
 709                         s = strcat(s, ":powerups");
 710
 711                 GameLogEcho(s);
 712                 GameLogEcho(":gameinfo:end");
 713         }
 714         else
 715                 matchid = strzone(ftos(random()));
 716
 717         cvar_set("nextmap", "");
 718
 719         SetDefaultAlpha();
 720
 721         if(autocvar_g_campaign)
 722                 CampaignPostInit();
 723
 724         fteqcc_testbugs();
 725
 726         Ban_LoadBans();
 727
 728         MapInfo_Enumerate();
 729         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 730
 731         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 732         {
 733                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 734                 if(fd != -1)
 735                 {
 736                         while((s = fgets(fd)))
 737                         {
 738                                 l = tokenize_console(s);
 739                                 if(l < 2)
 740                                         continue;
 741                                 if(argv(0) == "cd")
 742                                 {
 743                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 744                                         print("  cdtrack ", argv(2), "\n");
 745                                 }
 746                                 else if(argv(0) == "fog")
 747                                 {
 748                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 749                                         print("  \"fog\" \"", s, "\"\n");
 750                                 }
 751                                 else if(argv(0) == "set")
 752                                 {
 753                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 754                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 755                                 }
 756                                 else if(argv(0) != "//")
 757                                 {
 758                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 759                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 760                                 }
 761                         }
 762                         fclose(fd);
 763                 }
 764         }
 765
 766         WeaponStats_Init();
 767
 768         WEPSET_ADDSTAT();
 769         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 770         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 771         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 772         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 773         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 774         Nagger_Init();
 775
 776         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 777         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 778         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 779         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 780         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 781         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 782         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 783         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 784         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 785         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 786         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 787         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 788         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 789
 790         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 791         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 792
 793         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 794
 795         // g_movementspeed hack
 796         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 797         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 798         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 799         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 800
 801         // secrets
 802         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 803         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 804
 805         // misc
 806         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 807
 808         next_pingtime = time + 5;
 809
 810         detect_maptype();
 811
 812         // set up information replies for clients and server to use
 813         lsmaps_reply = "^7Maps available: ";
 814         lsnewmaps_reply = "^7Maps without a record set: ";
 815         for(i = 0, j = 0; i < MapInfo_count; ++i)
 816         {
 817                 if(MapInfo_Get_ByID(i))
 818                         if not(MapInfo_Map_flags & MapInfo_ForbiddenFlags())
 819                         {
 820                                 if(mod(i, 2))
 821                                         col = "^2";
 822                                 else
 823                                         col = "^3";
 824
 825                                 ++j;
 826
 827                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 828
 829                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 830                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 831                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 832                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 833                         }
 834         }
 835
 836         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 837         lsnewmaps_reply = strzone(strcat(((!g_race && !g_cts) ? "Need to be playing race or CTS for lsnewmaps to work." : lsnewmaps_reply), "\n"));
 838
 839         maplist_reply = "^7Maps in list: ";
 840         n = tokenize_console(autocvar_g_maplist);
 841         for(i = 0, j = 0; i < n; ++i)
 842         {
 843                 if(MapInfo_CheckMap(argv(i)))
 844                 {
 845                         if(mod(j, 2))
 846                                 col = "^2";
 847                         else
 848                                 col = "^3";
 849                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 850                         ++j;
 851                 }
 852         }
 853         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 854         MapInfo_ClearTemps();
 855
 856         for(i = 0; i < 10; ++i)
 857         {
 858                 s = getrecords(i);
 859                 if (s)
 860                         records_reply[i] = strzone(s);
 861         }
 862
 863         ladder_reply = strzone(getladder());
 864
 865         rankings_reply = strzone(getrankings());
 866
 867         // begin other init
 868         ClientInit_Spawn();
 869         RandomSeed_Spawn();
 870         PingPLReport_Spawn();
 871
 872         CheatInit();
 873
 874         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 875
 876         // fill sv_curl_serverpackages from .serverpackage files
 877         if(autocvar_sv_curl_serverpackages_auto)
 878         {
 879                 s = "";
 880                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 881                 for(i = 0; i < n; ++i)
 882                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 883                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 884                                 s = strcat(s, " ", argv(i));
 885                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 886                 if(fd >= 0)
 887                 {
 888                         j = search_getsize(fd);
 889                         for(i = 0; i < j; ++i)
 890                                 s = strcat(s, " ", search_getfilename(fd, i));
 891                         search_end(fd);
 892                 }
 893                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 894                 if(fd >= 0)
 895                 {
 896                         j = search_getsize(fd);
 897                         for(i = 0; i < j; ++i)
 898                                 s = strcat(s, " ", search_getfilename(fd, i));
 899                         search_end(fd);
 900                 }
 901                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 902         }
 903
 904         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 905         modname = "Xonotic";
 906         // physics/balance/config changes that count as mod
 907         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 908                 modname = cvar_string("g_mod_physics");
 909         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 910                 modname = cvar_string("g_mod_balance");
 911         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 912                 modname = cvar_string("g_mod_config");
 913         // extra mutators that deserve to count as mod
 914         MUTATOR_CALLHOOK(SetModname);
 915
 916         // save it for later
 917         modname = strzone(modname);
 918
 919         WinningConditionHelper(); // set worldstatus
 920
 921         world_initialized = 1;
 922 }
 923
 924 void spawnfunc_light (void)
 925 {
 926         //makestatic (self); // Who the f___ did that?
 927         remove(self);
 928 }
 929
 930 string GetGametype()
 931 {
 932         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 933 }
 934
 935 string getmapname_stored;
 936 string GetMapname()
 937 {
 938         return mapname;
 939 }
 940
 941 float Map_Count, Map_Current;
 942 string Map_Current_Name;
 943
 944 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 945 float GetMaplistPosition()
 946 {
 947         float pos, idx;
 948         string map;
 949
 950         map = GetMapname();
 951         idx = autocvar_g_maplist_index;
 952
 953         if(idx >= 0)
 954                 if(idx < Map_Count)
 955                         if(map == argv(idx))
 956                                 return idx;
 957
 958         for(pos = 0; pos < Map_Count; ++pos)
 959                 if(map == argv(pos))
 960                         return pos;
 961
 962         // resume normal maplist rotation if current map is not in g_maplist
 963         return idx;
 964 }
 965
 966 float MapHasRightSize(string map)
 967 {
 968         float fh;
 969         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 970         if(autocvar_g_maplist_check_waypoints)
 971         {
 972                 dprint("checkwp "); dprint(map);
 973                 if(!fexists(strcat("maps/", map, ".waypoints")))
 974                 {
 975                         dprint(": no waypoints\n");
 976                         return FALSE;
 977                 }
 978                 dprint(": has waypoints\n");
 979         }
 980
 981         // open map size restriction file
 982         dprint("opensize "); dprint(map);
 983         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 984         if(fh >= 0)
 985         {
 986                 float mapmin, mapmax;
 987                 dprint(": ok, ");
 988                 mapmin = stof(fgets(fh));
 989                 mapmax = stof(fgets(fh));
 990                 fclose(fh);
 991                 if(player_count < mapmin)
 992                 {
 993                         dprint("not enough\n");
 994                         return FALSE;
 995                 }
 996                 if(player_count > mapmax)
 997                 {
 998                         dprint("too many\n");
 999                         return FALSE;
1000                 }
1001                 dprint("right size\n");
1002                 return TRUE;
1003         }
1004         dprint(": not found\n");
1005         return TRUE;
1006 }
1007
1008 string Map_Filename(float position)
1009 {
1010         return strcat("maps/", argv(position), ".bsp");
1011 }
1012
1013 string strwords(string s, float w)
1014 {
1015         float endpos;
1016         for(endpos = 0; w && endpos >= 0; --w)
1017                 endpos = strstrofs(s, " ", endpos + 1);
1018         if(endpos < 0)
1019                 return s;
1020         else
1021                 return substring(s, 0, endpos);
1022 }
1023
1024 float strhasword(string s, string w)
1025 {
1026         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1027 }
1028
1029 void Map_MarkAsRecent(string m)
1030 {
1031         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1032 }
1033
1034 float Map_IsRecent(string m)
1035 {
1036         return strhasword(autocvar_g_maplist_mostrecent, m);
1037 }
1038
1039 float Map_Check(float position, float pass)
1040 {
1041         string filename;
1042         string map_next;
1043         map_next = argv(position);
1044         if(pass <= 1)
1045         {
1046                 if(Map_IsRecent(map_next))
1047                         return 0;
1048         }
1049         filename = Map_Filename(position);
1050         if(MapInfo_CheckMap(map_next))
1051         {
1052                 if(pass == 2)
1053                         return 1;
1054                 if(MapHasRightSize(map_next))
1055                         return 1;
1056                 return 0;
1057         }
1058         else
1059                 dprint( "Couldn't select '", filename, "'..\n" );
1060
1061         return 0;
1062 }
1063
1064 void Map_Goto_SetStr(string nextmapname)
1065 {
1066         if(getmapname_stored != "")
1067                 strunzone(getmapname_stored);
1068         if(nextmapname == "")
1069                 getmapname_stored = "";
1070         else
1071                 getmapname_stored = strzone(nextmapname);
1072 }
1073
1074 void Map_Goto_SetFloat(float position)
1075 {
1076         cvar_set("g_maplist_index", ftos(position));
1077         Map_Goto_SetStr(argv(position));
1078 }
1079
1080 void Map_Goto(float reinit)
1081 {
1082         MapInfo_LoadMap(getmapname_stored, reinit);
1083 }
1084
1085 // return codes of map selectors:
1086 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1087 //   -2 = permanent failure
1088 float() MaplistMethod_Iterate = // usual method
1089 {
1090         float pass, i;
1091
1092         for(pass = 1; pass <= 2; ++pass)
1093         {
1094                 for(i = 1; i < Map_Count; ++i)
1095                 {
1096                         float mapindex;
1097                         mapindex = mod(i + Map_Current, Map_Count);
1098                         if(Map_Check(mapindex, pass))
1099                                 return mapindex;
1100                 }
1101         }
1102         return -1;
1103 }
1104
1105 float() MaplistMethod_Repeat = // fallback method
1106 {
1107         if(Map_Check(Map_Current, 2))
1108                 return Map_Current;
1109         return -2;
1110 }
1111
1112 float() MaplistMethod_Random = // random map selection
1113 {
1114         float i, imax;
1115
1116         imax = 42;
1117
1118         for(i = 0; i <= imax; ++i)
1119         {
1120                 float mapindex;
1121                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1122                 if(Map_Check(mapindex, 1))
1123                         return mapindex;
1124         }
1125         return -1;
1126 }
1127
1128 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1129 // the exponent sets a bias on the map selection:
1130 // the higher the exponent, the less likely "shortly repeated" same maps are
1131 {
1132         float i, j, imax, insertpos;
1133
1134         imax = 42;
1135
1136         for(i = 0; i <= imax; ++i)
1137         {
1138                 string newlist;
1139
1140                 // now reinsert this at another position
1141                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1142                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1143                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1144                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1145
1146                 // insert the current map there
1147                 newlist = "";
1148                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1149                         newlist = strcat(newlist, " ", argv(j));
1150                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1151                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1152                         newlist = strcat(newlist, " ", argv(j));
1153                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1154                 cvar_set("g_maplist", newlist);
1155                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1156
1157                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1158                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1159                 if(Map_Check(Map_Current, 1))
1160                         return Map_Current;
1161         }
1162         return -1;
1163 }
1164
1165 void Maplist_Init()
1166 {
1167         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1168         if(Map_Count == 0)
1169         {
1170                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1171                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1172                 if(autocvar_g_maplist_shuffle)
1173                         ShuffleMaplist();
1174                 localcmd("\nmenu_cmd sync\n");
1175                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1176         }
1177         if(Map_Count == 0)
1178                 error("empty maplist, cannot select a new map");
1179         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1180
1181         if(Map_Current_Name)
1182                 strunzone(Map_Current_Name);
1183         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1184         // this may or may not be correct, but who cares, in the worst case a map
1185         // isn't chosen in the first pass that should have been
1186 }
1187
1188 string GetNextMap()
1189 {
1190         float nextMap;
1191
1192         Maplist_Init();
1193         nextMap = -1;
1194
1195         if(nextMap == -1)
1196                 if(autocvar_g_maplist_shuffle > 0)
1197                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1198
1199         if(nextMap == -1)
1200                 if(autocvar_g_maplist_selectrandom)
1201                         nextMap = MaplistMethod_Random();
1202
1203         if(nextMap == -1)
1204                 nextMap = MaplistMethod_Iterate();
1205
1206         if(nextMap == -1)
1207                 nextMap = MaplistMethod_Repeat();
1208
1209         if(nextMap >= 0)
1210         {
1211                 Map_Goto_SetFloat(nextMap);
1212                 return getmapname_stored;
1213         }
1214
1215         return "";
1216 }
1217
1218 float DoNextMapOverride(float reinit)
1219 {
1220         if(autocvar_g_campaign)
1221         {
1222                 CampaignPostIntermission();
1223                 alreadychangedlevel = TRUE;
1224                 return TRUE;
1225         }
1226         if(autocvar_quit_when_empty)
1227         {
1228                 if(player_count <= currentbots)
1229                 {
1230                         localcmd("quit\n");
1231                         alreadychangedlevel = TRUE;
1232                         return TRUE;
1233                 }
1234         }
1235         if(autocvar_quit_and_redirect != "")
1236         {
1237                 redirection_target = strzone(autocvar_quit_and_redirect);
1238                 alreadychangedlevel = TRUE;
1239                 return TRUE;
1240         }
1241         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1242         {
1243                 localcmd("restart\n");
1244                 alreadychangedlevel = TRUE;
1245                 return TRUE;
1246         }
1247         if(autocvar_nextmap != "")
1248                 if(MapInfo_CheckMap(autocvar_nextmap))
1249                 {
1250                         Map_Goto_SetStr(autocvar_nextmap);
1251                         Map_Goto(reinit);
1252                         alreadychangedlevel = TRUE;
1253                         return TRUE;
1254                 }
1255         if(!reinit && autocvar_lastlevel)
1256         {
1257                 cvar_settemp_restore();
1258                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1259                 alreadychangedlevel = TRUE;
1260                 return TRUE;
1261         }
1262         return FALSE;
1263 }
1264
1265 void GotoNextMap(float reinit)
1266 {
1267         //string nextmap;
1268         //float n, nummaps;
1269         //string s;
1270         if (alreadychangedlevel)
1271                 return;
1272         alreadychangedlevel = TRUE;
1273
1274         {
1275                 string nextMap;
1276                 float allowReset;
1277
1278                 for(allowReset = 1; allowReset >= 0; --allowReset)
1279                 {
1280                         nextMap = GetNextMap();
1281                         if(nextMap != "")
1282                                 break;
1283
1284                         if(allowReset)
1285                         {
1286                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1287                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1288                                 if(autocvar_g_maplist_shuffle)
1289                                         ShuffleMaplist();
1290                                 localcmd("\nmenu_cmd sync\n");
1291                         }
1292                         else
1293                         {
1294                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1295                         }
1296                 }
1297                 Map_Goto(reinit);
1298         }
1299 }
1300
1301
1302 /*
1303 ============
1304 IntermissionThink
1305
1306 When the player presses attack or jump, change to the next level
1307 ============
1308 */
1309 .float autoscreenshot;
1310 void() MapVote_Start;
1311 void() MapVote_Think;
1312 float mapvote_initialized;
1313 void IntermissionThink()
1314 {
1315         FixIntermissionClient(self);
1316
1317         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1318         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1319
1320         if( (server_screenshot || client_screenshot)
1321                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1322         {
1323                 self.autoscreenshot = -1;
1324                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1325                 return;
1326         }
1327
1328         if (time < intermission_exittime)
1329                 return;
1330
1331         if(!mapvote_initialized)
1332                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1333                         return;
1334
1335         MapVote_Start();
1336 }
1337
1338 /*
1339 ============
1340 FindIntermission
1341
1342 Returns the entity to view from
1343 ============
1344 */
1345 /*
1346 entity FindIntermission()
1347 {
1348         local   entity spot;
1349         local   float cyc;
1350
1351 // look for info_intermission first
1352         spot = find (world, classname, "info_intermission");
1353         if (spot)
1354         {       // pick a random one
1355                 cyc = random() * 4;
1356                 while (cyc > 1)
1357                 {
1358                         spot = find (spot, classname, "info_intermission");
1359                         if (!spot)
1360                                 spot = find (spot, classname, "info_intermission");
1361                         cyc = cyc - 1;
1362                 }
1363                 return spot;
1364         }
1365
1366 // then look for the start position
1367         spot = find (world, classname, "info_player_start");
1368         if (spot)
1369                 return spot;
1370
1371 // testinfo_player_start is only found in regioned levels
1372         spot = find (world, classname, "testplayerstart");
1373         if (spot)
1374                 return spot;
1375
1376 // then look for the start position
1377         spot = find (world, classname, "info_player_deathmatch");
1378         if (spot)
1379                 return spot;
1380
1381         //objerror ("FindIntermission: no spot");
1382         return world;
1383 }
1384 */
1385
1386 /*
1387 ===============================================================================
1388
1389 RULES
1390
1391 ===============================================================================
1392 */
1393
1394 void DumpStats(float final)
1395 {
1396         float file;
1397         string s;
1398         float to_console;
1399         float to_eventlog;
1400         float to_file;
1401         float i;
1402
1403         to_console = autocvar_sv_logscores_console;
1404         to_eventlog = autocvar_sv_eventlog;
1405         to_file = autocvar_sv_logscores_file;
1406
1407         if(!final)
1408         {
1409                 to_console = TRUE; // always print printstats replies
1410                 to_eventlog = FALSE; // but never print them to the event log
1411         }
1412
1413         if(to_eventlog)
1414                 if(autocvar_sv_eventlog_console)
1415                         to_console = FALSE; // otherwise we get the output twice
1416
1417         if(final)
1418                 s = ":scores:";
1419         else
1420                 s = ":status:";
1421         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1422
1423         if(to_console)
1424                 print(s, "\n");
1425         if(to_eventlog)
1426                 GameLogEcho(s);
1427
1428         file = -1;
1429         if(to_file)
1430         {
1431                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1432                 if(file == -1)
1433                         to_file = FALSE;
1434                 else
1435                         fputs(file, strcat(s, "\n"));
1436         }
1437
1438         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1439         if(to_console)
1440                 print(s, "\n");
1441         if(to_eventlog)
1442                 GameLogEcho(s);
1443         if(to_file)
1444                 fputs(file, strcat(s, "\n"));
1445
1446         FOR_EACH_CLIENT(other)
1447         {
1448                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1449                 {
1450                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1451                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1452                         if(IS_PLAYER(other) || g_arena || other.caplayer == 1 || g_lms)
1453                                 s = strcat(s, ftos(other.team), ":");
1454                         else
1455                                 s = strcat(s, "spectator:");
1456
1457                         if(to_console)
1458                                 print(s, other.netname, "\n");
1459                         if(to_eventlog)
1460                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1461                         if(to_file)
1462                                 fputs(file, strcat(s, other.netname, "\n"));
1463                 }
1464         }
1465
1466         if(teamplay)
1467         {
1468                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1469                 if(to_console)
1470                         print(s, "\n");
1471                 if(to_eventlog)
1472                         GameLogEcho(s);
1473                 if(to_file)
1474                         fputs(file, strcat(s, "\n"));
1475
1476                 for(i = 1; i < 16; ++i)
1477                 {
1478                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1479                         s = strcat(s, ":", ftos(i));
1480                         if(to_console)
1481                                 print(s, "\n");
1482                         if(to_eventlog)
1483                                 GameLogEcho(s);
1484                         if(to_file)
1485                                 fputs(file, strcat(s, "\n"));
1486                 }
1487         }
1488
1489         if(to_console)
1490                 print(":end\n");
1491         if(to_eventlog)
1492                 GameLogEcho(":end");
1493         if(to_file)
1494         {
1495                 fputs(file, ":end\n");
1496                 fclose(file);
1497         }
1498 }
1499
1500 void FixIntermissionClient(entity e)
1501 {
1502         string s;
1503         if(!e.autoscreenshot) // initial call
1504         {
1505                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1506                 e.health = -2342;
1507                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1508                 e.solid = SOLID_NOT;
1509                 e.movetype = MOVETYPE_NONE;
1510                 e.takedamage = DAMAGE_NO;
1511                 if(e.weaponentity)
1512                 {
1513                         e.weaponentity.effects = EF_NODRAW;
1514                         if (e.weaponentity.weaponentity)
1515                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1516                 }
1517                 if(IS_REAL_CLIENT(e))
1518                 {
1519                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1520                         s = autocvar_sv_intermission_cdtrack;
1521                         if(s != "")
1522                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1523                         msg_entity = e;
1524                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1525                 }
1526         }
1527 }
1528
1529 /*
1530 go to the next level for deathmatch
1531 only called if a time or frag limit has expired
1532 */
1533 void NextLevel()
1534 {
1535         gameover = TRUE;
1536
1537         intermission_running = 1;
1538
1539 // enforce a wait time before allowing changelevel
1540         if(player_count > 0)
1541                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1542         else
1543                 intermission_exittime = -1;
1544
1545         /*
1546         WriteByte (MSG_ALL, SVC_CDTRACK);
1547         WriteByte (MSG_ALL, 3);
1548         WriteByte (MSG_ALL, 3);
1549         // done in FixIntermission
1550         */
1551
1552         //pos = FindIntermission ();
1553
1554         VoteReset();
1555
1556         DumpStats(TRUE);
1557
1558         // send statistics
1559         entity e;
1560         PlayerStats_EndMatch(1);
1561         FOR_EACH_CLIENT(e)
1562                 PlayerStats_AddGlobalInfo(e);
1563         PlayerStats_Shutdown();
1564         WeaponStats_Shutdown();
1565
1566         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1567
1568         if(autocvar_sv_eventlog)
1569                 GameLogEcho(":gameover");
1570
1571         GameLogClose();
1572
1573         FOR_EACH_PLAYER(other) {
1574                 FixIntermissionClient(other);
1575                 if(other.winning)
1576                         bprint(other.netname, " ^7wins.\n");
1577         }
1578
1579         if(autocvar_g_campaign)
1580                 CampaignPreIntermission();
1581
1582         MUTATOR_CALLHOOK(MatchEnd);
1583
1584         localcmd("\nsv_hook_gameend\n");
1585 }
1586
1587 /*
1588 ============
1589 CheckRules_Player
1590
1591 Exit deathmatch games upon conditions
1592 ============
1593 */
1594 void CheckRules_Player()
1595 {
1596         if (gameover)   // someone else quit the game already
1597                 return;
1598
1599         if(self.deadflag == DEAD_NO)
1600                 self.play_time += frametime;
1601
1602         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1603         //   (div0: and that in CheckRules_World please)
1604 }
1605
1606 float checkrules_equality;
1607 float checkrules_suddendeathwarning;
1608 float checkrules_suddendeathend;
1609 float checkrules_overtimesadded; //how many overtimes have been already added
1610
1611 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1612 float WINNING_YES = 1; // winner found
1613 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1614 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1615
1616 float InitiateSuddenDeath()
1617 {
1618         // Check first whether normal overtimes could be added before initiating suddendeath mode
1619         // - for this timelimit_overtime needs to be >0 of course
1620         // - also check the winning condition calculated in the previous frame and only add normal overtime
1621         //   again, if at the point at which timelimit would be extended again, still no winner was found
1622         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1623         {
1624                 return 1; // need to call InitiateOvertime later
1625         }
1626         else
1627         {
1628                 if(!checkrules_suddendeathend)
1629                 {
1630                         if(autocvar_g_campaign)
1631                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1632                         else
1633                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1634                         if(g_race && !g_race_qualifying)
1635                                 race_StartCompleting();
1636                 }
1637                 return 0;
1638         }
1639 }
1640
1641 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1642 {
1643         ++checkrules_overtimesadded;
1644         //add one more overtime by simply extending the timelimit
1645         float tl;
1646         tl = autocvar_timelimit;
1647         tl += autocvar_timelimit_overtime;
1648         cvar_set("timelimit", ftos(tl));
1649
1650         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1651 }
1652
1653 float GetWinningCode(float fraglimitreached, float equality)
1654 {
1655         if(autocvar_g_campaign == 1)
1656                 if(fraglimitreached)
1657                         return WINNING_YES;
1658                 else
1659                         return WINNING_NO;
1660
1661         else
1662                 if(equality)
1663                         if(fraglimitreached)
1664                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1665                         else
1666                                 return WINNING_NEVER;
1667                 else
1668                         if(fraglimitreached)
1669                                 return WINNING_YES;
1670                         else
1671                                 return WINNING_NO;
1672 }
1673
1674 // set the .winning flag for exactly those players with a given field value
1675 void SetWinners(.float field, float value)
1676 {
1677         entity head;
1678         FOR_EACH_PLAYER(head)
1679                 head.winning = (head.field == value);
1680 }
1681
1682 // set the .winning flag for those players with a given field value
1683 void AddWinners(.float field, float value)
1684 {
1685         entity head;
1686         FOR_EACH_PLAYER(head)
1687                 if(head.field == value)
1688                         head.winning = 1;
1689 }
1690
1691 // clear the .winning flags
1692 void ClearWinners(void)
1693 {
1694         entity head;
1695         FOR_EACH_PLAYER(head)
1696                 head.winning = 0;
1697 }
1698
1699 // Onslaught winning condition:
1700 // game terminates if only one team has a working generator (or none)
1701 float WinningCondition_Onslaught()
1702 {
1703         entity head;
1704         float t1, t2, t3, t4;
1705
1706         WinningConditionHelper(); // set worldstatus
1707
1708         if(inWarmupStage)
1709                 return WINNING_NO;
1710
1711         // first check if the game has ended
1712         t1 = t2 = t3 = t4 = 0;
1713         head = find(world, classname, "onslaught_generator");
1714         while (head)
1715         {
1716                 if (head.health > 0)
1717                 {
1718                         if (head.team == NUM_TEAM_1) t1 = 1;
1719                         if (head.team == NUM_TEAM_2) t2 = 1;
1720                         if (head.team == NUM_TEAM_3) t3 = 1;
1721                         if (head.team == NUM_TEAM_4) t4 = 1;
1722                 }
1723                 head = find(head, classname, "onslaught_generator");
1724         }
1725         if (t1 + t2 + t3 + t4 < 2)
1726         {
1727                 // game over, only one team remains (or none)
1728                 ClearWinners();
1729                 if (t1) SetWinners(team, NUM_TEAM_1);
1730                 if (t2) SetWinners(team, NUM_TEAM_2);
1731                 if (t3) SetWinners(team, NUM_TEAM_3);
1732                 if (t4) SetWinners(team, NUM_TEAM_4);
1733                 dprint("Have a winner, ending game.\n");
1734                 return WINNING_YES;
1735         }
1736
1737         // Two or more teams remain
1738         return WINNING_NO;
1739 }
1740
1741 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1742 // they win. Otherwise the defending team wins once the timelimit passes.
1743 void assault_new_round();
1744 float WinningCondition_Assault()
1745 {
1746         float status;
1747
1748         WinningConditionHelper(); // set worldstatus
1749
1750         status = WINNING_NO;
1751         // as the timelimit has not yet passed just assume the defending team will win
1752         if(assault_attacker_team == NUM_TEAM_1)
1753         {
1754                 SetWinners(team, NUM_TEAM_2);
1755         }
1756         else
1757         {
1758                 SetWinners(team, NUM_TEAM_1);
1759         }
1760
1761         entity ent;
1762         ent = find(world, classname, "target_assault_roundend");
1763         if(ent)
1764         {
1765                 if(ent.winning) // round end has been triggered by attacking team
1766                 {
1767                         bprint("ASSAULT: round completed...\n");
1768                         SetWinners(team, assault_attacker_team);
1769
1770                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1771
1772                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1773                         {
1774                                 status = WINNING_YES;
1775                         }
1776                         else
1777                         {
1778                                 entity oldself;
1779                                 oldself = self;
1780                                 self = ent;
1781                                 assault_new_round();
1782                                 self = oldself;
1783                         }
1784                 }
1785         }
1786
1787         return status;
1788 }
1789
1790 // LMS winning condition: game terminates if and only if there's at most one
1791 // one player who's living lives. Top two scores being equal cancels the time
1792 // limit.
1793 float WinningCondition_LMS()
1794 {
1795         entity head, head2;
1796         float have_player;
1797         float have_players;
1798         float l;
1799
1800         have_player = FALSE;
1801         have_players = FALSE;
1802         l = LMS_NewPlayerLives();
1803
1804         head = find(world, classname, "player");
1805         if(head)
1806                 have_player = TRUE;
1807         head2 = find(head, classname, "player");
1808         if(head2)
1809                 have_players = TRUE;
1810
1811         if(have_player)
1812         {
1813                 // we have at least one player
1814                 if(have_players)
1815                 {
1816                         // two or more active players - continue with the game
1817                 }
1818                 else
1819                 {
1820                         // exactly one player?
1821
1822                         ClearWinners();
1823                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1824
1825                         if(l)
1826                         {
1827                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1828                                 return WINNING_NO;
1829                         }
1830                         else
1831                         {
1832                                 // a winner!
1833                                 // and assign him his first place
1834                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1835                                 return WINNING_YES;
1836                         }
1837                 }
1838         }
1839         else
1840         {
1841                 // nobody is playing at all...
1842                 if(l)
1843                 {
1844                         // wait for players...
1845                 }
1846                 else
1847                 {
1848                         // SNAFU (maybe a draw game?)
1849                         ClearWinners();
1850                         dprint("No players, ending game.\n");
1851                         return WINNING_YES;
1852                 }
1853         }
1854
1855         // When we get here, we have at least two players who are actually LIVING,
1856         // now check if the top two players have equal score.
1857         WinningConditionHelper();
1858
1859         ClearWinners();
1860         if(WinningConditionHelper_winner)
1861                 WinningConditionHelper_winner.winning = TRUE;
1862         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1863                 return WINNING_NEVER;
1864
1865         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1866         return WINNING_NO;
1867 }
1868
1869 void ShuffleMaplist()
1870 {
1871         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1872 }
1873
1874 float leaderfrags;
1875 float WinningCondition_Scores(float limit, float leadlimit)
1876 {
1877         float limitreached;
1878
1879         // TODO make everything use THIS winning condition (except LMS)
1880         WinningConditionHelper();
1881
1882         if(teamplay)
1883         {
1884                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1885                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1886                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1887                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1888         }
1889
1890         ClearWinners();
1891         if(WinningConditionHelper_winner)
1892                 WinningConditionHelper_winner.winning = 1;
1893         if(WinningConditionHelper_winnerteam >= 0)
1894                 SetWinners(team, WinningConditionHelper_winnerteam);
1895
1896         if(WinningConditionHelper_lowerisbetter)
1897         {
1898                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1899                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1900                 limit = -limit;
1901         }
1902
1903         if(WinningConditionHelper_zeroisworst)
1904                 leadlimit = 0; // not supported in this mode
1905
1906         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1907         // these modes always score in increments of 1, thus this makes sense
1908         {
1909                 if(leaderfrags != WinningConditionHelper_topscore)
1910                 {
1911                         leaderfrags = WinningConditionHelper_topscore;
1912
1913                         if (limit)
1914                         if (leaderfrags == limit - 1)
1915                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1916                         else if (leaderfrags == limit - 2)
1917                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1918                         else if (leaderfrags == limit - 3)
1919                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1920                 }
1921         }
1922
1923         limitreached = FALSE;
1924         if(limit)
1925                 if(WinningConditionHelper_topscore >= limit)
1926                         limitreached = TRUE;
1927         if(leadlimit)
1928         {
1929                 float leadlimitreached;
1930                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1931                 if(autocvar_leadlimit_and_fraglimit)
1932                         limitreached = (limitreached && leadlimitreached);
1933                 else
1934                         limitreached = (limitreached || leadlimitreached);
1935         }
1936
1937         if(limit)
1938                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1939
1940         return GetWinningCode(
1941                 WinningConditionHelper_topscore && limitreached,
1942                 WinningConditionHelper_equality
1943         );
1944 }
1945
1946 float WinningCondition_Race(float fraglimit)
1947 {
1948         float wc;
1949         entity p;
1950         float n, c;
1951
1952         n = 0;
1953         c = 0;
1954         FOR_EACH_PLAYER(p)
1955         {
1956                 ++n;
1957                 if(p.race_completed)
1958                         ++c;
1959         }
1960         if(n && (n == c))
1961                 return WINNING_YES;
1962         wc = WinningCondition_Scores(fraglimit, 0);
1963
1964         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1965         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1966         // do NOT support equality when the laps are all raced!
1967                 return WINNING_STARTSUDDENDEATHOVERTIME;
1968         else
1969                 return WINNING_NEVER;
1970 }
1971
1972 float WinningCondition_QualifyingThenRace(float limit)
1973 {
1974         float wc;
1975         wc = WinningCondition_Scores(limit, 0);
1976
1977         // NEVER initiate overtime
1978         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1979         {
1980                 return WINNING_YES;
1981         }
1982
1983         return wc;
1984 }
1985
1986 float WinningCondition_RanOutOfSpawns()
1987 {
1988         entity head;
1989
1990         if(have_team_spawns <= 0)
1991                 return WINNING_NO;
1992
1993         if(autocvar_g_spawn_useallspawns <= 0)
1994                 return WINNING_NO;
1995
1996         if(!some_spawn_has_been_used)
1997                 return WINNING_NO;
1998
1999         team1_score = team2_score = team3_score = team4_score = 0;
2000
2001         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2002         {
2003                 if(head.team == NUM_TEAM_1)
2004                         team1_score = 1;
2005                 else if(head.team == NUM_TEAM_2)
2006                         team2_score = 1;
2007                 else if(head.team == NUM_TEAM_3)
2008                         team3_score = 1;
2009                 else if(head.team == NUM_TEAM_4)
2010                         team4_score = 1;
2011         }
2012
2013         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2014         {
2015                 if(head.team == NUM_TEAM_1)
2016                         team1_score = 1;
2017                 else if(head.team == NUM_TEAM_2)
2018                         team2_score = 1;
2019                 else if(head.team == NUM_TEAM_3)
2020                         team3_score = 1;
2021                 else if(head.team == NUM_TEAM_4)
2022                         team4_score = 1;
2023         }
2024
2025         ClearWinners();
2026         if(team1_score + team2_score + team3_score + team4_score == 0)
2027         {
2028                 checkrules_equality = TRUE;
2029                 return WINNING_YES;
2030         }
2031         else if(team1_score + team2_score + team3_score + team4_score == 1)
2032         {
2033                 float t, i;
2034                 if(team1_score)
2035                         t = NUM_TEAM_1;
2036                 else if(team2_score)
2037                         t = NUM_TEAM_2;
2038                 else if(team3_score)
2039                         t = NUM_TEAM_3;
2040                 else // if(team4_score)
2041                         t = NUM_TEAM_4;
2042                 CheckAllowedTeams(world);
2043                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2044                 {
2045                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2046                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2047                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2048                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2049                 }
2050
2051                 AddWinners(team, t);
2052                 return WINNING_YES;
2053         }
2054         else
2055                 return WINNING_NO;
2056 }
2057
2058 /*
2059 ============
2060 CheckRules_World
2061
2062 Exit deathmatch games upon conditions
2063 ============
2064 */
2065 void ReadyRestart();
2066 void CheckRules_World()
2067 {
2068         float timelimit;
2069         float fraglimit;
2070         float leadlimit;
2071
2072         VoteThink();
2073         MapVote_Think();
2074
2075         SetDefaultAlpha();
2076
2077         /*
2078         MapVote_Think should now do that part
2079         if (intermission_running)
2080                 if (time >= intermission_exittime + 60)
2081                 {
2082                         if(!DoNextMapOverride())
2083                                 GotoNextMap();
2084                         return;
2085                 }
2086         */
2087
2088         if (gameover)   // someone else quit the game already
2089         {
2090                 if(player_count == 0) // Nobody there? Then let's go to the next map
2091                         MapVote_Start();
2092                         // this will actually check the player count in the next frame
2093                         // again, but this shouldn't hurt
2094                 return;
2095         }
2096
2097         timelimit = autocvar_timelimit * 60;
2098         fraglimit = autocvar_fraglimit;
2099         leadlimit = autocvar_leadlimit;
2100
2101         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2102         {
2103                 if(timelimit > 0)
2104                         timelimit = 0; // timelimit is not made for warmup
2105                 if(fraglimit > 0)
2106                         fraglimit = 0; // no fraglimit for now
2107                 leadlimit = 0; // no leadlimit for now
2108         }
2109
2110         if(timelimit > 0)
2111         {
2112                 timelimit += game_starttime;
2113         }
2114         else if (timelimit < 0)
2115         {
2116                 // endmatch
2117                 NextLevel();
2118                 return;
2119         }
2120
2121         if(g_onslaught)
2122                 timelimit = 0; // ONS has its own overtime rule
2123
2124         float wantovertime;
2125         wantovertime = 0;
2126
2127         if(timelimit > game_starttime)
2128                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2129         else
2130                 game_completion_ratio = 0;
2131
2132         if(checkrules_suddendeathend)
2133         {
2134                 if(!checkrules_suddendeathwarning)
2135                 {
2136                         checkrules_suddendeathwarning = TRUE;
2137                         if(g_race && !g_race_qualifying)
2138                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2139                         else
2140                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2141                 }
2142         }
2143         else
2144         {
2145                 if (timelimit && time >= timelimit)
2146                 {
2147                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2148                         {
2149                                 float totalplayers;
2150                                 float playerswithlaps;
2151                                 float readyplayers;
2152                                 entity head;
2153                                 totalplayers = playerswithlaps = readyplayers = 0;
2154                                 FOR_EACH_PLAYER(head)
2155                                 {
2156                                         ++totalplayers;
2157                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2158                                                 ++playerswithlaps;
2159                                         if(head.ready)
2160                                                 ++readyplayers;
2161                                 }
2162
2163                                 // at least 2 of the players have completed a lap: start the RACE
2164                                 // otherwise, the players should end the qualifying on their own
2165                                 if(readyplayers || playerswithlaps >= 2)
2166                                 {
2167                                         checkrules_suddendeathend = 0;
2168                                         ReadyRestart(); // go to race
2169                                         return;
2170                                 }
2171                                 else
2172                                         wantovertime |= InitiateSuddenDeath();
2173                         }
2174                         else
2175                                 wantovertime |= InitiateSuddenDeath();
2176                 }
2177         }
2178
2179         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2180         {
2181                 NextLevel();
2182                 return;
2183         }
2184
2185         float checkrules_status;
2186         checkrules_status = WinningCondition_RanOutOfSpawns();
2187         if(checkrules_status == WINNING_YES)
2188         {
2189                 bprint("Hey! Someone ran out of spawns!\n");
2190         }
2191         else if(g_race && !g_race_qualifying && timelimit >= 0)
2192         {
2193                 checkrules_status = WinningCondition_Race(fraglimit);
2194                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2195         }
2196         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2197         {
2198                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2199                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2200         }
2201         else if(g_assault)
2202         {
2203                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2204         }
2205         else if(g_lms)
2206         {
2207                 checkrules_status = WinningCondition_LMS();
2208         }
2209         else if (g_onslaught)
2210         {
2211                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2212         }
2213         else
2214         {
2215                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2216                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2217         }
2218
2219         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2220         {
2221                 checkrules_status = WINNING_NEVER;
2222                 checkrules_overtimesadded = -1;
2223                 wantovertime |= InitiateSuddenDeath();
2224         }
2225
2226         if(checkrules_status == WINNING_NEVER)
2227                 // equality cases! Nobody wins if the overtime ends in a draw.
2228                 ClearWinners();
2229
2230         if(wantovertime)
2231         {
2232                 if(checkrules_status == WINNING_NEVER)
2233                         InitiateOvertime();
2234                 else
2235                         checkrules_status = WINNING_YES;
2236         }
2237
2238         if(checkrules_suddendeathend)
2239                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2240                         checkrules_status = WINNING_YES;
2241
2242         if(checkrules_status == WINNING_YES)
2243         {
2244                 //print("WINNING\n");
2245                 NextLevel();
2246         }
2247 }
2248
2249 float mapvote_nextthink;
2250 float mapvote_initialized;
2251 float mapvote_keeptwotime;
2252 float mapvote_timeout;
2253 string mapvote_message;
2254 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2255 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2256 float mapvote_screenshot_dirs_count;
2257
2258 float mapvote_count;
2259 float mapvote_count_real;
2260 string mapvote_maps[MAPVOTE_COUNT];
2261 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2262 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2263 float mapvote_maps_suggested[MAPVOTE_COUNT];
2264 string mapvote_suggestions[MAPVOTE_COUNT];
2265 float mapvote_suggestion_ptr;
2266 float mapvote_voters;
2267 float mapvote_selections[MAPVOTE_COUNT];
2268 float mapvote_run;
2269 float mapvote_detail;
2270 float mapvote_abstain;
2271 .float mapvote;
2272
2273 void MapVote_ClearAllVotes()
2274 {
2275         FOR_EACH_CLIENT(other)
2276                 other.mapvote = 0;
2277 }
2278
2279 string MapVote_Suggest(string m)
2280 {
2281         float i;
2282         if(m == "")
2283                 return "That's not how to use this command.";
2284         if(!autocvar_g_maplist_votable_suggestions)
2285                 return "Suggestions are not accepted on this server.";
2286         if(mapvote_initialized)
2287                 return "Can't suggest - voting is already in progress!";
2288         m = MapInfo_FixName(m);
2289         if not(m)
2290                 return "The map you suggested is not available on this server.";
2291         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2292                 if(Map_IsRecent(m))
2293                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2294
2295         if(!MapInfo_CheckMap(m))
2296                 return "The map you suggested does not support the current game mode.";
2297         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2298                 if(mapvote_suggestions[i] == m)
2299                         return "This map was already suggested.";
2300         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2301         {
2302                 i = floor(random() * mapvote_suggestion_ptr);
2303         }
2304         else
2305         {
2306                 i = mapvote_suggestion_ptr;
2307                 mapvote_suggestion_ptr += 1;
2308         }
2309         if(mapvote_suggestions[i] != "")
2310                 strunzone(mapvote_suggestions[i]);
2311         mapvote_suggestions[i] = strzone(m);
2312         if(autocvar_sv_eventlog)
2313                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2314         return strcat("Suggestion of ", m, " accepted.");
2315 }
2316
2317 void MapVote_AddVotable(string nextMap, float isSuggestion)
2318 {
2319         float j, i, o;
2320         string pakfile, mapfile;
2321
2322         if(nextMap == "")
2323                 return;
2324         for(j = 0; j < mapvote_count; ++j)
2325                 if(mapvote_maps[j] == nextMap)
2326                         return;
2327         // suggestions might be no longer valid/allowed after gametype switch!
2328         if(isSuggestion)
2329                 if(!MapInfo_CheckMap(nextMap))
2330                         return;
2331         mapvote_maps[mapvote_count] = strzone(nextMap);
2332         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2333
2334         pakfile = string_null;
2335         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2336         {
2337                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2338                 pakfile = whichpack(strcat(mapfile, ".tga"));
2339                 if(pakfile == "")
2340                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2341                 if(pakfile == "")
2342                         pakfile = whichpack(strcat(mapfile, ".png"));
2343                 if(pakfile != "")
2344                         break;
2345         }
2346         if(i >= mapvote_screenshot_dirs_count)
2347                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2348         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2349                 pakfile = substring(pakfile, o, -1);
2350
2351         mapvote_maps_screenshot_dir[mapvote_count] = i;
2352         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2353
2354         mapvote_count += 1;
2355 }
2356
2357 void MapVote_Spawn();
2358 void MapVote_Init()
2359 {
2360         float i;
2361         float nmax, smax;
2362
2363         MapVote_ClearAllVotes();
2364
2365         mapvote_count = 0;
2366         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2367         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2368
2369         if(mapvote_abstain)
2370                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2371         else
2372                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2373         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2374
2375         // we need this for AddVotable, as that cycles through the screenshot dirs
2376         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2377         if(mapvote_screenshot_dirs_count == 0)
2378                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2379         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2380         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2381                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2382
2383         if(mapvote_suggestion_ptr)
2384                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2385                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2386
2387         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2388                 MapVote_AddVotable(GetNextMap(), FALSE);
2389
2390         if(mapvote_count == 0)
2391         {
2392                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2393                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2394                 if(autocvar_g_maplist_shuffle)
2395                         ShuffleMaplist();
2396                 localcmd("\nmenu_cmd sync\n");
2397                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2398                         MapVote_AddVotable(GetNextMap(), FALSE);
2399         }
2400
2401         mapvote_count_real = mapvote_count;
2402         if(mapvote_abstain)
2403                 MapVote_AddVotable("don't care", 0);
2404
2405         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2406
2407         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2408         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2409         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2410                 mapvote_keeptwotime = 0;
2411         mapvote_message = "Choose a map and press its key!";
2412
2413         MapVote_Spawn();
2414 }
2415
2416 void MapVote_SendPicture(float id)
2417 {
2418         msg_entity = self;
2419         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2420         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2421         WriteByte(MSG_ONE, id);
2422         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2423 }
2424
2425 float MapVote_GetMapMask()
2426 {
2427         float mask, i, power;
2428         mask = 0;
2429         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2430                 if(mapvote_maps[i] != "")
2431                         mask |= power;
2432         return mask;
2433 }
2434
2435 entity mapvote_ent;
2436 float MapVote_SendEntity(entity to, float sf)
2437 {
2438         float i;
2439
2440         if(sf & 1)
2441                 sf &~= 2; // if we send 1, we don't need to also send 2
2442
2443         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2444         WriteByte(MSG_ENTITY, sf);
2445
2446         if(sf & 1)
2447         {
2448                 // flag 1 == initialization
2449                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2450                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2451                 WriteString(MSG_ENTITY, "");
2452                 WriteByte(MSG_ENTITY, mapvote_count);
2453                 WriteByte(MSG_ENTITY, mapvote_abstain);
2454                 WriteByte(MSG_ENTITY, mapvote_detail);
2455                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2456                 if(mapvote_count <= 8)
2457                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2458                 else
2459                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2460                 for(i = 0; i < mapvote_count; ++i)
2461                         if(mapvote_maps[i] != "")
2462                         {
2463                                 if(mapvote_abstain && i == mapvote_count - 1)
2464                                 {
2465                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2466                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2467                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2468                                 }
2469                                 else
2470                                 {
2471                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2472                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2473                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2474                                 }
2475                         }
2476         }
2477
2478         if(sf & 2)
2479         {
2480                 // flag 2 == update of mask
2481                 if(mapvote_count <= 8)
2482                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2483                 else
2484                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2485         }
2486
2487         if(sf & 4)
2488         {
2489                 if(mapvote_detail)
2490                         for(i = 0; i < mapvote_count; ++i)
2491                                 if(mapvote_maps[i] != "")
2492                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2493
2494                 WriteByte(MSG_ENTITY, to.mapvote);
2495         }
2496
2497         return TRUE;
2498 }
2499
2500 void MapVote_Spawn()
2501 {
2502         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2503 }
2504
2505 void MapVote_TouchMask()
2506 {
2507         mapvote_ent.SendFlags |= 2;
2508 }
2509
2510 void MapVote_TouchVotes(entity voter)
2511 {
2512         mapvote_ent.SendFlags |= 4;
2513 }
2514
2515 float MapVote_Finished(float mappos)
2516 {
2517         string result;
2518         float i;
2519         float didntvote;
2520
2521         if(autocvar_sv_eventlog)
2522         {
2523                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2524                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2525                 didntvote = mapvote_voters;
2526                 for(i = 0; i < mapvote_count; ++i)
2527                         if(mapvote_maps[i] != "")
2528                         {
2529                                 didntvote -= mapvote_selections[i];
2530                                 if(i != mappos)
2531                                 {
2532                                         result = strcat(result, ":", mapvote_maps[i]);
2533                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2534                                 }
2535                         }
2536                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2537
2538                 GameLogEcho(result);
2539                 if(mapvote_maps_suggested[mappos])
2540                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2541         }
2542
2543         FOR_EACH_REALCLIENT(other)
2544                 FixClientCvars(other);
2545
2546         Map_Goto_SetStr(mapvote_maps[mappos]);
2547         Map_Goto(0);
2548         alreadychangedlevel = TRUE;
2549         return TRUE;
2550 }
2551 void MapVote_CheckRules_1()
2552 {
2553         float i;
2554
2555         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2556         {
2557                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2558                 mapvote_selections[i] = 0;
2559         }
2560
2561         mapvote_voters = 0;
2562         FOR_EACH_REALCLIENT(other)
2563         {
2564                 ++mapvote_voters;
2565                 if(other.mapvote)
2566                 {
2567                         i = other.mapvote - 1;
2568                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2569                         mapvote_selections[i] = mapvote_selections[i] + 1;
2570                 }
2571         }
2572 }
2573
2574 float MapVote_CheckRules_2()
2575 {
2576         float i;
2577         float firstPlace, secondPlace;
2578         float firstPlaceVotes, secondPlaceVotes;
2579         float mapvote_voters_real;
2580         string result;
2581
2582         if(mapvote_count_real == 1)
2583                 return MapVote_Finished(0);
2584
2585         mapvote_voters_real = mapvote_voters;
2586         if(mapvote_abstain)
2587                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2588
2589         RandomSelection_Init();
2590         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2591                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2592         firstPlace = RandomSelection_chosen_float;
2593         firstPlaceVotes = RandomSelection_best_priority;
2594         //dprint("First place: ", ftos(firstPlace), "\n");
2595         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2596
2597         RandomSelection_Init();
2598         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2599                 if(i != firstPlace)
2600                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2601         secondPlace = RandomSelection_chosen_float;
2602         secondPlaceVotes = RandomSelection_best_priority;
2603         //dprint("Second place: ", ftos(secondPlace), "\n");
2604         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2605
2606         if(firstPlace == -1)
2607                 error("No first place in map vote... WTF?");
2608
2609         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2610                 return MapVote_Finished(firstPlace);
2611
2612         if(mapvote_keeptwotime)
2613                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2614                 {
2615                         float didntvote;
2616                         MapVote_TouchMask();
2617                         mapvote_message = "Now decide between the TOP TWO!";
2618                         mapvote_keeptwotime = 0;
2619                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2620                         result = strcat(result, ":", ftos(firstPlaceVotes));
2621                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2622                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2623                         didntvote = mapvote_voters;
2624                         for(i = 0; i < mapvote_count; ++i)
2625                                 if(mapvote_maps[i] != "")
2626                                 {
2627                                         didntvote -= mapvote_selections[i];
2628                                         if(i != firstPlace)
2629                                                 if(i != secondPlace)
2630                                                 {
2631                                                         result = strcat(result, ":", mapvote_maps[i]);
2632                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2633                                                         if(i < mapvote_count_real)
2634                                                         {
2635                                                                 strunzone(mapvote_maps[i]);
2636                                                                 mapvote_maps[i] = "";
2637                                                                 strunzone(mapvote_maps_pakfile[i]);
2638                                                                 mapvote_maps_pakfile[i] = "";
2639                                                         }
2640                                                 }
2641                                 }
2642                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2643                         if(autocvar_sv_eventlog)
2644                                 GameLogEcho(result);
2645                 }
2646
2647         return FALSE;
2648 }
2649 void MapVote_Tick()
2650 {
2651         float keeptwo;
2652         float totalvotes;
2653
2654         keeptwo = mapvote_keeptwotime;
2655         MapVote_CheckRules_1(); // count
2656         if(MapVote_CheckRules_2()) // decide
2657                 return;
2658
2659         totalvotes = 0;
2660         FOR_EACH_REALCLIENT(other)
2661         {
2662                 // hide scoreboard again
2663                 if(other.health != 2342)
2664                 {
2665                         other.health = 2342;
2666                         other.impulse = 0;
2667                         if(IS_REAL_CLIENT(other))
2668                         {
2669                                 msg_entity = other;
2670                                 WriteByte(MSG_ONE, SVC_FINALE);
2671                                 WriteString(MSG_ONE, "");
2672                         }
2673                 }
2674
2675                 // clear possibly invalid votes
2676                 if(mapvote_maps[other.mapvote - 1] == "")
2677                         other.mapvote = 0;
2678                 // use impulses as new vote
2679                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2680                         if(mapvote_maps[other.impulse - 1] != "")
2681                         {
2682                                 other.mapvote = other.impulse;
2683                                 MapVote_TouchVotes(other);
2684                         }
2685                 other.impulse = 0;
2686
2687                 if(other.mapvote)
2688                         ++totalvotes;
2689         }
2690
2691         MapVote_CheckRules_1(); // just count
2692 }
2693 void MapVote_Start()
2694 {
2695         if(mapvote_run)
2696                 return;
2697
2698         // wait for stats to be sent first
2699         if(!playerstats_waitforme)
2700                 return;
2701
2702         MapInfo_Enumerate();
2703         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2704                 mapvote_run = TRUE;
2705 }
2706 void MapVote_Think()
2707 {
2708         if(!mapvote_run)
2709                 return;
2710
2711         if(alreadychangedlevel)
2712                 return;
2713
2714         if(time < mapvote_nextthink)
2715                 return;
2716         //dprint("tick\n");
2717
2718         mapvote_nextthink = time + 0.5;
2719
2720         if(!mapvote_initialized)
2721         {
2722                 if(autocvar_rescan_pending == 1)
2723                 {
2724                         cvar_set("rescan_pending", "2");
2725                         localcmd("fs_rescan\nrescan_pending 3\n");
2726                         return;
2727                 }
2728                 else if(autocvar_rescan_pending == 2)
2729                 {
2730                         return;
2731                 }
2732                 else if(autocvar_rescan_pending == 3)
2733                 {
2734                         // now build missing mapinfo files
2735                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2736                                 return;
2737
2738                         // we're done, start the timer
2739                         cvar_set("rescan_pending", "0");
2740                 }
2741
2742                 mapvote_initialized = TRUE;
2743                 if(DoNextMapOverride(0))
2744                         return;
2745                 if(!autocvar_g_maplist_votable || player_count <= 0)
2746                 {
2747                         GotoNextMap(0);
2748                         return;
2749                 }
2750                 MapVote_Init();
2751         }
2752
2753         MapVote_Tick();
2754 }
2755
2756 string GotoMap(string m)
2757 {
2758         if(!MapInfo_CheckMap(m))
2759                 return "The map you chose is not available on this server.";
2760         cvar_set("nextmap", m);
2761         cvar_set("timelimit", "-1");
2762         if(mapvote_initialized || alreadychangedlevel)
2763         {
2764                 if(DoNextMapOverride(0))
2765                         return "Map switch initiated.";
2766                 else
2767                         return "Hm... no. For some reason I like THIS map more.";
2768         }
2769         else
2770                 return "Map switch will happen after scoreboard.";
2771 }
2772
2773
2774 void EndFrame()
2775 {
2776         float altime;
2777         FOR_EACH_REALCLIENT(self)
2778         {
2779                 if(IS_SPEC(self))
2780                 {
2781                         if(self.enemy.typehitsound)
2782                                 self.typehit_time = time;
2783                         else if(self.enemy.hitsound)
2784                                 self.hit_time = time;
2785                 }
2786                 else
2787                 {
2788                         if(self.typehitsound)
2789                                 self.typehit_time = time;
2790                         else if(self.hitsound)
2791                                 self.hit_time = time;
2792                 }
2793         }
2794         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2795         // add 1 frametime because after this, engine SV_Physics
2796         // increases time by a frametime and then networks the frame
2797         // add another frametime because client shows everything with
2798         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2799         // needed!
2800         FOR_EACH_CLIENT(self)
2801         {
2802                 self.hitsound = FALSE;
2803                 self.typehitsound = FALSE;
2804                 antilag_record(self, altime);
2805         }
2806 }
2807
2808
2809 /*
2810  * RedirectionThink:
2811  * returns TRUE if redirecting
2812  */
2813 float redirection_timeout;
2814 float redirection_nextthink;
2815 float RedirectionThink()
2816 {
2817         float clients_found;
2818
2819         if(redirection_target == "")
2820                 return FALSE;
2821
2822         if(!redirection_timeout)
2823         {
2824                 cvar_set("sv_public", "-2");
2825                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2826                 if(redirection_target == "self")
2827                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2828                 else
2829                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2830         }
2831
2832         if(time < redirection_nextthink)
2833                 return TRUE;
2834
2835         redirection_nextthink = time + 1;
2836
2837         clients_found = 0;
2838         FOR_EACH_REALCLIENT(self)
2839         {
2840                 // TODO add timer
2841                 print("Redirecting: sending connect command to ", self.netname, "\n");
2842                 if(redirection_target == "self")
2843                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2844                 else
2845                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2846                 ++clients_found;
2847         }
2848
2849         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2850
2851         if(time > redirection_timeout || clients_found == 0)
2852                 localcmd("\nwait; wait; wait; quit\n");
2853
2854         return TRUE;
2855 }
2856
2857 void TargetMusic_RestoreGame();
2858 void RestoreGame()
2859 {
2860         // Loaded from a save game
2861         // some things then break, so let's work around them...
2862
2863         // Progs DB (capture records)
2864         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2865
2866         // Mapinfo
2867         MapInfo_Shutdown();
2868         MapInfo_Enumerate();
2869         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2870         WeaponStats_Init();
2871
2872         TargetMusic_RestoreGame();
2873 }
2874
2875 void Shutdown()
2876 {
2877         entity e;
2878
2879         gameover = 2;
2880
2881         if(world_initialized > 0)
2882         {
2883                 world_initialized = 0;
2884                 print("Saving persistent data...\n");
2885                 Ban_SaveBans();
2886
2887                 PlayerStats_EndMatch(0);
2888                 FOR_EACH_CLIENT(e)
2889                         PlayerStats_AddGlobalInfo(e);
2890                 PlayerStats_Shutdown();
2891
2892                 if(!cheatcount_total)
2893                 {
2894                         if(autocvar_sv_db_saveasdump)
2895                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2896                         else
2897                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2898                 }
2899                 if(autocvar_developer)
2900                 {
2901                         if(autocvar_sv_db_saveasdump)
2902                                 db_dump(TemporaryDB, "server-temp.db");
2903                         else
2904                                 db_save(TemporaryDB, "server-temp.db");
2905                 }
2906                 CheatShutdown(); // must be after cheatcount check
2907                 db_close(ServerProgsDB);
2908                 db_close(TemporaryDB);
2909                 print("done!\n");
2910                 // tell the bot system the game is ending now
2911                 bot_endgame();
2912
2913                 WeaponStats_Shutdown();
2914                 MapInfo_Shutdown();
2915         }
2916         else if(world_initialized == 0)
2917         {
2918                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2919         }
2920 }