qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap(float reinit);
  48 void ShuffleMaplist()
  49 float(float reinit) DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride(1))
 193                         GotoNextMap(1);
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_ghost_items");
 301                 BADPREFIX("g_playerstats_");
 302                 BADPREFIX("g_respawn_ghosts");
 303                 BADPREFIX("g_voice_flood_");
 304                 BADPREFIX("rcon_");
 305                 BADPREFIX("settemp_");
 306                 BADPREFIX("sv_allowdownloads");
 307                 BADPREFIX("sv_autodemo");
 308                 BADPREFIX("sv_curl_");
 309                 BADPREFIX("sv_eventlog");
 310                 BADPREFIX("sv_logscores_");
 311                 BADPREFIX("sv_master");
 312                 BADPREFIX("sv_weaponstats_");
 313                 BADPREFIX("sv_waypointsprite_");
 314                 BADCVAR("rescan_pending");
 315
 316                 // these can contain player IDs, so better hide
 317                 BADPREFIX("g_forced_team_");
 318
 319                 // mapinfo
 320                 BADCVAR("fraglimit");
 321                 BADCVAR("g_arena");
 322                 BADCVAR("g_assault");
 323                 BADCVAR("g_ca");
 324                 BADCVAR("g_ctf");
 325                 BADCVAR("g_cts");
 326                 BADCVAR("g_dm");
 327                 BADCVAR("g_domination");
 328                 BADCVAR("g_domination_default_teams");
 329                 BADCVAR("g_freezetag");
 330                 BADCVAR("g_keepaway");
 331                 BADCVAR("g_keyhunt");
 332                 BADCVAR("g_keyhunt_teams");
 333                 BADCVAR("g_keyhunt_teams");
 334                 BADCVAR("g_lms");
 335                 BADCVAR("g_nexball");
 336                 BADCVAR("g_onslaught");
 337                 BADCVAR("g_race");
 338                 BADCVAR("g_race_qualifying_timelimit");
 339                 BADCVAR("g_runematch");
 340                 BADCVAR("g_tdm");
 341                 BADCVAR("g_tdm_teams");
 342                 BADCVAR("leadlimit");
 343                 BADCVAR("nextmap");
 344                 BADCVAR("teamplay");
 345                 BADCVAR("timelimit");
 346
 347                 // long
 348                 BADCVAR("hostname");
 349                 BADCVAR("g_maplist");
 350                 BADCVAR("g_maplist_mostrecent");
 351                 BADCVAR("sv_motd");
 352
 353                 v = cvar_string(k);
 354                 d = cvar_defstring(k);
 355                 if(v == d)
 356                         continue;
 357
 358                 if(adding)
 359                 {
 360                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 361                         if(strlen(cvar_changes) > 16384)
 362                         {
 363                                 cvar_changes = "// too many settings have been changed to show them here\n";
 364                                 adding = 0;
 365                         }
 366                 }
 367
 368                 // now check if the changes are actually gameplay relevant
 369
 370                 // does nothing visible
 371                 BADCVAR("captureleadlimit_override");
 372                 BADCVAR("g_arena_point_leadlimit");
 373                 BADCVAR("g_balance_kill_delay");
 374                 BADCVAR("g_ca_point_leadlimit");
 375                 BADCVAR("g_ctf_captimerecord_always");
 376                 BADCVAR("g_ctf_capture_leadlimit");
 377                 BADCVAR("g_ctf_flag_capture_effects");
 378                 BADCVAR("g_ctf_flag_glowtrails");
 379                 BADCVAR("g_ctf_flag_pickup_effects");
 380                 BADCVAR("g_domination_point_leadlimit");
 381                 BADCVAR("g_forced_respawn");
 382                 BADCVAR("g_keyhunt_point_leadlimit");
 383                 BADCVAR("g_nexball_goalleadlimit");
 384                 BADCVAR("g_runematch_point_leadlimit");
 385                 BADCVAR("leadlimit_and_fraglimit");
 386                 BADCVAR("leadlimit_override");
 387                 BADCVAR("pausable");
 388                 BADCVAR("sv_allow_fullbright");
 389                 BADCVAR("sv_checkforpacketsduringsleep");
 390                 BADCVAR("sv_timeout");
 391                 BADCVAR("welcome_message_time");
 392                 BADPREFIX("crypto_");
 393                 BADPREFIX("g_chat_");
 394                 BADPREFIX("g_ctf_captimerecord_");
 395                 BADPREFIX("g_maplist_votable_");
 396                 BADPREFIX("net_");
 397                 BADPREFIX("prvm_");
 398                 BADPREFIX("skill_");
 399                 BADPREFIX("sv_cullentities_");
 400                 BADPREFIX("sv_fraginfo_");
 401                 BADPREFIX("sv_maxidle_");
 402                 BADPREFIX("sv_vote_");
 403                 BADPREFIX("timelimit_");
 404                 BADCVAR("gameversion");
 405                 BADPREFIX("gameversion_");
 406                 BADCVAR("sv_namechangetimer");
 407 #ifndef NO_LEGACY_NETWORKING
 408                 BADCVAR("sv_use_csqc_players"); // transition
 409 #endif
 410
 411                 // allowed changes to server admins (please sync this to server.cfg)
 412                 // vi commands:
 413                 //   :/"impure"/,$d
 414                 //   :g!,^\/\/[^ /],d
 415                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 416                 //   :%!sort
 417                 // yes, this does contain some redundant stuff, don't really care
 418                 BADCVAR("bot_config_file");
 419                 BADCVAR("bot_number");
 420                 BADCVAR("bot_prefix");
 421                 BADCVAR("bot_suffix");
 422                 BADCVAR("capturelimit_override");
 423                 BADCVAR("fraglimit_override");
 424                 BADCVAR("gametype");
 425                 BADCVAR("g_antilag");
 426                 BADCVAR("g_balance_teams");
 427                 BADCVAR("g_balance_teams_force");
 428                 BADCVAR("g_ban_sync_trusted_servers");
 429                 BADCVAR("g_ban_sync_uri");
 430                 BADCVAR("g_ctf_capture_limit");
 431                 BADCVAR("g_ctf_ignore_frags");
 432                 BADCVAR("g_ctf_win_mode");
 433                 BADCVAR("g_domination_point_limit");
 434                 BADCVAR("g_friendlyfire");
 435                 BADCVAR("g_fullbrightitems");
 436                 BADCVAR("g_fullbrightplayers");
 437                 BADCVAR("g_keyhunt_point_limit");
 438                 BADCVAR("g_keyhunt_teams_override");
 439                 BADCVAR("g_lms_lives_override");
 440                 BADCVAR("g_maplist");
 441                 BADCVAR("g_maplist_check_waypoints");
 442                 BADCVAR("g_maplist_mostrecent_count");
 443                 BADCVAR("g_maplist_shuffle");
 444                 BADCVAR("g_maplist_votable");
 445                 BADCVAR("g_maplist_votable_abstain");
 446                 BADCVAR("g_maplist_votable_nodetail");
 447                 BADCVAR("g_maplist_votable_suggestions");
 448                 BADCVAR("g_maxplayers");
 449                 BADCVAR("g_minstagib");
 450                 BADCVAR("g_mirrordamage");
 451                 BADCVAR("g_nexball_goallimit");
 452                 BADCVAR("g_powerups");
 453                 BADCVAR("g_runematch_point_limit");
 454                 BADCVAR("g_start_delay");
 455                 BADCVAR("g_warmup");
 456                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 457                 BADCVAR("hostname");
 458                 BADCVAR("log_file");
 459                 BADCVAR("maxplayers");
 460                 BADCVAR("minplayers");
 461                 BADCVAR("net_address");
 462                 BADCVAR("port");
 463                 BADCVAR("rcon_password");
 464                 BADCVAR("rcon_restricted_commands");
 465                 BADCVAR("rcon_restricted_password");
 466                 BADCVAR("skill");
 467                 BADCVAR("sv_adminnick");
 468                 BADCVAR("sv_autoscreenshot");
 469                 BADCVAR("sv_autotaunt");
 470                 BADCVAR("sv_curl_defaulturl");
 471                 BADCVAR("sv_defaultcharacter");
 472                 BADCVAR("sv_defaultplayercolors");
 473                 BADCVAR("sv_defaultplayermodel");
 474                 BADCVAR("sv_defaultplayerskin");
 475                 BADCVAR("sv_maxidle");
 476                 BADCVAR("sv_maxrate");
 477                 BADCVAR("sv_motd");
 478                 BADCVAR("sv_public");
 479                 BADCVAR("sv_ready_restart");
 480                 BADCVAR("sv_status_privacy");
 481                 BADCVAR("sv_taunt");
 482                 BADCVAR("sv_vote_call");
 483                 BADCVAR("sv_vote_commands");
 484                 BADCVAR("sv_vote_majority_factor");
 485                 BADCVAR("sv_vote_master");
 486                 BADCVAR("sv_vote_master_commands");
 487                 BADCVAR("sv_vote_master_password");
 488                 BADCVAR("sv_vote_simple_majority_factor");
 489                 BADCVAR("sys_ticrate");
 490                 BADCVAR("teamplay_mode");
 491                 BADCVAR("timelimit_override");
 492                 BADPREFIX("g_warmup_");
 493                 BADPREFIX("sv_ready_restart_");
 494
 495                 if(autocvar_g_minstagib)
 496                 {
 497                         BADCVAR("g_grappling_hook");
 498                         BADCVAR("g_jetpack");
 499                 }
 500 #undef BADPREFIX
 501 #undef BADCVAR
 502
 503                 if(pureadding)
 504                 {
 505                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 506                         if(strlen(cvar_purechanges) > 16384)
 507                         {
 508                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 509                                 pureadding = 0;
 510                         }
 511                 }
 512                 ++cvar_purechanges_count;
 513                 // WARNING: this variable is used for the server list
 514                 // NEVER dare to skip this code!
 515                 // Hacks to intentionally appearing as "pure server" even though you DO have
 516                 // modified settings may be punished by removal from the server list.
 517                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 518                 // though.
 519         }
 520         buf_del(h);
 521         if(cvar_changes == "")
 522                 cvar_changes = "// this server runs at default server settings\n";
 523         else
 524                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 525         cvar_changes = strzone(cvar_changes);
 526         if(cvar_purechanges == "")
 527                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 528         else
 529                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 530         cvar_purechanges = strzone(cvar_purechanges);
 531 }
 532
 533 void detect_maptype()
 534 {
 535 #if 0
 536         vector o, v;
 537         float i;
 538
 539         for(;;)
 540         {
 541                 o = world.mins;
 542                 o_x += random() * (world.maxs_x - world.mins_x);
 543                 o_y += random() * (world.maxs_y - world.mins_y);
 544                 o_z += random() * (world.maxs_z - world.mins_z);
 545
 546                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 547                 if(trace_fraction == 1)
 548                         continue;
 549
 550                 v = trace_endpos;
 551
 552                 for(i = 0; i < 64; i += 4)
 553                 {
 554                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 555         if(trace_fraction == 1)
 556                 continue;
 557                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 558                 }
 559
 560                 break;
 561         }
 562 #endif
 563 }
 564
 565 entity randomseed;
 566 float RandomSeed_Send(entity to, float sf)
 567 {
 568         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 569         WriteShort(MSG_ENTITY, self.cnt);
 570         return TRUE;
 571 }
 572 void RandomSeed_Think()
 573 {
 574         self.cnt = bound(0, floor(random() * 65536), 65535);
 575         self.nextthink = time + 5;
 576
 577         self.SendFlags |= 1;
 578 }
 579 void RandomSeed_Spawn()
 580 {
 581         randomseed = spawn();
 582         randomseed.think = RandomSeed_Think;
 583         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 584
 585         entity oldself;
 586         oldself = self;
 587         self = randomseed;
 588         self.think(); // sets random seed and nextthink
 589         self = oldself;
 590 }
 591
 592 void spawnfunc___init_dedicated_server(void)
 593 {
 594         // handler for _init/_init map (only for dedicated server initialization)
 595
 596         world_initialized = -1; // don't complain
 597         cvar = cvar_normal;
 598         cvar_string = cvar_string_normal;
 599         cvar_set = cvar_set_normal;
 600
 601         remove = remove_unsafely;
 602
 603         entity e;
 604         e = spawn();
 605         e.think = GotoFirstMap;
 606         e.nextthink = time; // this is usually 1 at this point
 607
 608         e = spawn();
 609         e.classname = "info_player_deathmatch"; // safeguard against player joining
 610
 611         self.classname = "worldspawn"; // safeguard against various stuff ;)
 612
 613         MapInfo_Enumerate();
 614         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 615 }
 616
 617 void Map_MarkAsRecent(string m);
 618 float world_already_spawned;
 619 void RegisterWeapons();
 620 void Nagger_Init();
 621 void ClientInit_Spawn();
 622 void WeaponStats_Init();
 623 void WeaponStats_Shutdown();
 624 void spawnfunc_worldspawn (void)
 625 {
 626         float fd, l, i, j, n;
 627         string s, col;
 628
 629         cvar = cvar_normal;
 630         cvar_string = cvar_string_normal;
 631         cvar_set = cvar_set_normal;
 632
 633         if(world_already_spawned)
 634                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 635         world_already_spawned = TRUE;
 636
 637         remove = remove_safely; // during spawning, watch what you remove!
 638
 639         check_unacceptable_compiler_bugs();
 640
 641         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 642
 643         compressShortVector_init();
 644
 645         allowed_to_spawn = TRUE;
 646
 647         entity head;
 648         head = nextent(world);
 649         maxclients = 0;
 650         while(head)
 651         {
 652                 ++maxclients;
 653                 head = nextent(head);
 654         }
 655
 656         // needs to be done so early as they would still spawn
 657         RegisterWeapons();
 658
 659         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 660
 661         TemporaryDB = db_create();
 662
 663         // 0 normal
 664         lightstyle(0, "m");
 665
 666         // 1 FLICKER (first variety)
 667         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 668
 669         // 2 SLOW STRONG PULSE
 670         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 671
 672         // 3 CANDLE (first variety)
 673         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 674
 675         // 4 FAST STROBE
 676         lightstyle(4, "mamamamamama");
 677
 678         // 5 GENTLE PULSE 1
 679         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 680
 681         // 6 FLICKER (second variety)
 682         lightstyle(6, "nmonqnmomnmomomno");
 683
 684         // 7 CANDLE (second variety)
 685         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 686
 687         // 8 CANDLE (third variety)
 688         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 689
 690         // 9 SLOW STROBE (fourth variety)
 691         lightstyle(9, "aaaaaaaazzzzzzzz");
 692
 693         // 10 FLUORESCENT FLICKER
 694         lightstyle(10, "mmamammmmammamamaaamammma");
 695
 696         // 11 SLOW PULSE NOT FADE TO BLACK
 697         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 698
 699         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 700
 701         // 63 testing
 702         lightstyle(63, "a");
 703
 704         if(autocvar_g_campaign)
 705                 CampaignPreInit();
 706
 707         Map_MarkAsRecent(mapname);
 708
 709         precache_model ("null"); // we need this one before InitGameplayMode
 710         InitGameplayMode();
 711         readlevelcvars();
 712         GrappleHookInit();
 713         ElectroInit();
 714         LaserInit();
 715
 716         player_count = 0;
 717         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 718         if(bot_waypoints_for_items == 1)
 719                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 720                         bot_waypoints_for_items = 0;
 721
 722         precache();
 723
 724         WaypointSprite_Init();
 725
 726         //if (g_domination)
 727         //      dom_init();
 728
 729         GameLogInit(); // prepare everything
 730         // NOTE for matchid:
 731         // changing the logic generating it is okay. But:
 732         // it HAS to stay <= 64 chars
 733         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 734         if(autocvar_sv_eventlog)
 735         {
 736                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 737                 matchid = strzone(s);
 738
 739                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 740                 s = ":gameinfo:mutators:LIST";
 741
 742                 ret_string = s;
 743                 MUTATOR_CALLHOOK(BuildMutatorsString);
 744                 s = ret_string;
 745
 746                 // simple, probably not good in the mutator system
 747                 if(autocvar_g_grappling_hook)
 748                         s = strcat(s, ":grappling_hook");
 749
 750                 // initialiation stuff, not good in the mutator system
 751                 if(!autocvar_g_use_ammunition)
 752                         s = strcat(s, ":no_use_ammunition");
 753
 754                 // initialiation stuff, not good in the mutator system
 755                 if(autocvar_g_pickup_items == 0)
 756                         s = strcat(s, ":no_pickup_items");
 757                 if(autocvar_g_pickup_items > 0)
 758                         s = strcat(s, ":pickup_items");
 759
 760                 // initialiation stuff, not good in the mutator system
 761                 if(autocvar_g_weaponarena != "0")
 762                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 763
 764                 // TODO to mutator system
 765                 if(autocvar_g_norecoil)
 766                         s = strcat(s, ":norecoil");
 767
 768                 // TODO to mutator system
 769                 if(autocvar_g_midair)
 770                         s = strcat(s, ":midair");
 771
 772                 // TODO to mutator system
 773                 if(autocvar_g_minstagib)
 774                         s = strcat(s, ":minstagib");
 775
 776                 // TODO to mutator system
 777                 if(autocvar_g_powerups == 0)
 778                         s = strcat(s, ":no_powerups");
 779                 if(autocvar_g_powerups > 0)
 780                         s = strcat(s, ":powerups");
 781
 782                 GameLogEcho(s);
 783                 GameLogEcho(":gameinfo:end");
 784         }
 785         else
 786                 matchid = strzone(ftos(random()));
 787
 788         cvar_set("nextmap", "");
 789
 790         SetDefaultAlpha();
 791
 792         if(autocvar_g_campaign)
 793                 CampaignPostInit();
 794
 795         fteqcc_testbugs();
 796
 797         Ban_LoadBans();
 798
 799         MapInfo_Enumerate();
 800         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 801
 802         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 803         {
 804                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 805                 if(fd != -1)
 806                 {
 807                         while((s = fgets(fd)))
 808                         {
 809                                 l = tokenize_console(s);
 810                                 if(l < 2)
 811                                         continue;
 812                                 if(argv(0) == "cd")
 813                                 {
 814                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 815                                         print("  cdtrack ", argv(2), "\n");
 816                                 }
 817                                 else if(argv(0) == "fog")
 818                                 {
 819                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 820                                         print("  \"fog\" \"", s, "\"\n");
 821                                 }
 822                                 else if(argv(0) == "set")
 823                                 {
 824                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 825                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 826                                 }
 827                                 else if(argv(0) != "//")
 828                                 {
 829                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 830                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 831                                 }
 832                         }
 833                         fclose(fd);
 834                 }
 835         }
 836
 837         WeaponStats_Init();
 838
 839         addstat(STAT_WEAPONS, AS_INT, weapons);
 840         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 841         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 842         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 843         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 844         Nagger_Init();
 845
 846         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 847         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 848         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 849         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 850         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 851         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 852         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 853         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 854         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 855         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 856         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 857         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 858
 859         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 860         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 861
 862         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 863
 864         if(g_ca || g_freezetag)
 865         {
 866                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 867                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 868                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 869                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 870         }
 871         if(g_freezetag)
 872         {
 873                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 874                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 875         }
 876
 877         // g_movementspeed hack
 878         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 879         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 880         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 881         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 882
 883         // secrets
 884         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 885         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 886
 887         next_pingtime = time + 5;
 888
 889         detect_maptype();
 890
 891         lsmaps_reply = "^7Maps available: ";
 892         lsnewmaps_reply = "^7Maps without a record set: ";
 893         for(i = 0, j = 0; i < MapInfo_count; ++i)
 894         {
 895                 if(MapInfo_Get_ByID(i))
 896                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 897                         {
 898                                 if(mod(i, 2))
 899                                         col = "^2";
 900                                 else
 901                                         col = "^3";
 902                                 ++j;
 903                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 904                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 905                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 906                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 907                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 908                         }
 909         }
 910         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 911         if (!g_race && !g_cts)
 912                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 913         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 914
 915         maplist_reply = "^7Maps in list: ";
 916         n = tokenize_console(autocvar_g_maplist);
 917         for(i = 0, j = 0; i < n; ++i)
 918         {
 919                 if(MapInfo_CheckMap(argv(i)))
 920                 {
 921                         if(mod(j, 2))
 922                                 col = "^2";
 923                         else
 924                                 col = "^3";
 925                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 926                         ++j;
 927                 }
 928         }
 929         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 930         MapInfo_ClearTemps();
 931
 932         for(i = 0; i < 10; ++i)
 933         {
 934                 records_reply[i] = strzone(getrecords(i));
 935         }
 936         if(g_cts)
 937                 ladder_reply = strzone(getladder());
 938
 939         rankings_reply = strzone(getrankings());
 940
 941         ClientInit_Spawn();
 942         RandomSeed_Spawn();
 943         PingPLReport_Spawn();
 944
 945         CheatInit();
 946
 947         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 948
 949         // fill sv_curl_serverpackages from .serverpackage files
 950         if(autocvar_sv_curl_serverpackages_auto)
 951         {
 952                 s = "";
 953                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 954                 for(i = 0; i < n; ++i)
 955                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 956                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 957                                 s = strcat(s, " ", argv(i));
 958                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 959                 if(fd >= 0)
 960                 {
 961                         j = search_getsize(fd);
 962                         for(i = 0; i < j; ++i)
 963                                 s = strcat(s, " ", search_getfilename(fd, i));
 964                         search_end(fd);
 965                 }
 966                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 967                 if(fd >= 0)
 968                 {
 969                         j = search_getsize(fd);
 970                         for(i = 0; i < j; ++i)
 971                                 s = strcat(s, " ", search_getfilename(fd, i));
 972                         search_end(fd);
 973                 }
 974                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 975         }
 976
 977         PlayerStats_Init();
 978
 979         world_initialized = 1;
 980 }
 981
 982 void spawnfunc_light (void)
 983 {
 984         //makestatic (self); // Who the f___ did that?
 985         remove(self);
 986 }
 987
 988 string GetGametype()
 989 {
 990         return GametypeNameFromType(game);
 991 }
 992
 993 string getmapname_stored;
 994 string GetMapname()
 995 {
 996         return mapname;
 997 }
 998
 999 float Map_Count, Map_Current;
1000 string Map_Current_Name;
1001
1002 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1003 float GetMaplistPosition()
1004 {
1005         float pos, idx;
1006         string map;
1007
1008         map = GetMapname();
1009         idx = autocvar_g_maplist_index;
1010
1011         if(idx >= 0)
1012                 if(idx < Map_Count)
1013                         if(map == argv(idx))
1014                                 return idx;
1015
1016         for(pos = 0; pos < Map_Count; ++pos)
1017                 if(map == argv(pos))
1018                         return pos;
1019
1020         // resume normal maplist rotation if current map is not in g_maplist
1021         return idx;
1022 }
1023
1024 float MapHasRightSize(string map)
1025 {
1026         float fh;
1027         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1028         if(autocvar_g_maplist_check_waypoints)
1029         {
1030                 dprint("checkwp "); dprint(map);
1031                 if(!fexists(strcat("maps/", map, ".waypoints")))
1032                 {
1033                         dprint(": no waypoints\n");
1034                         return FALSE;
1035                 }
1036                 dprint(": has waypoints\n");
1037         }
1038
1039         // open map size restriction file
1040         dprint("opensize "); dprint(map);
1041         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1042         if(fh >= 0)
1043         {
1044                 float mapmin, mapmax;
1045                 dprint(": ok, ");
1046                 mapmin = stof(fgets(fh));
1047                 mapmax = stof(fgets(fh));
1048                 fclose(fh);
1049                 if(player_count < mapmin)
1050                 {
1051                         dprint("not enough\n");
1052                         return FALSE;
1053                 }
1054                 if(player_count > mapmax)
1055                 {
1056                         dprint("too many\n");
1057                         return FALSE;
1058                 }
1059                 dprint("right size\n");
1060                 return TRUE;
1061         }
1062         dprint(": not found\n");
1063         return TRUE;
1064 }
1065
1066 string Map_Filename(float position)
1067 {
1068         return strcat("maps/", argv(position), ".bsp");
1069 }
1070
1071 string strwords(string s, float w)
1072 {
1073         float endpos;
1074         for(endpos = 0; w && endpos >= 0; --w)
1075                 endpos = strstrofs(s, " ", endpos + 1);
1076         if(endpos < 0)
1077                 return s;
1078         else
1079                 return substring(s, 0, endpos);
1080 }
1081
1082 float strhasword(string s, string w)
1083 {
1084         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1085 }
1086
1087 void Map_MarkAsRecent(string m)
1088 {
1089         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1090 }
1091
1092 float Map_IsRecent(string m)
1093 {
1094         return strhasword(autocvar_g_maplist_mostrecent, m);
1095 }
1096
1097 float Map_Check(float position, float pass)
1098 {
1099         string filename;
1100         string map_next;
1101         map_next = argv(position);
1102         if(pass <= 1)
1103         {
1104                 if(Map_IsRecent(map_next))
1105                         return 0;
1106         }
1107         filename = Map_Filename(position);
1108         if(MapInfo_CheckMap(map_next))
1109         {
1110                 if(pass == 2)
1111                         return 1;
1112                 if(MapHasRightSize(map_next))
1113                         return 1;
1114                 return 0;
1115         }
1116         else
1117                 dprint( "Couldn't select '", filename, "'..\n" );
1118
1119         return 0;
1120 }
1121
1122 void Map_Goto_SetStr(string nextmapname)
1123 {
1124         if(getmapname_stored != "")
1125                 strunzone(getmapname_stored);
1126         if(nextmapname == "")
1127                 getmapname_stored = "";
1128         else
1129                 getmapname_stored = strzone(nextmapname);
1130 }
1131
1132 void Map_Goto_SetFloat(float position)
1133 {
1134         cvar_set("g_maplist_index", ftos(position));
1135         Map_Goto_SetStr(argv(position));
1136 }
1137
1138 void GameResetCfg()
1139 {
1140         // settings persist, except...
1141         localcmd("\nsettemp_restore\n");
1142 }
1143
1144 void Map_Goto(float reinit)
1145 {
1146         GameResetCfg();
1147         MapInfo_LoadMap(getmapname_stored, reinit);
1148 }
1149
1150 // return codes of map selectors:
1151 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1152 //   -2 = permanent failure
1153 float() MaplistMethod_Iterate = // usual method
1154 {
1155         float pass, i;
1156
1157         for(pass = 1; pass <= 2; ++pass)
1158         {
1159                 for(i = 1; i < Map_Count; ++i)
1160                 {
1161                         float mapindex;
1162                         mapindex = mod(i + Map_Current, Map_Count);
1163                         if(Map_Check(mapindex, pass))
1164                                 return mapindex;
1165                 }
1166         }
1167         return -1;
1168 }
1169
1170 float() MaplistMethod_Repeat = // fallback method
1171 {
1172         if(Map_Check(Map_Current, 2))
1173                 return Map_Current;
1174         return -2;
1175 }
1176
1177 float() MaplistMethod_Random = // random map selection
1178 {
1179         float i, imax;
1180
1181         imax = 42;
1182
1183         for(i = 0; i <= imax; ++i)
1184         {
1185                 float mapindex;
1186                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1187                 if(Map_Check(mapindex, 1))
1188                         return mapindex;
1189         }
1190         return -1;
1191 }
1192
1193 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1194 // the exponent sets a bias on the map selection:
1195 // the higher the exponent, the less likely "shortly repeated" same maps are
1196 {
1197         float i, j, imax, insertpos;
1198
1199         imax = 42;
1200
1201         for(i = 0; i <= imax; ++i)
1202         {
1203                 string newlist;
1204
1205                 // now reinsert this at another position
1206                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1207                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1208                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1209                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1210
1211                 // insert the current map there
1212                 newlist = "";
1213                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1214                         newlist = strcat(newlist, " ", argv(j));
1215                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1216                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1217                         newlist = strcat(newlist, " ", argv(j));
1218                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1219                 cvar_set("g_maplist", newlist);
1220                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1221
1222                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1223                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1224                 if(Map_Check(Map_Current, 1))
1225                         return Map_Current;
1226         }
1227         return -1;
1228 }
1229
1230 void Maplist_Init()
1231 {
1232         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1233         if(Map_Count == 0)
1234         {
1235                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1236                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1237                 if(autocvar_g_maplist_shuffle)
1238                         ShuffleMaplist();
1239                 localcmd("\nmenu_cmd sync\n");
1240                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1241         }
1242         if(Map_Count == 0)
1243                 error("empty maplist, cannot select a new map");
1244         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1245
1246         if(Map_Current_Name)
1247                 strunzone(Map_Current_Name);
1248         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1249         // this may or may not be correct, but who cares, in the worst case a map
1250         // isn't chosen in the first pass that should have been
1251 }
1252
1253 string GetNextMap()
1254 {
1255         float nextMap;
1256
1257         Maplist_Init();
1258         nextMap = -1;
1259
1260         if(nextMap == -1)
1261                 if(autocvar_g_maplist_shuffle > 0)
1262                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1263
1264         if(nextMap == -1)
1265                 if(autocvar_g_maplist_selectrandom)
1266                         nextMap = MaplistMethod_Random();
1267
1268         if(nextMap == -1)
1269                 nextMap = MaplistMethod_Iterate();
1270
1271         if(nextMap == -1)
1272                 nextMap = MaplistMethod_Repeat();
1273
1274         if(nextMap >= 0)
1275         {
1276                 Map_Goto_SetFloat(nextMap);
1277                 return getmapname_stored;
1278         }
1279
1280         return "";
1281 }
1282
1283 float DoNextMapOverride(float reinit)
1284 {
1285         if(autocvar_g_campaign)
1286         {
1287                 CampaignPostIntermission();
1288                 alreadychangedlevel = TRUE;
1289                 return TRUE;
1290         }
1291         if(autocvar_quit_when_empty)
1292         {
1293                 if(player_count <= currentbots)
1294                 {
1295                         localcmd("quit\n");
1296                         alreadychangedlevel = TRUE;
1297                         return TRUE;
1298                 }
1299         }
1300         if(autocvar_quit_and_redirect != "")
1301         {
1302                 redirection_target = strzone(autocvar_quit_and_redirect);
1303                 alreadychangedlevel = TRUE;
1304                 return TRUE;
1305         }
1306         if (autocvar_samelevel) // if samelevel is set, stay on same level
1307         {
1308                 localcmd("restart\n");
1309                 alreadychangedlevel = TRUE;
1310                 return TRUE;
1311         }
1312         if(autocvar_nextmap != "")
1313                 if(MapInfo_CheckMap(autocvar_nextmap))
1314                 {
1315                         Map_Goto_SetStr(autocvar_nextmap);
1316                         Map_Goto(reinit);
1317                         alreadychangedlevel = TRUE;
1318                         return TRUE;
1319                 }
1320         if(autocvar_lastlevel)
1321         {
1322                 GameResetCfg();
1323                 localcmd("set lastlevel 0\ntogglemenu\n");
1324                 alreadychangedlevel = TRUE;
1325                 return TRUE;
1326         }
1327         return FALSE;
1328 }
1329
1330 void GotoNextMap(float reinit)
1331 {
1332         //string nextmap;
1333         //float n, nummaps;
1334         //string s;
1335         if (alreadychangedlevel)
1336                 return;
1337         alreadychangedlevel = TRUE;
1338
1339         {
1340                 string nextMap;
1341                 float allowReset;
1342
1343                 for(allowReset = 1; allowReset >= 0; --allowReset)
1344                 {
1345                         nextMap = GetNextMap();
1346                         if(nextMap != "")
1347                                 break;
1348
1349                         if(allowReset)
1350                         {
1351                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1352                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1353                                 if(autocvar_g_maplist_shuffle)
1354                                         ShuffleMaplist();
1355                                 localcmd("\nmenu_cmd sync\n");
1356                         }
1357                         else
1358                         {
1359                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1360                         }
1361                 }
1362                 Map_Goto(reinit);
1363         }
1364 }
1365
1366
1367 /*
1368 ============
1369 IntermissionThink
1370
1371 When the player presses attack or jump, change to the next level
1372 ============
1373 */
1374 .float autoscreenshot;
1375 void() MapVote_Start;
1376 void() MapVote_Think;
1377 float mapvote_initialized;
1378 void IntermissionThink()
1379 {
1380         FixIntermissionClient(self);
1381
1382         if( (autocvar_sv_autoscreenshot || self.cvar_cl_autoscreenshot)
1383                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1384         {
1385                 self.autoscreenshot = -1;
1386                 if(clienttype(self) == CLIENTTYPE_REAL) { stuffcmd(self, sprintf("\nautoscreenshot \"%s\" \"%s\"\n", GetMapname(), strftime(FALSE, "%s"))); }
1387                 return;
1388         }
1389
1390         if (time < intermission_exittime)
1391                 return;
1392
1393         if(!mapvote_initialized)
1394                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1395                         return;
1396
1397         MapVote_Start();
1398 }
1399
1400 /*
1401 ============
1402 FindIntermission
1403
1404 Returns the entity to view from
1405 ============
1406 */
1407 /*
1408 entity FindIntermission()
1409 {
1410         local   entity spot;
1411         local   float cyc;
1412
1413 // look for info_intermission first
1414         spot = find (world, classname, "info_intermission");
1415         if (spot)
1416         {       // pick a random one
1417                 cyc = random() * 4;
1418                 while (cyc > 1)
1419                 {
1420                         spot = find (spot, classname, "info_intermission");
1421                         if (!spot)
1422                                 spot = find (spot, classname, "info_intermission");
1423                         cyc = cyc - 1;
1424                 }
1425                 return spot;
1426         }
1427
1428 // then look for the start position
1429         spot = find (world, classname, "info_player_start");
1430         if (spot)
1431                 return spot;
1432
1433 // testinfo_player_start is only found in regioned levels
1434         spot = find (world, classname, "testplayerstart");
1435         if (spot)
1436                 return spot;
1437
1438 // then look for the start position
1439         spot = find (world, classname, "info_player_deathmatch");
1440         if (spot)
1441                 return spot;
1442
1443         //objerror ("FindIntermission: no spot");
1444         return world;
1445 }
1446 */
1447
1448 /*
1449 ===============================================================================
1450
1451 RULES
1452
1453 ===============================================================================
1454 */
1455
1456 void DumpStats(float final)
1457 {
1458         float file;
1459         string s;
1460         float to_console;
1461         float to_eventlog;
1462         float to_file;
1463         float i;
1464
1465         to_console = autocvar_sv_logscores_console;
1466         to_eventlog = autocvar_sv_eventlog;
1467         to_file = autocvar_sv_logscores_file;
1468
1469         if(!final)
1470         {
1471                 to_console = TRUE; // always print printstats replies
1472                 to_eventlog = FALSE; // but never print them to the event log
1473         }
1474
1475         if(to_eventlog)
1476                 if(autocvar_sv_eventlog_console)
1477                         to_console = FALSE; // otherwise we get the output twice
1478
1479         if(final)
1480                 s = ":scores:";
1481         else
1482                 s = ":status:";
1483         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1484
1485         if(to_console)
1486                 print(s, "\n");
1487         if(to_eventlog)
1488                 GameLogEcho(s);
1489         if(to_file)
1490         {
1491                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1492                 if(file == -1)
1493                         to_file = FALSE;
1494                 else
1495                         fputs(file, strcat(s, "\n"));
1496         }
1497
1498         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1499         if(to_console)
1500                 print(s, "\n");
1501         if(to_eventlog)
1502                 GameLogEcho(s);
1503         if(to_file)
1504                 fputs(file, strcat(s, "\n"));
1505
1506         FOR_EACH_CLIENT(other)
1507         {
1508                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1509                 {
1510                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1511                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1512                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1513                                 s = strcat(s, ftos(other.team), ":");
1514                         else
1515                                 s = strcat(s, "spectator:");
1516
1517                         if(to_console)
1518                                 print(s, other.netname, "\n");
1519                         if(to_eventlog)
1520                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1521                         if(to_file)
1522                                 fputs(file, strcat(s, other.netname, "\n"));
1523                 }
1524         }
1525
1526         if(teamplay)
1527         {
1528                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1529                 if(to_console)
1530                         print(s, "\n");
1531                 if(to_eventlog)
1532                         GameLogEcho(s);
1533                 if(to_file)
1534                         fputs(file, strcat(s, "\n"));
1535
1536                 for(i = 1; i < 16; ++i)
1537                 {
1538                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1539                         s = strcat(s, ":", ftos(i));
1540                         if(to_console)
1541                                 print(s, "\n");
1542                         if(to_eventlog)
1543                                 GameLogEcho(s);
1544                         if(to_file)
1545                                 fputs(file, strcat(s, "\n"));
1546                 }
1547         }
1548
1549         if(to_console)
1550                 print(":end\n");
1551         if(to_eventlog)
1552                 GameLogEcho(":end");
1553         if(to_file)
1554         {
1555                 fputs(file, ":end\n");
1556                 fclose(file);
1557         }
1558 }
1559
1560 void FixIntermissionClient(entity e)
1561 {
1562         string s;
1563         if(!e.autoscreenshot) // initial call
1564         {
1565                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1566                 e.health = -2342;
1567                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1568                 e.solid = SOLID_NOT;
1569                 e.movetype = MOVETYPE_NONE;
1570                 e.takedamage = DAMAGE_NO;
1571                 if(e.weaponentity)
1572                 {
1573                         e.weaponentity.effects = EF_NODRAW;
1574                         if (e.weaponentity.weaponentity)
1575                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1576                 }
1577                 if(clienttype(e) == CLIENTTYPE_REAL)
1578                 {
1579                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1580                         s = autocvar_sv_intermission_cdtrack;
1581                         if(s != "")
1582                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1583                         msg_entity = e;
1584                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1585                 }
1586         }
1587 }
1588
1589
1590 /*
1591 go to the next level for deathmatch
1592 only called if a time or frag limit has expired
1593 */
1594 void NextLevel()
1595 {
1596         gameover = TRUE;
1597
1598         intermission_running = 1;
1599
1600 // enforce a wait time before allowing changelevel
1601         if(player_count > 0)
1602                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1603         else
1604                 intermission_exittime = -1;
1605
1606         /*
1607         WriteByte (MSG_ALL, SVC_CDTRACK);
1608         WriteByte (MSG_ALL, 3);
1609         WriteByte (MSG_ALL, 3);
1610         // done in FixIntermission
1611         */
1612
1613         //pos = FindIntermission ();
1614
1615         VoteReset();
1616
1617         DumpStats(TRUE);
1618
1619         // send statistics
1620         entity e;
1621         PlayerStats_EndMatch(1);
1622         FOR_EACH_CLIENT(e)
1623                 PlayerStats_AddGlobalInfo(e);
1624         PlayerStats_Shutdown();
1625         WeaponStats_Shutdown();
1626
1627         if(autocvar_sv_eventlog)
1628                 GameLogEcho(":gameover");
1629
1630         GameLogClose();
1631
1632         FOR_EACH_PLAYER(other) {
1633                 FixIntermissionClient(other);
1634                 if(other.winning)
1635                         bprint(other.netname, " ^7wins.\n");
1636         }
1637
1638         if(autocvar_g_campaign)
1639                 CampaignPreIntermission();
1640
1641         localcmd("\nsv_hook_gameend\n");
1642 }
1643
1644 /*
1645 ============
1646 CheckRules_Player
1647
1648 Exit deathmatch games upon conditions
1649 ============
1650 */
1651 void CheckRules_Player()
1652 {
1653         if (gameover)   // someone else quit the game already
1654                 return;
1655
1656         if(self.deadflag == DEAD_NO)
1657                 self.play_time += frametime;
1658
1659         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1660         //   (div0: and that in CheckRules_World please)
1661 }
1662
1663 float checkrules_equality;
1664 float checkrules_suddendeathwarning;
1665 float checkrules_suddendeathend;
1666 float checkrules_overtimesadded; //how many overtimes have been already added
1667
1668 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1669 float WINNING_YES = 1; // winner found
1670 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1671 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1672
1673 float InitiateSuddenDeath()
1674 {
1675         // Check first whether normal overtimes could be added before initiating suddendeath mode
1676         // - for this timelimit_overtime needs to be >0 of course
1677         // - also check the winning condition calculated in the previous frame and only add normal overtime
1678         //   again, if at the point at which timelimit would be extended again, still no winner was found
1679         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1680         {
1681                 return 1; // need to call InitiateOvertime later
1682         }
1683         else
1684         {
1685                 if(!checkrules_suddendeathend)
1686                 {
1687                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1688                         if(g_race && !g_race_qualifying)
1689                                 race_StartCompleting();
1690                 }
1691                 return 0;
1692         }
1693 }
1694
1695 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1696 {
1697         ++checkrules_overtimesadded;
1698         //add one more overtime by simply extending the timelimit
1699         float tl;
1700         tl = autocvar_timelimit;
1701         tl += autocvar_timelimit_overtime;
1702         cvar_set("timelimit", ftos(tl));
1703         string minutesPlural;
1704         if (autocvar_timelimit_overtime == 1)
1705                 minutesPlural = " ^3minute";
1706         else
1707                 minutesPlural = " ^3minutes";
1708
1709         bcenterprint(
1710                 strcat(
1711                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1712                         ftos(autocvar_timelimit_overtime),
1713                         minutesPlural,
1714                         " to the game!"
1715                 )
1716         );
1717 }
1718
1719 float GetWinningCode(float fraglimitreached, float equality)
1720 {
1721         if(autocvar_g_campaign == 1)
1722                 if(fraglimitreached)
1723                         return WINNING_YES;
1724                 else
1725                         return WINNING_NO;
1726
1727         else
1728                 if(equality)
1729                         if(fraglimitreached)
1730                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1731                         else
1732                                 return WINNING_NEVER;
1733                 else
1734                         if(fraglimitreached)
1735                                 return WINNING_YES;
1736                         else
1737                                 return WINNING_NO;
1738 }
1739
1740 // set the .winning flag for exactly those players with a given field value
1741 void SetWinners(.float field, float value)
1742 {
1743         entity head;
1744         FOR_EACH_PLAYER(head)
1745                 head.winning = (head.field == value);
1746 }
1747
1748 // set the .winning flag for those players with a given field value
1749 void AddWinners(.float field, float value)
1750 {
1751         entity head;
1752         FOR_EACH_PLAYER(head)
1753                 if(head.field == value)
1754                         head.winning = 1;
1755 }
1756
1757 // clear the .winning flags
1758 void ClearWinners(void)
1759 {
1760         entity head;
1761         FOR_EACH_PLAYER(head)
1762                 head.winning = 0;
1763 }
1764
1765 // Onslaught winning condition:
1766 // game terminates if only one team has a working generator (or none)
1767 float WinningCondition_Onslaught()
1768 {
1769         entity head;
1770         float t1, t2, t3, t4;
1771
1772         WinningConditionHelper(); // set worldstatus
1773
1774         if(inWarmupStage)
1775                 return WINNING_NO;
1776
1777         // first check if the game has ended
1778         t1 = t2 = t3 = t4 = 0;
1779         head = find(world, classname, "onslaught_generator");
1780         while (head)
1781         {
1782                 if (head.health > 0)
1783                 {
1784                         if (head.team == COLOR_TEAM1) t1 = 1;
1785                         if (head.team == COLOR_TEAM2) t2 = 1;
1786                         if (head.team == COLOR_TEAM3) t3 = 1;
1787                         if (head.team == COLOR_TEAM4) t4 = 1;
1788                 }
1789                 head = find(head, classname, "onslaught_generator");
1790         }
1791         if (t1 + t2 + t3 + t4 < 2)
1792         {
1793                 // game over, only one team remains (or none)
1794                 ClearWinners();
1795                 if (t1) SetWinners(team, COLOR_TEAM1);
1796                 if (t2) SetWinners(team, COLOR_TEAM2);
1797                 if (t3) SetWinners(team, COLOR_TEAM3);
1798                 if (t4) SetWinners(team, COLOR_TEAM4);
1799                 dprint("Have a winner, ending game.\n");
1800                 return WINNING_YES;
1801         }
1802
1803         // Two or more teams remain
1804         return WINNING_NO;
1805 }
1806
1807 float LMS_NewPlayerLives()
1808 {
1809         float fl;
1810         fl = autocvar_fraglimit;
1811         if(fl == 0)
1812                 fl = 999;
1813
1814         // first player has left the game for dying too much? Nobody else can get in.
1815         if(lms_lowest_lives < 1)
1816                 return 0;
1817
1818         if(!autocvar_g_lms_join_anytime)
1819                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1820                         return 0;
1821
1822         return bound(1, lms_lowest_lives, fl);
1823 }
1824
1825 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1826 // they win. Otherwise the defending team wins once the timelimit passes.
1827 void assault_new_round();
1828 float WinningCondition_Assault()
1829 {
1830         float status;
1831
1832         WinningConditionHelper(); // set worldstatus
1833
1834         status = WINNING_NO;
1835         // as the timelimit has not yet passed just assume the defending team will win
1836         if(assault_attacker_team == COLOR_TEAM1)
1837         {
1838                 SetWinners(team, COLOR_TEAM2);
1839         }
1840         else
1841         {
1842                 SetWinners(team, COLOR_TEAM1);
1843         }
1844
1845         entity ent;
1846         ent = find(world, classname, "target_assault_roundend");
1847         if(ent)
1848         {
1849                 if(ent.winning) // round end has been triggered by attacking team
1850                 {
1851                         bprint("ASSAULT: round completed...\n");
1852                         SetWinners(team, assault_attacker_team);
1853
1854                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1855
1856                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1857                         {
1858                                 status = WINNING_YES;
1859                         }
1860                         else
1861                         {
1862                                 entity oldself;
1863                                 oldself = self;
1864                                 self = ent;
1865                                 assault_new_round();
1866                                 self = oldself;
1867                         }
1868                 }
1869         }
1870
1871         return status;
1872 }
1873
1874 // LMS winning condition: game terminates if and only if there's at most one
1875 // one player who's living lives. Top two scores being equal cancels the time
1876 // limit.
1877 float WinningCondition_LMS()
1878 {
1879         entity head, head2;
1880         float have_player;
1881         float have_players;
1882         float l;
1883
1884         have_player = FALSE;
1885         have_players = FALSE;
1886         l = LMS_NewPlayerLives();
1887
1888         head = find(world, classname, "player");
1889         if(head)
1890                 have_player = TRUE;
1891         head2 = find(head, classname, "player");
1892         if(head2)
1893                 have_players = TRUE;
1894
1895         if(have_player)
1896         {
1897                 // we have at least one player
1898                 if(have_players)
1899                 {
1900                         // two or more active players - continue with the game
1901                 }
1902                 else
1903                 {
1904                         // exactly one player?
1905
1906                         ClearWinners();
1907                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1908
1909                         if(l)
1910                         {
1911                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1912                                 return WINNING_NO;
1913                         }
1914                         else
1915                         {
1916                                 // a winner!
1917                                 // and assign him his first place
1918                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1919                                 return WINNING_YES;
1920                         }
1921                 }
1922         }
1923         else
1924         {
1925                 // nobody is playing at all...
1926                 if(l)
1927                 {
1928                         // wait for players...
1929                 }
1930                 else
1931                 {
1932                         // SNAFU (maybe a draw game?)
1933                         ClearWinners();
1934                         dprint("No players, ending game.\n");
1935                         return WINNING_YES;
1936                 }
1937         }
1938
1939         // When we get here, we have at least two players who are actually LIVING,
1940         // now check if the top two players have equal score.
1941         WinningConditionHelper();
1942
1943         ClearWinners();
1944         if(WinningConditionHelper_winner)
1945                 WinningConditionHelper_winner.winning = TRUE;
1946         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1947                 return WINNING_NEVER;
1948
1949         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1950         return WINNING_NO;
1951 }
1952
1953 void ShuffleMaplist()
1954 {
1955         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1956 }
1957
1958 float leaderfrags;
1959 float WinningCondition_Scores(float limit, float leadlimit)
1960 {
1961         float limitreached;
1962
1963         // TODO make everything use THIS winning condition (except LMS)
1964         WinningConditionHelper();
1965
1966         if(teamplay)
1967         {
1968                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1969                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1970                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1971                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1972         }
1973
1974         ClearWinners();
1975         if(WinningConditionHelper_winner)
1976                 WinningConditionHelper_winner.winning = 1;
1977         if(WinningConditionHelper_winnerteam >= 0)
1978                 SetWinners(team, WinningConditionHelper_winnerteam);
1979
1980         if(WinningConditionHelper_lowerisbetter)
1981         {
1982                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1983                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1984                 limit = -limit;
1985         }
1986
1987         if(WinningConditionHelper_zeroisworst)
1988                 leadlimit = 0; // not supported in this mode
1989
1990         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1991         // these modes always score in increments of 1, thus this makes sense
1992         {
1993                 if(leaderfrags != WinningConditionHelper_topscore)
1994                 {
1995                         leaderfrags = WinningConditionHelper_topscore;
1996
1997                         if (limit)
1998                         if (leaderfrags == limit - 1)
1999                                 Announce("1fragleft");
2000                         else if (leaderfrags == limit - 2)
2001                                 Announce("2fragsleft");
2002                         else if (leaderfrags == limit - 3)
2003                                 Announce("3fragsleft");
2004                 }
2005         }
2006
2007         limitreached = FALSE;
2008         if(limit)
2009                 if(WinningConditionHelper_topscore >= limit)
2010                         limitreached = TRUE;
2011         if(leadlimit)
2012         {
2013                 float leadlimitreached;
2014                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
2015                 if(autocvar_leadlimit_and_fraglimit)
2016                         limitreached = (limitreached && leadlimitreached);
2017                 else
2018                         limitreached = (limitreached || leadlimitreached);
2019         }
2020
2021         return GetWinningCode(
2022                 WinningConditionHelper_topscore && limitreached,
2023                 WinningConditionHelper_equality
2024         );
2025 }
2026
2027 float WinningCondition_Race(float fraglimit)
2028 {
2029         float wc;
2030         entity p;
2031         float n, c;
2032
2033         n = 0;
2034         c = 0;
2035         FOR_EACH_PLAYER(p)
2036         {
2037                 ++n;
2038                 if(p.race_completed)
2039                         ++c;
2040         }
2041         if(n && (n == c))
2042                 return WINNING_YES;
2043         wc = WinningCondition_Scores(fraglimit, 0);
2044
2045         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2046         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2047         // do NOT support equality when the laps are all raced!
2048                 return WINNING_STARTSUDDENDEATHOVERTIME;
2049         else
2050                 return WINNING_NEVER;
2051         return wc;
2052 }
2053
2054 float WinningCondition_QualifyingThenRace(float limit)
2055 {
2056         float wc;
2057         wc = WinningCondition_Scores(limit, 0);
2058
2059         // NEVER initiate overtime
2060         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2061         {
2062                 return WINNING_YES;
2063         }
2064
2065         return wc;
2066 }
2067
2068 float WinningCondition_RanOutOfSpawns()
2069 {
2070         entity head;
2071
2072         if(have_team_spawns <= 0)
2073                 return WINNING_NO;
2074
2075         if(autocvar_g_spawn_useallspawns <= 0)
2076                 return WINNING_NO;
2077
2078         if(!some_spawn_has_been_used)
2079                 return WINNING_NO;
2080
2081         team1_score = team2_score = team3_score = team4_score = 0;
2082
2083         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2084         {
2085                 if(head.team == COLOR_TEAM1)
2086                         team1_score = 1;
2087                 else if(head.team == COLOR_TEAM2)
2088                         team2_score = 1;
2089                 else if(head.team == COLOR_TEAM3)
2090                         team3_score = 1;
2091                 else if(head.team == COLOR_TEAM4)
2092                         team4_score = 1;
2093         }
2094
2095         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2096         {
2097                 if(head.team == COLOR_TEAM1)
2098                         team1_score = 1;
2099                 else if(head.team == COLOR_TEAM2)
2100                         team2_score = 1;
2101                 else if(head.team == COLOR_TEAM3)
2102                         team3_score = 1;
2103                 else if(head.team == COLOR_TEAM4)
2104                         team4_score = 1;
2105         }
2106
2107         ClearWinners();
2108         if(team1_score + team2_score + team3_score + team4_score == 0)
2109         {
2110                 checkrules_equality = TRUE;
2111                 return WINNING_YES;
2112         }
2113         else if(team1_score + team2_score + team3_score + team4_score == 1)
2114         {
2115                 float t, i;
2116                 if(team1_score) t = COLOR_TEAM1;
2117                 if(team2_score) t = COLOR_TEAM2;
2118                 if(team3_score) t = COLOR_TEAM3;
2119                 if(team4_score) t = COLOR_TEAM4;
2120                 CheckAllowedTeams(world);
2121                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2122                 {
2123                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2124                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2125                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2126                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2127                 }
2128
2129                 AddWinners(team, t);
2130                 return WINNING_YES;
2131         }
2132         else
2133                 return WINNING_NO;
2134 }
2135
2136 /*
2137 ============
2138 CheckRules_World
2139
2140 Exit deathmatch games upon conditions
2141 ============
2142 */
2143 void ReadyRestart();
2144 void CheckRules_World()
2145 {
2146         float timelimit;
2147         float fraglimit;
2148         float leadlimit;
2149
2150         VoteThink();
2151         MapVote_Think();
2152
2153         SetDefaultAlpha();
2154
2155         /*
2156         MapVote_Think should now do that part
2157         if (intermission_running)
2158                 if (time >= intermission_exittime + 60)
2159                 {
2160                         if(!DoNextMapOverride())
2161                                 GotoNextMap();
2162                         return;
2163                 }
2164         */
2165
2166         if (gameover)   // someone else quit the game already
2167         {
2168                 if(player_count == 0) // Nobody there? Then let's go to the next map
2169                         MapVote_Start();
2170                         // this will actually check the player count in the next frame
2171                         // again, but this shouldn't hurt
2172                 return;
2173         }
2174
2175         timelimit = autocvar_timelimit * 60;
2176         fraglimit = autocvar_fraglimit;
2177         leadlimit = autocvar_leadlimit;
2178
2179         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2180         {
2181                 if(timelimit > 0)
2182                         timelimit = 0; // timelimit is not made for warmup
2183                 if(fraglimit > 0)
2184                         fraglimit = 0; // no fraglimit for now
2185                 leadlimit = 0; // no leadlimit for now
2186         }
2187
2188         if(g_onslaught)
2189                 timelimit = 0; // ONS has its own overtime rule
2190
2191         if(timelimit > 0)
2192         {
2193                 timelimit += game_starttime;
2194         }
2195         else if (timelimit < 0)
2196         {
2197                 // endmatch
2198                 NextLevel();
2199                 return;
2200         }
2201
2202         float wantovertime;
2203         wantovertime = 0;
2204
2205         if(checkrules_suddendeathend)
2206         {
2207                 if(!checkrules_suddendeathwarning)
2208                 {
2209                         checkrules_suddendeathwarning = TRUE;
2210                         if(g_race && !g_race_qualifying)
2211                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2212                         else
2213                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2214                 }
2215         }
2216         else
2217         {
2218                 if (timelimit && time >= timelimit)
2219                 {
2220                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2221                         {
2222                                 float totalplayers;
2223                                 float playerswithlaps;
2224                                 float readyplayers;
2225                                 entity head;
2226                                 totalplayers = playerswithlaps = readyplayers = 0;
2227                                 FOR_EACH_PLAYER(head)
2228                                 {
2229                                         ++totalplayers;
2230                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2231                                                 ++playerswithlaps;
2232                                         if(head.ready)
2233                                                 ++readyplayers;
2234                                 }
2235
2236                                 // at least 2 of the players have completed a lap: start the RACE
2237                                 // otherwise, the players should end the qualifying on their own
2238                                 if(readyplayers || playerswithlaps >= 2)
2239                                 {
2240                                         checkrules_suddendeathend = 0;
2241                                         ReadyRestart(); // go to race
2242                                         return;
2243                                 }
2244                                 else
2245                                         wantovertime |= InitiateSuddenDeath();
2246                         }
2247                         else
2248                                 wantovertime |= InitiateSuddenDeath();
2249                 }
2250         }
2251
2252         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2253         {
2254                 NextLevel();
2255                 return;
2256         }
2257
2258         float checkrules_status;
2259         checkrules_status = WinningCondition_RanOutOfSpawns();
2260         if(checkrules_status == WINNING_YES)
2261         {
2262                 bprint("Hey! Someone ran out of spawns!\n");
2263         }
2264         else if(g_race && !g_race_qualifying && timelimit >= 0)
2265         {
2266                 checkrules_status = WinningCondition_Race(fraglimit);
2267                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2268         }
2269         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2270         {
2271                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2272                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2273         }
2274         else if(g_assault)
2275         {
2276                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2277         }
2278         else if(g_lms)
2279         {
2280                 checkrules_status = WinningCondition_LMS();
2281         }
2282         else if (g_onslaught)
2283         {
2284                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2285         }
2286         else
2287         {
2288                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2289                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2290         }
2291
2292         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2293         {
2294                 checkrules_status = WINNING_NEVER;
2295                 checkrules_overtimesadded = -1;
2296                 wantovertime |= InitiateSuddenDeath();
2297         }
2298
2299         if(checkrules_status == WINNING_NEVER)
2300                 // equality cases! Nobody wins if the overtime ends in a draw.
2301                 ClearWinners();
2302
2303         if(wantovertime)
2304         {
2305                 if(checkrules_status == WINNING_NEVER)
2306                         InitiateOvertime();
2307                 else
2308                         checkrules_status = WINNING_YES;
2309         }
2310
2311         if(checkrules_suddendeathend)
2312                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2313                         checkrules_status = WINNING_YES;
2314
2315         if(checkrules_status == WINNING_YES)
2316         {
2317                 //print("WINNING\n");
2318                 NextLevel();
2319         }
2320 }
2321
2322 float mapvote_nextthink;
2323 float mapvote_initialized;
2324 float mapvote_keeptwotime;
2325 float mapvote_timeout;
2326 string mapvote_message;
2327 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2328 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2329 float mapvote_screenshot_dirs_count;
2330
2331 float mapvote_count;
2332 float mapvote_count_real;
2333 string mapvote_maps[MAPVOTE_COUNT];
2334 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2335 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2336 float mapvote_maps_suggested[MAPVOTE_COUNT];
2337 string mapvote_suggestions[MAPVOTE_COUNT];
2338 float mapvote_suggestion_ptr;
2339 float mapvote_voters;
2340 float mapvote_selections[MAPVOTE_COUNT];
2341 float mapvote_run;
2342 float mapvote_detail;
2343 float mapvote_abstain;
2344 .float mapvote;
2345
2346 void MapVote_ClearAllVotes()
2347 {
2348         FOR_EACH_CLIENT(other)
2349                 other.mapvote = 0;
2350 }
2351
2352 string MapVote_Suggest(string m)
2353 {
2354         float i;
2355         if(m == "")
2356                 return "That's not how to use this command.";
2357         if(!autocvar_g_maplist_votable_suggestions)
2358                 return "Suggestions are not accepted on this server.";
2359         if(mapvote_initialized)
2360                 return "Can't suggest - voting is already in progress!";
2361         m = MapInfo_FixName(m);
2362         if(!m)
2363                 return "The map you suggested is not available on this server.";
2364         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2365                 if(Map_IsRecent(m))
2366                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2367
2368         if(!MapInfo_CheckMap(m))
2369                 return "The map you suggested does not support the current game mode.";
2370         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2371                 if(mapvote_suggestions[i] == m)
2372                         return "This map was already suggested.";
2373         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2374         {
2375                 i = floor(random() * mapvote_suggestion_ptr);
2376         }
2377         else
2378         {
2379                 i = mapvote_suggestion_ptr;
2380                 mapvote_suggestion_ptr += 1;
2381         }
2382         if(mapvote_suggestions[i] != "")
2383                 strunzone(mapvote_suggestions[i]);
2384         mapvote_suggestions[i] = strzone(m);
2385         if(autocvar_sv_eventlog)
2386                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2387         return strcat("Suggestion of ", m, " accepted.");
2388 }
2389
2390 void MapVote_AddVotable(string nextMap, float isSuggestion)
2391 {
2392         float j, i, o;
2393         string pakfile, mapfile;
2394
2395         if(nextMap == "")
2396                 return;
2397         for(j = 0; j < mapvote_count; ++j)
2398                 if(mapvote_maps[j] == nextMap)
2399                         return;
2400         // suggestions might be no longer valid/allowed after gametype switch!
2401         if(isSuggestion)
2402                 if(!MapInfo_CheckMap(nextMap))
2403                         return;
2404         mapvote_maps[mapvote_count] = strzone(nextMap);
2405         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2406
2407         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2408         {
2409                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2410                 pakfile = whichpack(strcat(mapfile, ".tga"));
2411                 if(pakfile == "")
2412                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2413                 if(pakfile == "")
2414                         pakfile = whichpack(strcat(mapfile, ".png"));
2415                 if(pakfile != "")
2416                         break;
2417         }
2418         if(i >= mapvote_screenshot_dirs_count)
2419                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2420         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2421                 pakfile = substring(pakfile, o, -1);
2422
2423         mapvote_maps_screenshot_dir[mapvote_count] = i;
2424         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2425
2426         mapvote_count += 1;
2427 }
2428
2429 void MapVote_Spawn();
2430 void MapVote_Init()
2431 {
2432         float i;
2433         float nmax, smax;
2434
2435         MapVote_ClearAllVotes();
2436
2437         mapvote_count = 0;
2438         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2439         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2440
2441         if(mapvote_abstain)
2442                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2443         else
2444                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2445         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2446
2447         // we need this for AddVotable, as that cycles through the screenshot dirs
2448         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2449         if(mapvote_screenshot_dirs_count == 0)
2450                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2451         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2452         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2453                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2454
2455         if(mapvote_suggestion_ptr)
2456                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2457                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2458
2459         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2460                 MapVote_AddVotable(GetNextMap(), FALSE);
2461
2462         if(mapvote_count == 0)
2463         {
2464                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2465                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2466                 if(autocvar_g_maplist_shuffle)
2467                         ShuffleMaplist();
2468                 localcmd("\nmenu_cmd sync\n");
2469                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2470                         MapVote_AddVotable(GetNextMap(), FALSE);
2471         }
2472
2473         mapvote_count_real = mapvote_count;
2474         if(mapvote_abstain)
2475                 MapVote_AddVotable("don't care", 0);
2476
2477         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2478
2479         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2480         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2481         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2482                 mapvote_keeptwotime = 0;
2483         mapvote_message = "Choose a map and press its key!";
2484
2485         MapVote_Spawn();
2486 }
2487
2488 void MapVote_SendPicture(float id)
2489 {
2490         msg_entity = self;
2491         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2492         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2493         WriteByte(MSG_ONE, id);
2494         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2495 }
2496
2497 float MapVote_GetMapMask()
2498 {
2499         float mask, i, power;
2500         mask = 0;
2501         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2502                 if(mapvote_maps[i] != "")
2503                         mask |= power;
2504         return mask;
2505 }
2506
2507 entity mapvote_ent;
2508 float MapVote_SendEntity(entity to, float sf)
2509 {
2510         float i;
2511
2512         if(sf & 1)
2513                 sf &~= 2; // if we send 1, we don't need to also send 2
2514
2515         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2516         WriteByte(MSG_ENTITY, sf);
2517
2518         if(sf & 1)
2519         {
2520                 // flag 1 == initialization
2521                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2522                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2523                 WriteString(MSG_ENTITY, "");
2524                 WriteByte(MSG_ENTITY, mapvote_count);
2525                 WriteByte(MSG_ENTITY, mapvote_abstain);
2526                 WriteByte(MSG_ENTITY, mapvote_detail);
2527                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2528                 if(mapvote_count <= 8)
2529                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2530                 else
2531                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2532                 for(i = 0; i < mapvote_count; ++i)
2533                         if(mapvote_maps[i] != "")
2534                         {
2535                                 if(mapvote_abstain && i == mapvote_count - 1)
2536                                 {
2537                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2538                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2539                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2540                                 }
2541                                 else
2542                                 {
2543                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2544                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2545                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2546                                 }
2547                         }
2548         }
2549
2550         if(sf & 2)
2551         {
2552                 // flag 2 == update of mask
2553                 if(mapvote_count <= 8)
2554                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2555                 else
2556                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2557         }
2558
2559         if(sf & 4)
2560         {
2561                 if(mapvote_detail)
2562                         for(i = 0; i < mapvote_count; ++i)
2563                                 if(mapvote_maps[i] != "")
2564                                         WriteByte(MSG_ENTITY, mapvote_selections[i]);
2565
2566                 WriteByte(MSG_ENTITY, to.mapvote);
2567         }
2568
2569         return TRUE;
2570 }
2571
2572 void MapVote_Spawn()
2573 {
2574         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2575 }
2576
2577 void MapVote_TouchMask()
2578 {
2579         mapvote_ent.SendFlags |= 2;
2580 }
2581
2582 void MapVote_TouchVotes(entity voter)
2583 {
2584         mapvote_ent.SendFlags |= 4;
2585 }
2586
2587 float MapVote_Finished(float mappos)
2588 {
2589         string result;
2590         float i;
2591         float didntvote;
2592
2593         if(autocvar_sv_eventlog)
2594         {
2595                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2596                 result = strcat(result, ":", ftos(mapvote_selections[mappos]), "::");
2597                 didntvote = mapvote_voters;
2598                 for(i = 0; i < mapvote_count; ++i)
2599                         if(mapvote_maps[i] != "")
2600                         {
2601                                 didntvote -= mapvote_selections[i];
2602                                 if(i != mappos)
2603                                 {
2604                                         result = strcat(result, ":", mapvote_maps[i]);
2605                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2606                                 }
2607                         }
2608                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2609
2610                 GameLogEcho(result);
2611                 if(mapvote_maps_suggested[mappos])
2612                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2613         }
2614
2615         FOR_EACH_REALCLIENT(other)
2616                 FixClientCvars(other);
2617
2618         Map_Goto_SetStr(mapvote_maps[mappos]);
2619         Map_Goto(0);
2620         alreadychangedlevel = TRUE;
2621         return TRUE;
2622 }
2623 void MapVote_CheckRules_1()
2624 {
2625         float i;
2626
2627         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2628         {
2629                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2630                 mapvote_selections[i] = 0;
2631         }
2632
2633         mapvote_voters = 0;
2634         FOR_EACH_REALCLIENT(other)
2635         {
2636                 ++mapvote_voters;
2637                 if(other.mapvote)
2638                 {
2639                         i = other.mapvote - 1;
2640                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2641                         mapvote_selections[i] = mapvote_selections[i] + 1;
2642                 }
2643         }
2644 }
2645
2646 float MapVote_CheckRules_2()
2647 {
2648         float i;
2649         float firstPlace, secondPlace;
2650         float firstPlaceVotes, secondPlaceVotes;
2651         float mapvote_voters_real;
2652         string result;
2653
2654         if(mapvote_count_real == 1)
2655                 return MapVote_Finished(0);
2656
2657         mapvote_voters_real = mapvote_voters;
2658         if(mapvote_abstain)
2659                 mapvote_voters_real -= mapvote_selections[mapvote_count - 1];
2660
2661         RandomSelection_Init();
2662         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2663                 RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2664         firstPlace = RandomSelection_chosen_float;
2665         firstPlaceVotes = RandomSelection_best_priority;
2666         //dprint("First place: ", ftos(firstPlace), "\n");
2667         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2668
2669         RandomSelection_Init();
2670         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2671                 if(i != firstPlace)
2672                         RandomSelection_Add(world, i, string_null, 1, mapvote_selections[i]);
2673         secondPlace = RandomSelection_chosen_float;
2674         secondPlaceVotes = RandomSelection_best_priority;
2675         //dprint("Second place: ", ftos(secondPlace), "\n");
2676         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2677
2678         if(firstPlace == -1)
2679                 error("No first place in map vote... WTF?");
2680
2681         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2682                 return MapVote_Finished(firstPlace);
2683
2684         if(mapvote_keeptwotime)
2685                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2686                 {
2687                         float didntvote;
2688                         MapVote_TouchMask();
2689                         mapvote_message = "Now decide between the TOP TWO!";
2690                         mapvote_keeptwotime = 0;
2691                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2692                         result = strcat(result, ":", ftos(firstPlaceVotes));
2693                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2694                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2695                         didntvote = mapvote_voters;
2696                         for(i = 0; i < mapvote_count; ++i)
2697                                 if(mapvote_maps[i] != "")
2698                                 {
2699                                         didntvote -= mapvote_selections[i];
2700                                         if(i != firstPlace)
2701                                                 if(i != secondPlace)
2702                                                 {
2703                                                         result = strcat(result, ":", mapvote_maps[i]);
2704                                                         result = strcat(result, ":", ftos(mapvote_selections[i]));
2705                                                         if(i < mapvote_count_real)
2706                                                         {
2707                                                                 strunzone(mapvote_maps[i]);
2708                                                                 mapvote_maps[i] = "";
2709                                                                 strunzone(mapvote_maps_pakfile[i]);
2710                                                                 mapvote_maps_pakfile[i] = "";
2711                                                         }
2712                                                 }
2713                                 }
2714                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2715                         if(autocvar_sv_eventlog)
2716                                 GameLogEcho(result);
2717                 }
2718
2719         return FALSE;
2720 }
2721 void MapVote_Tick()
2722 {
2723         float keeptwo;
2724         float totalvotes;
2725
2726         keeptwo = mapvote_keeptwotime;
2727         MapVote_CheckRules_1(); // count
2728         if(MapVote_CheckRules_2()) // decide
2729                 return;
2730
2731         totalvotes = 0;
2732         FOR_EACH_REALCLIENT(other)
2733         {
2734                 // hide scoreboard again
2735                 if(other.health != 2342)
2736                 {
2737                         other.health = 2342;
2738                         other.impulse = 0;
2739                         if(clienttype(other) == CLIENTTYPE_REAL)
2740                         {
2741                                 msg_entity = other;
2742                                 WriteByte(MSG_ONE, SVC_FINALE);
2743                                 WriteString(MSG_ONE, "");
2744                         }
2745                 }
2746
2747                 // clear possibly invalid votes
2748                 if(mapvote_maps[other.mapvote - 1] == "")
2749                         other.mapvote = 0;
2750                 // use impulses as new vote
2751                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2752                         if(mapvote_maps[other.impulse - 1] != "")
2753                         {
2754                                 other.mapvote = other.impulse;
2755                                 MapVote_TouchVotes(other);
2756                         }
2757                 other.impulse = 0;
2758
2759                 if(other.mapvote)
2760                         ++totalvotes;
2761         }
2762
2763         MapVote_CheckRules_1(); // just count
2764 }
2765 void MapVote_Start()
2766 {
2767         if(mapvote_run)
2768                 return;
2769
2770         // wait for stats to be sent first
2771         if(!playerstats_waitforme)
2772                 return;
2773
2774         MapInfo_Enumerate();
2775         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2776                 mapvote_run = TRUE;
2777 }
2778 void MapVote_Think()
2779 {
2780         if(!mapvote_run)
2781                 return;
2782
2783         if(alreadychangedlevel)
2784                 return;
2785
2786         if(time < mapvote_nextthink)
2787                 return;
2788         //dprint("tick\n");
2789
2790         mapvote_nextthink = time + 0.5;
2791
2792         if(!mapvote_initialized)
2793         {
2794                 if(autocvar_rescan_pending == 1)
2795                 {
2796                         cvar_set("rescan_pending", "2");
2797                         localcmd("fs_rescan\nrescan_pending 3\n");
2798                         return;
2799                 }
2800                 else if(autocvar_rescan_pending == 2)
2801                 {
2802                         return;
2803                 }
2804                 else if(autocvar_rescan_pending == 3)
2805                 {
2806                         // now build missing mapinfo files
2807                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2808                                 return;
2809
2810                         // we're done, start the timer
2811                         cvar_set("rescan_pending", "0");
2812                 }
2813
2814                 mapvote_initialized = TRUE;
2815                 if(DoNextMapOverride(0))
2816                         return;
2817                 if(!autocvar_g_maplist_votable || player_count <= 0)
2818                 {
2819                         GotoNextMap(0);
2820                         return;
2821                 }
2822                 MapVote_Init();
2823         }
2824
2825         MapVote_Tick();
2826 }
2827
2828 string GotoMap(string m)
2829 {
2830         if(!MapInfo_CheckMap(m))
2831                 return "The map you chose is not available on this server.";
2832         cvar_set("nextmap", m);
2833         cvar_set("timelimit", "-1");
2834         if(mapvote_initialized || alreadychangedlevel)
2835         {
2836                 if(DoNextMapOverride(0))
2837                         return "Map switch initiated.";
2838                 else
2839                         return "Hm... no. For some reason I like THIS map more.";
2840         }
2841         else
2842                 return "Map switch will happen after scoreboard.";
2843 }
2844
2845
2846 void EndFrame()
2847 {
2848         float altime;
2849         FOR_EACH_REALCLIENT(self)
2850         {
2851                 if(self.classname == "spectator")
2852                 {
2853                         if(self.enemy.typehitsound)
2854                                 self.typehit_time = time;
2855                         else if(self.enemy.hitsound)
2856                                 self.hit_time = time;
2857                 }
2858                 else
2859                 {
2860                         if(self.typehitsound)
2861                                 self.typehit_time = time;
2862                         else if(self.hitsound)
2863                                 self.hit_time = time;
2864                 }
2865         }
2866         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2867         // add 1 frametime because after this, engine SV_Physics
2868         // increases time by a frametime and then networks the frame
2869         // add another frametime because client shows everything with
2870         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2871         // needed!
2872         FOR_EACH_CLIENT(self)
2873         {
2874                 self.hitsound = FALSE;
2875                 self.typehitsound = FALSE;
2876                 antilag_record(self, altime);
2877         }
2878 }
2879
2880
2881 /*
2882  * RedirectionThink:
2883  * returns TRUE if redirecting
2884  */
2885 float redirection_timeout;
2886 float redirection_nextthink;
2887 float RedirectionThink()
2888 {
2889         float clients_found;
2890
2891         if(redirection_target == "")
2892                 return FALSE;
2893
2894         if(!redirection_timeout)
2895         {
2896                 cvar_set("sv_public", "-2");
2897                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2898                 if(redirection_target == "self")
2899                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2900                 else
2901                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2902         }
2903
2904         if(time < redirection_nextthink)
2905                 return TRUE;
2906
2907         redirection_nextthink = time + 1;
2908
2909         clients_found = 0;
2910         FOR_EACH_REALCLIENT(self)
2911         {
2912                 print("Redirecting: sending connect command to ", self.netname, "\n");
2913                 if(redirection_target == "self")
2914                         stuffcmd(self, "\ndisconnect; reconnect\n");
2915                 else
2916                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2917                 ++clients_found;
2918         }
2919
2920         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2921
2922         if(time > redirection_timeout || clients_found == 0)
2923                 localcmd("\nwait; wait; wait; quit\n");
2924
2925         return TRUE;
2926 }
2927
2928 void TargetMusic_RestoreGame();
2929 void RestoreGame()
2930 {
2931         // Loaded from a save game
2932         // some things then break, so let's work around them...
2933
2934         // Progs DB (capture records)
2935         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2936
2937         // Mapinfo
2938         MapInfo_Shutdown();
2939         MapInfo_Enumerate();
2940         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2941         WeaponStats_Init();
2942
2943         TargetMusic_RestoreGame();
2944 }
2945
2946 void SV_Shutdown()
2947 {
2948         entity e;
2949
2950         if(gameover > 1) // shutting down already?
2951                 return;
2952
2953         gameover = 2; // 2 = server shutting down
2954
2955         if(world_initialized > 0)
2956         {
2957                 world_initialized = 0;
2958                 print("Saving persistent data...\n");
2959                 Ban_SaveBans();
2960
2961                 PlayerStats_EndMatch(0);
2962                 FOR_EACH_CLIENT(e)
2963                         PlayerStats_AddGlobalInfo(e);
2964                 PlayerStats_Shutdown();
2965
2966                 if(!cheatcount_total)
2967                 {
2968                         if(autocvar_sv_db_saveasdump)
2969                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2970                         else
2971                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2972                 }
2973                 if(autocvar_developer)
2974                 {
2975                         if(autocvar_sv_db_saveasdump)
2976                                 db_dump(TemporaryDB, "server-temp.db");
2977                         else
2978                                 db_save(TemporaryDB, "server-temp.db");
2979                 }
2980                 CheatShutdown(); // must be after cheatcount check
2981                 db_close(ServerProgsDB);
2982                 db_close(TemporaryDB);
2983                 print("done!\n");
2984                 // tell the bot system the game is ending now
2985                 bot_endgame();
2986
2987                 WeaponStats_Shutdown();
2988                 MapInfo_Shutdown();
2989         }
2990         else if(world_initialized == 0)
2991         {
2992                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2993         }
2994 }