qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap(float reinit);
  48 void ShuffleMaplist()
  49 float(float reinit) DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride(1))
 193                         GotoNextMap(1);
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_ghost_items");
 301                 BADPREFIX("g_playerstats_");
 302                 BADPREFIX("g_respawn_ghosts");
 303                 BADPREFIX("g_voice_flood_");
 304                 BADPREFIX("rcon_");
 305                 BADPREFIX("sv_allowdownloads");
 306                 BADPREFIX("sv_autodemo");
 307                 BADPREFIX("sv_curl_");
 308                 BADPREFIX("sv_eventlog");
 309                 BADPREFIX("sv_logscores_");
 310                 BADPREFIX("sv_master");
 311                 BADPREFIX("sv_weaponstats_");
 312                 BADPREFIX("sv_waypointsprite_");
 313                 BADCVAR("rescan_pending");
 314
 315                 // these can contain player IDs, so better hide
 316                 BADPREFIX("g_forced_team_");
 317
 318                 // mapinfo
 319                 BADCVAR("fraglimit");
 320                 BADCVAR("g_arena");
 321                 BADCVAR("g_assault");
 322                 BADCVAR("g_ca");
 323                 BADCVAR("g_ctf");
 324                 BADCVAR("g_cts");
 325                 BADCVAR("g_dm");
 326                 BADCVAR("g_domination");
 327                 BADCVAR("g_domination_default_teams");
 328                 BADCVAR("g_freezetag");
 329                 BADCVAR("g_keepaway");
 330                 BADCVAR("g_keyhunt");
 331                 BADCVAR("g_keyhunt_teams");
 332                 BADCVAR("g_keyhunt_teams");
 333                 BADCVAR("g_lms");
 334                 BADCVAR("g_nexball");
 335                 BADCVAR("g_onslaught");
 336                 BADCVAR("g_race");
 337                 BADCVAR("g_race_qualifying_timelimit");
 338                 BADCVAR("g_runematch");
 339                 BADCVAR("g_tdm");
 340                 BADCVAR("g_tdm_teams");
 341                 BADCVAR("leadlimit");
 342                 BADCVAR("nextmap");
 343                 BADCVAR("teamplay");
 344                 BADCVAR("timelimit");
 345
 346                 // long
 347                 BADCVAR("hostname");
 348                 BADCVAR("g_maplist");
 349                 BADCVAR("g_maplist_mostrecent");
 350                 BADCVAR("sv_motd");
 351
 352                 v = cvar_string(k);
 353                 d = cvar_defstring(k);
 354                 if(v == d)
 355                         continue;
 356
 357                 if(adding)
 358                 {
 359                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 360                         if(strlen(cvar_changes) > 16384)
 361                         {
 362                                 cvar_changes = "// too many settings have been changed to show them here\n";
 363                                 adding = 0;
 364                         }
 365                 }
 366
 367                 // now check if the changes are actually gameplay relevant
 368
 369                 // does nothing visible
 370                 BADCVAR("captureleadlimit_override");
 371                 BADCVAR("g_arena_point_leadlimit");
 372                 BADCVAR("g_balance_kill_delay");
 373                 BADCVAR("g_ca_point_leadlimit");
 374                 BADCVAR("g_ctf_captimerecord_always");
 375                 BADCVAR("g_ctf_flag_capture_effects");
 376                 BADCVAR("g_ctf_flag_glowtrails");
 377                 BADCVAR("g_ctf_flag_pickup_effects");
 378                 BADCVAR("g_domination_point_leadlimit");
 379                 BADCVAR("g_forced_respawn");
 380                 BADCVAR("g_keyhunt_point_leadlimit");
 381                 BADCVAR("g_nexball_goalleadlimit");
 382                 BADCVAR("g_runematch_point_leadlimit");
 383                 BADCVAR("leadlimit_and_fraglimit");
 384                 BADCVAR("leadlimit_override");
 385                 BADCVAR("pausable");
 386                 BADCVAR("sv_allow_fullbright");
 387                 BADCVAR("sv_checkforpacketsduringsleep");
 388                 BADCVAR("sv_timeout");
 389                 BADPREFIX("sv_timeout_");
 390                 BADCVAR("welcome_message_time");
 391                 BADPREFIX("crypto_");
 392                 BADPREFIX("g_chat_");
 393                 BADPREFIX("g_ctf_captimerecord_");
 394                 BADPREFIX("g_maplist_votable_");
 395                 BADPREFIX("net_");
 396                 BADPREFIX("prvm_");
 397                 BADPREFIX("skill_");
 398                 BADPREFIX("sv_cullentities_");
 399                 BADPREFIX("sv_fraginfo_");
 400                 BADPREFIX("sv_maxidle_");
 401                 BADPREFIX("sv_vote_");
 402                 BADPREFIX("timelimit_");
 403                 BADCVAR("gameversion");
 404                 BADPREFIX("gameversion_");
 405                 BADCVAR("sv_namechangetimer");
 406 #ifndef NO_LEGACY_NETWORKING
 407                 BADCVAR("sv_use_csqc_players"); // transition
 408 #endif
 409
 410                 // allowed changes to server admins (please sync this to server.cfg)
 411                 // vi commands:
 412                 //   :/"impure"/,$d
 413                 //   :g!,^\/\/[^ /],d
 414                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 415                 //   :%!sort
 416                 // yes, this does contain some redundant stuff, don't really care
 417                 BADCVAR("bot_config_file");
 418                 BADCVAR("bot_number");
 419                 BADCVAR("bot_prefix");
 420                 BADCVAR("bot_suffix");
 421                 BADCVAR("capturelimit_override");
 422                 BADCVAR("fraglimit_override");
 423                 BADCVAR("gametype");
 424                 BADCVAR("g_antilag");
 425                 BADCVAR("g_balance_teams");
 426                 BADCVAR("g_balance_teams_force");
 427                 BADCVAR("g_ban_sync_trusted_servers");
 428                 BADCVAR("g_ban_sync_uri");
 429                 BADCVAR("g_ctf_ignore_frags");
 430                 BADCVAR("g_domination_point_limit");
 431                 BADCVAR("g_friendlyfire");
 432                 BADCVAR("g_fullbrightitems");
 433                 BADCVAR("g_fullbrightplayers");
 434                 BADCVAR("g_keyhunt_point_limit");
 435                 BADCVAR("g_keyhunt_teams_override");
 436                 BADCVAR("g_lms_lives_override");
 437                 BADCVAR("g_maplist");
 438                 BADCVAR("g_maplist_check_waypoints");
 439                 BADCVAR("g_maplist_mostrecent_count");
 440                 BADCVAR("g_maplist_shuffle");
 441                 BADCVAR("g_maplist_votable");
 442                 BADCVAR("g_maplist_votable_abstain");
 443                 BADCVAR("g_maplist_votable_nodetail");
 444                 BADCVAR("g_maplist_votable_suggestions");
 445                 BADCVAR("g_maxplayers");
 446                 BADCVAR("g_minstagib");
 447                 BADCVAR("g_mirrordamage");
 448                 BADCVAR("g_nexball_goallimit");
 449                 BADCVAR("g_powerups");
 450                 BADCVAR("g_runematch_point_limit");
 451                 BADCVAR("g_start_delay");
 452                 BADCVAR("g_warmup");
 453                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 454                 BADCVAR("hostname");
 455                 BADCVAR("log_file");
 456                 BADCVAR("maxplayers");
 457                 BADCVAR("minplayers");
 458                 BADCVAR("net_address");
 459                 BADCVAR("port");
 460                 BADCVAR("rcon_password");
 461                 BADCVAR("rcon_restricted_commands");
 462                 BADCVAR("rcon_restricted_password");
 463                 BADCVAR("skill");
 464                 BADCVAR("sv_adminnick");
 465                 BADCVAR("sv_autoscreenshot");
 466                 BADCVAR("sv_autotaunt");
 467                 BADCVAR("sv_curl_defaulturl");
 468                 BADCVAR("sv_defaultcharacter");
 469                 BADCVAR("sv_defaultplayercolors");
 470                 BADCVAR("sv_defaultplayermodel");
 471                 BADCVAR("sv_defaultplayerskin");
 472                 BADCVAR("sv_maxidle");
 473                 BADCVAR("sv_maxrate");
 474                 BADCVAR("sv_motd");
 475                 BADCVAR("sv_public");
 476                 BADCVAR("sv_ready_restart");
 477                 BADCVAR("sv_status_privacy");
 478                 BADCVAR("sv_taunt");
 479                 BADCVAR("sv_vote_call");
 480                 BADCVAR("sv_vote_commands");
 481                 BADCVAR("sv_vote_majority_factor");
 482                 BADCVAR("sv_vote_master");
 483                 BADCVAR("sv_vote_master_commands");
 484                 BADCVAR("sv_vote_master_password");
 485                 BADCVAR("sv_vote_simple_majority_factor");
 486                 BADCVAR("sys_ticrate");
 487                 BADCVAR("teamplay_mode");
 488                 BADCVAR("timelimit_override");
 489                 BADCVAR("g_spawnshieldtime");
 490                 BADPREFIX("g_warmup_");
 491                 BADPREFIX("sv_ready_restart_");
 492
 493                 if(autocvar_g_minstagib)
 494                 {
 495                         BADCVAR("g_grappling_hook");
 496                         BADCVAR("g_jetpack");
 497                 }
 498 #undef BADPREFIX
 499 #undef BADCVAR
 500
 501                 if(pureadding)
 502                 {
 503                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 504                         if(strlen(cvar_purechanges) > 16384)
 505                         {
 506                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 507                                 pureadding = 0;
 508                         }
 509                 }
 510                 ++cvar_purechanges_count;
 511                 // WARNING: this variable is used for the server list
 512                 // NEVER dare to skip this code!
 513                 // Hacks to intentionally appearing as "pure server" even though you DO have
 514                 // modified settings may be punished by removal from the server list.
 515                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 516                 // though.
 517         }
 518         buf_del(h);
 519         if(cvar_changes == "")
 520                 cvar_changes = "// this server runs at default server settings\n";
 521         else
 522                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 523         cvar_changes = strzone(cvar_changes);
 524         if(cvar_purechanges == "")
 525                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 526         else
 527                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 528         cvar_purechanges = strzone(cvar_purechanges);
 529 }
 530
 531 void detect_maptype()
 532 {
 533 #if 0
 534         vector o, v;
 535         float i;
 536
 537         for(;;)
 538         {
 539                 o = world.mins;
 540                 o_x += random() * (world.maxs_x - world.mins_x);
 541                 o_y += random() * (world.maxs_y - world.mins_y);
 542                 o_z += random() * (world.maxs_z - world.mins_z);
 543
 544                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 545                 if(trace_fraction == 1)
 546                         continue;
 547
 548                 v = trace_endpos;
 549
 550                 for(i = 0; i < 64; i += 4)
 551                 {
 552                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 553         if(trace_fraction == 1)
 554                 continue;
 555                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 556                 }
 557
 558                 break;
 559         }
 560 #endif
 561 }
 562
 563 entity randomseed;
 564 float RandomSeed_Send(entity to, float sf)
 565 {
 566         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 567         WriteShort(MSG_ENTITY, self.cnt);
 568         return TRUE;
 569 }
 570 void RandomSeed_Think()
 571 {
 572         self.cnt = bound(0, floor(random() * 65536), 65535);
 573         self.nextthink = time + 5;
 574
 575         self.SendFlags |= 1;
 576 }
 577 void RandomSeed_Spawn()
 578 {
 579         randomseed = spawn();
 580         randomseed.think = RandomSeed_Think;
 581         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 582
 583         entity oldself;
 584         oldself = self;
 585         self = randomseed;
 586         self.think(); // sets random seed and nextthink
 587         self = oldself;
 588 }
 589
 590 void spawnfunc___init_dedicated_server(void)
 591 {
 592         // handler for _init/_init map (only for dedicated server initialization)
 593
 594         world_initialized = -1; // don't complain
 595         cvar = cvar_normal;
 596         cvar_string = cvar_string_normal;
 597         cvar_set = cvar_set_normal;
 598
 599         remove = remove_unsafely;
 600
 601         entity e;
 602         e = spawn();
 603         e.think = GotoFirstMap;
 604         e.nextthink = time; // this is usually 1 at this point
 605
 606         e = spawn();
 607         e.classname = "info_player_deathmatch"; // safeguard against player joining
 608
 609         self.classname = "worldspawn"; // safeguard against various stuff ;)
 610
 611         // needs to be done so early because of the constants they create
 612         RegisterWeapons();
 613         RegisterGametypes();
 614
 615         MapInfo_Enumerate();
 616         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 617 }
 618
 619 void Map_MarkAsRecent(string m);
 620 float world_already_spawned;
 621 void RegisterWeapons();
 622 void Nagger_Init();
 623 void Item_ItemsTime_Init();
 624 void ClientInit_Spawn();
 625 void WeaponStats_Init();
 626 void WeaponStats_Shutdown();
 627 void spawnfunc_worldspawn (void)
 628 {
 629         float fd, l, i, j, n;
 630         string s, col;
 631
 632         cvar = cvar_normal;
 633         cvar_string = cvar_string_normal;
 634         cvar_set = cvar_set_normal;
 635
 636         if(world_already_spawned)
 637                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 638         world_already_spawned = TRUE;
 639
 640         remove = remove_safely; // during spawning, watch what you remove!
 641
 642         check_unacceptable_compiler_bugs();
 643
 644         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 645
 646         compressShortVector_init();
 647
 648         allowed_to_spawn = TRUE;
 649
 650         entity head;
 651         head = nextent(world);
 652         maxclients = 0;
 653         while(head)
 654         {
 655                 ++maxclients;
 656                 head = nextent(head);
 657         }
 658
 659         // needs to be done so early because of the constants they create
 660         RegisterWeapons();
 661         RegisterGametypes();
 662
 663         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 664
 665         TemporaryDB = db_create();
 666
 667         // 0 normal
 668         lightstyle(0, "m");
 669
 670         // 1 FLICKER (first variety)
 671         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 672
 673         // 2 SLOW STRONG PULSE
 674         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 675
 676         // 3 CANDLE (first variety)
 677         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 678
 679         // 4 FAST STROBE
 680         lightstyle(4, "mamamamamama");
 681
 682         // 5 GENTLE PULSE 1
 683         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 684
 685         // 6 FLICKER (second variety)
 686         lightstyle(6, "nmonqnmomnmomomno");
 687
 688         // 7 CANDLE (second variety)
 689         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 690
 691         // 8 CANDLE (third variety)
 692         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 693
 694         // 9 SLOW STROBE (fourth variety)
 695         lightstyle(9, "aaaaaaaazzzzzzzz");
 696
 697         // 10 FLUORESCENT FLICKER
 698         lightstyle(10, "mmamammmmammamamaaamammma");
 699
 700         // 11 SLOW PULSE NOT FADE TO BLACK
 701         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 702
 703         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 704
 705         // 63 testing
 706         lightstyle(63, "a");
 707
 708         if(autocvar_g_campaign)
 709                 CampaignPreInit();
 710
 711         Map_MarkAsRecent(mapname);
 712
 713         precache_model ("null"); // we need this one before InitGameplayMode
 714         InitGameplayMode();
 715         readlevelcvars();
 716         GrappleHookInit();
 717         ElectroInit();
 718         LaserInit();
 719
 720         player_count = 0;
 721         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 722         if(bot_waypoints_for_items == 1)
 723                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 724                         bot_waypoints_for_items = 0;
 725
 726         precache();
 727
 728         WaypointSprite_Init();
 729
 730         //if (g_domination)
 731         //      dom_init();
 732
 733         GameLogInit(); // prepare everything
 734         // NOTE for matchid:
 735         // changing the logic generating it is okay. But:
 736         // it HAS to stay <= 64 chars
 737         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 738         if(autocvar_sv_eventlog)
 739         {
 740                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 741                 matchid = strzone(s);
 742
 743                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 744                 s = ":gameinfo:mutators:LIST";
 745
 746                 ret_string = s;
 747                 MUTATOR_CALLHOOK(BuildMutatorsString);
 748                 s = ret_string;
 749
 750                 // simple, probably not good in the mutator system
 751                 if(autocvar_g_grappling_hook)
 752                         s = strcat(s, ":grappling_hook");
 753
 754                 // initialiation stuff, not good in the mutator system
 755                 if(!autocvar_g_use_ammunition)
 756                         s = strcat(s, ":no_use_ammunition");
 757
 758                 // initialiation stuff, not good in the mutator system
 759                 if(autocvar_g_pickup_items == 0)
 760                         s = strcat(s, ":no_pickup_items");
 761                 if(autocvar_g_pickup_items > 0)
 762                         s = strcat(s, ":pickup_items");
 763
 764                 // initialiation stuff, not good in the mutator system
 765                 if(autocvar_g_weaponarena != "0")
 766                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 767
 768                 // TODO to mutator system
 769                 if(autocvar_g_norecoil)
 770                         s = strcat(s, ":norecoil");
 771
 772                 // TODO to mutator system
 773                 if(autocvar_g_midair)
 774                         s = strcat(s, ":midair");
 775
 776                 // TODO to mutator system
 777                 if(autocvar_g_minstagib)
 778                         s = strcat(s, ":minstagib");
 779
 780                 // TODO to mutator system
 781                 if(autocvar_g_powerups == 0)
 782                         s = strcat(s, ":no_powerups");
 783                 if(autocvar_g_powerups > 0)
 784                         s = strcat(s, ":powerups");
 785
 786                 GameLogEcho(s);
 787                 GameLogEcho(":gameinfo:end");
 788         }
 789         else
 790                 matchid = strzone(ftos(random()));
 791
 792         cvar_set("nextmap", "");
 793
 794         SetDefaultAlpha();
 795
 796         if(autocvar_g_campaign)
 797                 CampaignPostInit();
 798
 799         fteqcc_testbugs();
 800
 801         Ban_LoadBans();
 802
 803         MapInfo_Enumerate();
 804         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 805
 806         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 807         {
 808                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 809                 if(fd != -1)
 810                 {
 811                         while((s = fgets(fd)))
 812                         {
 813                                 l = tokenize_console(s);
 814                                 if(l < 2)
 815                                         continue;
 816                                 if(argv(0) == "cd")
 817                                 {
 818                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 819                                         print("  cdtrack ", argv(2), "\n");
 820                                 }
 821                                 else if(argv(0) == "fog")
 822                                 {
 823                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 824                                         print("  \"fog\" \"", s, "\"\n");
 825                                 }
 826                                 else if(argv(0) == "set")
 827                                 {
 828                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 829                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 830                                 }
 831                                 else if(argv(0) != "//")
 832                                 {
 833                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 834                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 835                                 }
 836                         }
 837                         fclose(fd);
 838                 }
 839         }
 840
 841         WeaponStats_Init();
 842
 843         addstat(STAT_WEAPONS, AS_INT, weapons);
 844         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 845         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 846         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 847         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 848         Nagger_Init();
 849
 850         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 851         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 852         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 853         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 854         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 855         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 856         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 857         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 858         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 859         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 860         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 861         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 862
 863         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 864         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 865
 866         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 867
 868         addstat(STAT_ARMOR_LARGE_TIME, AS_FLOAT, item_armor_large_time);
 869         addstat(STAT_HEALTH_MEGA_TIME, AS_FLOAT, item_health_mega_time);
 870         addstat(STAT_INVISIBLE_TIME, AS_FLOAT, item_invisible_time);
 871         addstat(STAT_SPEED_TIME, AS_FLOAT, item_speed_time);
 872         addstat(STAT_EXTRALIFE_TIME, AS_FLOAT, item_extralife_time);
 873         addstat(STAT_STRENGTH_TIME, AS_FLOAT, item_strength_time);
 874         addstat(STAT_SHIELD_TIME, AS_FLOAT, item_shield_time);
 875         addstat(STAT_FUELREGEN_TIME, AS_FLOAT, item_fuelregen_time);
 876         addstat(STAT_JETPACK_TIME, AS_FLOAT, item_jetpack_time);
 877         Item_ItemsTime_Init();
 878
 879         if(g_ca || g_freezetag)
 880         {
 881                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 882                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 883                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 884                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 885         }
 886         if(g_freezetag)
 887         {
 888                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 889                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 890         }
 891
 892         // g_movementspeed hack
 893         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 894         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 895         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 896         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 897
 898         // secrets
 899         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 900         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 901
 902         next_pingtime = time + 5;
 903
 904         detect_maptype();
 905
 906         lsmaps_reply = "^7Maps available: ";
 907         lsnewmaps_reply = "^7Maps without a record set: ";
 908         for(i = 0, j = 0; i < MapInfo_count; ++i)
 909         {
 910                 if(MapInfo_Get_ByID(i))
 911                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 912                         {
 913                                 if(mod(i, 2))
 914                                         col = "^2";
 915                                 else
 916                                         col = "^3";
 917                                 ++j;
 918                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 919                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 920                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 921                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 922                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 923                         }
 924         }
 925         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 926         if (!g_race && !g_cts)
 927                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 928         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 929
 930         maplist_reply = "^7Maps in list: ";
 931         n = tokenize_console(autocvar_g_maplist);
 932         for(i = 0, j = 0; i < n; ++i)
 933         {
 934                 if(MapInfo_CheckMap(argv(i)))
 935                 {
 936                         if(mod(j, 2))
 937                                 col = "^2";
 938                         else
 939                                 col = "^3";
 940                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 941                         ++j;
 942                 }
 943         }
 944         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 945         MapInfo_ClearTemps();
 946
 947         for(i = 0; i < 10; ++i)
 948         {
 949                 records_reply[i] = strzone(getrecords(i));
 950         }
 951         if(g_cts)
 952                 ladder_reply = strzone(getladder());
 953
 954         rankings_reply = strzone(getrankings());
 955
 956         ClientInit_Spawn();
 957         RandomSeed_Spawn();
 958         PingPLReport_Spawn();
 959
 960         CheatInit();
 961
 962         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 963
 964         // fill sv_curl_serverpackages from .serverpackage files
 965         if(autocvar_sv_curl_serverpackages_auto)
 966         {
 967                 s = "";
 968                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 969                 for(i = 0; i < n; ++i)
 970                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 971                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 972                                 s = strcat(s, " ", argv(i));
 973                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 974                 if(fd >= 0)
 975                 {
 976                         j = search_getsize(fd);
 977                         for(i = 0; i < j; ++i)
 978                                 s = strcat(s, " ", search_getfilename(fd, i));
 979                         search_end(fd);
 980                 }
 981                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 982                 if(fd >= 0)
 983                 {
 984                         j = search_getsize(fd);
 985                         for(i = 0; i < j; ++i)
 986                                 s = strcat(s, " ", search_getfilename(fd, i));
 987                         search_end(fd);
 988                 }
 989                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 990         }
 991
 992         PlayerStats_Init();
 993
 994         world_initialized = 1;
 995 }
 996
 997 void spawnfunc_light (void)
 998 {
 999         //makestatic (self); // Who the f___ did that?
1000         remove(self);
1001 }
1002
1003 string GetGametype()
1004 {
1005         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
1006 }
1007
1008 string getmapname_stored;
1009 string GetMapname()
1010 {
1011         return mapname;
1012 }
1013
1014 float Map_Count, Map_Current;
1015 string Map_Current_Name;
1016
1017 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1018 float GetMaplistPosition()
1019 {
1020         float pos, idx;
1021         string map;
1022
1023         map = GetMapname();
1024         idx = autocvar_g_maplist_index;
1025
1026         if(idx >= 0)
1027                 if(idx < Map_Count)
1028                         if(map == argv(idx))
1029                                 return idx;
1030
1031         for(pos = 0; pos < Map_Count; ++pos)
1032                 if(map == argv(pos))
1033                         return pos;
1034
1035         // resume normal maplist rotation if current map is not in g_maplist
1036         return idx;
1037 }
1038
1039 float MapHasRightSize(string map)
1040 {
1041         float fh;
1042         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1043         if(autocvar_g_maplist_check_waypoints)
1044         {
1045                 dprint("checkwp "); dprint(map);
1046                 if(!fexists(strcat("maps/", map, ".waypoints")))
1047                 {
1048                         dprint(": no waypoints\n");
1049                         return FALSE;
1050                 }
1051                 dprint(": has waypoints\n");
1052         }
1053
1054         // open map size restriction file
1055         dprint("opensize "); dprint(map);
1056         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1057         if(fh >= 0)
1058         {
1059                 float mapmin, mapmax;
1060                 dprint(": ok, ");
1061                 mapmin = stof(fgets(fh));
1062                 mapmax = stof(fgets(fh));
1063                 fclose(fh);
1064                 if(player_count < mapmin)
1065                 {
1066                         dprint("not enough\n");
1067                         return FALSE;
1068                 }
1069                 if(player_count > mapmax)
1070                 {
1071                         dprint("too many\n");
1072                         return FALSE;
1073                 }
1074                 dprint("right size\n");
1075                 return TRUE;
1076         }
1077         dprint(": not found\n");
1078         return TRUE;
1079 }
1080
1081 string Map_Filename(float position)
1082 {
1083         return strcat("maps/", argv(position), ".bsp");
1084 }
1085
1086 string strwords(string s, float w)
1087 {
1088         float endpos;
1089         for(endpos = 0; w && endpos >= 0; --w)
1090                 endpos = strstrofs(s, " ", endpos + 1);
1091         if(endpos < 0)
1092                 return s;
1093         else
1094                 return substring(s, 0, endpos);
1095 }
1096
1097 float strhasword(string s, string w)
1098 {
1099         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1100 }
1101
1102 void Map_MarkAsRecent(string m)
1103 {
1104         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1105 }
1106
1107 float Map_IsRecent(string m)
1108 {
1109         return strhasword(autocvar_g_maplist_mostrecent, m);
1110 }
1111
1112 float Map_Check(float position, float pass)
1113 {
1114         string filename;
1115         string map_next;
1116         map_next = argv(position);
1117         if(pass <= 1)
1118         {
1119                 if(Map_IsRecent(map_next))
1120                         return 0;
1121         }
1122         filename = Map_Filename(position);
1123         if(MapInfo_CheckMap(map_next))
1124         {
1125                 if(pass == 2)
1126                         return 1;
1127                 if(MapHasRightSize(map_next))
1128                         return 1;
1129                 return 0;
1130         }
1131         else
1132                 dprint( "Couldn't select '", filename, "'..\n" );
1133
1134         return 0;
1135 }
1136
1137 void Map_Goto_SetStr(string nextmapname)
1138 {
1139         if(getmapname_stored != "")
1140                 strunzone(getmapname_stored);
1141         if(nextmapname == "")
1142                 getmapname_stored = "";
1143         else
1144                 getmapname_stored = strzone(nextmapname);
1145 }
1146
1147 void Map_Goto_SetFloat(float position)
1148 {
1149         cvar_set("g_maplist_index", ftos(position));
1150         Map_Goto_SetStr(argv(position));
1151 }
1152
1153 void Map_Goto(float reinit)
1154 {
1155         MapInfo_LoadMap(getmapname_stored, reinit);
1156 }
1157
1158 // return codes of map selectors:
1159 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1160 //   -2 = permanent failure
1161 float() MaplistMethod_Iterate = // usual method
1162 {
1163         float pass, i;
1164
1165         for(pass = 1; pass <= 2; ++pass)
1166         {
1167                 for(i = 1; i < Map_Count; ++i)
1168                 {
1169                         float mapindex;
1170                         mapindex = mod(i + Map_Current, Map_Count);
1171                         if(Map_Check(mapindex, pass))
1172                                 return mapindex;
1173                 }
1174         }
1175         return -1;
1176 }
1177
1178 float() MaplistMethod_Repeat = // fallback method
1179 {
1180         if(Map_Check(Map_Current, 2))
1181                 return Map_Current;
1182         return -2;
1183 }
1184
1185 float() MaplistMethod_Random = // random map selection
1186 {
1187         float i, imax;
1188
1189         imax = 42;
1190
1191         for(i = 0; i <= imax; ++i)
1192         {
1193                 float mapindex;
1194                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1195                 if(Map_Check(mapindex, 1))
1196                         return mapindex;
1197         }
1198         return -1;
1199 }
1200
1201 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1202 // the exponent sets a bias on the map selection:
1203 // the higher the exponent, the less likely "shortly repeated" same maps are
1204 {
1205         float i, j, imax, insertpos;
1206
1207         imax = 42;
1208
1209         for(i = 0; i <= imax; ++i)
1210         {
1211                 string newlist;
1212
1213                 // now reinsert this at another position
1214                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1215                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1216                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1217                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1218
1219                 // insert the current map there
1220                 newlist = "";
1221                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1222                         newlist = strcat(newlist, " ", argv(j));
1223                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1224                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1225                         newlist = strcat(newlist, " ", argv(j));
1226                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1227                 cvar_set("g_maplist", newlist);
1228                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1229
1230                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1231                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1232                 if(Map_Check(Map_Current, 1))
1233                         return Map_Current;
1234         }
1235         return -1;
1236 }
1237
1238 void Maplist_Init()
1239 {
1240         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1241         if(Map_Count == 0)
1242         {
1243                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1244                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1245                 if(autocvar_g_maplist_shuffle)
1246                         ShuffleMaplist();
1247                 localcmd("\nmenu_cmd sync\n");
1248                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1249         }
1250         if(Map_Count == 0)
1251                 error("empty maplist, cannot select a new map");
1252         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1253
1254         if(Map_Current_Name)
1255                 strunzone(Map_Current_Name);
1256         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1257         // this may or may not be correct, but who cares, in the worst case a map
1258         // isn't chosen in the first pass that should have been
1259 }
1260
1261 string GetNextMap()
1262 {
1263         float nextMap;
1264
1265         Maplist_Init();
1266         nextMap = -1;
1267
1268         if(nextMap == -1)
1269                 if(autocvar_g_maplist_shuffle > 0)
1270                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1271
1272         if(nextMap == -1)
1273                 if(autocvar_g_maplist_selectrandom)
1274                         nextMap = MaplistMethod_Random();
1275
1276         if(nextMap == -1)
1277                 nextMap = MaplistMethod_Iterate();
1278
1279         if(nextMap == -1)
1280                 nextMap = MaplistMethod_Repeat();
1281
1282         if(nextMap >= 0)
1283         {
1284                 Map_Goto_SetFloat(nextMap);
1285                 return getmapname_stored;
1286         }
1287
1288         return "";
1289 }
1290
1291 float DoNextMapOverride(float reinit)
1292 {
1293         if(autocvar_g_campaign)
1294         {
1295                 CampaignPostIntermission();
1296                 alreadychangedlevel = TRUE;
1297                 return TRUE;
1298         }
1299         if(autocvar_quit_when_empty)
1300         {
1301                 if(player_count <= currentbots)
1302                 {
1303                         localcmd("quit\n");
1304                         alreadychangedlevel = TRUE;
1305                         return TRUE;
1306                 }
1307         }
1308         if(autocvar_quit_and_redirect != "")
1309         {
1310                 redirection_target = strzone(autocvar_quit_and_redirect);
1311                 alreadychangedlevel = TRUE;
1312                 return TRUE;
1313         }
1314         if (autocvar_samelevel) // if samelevel is set, stay on same level
1315         {
1316                 localcmd("restart\n");
1317                 alreadychangedlevel = TRUE;
1318                 return TRUE;
1319         }
1320         if(autocvar_nextmap != "")
1321                 if(MapInfo_CheckMap(autocvar_nextmap))
1322                 {
1323                         Map_Goto_SetStr(autocvar_nextmap);
1324                         Map_Goto(reinit);
1325                         alreadychangedlevel = TRUE;
1326                         return TRUE;
1327                 }
1328         if(autocvar_lastlevel)
1329         {
1330                 cvar_settemp_restore();
1331                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1332                 alreadychangedlevel = TRUE;
1333                 return TRUE;
1334         }
1335         return FALSE;
1336 }
1337
1338 void GotoNextMap(float reinit)
1339 {
1340         //string nextmap;
1341         //float n, nummaps;
1342         //string s;
1343         if (alreadychangedlevel)
1344                 return;
1345         alreadychangedlevel = TRUE;
1346
1347         {
1348                 string nextMap;
1349                 float allowReset;
1350
1351                 for(allowReset = 1; allowReset >= 0; --allowReset)
1352                 {
1353                         nextMap = GetNextMap();
1354                         if(nextMap != "")
1355                                 break;
1356
1357                         if(allowReset)
1358                         {
1359                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1360                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1361                                 if(autocvar_g_maplist_shuffle)
1362                                         ShuffleMaplist();
1363                                 localcmd("\nmenu_cmd sync\n");
1364                         }
1365                         else
1366                         {
1367                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1368                         }
1369                 }
1370                 Map_Goto(reinit);
1371         }
1372 }
1373
1374
1375 /*
1376 ============
1377 IntermissionThink
1378
1379 When the player presses attack or jump, change to the next level
1380 ============
1381 */
1382 .float autoscreenshot;
1383 void() MapVote_Start;
1384 void() MapVote_Think;
1385 float mapvote_initialized;
1386 void IntermissionThink()
1387 {
1388         FixIntermissionClient(self);
1389
1390         if( (autocvar_sv_autoscreenshot || self.cvar_cl_autoscreenshot)
1391                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1392         {
1393                 self.autoscreenshot = -1;
1394                 if(clienttype(self) == CLIENTTYPE_REAL)
1395                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1396                 return;
1397         }
1398
1399         if (time < intermission_exittime)
1400                 return;
1401
1402         if(!mapvote_initialized)
1403                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1404                         return;
1405
1406         MapVote_Start();
1407 }
1408
1409 /*
1410 ============
1411 FindIntermission
1412
1413 Returns the entity to view from
1414 ============
1415 */
1416 /*
1417 entity FindIntermission()
1418 {
1419         local   entity spot;
1420         local   float cyc;
1421
1422 // look for info_intermission first
1423         spot = find (world, classname, "info_intermission");
1424         if (spot)
1425         {       // pick a random one
1426                 cyc = random() * 4;
1427                 while (cyc > 1)
1428                 {
1429                         spot = find (spot, classname, "info_intermission");
1430                         if (!spot)
1431                                 spot = find (spot, classname, "info_intermission");
1432                         cyc = cyc - 1;
1433                 }
1434                 return spot;
1435         }
1436
1437 // then look for the start position
1438         spot = find (world, classname, "info_player_start");
1439         if (spot)
1440                 return spot;
1441
1442 // testinfo_player_start is only found in regioned levels
1443         spot = find (world, classname, "testplayerstart");
1444         if (spot)
1445                 return spot;
1446
1447 // then look for the start position
1448         spot = find (world, classname, "info_player_deathmatch");
1449         if (spot)
1450                 return spot;
1451
1452         //objerror ("FindIntermission: no spot");
1453         return world;
1454 }
1455 */
1456
1457 /*
1458 ===============================================================================
1459
1460 RULES
1461
1462 ===============================================================================
1463 */
1464
1465 void DumpStats(float final)
1466 {
1467         float file;
1468         string s;
1469         float to_console;
1470         float to_eventlog;
1471         float to_file;
1472         float i;
1473
1474         to_console = autocvar_sv_logscores_console;
1475         to_eventlog = autocvar_sv_eventlog;
1476         to_file = autocvar_sv_logscores_file;
1477
1478         if(!final)
1479         {
1480                 to_console = TRUE; // always print printstats replies
1481                 to_eventlog = FALSE; // but never print them to the event log
1482         }
1483
1484         if(to_eventlog)
1485                 if(autocvar_sv_eventlog_console)
1486                         to_console = FALSE; // otherwise we get the output twice
1487
1488         if(final)
1489                 s = ":scores:";
1490         else
1491                 s = ":status:";
1492         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1493
1494         if(to_console)
1495                 print(s, "\n");
1496         if(to_eventlog)
1497                 GameLogEcho(s);
1498         if(to_file)
1499         {
1500                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1501                 if(file == -1)
1502                         to_file = FALSE;
1503                 else
1504                         fputs(file, strcat(s, "\n"));
1505         }
1506
1507         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1508         if(to_console)
1509                 print(s, "\n");
1510         if(to_eventlog)
1511                 GameLogEcho(s);
1512         if(to_file)
1513                 fputs(file, strcat(s, "\n"));
1514
1515         FOR_EACH_CLIENT(other)
1516         {
1517                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1518                 {
1519                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1520                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1521                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1522                                 s = strcat(s, ftos(other.team), ":");
1523                         else
1524                                 s = strcat(s, "spectator:");
1525
1526                         if(to_console)
1527                                 print(s, other.netname, "\n");
1528                         if(to_eventlog)
1529                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1530                         if(to_file)
1531                                 fputs(file, strcat(s, other.netname, "\n"));
1532                 }
1533         }
1534
1535         if(teamplay)
1536         {
1537                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1538                 if(to_console)
1539                         print(s, "\n");
1540                 if(to_eventlog)
1541                         GameLogEcho(s);
1542                 if(to_file)
1543                         fputs(file, strcat(s, "\n"));
1544
1545                 for(i = 1; i < 16; ++i)
1546                 {
1547                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1548                         s = strcat(s, ":", ftos(i));
1549                         if(to_console)
1550                                 print(s, "\n");
1551                         if(to_eventlog)
1552                                 GameLogEcho(s);
1553                         if(to_file)
1554                                 fputs(file, strcat(s, "\n"));
1555                 }
1556         }
1557
1558         if(to_console)
1559                 print(":end\n");
1560         if(to_eventlog)
1561                 GameLogEcho(":end");
1562         if(to_file)
1563         {
1564                 fputs(file, ":end\n");
1565                 fclose(file);
1566         }
1567 }
1568
1569 void FixIntermissionClient(entity e)
1570 {
1571         string s;
1572         if(!e.autoscreenshot) // initial call
1573         {
1574                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1575                 e.health = -2342;
1576                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1577                 e.solid = SOLID_NOT;
1578                 e.movetype = MOVETYPE_NONE;
1579                 e.takedamage = DAMAGE_NO;
1580                 if(e.weaponentity)
1581                 {
1582                         e.weaponentity.effects = EF_NODRAW;
1583                         if (e.weaponentity.weaponentity)
1584                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1585                 }
1586                 if(clienttype(e) == CLIENTTYPE_REAL)
1587                 {
1588                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1589                         s = autocvar_sv_intermission_cdtrack;
1590                         if(s != "")
1591                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1592                         msg_entity = e;
1593                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1594                 }
1595         }
1596 }
1597
1598
1599 /*
1600 go to the next level for deathmatch
1601 only called if a time or frag limit has expired
1602 */
1603 void NextLevel()
1604 {
1605         gameover = TRUE;
1606
1607         intermission_running = 1;
1608
1609 // enforce a wait time before allowing changelevel
1610         if(player_count > 0)
1611                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1612         else
1613                 intermission_exittime = -1;
1614
1615         /*
1616         WriteByte (MSG_ALL, SVC_CDTRACK);
1617         WriteByte (MSG_ALL, 3);
1618         WriteByte (MSG_ALL, 3);
1619         // done in FixIntermission
1620         */
1621
1622         //pos = FindIntermission ();
1623
1624         VoteReset();
1625
1626         DumpStats(TRUE);
1627
1628         // send statistics
1629         entity e;
1630         PlayerStats_EndMatch(1);
1631         FOR_EACH_CLIENT(e)
1632                 PlayerStats_AddGlobalInfo(e);
1633         PlayerStats_Shutdown();
1634         WeaponStats_Shutdown();
1635
1636         if(autocvar_sv_eventlog)
1637                 GameLogEcho(":gameover");
1638
1639         GameLogClose();
1640
1641         FOR_EACH_PLAYER(other) {
1642                 FixIntermissionClient(other);
1643                 if(other.winning)
1644                         bprint(other.netname, " ^7wins.\n");
1645         }
1646
1647         if(autocvar_g_campaign)
1648                 CampaignPreIntermission();
1649
1650         localcmd("\nsv_hook_gameend\n");
1651 }
1652
1653 /*
1654 ============
1655 CheckRules_Player
1656
1657 Exit deathmatch games upon conditions
1658 ============
1659 */
1660 void CheckRules_Player()
1661 {
1662         if (gameover)   // someone else quit the game already
1663                 return;
1664
1665         if(self.deadflag == DEAD_NO)
1666                 self.play_time += frametime;
1667
1668         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1669         //   (div0: and that in CheckRules_World please)
1670 }
1671
1672 float checkrules_equality;
1673 float checkrules_suddendeathwarning;
1674 float checkrules_suddendeathend;
1675 float checkrules_overtimesadded; //how many overtimes have been already added
1676
1677 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1678 float WINNING_YES = 1; // winner found
1679 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1680 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1681
1682 float InitiateSuddenDeath()
1683 {
1684         // Check first whether normal overtimes could be added before initiating suddendeath mode
1685         // - for this timelimit_overtime needs to be >0 of course
1686         // - also check the winning condition calculated in the previous frame and only add normal overtime
1687         //   again, if at the point at which timelimit would be extended again, still no winner was found
1688         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1689         {
1690                 return 1; // need to call InitiateOvertime later
1691         }
1692         else
1693         {
1694                 if(!checkrules_suddendeathend)
1695                 {
1696                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1697                         if(g_race && !g_race_qualifying)
1698                                 race_StartCompleting();
1699                 }
1700                 return 0;
1701         }
1702 }
1703
1704 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1705 {
1706         ++checkrules_overtimesadded;
1707         //add one more overtime by simply extending the timelimit
1708         float tl;
1709         tl = autocvar_timelimit;
1710         tl += autocvar_timelimit_overtime;
1711         cvar_set("timelimit", ftos(tl));
1712         string minutesPlural;
1713         if (autocvar_timelimit_overtime == 1)
1714                 minutesPlural = " ^3minute";
1715         else
1716                 minutesPlural = " ^3minutes";
1717
1718         bcenterprint(
1719                 strcat(
1720                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1721                         ftos(autocvar_timelimit_overtime),
1722                         minutesPlural,
1723                         " to the game!"
1724                 )
1725         );
1726 }
1727
1728 float GetWinningCode(float fraglimitreached, float equality)
1729 {
1730         if(autocvar_g_campaign == 1)
1731                 if(fraglimitreached)
1732                         return WINNING_YES;
1733                 else
1734                         return WINNING_NO;
1735
1736         else
1737                 if(equality)
1738                         if(fraglimitreached)
1739                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1740                         else
1741                                 return WINNING_NEVER;
1742                 else
1743                         if(fraglimitreached)
1744                                 return WINNING_YES;
1745                         else
1746                                 return WINNING_NO;
1747 }
1748
1749 // set the .winning flag for exactly those players with a given field value
1750 void SetWinners(.float field, float value)
1751 {
1752         entity head;
1753         FOR_EACH_PLAYER(head)
1754                 head.winning = (head.field == value);
1755 }
1756
1757 // set the .winning flag for those players with a given field value
1758 void AddWinners(.float field, float value)
1759 {
1760         entity head;
1761         FOR_EACH_PLAYER(head)
1762                 if(head.field == value)
1763                         head.winning = 1;
1764 }
1765
1766 // clear the .winning flags
1767 void ClearWinners(void)
1768 {
1769         entity head;
1770         FOR_EACH_PLAYER(head)
1771                 head.winning = 0;
1772 }
1773
1774 // Onslaught winning condition:
1775 // game terminates if only one team has a working generator (or none)
1776 float WinningCondition_Onslaught()
1777 {
1778         entity head;
1779         float t1, t2, t3, t4;
1780
1781         WinningConditionHelper(); // set worldstatus
1782
1783         if(inWarmupStage)
1784                 return WINNING_NO;
1785
1786         // first check if the game has ended
1787         t1 = t2 = t3 = t4 = 0;
1788         head = find(world, classname, "onslaught_generator");
1789         while (head)
1790         {
1791                 if (head.health > 0)
1792                 {
1793                         if (head.team == COLOR_TEAM1) t1 = 1;
1794                         if (head.team == COLOR_TEAM2) t2 = 1;
1795                         if (head.team == COLOR_TEAM3) t3 = 1;
1796                         if (head.team == COLOR_TEAM4) t4 = 1;
1797                 }
1798                 head = find(head, classname, "onslaught_generator");
1799         }
1800         if (t1 + t2 + t3 + t4 < 2)
1801         {
1802                 // game over, only one team remains (or none)
1803                 ClearWinners();
1804                 if (t1) SetWinners(team, COLOR_TEAM1);
1805                 if (t2) SetWinners(team, COLOR_TEAM2);
1806                 if (t3) SetWinners(team, COLOR_TEAM3);
1807                 if (t4) SetWinners(team, COLOR_TEAM4);
1808                 dprint("Have a winner, ending game.\n");
1809                 return WINNING_YES;
1810         }
1811
1812         // Two or more teams remain
1813         return WINNING_NO;
1814 }
1815
1816 float LMS_NewPlayerLives()
1817 {
1818         float fl;
1819         fl = autocvar_fraglimit;
1820         if(fl == 0)
1821                 fl = 999;
1822
1823         // first player has left the game for dying too much? Nobody else can get in.
1824         if(lms_lowest_lives < 1)
1825                 return 0;
1826
1827         if(!autocvar_g_lms_join_anytime)
1828                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1829                         return 0;
1830
1831         return bound(1, lms_lowest_lives, fl);
1832 }
1833
1834 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1835 // they win. Otherwise the defending team wins once the timelimit passes.
1836 void assault_new_round();
1837 float WinningCondition_Assault()
1838 {
1839         float status;
1840
1841         WinningConditionHelper(); // set worldstatus
1842
1843         status = WINNING_NO;
1844         // as the timelimit has not yet passed just assume the defending team will win
1845         if(assault_attacker_team == COLOR_TEAM1)
1846         {
1847                 SetWinners(team, COLOR_TEAM2);
1848         }
1849         else
1850         {
1851                 SetWinners(team, COLOR_TEAM1);
1852         }
1853
1854         entity ent;
1855         ent = find(world, classname, "target_assault_roundend");
1856         if(ent)
1857         {
1858                 if(ent.winning) // round end has been triggered by attacking team
1859                 {
1860                         bprint("ASSAULT: round completed...\n");
1861                         SetWinners(team, assault_attacker_team);
1862
1863                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1864
1865                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1866                         {
1867                                 status = WINNING_YES;
1868                         }
1869                         else
1870                         {
1871                                 entity oldself;
1872                                 oldself = self;
1873                                 self = ent;
1874                                 assault_new_round();
1875                                 self = oldself;
1876                         }
1877                 }
1878         }
1879
1880         return status;
1881 }
1882
1883 // LMS winning condition: game terminates if and only if there's at most one
1884 // one player who's living lives. Top two scores being equal cancels the time
1885 // limit.
1886 float WinningCondition_LMS()
1887 {
1888         entity head, head2;
1889         float have_player;
1890         float have_players;
1891         float l;
1892
1893         have_player = FALSE;
1894         have_players = FALSE;
1895         l = LMS_NewPlayerLives();
1896
1897         head = find(world, classname, "player");
1898         if(head)
1899                 have_player = TRUE;
1900         head2 = find(head, classname, "player");
1901         if(head2)
1902                 have_players = TRUE;
1903
1904         if(have_player)
1905         {
1906                 // we have at least one player
1907                 if(have_players)
1908                 {
1909                         // two or more active players - continue with the game
1910                 }
1911                 else
1912                 {
1913                         // exactly one player?
1914
1915                         ClearWinners();
1916                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1917
1918                         if(l)
1919                         {
1920                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1921                                 return WINNING_NO;
1922                         }
1923                         else
1924                         {
1925                                 // a winner!
1926                                 // and assign him his first place
1927                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1928                                 return WINNING_YES;
1929                         }
1930                 }
1931         }
1932         else
1933         {
1934                 // nobody is playing at all...
1935                 if(l)
1936                 {
1937                         // wait for players...
1938                 }
1939                 else
1940                 {
1941                         // SNAFU (maybe a draw game?)
1942                         ClearWinners();
1943                         dprint("No players, ending game.\n");
1944                         return WINNING_YES;
1945                 }
1946         }
1947
1948         // When we get here, we have at least two players who are actually LIVING,
1949         // now check if the top two players have equal score.
1950         WinningConditionHelper();
1951
1952         ClearWinners();
1953         if(WinningConditionHelper_winner)
1954                 WinningConditionHelper_winner.winning = TRUE;
1955         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1956                 return WINNING_NEVER;
1957
1958         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1959         return WINNING_NO;
1960 }
1961
1962 void ShuffleMaplist()
1963 {
1964         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1965 }
1966
1967 float leaderfrags;
1968 float WinningCondition_Scores(float limit, float leadlimit)
1969 {
1970         float limitreached;
1971
1972         // TODO make everything use THIS winning condition (except LMS)
1973         WinningConditionHelper();
1974
1975         if(teamplay)
1976         {
1977                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1978                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1979                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1980                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1981         }
1982
1983         ClearWinners();
1984         if(WinningConditionHelper_winner)
1985                 WinningConditionHelper_winner.winning = 1;
1986         if(WinningConditionHelper_winnerteam >= 0)
1987                 SetWinners(team, WinningConditionHelper_winnerteam);
1988
1989         if(WinningConditionHelper_lowerisbetter)
1990         {
1991                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1992                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1993                 limit = -limit;
1994         }
1995
1996         if(WinningConditionHelper_zeroisworst)
1997                 leadlimit = 0; // not supported in this mode
1998
1999         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
2000         // these modes always score in increments of 1, thus this makes sense
2001         {
2002                 if(leaderfrags != WinningConditionHelper_topscore)
2003                 {
2004                         leaderfrags = WinningConditionHelper_topscore;
2005
2006                         if (limit)
2007                         if (leaderfrags == limit - 1)
2008                                 Announce("1fragleft");
2009                         else if (leaderfrags == limit - 2)
2010                                 Announce("2fragsleft");
2011                         else if (leaderfrags == limit - 3)
2012                                 Announce("3fragsleft");
2013                 }
2014         }
2015
2016         limitreached = FALSE;
2017         if(limit)
2018                 if(WinningConditionHelper_topscore >= limit)
2019                         limitreached = TRUE;
2020         if(leadlimit)
2021         {
2022                 float leadlimitreached;
2023                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
2024                 if(autocvar_leadlimit_and_fraglimit)
2025                         limitreached = (limitreached && leadlimitreached);
2026                 else
2027                         limitreached = (limitreached || leadlimitreached);
2028         }
2029
2030         return GetWinningCode(
2031                 WinningConditionHelper_topscore && limitreached,
2032                 WinningConditionHelper_equality
2033         );
2034 }
2035
2036 float WinningCondition_Race(float fraglimit)
2037 {
2038         float wc;
2039         entity p;
2040         float n, c;
2041
2042         n = 0;
2043         c = 0;
2044         FOR_EACH_PLAYER(p)
2045         {
2046                 ++n;
2047                 if(p.race_completed)
2048                         ++c;
2049         }
2050         if(n && (n == c))
2051                 return WINNING_YES;
2052         wc = WinningCondition_Scores(fraglimit, 0);
2053
2054         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2055         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2056         // do NOT support equality when the laps are all raced!
2057                 return WINNING_STARTSUDDENDEATHOVERTIME;
2058         else
2059                 return WINNING_NEVER;
2060         return wc;
2061 }
2062
2063 void ReadyRestart();
2064 float WinningCondition_QualifyingThenRace(float limit)
2065 {
2066         float wc;
2067         wc = WinningCondition_Scores(limit, 0);
2068
2069         // NEVER initiate overtime
2070         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2071         {
2072                 return WINNING_YES;
2073         }
2074
2075         return wc;
2076 }
2077
2078 float WinningCondition_RanOutOfSpawns()
2079 {
2080         entity head;
2081
2082         if(have_team_spawns <= 0)
2083                 return WINNING_NO;
2084
2085         if(autocvar_g_spawn_useallspawns <= 0)
2086                 return WINNING_NO;
2087
2088         if(!some_spawn_has_been_used)
2089                 return WINNING_NO;
2090
2091         team1_score = team2_score = team3_score = team4_score = 0;
2092
2093         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2094         {
2095                 if(head.team == COLOR_TEAM1)
2096                         team1_score = 1;
2097                 else if(head.team == COLOR_TEAM2)
2098                         team2_score = 1;
2099                 else if(head.team == COLOR_TEAM3)
2100                         team3_score = 1;
2101                 else if(head.team == COLOR_TEAM4)
2102                         team4_score = 1;
2103         }
2104
2105         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2106         {
2107                 if(head.team == COLOR_TEAM1)
2108                         team1_score = 1;
2109                 else if(head.team == COLOR_TEAM2)
2110                         team2_score = 1;
2111                 else if(head.team == COLOR_TEAM3)
2112                         team3_score = 1;
2113                 else if(head.team == COLOR_TEAM4)
2114                         team4_score = 1;
2115         }
2116
2117         ClearWinners();
2118         if(team1_score + team2_score + team3_score + team4_score == 0)
2119         {
2120                 checkrules_equality = TRUE;
2121                 return WINNING_YES;
2122         }
2123         else if(team1_score + team2_score + team3_score + team4_score == 1)
2124         {
2125                 float t, i;
2126                 if(team1_score) t = COLOR_TEAM1;
2127                 if(team2_score) t = COLOR_TEAM2;
2128                 if(team3_score) t = COLOR_TEAM3;
2129                 if(team4_score) t = COLOR_TEAM4;
2130                 CheckAllowedTeams(world);
2131                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2132                 {
2133                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2134                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2135                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2136                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2137                 }
2138
2139                 AddWinners(team, t);
2140                 return WINNING_YES;
2141         }
2142         else
2143                 return WINNING_NO;
2144 }
2145
2146 /*
2147 ============
2148 CheckRules_World
2149
2150 Exit deathmatch games upon conditions
2151 ============
2152 */
2153 void CheckRules_World()
2154 {
2155         float timelimit;
2156         float fraglimit;
2157         float leadlimit;
2158
2159         VoteThink();
2160         MapVote_Think();
2161
2162         SetDefaultAlpha();
2163
2164         /*
2165         MapVote_Think should now do that part
2166         if (intermission_running)
2167                 if (time >= intermission_exittime + 60)
2168                 {
2169                         if(!DoNextMapOverride())
2170                                 GotoNextMap();
2171                         return;
2172                 }
2173         */
2174
2175         if (gameover)   // someone else quit the game already
2176         {
2177                 if(player_count == 0) // Nobody there? Then let's go to the next map
2178                         MapVote_Start();
2179                         // this will actually check the player count in the next frame
2180                         // again, but this shouldn't hurt
2181                 return;
2182         }
2183
2184         timelimit = autocvar_timelimit * 60;
2185         fraglimit = autocvar_fraglimit;
2186         leadlimit = autocvar_leadlimit;
2187
2188         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2189         {
2190                 if(timelimit > 0)
2191                         timelimit = 0; // timelimit is not made for warmup
2192                 if(fraglimit > 0)
2193                         fraglimit = 0; // no fraglimit for now
2194                 leadlimit = 0; // no leadlimit for now
2195         }
2196
2197         if(g_onslaught)
2198                 timelimit = 0; // ONS has its own overtime rule
2199
2200         if(timelimit > 0)
2201         {
2202                 timelimit += game_starttime;
2203         }
2204         else if (timelimit < 0)
2205         {
2206                 // endmatch
2207                 NextLevel();
2208                 return;
2209         }
2210
2211         float wantovertime;
2212         wantovertime = 0;
2213
2214         if(checkrules_suddendeathend)
2215         {
2216                 if(!checkrules_suddendeathwarning)
2217                 {
2218                         checkrules_suddendeathwarning = TRUE;
2219                         if(g_race && !g_race_qualifying)
2220                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2221                         else
2222                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2223                 }
2224         }
2225         else
2226         {
2227                 if (timelimit && time >= timelimit)
2228                 {
2229                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2230                         {
2231                                 float totalplayers;
2232                                 float playerswithlaps;
2233                                 float readyplayers;
2234                                 entity head;
2235                                 totalplayers = playerswithlaps = readyplayers = 0;
2236                                 FOR_EACH_PLAYER(head)
2237                                 {
2238                                         ++totalplayers;
2239                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2240                                                 ++playerswithlaps;
2241                                         if(head.ready)
2242                                                 ++readyplayers;
2243                                 }
2244
2245                                 // at least 2 of the players have completed a lap: start the RACE
2246                                 // otherwise, the players should end the qualifying on their own
2247                                 if(readyplayers || playerswithlaps >= 2)
2248                                 {
2249                                         checkrules_suddendeathend = 0;
2250                                         ReadyRestart(); // go to race
2251                                         return;
2252                                 }
2253                                 else
2254                                         wantovertime |= InitiateSuddenDeath();
2255                         }
2256                         else
2257                                 wantovertime |= InitiateSuddenDeath();
2258                 }
2259         }
2260
2261         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2262         {
2263                 NextLevel();
2264                 return;
2265         }
2266
2267         float checkrules_status;
2268         checkrules_status = WinningCondition_RanOutOfSpawns();
2269         if(checkrules_status == WINNING_YES)
2270         {
2271                 bprint("Hey! Someone ran out of spawns!\n");
2272         }
2273         else if(g_race && !g_race_qualifying && timelimit >= 0)
2274         {
2275                 checkrules_status = WinningCondition_Race(fraglimit);
2276                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2277         }
2278         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2279         {
2280                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2281                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2282         }
2283         else if(g_assault)
2284         {
2285                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2286         }
2287         else if(g_lms)
2288         {
2289                 checkrules_status = WinningCondition_LMS();
2290         }
2291         else if (g_onslaught)
2292         {
2293                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2294         }
2295         else
2296         {
2297                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2298                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2299         }
2300
2301         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2302         {
2303                 checkrules_status = WINNING_NEVER;
2304                 checkrules_overtimesadded = -1;
2305                 wantovertime |= InitiateSuddenDeath();
2306         }
2307
2308         if(checkrules_status == WINNING_NEVER)
2309                 // equality cases! Nobody wins if the overtime ends in a draw.
2310                 ClearWinners();
2311
2312         if(wantovertime)
2313         {
2314                 if(checkrules_status == WINNING_NEVER)
2315                         InitiateOvertime();
2316                 else
2317                         checkrules_status = WINNING_YES;
2318         }
2319
2320         if(checkrules_suddendeathend)
2321                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2322                         checkrules_status = WINNING_YES;
2323
2324         if(checkrules_status == WINNING_YES)
2325         {
2326                 //print("WINNING\n");
2327                 NextLevel();
2328         }
2329 }
2330
2331 float mapvote_nextthink;
2332 float mapvote_initialized;
2333 float mapvote_keeptwotime;
2334 float mapvote_timeout;
2335 string mapvote_message;
2336 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2337 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2338 float mapvote_screenshot_dirs_count;
2339
2340 float mapvote_count;
2341 float mapvote_count_real;
2342 string mapvote_maps[MAPVOTE_COUNT];
2343 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2344 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2345 float mapvote_maps_suggested[MAPVOTE_COUNT];
2346 string mapvote_suggestions[MAPVOTE_COUNT];
2347 float mapvote_suggestion_ptr;
2348 float mapvote_voters;
2349 float mapvote_votes[MAPVOTE_COUNT];
2350 float mapvote_run;
2351 float mapvote_detail;
2352 float mapvote_abstain;
2353 .float mapvote;
2354
2355 void MapVote_ClearAllVotes()
2356 {
2357         FOR_EACH_CLIENT(other)
2358                 other.mapvote = 0;
2359 }
2360
2361 string MapVote_Suggest(string m)
2362 {
2363         float i;
2364         if(m == "")
2365                 return "That's not how to use this command.";
2366         if(!autocvar_g_maplist_votable_suggestions)
2367                 return "Suggestions are not accepted on this server.";
2368         if(mapvote_initialized)
2369                 return "Can't suggest - voting is already in progress!";
2370         m = MapInfo_FixName(m);
2371         if(!m)
2372                 return "The map you suggested is not available on this server.";
2373         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2374                 if(Map_IsRecent(m))
2375                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2376
2377         if(!MapInfo_CheckMap(m))
2378                 return "The map you suggested does not support the current game mode.";
2379         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2380                 if(mapvote_suggestions[i] == m)
2381                         return "This map was already suggested.";
2382         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2383         {
2384                 i = floor(random() * mapvote_suggestion_ptr);
2385         }
2386         else
2387         {
2388                 i = mapvote_suggestion_ptr;
2389                 mapvote_suggestion_ptr += 1;
2390         }
2391         if(mapvote_suggestions[i] != "")
2392                 strunzone(mapvote_suggestions[i]);
2393         mapvote_suggestions[i] = strzone(m);
2394         if(autocvar_sv_eventlog)
2395                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2396         return strcat("Suggestion of ", m, " accepted.");
2397 }
2398
2399 void MapVote_AddVotable(string nextMap, float isSuggestion)
2400 {
2401         float j, i, o;
2402         string pakfile, mapfile;
2403
2404         if(nextMap == "")
2405                 return;
2406         for(j = 0; j < mapvote_count; ++j)
2407                 if(mapvote_maps[j] == nextMap)
2408                         return;
2409         // suggestions might be no longer valid/allowed after gametype switch!
2410         if(isSuggestion)
2411                 if(!MapInfo_CheckMap(nextMap))
2412                         return;
2413         mapvote_maps[mapvote_count] = strzone(nextMap);
2414         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2415
2416         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2417         {
2418                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2419                 pakfile = whichpack(strcat(mapfile, ".tga"));
2420                 if(pakfile == "")
2421                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2422                 if(pakfile == "")
2423                         pakfile = whichpack(strcat(mapfile, ".png"));
2424                 if(pakfile != "")
2425                         break;
2426         }
2427         if(i >= mapvote_screenshot_dirs_count)
2428                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2429         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2430                 pakfile = substring(pakfile, o, -1);
2431
2432         mapvote_maps_screenshot_dir[mapvote_count] = i;
2433         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2434
2435         mapvote_count += 1;
2436 }
2437
2438 void MapVote_Spawn();
2439 void MapVote_Init()
2440 {
2441         float i;
2442         float nmax, smax;
2443
2444         MapVote_ClearAllVotes();
2445
2446         mapvote_count = 0;
2447         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2448         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2449
2450         if(mapvote_abstain)
2451                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2452         else
2453                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2454         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2455
2456         // we need this for AddVotable, as that cycles through the screenshot dirs
2457         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2458         if(mapvote_screenshot_dirs_count == 0)
2459                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2460         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2461         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2462                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2463
2464         if(mapvote_suggestion_ptr)
2465                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2466                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2467
2468         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2469                 MapVote_AddVotable(GetNextMap(), FALSE);
2470
2471         if(mapvote_count == 0)
2472         {
2473                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2474                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2475                 if(autocvar_g_maplist_shuffle)
2476                         ShuffleMaplist();
2477                 localcmd("\nmenu_cmd sync\n");
2478                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2479                         MapVote_AddVotable(GetNextMap(), FALSE);
2480         }
2481
2482         mapvote_count_real = mapvote_count;
2483         if(mapvote_abstain)
2484                 MapVote_AddVotable("don't care", 0);
2485
2486         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2487
2488         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2489         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2490         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2491                 mapvote_keeptwotime = 0;
2492         mapvote_message = "Choose a map and press its key!";
2493
2494         MapVote_Spawn();
2495 }
2496
2497 void MapVote_SendPicture(float id)
2498 {
2499         msg_entity = self;
2500         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2501         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2502         WriteByte(MSG_ONE, id);
2503         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2504 }
2505
2506 float GameCommand_MapVote(string cmd)
2507 {
2508         if(!intermission_running)
2509                 return FALSE;
2510
2511         if(cmd == "mv_getpic")
2512         {
2513                 MapVote_SendPicture(stof(argv(1)));
2514                 return TRUE;
2515         }
2516
2517         return FALSE;
2518 }
2519
2520 float MapVote_GetMapMask()
2521 {
2522         float mask, i, power;
2523         mask = 0;
2524         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2525                 if(mapvote_maps[i] != "")
2526                         mask |= power;
2527         return mask;
2528 }
2529
2530 entity mapvote_ent;
2531 float MapVote_SendEntity(entity to, float sf)
2532 {
2533         float i;
2534
2535         if(sf & 1)
2536                 sf &~= 2; // if we send 1, we don't need to also send 2
2537
2538         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2539         WriteByte(MSG_ENTITY, sf);
2540
2541         if(sf & 1)
2542         {
2543                 // flag 1 == initialization
2544                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2545                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2546                 WriteString(MSG_ENTITY, "");
2547                 WriteByte(MSG_ENTITY, mapvote_count);
2548                 WriteByte(MSG_ENTITY, mapvote_abstain);
2549                 WriteByte(MSG_ENTITY, mapvote_detail);
2550                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2551                 if(mapvote_count <= 8)
2552                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2553                 else
2554                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2555                 for(i = 0; i < mapvote_count; ++i)
2556                         if(mapvote_maps[i] != "")
2557                         {
2558                                 if(mapvote_abstain && i == mapvote_count - 1)
2559                                 {
2560                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2561                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2562                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2563                                 }
2564                                 else
2565                                 {
2566                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2567                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2568                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2569                                 }
2570                         }
2571         }
2572
2573         if(sf & 2)
2574         {
2575                 // flag 2 == update of mask
2576                 if(mapvote_count <= 8)
2577                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2578                 else
2579                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2580         }
2581
2582         if(sf & 4)
2583         {
2584                 if(mapvote_detail)
2585                         for(i = 0; i < mapvote_count; ++i)
2586                                 if(mapvote_maps[i] != "")
2587                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2588
2589                 WriteByte(MSG_ENTITY, to.mapvote);
2590         }
2591
2592         return TRUE;
2593 }
2594
2595 void MapVote_Spawn()
2596 {
2597         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2598 }
2599
2600 void MapVote_TouchMask()
2601 {
2602         mapvote_ent.SendFlags |= 2;
2603 }
2604
2605 void MapVote_TouchVotes(entity voter)
2606 {
2607         mapvote_ent.SendFlags |= 4;
2608 }
2609
2610 float MapVote_Finished(float mappos)
2611 {
2612         string result;
2613         float i;
2614         float didntvote;
2615
2616         if(autocvar_sv_eventlog)
2617         {
2618                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2619                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2620                 didntvote = mapvote_voters;
2621                 for(i = 0; i < mapvote_count; ++i)
2622                         if(mapvote_maps[i] != "")
2623                         {
2624                                 didntvote -= mapvote_votes[i];
2625                                 if(i != mappos)
2626                                 {
2627                                         result = strcat(result, ":", mapvote_maps[i]);
2628                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2629                                 }
2630                         }
2631                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2632
2633                 GameLogEcho(result);
2634                 if(mapvote_maps_suggested[mappos])
2635                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2636         }
2637
2638         FOR_EACH_REALCLIENT(other)
2639                 FixClientCvars(other);
2640
2641         Map_Goto_SetStr(mapvote_maps[mappos]);
2642         Map_Goto(0);
2643         alreadychangedlevel = TRUE;
2644         return TRUE;
2645 }
2646 void MapVote_CheckRules_1()
2647 {
2648         float i;
2649
2650         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2651         {
2652                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2653                 mapvote_votes[i] = 0;
2654         }
2655
2656         mapvote_voters = 0;
2657         FOR_EACH_REALCLIENT(other)
2658         {
2659                 ++mapvote_voters;
2660                 if(other.mapvote)
2661                 {
2662                         i = other.mapvote - 1;
2663                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2664                         mapvote_votes[i] = mapvote_votes[i] + 1;
2665                 }
2666         }
2667 }
2668
2669 float MapVote_CheckRules_2()
2670 {
2671         float i;
2672         float firstPlace, secondPlace;
2673         float firstPlaceVotes, secondPlaceVotes;
2674         float mapvote_voters_real;
2675         string result;
2676
2677         if(mapvote_count_real == 1)
2678                 return MapVote_Finished(0);
2679
2680         mapvote_voters_real = mapvote_voters;
2681         if(mapvote_abstain)
2682                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2683
2684         RandomSelection_Init();
2685         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2686                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2687         firstPlace = RandomSelection_chosen_float;
2688         firstPlaceVotes = RandomSelection_best_priority;
2689         //dprint("First place: ", ftos(firstPlace), "\n");
2690         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2691
2692         RandomSelection_Init();
2693         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2694                 if(i != firstPlace)
2695                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2696         secondPlace = RandomSelection_chosen_float;
2697         secondPlaceVotes = RandomSelection_best_priority;
2698         //dprint("Second place: ", ftos(secondPlace), "\n");
2699         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2700
2701         if(firstPlace == -1)
2702                 error("No first place in map vote... WTF?");
2703
2704         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2705                 return MapVote_Finished(firstPlace);
2706
2707         if(mapvote_keeptwotime)
2708                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2709                 {
2710                         float didntvote;
2711                         MapVote_TouchMask();
2712                         mapvote_message = "Now decide between the TOP TWO!";
2713                         mapvote_keeptwotime = 0;
2714                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2715                         result = strcat(result, ":", ftos(firstPlaceVotes));
2716                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2717                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2718                         didntvote = mapvote_voters;
2719                         for(i = 0; i < mapvote_count; ++i)
2720                                 if(mapvote_maps[i] != "")
2721                                 {
2722                                         didntvote -= mapvote_votes[i];
2723                                         if(i != firstPlace)
2724                                                 if(i != secondPlace)
2725                                                 {
2726                                                         result = strcat(result, ":", mapvote_maps[i]);
2727                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2728                                                         if(i < mapvote_count_real)
2729                                                         {
2730                                                                 strunzone(mapvote_maps[i]);
2731                                                                 mapvote_maps[i] = "";
2732                                                                 strunzone(mapvote_maps_pakfile[i]);
2733                                                                 mapvote_maps_pakfile[i] = "";
2734                                                         }
2735                                                 }
2736                                 }
2737                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2738                         if(autocvar_sv_eventlog)
2739                                 GameLogEcho(result);
2740                 }
2741
2742         return FALSE;
2743 }
2744 void MapVote_Tick()
2745 {
2746         float keeptwo;
2747         float totalvotes;
2748
2749         keeptwo = mapvote_keeptwotime;
2750         MapVote_CheckRules_1(); // count
2751         if(MapVote_CheckRules_2()) // decide
2752                 return;
2753
2754         totalvotes = 0;
2755         FOR_EACH_REALCLIENT(other)
2756         {
2757                 // hide scoreboard again
2758                 if(other.health != 2342)
2759                 {
2760                         other.health = 2342;
2761                         other.impulse = 0;
2762                         if(clienttype(other) == CLIENTTYPE_REAL)
2763                         {
2764                                 msg_entity = other;
2765                                 WriteByte(MSG_ONE, SVC_FINALE);
2766                                 WriteString(MSG_ONE, "");
2767                         }
2768                 }
2769
2770                 // clear possibly invalid votes
2771                 if(mapvote_maps[other.mapvote - 1] == "")
2772                         other.mapvote = 0;
2773                 // use impulses as new vote
2774                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2775                         if(mapvote_maps[other.impulse - 1] != "")
2776                         {
2777                                 other.mapvote = other.impulse;
2778                                 MapVote_TouchVotes(other);
2779                         }
2780                 other.impulse = 0;
2781
2782                 if(other.mapvote)
2783                         ++totalvotes;
2784         }
2785
2786         MapVote_CheckRules_1(); // just count
2787 }
2788 void MapVote_Start()
2789 {
2790         if(mapvote_run)
2791                 return;
2792
2793         // wait for stats to be sent first
2794         if(!playerstats_waitforme)
2795                 return;
2796
2797         MapInfo_Enumerate();
2798         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2799                 mapvote_run = TRUE;
2800 }
2801 void MapVote_Think()
2802 {
2803         if(!mapvote_run)
2804                 return;
2805
2806         if(alreadychangedlevel)
2807                 return;
2808
2809         if(time < mapvote_nextthink)
2810                 return;
2811         //dprint("tick\n");
2812
2813         mapvote_nextthink = time + 0.5;
2814
2815         if(!mapvote_initialized)
2816         {
2817                 if(autocvar_rescan_pending == 1)
2818                 {
2819                         cvar_set("rescan_pending", "2");
2820                         localcmd("fs_rescan\nrescan_pending 3\n");
2821                         return;
2822                 }
2823                 else if(autocvar_rescan_pending == 2)
2824                 {
2825                         return;
2826                 }
2827                 else if(autocvar_rescan_pending == 3)
2828                 {
2829                         // now build missing mapinfo files
2830                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2831                                 return;
2832
2833                         // we're done, start the timer
2834                         cvar_set("rescan_pending", "0");
2835                 }
2836
2837                 mapvote_initialized = TRUE;
2838                 if(DoNextMapOverride(0))
2839                         return;
2840                 if(!autocvar_g_maplist_votable || player_count <= 0)
2841                 {
2842                         GotoNextMap(0);
2843                         return;
2844                 }
2845                 MapVote_Init();
2846         }
2847
2848         MapVote_Tick();
2849 }
2850
2851 string GotoMap(string m)
2852 {
2853         if(!MapInfo_CheckMap(m))
2854                 return "The map you chose is not available on this server.";
2855         cvar_set("nextmap", m);
2856         cvar_set("timelimit", "-1");
2857         if(mapvote_initialized || alreadychangedlevel)
2858         {
2859                 if(DoNextMapOverride(0))
2860                         return "Map switch initiated.";
2861                 else
2862                         return "Hm... no. For some reason I like THIS map more.";
2863         }
2864         else
2865                 return "Map switch will happen after scoreboard.";
2866 }
2867
2868
2869 void EndFrame()
2870 {
2871         float altime;
2872         FOR_EACH_REALCLIENT(self)
2873         {
2874                 if(self.classname == "spectator")
2875                 {
2876                         if(self.enemy.typehitsound)
2877                                 self.typehit_time = time;
2878                         else if(self.enemy.hitsound)
2879                                 self.hit_time = time;
2880                 }
2881                 else
2882                 {
2883                         if(self.typehitsound)
2884                                 self.typehit_time = time;
2885                         else if(self.hitsound)
2886                                 self.hit_time = time;
2887                 }
2888         }
2889         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2890         // add 1 frametime because after this, engine SV_Physics
2891         // increases time by a frametime and then networks the frame
2892         // add another frametime because client shows everything with
2893         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2894         // needed!
2895         FOR_EACH_CLIENT(self)
2896         {
2897                 self.hitsound = FALSE;
2898                 self.typehitsound = FALSE;
2899                 antilag_record(self, altime);
2900         }
2901 }
2902
2903
2904 /*
2905  * RedirectionThink:
2906  * returns TRUE if redirecting
2907  */
2908 float redirection_timeout;
2909 float redirection_nextthink;
2910 float RedirectionThink()
2911 {
2912         float clients_found;
2913
2914         if(redirection_target == "")
2915                 return FALSE;
2916
2917         if(!redirection_timeout)
2918         {
2919                 cvar_set("sv_public", "-2");
2920                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2921                 if(redirection_target == "self")
2922                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2923                 else
2924                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2925         }
2926
2927         if(time < redirection_nextthink)
2928                 return TRUE;
2929
2930         redirection_nextthink = time + 1;
2931
2932         clients_found = 0;
2933         FOR_EACH_REALCLIENT(self)
2934         {
2935                 print("Redirecting: sending connect command to ", self.netname, "\n");
2936                 if(redirection_target == "self")
2937                         stuffcmd(self, "\ndisconnect; reconnect\n");
2938                 else
2939                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2940                 ++clients_found;
2941         }
2942
2943         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2944
2945         if(time > redirection_timeout || clients_found == 0)
2946                 localcmd("\nwait; wait; wait; quit\n");
2947
2948         return TRUE;
2949 }
2950
2951 void TargetMusic_RestoreGame();
2952 void RestoreGame()
2953 {
2954         // Loaded from a save game
2955         // some things then break, so let's work around them...
2956
2957         // Progs DB (capture records)
2958         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2959
2960         // Mapinfo
2961         MapInfo_Shutdown();
2962         MapInfo_Enumerate();
2963         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2964         WeaponStats_Init();
2965
2966         TargetMusic_RestoreGame();
2967 }
2968
2969 void Shutdown()
2970 {
2971         entity e;
2972
2973         gameover = 2;
2974
2975         if(world_initialized > 0)
2976         {
2977                 world_initialized = 0;
2978                 print("Saving persistent data...\n");
2979                 Ban_SaveBans();
2980
2981                 PlayerStats_EndMatch(0);
2982                 FOR_EACH_CLIENT(e)
2983                         PlayerStats_AddGlobalInfo(e);
2984                 PlayerStats_Shutdown();
2985
2986                 if(!cheatcount_total)
2987                 {
2988                         if(autocvar_sv_db_saveasdump)
2989                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2990                         else
2991                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2992                 }
2993                 if(autocvar_developer)
2994                 {
2995                         if(autocvar_sv_db_saveasdump)
2996                                 db_dump(TemporaryDB, "server-temp.db");
2997                         else
2998                                 db_save(TemporaryDB, "server-temp.db");
2999                 }
3000                 CheatShutdown(); // must be after cheatcount check
3001                 db_close(ServerProgsDB);
3002                 db_close(TemporaryDB);
3003                 print("done!\n");
3004                 // tell the bot system the game is ending now
3005                 bot_endgame();
3006
3007                 WeaponStats_Shutdown();
3008                 MapInfo_Shutdown();
3009         }
3010         else if(world_initialized == 0)
3011         {
3012                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
3013         }
3014 }