qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/_mod.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include <common/net_linked.qh>
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/_mod.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications/all.qh"
  29 #include "../common/physics/player.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/_mod.qh"
  37 #include <common/weapons/_all.qh>
  38 #include "../common/state.qh"
  39
  40 const float LATENCY_THINKRATE = 10;
  41 .float latency_sum;
  42 .float latency_cnt;
  43 .float latency_time;
  44 entity pingplreport;
  45 void PingPLReport_Think(entity this)
  46 {
  47         float delta;
  48         entity e;
  49
  50         delta = 3 / maxclients;
  51         if(delta < sys_frametime)
  52                 delta = 0;
  53         this.nextthink = time + delta;
  54
  55         e = edict_num(this.cnt + 1);
  56         if(IS_REAL_CLIENT(e))
  57         {
  58                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  59                 WriteByte(MSG_BROADCAST, this.cnt);
  60                 WriteShort(MSG_BROADCAST, bound(1, e.ping, 65535));
  61                 WriteByte(MSG_BROADCAST, min(ceil(e.ping_packetloss * 255), 255));
  62                 WriteByte(MSG_BROADCAST, min(ceil(e.ping_movementloss * 255), 255));
  63
  64                 // record latency times for clients throughout the match so we can report it to playerstats
  65                 if(time > (e.latency_time + LATENCY_THINKRATE))
  66                 {
  67                         e.latency_sum += e.ping;
  68                         e.latency_cnt += 1;
  69                         e.latency_time = time;
  70                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  71                 }
  72         }
  73         else
  74         {
  75                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  76                 WriteByte(MSG_BROADCAST, this.cnt);
  77                 WriteShort(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80         }
  81         this.cnt = (this.cnt + 1) % maxclients;
  82 }
  83 void PingPLReport_Spawn()
  84 {
  85         pingplreport = new_pure(pingplreport);
  86         setthink(pingplreport, PingPLReport_Think);
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap(entity this)
 109 {
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 this.nextthink = time;
 134         }
 135         else
 136         {
 137                 this.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         if(cvar_changes)
 149                 strunzone(cvar_changes);
 150         cvar_changes = string_null;
 151         if(cvar_purechanges)
 152                 strunzone(cvar_purechanges);
 153         cvar_purechanges = string_null;
 154         cvar_purechanges_count = 0;
 155
 156         h = buf_create();
 157         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 158         n = buf_getsize(h);
 159
 160         adding = true;
 161         pureadding = true;
 162
 163         for(i = 0; i < n; ++i)
 164         {
 165                 k = bufstr_get(h, i);
 166
 167 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 168 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 169 #define BADCVAR(p) if(k == p) continue
 170
 171                 // general excludes and namespaces for server admin used cvars
 172                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 173
 174                 // internal
 175                 BADPREFIX("csqc_");
 176                 BADPREFIX("cvar_check_");
 177                 BADCVAR("gamecfg");
 178                 BADCVAR("g_configversion");
 179                 BADCVAR("halflifebsp");
 180                 BADCVAR("sv_mapformat_is_quake2");
 181                 BADCVAR("sv_mapformat_is_quake3");
 182                 BADPREFIX("sv_world");
 183
 184                 // client
 185                 BADPREFIX("chase_");
 186                 BADPREFIX("cl_");
 187                 BADPREFIX("con_");
 188                 BADPREFIX("scoreboard_");
 189                 BADPREFIX("g_campaign");
 190                 BADPREFIX("g_waypointsprite_");
 191                 BADPREFIX("gl_");
 192                 BADPREFIX("joy");
 193                 BADPREFIX("hud_");
 194                 BADPREFIX("m_");
 195                 BADPREFIX("menu_");
 196                 BADPREFIX("net_slist_");
 197                 BADPREFIX("r_");
 198                 BADPREFIX("sbar_");
 199                 BADPREFIX("scr_");
 200                 BADPREFIX("snd_");
 201                 BADPREFIX("show");
 202                 BADPREFIX("sensitivity");
 203                 BADPREFIX("userbind");
 204                 BADPREFIX("v_");
 205                 BADPREFIX("vid_");
 206                 BADPREFIX("crosshair");
 207                 BADCVAR("mod_q3bsp_lightmapmergepower");
 208                 BADCVAR("mod_q3bsp_nolightmaps");
 209                 BADCVAR("fov");
 210                 BADCVAR("mastervolume");
 211                 BADCVAR("volume");
 212                 BADCVAR("bgmvolume");
 213                 BADCVAR("in_pitch_min");
 214                 BADCVAR("in_pitch_max");
 215
 216                 // private
 217                 BADCVAR("developer");
 218                 BADCVAR("log_dest_udp");
 219                 BADCVAR("net_address");
 220                 BADCVAR("net_address_ipv6");
 221                 BADCVAR("port");
 222                 BADCVAR("savedgamecfg");
 223                 BADCVAR("serverconfig");
 224                 BADCVAR("sv_autoscreenshot");
 225                 BADCVAR("sv_heartbeatperiod");
 226                 BADCVAR("sv_vote_master_password");
 227                 BADCVAR("sys_colortranslation");
 228                 BADCVAR("sys_specialcharactertranslation");
 229                 BADCVAR("timeformat");
 230                 BADCVAR("timestamps");
 231                 BADCVAR("g_require_stats");
 232                 BADPREFIX("developer_");
 233                 BADPREFIX("g_ban_");
 234                 BADPREFIX("g_banned_list");
 235                 BADPREFIX("g_require_stats_");
 236                 BADPREFIX("g_chat_flood_");
 237                 BADPREFIX("g_ghost_items");
 238                 BADPREFIX("g_playerstats_");
 239                 BADPREFIX("g_voice_flood_");
 240                 BADPREFIX("log_file");
 241                 BADPREFIX("quit_");
 242                 BADPREFIX("rcon_");
 243                 BADPREFIX("sv_allowdownloads");
 244                 BADPREFIX("sv_autodemo");
 245                 BADPREFIX("sv_curl_");
 246                 BADPREFIX("sv_eventlog");
 247                 BADPREFIX("sv_logscores_");
 248                 BADPREFIX("sv_master");
 249                 BADPREFIX("sv_weaponstats_");
 250                 BADPREFIX("sv_waypointsprite_");
 251                 BADCVAR("rescan_pending");
 252
 253                 // these can contain player IDs, so better hide
 254                 BADPREFIX("g_forced_team_");
 255                 BADCVAR("sv_muteban_list");
 256
 257                 // mapinfo
 258                 BADCVAR("fraglimit");
 259                 BADCVAR("g_arena");
 260                 BADCVAR("g_assault");
 261                 BADCVAR("g_ca");
 262                 BADCVAR("g_ca_teams");
 263                 BADCVAR("g_conquest");
 264                 BADCVAR("g_ctf");
 265                 BADCVAR("g_cts");
 266                 BADCVAR("g_dotc");
 267                 BADCVAR("g_dm");
 268                 BADCVAR("g_domination");
 269                 BADCVAR("g_domination_default_teams");
 270                 BADCVAR("g_freezetag");
 271                 BADCVAR("g_freezetag_teams");
 272                 BADCVAR("g_invasion_teams");
 273                 BADCVAR("g_jailbreak");
 274                 BADCVAR("g_jailbreak_teams");
 275                 BADCVAR("g_keepaway");
 276                 BADCVAR("g_keyhunt");
 277                 BADCVAR("g_keyhunt_teams");
 278                 BADCVAR("g_lms");
 279                 BADCVAR("g_nexball");
 280                 BADCVAR("g_onslaught");
 281                 BADCVAR("g_race");
 282                 BADCVAR("g_race_laps_limit");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_race_qualifying_timelimit_override");
 285                 BADCVAR("g_runematch");
 286                 BADCVAR("g_snafu");
 287                 BADCVAR("g_tdm");
 288                 BADCVAR("g_tdm_teams");
 289                 BADCVAR("g_vip");
 290                 BADCVAR("leadlimit");
 291                 BADCVAR("nextmap");
 292                 BADCVAR("teamplay");
 293                 BADCVAR("timelimit");
 294                 BADCVAR("g_mapinfo_ignore_warnings");
 295
 296                 // long
 297                 BADCVAR("hostname");
 298                 BADCVAR("g_maplist");
 299                 BADCVAR("g_maplist_mostrecent");
 300                 BADCVAR("sv_motd");
 301
 302                 v = cvar_string(k);
 303                 d = cvar_defstring(k);
 304                 if(v == d)
 305                         continue;
 306
 307                 if(adding)
 308                 {
 309                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 310                         if(strlen(cvar_changes) > 16384)
 311                         {
 312                                 cvar_changes = "// too many settings have been changed to show them here\n";
 313                                 adding = 0;
 314                         }
 315                 }
 316
 317                 // now check if the changes are actually gameplay relevant
 318
 319                 // does nothing gameplay relevant
 320                 BADCVAR("captureleadlimit_override");
 321                 BADCVAR("condump_stripcolors");
 322                 BADCVAR("gameversion");
 323                 BADCVAR("g_allow_oldvortexbeam");
 324                 BADCVAR("g_balance_kill_delay");
 325                 BADCVAR("g_buffs_pickup_anyway");
 326                 BADCVAR("g_buffs_randomize");
 327                 BADCVAR("g_campcheck_distance");
 328                 BADCVAR("g_ca_point_leadlimit");
 329                 BADCVAR("g_ca_point_limit");
 330                 BADCVAR("g_ctf_captimerecord_always");
 331                 BADCVAR("g_ctf_flag_glowtrails");
 332                 BADCVAR("g_ctf_flag_pickup_verbosename");
 333                 BADCVAR("g_domination_point_leadlimit");
 334                 BADCVAR("g_forced_respawn");
 335                 BADCVAR("g_freezetag_point_leadlimit");
 336                 BADCVAR("g_freezetag_point_limit");
 337                 BADCVAR("g_hats");
 338                 BADCVAR("g_invasion_point_limit");
 339                 BADCVAR("g_jump_grunt");
 340                 BADCVAR("g_keyhunt_point_leadlimit");
 341                 BADCVAR("g_nexball_goalleadlimit");
 342                 BADCVAR("g_new_toys_use_pickupsound");
 343                 BADCVAR("g_physics_predictall");
 344                 BADCVAR("g_piggyback");
 345                 BADCVAR("g_playerclip_collisions");
 346                 BADCVAR("g_tdm_point_leadlimit");
 347                 BADCVAR("g_tdm_point_limit");
 348                 BADCVAR("leadlimit_and_fraglimit");
 349                 BADCVAR("leadlimit_override");
 350                 BADCVAR("pausable");
 351                 BADCVAR("sv_checkforpacketsduringsleep");
 352                 BADCVAR("sv_damagetext");
 353                 BADCVAR("sv_db_saveasdump");
 354                 BADCVAR("sv_intermission_cdtrack");
 355                 BADCVAR("sv_minigames");
 356                 BADCVAR("sv_namechangetimer");
 357                 BADCVAR("sv_precacheplayermodels");
 358                 BADCVAR("sv_stepheight");
 359                 BADCVAR("sv_timeout");
 360                 BADCVAR("sv_weapons_modeloverride");
 361                 BADPREFIX("crypto_");
 362                 BADPREFIX("gameversion_");
 363                 BADPREFIX("g_chat_");
 364                 BADPREFIX("g_ctf_captimerecord_");
 365                 BADPREFIX("g_maplist_");
 366                 BADPREFIX("g_mod_");
 367                 BADPREFIX("g_respawn_");
 368                 BADPREFIX("net_");
 369                 BADPREFIX("notification_");
 370                 BADPREFIX("prvm_");
 371                 BADPREFIX("skill_");
 372                 BADPREFIX("sv_allow_");
 373                 BADPREFIX("sv_cullentities_");
 374                 BADPREFIX("sv_maxidle_");
 375                 BADPREFIX("sv_minigames_");
 376                 BADPREFIX("sv_radio_");
 377                 BADPREFIX("sv_timeout_");
 378                 BADPREFIX("sv_vote_");
 379                 BADPREFIX("timelimit_");
 380
 381                 // allowed changes to server admins (please sync this to server.cfg)
 382                 // vi commands:
 383                 //   :/"impure"/,$d
 384                 //   :g!,^\/\/[^ /],d
 385                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 386                 //   :%!sort
 387                 // yes, this does contain some redundant stuff, don't really care
 388                 BADCVAR("bot_config_file");
 389                 BADCVAR("bot_number");
 390                 BADCVAR("bot_prefix");
 391                 BADCVAR("bot_suffix");
 392                 BADCVAR("capturelimit_override");
 393                 BADCVAR("fraglimit_override");
 394                 BADCVAR("gametype");
 395                 BADCVAR("g_antilag");
 396                 BADCVAR("g_balance_teams");
 397                 BADCVAR("g_balance_teams_prevent_imbalance");
 398                 BADCVAR("g_balance_teams_scorefactor");
 399                 BADCVAR("g_ban_sync_trusted_servers");
 400                 BADCVAR("g_ban_sync_uri");
 401                 BADCVAR("g_buffs");
 402                 BADCVAR("g_ca_teams_override");
 403                 BADCVAR("g_ctf_ignore_frags");
 404                 BADCVAR("g_ctf_leaderboard");
 405                 BADCVAR("g_domination_point_limit");
 406                 BADCVAR("g_domination_teams_override");
 407                 BADCVAR("g_freezetag_teams_override");
 408                 BADCVAR("g_friendlyfire");
 409                 BADCVAR("g_fullbrightitems");
 410                 BADCVAR("g_fullbrightplayers");
 411                 BADCVAR("g_keyhunt_point_limit");
 412                 BADCVAR("g_keyhunt_teams_override");
 413                 BADCVAR("g_lms_lives_override");
 414                 BADCVAR("g_maplist");
 415                 BADCVAR("g_maxplayers");
 416                 BADCVAR("g_mirrordamage");
 417                 BADCVAR("g_nexball_goallimit");
 418                 BADCVAR("g_norecoil");
 419                 BADCVAR("g_physics_clientselect");
 420                 BADCVAR("g_pinata");
 421                 BADCVAR("g_powerups");
 422                 BADCVAR("g_spawnshieldtime");
 423                 BADCVAR("g_start_delay");
 424                 BADCVAR("g_superspectate");
 425                 BADCVAR("g_tdm_teams_override");
 426                 BADCVAR("g_warmup");
 427                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 428                 BADCVAR("hostname");
 429                 BADCVAR("log_file");
 430                 BADCVAR("maxplayers");
 431                 BADCVAR("minplayers");
 432                 BADCVAR("net_address");
 433                 BADCVAR("port");
 434                 BADCVAR("rcon_password");
 435                 BADCVAR("rcon_restricted_commands");
 436                 BADCVAR("rcon_restricted_password");
 437                 BADCVAR("skill");
 438                 BADCVAR("sv_adminnick");
 439                 BADCVAR("sv_autoscreenshot");
 440                 BADCVAR("sv_autotaunt");
 441                 BADCVAR("sv_curl_defaulturl");
 442                 BADCVAR("sv_defaultcharacter");
 443                 BADCVAR("sv_defaultcharacterskin");
 444                 BADCVAR("sv_defaultplayercolors");
 445                 BADCVAR("sv_defaultplayermodel");
 446                 BADCVAR("sv_defaultplayerskin");
 447                 BADCVAR("sv_maxidle");
 448                 BADCVAR("sv_maxrate");
 449                 BADCVAR("sv_motd");
 450                 BADCVAR("sv_public");
 451                 BADCVAR("sv_ready_restart");
 452                 BADCVAR("sv_status_privacy");
 453                 BADCVAR("sv_taunt");
 454                 BADCVAR("sv_vote_call");
 455                 BADCVAR("sv_vote_commands");
 456                 BADCVAR("sv_vote_majority_factor");
 457                 BADCVAR("sv_vote_master");
 458                 BADCVAR("sv_vote_master_commands");
 459                 BADCVAR("sv_vote_master_password");
 460                 BADCVAR("sv_vote_simple_majority_factor");
 461                 BADCVAR("teamplay_mode");
 462                 BADCVAR("timelimit_override");
 463                 BADPREFIX("g_warmup_");
 464                 BADPREFIX("sv_ready_restart_");
 465
 466                 // mutators that announce themselves properly to the server browser
 467                 BADCVAR("g_instagib");
 468                 BADCVAR("g_new_toys");
 469                 BADCVAR("g_nix");
 470                 BADCVAR("g_grappling_hook");
 471                 BADCVAR("g_jetpack");
 472
 473 #undef BADPRESUFFIX
 474 #undef BADPREFIX
 475 #undef BADCVAR
 476
 477                 if(pureadding)
 478                 {
 479                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 480                         if(strlen(cvar_purechanges) > 16384)
 481                         {
 482                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 483                                 pureadding = 0;
 484                         }
 485                 }
 486                 ++cvar_purechanges_count;
 487                 // WARNING: this variable is used for the server list
 488                 // NEVER dare to skip this code!
 489                 // Hacks to intentionally appearing as "pure server" even though you DO have
 490                 // modified settings may be punished by removal from the server list.
 491                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 492                 // though.
 493         }
 494         buf_del(h);
 495         if(cvar_changes == "")
 496                 cvar_changes = "// this server runs at default server settings\n";
 497         else
 498                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 499         cvar_changes = strzone(cvar_changes);
 500         if(cvar_purechanges == "")
 501                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 502         else
 503                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 504         cvar_purechanges = strzone(cvar_purechanges);
 505 }
 506
 507 void detect_maptype()
 508 {
 509 #if 0
 510         vector o, v;
 511         float i;
 512
 513         for (;;)
 514         {
 515                 o = world.mins;
 516                 o.x += random() * (world.maxs.x - world.mins.x);
 517                 o.y += random() * (world.maxs.y - world.mins.y);
 518                 o.z += random() * (world.maxs.z - world.mins.z);
 519
 520                 tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 32768', MOVE_WORLDONLY, NULL);
 521                 if(trace_fraction == 1)
 522                         continue;
 523
 524                 v = trace_endpos;
 525
 526                 for(i = 0; i < 64; i += 4)
 527                 {
 528                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, NULL);
 529         if(trace_fraction == 1)
 530                 continue;
 531                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 532                 }
 533
 534                 break;
 535         }
 536 #endif
 537 }
 538
 539 entity randomseed;
 540 bool RandomSeed_Send(entity this, entity to, int sf)
 541 {
 542         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 543         WriteShort(MSG_ENTITY, this.cnt);
 544         return true;
 545 }
 546 void RandomSeed_Think(entity this)
 547 {
 548         this.cnt = bound(0, floor(random() * 65536), 65535);
 549         this.nextthink = time + 5;
 550
 551         this.SendFlags |= 1;
 552 }
 553 void RandomSeed_Spawn()
 554 {
 555         randomseed = new_pure(randomseed);
 556         setthink(randomseed, RandomSeed_Think);
 557         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 558
 559         getthink(randomseed)(randomseed); // sets random seed and nextthink
 560 }
 561
 562 spawnfunc(__init_dedicated_server)
 563 {
 564         // handler for _init/_init map (only for dedicated server initialization)
 565
 566         world_initialized = -1; // don't complain
 567         cvar = cvar_normal;
 568         cvar_string = cvar_string_normal;
 569         cvar_set = cvar_set_normal;
 570
 571         delete_fn = remove_unsafely;
 572
 573         entity e = spawn();
 574         setthink(e, GotoFirstMap);
 575         e.nextthink = time; // this is usually 1 at this point
 576
 577         e = new(info_player_deathmatch);  // safeguard against player joining
 578
 579         this.classname = "worldspawn"; // safeguard against various stuff ;)
 580
 581         // needs to be done so early because of the constants they create
 582         static_init();
 583         static_init_late();
 584         static_init_precache();
 585
 586         IL_PUSH(g_spawnpoints, e); // just incase
 587
 588         MapInfo_Enumerate();
 589         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 590 }
 591
 592 void __init_dedicated_server_shutdown() {
 593         MapInfo_Shutdown();
 594 }
 595
 596 void SetLimits(int fraglimit_override, int leadlimit_override, float timelimit_override, float qualifying_override)
 597 {
 598         if(!autocvar_g_campaign)
 599         {
 600                 if(fraglimit_override >= 0) cvar_set("fraglimit", ftos(fraglimit_override));
 601                 if(timelimit_override >= 0) cvar_set("timelimit", ftos(timelimit_override));
 602                 if(leadlimit_override >= 0) cvar_set("leadlimit", ftos(leadlimit_override));
 603                 if(qualifying_override >= 0) cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 604         }
 605         limits_are_set = true;
 606 }
 607
 608 void Map_MarkAsRecent(string m);
 609 float world_already_spawned;
 610 void Nagger_Init();
 611 void ClientInit_Spawn();
 612 void WeaponStats_Init();
 613 void WeaponStats_Shutdown();
 614 spawnfunc(worldspawn)
 615 {
 616         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 617
 618     bool wantrestart = false;
 619         {
 620                 if (!server_is_dedicated)
 621                 {
 622                         // force unloading of server pk3 files when starting a listen server
 623                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 624                         // restore csqc_progname too
 625                         string expect = "csprogs.dat";
 626                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 627                         cvar_set_normal("csqc_progname", expect);
 628                 }
 629                 else
 630                 {
 631                         // Try to use versioned csprogs from pk3
 632                         // Only ever use versioned csprogs.dat files on dedicated servers;
 633                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 634                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 635                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 636                         string select = "csprogs.dat";
 637                         if (fexists(pk3csprogs)) select = pk3csprogs;
 638                         if (cvar_string_normal("csqc_progname") != select)
 639                         {
 640                                 cvar_set_normal("csqc_progname", select);
 641                                 wantrestart = true;
 642                         }
 643                         // Check for updates on startup
 644                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 645                         int sentinel = fopen("progs.txt", FILE_READ);
 646                         if (sentinel >= 0)
 647                         {
 648                                 string switchversion = fgets(sentinel);
 649                                 fclose(sentinel);
 650                                 if (switchversion != "" && switchversion != WATERMARK)
 651                                 {
 652                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s\n", switchversion);
 653                                         // if it doesn't exist, assume either:
 654                                         //   a) the current program was overwritten
 655                                         //   b) this is a client only update
 656                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 657                                         if (fexists(newprogs))
 658                                         {
 659                                                 cvar_set_normal("sv_progs", newprogs);
 660                                                 wantrestart = true;
 661                                         }
 662                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 663                                         if (fexists(newcsprogs))
 664                                         {
 665                                                 cvar_set_normal("csqc_progname", newcsprogs);
 666                                                 wantrestart = true;
 667                                         }
 668                                 }
 669                         }
 670                 }
 671                 if (wantrestart)
 672                 {
 673                         LOG_INFOF("Restart requested\n");
 674                         changelevel(mapname);
 675                         // let initialization continue, shutdown depends on it
 676                 }
 677         }
 678
 679         cvar = cvar_normal;
 680         cvar_string = cvar_string_normal;
 681         cvar_set = cvar_set_normal;
 682
 683         if(world_already_spawned)
 684                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 685         world_already_spawned = true;
 686
 687         delete_fn = remove_safely; // during spawning, watch what you remove!
 688
 689         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 690
 691         maxclients = 0;
 692         for (entity head = nextent(NULL); head; head = nextent(head))
 693         {
 694                 ++maxclients;
 695         }
 696
 697         // needs to be done so early because of the constants they create
 698         static_init();
 699
 700         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 701
 702         TemporaryDB = db_create();
 703
 704         // 0 normal
 705         lightstyle(0, "m");
 706
 707         // 1 FLICKER (first variety)
 708         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 709
 710         // 2 SLOW STRONG PULSE
 711         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 712
 713         // 3 CANDLE (first variety)
 714         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 715
 716         // 4 FAST STROBE
 717         lightstyle(4, "mamamamamama");
 718
 719         // 5 GENTLE PULSE 1
 720         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 721
 722         // 6 FLICKER (second variety)
 723         lightstyle(6, "nmonqnmomnmomomno");
 724
 725         // 7 CANDLE (second variety)
 726         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 727
 728         // 8 CANDLE (third variety)
 729         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 730
 731         // 9 SLOW STROBE (fourth variety)
 732         lightstyle(9, "aaaaaaaazzzzzzzz");
 733
 734         // 10 FLUORESCENT FLICKER
 735         lightstyle(10, "mmamammmmammamamaaamammma");
 736
 737         // 11 SLOW PULSE NOT FADE TO BLACK
 738         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 739
 740         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 741
 742         // 63 testing
 743         lightstyle(63, "a");
 744
 745         if(autocvar_g_campaign)
 746                 CampaignPreInit();
 747
 748         Map_MarkAsRecent(mapname);
 749
 750         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 751
 752         InitGameplayMode();
 753         static_init_late();
 754         static_init_precache();
 755         readlevelcvars();
 756         GrappleHookInit();
 757
 758         if(!limits_are_set)
 759                 SetLimits(autocvar_fraglimit_override, autocvar_leadlimit_override, autocvar_timelimit_override, -1);
 760
 761         if(warmup_limit == 0)
 762                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 763
 764         player_count = 0;
 765         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 766         if(bot_waypoints_for_items == 1)
 767                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 768                         bot_waypoints_for_items = 0;
 769
 770         precache();
 771
 772         WaypointSprite_Init();
 773
 774         GameLogInit(); // prepare everything
 775         // NOTE for matchid:
 776         // changing the logic generating it is okay. But:
 777         // it HAS to stay <= 64 chars
 778         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 779         if(autocvar_sv_eventlog)
 780         {
 781                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 782                 matchid = strzone(s);
 783
 784                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 785                 s = ":gameinfo:mutators:LIST";
 786
 787                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 788                 s = M_ARGV(0, string);
 789
 790                 // initialiation stuff, not good in the mutator system
 791                 if(!autocvar_g_use_ammunition)
 792                         s = strcat(s, ":no_use_ammunition");
 793
 794                 // initialiation stuff, not good in the mutator system
 795                 if(autocvar_g_pickup_items == 0)
 796                         s = strcat(s, ":no_pickup_items");
 797                 if(autocvar_g_pickup_items > 0)
 798                         s = strcat(s, ":pickup_items");
 799
 800                 // initialiation stuff, not good in the mutator system
 801                 if(autocvar_g_weaponarena != "0")
 802                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 803
 804                 // TODO to mutator system
 805                 if(autocvar_g_norecoil)
 806                         s = strcat(s, ":norecoil");
 807
 808                 // TODO to mutator system
 809                 if(autocvar_g_powerups == 0)
 810                         s = strcat(s, ":no_powerups");
 811                 if(autocvar_g_powerups > 0)
 812                         s = strcat(s, ":powerups");
 813
 814                 GameLogEcho(s);
 815                 GameLogEcho(":gameinfo:end");
 816         }
 817         else
 818                 matchid = strzone(ftos(random()));
 819
 820         cvar_set("nextmap", "");
 821
 822         SetDefaultAlpha();
 823
 824         if(autocvar_g_campaign)
 825                 CampaignPostInit();
 826
 827         Ban_LoadBans();
 828
 829         MapInfo_Enumerate();
 830         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 831
 832         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 833         {
 834                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 835                 if(fd != -1)
 836                 {
 837                         string s;
 838                         while((s = fgets(fd)))
 839                         {
 840                                 int l = tokenize_console(s);
 841                                 if(l < 2)
 842                                         continue;
 843                                 if(argv(0) == "cd")
 844                                 {
 845                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 846                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 847                                 }
 848                                 else if(argv(0) == "fog")
 849                                 {
 850                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 851                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 852                                 }
 853                                 else if(argv(0) == "set")
 854                                 {
 855                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 856                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 857                                 }
 858                                 else if(argv(0) != "//")
 859                                 {
 860                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 861                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 862                                 }
 863                         }
 864                         fclose(fd);
 865                 }
 866         }
 867
 868         WeaponStats_Init();
 869
 870         Nagger_Init();
 871
 872         next_pingtime = time + 5;
 873
 874         detect_maptype();
 875
 876         // set up information replies for clients and server to use
 877         maplist_reply = strzone(getmaplist());
 878         lsmaps_reply = strzone(getlsmaps());
 879         monsterlist_reply = strzone(getmonsterlist());
 880         for(int i = 0; i < 10; ++i)
 881         {
 882                 string s = getrecords(i);
 883                 if (s)
 884                         records_reply[i] = strzone(s);
 885         }
 886         ladder_reply = strzone(getladder());
 887         rankings_reply = strzone(getrankings());
 888
 889         // begin other init
 890         ClientInit_Spawn();
 891         RandomSeed_Spawn();
 892         PingPLReport_Spawn();
 893
 894         CheatInit();
 895
 896         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 897
 898         // fill sv_curl_serverpackages from .serverpackage files
 899         if (autocvar_sv_curl_serverpackages_auto)
 900         {
 901                 string s = "csprogs-" WATERMARK ".txt";
 902                 // remove automatically managed files from the list to prevent duplicates
 903                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 904                 {
 905                         string pkg = argv(i);
 906                         if (startsWith(pkg, "csprogs-")) continue;
 907                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 908                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 909                         s = cons(s, pkg);
 910                 }
 911                 // add automatically managed files to the list
 912                 #define X(match) MACRO_BEGIN { \
 913                         int fd = search_begin(match, true, false); \
 914                         if (fd >= 0) \
 915                         { \
 916                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 917                                 { \
 918                                         s = cons(s, search_getfilename(fd, i)); \
 919                                 } \
 920                                 search_end(fd); \
 921                         } \
 922                 } MACRO_END
 923                 X("*-serverpackage.txt");
 924                 X("*.serverpackage");
 925                 #undef X
 926                 cvar_set("sv_curl_serverpackages", s);
 927         }
 928
 929         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 930         modname = "Xonotic";
 931         // physics/balance/config changes that count as mod
 932         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 933                 modname = cvar_string("g_mod_physics");
 934         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 935                 modname = cvar_string("g_mod_balance");
 936         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 937                 modname = cvar_string("g_mod_config");
 938         // extra mutators that deserve to count as mod
 939         MUTATOR_CALLHOOK(SetModname, modname);
 940         modname = M_ARGV(0, string);
 941
 942         // save it for later
 943         modname = strzone(modname);
 944
 945         WinningConditionHelper(this); // set worldstatus
 946
 947         world_initialized = 1;
 948 }
 949
 950 spawnfunc(light)
 951 {
 952         //makestatic (this); // Who the f___ did that?
 953         delete(this);
 954 }
 955
 956 string GetGametype()
 957 {
 958         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 959 }
 960
 961 string GetMapname()
 962 {
 963         return mapname;
 964 }
 965
 966 float Map_Count, Map_Current;
 967 string Map_Current_Name;
 968
 969 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 970 float GetMaplistPosition()
 971 {
 972         float pos, idx;
 973         string map;
 974
 975         map = GetMapname();
 976         idx = autocvar_g_maplist_index;
 977
 978         if(idx >= 0)
 979                 if(idx < Map_Count)
 980                         if(map == argv(idx))
 981                                 return idx;
 982
 983         for(pos = 0; pos < Map_Count; ++pos)
 984                 if(map == argv(pos))
 985                         return pos;
 986
 987         // resume normal maplist rotation if current map is not in g_maplist
 988         return idx;
 989 }
 990
 991 float MapHasRightSize(string map)
 992 {
 993         float fh;
 994         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 995         if(autocvar_g_maplist_check_waypoints)
 996         {
 997                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 998                 if(!fexists(strcat("maps/", map, ".waypoints")))
 999                 {
1000                         LOG_TRACE(": no waypoints");
1001                         return false;
1002                 }
1003                 LOG_TRACE(": has waypoints");
1004         }
1005
1006         // open map size restriction file
1007         LOG_TRACE("opensize "); LOG_TRACE(map);
1008         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1009         if(fh >= 0)
1010         {
1011                 float mapmin, mapmax;
1012                 LOG_TRACE(": ok, ");
1013                 mapmin = stof(fgets(fh));
1014                 mapmax = stof(fgets(fh));
1015                 fclose(fh);
1016                 if(player_count < mapmin)
1017                 {
1018                         LOG_TRACE("not enough");
1019                         return false;
1020                 }
1021                 if(player_count > mapmax)
1022                 {
1023                         LOG_TRACE("too many");
1024                         return false;
1025                 }
1026                 LOG_TRACE("right size");
1027                 return true;
1028         }
1029         LOG_TRACE(": not found");
1030         return true;
1031 }
1032
1033 string Map_Filename(float position)
1034 {
1035         return strcat("maps/", argv(position), ".bsp");
1036 }
1037
1038 void Map_MarkAsRecent(string m)
1039 {
1040         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1041 }
1042
1043 float Map_IsRecent(string m)
1044 {
1045         return strhasword(autocvar_g_maplist_mostrecent, m);
1046 }
1047
1048 float Map_Check(float position, float pass)
1049 {
1050         string filename;
1051         string map_next;
1052         map_next = argv(position);
1053         if(pass <= 1)
1054         {
1055                 if(Map_IsRecent(map_next))
1056                         return 0;
1057         }
1058         filename = Map_Filename(position);
1059         if(MapInfo_CheckMap(map_next))
1060         {
1061                 if(pass == 2)
1062                         return 1;
1063                 if(MapHasRightSize(map_next))
1064                         return 1;
1065                 return 0;
1066         }
1067         else
1068                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1069
1070         return 0;
1071 }
1072
1073 void Map_Goto_SetStr(string nextmapname)
1074 {
1075         if(getmapname_stored != "")
1076                 strunzone(getmapname_stored);
1077         if(nextmapname == "")
1078                 getmapname_stored = "";
1079         else
1080                 getmapname_stored = strzone(nextmapname);
1081 }
1082
1083 void Map_Goto_SetFloat(float position)
1084 {
1085         cvar_set("g_maplist_index", ftos(position));
1086         Map_Goto_SetStr(argv(position));
1087 }
1088
1089 void Map_Goto(float reinit)
1090 {
1091         MapInfo_LoadMap(getmapname_stored, reinit);
1092 }
1093
1094 // return codes of map selectors:
1095 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1096 //   -2 = permanent failure
1097 float() MaplistMethod_Iterate = // usual method
1098 {
1099         float pass, i;
1100
1101         LOG_TRACE("Trying MaplistMethod_Iterate");
1102
1103         for(pass = 1; pass <= 2; ++pass)
1104         {
1105                 for(i = 1; i < Map_Count; ++i)
1106                 {
1107                         float mapindex;
1108                         mapindex = (i + Map_Current) % Map_Count;
1109                         if(Map_Check(mapindex, pass))
1110                                 return mapindex;
1111                 }
1112         }
1113         return -1;
1114 }
1115
1116 float() MaplistMethod_Repeat = // fallback method
1117 {
1118         LOG_TRACE("Trying MaplistMethod_Repeat");
1119
1120         if(Map_Check(Map_Current, 2))
1121                 return Map_Current;
1122         return -2;
1123 }
1124
1125 float() MaplistMethod_Random = // random map selection
1126 {
1127         float i, imax;
1128
1129         LOG_TRACE("Trying MaplistMethod_Random");
1130
1131         imax = 42;
1132
1133         for(i = 0; i <= imax; ++i)
1134         {
1135                 float mapindex;
1136                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1137                 if(Map_Check(mapindex, 1))
1138                         return mapindex;
1139         }
1140         return -1;
1141 }
1142
1143 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1144 // the exponent sets a bias on the map selection:
1145 // the higher the exponent, the less likely "shortly repeated" same maps are
1146 {
1147         float i, j, imax, insertpos;
1148
1149         LOG_TRACE("Trying MaplistMethod_Shuffle");
1150
1151         imax = 42;
1152
1153         for(i = 0; i <= imax; ++i)
1154         {
1155                 string newlist;
1156
1157                 // now reinsert this at another position
1158                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1159                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1160                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1161                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1162
1163                 // insert the current map there
1164                 newlist = "";
1165                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1166                         newlist = strcat(newlist, " ", argv(j));
1167                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1168                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1169                         newlist = strcat(newlist, " ", argv(j));
1170                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1171                 cvar_set("g_maplist", newlist);
1172                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1173
1174                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1175                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1176                 if(Map_Check(Map_Current, 1))
1177                         return Map_Current;
1178         }
1179         return -1;
1180 }
1181
1182 void Maplist_Init()
1183 {
1184         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1185         float i;
1186         for (i = 0; i < Map_Count; ++i)
1187                 if (Map_Check(i, 2))
1188                         break;
1189         if (i == Map_Count)
1190         {
1191                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1192                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1193                 if(autocvar_g_maplist_shuffle)
1194                         ShuffleMaplist();
1195                 localcmd("\nmenu_cmd sync\n");
1196                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1197         }
1198         if(Map_Count == 0)
1199                 error("empty maplist, cannot select a new map");
1200         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1201
1202         if(Map_Current_Name)
1203                 strunzone(Map_Current_Name);
1204         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1205         // this may or may not be correct, but who cares, in the worst case a map
1206         // isn't chosen in the first pass that should have been
1207 }
1208
1209 string GetNextMap()
1210 {
1211         float nextMap;
1212
1213         Maplist_Init();
1214         nextMap = -1;
1215
1216         if(nextMap == -1)
1217                 if(autocvar_g_maplist_shuffle > 0)
1218                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1219
1220         if(nextMap == -1)
1221                 if(autocvar_g_maplist_selectrandom)
1222                         nextMap = MaplistMethod_Random();
1223
1224         if(nextMap == -1)
1225                 nextMap = MaplistMethod_Iterate();
1226
1227         if(nextMap == -1)
1228                 nextMap = MaplistMethod_Repeat();
1229
1230         if(nextMap >= 0)
1231         {
1232                 Map_Goto_SetFloat(nextMap);
1233                 return getmapname_stored;
1234         }
1235
1236         return "";
1237 }
1238
1239 float DoNextMapOverride(float reinit)
1240 {
1241         if(autocvar_g_campaign)
1242         {
1243                 CampaignPostIntermission();
1244                 alreadychangedlevel = true;
1245                 return true;
1246         }
1247         if(autocvar_quit_when_empty)
1248         {
1249                 if(player_count <= currentbots)
1250                 {
1251                         localcmd("quit\n");
1252                         alreadychangedlevel = true;
1253                         return true;
1254                 }
1255         }
1256         if(autocvar_quit_and_redirect != "")
1257         {
1258                 redirection_target = strzone(autocvar_quit_and_redirect);
1259                 alreadychangedlevel = true;
1260                 return true;
1261         }
1262         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1263         {
1264                 localcmd("restart\n");
1265                 alreadychangedlevel = true;
1266                 return true;
1267         }
1268         if(autocvar_nextmap != "")
1269         {
1270                 string m;
1271                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1272                 cvar_set("nextmap",m);
1273
1274                 if(!m || gametypevote)
1275                         return false;
1276                 if(autocvar_sv_vote_gametype)
1277                 {
1278                         Map_Goto_SetStr(m);
1279                         return false;
1280                 }
1281
1282                 if(MapInfo_CheckMap(m))
1283                 {
1284                         Map_Goto_SetStr(m);
1285                         Map_Goto(reinit);
1286                         alreadychangedlevel = true;
1287                         return true;
1288                 }
1289         }
1290         if(!reinit && autocvar_lastlevel)
1291         {
1292                 cvar_settemp_restore();
1293                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1294                 alreadychangedlevel = true;
1295                 return true;
1296         }
1297         return false;
1298 }
1299
1300 void GotoNextMap(float reinit)
1301 {
1302         //string nextmap;
1303         //float n, nummaps;
1304         //string s;
1305         if (alreadychangedlevel)
1306                 return;
1307         alreadychangedlevel = true;
1308
1309         string nextMap;
1310
1311         nextMap = GetNextMap();
1312         if(nextMap == "")
1313                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1314         Map_Goto(reinit);
1315 }
1316
1317
1318 /*
1319 ============
1320 IntermissionThink
1321
1322 When the player presses attack or jump, change to the next level
1323 ============
1324 */
1325 .float autoscreenshot;
1326 void IntermissionThink(entity this)
1327 {
1328         FixIntermissionClient(this);
1329
1330         float server_screenshot = (autocvar_sv_autoscreenshot && this.cvar_cl_autoscreenshot);
1331         float client_screenshot = (this.cvar_cl_autoscreenshot == 2);
1332
1333         if( (server_screenshot || client_screenshot)
1334                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1335         {
1336                 this.autoscreenshot = -1;
1337                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1338                 return;
1339         }
1340
1341         if (time < intermission_exittime)
1342                 return;
1343
1344         if(!mapvote_initialized)
1345                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1346                         return;
1347
1348         MapVote_Start();
1349 }
1350
1351 /*
1352 ============
1353 FindIntermission
1354
1355 Returns the entity to view from
1356 ============
1357 */
1358 /*
1359 entity FindIntermission()
1360 {
1361         local   entity spot;
1362         local   float cyc;
1363
1364 // look for info_intermission first
1365         spot = find(NULL, classname, "info_intermission");
1366         if (spot)
1367         {       // pick a random one
1368                 cyc = random() * 4;
1369                 while (cyc > 1)
1370                 {
1371                         spot = find(spot, classname, "info_intermission");
1372                         if (!spot)
1373                                 spot = find(spot, classname, "info_intermission");
1374                         cyc = cyc - 1;
1375                 }
1376                 return spot;
1377         }
1378
1379 // then look for the start position
1380         spot = find(NULL, classname, "info_player_start");
1381         if (spot)
1382                 return spot;
1383
1384 // testinfo_player_start is only found in regioned levels
1385         spot = find(NULL, classname, "testplayerstart");
1386         if (spot)
1387                 return spot;
1388
1389 // then look for the start position
1390         spot = find(NULL, classname, "info_player_deathmatch");
1391         if (spot)
1392                 return spot;
1393
1394         //objerror ("FindIntermission: no spot");
1395         return NULL;
1396 }
1397 */
1398
1399 /*
1400 ===============================================================================
1401
1402 RULES
1403
1404 ===============================================================================
1405 */
1406
1407 void DumpStats(float final)
1408 {
1409         float file;
1410         string s;
1411         float to_console;
1412         float to_eventlog;
1413         float to_file;
1414         float i;
1415
1416         to_console = autocvar_sv_logscores_console;
1417         to_eventlog = autocvar_sv_eventlog;
1418         to_file = autocvar_sv_logscores_file;
1419
1420         if(!final)
1421         {
1422                 to_console = true; // always print printstats replies
1423                 to_eventlog = false; // but never print them to the event log
1424         }
1425
1426         if(to_eventlog)
1427                 if(autocvar_sv_eventlog_console)
1428                         to_console = false; // otherwise we get the output twice
1429
1430         if(final)
1431                 s = ":scores:";
1432         else
1433                 s = ":status:";
1434         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1435
1436         if(to_console)
1437                 LOG_INFO(s, "\n");
1438         if(to_eventlog)
1439                 GameLogEcho(s);
1440
1441         file = -1;
1442         if(to_file)
1443         {
1444                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1445                 if(file == -1)
1446                         to_file = false;
1447                 else
1448                         fputs(file, strcat(s, "\n"));
1449         }
1450
1451         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1452         if(to_console)
1453                 LOG_INFO(s, "\n");
1454         if(to_eventlog)
1455                 GameLogEcho(s);
1456         if(to_file)
1457                 fputs(file, strcat(s, "\n"));
1458
1459         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), LAMBDA(
1460                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1461                 s = strcat(s, ftos(rint(time - it.jointime)), ":");
1462                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1463                         s = strcat(s, ftos(it.team), ":");
1464                 else
1465                         s = strcat(s, "spectator:");
1466
1467                 if(to_console)
1468                         LOG_INFO(s, playername(it, false), "\n");
1469                 if(to_eventlog)
1470                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1471                 if(to_file)
1472                         fputs(file, strcat(s, playername(it, false), "\n"));
1473         ));
1474
1475         if(teamplay)
1476         {
1477                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1478                 if(to_console)
1479                         LOG_INFO(s, "\n");
1480                 if(to_eventlog)
1481                         GameLogEcho(s);
1482                 if(to_file)
1483                         fputs(file, strcat(s, "\n"));
1484
1485                 for(i = 1; i < 16; ++i)
1486                 {
1487                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1488                         s = strcat(s, ":", ftos(i));
1489                         if(to_console)
1490                                 LOG_INFO(s, "\n");
1491                         if(to_eventlog)
1492                                 GameLogEcho(s);
1493                         if(to_file)
1494                                 fputs(file, strcat(s, "\n"));
1495                 }
1496         }
1497
1498         if(to_console)
1499                 LOG_INFO(":end\n");
1500         if(to_eventlog)
1501                 GameLogEcho(":end");
1502         if(to_file)
1503         {
1504                 fputs(file, ":end\n");
1505                 fclose(file);
1506         }
1507 }
1508
1509 void FixIntermissionClient(entity e)
1510 {
1511         if(!e.autoscreenshot) // initial call
1512         {
1513                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1514                 e.health = -2342;
1515                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1516                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1517                 {
1518                     .entity weaponentity = weaponentities[slot];
1519                         if(e.(weaponentity))
1520                         {
1521                                 e.(weaponentity).effects = EF_NODRAW;
1522                                 if (e.(weaponentity).weaponchild)
1523                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1524                         }
1525                 }
1526                 if(IS_REAL_CLIENT(e))
1527                 {
1528                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1529                         RandomSelection_Init();
1530                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, LAMBDA(
1531                                 RandomSelection_AddString(it, 1, 1);
1532                         ));
1533                         if (RandomSelection_chosen_string != "")
1534                         {
1535                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1536                         }
1537                         msg_entity = e;
1538                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1539                 }
1540         }
1541 }
1542
1543 /*
1544 go to the next level for deathmatch
1545 only called if a time or frag limit has expired
1546 */
1547 void NextLevel()
1548 {
1549         game_stopped = true;
1550         intermission_running = 1; // game over
1551
1552         // enforce a wait time before allowing changelevel
1553         if(player_count > 0)
1554                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1555         else
1556                 intermission_exittime = -1;
1557
1558         /*
1559         WriteByte (MSG_ALL, SVC_CDTRACK);
1560         WriteByte (MSG_ALL, 3);
1561         WriteByte (MSG_ALL, 3);
1562         // done in FixIntermission
1563         */
1564
1565         //pos = FindIntermission ();
1566
1567         VoteReset();
1568
1569         DumpStats(true);
1570
1571         // send statistics
1572         PlayerStats_GameReport(true);
1573         WeaponStats_Shutdown();
1574
1575         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1576
1577         if(autocvar_sv_eventlog)
1578                 GameLogEcho(":gameover");
1579
1580         GameLogClose();
1581
1582         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1583                 FixIntermissionClient(it);
1584                 if(it.winning)
1585                         bprint(playername(it, false), " ^7wins.\n");
1586         ));
1587
1588         target_music_kill();
1589
1590         if(autocvar_g_campaign)
1591                 CampaignPreIntermission();
1592
1593         MUTATOR_CALLHOOK(MatchEnd);
1594
1595         localcmd("\nsv_hook_gameend\n");
1596 }
1597
1598 /*
1599 ============
1600 CheckRules_Player
1601
1602 Exit deathmatch games upon conditions
1603 ============
1604 */
1605 void CheckRules_Player(entity this)
1606 {
1607         if (game_stopped) // someone else quit the game already
1608                 return;
1609
1610         if(!IS_DEAD(this))
1611                 this.play_time += frametime;
1612
1613         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1614         //   (div0: and that in CheckRules_World please)
1615 }
1616
1617
1618 float InitiateSuddenDeath()
1619 {
1620         // Check first whether normal overtimes could be added before initiating suddendeath mode
1621         // - for this timelimit_overtime needs to be >0 of course
1622         // - also check the winning condition calculated in the previous frame and only add normal overtime
1623         //   again, if at the point at which timelimit would be extended again, still no winner was found
1624         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1625         {
1626                 return 1; // need to call InitiateOvertime later
1627         }
1628         else
1629         {
1630                 if(!checkrules_suddendeathend)
1631                 {
1632                         if(autocvar_g_campaign)
1633                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1634                         else
1635                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1636                         if(g_race && !g_race_qualifying)
1637                                 race_StartCompleting();
1638                 }
1639                 return 0;
1640         }
1641 }
1642
1643 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1644 {
1645         ++checkrules_overtimesadded;
1646         //add one more overtime by simply extending the timelimit
1647         float tl;
1648         tl = autocvar_timelimit;
1649         tl += autocvar_timelimit_overtime;
1650         cvar_set("timelimit", ftos(tl));
1651
1652         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1653 }
1654
1655 float GetWinningCode(float fraglimitreached, float equality)
1656 {
1657         if(autocvar_g_campaign == 1)
1658                 if(fraglimitreached)
1659                         return WINNING_YES;
1660                 else
1661                         return WINNING_NO;
1662
1663         else
1664                 if(equality)
1665                         if(fraglimitreached)
1666                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1667                         else
1668                                 return WINNING_NEVER;
1669                 else
1670                         if(fraglimitreached)
1671                                 return WINNING_YES;
1672                         else
1673                                 return WINNING_NO;
1674 }
1675
1676 // set the .winning flag for exactly those players with a given field value
1677 void SetWinners(.float field, float value)
1678 {
1679         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = (it.(field) == value)));
1680 }
1681
1682 // set the .winning flag for those players with a given field value
1683 void AddWinners(.float field, float value)
1684 {
1685         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1686                 if(it.(field) == value)
1687                         it.winning = 1;
1688         ));
1689 }
1690
1691 // clear the .winning flags
1692 void ClearWinners()
1693 {
1694         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = 0));
1695 }
1696
1697 void ShuffleMaplist()
1698 {
1699         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1700 }
1701
1702 float leaderfrags;
1703 float WinningCondition_Scores(float limit, float leadlimit)
1704 {
1705         float limitreached;
1706
1707         // TODO make everything use THIS winning condition (except LMS)
1708         WinningConditionHelper(NULL);
1709
1710         if(teamplay)
1711         {
1712                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1713                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1714                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1715                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1716         }
1717
1718         ClearWinners();
1719         if(WinningConditionHelper_winner)
1720                 WinningConditionHelper_winner.winning = 1;
1721         if(WinningConditionHelper_winnerteam >= 0)
1722                 SetWinners(team, WinningConditionHelper_winnerteam);
1723
1724         if(WinningConditionHelper_lowerisbetter)
1725         {
1726                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1727                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1728                 limit = -limit;
1729         }
1730
1731         if(WinningConditionHelper_zeroisworst)
1732                 leadlimit = 0; // not supported in this mode
1733
1734         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1735         // these modes always score in increments of 1, thus this makes sense
1736         {
1737                 if(leaderfrags != WinningConditionHelper_topscore)
1738                 {
1739                         leaderfrags = WinningConditionHelper_topscore;
1740
1741                         if (limit)
1742                         if (leaderfrags == limit - 1)
1743                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1744                         else if (leaderfrags == limit - 2)
1745                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1746                         else if (leaderfrags == limit - 3)
1747                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1748                 }
1749         }
1750
1751         limitreached = false;
1752         if(limit)
1753                 if(WinningConditionHelper_topscore >= limit)
1754                         limitreached = true;
1755         if(leadlimit)
1756         {
1757                 float leadlimitreached;
1758                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1759                 if(autocvar_leadlimit_and_fraglimit)
1760                         limitreached = (limitreached && leadlimitreached);
1761                 else
1762                         limitreached = (limitreached || leadlimitreached);
1763         }
1764
1765         if(limit)
1766                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1767
1768         return GetWinningCode(
1769                 WinningConditionHelper_topscore && limitreached,
1770                 WinningConditionHelper_equality
1771         );
1772 }
1773
1774 float WinningCondition_RanOutOfSpawns()
1775 {
1776         if(have_team_spawns <= 0)
1777                 return WINNING_NO;
1778
1779         if(!autocvar_g_spawn_useallspawns)
1780                 return WINNING_NO;
1781
1782         if(!some_spawn_has_been_used)
1783                 return WINNING_NO;
1784
1785         team1_score = team2_score = team3_score = team4_score = 0;
1786
1787         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), LAMBDA(
1788                 switch(it.team)
1789                 {
1790                         case NUM_TEAM_1: team1_score = 1; break;
1791                         case NUM_TEAM_2: team2_score = 1; break;
1792                         case NUM_TEAM_3: team3_score = 1; break;
1793                         case NUM_TEAM_4: team4_score = 1; break;
1794                 }
1795         ));
1796
1797         IL_EACH(g_spawnpoints, true,
1798         {
1799                 switch(it.team)
1800                 {
1801                         case NUM_TEAM_1: team1_score = 1; break;
1802                         case NUM_TEAM_2: team2_score = 1; break;
1803                         case NUM_TEAM_3: team3_score = 1; break;
1804                         case NUM_TEAM_4: team4_score = 1; break;
1805                 }
1806         });
1807
1808         ClearWinners();
1809         if(team1_score + team2_score + team3_score + team4_score == 0)
1810         {
1811                 checkrules_equality = true;
1812                 return WINNING_YES;
1813         }
1814         else if(team1_score + team2_score + team3_score + team4_score == 1)
1815         {
1816                 float t, i;
1817                 if(team1_score)
1818                         t = NUM_TEAM_1;
1819                 else if(team2_score)
1820                         t = NUM_TEAM_2;
1821                 else if(team3_score)
1822                         t = NUM_TEAM_3;
1823                 else // if(team4_score)
1824                         t = NUM_TEAM_4;
1825                 CheckAllowedTeams(NULL);
1826                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1827                 {
1828                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1829                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1830                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1831                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1832                 }
1833
1834                 AddWinners(team, t);
1835                 return WINNING_YES;
1836         }
1837         else
1838                 return WINNING_NO;
1839 }
1840
1841 /*
1842 ============
1843 CheckRules_World
1844
1845 Exit deathmatch games upon conditions
1846 ============
1847 */
1848 void CheckRules_World()
1849 {
1850         float timelimit;
1851         float fraglimit;
1852         float leadlimit;
1853
1854         VoteThink();
1855         MapVote_Think();
1856
1857         SetDefaultAlpha();
1858
1859         if (intermission_running) // someone else quit the game already
1860         {
1861                 if(player_count == 0) // Nobody there? Then let's go to the next map
1862                         MapVote_Start();
1863                         // this will actually check the player count in the next frame
1864                         // again, but this shouldn't hurt
1865                 return;
1866         }
1867
1868         timelimit = autocvar_timelimit * 60;
1869         fraglimit = autocvar_fraglimit;
1870         leadlimit = autocvar_leadlimit;
1871
1872         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1873         {
1874                 if(timelimit > 0)
1875                         timelimit = 0; // timelimit is not made for warmup
1876                 if(fraglimit > 0)
1877                         fraglimit = 0; // no fraglimit for now
1878                 leadlimit = 0; // no leadlimit for now
1879         }
1880
1881         if(timelimit > 0)
1882         {
1883                 timelimit += game_starttime;
1884         }
1885         else if (timelimit < 0)
1886         {
1887                 // endmatch
1888                 NextLevel();
1889                 return;
1890         }
1891
1892         float wantovertime;
1893         wantovertime = 0;
1894
1895         if(timelimit > game_starttime)
1896                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1897         else
1898                 game_completion_ratio = 0;
1899
1900         if(checkrules_suddendeathend)
1901         {
1902                 if(!checkrules_suddendeathwarning)
1903                 {
1904                         checkrules_suddendeathwarning = true;
1905                         if(g_race && !g_race_qualifying)
1906                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1907                         else
1908                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1909                 }
1910         }
1911         else
1912         {
1913                 if (timelimit && time >= timelimit)
1914                 {
1915                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1916                         {
1917                                 float totalplayers;
1918                                 float playerswithlaps;
1919                                 float readyplayers;
1920                                 totalplayers = playerswithlaps = readyplayers = 0;
1921                                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1922                                         ++totalplayers;
1923                                         if(PlayerScore_Add(it, SP_RACE_FASTEST, 0))
1924                                                 ++playerswithlaps;
1925                                         if(it.ready)
1926                                                 ++readyplayers;
1927                                 ));
1928
1929                                 // at least 2 of the players have completed a lap: start the RACE
1930                                 // otherwise, the players should end the qualifying on their own
1931                                 if(readyplayers || playerswithlaps >= 2)
1932                                 {
1933                                         checkrules_suddendeathend = 0;
1934                                         ReadyRestart(); // go to race
1935                                         return;
1936                                 }
1937                                 else
1938                                         wantovertime |= InitiateSuddenDeath();
1939                         }
1940                         else
1941                                 wantovertime |= InitiateSuddenDeath();
1942                 }
1943         }
1944
1945         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1946         {
1947                 NextLevel();
1948                 return;
1949         }
1950
1951         int checkrules_status = WinningCondition_RanOutOfSpawns();
1952         if(checkrules_status == WINNING_YES)
1953                 bprint("Hey! Someone ran out of spawns!\n");
1954         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1955                 checkrules_status = M_ARGV(0, float);
1956         else
1957                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1958
1959         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1960         {
1961                 checkrules_status = WINNING_NEVER;
1962                 checkrules_overtimesadded = -1;
1963                 wantovertime |= InitiateSuddenDeath();
1964         }
1965
1966         if(checkrules_status == WINNING_NEVER)
1967                 // equality cases! Nobody wins if the overtime ends in a draw.
1968                 ClearWinners();
1969
1970         if(wantovertime)
1971         {
1972                 if(checkrules_status == WINNING_NEVER)
1973                         InitiateOvertime();
1974                 else
1975                         checkrules_status = WINNING_YES;
1976         }
1977
1978         if(checkrules_suddendeathend)
1979                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1980                         checkrules_status = WINNING_YES;
1981
1982         if(checkrules_status == WINNING_YES)
1983         {
1984                 //print("WINNING\n");
1985                 NextLevel();
1986         }
1987 }
1988
1989 string GotoMap(string m)
1990 {
1991         m = GameTypeVote_MapInfo_FixName(m);
1992         if (!m)
1993                 return "The map you suggested is not available on this server.";
1994         if (!autocvar_sv_vote_gametype)
1995         if(!MapInfo_CheckMap(m))
1996                 return "The map you suggested does not support the current game mode.";
1997         cvar_set("nextmap", m);
1998         cvar_set("timelimit", "-1");
1999         if(mapvote_initialized || alreadychangedlevel)
2000         {
2001                 if(DoNextMapOverride(0))
2002                         return "Map switch initiated.";
2003                 else
2004                         return "Hm... no. For some reason I like THIS map more.";
2005         }
2006         else
2007                 return "Map switch will happen after scoreboard.";
2008 }
2009
2010 bool autocvar_sv_gameplayfix_multiplethinksperframe;
2011 void RunThink(entity this)
2012 {
2013         // don't let things stay in the past.
2014         // it is possible to start that way by a trigger with a local time.
2015         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2016                 return;
2017
2018         float oldtime = time; // do we need to save this?
2019
2020         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2021         {
2022                 time = max(oldtime, this.nextthink);
2023                 this.nextthink = 0;
2024
2025                 if(getthink(this))
2026                         getthink(this)(this);
2027                 // mods often set nextthink to time to cause a think every frame,
2028                 // we don't want to loop in that case, so exit if the new nextthink is
2029                 // <= the time the qc was told, also exit if it is past the end of the
2030                 // frame
2031                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2032                         break;
2033         }
2034
2035         time = oldtime;
2036 }
2037
2038 bool autocvar_sv_freezenonclients;
2039 bool autocvar_sv_gameplayfix_delayprojectiles;
2040 void Physics_Frame()
2041 {
2042         if(autocvar_sv_freezenonclients)
2043                 return;
2044
2045         FOREACH_ENTITY_FLOAT(pure_data, false,
2046         {
2047                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
2048                         continue;
2049
2050                 //set_movetype(it, it.move_movetype);
2051                 // inline the set_movetype function, since this is called a lot
2052                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
2053
2054                 if(it.move_movetype == MOVETYPE_NONE)
2055                         continue;
2056
2057                 if(it.move_qcphysics)
2058                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2059
2060                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2061                 {
2062                         // handle thinking here
2063                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2064                                 RunThink(it);
2065                 }
2066         });
2067
2068         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2069                 return;
2070
2071         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2072         {
2073                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2074                         continue;
2075                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2076         });
2077 }
2078
2079 void systems_update();
2080 void EndFrame()
2081 {
2082         anticheat_endframe();
2083
2084         Physics_Frame();
2085
2086         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2087                 entity e = IS_SPEC(it) ? it.enemy : it;
2088                 if (e.typehitsound) {
2089                         it.typehit_time = time;
2090                 } else if (e.killsound) {
2091                         it.kill_time = time;
2092                 } else if (e.damage_dealt) {
2093                         it.hit_time = time;
2094                         it.damage_dealt_total += ceil(e.damage_dealt);
2095                 }
2096         });
2097         // add 1 frametime because after this, engine SV_Physics
2098         // increases time by a frametime and then networks the frame
2099         // add another frametime because client shows everything with
2100         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2101         // needed!
2102         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2103         FOREACH_CLIENT(true, {
2104                 it.typehitsound = false;
2105                 it.damage_dealt = 0;
2106                 it.killsound = false;
2107                 antilag_record(it, CS(it), altime);
2108         });
2109         IL_EACH(g_monsters, true,
2110         {
2111                 antilag_record(it, it, altime);
2112         });
2113         systems_update();
2114         IL_ENDFRAME();
2115 }
2116
2117
2118 /*
2119  * RedirectionThink:
2120  * returns true if redirecting
2121  */
2122 float redirection_timeout;
2123 float redirection_nextthink;
2124 float RedirectionThink()
2125 {
2126         float clients_found;
2127
2128         if(redirection_target == "")
2129                 return false;
2130
2131         if(!redirection_timeout)
2132         {
2133                 cvar_set("sv_public", "-2");
2134                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2135                 if(redirection_target == "self")
2136                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2137                 else
2138                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2139         }
2140
2141         if(time < redirection_nextthink)
2142                 return true;
2143
2144         redirection_nextthink = time + 1;
2145
2146         clients_found = 0;
2147         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
2148                 // TODO add timer
2149                 LOG_INFO("Redirecting: sending connect command to ", it.netname, "\n");
2150                 if(redirection_target == "self")
2151                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2152                 else
2153                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2154                 ++clients_found;
2155         ));
2156
2157         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2158
2159         if(time > redirection_timeout || clients_found == 0)
2160                 localcmd("\nwait; wait; wait; quit\n");
2161
2162         return true;
2163 }
2164
2165 void TargetMusic_RestoreGame();
2166 void RestoreGame()
2167 {
2168         // Loaded from a save game
2169         // some things then break, so let's work around them...
2170
2171         // Progs DB (capture records)
2172         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2173
2174         // Mapinfo
2175         MapInfo_Shutdown();
2176         MapInfo_Enumerate();
2177         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2178         WeaponStats_Init();
2179
2180         TargetMusic_RestoreGame();
2181 }
2182
2183 void Shutdown()
2184 {
2185         game_stopped = 2;
2186
2187         if(world_initialized > 0)
2188         {
2189                 world_initialized = 0;
2190                 LOG_TRACE("Saving persistent data...");
2191                 Ban_SaveBans();
2192
2193                 // playerstats with unfinished match
2194                 PlayerStats_GameReport(false);
2195
2196                 if(!cheatcount_total)
2197                 {
2198                         if(autocvar_sv_db_saveasdump)
2199                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2200                         else
2201                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2202                 }
2203                 if(autocvar_developer)
2204                 {
2205                         if(autocvar_sv_db_saveasdump)
2206                                 db_dump(TemporaryDB, "server-temp.db");
2207                         else
2208                                 db_save(TemporaryDB, "server-temp.db");
2209                 }
2210                 CheatShutdown(); // must be after cheatcount check
2211                 db_close(ServerProgsDB);
2212                 db_close(TemporaryDB);
2213                 LOG_TRACE("Saving persistent data... done!");
2214                 // tell the bot system the game is ending now
2215                 bot_endgame();
2216
2217                 WeaponStats_Shutdown();
2218                 MapInfo_Shutdown();
2219         }
2220         else if(world_initialized == 0)
2221         {
2222                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2223         }
2224         else
2225         {
2226                 __init_dedicated_server_shutdown();
2227         }
2228 }