qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/all.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include "../common/deathtypes/all.qh"
  23 #include "../common/mapinfo.qh"
  24 #include "../common/monsters/all.qh"
  25 #include "../common/monsters/sv_monsters.qh"
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/notifications/all.qh"
  28 #include "../common/physics/player.qh"
  29 #include "../common/playerstats.qh"
  30 #include "../common/stats.qh"
  31 #include "../common/teams.qh"
  32 #include "../common/triggers/trigger/secret.qh"
  33 #include "../common/triggers/target/music.qh"
  34 #include "../common/util.qh"
  35 #include "../common/items/all.qh"
  36 #include "../common/weapons/all.qh"
  37
  38 const float LATENCY_THINKRATE = 10;
  39 .float latency_sum;
  40 .float latency_cnt;
  41 .float latency_time;
  42 entity pingplreport;
  43 void PingPLReport_Think()
  44 {SELFPARAM();
  45         float delta;
  46         entity e;
  47
  48         delta = 3 / maxclients;
  49         if(delta < sys_frametime)
  50                 delta = 0;
  51         self.nextthink = time + delta;
  52
  53         e = edict_num(self.cnt + 1);
  54         if(IS_REAL_CLIENT(e))
  55         {
  56                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  57                 WriteByte(MSG_BROADCAST, self.cnt);
  58                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  59                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  61
  62                 // record latency times for clients throughout the match so we can report it to playerstats
  63                 if(time > (e.latency_time + LATENCY_THINKRATE))
  64                 {
  65                         e.latency_sum += e.ping;
  66                         e.latency_cnt += 1;
  67                         e.latency_time = time;
  68                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  69                 }
  70         }
  71         else
  72         {
  73                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  74                 WriteByte(MSG_BROADCAST, self.cnt);
  75                 WriteShort(MSG_BROADCAST, 0);
  76                 WriteByte(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78         }
  79         self.cnt = (self.cnt + 1) % maxclients;
  80 }
  81 void PingPLReport_Spawn()
  82 {
  83         pingplreport = new_pure(pingplreport);
  84         pingplreport.think = PingPLReport_Think;
  85         pingplreport.nextthink = time;
  86 }
  87
  88 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  89 string redirection_target;
  90 float world_initialized;
  91
  92 string GetGametype();
  93 void ShuffleMaplist();
  94
  95 void SetDefaultAlpha()
  96 {
  97         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
  98         {
  99                 default_player_alpha = autocvar_g_player_alpha;
 100                 if(default_player_alpha == 0)
 101                         default_player_alpha = 1;
 102                 default_weapon_alpha = default_player_alpha;
 103         }
 104 }
 105
 106 void GotoFirstMap()
 107 {SELFPARAM();
 108         float n;
 109         if(autocvar__sv_init)
 110         {
 111                 // cvar_set("_sv_init", "0");
 112                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 113                 // to this "init" map on a dedicated server will cause no permanent
 114                 // harm
 115                 if(autocvar_g_maplist_shuffle)
 116                         ShuffleMaplist();
 117                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 118                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 119
 120                 MapInfo_Enumerate();
 121                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 122
 123                 if(!DoNextMapOverride(1))
 124                         GotoNextMap(1);
 125
 126                 return;
 127         }
 128
 129         if(time < 5)
 130         {
 131                 self.nextthink = time;
 132         }
 133         else
 134         {
 135                 self.nextthink = time + 1;
 136                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 137         }
 138 }
 139
 140 void cvar_changes_init()
 141 {
 142         float h;
 143         string k, v, d;
 144         float n, i, adding, pureadding;
 145
 146         if(cvar_changes)
 147                 strunzone(cvar_changes);
 148         cvar_changes = string_null;
 149         if(cvar_purechanges)
 150                 strunzone(cvar_purechanges);
 151         cvar_purechanges = string_null;
 152         cvar_purechanges_count = 0;
 153
 154         h = buf_create();
 155         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 156         n = buf_getsize(h);
 157
 158         adding = true;
 159         pureadding = true;
 160
 161         for(i = 0; i < n; ++i)
 162         {
 163                 k = bufstr_get(h, i);
 164
 165 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 166 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 167 #define BADCVAR(p) if(k == p) continue
 168
 169                 // general excludes and namespaces for server admin used cvars
 170                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 171
 172                 // internal
 173                 BADPREFIX("csqc_");
 174                 BADPREFIX("cvar_check_");
 175                 BADCVAR("gamecfg");
 176                 BADCVAR("g_configversion");
 177                 BADCVAR("g_maplist_index");
 178                 BADCVAR("halflifebsp");
 179                 BADCVAR("sv_mapformat_is_quake2");
 180                 BADCVAR("sv_mapformat_is_quake3");
 181                 BADPREFIX("sv_world");
 182
 183                 // client
 184                 BADPREFIX("chase_");
 185                 BADPREFIX("cl_");
 186                 BADPREFIX("con_");
 187                 BADPREFIX("scoreboard_");
 188                 BADPREFIX("g_campaign");
 189                 BADPREFIX("g_waypointsprite_");
 190                 BADPREFIX("gl_");
 191                 BADPREFIX("joy");
 192                 BADPREFIX("hud_");
 193                 BADPREFIX("m_");
 194                 BADPREFIX("menu_");
 195                 BADPREFIX("net_slist_");
 196                 BADPREFIX("r_");
 197                 BADPREFIX("sbar_");
 198                 BADPREFIX("scr_");
 199                 BADPREFIX("snd_");
 200                 BADPREFIX("show");
 201                 BADPREFIX("sensitivity");
 202                 BADPREFIX("userbind");
 203                 BADPREFIX("v_");
 204                 BADPREFIX("vid_");
 205                 BADPREFIX("crosshair");
 206                 BADCVAR("mod_q3bsp_lightmapmergepower");
 207                 BADCVAR("mod_q3bsp_nolightmaps");
 208                 BADCVAR("fov");
 209                 BADCVAR("mastervolume");
 210                 BADCVAR("volume");
 211                 BADCVAR("bgmvolume");
 212
 213                 // private
 214                 BADCVAR("developer");
 215                 BADCVAR("log_dest_udp");
 216                 BADCVAR("net_address");
 217                 BADCVAR("net_address_ipv6");
 218                 BADCVAR("port");
 219                 BADCVAR("savedgamecfg");
 220                 BADCVAR("serverconfig");
 221                 BADCVAR("sv_autoscreenshot");
 222                 BADCVAR("sv_heartbeatperiod");
 223                 BADCVAR("sv_vote_master_password");
 224                 BADCVAR("sys_colortranslation");
 225                 BADCVAR("sys_specialcharactertranslation");
 226                 BADCVAR("timeformat");
 227                 BADCVAR("timestamps");
 228                 BADPREFIX("developer_");
 229                 BADPREFIX("g_ban_");
 230                 BADPREFIX("g_banned_list");
 231                 BADPREFIX("g_chat_flood_");
 232                 BADPREFIX("g_ghost_items");
 233                 BADPREFIX("g_playerstats_");
 234                 BADPREFIX("g_voice_flood_");
 235                 BADPREFIX("log_file");
 236                 BADPREFIX("rcon_");
 237                 BADPREFIX("sv_allowdownloads");
 238                 BADPREFIX("sv_autodemo");
 239                 BADPREFIX("sv_curl_");
 240                 BADPREFIX("sv_eventlog");
 241                 BADPREFIX("sv_logscores_");
 242                 BADPREFIX("sv_master");
 243                 BADPREFIX("sv_weaponstats_");
 244                 BADPREFIX("sv_waypointsprite_");
 245                 BADCVAR("rescan_pending");
 246
 247                 // these can contain player IDs, so better hide
 248                 BADPREFIX("g_forced_team_");
 249
 250                 // mapinfo
 251                 BADCVAR("fraglimit");
 252                 BADCVAR("g_assault");
 253                 BADCVAR("g_ca");
 254                 BADCVAR("g_ca_teams");
 255                 BADCVAR("g_ctf");
 256                 BADCVAR("g_cts");
 257                 BADCVAR("g_dm");
 258                 BADCVAR("g_domination");
 259                 BADCVAR("g_domination_default_teams");
 260                 BADCVAR("g_freezetag");
 261                 BADCVAR("g_freezetag_teams");
 262                 BADCVAR("g_invasion_teams");
 263                 BADCVAR("g_keepaway");
 264                 BADCVAR("g_keyhunt");
 265                 BADCVAR("g_keyhunt_teams");
 266                 BADCVAR("g_lms");
 267                 BADCVAR("g_nexball");
 268                 BADCVAR("g_onslaught");
 269                 BADCVAR("g_race");
 270                 BADCVAR("g_race_laps_limit");
 271                 BADCVAR("g_race_qualifying_timelimit");
 272                 BADCVAR("g_race_qualifying_timelimit_override");
 273                 BADCVAR("g_tdm");
 274                 BADCVAR("g_tdm_teams");
 275                 BADCVAR("leadlimit");
 276                 BADCVAR("nextmap");
 277                 BADCVAR("teamplay");
 278                 BADCVAR("timelimit");
 279
 280                 // long
 281                 BADCVAR("hostname");
 282                 BADCVAR("g_maplist");
 283                 BADCVAR("g_maplist_mostrecent");
 284                 BADCVAR("sv_motd");
 285
 286                 v = cvar_string(k);
 287                 d = cvar_defstring(k);
 288                 if(v == d)
 289                         continue;
 290
 291                 if(adding)
 292                 {
 293                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 294                         if(strlen(cvar_changes) > 16384)
 295                         {
 296                                 cvar_changes = "// too many settings have been changed to show them here\n";
 297                                 adding = 0;
 298                         }
 299                 }
 300
 301                 // now check if the changes are actually gameplay relevant
 302
 303                 // does nothing gameplay relevant
 304                 BADCVAR("captureleadlimit_override");
 305                 BADCVAR("gameversion");
 306                 BADCVAR("g_allow_oldvortexbeam");
 307                 BADCVAR("g_balance_kill_delay");
 308                 BADCVAR("g_campcheck_distance");
 309                 BADCVAR("g_ca_point_leadlimit");
 310                 BADCVAR("g_ca_point_limit");
 311                 BADCVAR("g_ctf_captimerecord_always");
 312                 BADCVAR("g_ctf_flag_glowtrails");
 313                 BADCVAR("g_ctf_flag_pickup_verbosename");
 314                 BADCVAR("g_domination_point_leadlimit");
 315                 BADCVAR("g_forced_respawn");
 316                 BADCVAR("g_freezetag_point_leadlimit");
 317                 BADCVAR("g_freezetag_point_limit");
 318                 BADCVAR("g_hats");
 319                 BADCVAR("g_invasion_point_limit");
 320                 BADCVAR("g_keyhunt_point_leadlimit");
 321                 BADCVAR("g_nexball_goalleadlimit");
 322                 BADCVAR("g_tdm_point_leadlimit");
 323                 BADCVAR("g_tdm_point_limit");
 324                 BADCVAR("leadlimit_and_fraglimit");
 325                 BADCVAR("leadlimit_override");
 326                 BADCVAR("pausable");
 327                 BADCVAR("sv_allow_fullbright");
 328                 BADCVAR("sv_checkforpacketsduringsleep");
 329                 BADCVAR("sv_intermission_cdtrack");
 330                 BADCVAR("sv_minigames");
 331                 BADCVAR("sv_namechangetimer");
 332                 BADCVAR("sv_precacheplayermodels");
 333                 BADCVAR("sv_timeout");
 334                 BADPREFIX("crypto_");
 335                 BADPREFIX("gameversion_");
 336                 BADPREFIX("g_chat_");
 337                 BADPREFIX("g_ctf_captimerecord_");
 338                 BADPREFIX("g_maplist_votable_");
 339                 BADPREFIX("g_mod_");
 340                 BADPREFIX("g_respawn_");
 341                 BADPREFIX("net_");
 342                 BADPREFIX("prvm_");
 343                 BADPREFIX("skill_");
 344                 BADPREFIX("sv_cullentities_");
 345                 BADPREFIX("sv_maxidle_");
 346                 BADPREFIX("sv_minigames_");
 347                 BADPREFIX("sv_timeout_");
 348                 BADPREFIX("sv_vote_");
 349                 BADPREFIX("timelimit_");
 350
 351                 // allowed changes to server admins (please sync this to server.cfg)
 352                 // vi commands:
 353                 //   :/"impure"/,$d
 354                 //   :g!,^\/\/[^ /],d
 355                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 356                 //   :%!sort
 357                 // yes, this does contain some redundant stuff, don't really care
 358                 BADCVAR("bot_config_file");
 359                 BADCVAR("bot_number");
 360                 BADCVAR("bot_prefix");
 361                 BADCVAR("bot_suffix");
 362                 BADCVAR("capturelimit_override");
 363                 BADCVAR("fraglimit_override");
 364                 BADCVAR("gametype");
 365                 BADCVAR("g_antilag");
 366                 BADCVAR("g_balance_teams");
 367                 BADCVAR("g_balance_teams_prevent_imbalance");
 368                 BADCVAR("g_balance_teams_scorefactor");
 369                 BADCVAR("g_ban_sync_trusted_servers");
 370                 BADCVAR("g_ban_sync_uri");
 371                 BADCVAR("g_ca_teams_override");
 372                 BADCVAR("g_ctf_ignore_frags");
 373                 BADCVAR("g_domination_point_limit");
 374                 BADCVAR("g_domination_teams_override");
 375                 BADCVAR("g_freezetag_teams_override");
 376                 BADCVAR("g_friendlyfire");
 377                 BADCVAR("g_fullbrightitems");
 378                 BADCVAR("g_fullbrightplayers");
 379                 BADCVAR("g_keyhunt_point_limit");
 380                 BADCVAR("g_keyhunt_teams_override");
 381                 BADCVAR("g_lms_lives_override");
 382                 BADCVAR("g_maplist");
 383                 BADCVAR("g_maplist_check_waypoints");
 384                 BADCVAR("g_maplist_mostrecent_count");
 385                 BADCVAR("g_maplist_shuffle");
 386                 BADCVAR("g_maplist_votable");
 387                 BADCVAR("g_maplist_votable_abstain");
 388                 BADCVAR("g_maplist_votable_nodetail");
 389                 BADCVAR("g_maplist_votable_suggestions");
 390                 BADCVAR("g_maxplayers");
 391                 BADCVAR("g_mirrordamage");
 392                 BADCVAR("g_nexball_goallimit");
 393                 BADCVAR("g_powerups");
 394                 BADCVAR("g_spawnshieldtime");
 395                 BADCVAR("g_start_delay");
 396                 BADCVAR("g_superspectate");
 397                 BADCVAR("g_tdm_teams_override");
 398                 BADCVAR("g_warmup");
 399                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 400                 BADCVAR("hostname");
 401                 BADCVAR("log_file");
 402                 BADCVAR("maxplayers");
 403                 BADCVAR("minplayers");
 404                 BADCVAR("net_address");
 405                 BADCVAR("port");
 406                 BADCVAR("rcon_password");
 407                 BADCVAR("rcon_restricted_commands");
 408                 BADCVAR("rcon_restricted_password");
 409                 BADCVAR("skill");
 410                 BADCVAR("sv_adminnick");
 411                 BADCVAR("sv_autoscreenshot");
 412                 BADCVAR("sv_autotaunt");
 413                 BADCVAR("sv_curl_defaulturl");
 414                 BADCVAR("sv_defaultcharacter");
 415                 BADCVAR("sv_defaultplayercolors");
 416                 BADCVAR("sv_defaultplayermodel");
 417                 BADCVAR("sv_defaultplayerskin");
 418                 BADCVAR("sv_maxidle");
 419                 BADCVAR("sv_maxrate");
 420                 BADCVAR("sv_motd");
 421                 BADCVAR("sv_public");
 422                 BADCVAR("sv_ready_restart");
 423                 BADCVAR("sv_status_privacy");
 424                 BADCVAR("sv_taunt");
 425                 BADCVAR("sv_vote_call");
 426                 BADCVAR("sv_vote_commands");
 427                 BADCVAR("sv_vote_majority_factor");
 428                 BADCVAR("sv_vote_master");
 429                 BADCVAR("sv_vote_master_commands");
 430                 BADCVAR("sv_vote_master_password");
 431                 BADCVAR("sv_vote_simple_majority_factor");
 432                 BADCVAR("teamplay_mode");
 433                 BADCVAR("timelimit_override");
 434                 BADPREFIX("g_warmup_");
 435                 BADPREFIX("sv_ready_restart_");
 436
 437                 // mutators that announce themselves properly to the server browser
 438                 BADCVAR("g_instagib");
 439                 BADCVAR("g_new_toys");
 440                 BADCVAR("g_nix");
 441                 BADCVAR("g_grappling_hook");
 442                 BADCVAR("g_jetpack");
 443
 444 #undef BADPREFIX
 445 #undef BADCVAR
 446
 447                 if(pureadding)
 448                 {
 449                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 450                         if(strlen(cvar_purechanges) > 16384)
 451                         {
 452                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 453                                 pureadding = 0;
 454                         }
 455                 }
 456                 ++cvar_purechanges_count;
 457                 // WARNING: this variable is used for the server list
 458                 // NEVER dare to skip this code!
 459                 // Hacks to intentionally appearing as "pure server" even though you DO have
 460                 // modified settings may be punished by removal from the server list.
 461                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 462                 // though.
 463         }
 464         buf_del(h);
 465         if(cvar_changes == "")
 466                 cvar_changes = "// this server runs at default server settings\n";
 467         else
 468                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 469         cvar_changes = strzone(cvar_changes);
 470         if(cvar_purechanges == "")
 471                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 472         else
 473                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 474         cvar_purechanges = strzone(cvar_purechanges);
 475 }
 476
 477 void detect_maptype()
 478 {
 479 #if 0
 480         vector o, v;
 481         float i;
 482
 483         for (;;)
 484         {
 485                 o = world.mins;
 486                 o.x += random() * (world.maxs.x - world.mins.x);
 487                 o.y += random() * (world.maxs.y - world.mins.y);
 488                 o.z += random() * (world.maxs.z - world.mins.z);
 489
 490                 tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 32768', MOVE_WORLDONLY, world);
 491                 if(trace_fraction == 1)
 492                         continue;
 493
 494                 v = trace_endpos;
 495
 496                 for(i = 0; i < 64; i += 4)
 497                 {
 498                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 499         if(trace_fraction == 1)
 500                 continue;
 501                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 502                 }
 503
 504                 break;
 505         }
 506 #endif
 507 }
 508
 509 entity randomseed;
 510 bool RandomSeed_Send(entity this, entity to, int sf)
 511 {
 512         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 513         WriteShort(MSG_ENTITY, self.cnt);
 514         return true;
 515 }
 516 void RandomSeed_Think()
 517 {SELFPARAM();
 518         self.cnt = bound(0, floor(random() * 65536), 65535);
 519         self.nextthink = time + 5;
 520
 521         self.SendFlags |= 1;
 522 }
 523 void RandomSeed_Spawn()
 524 {SELFPARAM();
 525         randomseed = new_pure(randomseed);
 526         randomseed.think = RandomSeed_Think;
 527         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 528
 529         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 530 }
 531
 532 spawnfunc(__init_dedicated_server)
 533 {
 534         // handler for _init/_init map (only for dedicated server initialization)
 535
 536         world_initialized = -1; // don't complain
 537         cvar = cvar_normal;
 538         cvar_string = cvar_string_normal;
 539         cvar_set = cvar_set_normal;
 540
 541         remove = remove_unsafely;
 542
 543         entity e = spawn();
 544         e.think = GotoFirstMap;
 545         e.nextthink = time; // this is usually 1 at this point
 546
 547         e = new(info_player_deathmatch);  // safeguard against player joining
 548
 549         self.classname = "worldspawn"; // safeguard against various stuff ;)
 550
 551         // needs to be done so early because of the constants they create
 552         static_init();
 553         static_init_late();
 554         static_init_precache();
 555
 556         MapInfo_Enumerate();
 557         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 558 }
 559
 560 void __init_dedicated_server_shutdown() {
 561         MapInfo_Shutdown();
 562 }
 563
 564 void Map_MarkAsRecent(string m);
 565 float world_already_spawned;
 566 void Nagger_Init();
 567 void ClientInit_Spawn();
 568 void WeaponStats_Init();
 569 void WeaponStats_Shutdown();
 570 spawnfunc(worldspawn)
 571 {
 572         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 573
 574         {
 575                 bool wantrestart = false;
 576
 577                 if (!server_is_dedicated)
 578                 {
 579                         // force unloading of server pk3 files when starting a listen server
 580                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 581                         // restore csqc_progname too
 582                         string expect = "csprogs.dat";
 583                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 584                         cvar_set_normal("csqc_progname", expect);
 585                 }
 586                 else
 587                 {
 588                         // Try to use versioned csprogs from pk3
 589                         // Only ever use versioned csprogs.dat files on dedicated servers;
 590                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 591                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 592                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 593                         string select = "csprogs.dat";
 594                         if (fexists(pk3csprogs)) select = pk3csprogs;
 595                         if (cvar_string_normal("csqc_progname") != select)
 596                         {
 597                                 cvar_set_normal("csqc_progname", select);
 598                                 wantrestart = true;
 599                         }
 600                         // Check for updates on startup
 601                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 602                         int sentinel = fopen("progs.txt", FILE_READ);
 603                         if (sentinel >= 0)
 604                         {
 605                                 string switchversion = fgets(sentinel);
 606                                 fclose(sentinel);
 607                                 if (switchversion != "" && switchversion != WATERMARK)
 608                                 {
 609                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s\n", switchversion);
 610                                         // if it doesn't exist, assume either:
 611                                         //   a) the current program was overwritten
 612                                         //   b) this is a client only update
 613                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 614                                         if (fexists(newprogs))
 615                                         {
 616                                                 cvar_set_normal("sv_progs", newprogs);
 617                                                 wantrestart = true;
 618                                         }
 619                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 620                                         if (fexists(newcsprogs))
 621                                         {
 622                                                 cvar_set_normal("csqc_progname", newcsprogs);
 623                                                 wantrestart = true;
 624                                         }
 625                                 }
 626                         }
 627                 }
 628                 if (wantrestart)
 629                 {
 630                         LOG_INFOF("Restart requested\n");
 631                         changelevel(mapname);
 632                         // let initialization continue, shutdown depends on it
 633                 }
 634         }
 635
 636         float fd, l;
 637         string s;
 638
 639         cvar = cvar_normal;
 640         cvar_string = cvar_string_normal;
 641         cvar_set = cvar_set_normal;
 642
 643         if(world_already_spawned)
 644                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 645         world_already_spawned = true;
 646
 647         remove = remove_safely; // during spawning, watch what you remove!
 648
 649         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 650
 651         compressShortVector_init();
 652
 653         maxclients = 0;
 654         for (entity head = nextent(world); head; head = nextent(head))
 655         {
 656                 ++maxclients;
 657         }
 658
 659         // needs to be done so early because of the constants they create
 660         static_init();
 661
 662         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 663
 664         TemporaryDB = db_create();
 665
 666         // 0 normal
 667         lightstyle(0, "m");
 668
 669         // 1 FLICKER (first variety)
 670         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 671
 672         // 2 SLOW STRONG PULSE
 673         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 674
 675         // 3 CANDLE (first variety)
 676         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 677
 678         // 4 FAST STROBE
 679         lightstyle(4, "mamamamamama");
 680
 681         // 5 GENTLE PULSE 1
 682         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 683
 684         // 6 FLICKER (second variety)
 685         lightstyle(6, "nmonqnmomnmomomno");
 686
 687         // 7 CANDLE (second variety)
 688         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 689
 690         // 8 CANDLE (third variety)
 691         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 692
 693         // 9 SLOW STROBE (fourth variety)
 694         lightstyle(9, "aaaaaaaazzzzzzzz");
 695
 696         // 10 FLUORESCENT FLICKER
 697         lightstyle(10, "mmamammmmammamamaaamammma");
 698
 699         // 11 SLOW PULSE NOT FADE TO BLACK
 700         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 701
 702         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 703
 704         // 63 testing
 705         lightstyle(63, "a");
 706
 707         if(autocvar_g_campaign)
 708                 CampaignPreInit();
 709
 710         Map_MarkAsRecent(mapname);
 711
 712         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 713
 714         InitGameplayMode();
 715         static_init_late();
 716         static_init_precache();
 717         readlevelcvars();
 718         GrappleHookInit();
 719
 720         player_count = 0;
 721         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 722         if(bot_waypoints_for_items == 1)
 723                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 724                         bot_waypoints_for_items = 0;
 725
 726         precache();
 727
 728         WaypointSprite_Init();
 729
 730         GameLogInit(); // prepare everything
 731         // NOTE for matchid:
 732         // changing the logic generating it is okay. But:
 733         // it HAS to stay <= 64 chars
 734         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 735         if(autocvar_sv_eventlog)
 736         {
 737                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 738                 matchid = strzone(s);
 739
 740                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 741                 s = ":gameinfo:mutators:LIST";
 742
 743                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 744                 s = ret_string;
 745
 746                 // initialiation stuff, not good in the mutator system
 747                 if(!autocvar_g_use_ammunition)
 748                         s = strcat(s, ":no_use_ammunition");
 749
 750                 // initialiation stuff, not good in the mutator system
 751                 if(autocvar_g_pickup_items == 0)
 752                         s = strcat(s, ":no_pickup_items");
 753                 if(autocvar_g_pickup_items > 0)
 754                         s = strcat(s, ":pickup_items");
 755
 756                 // initialiation stuff, not good in the mutator system
 757                 if(autocvar_g_weaponarena != "0")
 758                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 759
 760                 // TODO to mutator system
 761                 if(autocvar_g_norecoil)
 762                         s = strcat(s, ":norecoil");
 763
 764                 // TODO to mutator system
 765                 if(autocvar_g_powerups == 0)
 766                         s = strcat(s, ":no_powerups");
 767                 if(autocvar_g_powerups > 0)
 768                         s = strcat(s, ":powerups");
 769
 770                 GameLogEcho(s);
 771                 GameLogEcho(":gameinfo:end");
 772         }
 773         else
 774                 matchid = strzone(ftos(random()));
 775
 776         cvar_set("nextmap", "");
 777
 778         SetDefaultAlpha();
 779
 780         if(autocvar_g_campaign)
 781                 CampaignPostInit();
 782
 783         Ban_LoadBans();
 784
 785         MapInfo_Enumerate();
 786         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 787
 788         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 789         {
 790                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 791                 if(fd != -1)
 792                 {
 793                         while((s = fgets(fd)))
 794                         {
 795                                 l = tokenize_console(s);
 796                                 if(l < 2)
 797                                         continue;
 798                                 if(argv(0) == "cd")
 799                                 {
 800                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 801                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 802                                 }
 803                                 else if(argv(0) == "fog")
 804                                 {
 805                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 806                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 807                                 }
 808                                 else if(argv(0) == "set")
 809                                 {
 810                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 811                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 812                                 }
 813                                 else if(argv(0) != "//")
 814                                 {
 815                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 816                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 817                                 }
 818                         }
 819                         fclose(fd);
 820                 }
 821         }
 822
 823         WeaponStats_Init();
 824
 825         Nagger_Init();
 826
 827         next_pingtime = time + 5;
 828
 829         detect_maptype();
 830
 831         // set up information replies for clients and server to use
 832         maplist_reply = strzone(getmaplist());
 833         lsmaps_reply = strzone(getlsmaps());
 834         monsterlist_reply = strzone(getmonsterlist());
 835         for(int i = 0; i < 10; ++i)
 836         {
 837                 s = getrecords(i);
 838                 if (s)
 839                         records_reply[i] = strzone(s);
 840         }
 841         ladder_reply = strzone(getladder());
 842         rankings_reply = strzone(getrankings());
 843
 844         // begin other init
 845         ClientInit_Spawn();
 846         RandomSeed_Spawn();
 847         PingPLReport_Spawn();
 848
 849         CheatInit();
 850
 851         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 852
 853         // fill sv_curl_serverpackages from .serverpackage files
 854         if (autocvar_sv_curl_serverpackages_auto)
 855         {
 856                 s = "csprogs-" WATERMARK ".txt";
 857                 // remove automatically managed files from the list to prevent duplicates
 858                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 859                 {
 860                         string pkg = argv(i);
 861                         if (startsWith(pkg, "csprogs-")) continue;
 862                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 863                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 864                         s = cons(s, pkg);
 865                 }
 866                 // add automatically managed files to the list
 867                 #define X(match) MACRO_BEGIN { \
 868                         fd = search_begin(match, true, false); \
 869                         if (fd >= 0) \
 870                         { \
 871                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 872                                 { \
 873                                         s = cons(s, search_getfilename(fd, i)); \
 874                                 } \
 875                                 search_end(fd); \
 876                         } \
 877                 } MACRO_END
 878                 X("*-serverpackage.txt");
 879                 X("*.serverpackage");
 880                 #undef X
 881                 cvar_set("sv_curl_serverpackages", s);
 882         }
 883
 884         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 885         modname = "Xonotic";
 886         // physics/balance/config changes that count as mod
 887         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 888                 modname = cvar_string("g_mod_physics");
 889         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 890                 modname = cvar_string("g_mod_balance");
 891         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 892                 modname = cvar_string("g_mod_config");
 893         // extra mutators that deserve to count as mod
 894         MUTATOR_CALLHOOK(SetModname);
 895
 896         // save it for later
 897         modname = strzone(modname);
 898
 899         WinningConditionHelper(); // set worldstatus
 900
 901         world_initialized = 1;
 902 }
 903
 904 spawnfunc(light)
 905 {
 906         //makestatic (self); // Who the f___ did that?
 907         remove(self);
 908 }
 909
 910 string GetGametype()
 911 {
 912         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 913 }
 914
 915 string GetMapname()
 916 {
 917         return mapname;
 918 }
 919
 920 float Map_Count, Map_Current;
 921 string Map_Current_Name;
 922
 923 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 924 float GetMaplistPosition()
 925 {
 926         float pos, idx;
 927         string map;
 928
 929         map = GetMapname();
 930         idx = autocvar_g_maplist_index;
 931
 932         if(idx >= 0)
 933                 if(idx < Map_Count)
 934                         if(map == argv(idx))
 935                                 return idx;
 936
 937         for(pos = 0; pos < Map_Count; ++pos)
 938                 if(map == argv(pos))
 939                         return pos;
 940
 941         // resume normal maplist rotation if current map is not in g_maplist
 942         return idx;
 943 }
 944
 945 float MapHasRightSize(string map)
 946 {
 947         float fh;
 948         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 949         if(autocvar_g_maplist_check_waypoints)
 950         {
 951                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 952                 if(!fexists(strcat("maps/", map, ".waypoints")))
 953                 {
 954                         LOG_TRACE(": no waypoints\n");
 955                         return false;
 956                 }
 957                 LOG_TRACE(": has waypoints\n");
 958         }
 959
 960         // open map size restriction file
 961         LOG_TRACE("opensize "); LOG_TRACE(map);
 962         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 963         if(fh >= 0)
 964         {
 965                 float mapmin, mapmax;
 966                 LOG_TRACE(": ok, ");
 967                 mapmin = stof(fgets(fh));
 968                 mapmax = stof(fgets(fh));
 969                 fclose(fh);
 970                 if(player_count < mapmin)
 971                 {
 972                         LOG_TRACE("not enough\n");
 973                         return false;
 974                 }
 975                 if(player_count > mapmax)
 976                 {
 977                         LOG_TRACE("too many\n");
 978                         return false;
 979                 }
 980                 LOG_TRACE("right size\n");
 981                 return true;
 982         }
 983         LOG_TRACE(": not found\n");
 984         return true;
 985 }
 986
 987 string Map_Filename(float position)
 988 {
 989         return strcat("maps/", argv(position), ".bsp");
 990 }
 991
 992 void Map_MarkAsRecent(string m)
 993 {
 994         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 995 }
 996
 997 float Map_IsRecent(string m)
 998 {
 999         return strhasword(autocvar_g_maplist_mostrecent, m);
1000 }
1001
1002 float Map_Check(float position, float pass)
1003 {
1004         string filename;
1005         string map_next;
1006         map_next = argv(position);
1007         if(pass <= 1)
1008         {
1009                 if(Map_IsRecent(map_next))
1010                         return 0;
1011         }
1012         filename = Map_Filename(position);
1013         if(MapInfo_CheckMap(map_next))
1014         {
1015                 if(pass == 2)
1016                         return 1;
1017                 if(MapHasRightSize(map_next))
1018                         return 1;
1019                 return 0;
1020         }
1021         else
1022                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
1023
1024         return 0;
1025 }
1026
1027 void Map_Goto_SetStr(string nextmapname)
1028 {
1029         if(getmapname_stored != "")
1030                 strunzone(getmapname_stored);
1031         if(nextmapname == "")
1032                 getmapname_stored = "";
1033         else
1034                 getmapname_stored = strzone(nextmapname);
1035 }
1036
1037 void Map_Goto_SetFloat(float position)
1038 {
1039         cvar_set("g_maplist_index", ftos(position));
1040         Map_Goto_SetStr(argv(position));
1041 }
1042
1043 void Map_Goto(float reinit)
1044 {
1045         MapInfo_LoadMap(getmapname_stored, reinit);
1046 }
1047
1048 // return codes of map selectors:
1049 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1050 //   -2 = permanent failure
1051 float() MaplistMethod_Iterate = // usual method
1052 {
1053         float pass, i;
1054
1055         LOG_TRACE("Trying MaplistMethod_Iterate\n");
1056
1057         for(pass = 1; pass <= 2; ++pass)
1058         {
1059                 for(i = 1; i < Map_Count; ++i)
1060                 {
1061                         float mapindex;
1062                         mapindex = (i + Map_Current) % Map_Count;
1063                         if(Map_Check(mapindex, pass))
1064                                 return mapindex;
1065                 }
1066         }
1067         return -1;
1068 }
1069
1070 float() MaplistMethod_Repeat = // fallback method
1071 {
1072         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1073
1074         if(Map_Check(Map_Current, 2))
1075                 return Map_Current;
1076         return -2;
1077 }
1078
1079 float() MaplistMethod_Random = // random map selection
1080 {
1081         float i, imax;
1082
1083         LOG_TRACE("Trying MaplistMethod_Random\n");
1084
1085         imax = 42;
1086
1087         for(i = 0; i <= imax; ++i)
1088         {
1089                 float mapindex;
1090                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1091                 if(Map_Check(mapindex, 1))
1092                         return mapindex;
1093         }
1094         return -1;
1095 }
1096
1097 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1098 // the exponent sets a bias on the map selection:
1099 // the higher the exponent, the less likely "shortly repeated" same maps are
1100 {
1101         float i, j, imax, insertpos;
1102
1103         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1104
1105         imax = 42;
1106
1107         for(i = 0; i <= imax; ++i)
1108         {
1109                 string newlist;
1110
1111                 // now reinsert this at another position
1112                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1113                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1114                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1115                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1116
1117                 // insert the current map there
1118                 newlist = "";
1119                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1120                         newlist = strcat(newlist, " ", argv(j));
1121                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1122                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1123                         newlist = strcat(newlist, " ", argv(j));
1124                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1125                 cvar_set("g_maplist", newlist);
1126                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1127
1128                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1129                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1130                 if(Map_Check(Map_Current, 1))
1131                         return Map_Current;
1132         }
1133         return -1;
1134 }
1135
1136 void Maplist_Init()
1137 {
1138         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1139         float i;
1140         for (i = 0; i < Map_Count; ++i)
1141                 if (Map_Check(i, 2))
1142                         break;
1143         if (i == Map_Count)
1144         {
1145                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1146                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1147                 if(autocvar_g_maplist_shuffle)
1148                         ShuffleMaplist();
1149                 localcmd("\nmenu_cmd sync\n");
1150                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1151         }
1152         if(Map_Count == 0)
1153                 error("empty maplist, cannot select a new map");
1154         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1155
1156         if(Map_Current_Name)
1157                 strunzone(Map_Current_Name);
1158         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1159         // this may or may not be correct, but who cares, in the worst case a map
1160         // isn't chosen in the first pass that should have been
1161 }
1162
1163 string GetNextMap()
1164 {
1165         float nextMap;
1166
1167         Maplist_Init();
1168         nextMap = -1;
1169
1170         if(nextMap == -1)
1171                 if(autocvar_g_maplist_shuffle > 0)
1172                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1173
1174         if(nextMap == -1)
1175                 if(autocvar_g_maplist_selectrandom)
1176                         nextMap = MaplistMethod_Random();
1177
1178         if(nextMap == -1)
1179                 nextMap = MaplistMethod_Iterate();
1180
1181         if(nextMap == -1)
1182                 nextMap = MaplistMethod_Repeat();
1183
1184         if(nextMap >= 0)
1185         {
1186                 Map_Goto_SetFloat(nextMap);
1187                 return getmapname_stored;
1188         }
1189
1190         return "";
1191 }
1192
1193 float DoNextMapOverride(float reinit)
1194 {
1195         if(autocvar_g_campaign)
1196         {
1197                 CampaignPostIntermission();
1198                 alreadychangedlevel = true;
1199                 return true;
1200         }
1201         if(autocvar_quit_when_empty)
1202         {
1203                 if(player_count <= currentbots)
1204                 {
1205                         localcmd("quit\n");
1206                         alreadychangedlevel = true;
1207                         return true;
1208                 }
1209         }
1210         if(autocvar_quit_and_redirect != "")
1211         {
1212                 redirection_target = strzone(autocvar_quit_and_redirect);
1213                 alreadychangedlevel = true;
1214                 return true;
1215         }
1216         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1217         {
1218                 localcmd("restart\n");
1219                 alreadychangedlevel = true;
1220                 return true;
1221         }
1222         if(autocvar_nextmap != "")
1223         {
1224                 string m;
1225                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1226                 cvar_set("nextmap",m);
1227
1228                 if(!m || gametypevote)
1229                         return false;
1230                 if(autocvar_sv_vote_gametype)
1231                 {
1232                         Map_Goto_SetStr(m);
1233                         return false;
1234                 }
1235
1236                 if(MapInfo_CheckMap(m))
1237                 {
1238                         Map_Goto_SetStr(m);
1239                         Map_Goto(reinit);
1240                         alreadychangedlevel = true;
1241                         return true;
1242                 }
1243         }
1244         if(!reinit && autocvar_lastlevel)
1245         {
1246                 cvar_settemp_restore();
1247                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1248                 alreadychangedlevel = true;
1249                 return true;
1250         }
1251         return false;
1252 }
1253
1254 void GotoNextMap(float reinit)
1255 {
1256         //string nextmap;
1257         //float n, nummaps;
1258         //string s;
1259         if (alreadychangedlevel)
1260                 return;
1261         alreadychangedlevel = true;
1262
1263         string nextMap;
1264
1265         nextMap = GetNextMap();
1266         if(nextMap == "")
1267                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1268         Map_Goto(reinit);
1269 }
1270
1271
1272 /*
1273 ============
1274 IntermissionThink
1275
1276 When the player presses attack or jump, change to the next level
1277 ============
1278 */
1279 .float autoscreenshot;
1280 void IntermissionThink()
1281 {SELFPARAM();
1282         FixIntermissionClient(self);
1283
1284         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1285         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1286
1287         if( (server_screenshot || client_screenshot)
1288                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1289         {
1290                 self.autoscreenshot = -1;
1291                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1292                 return;
1293         }
1294
1295         if (time < intermission_exittime)
1296                 return;
1297
1298         if(!mapvote_initialized)
1299                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(self) || PHYS_INPUT_BUTTON_JUMP(self) || PHYS_INPUT_BUTTON_ATCK2(self) || PHYS_INPUT_BUTTON_HOOK(self) || PHYS_INPUT_BUTTON_USE(self)))
1300                         return;
1301
1302         MapVote_Start();
1303 }
1304
1305 /*
1306 ============
1307 FindIntermission
1308
1309 Returns the entity to view from
1310 ============
1311 */
1312 /*
1313 entity FindIntermission()
1314 {
1315         local   entity spot;
1316         local   float cyc;
1317
1318 // look for info_intermission first
1319         spot = find (world, classname, "info_intermission");
1320         if (spot)
1321         {       // pick a random one
1322                 cyc = random() * 4;
1323                 while (cyc > 1)
1324                 {
1325                         spot = find (spot, classname, "info_intermission");
1326                         if (!spot)
1327                                 spot = find (spot, classname, "info_intermission");
1328                         cyc = cyc - 1;
1329                 }
1330                 return spot;
1331         }
1332
1333 // then look for the start position
1334         spot = find (world, classname, "info_player_start");
1335         if (spot)
1336                 return spot;
1337
1338 // testinfo_player_start is only found in regioned levels
1339         spot = find (world, classname, "testplayerstart");
1340         if (spot)
1341                 return spot;
1342
1343 // then look for the start position
1344         spot = find (world, classname, "info_player_deathmatch");
1345         if (spot)
1346                 return spot;
1347
1348         //objerror ("FindIntermission: no spot");
1349         return world;
1350 }
1351 */
1352
1353 /*
1354 ===============================================================================
1355
1356 RULES
1357
1358 ===============================================================================
1359 */
1360
1361 void DumpStats(float final)
1362 {
1363         float file;
1364         string s;
1365         float to_console;
1366         float to_eventlog;
1367         float to_file;
1368         float i;
1369
1370         to_console = autocvar_sv_logscores_console;
1371         to_eventlog = autocvar_sv_eventlog;
1372         to_file = autocvar_sv_logscores_file;
1373
1374         if(!final)
1375         {
1376                 to_console = true; // always print printstats replies
1377                 to_eventlog = false; // but never print them to the event log
1378         }
1379
1380         if(to_eventlog)
1381                 if(autocvar_sv_eventlog_console)
1382                         to_console = false; // otherwise we get the output twice
1383
1384         if(final)
1385                 s = ":scores:";
1386         else
1387                 s = ":status:";
1388         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1389
1390         if(to_console)
1391                 LOG_INFO(s, "\n");
1392         if(to_eventlog)
1393                 GameLogEcho(s);
1394
1395         file = -1;
1396         if(to_file)
1397         {
1398                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1399                 if(file == -1)
1400                         to_file = false;
1401                 else
1402                         fputs(file, strcat(s, "\n"));
1403         }
1404
1405         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1406         if(to_console)
1407                 LOG_INFO(s, "\n");
1408         if(to_eventlog)
1409                 GameLogEcho(s);
1410         if(to_file)
1411                 fputs(file, strcat(s, "\n"));
1412
1413         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), LAMBDA(
1414                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1415                 s = strcat(s, ftos(rint(time - it.jointime)), ":");
1416                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it, s))
1417                         s = strcat(s, ftos(it.team), ":");
1418                 else
1419                         s = strcat(s, "spectator:");
1420
1421                 if(to_console)
1422                         LOG_INFO(s, it.netname, "\n");
1423                 if(to_eventlog)
1424                         GameLogEcho(strcat(s, ftos(it.playerid), ":", it.netname));
1425                 if(to_file)
1426                         fputs(file, strcat(s, it.netname, "\n"));
1427         ));
1428
1429         if(teamplay)
1430         {
1431                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1432                 if(to_console)
1433                         LOG_INFO(s, "\n");
1434                 if(to_eventlog)
1435                         GameLogEcho(s);
1436                 if(to_file)
1437                         fputs(file, strcat(s, "\n"));
1438
1439                 for(i = 1; i < 16; ++i)
1440                 {
1441                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1442                         s = strcat(s, ":", ftos(i));
1443                         if(to_console)
1444                                 LOG_INFO(s, "\n");
1445                         if(to_eventlog)
1446                                 GameLogEcho(s);
1447                         if(to_file)
1448                                 fputs(file, strcat(s, "\n"));
1449                 }
1450         }
1451
1452         if(to_console)
1453                 LOG_INFO(":end\n");
1454         if(to_eventlog)
1455                 GameLogEcho(":end");
1456         if(to_file)
1457         {
1458                 fputs(file, ":end\n");
1459                 fclose(file);
1460         }
1461 }
1462
1463 void FixIntermissionClient(entity e)
1464 {
1465         if(!e.autoscreenshot) // initial call
1466         {
1467                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1468                 e.health = -2342;
1469                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1470                 e.solid = SOLID_NOT;
1471                 e.movetype = MOVETYPE_NONE;
1472                 e.takedamage = DAMAGE_NO;
1473                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1474                 {
1475                     .entity weaponentity = weaponentities[slot];
1476                         if(e.(weaponentity))
1477                         {
1478                                 e.(weaponentity).effects = EF_NODRAW;
1479                                 if (e.(weaponentity).weaponchild)
1480                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1481                         }
1482                 }
1483                 if(IS_REAL_CLIENT(e))
1484                 {
1485                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1486                         RandomSelection_Init();
1487                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, LAMBDA(
1488                                 RandomSelection_Add(NULL, 0, it, 1, 1);
1489                         ));
1490                         if (RandomSelection_chosen_string != "")
1491                         {
1492                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1493                         }
1494                         msg_entity = e;
1495                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1496                 }
1497         }
1498 }
1499
1500 /*
1501 go to the next level for deathmatch
1502 only called if a time or frag limit has expired
1503 */
1504 void NextLevel()
1505 {
1506         gameover = true;
1507
1508         intermission_running = 1;
1509
1510 // enforce a wait time before allowing changelevel
1511         if(player_count > 0)
1512                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1513         else
1514                 intermission_exittime = -1;
1515
1516         /*
1517         WriteByte (MSG_ALL, SVC_CDTRACK);
1518         WriteByte (MSG_ALL, 3);
1519         WriteByte (MSG_ALL, 3);
1520         // done in FixIntermission
1521         */
1522
1523         //pos = FindIntermission ();
1524
1525         VoteReset();
1526
1527         DumpStats(true);
1528
1529         // send statistics
1530         PlayerStats_GameReport(true);
1531         WeaponStats_Shutdown();
1532
1533         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, CPID_Null); // kill all centerprints now
1534
1535         if(autocvar_sv_eventlog)
1536                 GameLogEcho(":gameover");
1537
1538         GameLogClose();
1539
1540         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1541                 FixIntermissionClient(it);
1542                 if(it.winning)
1543                         bprint(it.netname, " ^7wins.\n");
1544         ));
1545
1546         entity oldself = self;
1547         target_music_kill();
1548         self = oldself;
1549
1550         if(autocvar_g_campaign)
1551                 CampaignPreIntermission();
1552
1553         MUTATOR_CALLHOOK(MatchEnd);
1554
1555         localcmd("\nsv_hook_gameend\n");
1556 }
1557
1558 /*
1559 ============
1560 CheckRules_Player
1561
1562 Exit deathmatch games upon conditions
1563 ============
1564 */
1565 void CheckRules_Player()
1566 {SELFPARAM();
1567         if (gameover)   // someone else quit the game already
1568                 return;
1569
1570         if(!IS_DEAD(self))
1571                 self.play_time += frametime;
1572
1573         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1574         //   (div0: and that in CheckRules_World please)
1575 }
1576
1577
1578 float InitiateSuddenDeath()
1579 {
1580         // Check first whether normal overtimes could be added before initiating suddendeath mode
1581         // - for this timelimit_overtime needs to be >0 of course
1582         // - also check the winning condition calculated in the previous frame and only add normal overtime
1583         //   again, if at the point at which timelimit would be extended again, still no winner was found
1584         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1585         {
1586                 return 1; // need to call InitiateOvertime later
1587         }
1588         else
1589         {
1590                 if(!checkrules_suddendeathend)
1591                 {
1592                         if(autocvar_g_campaign)
1593                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1594                         else
1595                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1596                         if(g_race && !g_race_qualifying)
1597                                 race_StartCompleting();
1598                 }
1599                 return 0;
1600         }
1601 }
1602
1603 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1604 {
1605         ++checkrules_overtimesadded;
1606         //add one more overtime by simply extending the timelimit
1607         float tl;
1608         tl = autocvar_timelimit;
1609         tl += autocvar_timelimit_overtime;
1610         cvar_set("timelimit", ftos(tl));
1611
1612         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1613 }
1614
1615 float GetWinningCode(float fraglimitreached, float equality)
1616 {
1617         if(autocvar_g_campaign == 1)
1618                 if(fraglimitreached)
1619                         return WINNING_YES;
1620                 else
1621                         return WINNING_NO;
1622
1623         else
1624                 if(equality)
1625                         if(fraglimitreached)
1626                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1627                         else
1628                                 return WINNING_NEVER;
1629                 else
1630                         if(fraglimitreached)
1631                                 return WINNING_YES;
1632                         else
1633                                 return WINNING_NO;
1634 }
1635
1636 // set the .winning flag for exactly those players with a given field value
1637 void SetWinners(.float field, float value)
1638 {
1639         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = (it.(field) == value)));
1640 }
1641
1642 // set the .winning flag for those players with a given field value
1643 void AddWinners(.float field, float value)
1644 {
1645         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1646                 if(it.(field) == value)
1647                         it.winning = 1;
1648         ));
1649 }
1650
1651 // clear the .winning flags
1652 void ClearWinners()
1653 {
1654         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.winning = 0));
1655 }
1656
1657 void ShuffleMaplist()
1658 {
1659         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1660 }
1661
1662 float leaderfrags;
1663 float WinningCondition_Scores(float limit, float leadlimit)
1664 {
1665         float limitreached;
1666
1667         // TODO make everything use THIS winning condition (except LMS)
1668         WinningConditionHelper();
1669
1670         if(teamplay)
1671         {
1672                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1673                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1674                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1675                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1676         }
1677
1678         ClearWinners();
1679         if(WinningConditionHelper_winner)
1680                 WinningConditionHelper_winner.winning = 1;
1681         if(WinningConditionHelper_winnerteam >= 0)
1682                 SetWinners(team, WinningConditionHelper_winnerteam);
1683
1684         if(WinningConditionHelper_lowerisbetter)
1685         {
1686                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1687                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1688                 limit = -limit;
1689         }
1690
1691         if(WinningConditionHelper_zeroisworst)
1692                 leadlimit = 0; // not supported in this mode
1693
1694         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1695         // these modes always score in increments of 1, thus this makes sense
1696         {
1697                 if(leaderfrags != WinningConditionHelper_topscore)
1698                 {
1699                         leaderfrags = WinningConditionHelper_topscore;
1700
1701                         if (limit)
1702                         if (leaderfrags == limit - 1)
1703                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1704                         else if (leaderfrags == limit - 2)
1705                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1706                         else if (leaderfrags == limit - 3)
1707                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1708                 }
1709         }
1710
1711         limitreached = false;
1712         if(limit)
1713                 if(WinningConditionHelper_topscore >= limit)
1714                         limitreached = true;
1715         if(leadlimit)
1716         {
1717                 float leadlimitreached;
1718                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1719                 if(autocvar_leadlimit_and_fraglimit)
1720                         limitreached = (limitreached && leadlimitreached);
1721                 else
1722                         limitreached = (limitreached || leadlimitreached);
1723         }
1724
1725         if(limit)
1726                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1727
1728         return GetWinningCode(
1729                 WinningConditionHelper_topscore && limitreached,
1730                 WinningConditionHelper_equality
1731         );
1732 }
1733
1734 float WinningCondition_RanOutOfSpawns()
1735 {
1736         if(have_team_spawns <= 0)
1737                 return WINNING_NO;
1738
1739         if(!autocvar_g_spawn_useallspawns)
1740                 return WINNING_NO;
1741
1742         if(!some_spawn_has_been_used)
1743                 return WINNING_NO;
1744
1745         team1_score = team2_score = team3_score = team4_score = 0;
1746
1747         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), LAMBDA(
1748                 switch(it.team)
1749                 {
1750                         case NUM_TEAM_1: team1_score = 1; break;
1751                         case NUM_TEAM_2: team2_score = 1; break;
1752                         case NUM_TEAM_3: team3_score = 1; break;
1753                         case NUM_TEAM_4: team4_score = 1; break;
1754                 }
1755         ));
1756
1757         FOREACH_ENTITY_CLASS("info_player_deathmatch", true, LAMBDA(
1758                 switch(it.team)
1759                 {
1760                         case NUM_TEAM_1: team1_score = 1; break;
1761                         case NUM_TEAM_2: team2_score = 1; break;
1762                         case NUM_TEAM_3: team3_score = 1; break;
1763                         case NUM_TEAM_4: team4_score = 1; break;
1764                 }
1765         ));
1766
1767         ClearWinners();
1768         if(team1_score + team2_score + team3_score + team4_score == 0)
1769         {
1770                 checkrules_equality = true;
1771                 return WINNING_YES;
1772         }
1773         else if(team1_score + team2_score + team3_score + team4_score == 1)
1774         {
1775                 float t, i;
1776                 if(team1_score)
1777                         t = NUM_TEAM_1;
1778                 else if(team2_score)
1779                         t = NUM_TEAM_2;
1780                 else if(team3_score)
1781                         t = NUM_TEAM_3;
1782                 else // if(team4_score)
1783                         t = NUM_TEAM_4;
1784                 CheckAllowedTeams(world);
1785                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1786                 {
1787                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1788                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1789                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1790                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1791                 }
1792
1793                 AddWinners(team, t);
1794                 return WINNING_YES;
1795         }
1796         else
1797                 return WINNING_NO;
1798 }
1799
1800 /*
1801 ============
1802 CheckRules_World
1803
1804 Exit deathmatch games upon conditions
1805 ============
1806 */
1807 void CheckRules_World()
1808 {
1809         float timelimit;
1810         float fraglimit;
1811         float leadlimit;
1812
1813         VoteThink();
1814         MapVote_Think();
1815
1816         SetDefaultAlpha();
1817
1818         if (gameover)   // someone else quit the game already
1819         {
1820                 if(player_count == 0) // Nobody there? Then let's go to the next map
1821                         MapVote_Start();
1822                         // this will actually check the player count in the next frame
1823                         // again, but this shouldn't hurt
1824                 return;
1825         }
1826
1827         timelimit = autocvar_timelimit * 60;
1828         fraglimit = autocvar_fraglimit;
1829         leadlimit = autocvar_leadlimit;
1830
1831         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1832         {
1833                 if(timelimit > 0)
1834                         timelimit = 0; // timelimit is not made for warmup
1835                 if(fraglimit > 0)
1836                         fraglimit = 0; // no fraglimit for now
1837                 leadlimit = 0; // no leadlimit for now
1838         }
1839
1840         if(timelimit > 0)
1841         {
1842                 timelimit += game_starttime;
1843         }
1844         else if (timelimit < 0)
1845         {
1846                 // endmatch
1847                 NextLevel();
1848                 return;
1849         }
1850
1851         float wantovertime;
1852         wantovertime = 0;
1853
1854         if(timelimit > game_starttime)
1855                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1856         else
1857                 game_completion_ratio = 0;
1858
1859         if(checkrules_suddendeathend)
1860         {
1861                 if(!checkrules_suddendeathwarning)
1862                 {
1863                         checkrules_suddendeathwarning = true;
1864                         if(g_race && !g_race_qualifying)
1865                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
1866                         else
1867                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
1868                 }
1869         }
1870         else
1871         {
1872                 if (timelimit && time >= timelimit)
1873                 {
1874                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1875                         {
1876                                 float totalplayers;
1877                                 float playerswithlaps;
1878                                 float readyplayers;
1879                                 totalplayers = playerswithlaps = readyplayers = 0;
1880                                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
1881                                         ++totalplayers;
1882                                         if(PlayerScore_Add(it, SP_RACE_FASTEST, 0))
1883                                                 ++playerswithlaps;
1884                                         if(it.ready)
1885                                                 ++readyplayers;
1886                                 ));
1887
1888                                 // at least 2 of the players have completed a lap: start the RACE
1889                                 // otherwise, the players should end the qualifying on their own
1890                                 if(readyplayers || playerswithlaps >= 2)
1891                                 {
1892                                         checkrules_suddendeathend = 0;
1893                                         ReadyRestart(); // go to race
1894                                         return;
1895                                 }
1896                                 else
1897                                         wantovertime |= InitiateSuddenDeath();
1898                         }
1899                         else
1900                                 wantovertime |= InitiateSuddenDeath();
1901                 }
1902         }
1903
1904         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1905         {
1906                 NextLevel();
1907                 return;
1908         }
1909
1910         int checkrules_status = WinningCondition_RanOutOfSpawns();
1911         if(checkrules_status == WINNING_YES)
1912                 bprint("Hey! Someone ran out of spawns!\n");
1913         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1914                 checkrules_status = ret_float;
1915         else
1916                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1917
1918         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1919         {
1920                 checkrules_status = WINNING_NEVER;
1921                 checkrules_overtimesadded = -1;
1922                 wantovertime |= InitiateSuddenDeath();
1923         }
1924
1925         if(checkrules_status == WINNING_NEVER)
1926                 // equality cases! Nobody wins if the overtime ends in a draw.
1927                 ClearWinners();
1928
1929         if(wantovertime)
1930         {
1931                 if(checkrules_status == WINNING_NEVER)
1932                         InitiateOvertime();
1933                 else
1934                         checkrules_status = WINNING_YES;
1935         }
1936
1937         if(checkrules_suddendeathend)
1938                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1939                         checkrules_status = WINNING_YES;
1940
1941         if(checkrules_status == WINNING_YES)
1942         {
1943                 //print("WINNING\n");
1944                 NextLevel();
1945         }
1946 }
1947
1948 string GotoMap(string m)
1949 {
1950         m = GameTypeVote_MapInfo_FixName(m);
1951         if (!m)
1952                 return "The map you suggested is not available on this server.";
1953         if (!autocvar_sv_vote_gametype)
1954         if(!MapInfo_CheckMap(m))
1955                 return "The map you suggested does not support the current game mode.";
1956         cvar_set("nextmap", m);
1957         cvar_set("timelimit", "-1");
1958         if(mapvote_initialized || alreadychangedlevel)
1959         {
1960                 if(DoNextMapOverride(0))
1961                         return "Map switch initiated.";
1962                 else
1963                         return "Hm... no. For some reason I like THIS map more.";
1964         }
1965         else
1966                 return "Map switch will happen after scoreboard.";
1967 }
1968
1969
1970 void EndFrame()
1971 {SELFPARAM();
1972         anticheat_endframe();
1973
1974         float altime;
1975         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
1976                 entity e = IS_SPEC(it) ? it.enemy : it;
1977                 if(e.typehitsound)
1978                         it.typehit_time = time;
1979                 else if(e.damage_dealt)
1980                 {
1981                         it.hit_time = time;
1982                         it.damage_dealt_total += ceil(e.damage_dealt);
1983                 }
1984         ));
1985         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
1986         // add 1 frametime because after this, engine SV_Physics
1987         // increases time by a frametime and then networks the frame
1988         // add another frametime because client shows everything with
1989         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
1990         // needed!
1991         FOREACH_CLIENT(true, LAMBDA(
1992                 it.typehitsound = false;
1993                 it.damage_dealt = 0;
1994                 setself(it);
1995                 antilag_record(it, altime);
1996         ));
1997         FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
1998                 setself(it);
1999                 antilag_record(it, altime);
2000         ));
2001         FOREACH_CLIENT(PS(it), LAMBDA(
2002                 PlayerState s = PS(it);
2003                 s.ps_push(s, it);
2004         ));
2005 }
2006
2007
2008 /*
2009  * RedirectionThink:
2010  * returns true if redirecting
2011  */
2012 float redirection_timeout;
2013 float redirection_nextthink;
2014 float RedirectionThink()
2015 {SELFPARAM();
2016         float clients_found;
2017
2018         if(redirection_target == "")
2019                 return false;
2020
2021         if(!redirection_timeout)
2022         {
2023                 cvar_set("sv_public", "-2");
2024                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2025                 if(redirection_target == "self")
2026                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2027                 else
2028                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2029         }
2030
2031         if(time < redirection_nextthink)
2032                 return true;
2033
2034         redirection_nextthink = time + 1;
2035
2036         clients_found = 0;
2037         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
2038                 setself(it);
2039                 // TODO add timer
2040                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2041                 if(redirection_target == "self")
2042                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2043                 else
2044                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2045                 ++clients_found;
2046         ));
2047
2048         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2049
2050         if(time > redirection_timeout || clients_found == 0)
2051                 localcmd("\nwait; wait; wait; quit\n");
2052
2053         return true;
2054 }
2055
2056 void TargetMusic_RestoreGame();
2057 void RestoreGame()
2058 {
2059         // Loaded from a save game
2060         // some things then break, so let's work around them...
2061
2062         // Progs DB (capture records)
2063         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2064
2065         // Mapinfo
2066         MapInfo_Shutdown();
2067         MapInfo_Enumerate();
2068         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2069         WeaponStats_Init();
2070
2071         TargetMusic_RestoreGame();
2072 }
2073
2074 void Shutdown()
2075 {
2076         gameover = 2;
2077
2078         if(world_initialized > 0)
2079         {
2080                 world_initialized = 0;
2081                 LOG_TRACE("Saving persistent data...\n");
2082                 Ban_SaveBans();
2083
2084                 // playerstats with unfinished match
2085                 PlayerStats_GameReport(false);
2086
2087                 if(!cheatcount_total)
2088                 {
2089                         if(autocvar_sv_db_saveasdump)
2090                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2091                         else
2092                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2093                 }
2094                 if(autocvar_developer)
2095                 {
2096                         if(autocvar_sv_db_saveasdump)
2097                                 db_dump(TemporaryDB, "server-temp.db");
2098                         else
2099                                 db_save(TemporaryDB, "server-temp.db");
2100                 }
2101                 CheatShutdown(); // must be after cheatcount check
2102                 db_close(ServerProgsDB);
2103                 db_close(TemporaryDB);
2104                 LOG_TRACE("Saving persistent data... done!\n");
2105                 // tell the bot system the game is ending now
2106                 bot_endgame();
2107
2108                 WeaponStats_Shutdown();
2109                 MapInfo_Shutdown();
2110         }
2111         else if(world_initialized == 0)
2112         {
2113                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2114         }
2115         else
2116         {
2117                 __init_dedicated_server_shutdown();
2118         }
2119 }