qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride())
 193                         GotoNextMap();
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_playerstats_");
 301                 BADPREFIX("g_voice_flood_");
 302                 BADPREFIX("rcon_");
 303                 BADPREFIX("settemp_");
 304                 BADPREFIX("sv_allowdownloads_");
 305                 BADPREFIX("sv_autodemo");
 306                 BADPREFIX("sv_curl_");
 307                 BADPREFIX("sv_eventlog");
 308                 BADPREFIX("sv_logscores_");
 309                 BADPREFIX("sv_master");
 310                 BADPREFIX("sv_weaponstats_");
 311                 BADPREFIX("sv_waypointsprite_");
 312                 BADCVAR("rescan_pending");
 313
 314                 // these can contain player IDs, so better hide
 315                 BADPREFIX("g_forced_team_");
 316
 317                 // mapinfo
 318                 BADCVAR("fraglimit");
 319                 BADCVAR("g_arena");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ca");
 322                 BADCVAR("g_ctf");
 323                 BADCVAR("g_cts");
 324                 BADCVAR("g_dm");
 325                 BADCVAR("g_domination");
 326                 BADCVAR("g_domination_default_teams");
 327                 BADCVAR("g_freezetag");
 328                 BADCVAR("g_keepaway");
 329                 BADCVAR("g_keyhunt");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_keyhunt_teams");
 332                 BADCVAR("g_lms");
 333                 BADCVAR("g_nexball");
 334                 BADCVAR("g_onslaught");
 335                 BADCVAR("g_race");
 336                 BADCVAR("g_race_qualifying_timelimit");
 337                 BADCVAR("g_runematch");
 338                 BADCVAR("g_tdm");
 339                 BADCVAR("g_tdm_teams");
 340                 BADCVAR("leadlimit");
 341                 BADCVAR("nextmap");
 342                 BADCVAR("teamplay");
 343                 BADCVAR("timelimit");
 344
 345                 // long
 346                 BADCVAR("hostname");
 347                 BADCVAR("g_maplist");
 348                 BADCVAR("g_maplist_mostrecent");
 349                 BADCVAR("sv_motd");
 350
 351                 v = cvar_string(k);
 352                 d = cvar_defstring(k);
 353                 if(v == d)
 354                         continue;
 355
 356                 if(adding)
 357                 {
 358                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 359                         if(strlen(cvar_changes) > 16384)
 360                         {
 361                                 cvar_changes = "// too many settings have been changed to show them here\n";
 362                                 adding = 0;
 363                         }
 364                 }
 365
 366                 // now check if the changes are actually gameplay relevant
 367
 368                 // does nothing visible
 369                 BADCVAR("captureleadlimit_override");
 370                 BADCVAR("g_arena_point_leadlimit");
 371                 BADCVAR("g_balance_kill_delay");
 372                 BADCVAR("g_ca_point_leadlimit");
 373                 BADCVAR("g_ctf_captimerecord_always");
 374                 BADCVAR("g_ctf_capture_leadlimit");
 375                 BADCVAR("g_ctf_flag_capture_effects");
 376                 BADCVAR("g_ctf_flag_glowtrails");
 377                 BADCVAR("g_ctf_flag_pickup_effects");
 378                 BADCVAR("g_domination_point_leadlimit");
 379                 BADCVAR("g_forced_respawn");
 380                 BADCVAR("g_keyhunt_point_leadlimit");
 381                 BADCVAR("g_nexball_goalleadlimit");
 382                 BADCVAR("g_runematch_point_leadlimit");
 383                 BADCVAR("leadlimit_and_fraglimit");
 384                 BADCVAR("leadlimit_override");
 385                 BADCVAR("pausable");
 386                 BADCVAR("sv_allow_fullbright");
 387                 BADCVAR("sv_checkforpacketsduringsleep");
 388                 BADCVAR("sv_timeout");
 389                 BADCVAR("welcome_message_time");
 390                 BADPREFIX("crypto_");
 391                 BADPREFIX("g_chat_");
 392                 BADPREFIX("g_ctf_captimerecord_");
 393                 BADPREFIX("g_maplist_votable_");
 394                 BADPREFIX("net_");
 395                 BADPREFIX("prvm_");
 396                 BADPREFIX("skill_");
 397                 BADPREFIX("sv_cullentities_");
 398                 BADPREFIX("sv_fraginfo_");
 399                 BADPREFIX("sv_maxidle_");
 400                 BADPREFIX("sv_vote_");
 401                 BADPREFIX("timelimit_");
 402                 BADCVAR("gameversion");
 403                 BADPREFIX("gameversion_");
 404                 BADCVAR("sv_namechangetimer");
 405 #ifndef NO_LEGACY_NETWORKING
 406                 BADCVAR("sv_use_csqc_players"); // transition
 407 #endif
 408
 409                 // allowed changes to server admins (please sync this to server.cfg)
 410                 // vi commands:
 411                 //   :/"impure"/,$d
 412                 //   :g!,^\/\/[^ /],d
 413                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 414                 //   :%!sort
 415                 // yes, this does contain some redundant stuff, don't really care
 416                 BADCVAR("bot_config_file");
 417                 BADCVAR("bot_number");
 418                 BADCVAR("bot_prefix");
 419                 BADCVAR("bot_suffix");
 420                 BADCVAR("capturelimit_override");
 421                 BADCVAR("fraglimit_override");
 422                 BADCVAR("gametype");
 423                 BADCVAR("g_antilag");
 424                 BADCVAR("g_balance_teams");
 425                 BADCVAR("g_balance_teams_force");
 426                 BADCVAR("g_ban_sync_trusted_servers");
 427                 BADCVAR("g_ban_sync_uri");
 428                 BADCVAR("g_ctf_capture_limit");
 429                 BADCVAR("g_ctf_ignore_frags");
 430                 BADCVAR("g_ctf_win_mode");
 431                 BADCVAR("g_domination_point_limit");
 432                 BADCVAR("g_friendlyfire");
 433                 BADCVAR("g_fullbrightitems");
 434                 BADCVAR("g_fullbrightplayers");
 435                 BADCVAR("g_keyhunt_point_limit");
 436                 BADCVAR("g_keyhunt_teams_override");
 437                 BADCVAR("g_lms_lives_override");
 438                 BADCVAR("g_maplist");
 439                 BADCVAR("g_maplist_check_waypoints");
 440                 BADCVAR("g_maplist_mostrecent_count");
 441                 BADCVAR("g_maplist_shuffle");
 442                 BADCVAR("g_maplist_votable");
 443                 BADCVAR("g_maplist_votable_abstain");
 444                 BADCVAR("g_maplist_votable_nodetail");
 445                 BADCVAR("g_maplist_votable_suggestions");
 446                 BADCVAR("g_maxplayers");
 447                 BADCVAR("g_minstagib");
 448                 BADCVAR("g_mirrordamage");
 449                 BADCVAR("g_nexball_goallimit");
 450                 BADCVAR("g_powerups");
 451                 BADCVAR("g_runematch_point_limit");
 452                 BADCVAR("g_start_delay");
 453                 BADCVAR("g_warmup");
 454                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 455                 BADCVAR("hostname");
 456                 BADCVAR("log_file");
 457                 BADCVAR("maxplayers");
 458                 BADCVAR("minplayers");
 459                 BADCVAR("net_address");
 460                 BADCVAR("port");
 461                 BADCVAR("rcon_password");
 462                 BADCVAR("rcon_restricted_commands");
 463                 BADCVAR("rcon_restricted_password");
 464                 BADCVAR("skill");
 465                 BADCVAR("sv_adminnick");
 466                 BADCVAR("sv_autoscreenshot");
 467                 BADCVAR("sv_autotaunt");
 468                 BADCVAR("sv_curl_defaulturl");
 469                 BADCVAR("sv_defaultcharacter");
 470                 BADCVAR("sv_defaultplayercolors");
 471                 BADCVAR("sv_defaultplayermodel");
 472                 BADCVAR("sv_defaultplayerskin");
 473                 BADCVAR("sv_maxidle");
 474                 BADCVAR("sv_maxrate");
 475                 BADCVAR("sv_motd");
 476                 BADCVAR("sv_public");
 477                 BADCVAR("sv_ready_restart");
 478                 BADCVAR("sv_status_privacy");
 479                 BADCVAR("sv_taunt");
 480                 BADCVAR("sv_vote_call");
 481                 BADCVAR("sv_vote_commands");
 482                 BADCVAR("sv_vote_majority_factor");
 483                 BADCVAR("sv_vote_master");
 484                 BADCVAR("sv_vote_master_commands");
 485                 BADCVAR("sv_vote_master_password");
 486                 BADCVAR("sv_vote_simple_majority_factor");
 487                 BADCVAR("sys_ticrate");
 488                 BADCVAR("teamplay_mode");
 489                 BADCVAR("timelimit_override");
 490                 BADPREFIX("g_warmup_");
 491                 BADPREFIX("sv_ready_restart_");
 492
 493                 if(autocvar_g_minstagib)
 494                 {
 495                         BADCVAR("g_grappling_hook");
 496                         BADCVAR("g_jetpack");
 497                 }
 498 #undef BADPREFIX
 499 #undef BADCVAR
 500
 501                 if(pureadding)
 502                 {
 503                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 504                         if(strlen(cvar_purechanges) > 16384)
 505                         {
 506                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 507                                 pureadding = 0;
 508                         }
 509                 }
 510                 ++cvar_purechanges_count;
 511                 // WARNING: this variable is used for the server list
 512                 // NEVER dare to skip this code!
 513                 // Hacks to intentionally appearing as "pure server" even though you DO have
 514                 // modified settings may be punished by removal from the server list.
 515                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 516                 // though.
 517         }
 518         buf_del(h);
 519         if(cvar_changes == "")
 520                 cvar_changes = "// this server runs at default server settings\n";
 521         else
 522                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 523         cvar_changes = strzone(cvar_changes);
 524         if(cvar_purechanges == "")
 525                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 526         else
 527                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 528         cvar_purechanges = strzone(cvar_purechanges);
 529 }
 530
 531 void detect_maptype()
 532 {
 533 #if 0
 534         vector o, v;
 535         float i;
 536
 537         for(;;)
 538         {
 539                 o = world.mins;
 540                 o_x += random() * (world.maxs_x - world.mins_x);
 541                 o_y += random() * (world.maxs_y - world.mins_y);
 542                 o_z += random() * (world.maxs_z - world.mins_z);
 543
 544                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 545                 if(trace_fraction == 1)
 546                         continue;
 547
 548                 v = trace_endpos;
 549
 550                 for(i = 0; i < 64; i += 4)
 551                 {
 552                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 553         if(trace_fraction == 1)
 554                 continue;
 555                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 556                 }
 557
 558                 break;
 559         }
 560 #endif
 561 }
 562
 563 entity randomseed;
 564 float RandomSeed_Send(entity to, float sf)
 565 {
 566         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 567         WriteShort(MSG_ENTITY, self.cnt);
 568         return TRUE;
 569 }
 570 void RandomSeed_Think()
 571 {
 572         self.cnt = bound(0, floor(random() * 65536), 65535);
 573         self.nextthink = time + 5;
 574
 575         self.SendFlags |= 1;
 576 }
 577 void RandomSeed_Spawn()
 578 {
 579         randomseed = spawn();
 580         randomseed.think = RandomSeed_Think;
 581         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 582
 583         entity oldself;
 584         oldself = self;
 585         self = randomseed;
 586         self.think(); // sets random seed and nextthink
 587         self = oldself;
 588 }
 589
 590 void spawnfunc___init_dedicated_server(void)
 591 {
 592         // handler for _init/_init map (only for dedicated server initialization)
 593
 594         world_initialized = -1; // don't complain
 595         cvar = cvar_normal;
 596         cvar_string = cvar_string_normal;
 597         cvar_set = cvar_set_normal;
 598
 599         remove = remove_unsafely;
 600
 601         entity e;
 602         e = spawn();
 603         e.think = GotoFirstMap;
 604         e.nextthink = time; // this is usually 1 at this point
 605
 606         e = spawn();
 607         e.classname = "info_player_deathmatch"; // safeguard against player joining
 608
 609         self.classname = "worldspawn"; // safeguard against various stuff ;)
 610
 611         MapInfo_Enumerate();
 612         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 613 }
 614
 615 void Map_MarkAsRecent(string m);
 616 float world_already_spawned;
 617 void RegisterWeapons();
 618 void Nagger_Init();
 619 void Item_ItemsTime_Init();
 620 void ClientInit_Spawn();
 621 void WeaponStats_Init();
 622 void WeaponStats_Shutdown();
 623 void spawnfunc_worldspawn (void)
 624 {
 625         float fd, l, i, j, n;
 626         string s, col;
 627
 628         cvar = cvar_normal;
 629         cvar_string = cvar_string_normal;
 630         cvar_set = cvar_set_normal;
 631
 632         if(world_already_spawned)
 633                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 634         world_already_spawned = TRUE;
 635
 636         remove = remove_safely; // during spawning, watch what you remove!
 637
 638         check_unacceptable_compiler_bugs();
 639
 640         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 641
 642         compressShortVector_init();
 643
 644         allowed_to_spawn = TRUE;
 645
 646         entity head;
 647         head = nextent(world);
 648         maxclients = 0;
 649         while(head)
 650         {
 651                 ++maxclients;
 652                 head = nextent(head);
 653         }
 654
 655         // needs to be done so early as they would still spawn
 656         RegisterWeapons();
 657
 658         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 659
 660         TemporaryDB = db_create();
 661
 662         // 0 normal
 663         lightstyle(0, "m");
 664
 665         // 1 FLICKER (first variety)
 666         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 667
 668         // 2 SLOW STRONG PULSE
 669         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 670
 671         // 3 CANDLE (first variety)
 672         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 673
 674         // 4 FAST STROBE
 675         lightstyle(4, "mamamamamama");
 676
 677         // 5 GENTLE PULSE 1
 678         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 679
 680         // 6 FLICKER (second variety)
 681         lightstyle(6, "nmonqnmomnmomomno");
 682
 683         // 7 CANDLE (second variety)
 684         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 685
 686         // 8 CANDLE (third variety)
 687         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 688
 689         // 9 SLOW STROBE (fourth variety)
 690         lightstyle(9, "aaaaaaaazzzzzzzz");
 691
 692         // 10 FLUORESCENT FLICKER
 693         lightstyle(10, "mmamammmmammamamaaamammma");
 694
 695         // 11 SLOW PULSE NOT FADE TO BLACK
 696         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 697
 698         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 699
 700         // 63 testing
 701         lightstyle(63, "a");
 702
 703         if(autocvar_g_campaign)
 704                 CampaignPreInit();
 705
 706         Map_MarkAsRecent(mapname);
 707
 708         precache_model ("null"); // we need this one before InitGameplayMode
 709         InitGameplayMode();
 710         readlevelcvars();
 711         GrappleHookInit();
 712         ElectroInit();
 713         LaserInit();
 714
 715         player_count = 0;
 716         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 717         if(bot_waypoints_for_items == 1)
 718                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 719                         bot_waypoints_for_items = 0;
 720
 721         precache();
 722
 723         WaypointSprite_Init();
 724
 725         //if (g_domination)
 726         //      dom_init();
 727
 728         GameLogInit(); // prepare everything
 729         // NOTE for matchid:
 730         // changing the logic generating it is okay. But:
 731         // it HAS to stay <= 64 chars
 732         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 733         if(autocvar_sv_eventlog)
 734         {
 735                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 736                 matchid = strzone(s);
 737
 738                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 739                 s = ":gameinfo:mutators:LIST";
 740
 741                 ret_string = s;
 742                 MUTATOR_CALLHOOK(BuildMutatorsString);
 743                 s = ret_string;
 744
 745                 // simple, probably not good in the mutator system
 746                 if(autocvar_g_grappling_hook)
 747                         s = strcat(s, ":grappling_hook");
 748
 749                 // initialiation stuff, not good in the mutator system
 750                 if(!autocvar_g_use_ammunition)
 751                         s = strcat(s, ":no_use_ammunition");
 752
 753                 // initialiation stuff, not good in the mutator system
 754                 if(autocvar_g_pickup_items == 0)
 755                         s = strcat(s, ":no_pickup_items");
 756                 if(autocvar_g_pickup_items > 0)
 757                         s = strcat(s, ":pickup_items");
 758
 759                 // initialiation stuff, not good in the mutator system
 760                 if(autocvar_g_weaponarena != "0")
 761                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 762
 763                 // TODO to mutator system
 764                 if(autocvar_g_norecoil)
 765                         s = strcat(s, ":norecoil");
 766
 767                 // TODO to mutator system
 768                 if(autocvar_g_midair)
 769                         s = strcat(s, ":midair");
 770
 771                 // TODO to mutator system
 772                 if(autocvar_g_minstagib)
 773                         s = strcat(s, ":minstagib");
 774
 775                 // TODO to mutator system
 776                 if(autocvar_g_powerups == 0)
 777                         s = strcat(s, ":no_powerups");
 778                 if(autocvar_g_powerups > 0)
 779                         s = strcat(s, ":powerups");
 780
 781                 GameLogEcho(s);
 782                 GameLogEcho(":gameinfo:end");
 783         }
 784         else
 785                 matchid = strzone(ftos(random()));
 786
 787         cvar_set("nextmap", "");
 788
 789         SetDefaultAlpha();
 790
 791         if(autocvar_g_campaign)
 792                 CampaignPostInit();
 793
 794         fteqcc_testbugs();
 795
 796         Ban_LoadBans();
 797
 798         MapInfo_Enumerate();
 799         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 800
 801         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 802         {
 803                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 804                 if(fd != -1)
 805                 {
 806                         while((s = fgets(fd)))
 807                         {
 808                                 l = tokenize_console(s);
 809                                 if(l < 2)
 810                                         continue;
 811                                 if(argv(0) == "cd")
 812                                 {
 813                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 814                                         print("  cdtrack ", argv(2), "\n");
 815                                 }
 816                                 else if(argv(0) == "fog")
 817                                 {
 818                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 819                                         print("  \"fog\" \"", s, "\"\n");
 820                                 }
 821                                 else if(argv(0) == "set")
 822                                 {
 823                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 824                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 825                                 }
 826                                 else if(argv(0) != "//")
 827                                 {
 828                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 829                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 830                                 }
 831                         }
 832                         fclose(fd);
 833                 }
 834         }
 835
 836         WeaponStats_Init();
 837
 838         addstat(STAT_WEAPONS, AS_INT, weapons);
 839         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 840         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 841         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 842         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 843         Nagger_Init();
 844
 845         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 846         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 847         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 848         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 849         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 850         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 851         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 852         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 853         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 854         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 855         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 856         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 857
 858         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 859         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 860
 861         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 862
 863         addstat(STAT_ARMOR_LARGE_TIME, AS_FLOAT, item_armor_large_time);
 864         addstat(STAT_HEALTH_MEGA_TIME, AS_FLOAT, item_health_mega_time);
 865         addstat(STAT_STRENGTH_TIME, AS_FLOAT, item_strength_time);
 866         addstat(STAT_INVISIBLE_TIME, AS_FLOAT, item_invisible_time);
 867         addstat(STAT_EXTRALIFE_TIME, AS_FLOAT, item_extralife_time);
 868         addstat(STAT_SPEED_TIME, AS_FLOAT, item_speed_time);
 869         addstat(STAT_SHIELD_TIME, AS_FLOAT, item_shield_time);
 870         addstat(STAT_FUELREGEN_TIME, AS_FLOAT, item_fuelregen_time);
 871         addstat(STAT_JETPACK_TIME, AS_FLOAT, item_jetpack_time);
 872         Item_ItemsTime_Init();
 873
 874         if(g_ca || g_freezetag)
 875         {
 876                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 877                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 878                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 879                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 880         }
 881         if(g_freezetag)
 882         {
 883                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 884                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 885         }
 886
 887         // g_movementspeed hack
 888         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 889         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 890         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 891         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 892
 893         // secrets
 894         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 895         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 896
 897         next_pingtime = time + 5;
 898
 899         detect_maptype();
 900
 901         lsmaps_reply = "^7Maps available: ";
 902         lsnewmaps_reply = "^7Maps without a record set: ";
 903         for(i = 0, j = 0; i < MapInfo_count; ++i)
 904         {
 905                 if(MapInfo_Get_ByID(i))
 906                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 907                         {
 908                                 if(mod(i, 2))
 909                                         col = "^2";
 910                                 else
 911                                         col = "^3";
 912                                 ++j;
 913                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 914                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 915                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 916                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 917                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 918                         }
 919         }
 920         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 921         if (!g_race && !g_cts)
 922                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 923         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 924
 925         maplist_reply = "^7Maps in list: ";
 926         n = tokenize_console(autocvar_g_maplist);
 927         for(i = 0, j = 0; i < n; ++i)
 928         {
 929                 if(MapInfo_CheckMap(argv(i)))
 930                 {
 931                         if(mod(j, 2))
 932                                 col = "^2";
 933                         else
 934                                 col = "^3";
 935                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 936                         ++j;
 937                 }
 938         }
 939         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 940         MapInfo_ClearTemps();
 941
 942         for(i = 0; i < 10; ++i)
 943         {
 944                 records_reply[i] = strzone(getrecords(i));
 945         }
 946         if(g_cts)
 947                 ladder_reply = strzone(getladder());
 948
 949         rankings_reply = strzone(getrankings());
 950
 951         ClientInit_Spawn();
 952         RandomSeed_Spawn();
 953         PingPLReport_Spawn();
 954
 955         CheatInit();
 956
 957         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 958
 959         // fill sv_curl_serverpackages from .serverpackage files
 960         if(autocvar_sv_curl_serverpackages_auto)
 961         {
 962                 s = "";
 963                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 964                 for(i = 0; i < n; ++i)
 965                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 966                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 967                                 s = strcat(s, " ", argv(i));
 968                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 969                 if(fd >= 0)
 970                 {
 971                         j = search_getsize(fd);
 972                         for(i = 0; i < j; ++i)
 973                                 s = strcat(s, " ", search_getfilename(fd, i));
 974                         search_end(fd);
 975                 }
 976                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 977                 if(fd >= 0)
 978                 {
 979                         j = search_getsize(fd);
 980                         for(i = 0; i < j; ++i)
 981                                 s = strcat(s, " ", search_getfilename(fd, i));
 982                         search_end(fd);
 983                 }
 984                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 985         }
 986
 987         PlayerStats_Init();
 988
 989         world_initialized = 1;
 990 }
 991
 992 void spawnfunc_light (void)
 993 {
 994         //makestatic (self); // Who the f___ did that?
 995         remove(self);
 996 }
 997
 998 string GetGametype()
 999 {
1000         return GametypeNameFromType(game);
1001 }
1002
1003 string getmapname_stored;
1004 string GetMapname()
1005 {
1006         return mapname;
1007 }
1008
1009 float Map_Count, Map_Current;
1010 string Map_Current_Name;
1011
1012 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1013 float GetMaplistPosition()
1014 {
1015         float pos, idx;
1016         string map;
1017
1018         map = GetMapname();
1019         idx = autocvar_g_maplist_index;
1020
1021         if(idx >= 0)
1022                 if(idx < Map_Count)
1023                         if(map == argv(idx))
1024                                 return idx;
1025
1026         for(pos = 0; pos < Map_Count; ++pos)
1027                 if(map == argv(pos))
1028                         return pos;
1029
1030         // resume normal maplist rotation if current map is not in g_maplist
1031         return idx;
1032 }
1033
1034 float MapHasRightSize(string map)
1035 {
1036         float fh;
1037         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1038         if(autocvar_g_maplist_check_waypoints)
1039         {
1040                 dprint("checkwp "); dprint(map);
1041                 if(!fexists(strcat("maps/", map, ".waypoints")))
1042                 {
1043                         dprint(": no waypoints\n");
1044                         return FALSE;
1045                 }
1046                 dprint(": has waypoints\n");
1047         }
1048
1049         // open map size restriction file
1050         dprint("opensize "); dprint(map);
1051         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1052         if(fh >= 0)
1053         {
1054                 float mapmin, mapmax;
1055                 dprint(": ok, ");
1056                 mapmin = stof(fgets(fh));
1057                 mapmax = stof(fgets(fh));
1058                 fclose(fh);
1059                 if(player_count < mapmin)
1060                 {
1061                         dprint("not enough\n");
1062                         return FALSE;
1063                 }
1064                 if(player_count > mapmax)
1065                 {
1066                         dprint("too many\n");
1067                         return FALSE;
1068                 }
1069                 dprint("right size\n");
1070                 return TRUE;
1071         }
1072         dprint(": not found\n");
1073         return TRUE;
1074 }
1075
1076 string Map_Filename(float position)
1077 {
1078         return strcat("maps/", argv(position), ".bsp");
1079 }
1080
1081 string strwords(string s, float w)
1082 {
1083         float endpos;
1084         for(endpos = 0; w && endpos >= 0; --w)
1085                 endpos = strstrofs(s, " ", endpos + 1);
1086         if(endpos < 0)
1087                 return s;
1088         else
1089                 return substring(s, 0, endpos);
1090 }
1091
1092 float strhasword(string s, string w)
1093 {
1094         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1095 }
1096
1097 void Map_MarkAsRecent(string m)
1098 {
1099         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1100 }
1101
1102 float Map_IsRecent(string m)
1103 {
1104         return strhasword(autocvar_g_maplist_mostrecent, m);
1105 }
1106
1107 float Map_Check(float position, float pass)
1108 {
1109         string filename;
1110         string map_next;
1111         map_next = argv(position);
1112         if(pass <= 1)
1113         {
1114                 if(Map_IsRecent(map_next))
1115                         return 0;
1116         }
1117         filename = Map_Filename(position);
1118         if(MapInfo_CheckMap(map_next))
1119         {
1120                 if(pass == 2)
1121                         return 1;
1122                 if(MapHasRightSize(map_next))
1123                         return 1;
1124                 return 0;
1125         }
1126         else
1127                 dprint( "Couldn't select '", filename, "'..\n" );
1128
1129         return 0;
1130 }
1131
1132 void Map_Goto_SetStr(string nextmapname)
1133 {
1134         if(getmapname_stored != "")
1135                 strunzone(getmapname_stored);
1136         if(nextmapname == "")
1137                 getmapname_stored = "";
1138         else
1139                 getmapname_stored = strzone(nextmapname);
1140 }
1141
1142 void Map_Goto_SetFloat(float position)
1143 {
1144         cvar_set("g_maplist_index", ftos(position));
1145         Map_Goto_SetStr(argv(position));
1146 }
1147
1148 void GameResetCfg()
1149 {
1150         // settings persist, except...
1151         localcmd("\nsettemp_restore\n");
1152 }
1153
1154 void Map_Goto()
1155 {
1156         GameResetCfg();
1157         MapInfo_LoadMap(getmapname_stored);
1158 }
1159
1160 // return codes of map selectors:
1161 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1162 //   -2 = permanent failure
1163 float() MaplistMethod_Iterate = // usual method
1164 {
1165         float pass, i;
1166
1167         for(pass = 1; pass <= 2; ++pass)
1168         {
1169                 for(i = 1; i < Map_Count; ++i)
1170                 {
1171                         float mapindex;
1172                         mapindex = mod(i + Map_Current, Map_Count);
1173                         if(Map_Check(mapindex, pass))
1174                                 return mapindex;
1175                 }
1176         }
1177         return -1;
1178 }
1179
1180 float() MaplistMethod_Repeat = // fallback method
1181 {
1182         if(Map_Check(Map_Current, 2))
1183                 return Map_Current;
1184         return -2;
1185 }
1186
1187 float() MaplistMethod_Random = // random map selection
1188 {
1189         float i, imax;
1190
1191         imax = 42;
1192
1193         for(i = 0; i <= imax; ++i)
1194         {
1195                 float mapindex;
1196                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1197                 if(Map_Check(mapindex, 1))
1198                         return mapindex;
1199         }
1200         return -1;
1201 }
1202
1203 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1204 // the exponent sets a bias on the map selection:
1205 // the higher the exponent, the less likely "shortly repeated" same maps are
1206 {
1207         float i, j, imax, insertpos;
1208
1209         imax = 42;
1210
1211         for(i = 0; i <= imax; ++i)
1212         {
1213                 string newlist;
1214
1215                 // now reinsert this at another position
1216                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1217                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1218                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1219                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1220
1221                 // insert the current map there
1222                 newlist = "";
1223                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1224                         newlist = strcat(newlist, " ", argv(j));
1225                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1226                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1227                         newlist = strcat(newlist, " ", argv(j));
1228                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1229                 cvar_set("g_maplist", newlist);
1230                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1231
1232                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1233                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1234                 if(Map_Check(Map_Current, 1))
1235                         return Map_Current;
1236         }
1237         return -1;
1238 }
1239
1240 void Maplist_Init()
1241 {
1242         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1243         if(Map_Count == 0)
1244         {
1245                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1246                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1247                 if(autocvar_g_maplist_shuffle)
1248                         ShuffleMaplist();
1249                 localcmd("\nmenu_cmd sync\n");
1250                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1251         }
1252         if(Map_Count == 0)
1253                 error("empty maplist, cannot select a new map");
1254         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1255
1256         if(Map_Current_Name)
1257                 strunzone(Map_Current_Name);
1258         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1259         // this may or may not be correct, but who cares, in the worst case a map
1260         // isn't chosen in the first pass that should have been
1261 }
1262
1263 string GetNextMap()
1264 {
1265         float nextMap;
1266
1267         Maplist_Init();
1268         nextMap = -1;
1269
1270         if(nextMap == -1)
1271                 if(autocvar_g_maplist_shuffle > 0)
1272                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1273
1274         if(nextMap == -1)
1275                 if(autocvar_g_maplist_selectrandom)
1276                         nextMap = MaplistMethod_Random();
1277
1278         if(nextMap == -1)
1279                 nextMap = MaplistMethod_Iterate();
1280
1281         if(nextMap == -1)
1282                 nextMap = MaplistMethod_Repeat();
1283
1284         if(nextMap >= 0)
1285         {
1286                 Map_Goto_SetFloat(nextMap);
1287                 return getmapname_stored;
1288         }
1289
1290         return "";
1291 }
1292
1293 float DoNextMapOverride()
1294 {
1295         if(autocvar_g_campaign)
1296         {
1297                 CampaignPostIntermission();
1298                 alreadychangedlevel = TRUE;
1299                 return TRUE;
1300         }
1301         if(autocvar_quit_when_empty)
1302         {
1303                 if(player_count <= currentbots)
1304                 {
1305                         localcmd("quit\n");
1306                         alreadychangedlevel = TRUE;
1307                         return TRUE;
1308                 }
1309         }
1310         if(autocvar_quit_and_redirect != "")
1311         {
1312                 redirection_target = strzone(autocvar_quit_and_redirect);
1313                 alreadychangedlevel = TRUE;
1314                 return TRUE;
1315         }
1316         if (autocvar_samelevel) // if samelevel is set, stay on same level
1317         {
1318                 localcmd("restart\n");
1319                 alreadychangedlevel = TRUE;
1320                 return TRUE;
1321         }
1322         if(autocvar_nextmap != "")
1323                 if(MapInfo_CheckMap(autocvar_nextmap))
1324                 {
1325                         Map_Goto_SetStr(autocvar_nextmap);
1326                         Map_Goto();
1327                         alreadychangedlevel = TRUE;
1328                         return TRUE;
1329                 }
1330         if(autocvar_lastlevel)
1331         {
1332                 GameResetCfg();
1333                 localcmd("set lastlevel 0\ntogglemenu\n");
1334                 alreadychangedlevel = TRUE;
1335                 return TRUE;
1336         }
1337         return FALSE;
1338 }
1339
1340 void GotoNextMap()
1341 {
1342         //string nextmap;
1343         //float n, nummaps;
1344         //string s;
1345         if (alreadychangedlevel)
1346                 return;
1347         alreadychangedlevel = TRUE;
1348
1349         {
1350                 string nextMap;
1351                 float allowReset;
1352
1353                 for(allowReset = 1; allowReset >= 0; --allowReset)
1354                 {
1355                         nextMap = GetNextMap();
1356                         if(nextMap != "")
1357                                 break;
1358
1359                         if(allowReset)
1360                         {
1361                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1362                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1363                                 if(autocvar_g_maplist_shuffle)
1364                                         ShuffleMaplist();
1365                                 localcmd("\nmenu_cmd sync\n");
1366                         }
1367                         else
1368                         {
1369                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1370                         }
1371                 }
1372                 Map_Goto();
1373         }
1374 }
1375
1376
1377 /*
1378 ============
1379 IntermissionThink
1380
1381 When the player presses attack or jump, change to the next level
1382 ============
1383 */
1384 .float autoscreenshot;
1385 void() MapVote_Start;
1386 void() MapVote_Think;
1387 float mapvote_initialized;
1388 void IntermissionThink()
1389 {
1390         FixIntermissionClient(self);
1391
1392         if( (autocvar_sv_autoscreenshot || self.cvar_cl_autoscreenshot)
1393                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1394         {
1395                 self.autoscreenshot = -1;
1396                 if(clienttype(self) == CLIENTTYPE_REAL)
1397                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1398                 return;
1399         }
1400
1401         if (time < intermission_exittime)
1402                 return;
1403
1404         if(!mapvote_initialized)
1405                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1406                         return;
1407
1408         MapVote_Start();
1409 }
1410
1411 /*
1412 ============
1413 FindIntermission
1414
1415 Returns the entity to view from
1416 ============
1417 */
1418 /*
1419 entity FindIntermission()
1420 {
1421         local   entity spot;
1422         local   float cyc;
1423
1424 // look for info_intermission first
1425         spot = find (world, classname, "info_intermission");
1426         if (spot)
1427         {       // pick a random one
1428                 cyc = random() * 4;
1429                 while (cyc > 1)
1430                 {
1431                         spot = find (spot, classname, "info_intermission");
1432                         if (!spot)
1433                                 spot = find (spot, classname, "info_intermission");
1434                         cyc = cyc - 1;
1435                 }
1436                 return spot;
1437         }
1438
1439 // then look for the start position
1440         spot = find (world, classname, "info_player_start");
1441         if (spot)
1442                 return spot;
1443
1444 // testinfo_player_start is only found in regioned levels
1445         spot = find (world, classname, "testplayerstart");
1446         if (spot)
1447                 return spot;
1448
1449 // then look for the start position
1450         spot = find (world, classname, "info_player_deathmatch");
1451         if (spot)
1452                 return spot;
1453
1454         //objerror ("FindIntermission: no spot");
1455         return world;
1456 }
1457 */
1458
1459 /*
1460 ===============================================================================
1461
1462 RULES
1463
1464 ===============================================================================
1465 */
1466
1467 void DumpStats(float final)
1468 {
1469         float file;
1470         string s;
1471         float to_console;
1472         float to_eventlog;
1473         float to_file;
1474         float i;
1475
1476         to_console = autocvar_sv_logscores_console;
1477         to_eventlog = autocvar_sv_eventlog;
1478         to_file = autocvar_sv_logscores_file;
1479
1480         if(!final)
1481         {
1482                 to_console = TRUE; // always print printstats replies
1483                 to_eventlog = FALSE; // but never print them to the event log
1484         }
1485
1486         if(to_eventlog)
1487                 if(autocvar_sv_eventlog_console)
1488                         to_console = FALSE; // otherwise we get the output twice
1489
1490         if(final)
1491                 s = ":scores:";
1492         else
1493                 s = ":status:";
1494         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1495
1496         if(to_console)
1497                 print(s, "\n");
1498         if(to_eventlog)
1499                 GameLogEcho(s);
1500         if(to_file)
1501         {
1502                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1503                 if(file == -1)
1504                         to_file = FALSE;
1505                 else
1506                         fputs(file, strcat(s, "\n"));
1507         }
1508
1509         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1510         if(to_console)
1511                 print(s, "\n");
1512         if(to_eventlog)
1513                 GameLogEcho(s);
1514         if(to_file)
1515                 fputs(file, strcat(s, "\n"));
1516
1517         FOR_EACH_CLIENT(other)
1518         {
1519                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1520                 {
1521                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1522                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1523                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1524                                 s = strcat(s, ftos(other.team), ":");
1525                         else
1526                                 s = strcat(s, "spectator:");
1527
1528                         if(to_console)
1529                                 print(s, other.netname, "\n");
1530                         if(to_eventlog)
1531                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1532                         if(to_file)
1533                                 fputs(file, strcat(s, other.netname, "\n"));
1534                 }
1535         }
1536
1537         if(teamplay)
1538         {
1539                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1540                 if(to_console)
1541                         print(s, "\n");
1542                 if(to_eventlog)
1543                         GameLogEcho(s);
1544                 if(to_file)
1545                         fputs(file, strcat(s, "\n"));
1546
1547                 for(i = 1; i < 16; ++i)
1548                 {
1549                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1550                         s = strcat(s, ":", ftos(i));
1551                         if(to_console)
1552                                 print(s, "\n");
1553                         if(to_eventlog)
1554                                 GameLogEcho(s);
1555                         if(to_file)
1556                                 fputs(file, strcat(s, "\n"));
1557                 }
1558         }
1559
1560         if(to_console)
1561                 print(":end\n");
1562         if(to_eventlog)
1563                 GameLogEcho(":end");
1564         if(to_file)
1565         {
1566                 fputs(file, ":end\n");
1567                 fclose(file);
1568         }
1569 }
1570
1571 void FixIntermissionClient(entity e)
1572 {
1573         string s;
1574         if(!e.autoscreenshot) // initial call
1575         {
1576                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1577                 e.health = -2342;
1578                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1579                 e.solid = SOLID_NOT;
1580                 e.movetype = MOVETYPE_NONE;
1581                 e.takedamage = DAMAGE_NO;
1582                 if(e.weaponentity)
1583                 {
1584                         e.weaponentity.effects = EF_NODRAW;
1585                         if (e.weaponentity.weaponentity)
1586                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1587                 }
1588                 if(clienttype(e) == CLIENTTYPE_REAL)
1589                 {
1590                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1591                         s = autocvar_sv_intermission_cdtrack;
1592                         if(s != "")
1593                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1594                         msg_entity = e;
1595                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1596                 }
1597         }
1598 }
1599
1600
1601 /*
1602 go to the next level for deathmatch
1603 only called if a time or frag limit has expired
1604 */
1605 void NextLevel()
1606 {
1607         gameover = TRUE;
1608
1609         intermission_running = 1;
1610
1611 // enforce a wait time before allowing changelevel
1612         if(player_count > 0)
1613                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1614         else
1615                 intermission_exittime = -1;
1616
1617         /*
1618         WriteByte (MSG_ALL, SVC_CDTRACK);
1619         WriteByte (MSG_ALL, 3);
1620         WriteByte (MSG_ALL, 3);
1621         // done in FixIntermission
1622         */
1623
1624         //pos = FindIntermission ();
1625
1626         VoteReset();
1627
1628         DumpStats(TRUE);
1629
1630         // send statistics
1631         entity e;
1632         PlayerStats_EndMatch(1);
1633         FOR_EACH_CLIENT(e)
1634                 PlayerStats_AddGlobalInfo(e);
1635         PlayerStats_Shutdown();
1636         WeaponStats_Shutdown();
1637
1638         if(autocvar_sv_eventlog)
1639                 GameLogEcho(":gameover");
1640
1641         GameLogClose();
1642
1643         FOR_EACH_PLAYER(other) {
1644                 FixIntermissionClient(other);
1645                 if(other.winning)
1646                         bprint(other.netname, " ^7wins.\n");
1647         }
1648
1649         if(autocvar_g_campaign)
1650                 CampaignPreIntermission();
1651
1652         localcmd("\nsv_hook_gameend\n");
1653 }
1654
1655 /*
1656 ============
1657 CheckRules_Player
1658
1659 Exit deathmatch games upon conditions
1660 ============
1661 */
1662 void CheckRules_Player()
1663 {
1664         if (gameover)   // someone else quit the game already
1665                 return;
1666
1667         if(self.deadflag == DEAD_NO)
1668                 self.play_time += frametime;
1669
1670         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1671         //   (div0: and that in CheckRules_World please)
1672 }
1673
1674 float checkrules_equality;
1675 float checkrules_suddendeathwarning;
1676 float checkrules_suddendeathend;
1677 float checkrules_overtimesadded; //how many overtimes have been already added
1678
1679 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1680 float WINNING_YES = 1; // winner found
1681 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1682 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1683
1684 float InitiateSuddenDeath()
1685 {
1686         // Check first whether normal overtimes could be added before initiating suddendeath mode
1687         // - for this timelimit_overtime needs to be >0 of course
1688         // - also check the winning condition calculated in the previous frame and only add normal overtime
1689         //   again, if at the point at which timelimit would be extended again, still no winner was found
1690         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1691         {
1692                 return 1; // need to call InitiateOvertime later
1693         }
1694         else
1695         {
1696                 if(!checkrules_suddendeathend)
1697                 {
1698                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1699                         if(g_race && !g_race_qualifying)
1700                                 race_StartCompleting();
1701                 }
1702                 return 0;
1703         }
1704 }
1705
1706 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1707 {
1708         ++checkrules_overtimesadded;
1709         //add one more overtime by simply extending the timelimit
1710         float tl;
1711         tl = autocvar_timelimit;
1712         tl += autocvar_timelimit_overtime;
1713         cvar_set("timelimit", ftos(tl));
1714         string minutesPlural;
1715         if (autocvar_timelimit_overtime == 1)
1716                 minutesPlural = " ^3minute";
1717         else
1718                 minutesPlural = " ^3minutes";
1719
1720         bcenterprint(
1721                 strcat(
1722                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1723                         ftos(autocvar_timelimit_overtime),
1724                         minutesPlural,
1725                         " to the game!"
1726                 )
1727         );
1728 }
1729
1730 float GetWinningCode(float fraglimitreached, float equality)
1731 {
1732         if(autocvar_g_campaign == 1)
1733                 if(fraglimitreached)
1734                         return WINNING_YES;
1735                 else
1736                         return WINNING_NO;
1737
1738         else
1739                 if(equality)
1740                         if(fraglimitreached)
1741                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1742                         else
1743                                 return WINNING_NEVER;
1744                 else
1745                         if(fraglimitreached)
1746                                 return WINNING_YES;
1747                         else
1748                                 return WINNING_NO;
1749 }
1750
1751 // set the .winning flag for exactly those players with a given field value
1752 void SetWinners(.float field, float value)
1753 {
1754         entity head;
1755         FOR_EACH_PLAYER(head)
1756                 head.winning = (head.field == value);
1757 }
1758
1759 // set the .winning flag for those players with a given field value
1760 void AddWinners(.float field, float value)
1761 {
1762         entity head;
1763         FOR_EACH_PLAYER(head)
1764                 if(head.field == value)
1765                         head.winning = 1;
1766 }
1767
1768 // clear the .winning flags
1769 void ClearWinners(void)
1770 {
1771         entity head;
1772         FOR_EACH_PLAYER(head)
1773                 head.winning = 0;
1774 }
1775
1776 // Onslaught winning condition:
1777 // game terminates if only one team has a working generator (or none)
1778 float WinningCondition_Onslaught()
1779 {
1780         entity head;
1781         float t1, t2, t3, t4;
1782
1783         WinningConditionHelper(); // set worldstatus
1784
1785         if(inWarmupStage)
1786                 return WINNING_NO;
1787
1788         // first check if the game has ended
1789         t1 = t2 = t3 = t4 = 0;
1790         head = find(world, classname, "onslaught_generator");
1791         while (head)
1792         {
1793                 if (head.health > 0)
1794                 {
1795                         if (head.team == COLOR_TEAM1) t1 = 1;
1796                         if (head.team == COLOR_TEAM2) t2 = 1;
1797                         if (head.team == COLOR_TEAM3) t3 = 1;
1798                         if (head.team == COLOR_TEAM4) t4 = 1;
1799                 }
1800                 head = find(head, classname, "onslaught_generator");
1801         }
1802         if (t1 + t2 + t3 + t4 < 2)
1803         {
1804                 // game over, only one team remains (or none)
1805                 ClearWinners();
1806                 if (t1) SetWinners(team, COLOR_TEAM1);
1807                 if (t2) SetWinners(team, COLOR_TEAM2);
1808                 if (t3) SetWinners(team, COLOR_TEAM3);
1809                 if (t4) SetWinners(team, COLOR_TEAM4);
1810                 dprint("Have a winner, ending game.\n");
1811                 return WINNING_YES;
1812         }
1813
1814         // Two or more teams remain
1815         return WINNING_NO;
1816 }
1817
1818 float LMS_NewPlayerLives()
1819 {
1820         float fl;
1821         fl = autocvar_fraglimit;
1822         if(fl == 0)
1823                 fl = 999;
1824
1825         // first player has left the game for dying too much? Nobody else can get in.
1826         if(lms_lowest_lives < 1)
1827                 return 0;
1828
1829         if(!autocvar_g_lms_join_anytime)
1830                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1831                         return 0;
1832
1833         return bound(1, lms_lowest_lives, fl);
1834 }
1835
1836 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1837 // they win. Otherwise the defending team wins once the timelimit passes.
1838 void assault_new_round();
1839 float WinningCondition_Assault()
1840 {
1841         float status;
1842
1843         WinningConditionHelper(); // set worldstatus
1844
1845         status = WINNING_NO;
1846         // as the timelimit has not yet passed just assume the defending team will win
1847         if(assault_attacker_team == COLOR_TEAM1)
1848         {
1849                 SetWinners(team, COLOR_TEAM2);
1850         }
1851         else
1852         {
1853                 SetWinners(team, COLOR_TEAM1);
1854         }
1855
1856         entity ent;
1857         ent = find(world, classname, "target_assault_roundend");
1858         if(ent)
1859         {
1860                 if(ent.winning) // round end has been triggered by attacking team
1861                 {
1862                         bprint("ASSAULT: round completed...\n");
1863                         SetWinners(team, assault_attacker_team);
1864
1865                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1866
1867                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1868                         {
1869                                 status = WINNING_YES;
1870                         }
1871                         else
1872                         {
1873                                 entity oldself;
1874                                 oldself = self;
1875                                 self = ent;
1876                                 assault_new_round();
1877                                 self = oldself;
1878                         }
1879                 }
1880         }
1881
1882         return status;
1883 }
1884
1885 // LMS winning condition: game terminates if and only if there's at most one
1886 // one player who's living lives. Top two scores being equal cancels the time
1887 // limit.
1888 float WinningCondition_LMS()
1889 {
1890         entity head, head2;
1891         float have_player;
1892         float have_players;
1893         float l;
1894
1895         have_player = FALSE;
1896         have_players = FALSE;
1897         l = LMS_NewPlayerLives();
1898
1899         head = find(world, classname, "player");
1900         if(head)
1901                 have_player = TRUE;
1902         head2 = find(head, classname, "player");
1903         if(head2)
1904                 have_players = TRUE;
1905
1906         if(have_player)
1907         {
1908                 // we have at least one player
1909                 if(have_players)
1910                 {
1911                         // two or more active players - continue with the game
1912                 }
1913                 else
1914                 {
1915                         // exactly one player?
1916
1917                         ClearWinners();
1918                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1919
1920                         if(l)
1921                         {
1922                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1923                                 return WINNING_NO;
1924                         }
1925                         else
1926                         {
1927                                 // a winner!
1928                                 // and assign him his first place
1929                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1930                                 return WINNING_YES;
1931                         }
1932                 }
1933         }
1934         else
1935         {
1936                 // nobody is playing at all...
1937                 if(l)
1938                 {
1939                         // wait for players...
1940                 }
1941                 else
1942                 {
1943                         // SNAFU (maybe a draw game?)
1944                         ClearWinners();
1945                         dprint("No players, ending game.\n");
1946                         return WINNING_YES;
1947                 }
1948         }
1949
1950         // When we get here, we have at least two players who are actually LIVING,
1951         // now check if the top two players have equal score.
1952         WinningConditionHelper();
1953
1954         ClearWinners();
1955         if(WinningConditionHelper_winner)
1956                 WinningConditionHelper_winner.winning = TRUE;
1957         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1958                 return WINNING_NEVER;
1959
1960         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1961         return WINNING_NO;
1962 }
1963
1964 void ShuffleMaplist()
1965 {
1966         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1967 }
1968
1969 float leaderfrags;
1970 float WinningCondition_Scores(float limit, float leadlimit)
1971 {
1972         float limitreached;
1973
1974         // TODO make everything use THIS winning condition (except LMS)
1975         WinningConditionHelper();
1976
1977         if(teamplay)
1978         {
1979                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1980                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1981                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1982                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1983         }
1984
1985         ClearWinners();
1986         if(WinningConditionHelper_winner)
1987                 WinningConditionHelper_winner.winning = 1;
1988         if(WinningConditionHelper_winnerteam >= 0)
1989                 SetWinners(team, WinningConditionHelper_winnerteam);
1990
1991         if(WinningConditionHelper_lowerisbetter)
1992         {
1993                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1994                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1995                 limit = -limit;
1996         }
1997
1998         if(WinningConditionHelper_zeroisworst)
1999                 leadlimit = 0; // not supported in this mode
2000
2001         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
2002         // these modes always score in increments of 1, thus this makes sense
2003         {
2004                 if(leaderfrags != WinningConditionHelper_topscore)
2005                 {
2006                         leaderfrags = WinningConditionHelper_topscore;
2007
2008                         if (limit)
2009                         if (leaderfrags == limit - 1)
2010                                 Announce("1fragleft");
2011                         else if (leaderfrags == limit - 2)
2012                                 Announce("2fragsleft");
2013                         else if (leaderfrags == limit - 3)
2014                                 Announce("3fragsleft");
2015                 }
2016         }
2017
2018         limitreached = FALSE;
2019         if(limit)
2020                 if(WinningConditionHelper_topscore >= limit)
2021                         limitreached = TRUE;
2022         if(leadlimit)
2023         {
2024                 float leadlimitreached;
2025                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
2026                 if(autocvar_leadlimit_and_fraglimit)
2027                         limitreached = (limitreached && leadlimitreached);
2028                 else
2029                         limitreached = (limitreached || leadlimitreached);
2030         }
2031
2032         return GetWinningCode(
2033                 WinningConditionHelper_topscore && limitreached,
2034                 WinningConditionHelper_equality
2035         );
2036 }
2037
2038 float WinningCondition_Race(float fraglimit)
2039 {
2040         float wc;
2041         entity p;
2042         float n, c;
2043
2044         n = 0;
2045         c = 0;
2046         FOR_EACH_PLAYER(p)
2047         {
2048                 ++n;
2049                 if(p.race_completed)
2050                         ++c;
2051         }
2052         if(n && (n == c))
2053                 return WINNING_YES;
2054         wc = WinningCondition_Scores(fraglimit, 0);
2055
2056         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2057         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2058         // do NOT support equality when the laps are all raced!
2059                 return WINNING_STARTSUDDENDEATHOVERTIME;
2060         else
2061                 return WINNING_NEVER;
2062         return wc;
2063 }
2064
2065 void ReadyRestart();
2066 float WinningCondition_QualifyingThenRace(float limit)
2067 {
2068         float wc;
2069         wc = WinningCondition_Scores(limit, 0);
2070
2071         // NEVER initiate overtime
2072         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2073         {
2074                 return WINNING_YES;
2075         }
2076
2077         return wc;
2078 }
2079
2080 float WinningCondition_RanOutOfSpawns()
2081 {
2082         entity head;
2083
2084         if(have_team_spawns <= 0)
2085                 return WINNING_NO;
2086
2087         if(autocvar_g_spawn_useallspawns <= 0)
2088                 return WINNING_NO;
2089
2090         if(!some_spawn_has_been_used)
2091                 return WINNING_NO;
2092
2093         team1_score = team2_score = team3_score = team4_score = 0;
2094
2095         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2096         {
2097                 if(head.team == COLOR_TEAM1)
2098                         team1_score = 1;
2099                 else if(head.team == COLOR_TEAM2)
2100                         team2_score = 1;
2101                 else if(head.team == COLOR_TEAM3)
2102                         team3_score = 1;
2103                 else if(head.team == COLOR_TEAM4)
2104                         team4_score = 1;
2105         }
2106
2107         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2108         {
2109                 if(head.team == COLOR_TEAM1)
2110                         team1_score = 1;
2111                 else if(head.team == COLOR_TEAM2)
2112                         team2_score = 1;
2113                 else if(head.team == COLOR_TEAM3)
2114                         team3_score = 1;
2115                 else if(head.team == COLOR_TEAM4)
2116                         team4_score = 1;
2117         }
2118
2119         ClearWinners();
2120         if(team1_score + team2_score + team3_score + team4_score == 0)
2121         {
2122                 checkrules_equality = TRUE;
2123                 return WINNING_YES;
2124         }
2125         else if(team1_score + team2_score + team3_score + team4_score == 1)
2126         {
2127                 float t, i;
2128                 if(team1_score) t = COLOR_TEAM1;
2129                 if(team2_score) t = COLOR_TEAM2;
2130                 if(team3_score) t = COLOR_TEAM3;
2131                 if(team4_score) t = COLOR_TEAM4;
2132                 CheckAllowedTeams(world);
2133                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2134                 {
2135                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2136                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2137                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2138                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2139                 }
2140
2141                 AddWinners(team, t);
2142                 return WINNING_YES;
2143         }
2144         else
2145                 return WINNING_NO;
2146 }
2147
2148 /*
2149 ============
2150 CheckRules_World
2151
2152 Exit deathmatch games upon conditions
2153 ============
2154 */
2155 void CheckRules_World()
2156 {
2157         float timelimit;
2158         float fraglimit;
2159         float leadlimit;
2160
2161         VoteThink();
2162         MapVote_Think();
2163
2164         SetDefaultAlpha();
2165
2166         /*
2167         MapVote_Think should now do that part
2168         if (intermission_running)
2169                 if (time >= intermission_exittime + 60)
2170                 {
2171                         if(!DoNextMapOverride())
2172                                 GotoNextMap();
2173                         return;
2174                 }
2175         */
2176
2177         if (gameover)   // someone else quit the game already
2178         {
2179                 if(player_count == 0) // Nobody there? Then let's go to the next map
2180                         MapVote_Start();
2181                         // this will actually check the player count in the next frame
2182                         // again, but this shouldn't hurt
2183                 return;
2184         }
2185
2186         timelimit = autocvar_timelimit * 60;
2187         fraglimit = autocvar_fraglimit;
2188         leadlimit = autocvar_leadlimit;
2189
2190         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2191         {
2192                 if(timelimit > 0)
2193                         timelimit = 0; // timelimit is not made for warmup
2194                 if(fraglimit > 0)
2195                         fraglimit = 0; // no fraglimit for now
2196                 leadlimit = 0; // no leadlimit for now
2197         }
2198
2199         if(g_onslaught)
2200                 timelimit = 0; // ONS has its own overtime rule
2201
2202         if(timelimit > 0)
2203         {
2204                 timelimit += game_starttime;
2205         }
2206         else if (timelimit < 0)
2207         {
2208                 // endmatch
2209                 NextLevel();
2210                 return;
2211         }
2212
2213         float wantovertime;
2214         wantovertime = 0;
2215
2216         if(checkrules_suddendeathend)
2217         {
2218                 if(!checkrules_suddendeathwarning)
2219                 {
2220                         checkrules_suddendeathwarning = TRUE;
2221                         if(g_race && !g_race_qualifying)
2222                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2223                         else
2224                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2225                 }
2226         }
2227         else
2228         {
2229                 if (timelimit && time >= timelimit)
2230                 {
2231                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2232                         {
2233                                 float totalplayers;
2234                                 float playerswithlaps;
2235                                 float readyplayers;
2236                                 entity head;
2237                                 totalplayers = playerswithlaps = readyplayers = 0;
2238                                 FOR_EACH_PLAYER(head)
2239                                 {
2240                                         ++totalplayers;
2241                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2242                                                 ++playerswithlaps;
2243                                         if(head.ready)
2244                                                 ++readyplayers;
2245                                 }
2246
2247                                 // at least 2 of the players have completed a lap: start the RACE
2248                                 // otherwise, the players should end the qualifying on their own
2249                                 if(readyplayers || playerswithlaps >= 2)
2250                                 {
2251                                         checkrules_suddendeathend = 0;
2252                                         ReadyRestart(); // go to race
2253                                         return;
2254                                 }
2255                                 else
2256                                         wantovertime |= InitiateSuddenDeath();
2257                         }
2258                         else
2259                                 wantovertime |= InitiateSuddenDeath();
2260                 }
2261         }
2262
2263         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2264         {
2265                 NextLevel();
2266                 return;
2267         }
2268
2269         float checkrules_status;
2270         checkrules_status = WinningCondition_RanOutOfSpawns();
2271         if(checkrules_status == WINNING_YES)
2272         {
2273                 bprint("Hey! Someone ran out of spawns!\n");
2274         }
2275         else if(g_race && !g_race_qualifying && timelimit >= 0)
2276         {
2277                 checkrules_status = WinningCondition_Race(fraglimit);
2278                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2279         }
2280         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2281         {
2282                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2283                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2284         }
2285         else if(g_assault)
2286         {
2287                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2288         }
2289         else if(g_lms)
2290         {
2291                 checkrules_status = WinningCondition_LMS();
2292         }
2293         else if (g_onslaught)
2294         {
2295                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2296         }
2297         else
2298         {
2299                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2300                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2301         }
2302
2303         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2304         {
2305                 checkrules_status = WINNING_NEVER;
2306                 checkrules_overtimesadded = -1;
2307                 wantovertime |= InitiateSuddenDeath();
2308         }
2309
2310         if(checkrules_status == WINNING_NEVER)
2311                 // equality cases! Nobody wins if the overtime ends in a draw.
2312                 ClearWinners();
2313
2314         if(wantovertime)
2315         {
2316                 if(checkrules_status == WINNING_NEVER)
2317                         InitiateOvertime();
2318                 else
2319                         checkrules_status = WINNING_YES;
2320         }
2321
2322         if(checkrules_suddendeathend)
2323                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2324                         checkrules_status = WINNING_YES;
2325
2326         if(checkrules_status == WINNING_YES)
2327         {
2328                 //print("WINNING\n");
2329                 NextLevel();
2330         }
2331 }
2332
2333 float mapvote_nextthink;
2334 float mapvote_initialized;
2335 float mapvote_keeptwotime;
2336 float mapvote_timeout;
2337 string mapvote_message;
2338 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2339 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2340 float mapvote_screenshot_dirs_count;
2341
2342 float mapvote_count;
2343 float mapvote_count_real;
2344 string mapvote_maps[MAPVOTE_COUNT];
2345 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2346 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2347 float mapvote_maps_suggested[MAPVOTE_COUNT];
2348 string mapvote_suggestions[MAPVOTE_COUNT];
2349 float mapvote_suggestion_ptr;
2350 float mapvote_voters;
2351 float mapvote_votes[MAPVOTE_COUNT];
2352 float mapvote_run;
2353 float mapvote_detail;
2354 float mapvote_abstain;
2355 .float mapvote;
2356
2357 void MapVote_ClearAllVotes()
2358 {
2359         FOR_EACH_CLIENT(other)
2360                 other.mapvote = 0;
2361 }
2362
2363 string MapVote_Suggest(string m)
2364 {
2365         float i;
2366         if(m == "")
2367                 return "That's not how to use this command.";
2368         if(!autocvar_g_maplist_votable_suggestions)
2369                 return "Suggestions are not accepted on this server.";
2370         if(mapvote_initialized)
2371                 return "Can't suggest - voting is already in progress!";
2372         m = MapInfo_FixName(m);
2373         if(!m)
2374                 return "The map you suggested is not available on this server.";
2375         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2376                 if(Map_IsRecent(m))
2377                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2378
2379         if(!MapInfo_CheckMap(m))
2380                 return "The map you suggested does not support the current game mode.";
2381         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2382                 if(mapvote_suggestions[i] == m)
2383                         return "This map was already suggested.";
2384         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2385         {
2386                 i = floor(random() * mapvote_suggestion_ptr);
2387         }
2388         else
2389         {
2390                 i = mapvote_suggestion_ptr;
2391                 mapvote_suggestion_ptr += 1;
2392         }
2393         if(mapvote_suggestions[i] != "")
2394                 strunzone(mapvote_suggestions[i]);
2395         mapvote_suggestions[i] = strzone(m);
2396         if(autocvar_sv_eventlog)
2397                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2398         return strcat("Suggestion of ", m, " accepted.");
2399 }
2400
2401 void MapVote_AddVotable(string nextMap, float isSuggestion)
2402 {
2403         float j, i, o;
2404         string pakfile, mapfile;
2405
2406         if(nextMap == "")
2407                 return;
2408         for(j = 0; j < mapvote_count; ++j)
2409                 if(mapvote_maps[j] == nextMap)
2410                         return;
2411         // suggestions might be no longer valid/allowed after gametype switch!
2412         if(isSuggestion)
2413                 if(!MapInfo_CheckMap(nextMap))
2414                         return;
2415         mapvote_maps[mapvote_count] = strzone(nextMap);
2416         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2417
2418         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2419         {
2420                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2421                 pakfile = whichpack(strcat(mapfile, ".tga"));
2422                 if(pakfile == "")
2423                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2424                 if(pakfile == "")
2425                         pakfile = whichpack(strcat(mapfile, ".png"));
2426                 if(pakfile != "")
2427                         break;
2428         }
2429         if(i >= mapvote_screenshot_dirs_count)
2430                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2431         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2432                 pakfile = substring(pakfile, o, -1);
2433
2434         mapvote_maps_screenshot_dir[mapvote_count] = i;
2435         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2436
2437         mapvote_count += 1;
2438 }
2439
2440 void MapVote_Spawn();
2441 void MapVote_Init()
2442 {
2443         float i;
2444         float nmax, smax;
2445
2446         MapVote_ClearAllVotes();
2447
2448         mapvote_count = 0;
2449         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2450         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2451
2452         if(mapvote_abstain)
2453                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2454         else
2455                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2456         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2457
2458         // we need this for AddVotable, as that cycles through the screenshot dirs
2459         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2460         if(mapvote_screenshot_dirs_count == 0)
2461                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2462         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2463         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2464                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2465
2466         if(mapvote_suggestion_ptr)
2467                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2468                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2469
2470         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2471                 MapVote_AddVotable(GetNextMap(), FALSE);
2472
2473         if(mapvote_count == 0)
2474         {
2475                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2476                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2477                 if(autocvar_g_maplist_shuffle)
2478                         ShuffleMaplist();
2479                 localcmd("\nmenu_cmd sync\n");
2480                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2481                         MapVote_AddVotable(GetNextMap(), FALSE);
2482         }
2483
2484         mapvote_count_real = mapvote_count;
2485         if(mapvote_abstain)
2486                 MapVote_AddVotable("don't care", 0);
2487
2488         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2489
2490         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2491         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2492         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2493                 mapvote_keeptwotime = 0;
2494         mapvote_message = "Choose a map and press its key!";
2495
2496         MapVote_Spawn();
2497 }
2498
2499 void MapVote_SendPicture(float id)
2500 {
2501         msg_entity = self;
2502         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2503         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2504         WriteByte(MSG_ONE, id);
2505         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2506 }
2507
2508 float GameCommand_MapVote(string cmd)
2509 {
2510         if(!intermission_running)
2511                 return FALSE;
2512
2513         if(cmd == "mv_getpic")
2514         {
2515                 MapVote_SendPicture(stof(argv(1)));
2516                 return TRUE;
2517         }
2518
2519         return FALSE;
2520 }
2521
2522 float MapVote_GetMapMask()
2523 {
2524         float mask, i, power;
2525         mask = 0;
2526         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2527                 if(mapvote_maps[i] != "")
2528                         mask |= power;
2529         return mask;
2530 }
2531
2532 entity mapvote_ent;
2533 float MapVote_SendEntity(entity to, float sf)
2534 {
2535         float i;
2536
2537         if(sf & 1)
2538                 sf &~= 2; // if we send 1, we don't need to also send 2
2539
2540         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2541         WriteByte(MSG_ENTITY, sf);
2542
2543         if(sf & 1)
2544         {
2545                 // flag 1 == initialization
2546                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2547                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2548                 WriteString(MSG_ENTITY, "");
2549                 WriteByte(MSG_ENTITY, mapvote_count);
2550                 WriteByte(MSG_ENTITY, mapvote_abstain);
2551                 WriteByte(MSG_ENTITY, mapvote_detail);
2552                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2553                 if(mapvote_count <= 8)
2554                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2555                 else
2556                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2557                 for(i = 0; i < mapvote_count; ++i)
2558                         if(mapvote_maps[i] != "")
2559                         {
2560                                 if(mapvote_abstain && i == mapvote_count - 1)
2561                                 {
2562                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2563                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2564                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2565                                 }
2566                                 else
2567                                 {
2568                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2569                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2570                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2571                                 }
2572                         }
2573         }
2574
2575         if(sf & 2)
2576         {
2577                 // flag 2 == update of mask
2578                 if(mapvote_count <= 8)
2579                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2580                 else
2581                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2582         }
2583
2584         if(sf & 4)
2585         {
2586                 if(mapvote_detail)
2587                         for(i = 0; i < mapvote_count; ++i)
2588                                 if(mapvote_maps[i] != "")
2589                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2590
2591                 WriteByte(MSG_ENTITY, to.mapvote);
2592         }
2593
2594         return TRUE;
2595 }
2596
2597 void MapVote_Spawn()
2598 {
2599         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2600 }
2601
2602 void MapVote_TouchMask()
2603 {
2604         mapvote_ent.SendFlags |= 2;
2605 }
2606
2607 void MapVote_TouchVotes(entity voter)
2608 {
2609         mapvote_ent.SendFlags |= 4;
2610 }
2611
2612 float MapVote_Finished(float mappos)
2613 {
2614         string result;
2615         float i;
2616         float didntvote;
2617
2618         if(autocvar_sv_eventlog)
2619         {
2620                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2621                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2622                 didntvote = mapvote_voters;
2623                 for(i = 0; i < mapvote_count; ++i)
2624                         if(mapvote_maps[i] != "")
2625                         {
2626                                 didntvote -= mapvote_votes[i];
2627                                 if(i != mappos)
2628                                 {
2629                                         result = strcat(result, ":", mapvote_maps[i]);
2630                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2631                                 }
2632                         }
2633                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2634
2635                 GameLogEcho(result);
2636                 if(mapvote_maps_suggested[mappos])
2637                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2638         }
2639
2640         FOR_EACH_REALCLIENT(other)
2641                 FixClientCvars(other);
2642
2643         Map_Goto_SetStr(mapvote_maps[mappos]);
2644         Map_Goto();
2645         alreadychangedlevel = TRUE;
2646         return TRUE;
2647 }
2648 void MapVote_CheckRules_1()
2649 {
2650         float i;
2651
2652         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2653         {
2654                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2655                 mapvote_votes[i] = 0;
2656         }
2657
2658         mapvote_voters = 0;
2659         FOR_EACH_REALCLIENT(other)
2660         {
2661                 ++mapvote_voters;
2662                 if(other.mapvote)
2663                 {
2664                         i = other.mapvote - 1;
2665                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2666                         mapvote_votes[i] = mapvote_votes[i] + 1;
2667                 }
2668         }
2669 }
2670
2671 float MapVote_CheckRules_2()
2672 {
2673         float i;
2674         float firstPlace, secondPlace;
2675         float firstPlaceVotes, secondPlaceVotes;
2676         float mapvote_voters_real;
2677         string result;
2678
2679         if(mapvote_count_real == 1)
2680                 return MapVote_Finished(0);
2681
2682         mapvote_voters_real = mapvote_voters;
2683         if(mapvote_abstain)
2684                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2685
2686         RandomSelection_Init();
2687         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2688                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2689         firstPlace = RandomSelection_chosen_float;
2690         firstPlaceVotes = RandomSelection_best_priority;
2691         //dprint("First place: ", ftos(firstPlace), "\n");
2692         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2693
2694         RandomSelection_Init();
2695         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2696                 if(i != firstPlace)
2697                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2698         secondPlace = RandomSelection_chosen_float;
2699         secondPlaceVotes = RandomSelection_best_priority;
2700         //dprint("Second place: ", ftos(secondPlace), "\n");
2701         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2702
2703         if(firstPlace == -1)
2704                 error("No first place in map vote... WTF?");
2705
2706         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2707                 return MapVote_Finished(firstPlace);
2708
2709         if(mapvote_keeptwotime)
2710                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2711                 {
2712                         float didntvote;
2713                         MapVote_TouchMask();
2714                         mapvote_message = "Now decide between the TOP TWO!";
2715                         mapvote_keeptwotime = 0;
2716                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2717                         result = strcat(result, ":", ftos(firstPlaceVotes));
2718                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2719                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2720                         didntvote = mapvote_voters;
2721                         for(i = 0; i < mapvote_count; ++i)
2722                                 if(mapvote_maps[i] != "")
2723                                 {
2724                                         didntvote -= mapvote_votes[i];
2725                                         if(i != firstPlace)
2726                                                 if(i != secondPlace)
2727                                                 {
2728                                                         result = strcat(result, ":", mapvote_maps[i]);
2729                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2730                                                         if(i < mapvote_count_real)
2731                                                         {
2732                                                                 strunzone(mapvote_maps[i]);
2733                                                                 mapvote_maps[i] = "";
2734                                                                 strunzone(mapvote_maps_pakfile[i]);
2735                                                                 mapvote_maps_pakfile[i] = "";
2736                                                         }
2737                                                 }
2738                                 }
2739                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2740                         if(autocvar_sv_eventlog)
2741                                 GameLogEcho(result);
2742                 }
2743
2744         return FALSE;
2745 }
2746 void MapVote_Tick()
2747 {
2748         float keeptwo;
2749         float totalvotes;
2750
2751         keeptwo = mapvote_keeptwotime;
2752         MapVote_CheckRules_1(); // count
2753         if(MapVote_CheckRules_2()) // decide
2754                 return;
2755
2756         totalvotes = 0;
2757         FOR_EACH_REALCLIENT(other)
2758         {
2759                 // hide scoreboard again
2760                 if(other.health != 2342)
2761                 {
2762                         other.health = 2342;
2763                         other.impulse = 0;
2764                         if(clienttype(other) == CLIENTTYPE_REAL)
2765                         {
2766                                 msg_entity = other;
2767                                 WriteByte(MSG_ONE, SVC_FINALE);
2768                                 WriteString(MSG_ONE, "");
2769                         }
2770                 }
2771
2772                 // clear possibly invalid votes
2773                 if(mapvote_maps[other.mapvote - 1] == "")
2774                         other.mapvote = 0;
2775                 // use impulses as new vote
2776                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2777                         if(mapvote_maps[other.impulse - 1] != "")
2778                         {
2779                                 other.mapvote = other.impulse;
2780                                 MapVote_TouchVotes(other);
2781                         }
2782                 other.impulse = 0;
2783
2784                 if(other.mapvote)
2785                         ++totalvotes;
2786         }
2787
2788         MapVote_CheckRules_1(); // just count
2789 }
2790 void MapVote_Start()
2791 {
2792         if(mapvote_run)
2793                 return;
2794
2795         // wait for stats to be sent first
2796         if(!playerstats_waitforme)
2797                 return;
2798
2799         MapInfo_Enumerate();
2800         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2801                 mapvote_run = TRUE;
2802 }
2803 void MapVote_Think()
2804 {
2805         if(!mapvote_run)
2806                 return;
2807
2808         if(alreadychangedlevel)
2809                 return;
2810
2811         if(time < mapvote_nextthink)
2812                 return;
2813         //dprint("tick\n");
2814
2815         mapvote_nextthink = time + 0.5;
2816
2817         if(!mapvote_initialized)
2818         {
2819                 if(autocvar_rescan_pending == 1)
2820                 {
2821                         cvar_set("rescan_pending", "2");
2822                         localcmd("fs_rescan\nrescan_pending 3\n");
2823                         return;
2824                 }
2825                 else if(autocvar_rescan_pending == 2)
2826                 {
2827                         return;
2828                 }
2829                 else if(autocvar_rescan_pending == 3)
2830                 {
2831                         // now build missing mapinfo files
2832                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2833                                 return;
2834
2835                         // we're done, start the timer
2836                         cvar_set("rescan_pending", "0");
2837                 }
2838
2839                 mapvote_initialized = TRUE;
2840                 if(DoNextMapOverride())
2841                         return;
2842                 if(!autocvar_g_maplist_votable || player_count <= 0)
2843                 {
2844                         GotoNextMap();
2845                         return;
2846                 }
2847                 MapVote_Init();
2848         }
2849
2850         MapVote_Tick();
2851 }
2852
2853 string GotoMap(string m)
2854 {
2855         if(!MapInfo_CheckMap(m))
2856                 return "The map you chose is not available on this server.";
2857         cvar_set("nextmap", m);
2858         cvar_set("timelimit", "-1");
2859         if(mapvote_initialized || alreadychangedlevel)
2860         {
2861                 if(DoNextMapOverride())
2862                         return "Map switch initiated.";
2863                 else
2864                         return "Hm... no. For some reason I like THIS map more.";
2865         }
2866         else
2867                 return "Map switch will happen after scoreboard.";
2868 }
2869
2870
2871 void EndFrame()
2872 {
2873         float altime;
2874         FOR_EACH_REALCLIENT(self)
2875         {
2876                 if(self.classname == "spectator")
2877                 {
2878                         if(self.enemy.typehitsound)
2879                                 self.typehit_time = time;
2880                         else if(self.enemy.hitsound)
2881                                 self.hit_time = time;
2882                 }
2883                 else
2884                 {
2885                         if(self.typehitsound)
2886                                 self.typehit_time = time;
2887                         else if(self.hitsound)
2888                                 self.hit_time = time;
2889                 }
2890         }
2891         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2892         // add 1 frametime because after this, engine SV_Physics
2893         // increases time by a frametime and then networks the frame
2894         // add another frametime because client shows everything with
2895         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2896         // needed!
2897         FOR_EACH_CLIENT(self)
2898         {
2899                 self.hitsound = FALSE;
2900                 self.typehitsound = FALSE;
2901                 antilag_record(self, altime);
2902         }
2903 }
2904
2905
2906 /*
2907  * RedirectionThink:
2908  * returns TRUE if redirecting
2909  */
2910 float redirection_timeout;
2911 float redirection_nextthink;
2912 float RedirectionThink()
2913 {
2914         float clients_found;
2915
2916         if(redirection_target == "")
2917                 return FALSE;
2918
2919         if(!redirection_timeout)
2920         {
2921                 cvar_set("sv_public", "-2");
2922                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2923                 if(redirection_target == "self")
2924                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2925                 else
2926                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2927         }
2928
2929         if(time < redirection_nextthink)
2930                 return TRUE;
2931
2932         redirection_nextthink = time + 1;
2933
2934         clients_found = 0;
2935         FOR_EACH_REALCLIENT(self)
2936         {
2937                 print("Redirecting: sending connect command to ", self.netname, "\n");
2938                 if(redirection_target == "self")
2939                         stuffcmd(self, "\ndisconnect; reconnect\n");
2940                 else
2941                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2942                 ++clients_found;
2943         }
2944
2945         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2946
2947         if(time > redirection_timeout || clients_found == 0)
2948                 localcmd("\nwait; wait; wait; quit\n");
2949
2950         return TRUE;
2951 }
2952
2953 void TargetMusic_RestoreGame();
2954 void RestoreGame()
2955 {
2956         // Loaded from a save game
2957         // some things then break, so let's work around them...
2958
2959         // Progs DB (capture records)
2960         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2961
2962         // Mapinfo
2963         MapInfo_Shutdown();
2964         MapInfo_Enumerate();
2965         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2966         WeaponStats_Init();
2967
2968         TargetMusic_RestoreGame();
2969 }
2970
2971 void SV_Shutdown()
2972 {
2973         entity e;
2974
2975         if(gameover > 1) // shutting down already?
2976                 return;
2977
2978         gameover = 2; // 2 = server shutting down
2979
2980         if(world_initialized > 0)
2981         {
2982                 world_initialized = 0;
2983                 print("Saving persistent data...\n");
2984                 Ban_SaveBans();
2985
2986                 PlayerStats_EndMatch(0);
2987                 FOR_EACH_CLIENT(e)
2988                         PlayerStats_AddGlobalInfo(e);
2989                 PlayerStats_Shutdown();
2990
2991                 if(!cheatcount_total)
2992                 {
2993                         if(autocvar_sv_db_saveasdump)
2994                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2995                         else
2996                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2997                 }
2998                 if(autocvar_developer)
2999                 {
3000                         if(autocvar_sv_db_saveasdump)
3001                                 db_dump(TemporaryDB, "server-temp.db");
3002                         else
3003                                 db_save(TemporaryDB, "server-temp.db");
3004                 }
3005                 CheatShutdown(); // must be after cheatcount check
3006                 db_close(ServerProgsDB);
3007                 db_close(TemporaryDB);
3008                 print("done!\n");
3009                 // tell the bot system the game is ending now
3010                 bot_endgame();
3011
3012                 WeaponStats_Shutdown();
3013                 MapInfo_Shutdown();
3014         }
3015         else if(world_initialized == 0)
3016         {
3017                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
3018         }
3019 }