qcsrc/server/sv_main.qc

   1
   2 #include "anticheat.qh"
   3 #include "g_hook.qh"
   4 #include "g_world.qh"
   5
   6 #include "bot/bot.qh"
   7 #include "bot/waypoints.qh"
   8
   9 #include "command/common.qh"
  10
  11 #include "mutators/all.qh"
  12 #include "weapons/csqcprojectile.qh"
  13
  14 #include "../common/constants.qh"
  15 #include "../common/deathtypes/all.qh"
  16 #include "../common/debug.qh"
  17 #include "../common/mapinfo.qh"
  18 #include "../common/util.qh"
  19
  20 #include "../common/vehicles/all.qh"
  21 #include "../common/weapons/all.qh"
  22
  23 #include "../lib/csqcmodel/sv_model.qh"
  24
  25 #include "../lib/warpzone/common.qh"
  26 #include "../lib/warpzone/server.qh"
  27
  28 .float lastground;
  29 .int state;
  30
  31 void CreatureFrame_hotliquids(entity this)
  32 {
  33         if (this.dmgtime < time)
  34         {
  35                 this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  36
  37                 if (this.flags & FL_PROJECTILE)
  38                 {
  39                         if (this.watertype == CONTENT_LAVA)
  40                                 Damage (this, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  41                         else if (this.watertype == CONTENT_SLIME)
  42                                 Damage (this, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  43                 }
  44                 else
  45                 {
  46                         if (this.watertype == CONTENT_LAVA)
  47                         {
  48                                 if (this.watersound_finished < time)
  49                                 {
  50                                         this.watersound_finished = time + 0.5;
  51                                         sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  52                                 }
  53                                 Damage (this, world, world, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  54                                 if(autocvar_g_balance_contents_playerdamage_lava_burn)
  55                                         Fire_AddDamage(this, world, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  56                         }
  57                         else if (this.watertype == CONTENT_SLIME)
  58                         {
  59                                 if (this.watersound_finished < time)
  60                                 {
  61                                         this.watersound_finished = time + 0.5;
  62                                         sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  63                                 }
  64                                 Damage (this, world, world, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  65                         }
  66                 }
  67         }
  68 }
  69
  70 void CreatureFrame_Liquids(entity this)
  71 {
  72         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  73         {
  74                 if (!(this.flags & FL_INWATER))
  75                 {
  76                         this.flags |= FL_INWATER;
  77                         this.dmgtime = 0;
  78                 }
  79
  80                 CreatureFrame_hotliquids(this);
  81         }
  82         else
  83         {
  84                 if (this.flags & FL_INWATER)
  85                 {
  86                         // play leave water sound
  87                         this.flags &= ~FL_INWATER;
  88                         this.dmgtime = 0;
  89                 }
  90                 this.air_finished = time + 12;
  91                 this.dmg = 2;
  92         }
  93 }
  94
  95 void CreatureFrame_FallDamage(entity this)
  96 {
  97         if(!IS_VEHICLE(this) && !(this.flags & FL_PROJECTILE)) // vehicles don't get falling damage
  98         {
  99                 // check for falling damage
 100                 float velocity_len = vlen(this.velocity);
 101                 if(!this.hook.state)
 102                 {
 103                         float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 104                         if (this.deadflag)
 105                                 dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 106                         else
 107                                 dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 108                         if (dm > 0)
 109                                 Damage (this, world, world, dm, DEATH_FALL.m_id, this.origin, '0 0 0');
 110                 }
 111
 112                 if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 113                         Damage (this, world, world, 100000, DEATH_SHOOTING_STAR.m_id, this.origin, '0 0 0');
 114         }
 115 }
 116
 117 void CreatureFrame_All()
 118 {
 119         FOREACH_ENTITY_FLOAT(damagedbycontents, true, LAMBDA(
 120                 if(it.movetype == MOVETYPE_NOCLIP) continue;
 121                 CreatureFrame_Liquids(it);
 122                 CreatureFrame_FallDamage(it);
 123                 it.oldvelocity = it.velocity;
 124         ));
 125 }
 126
 127 void Pause_TryPause(bool ispaused)
 128 {
 129         int n = 0;
 130         entity it;
 131         FOR_EACH_REALPLAYER(it)
 132         {
 133                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 134                 ++n;
 135         }
 136         if (!n) return;
 137         setpause(ispaused);
 138 }
 139
 140 void SV_PausedTic(float elapsedtime)
 141 {
 142         if (!server_is_dedicated) Pause_TryPause(false);
 143 }
 144
 145 /*
 146 =============
 147 StartFrame
 148
 149 Called before each frame by the server
 150 =============
 151 */
 152
 153 float game_delay;
 154 float game_delay_last;
 155
 156 bool autocvar_sv_autopause = true;
 157 float RedirectionThink();
 158 void StartFrame()
 159 {
 160         SELFPARAM();
 161         execute_next_frame();
 162         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 163
 164         remove = remove_unsafely; // not during spawning!
 165         serverprevtime = servertime;
 166         servertime = time;
 167         serverframetime = frametime;
 168
 169 #ifdef PROFILING
 170         if(time > client_cefc_accumulatortime + 1)
 171         {
 172                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 173                 LOG_INFO("CEFC time: ", ftos(t * 1000), "ms; ");
 174                 int c_seeing = 0;
 175                 int c_seen = 0;
 176                 entity cl;
 177                 FOR_EACH_CLIENT(cl)
 178                 {
 179                         if(IS_REAL_CLIENT(cl))
 180                                 ++c_seeing;
 181                         if(IS_PLAYER(cl))
 182                                 ++c_seen;
 183                 }
 184                 LOG_INFO("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 185                 LOG_INFO("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 186
 187                 client_cefc_accumulatortime = time;
 188                 client_cefc_accumulator = 0;
 189         }
 190 #endif
 191
 192         FOREACH_ENTITY_FLOAT(csqcprojectile_clientanimate, true, LAMBDA(CSQCProjectile_Check(it)));
 193
 194         if(RedirectionThink())
 195                 return;
 196
 197         UncustomizeEntitiesRun();
 198         InitializeEntitiesRun();
 199
 200         WarpZone_StartFrame();
 201
 202         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 203         if(sys_frametime <= 0)
 204                 sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 205
 206         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 207                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 208
 209         skill = autocvar_skill;
 210
 211         // detect when the pre-game countdown (if any) has ended and the game has started
 212         game_delay = (time < game_starttime);
 213
 214         if(autocvar_sv_eventlog && game_delay_last && !game_delay)
 215                 GameLogEcho(":startdelay_ended");
 216
 217         game_delay_last = game_delay;
 218
 219         CreatureFrame_All();
 220         CheckRules_World();
 221
 222         // if in warmup stage and limit for warmup is hit start match
 223         if(warmup_stage)
 224         if(!gameover)
 225         if((g_warmup_limit > 0 && time >= g_warmup_limit)
 226          || (g_warmup_limit == 0 && autocvar_timelimit != 0 && time >= autocvar_timelimit * 60))
 227         {
 228                 ReadyRestart();
 229                 return;
 230         }
 231
 232         bot_serverframe();
 233         anticheat_startframe();
 234         MUTATOR_CALLHOOK(SV_StartFrame);
 235
 236     FOREACH_CLIENT(true, LAMBDA(GlobalStats_update(it)));
 237 }
 238
 239 .vector originjitter;
 240 .vector anglesjitter;
 241 .float anglejitter;
 242 .string gametypefilter;
 243 .string cvarfilter;
 244 float DoesQ3ARemoveThisEntity();
 245 void SV_OnEntityPreSpawnFunction()
 246 {SELFPARAM();
 247         __spawnfunc_expect = this;
 248         if (self)
 249         if (self.gametypefilter != "")
 250         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, self.gametypefilter))
 251         {
 252                 remove(self);
 253                 return;
 254         }
 255         if(self.cvarfilter != "")
 256         {
 257                 float n, i, o, inv;
 258                 string s, k, v;
 259                 inv = 0;
 260
 261                 s = self.cvarfilter;
 262                 if(substring(s, 0, 1) == "+")
 263                 {
 264                         s = substring(s, 1, -1);
 265                 }
 266                 else if(substring(s, 0, 1) == "-")
 267                 {
 268                         inv = 1;
 269                         s = substring(s, 1, -1);
 270                 }
 271
 272                 n = tokenize_console(s);
 273                 for(i = 0; i < n; ++i)
 274                 {
 275                         s = argv(i);
 276                         // syntax:
 277                         // var>x
 278                         // var<x
 279                         // var>=x
 280                         // var<=x
 281                         // var==x
 282                         // var!=x
 283                         // var===x
 284                         // var!==x
 285                         if((o = strstrofs(s, ">=", 0)) >= 0)
 286                         {
 287                                 k = substring(s, 0, o);
 288                                 v = substring(s, o+2, -1);
 289                                 if(cvar(k) < stof(v))
 290                                         goto cvar_fail;
 291                         }
 292                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 293                         {
 294                                 k = substring(s, 0, o);
 295                                 v = substring(s, o+2, -1);
 296                                 if(cvar(k) > stof(v))
 297                                         goto cvar_fail;
 298                         }
 299                         else if((o = strstrofs(s, ">", 0)) >= 0)
 300                         {
 301                                 k = substring(s, 0, o);
 302                                 v = substring(s, o+1, -1);
 303                                 if(cvar(k) <= stof(v))
 304                                         goto cvar_fail;
 305                         }
 306                         else if((o = strstrofs(s, "<", 0)) >= 0)
 307                         {
 308                                 k = substring(s, 0, o);
 309                                 v = substring(s, o+1, -1);
 310                                 if(cvar(k) >= stof(v))
 311                                         goto cvar_fail;
 312                         }
 313                         else if((o = strstrofs(s, "==", 0)) >= 0)
 314                         {
 315                                 k = substring(s, 0, o);
 316                                 v = substring(s, o+2, -1);
 317                                 if(cvar(k) != stof(v))
 318                                         goto cvar_fail;
 319                         }
 320                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 321                         {
 322                                 k = substring(s, 0, o);
 323                                 v = substring(s, o+2, -1);
 324                                 if(cvar(k) == stof(v))
 325                                         goto cvar_fail;
 326                         }
 327                         else if((o = strstrofs(s, "===", 0)) >= 0)
 328                         {
 329                                 k = substring(s, 0, o);
 330                                 v = substring(s, o+2, -1);
 331                                 if(cvar_string(k) != v)
 332                                         goto cvar_fail;
 333                         }
 334                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 335                         {
 336                                 k = substring(s, 0, o);
 337                                 v = substring(s, o+2, -1);
 338                                 if(cvar_string(k) == v)
 339                                         goto cvar_fail;
 340                         }
 341                         else if(substring(s, 0, 1) == "!")
 342                         {
 343                                 k = substring(s, 1, -1);
 344                                 if(cvar(k))
 345                                         goto cvar_fail;
 346                         }
 347                         else
 348                         {
 349                                 k = s;
 350                                 if (!cvar(k))
 351                                         goto cvar_fail;
 352                         }
 353                 }
 354                 inv = !inv;
 355 :cvar_fail
 356                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 357                 if (!inv)
 358                 {
 359                         //print("cvarfilter fail\n");
 360                         remove(self);
 361                         return;
 362                 }
 363         }
 364
 365         if(DoesQ3ARemoveThisEntity())
 366         {
 367                 remove(self);
 368                 return;
 369         }
 370
 371         // support special -1 and -2 angle from radiant
 372         if (self.angles == '0 -1 0')
 373                 self.angles = '-90 0 0';
 374         else if (self.angles == '0 -2 0')
 375                 self.angles = '+90 0 0';
 376
 377         if(self.originjitter.x != 0)
 378                 self.origin_x = self.origin.x + (random() * 2 - 1) * self.originjitter.x;
 379         if(self.originjitter.y != 0)
 380                 self.origin_y = self.origin.y + (random() * 2 - 1) * self.originjitter.y;
 381         if(self.originjitter.z != 0)
 382                 self.origin_z = self.origin.z + (random() * 2 - 1) * self.originjitter.z;
 383         if(self.anglesjitter.x != 0)
 384                 self.angles_x = self.angles.x + (random() * 2 - 1) * self.anglesjitter.x;
 385         if(self.anglesjitter.y != 0)
 386                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglesjitter.y;
 387         if(self.anglesjitter.z != 0)
 388                 self.angles_z = self.angles.z + (random() * 2 - 1) * self.anglesjitter.z;
 389         if(self.anglejitter != 0)
 390                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglejitter;
 391
 392         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
 393         {
 394                 remove(self);
 395                 return;
 396         }
 397 }
 398
 399 void WarpZone_PostInitialize_Callback()
 400 {
 401         // create waypoint links for warpzones
 402         entity e;
 403         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 404         {
 405                 vector src, dst;
 406                 src = (e.absmin + e.absmax) * 0.5;
 407                 makevectors(e.warpzone_angles);
 408                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 409                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 410                 makevectors(e.enemy.warpzone_angles);
 411                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 412                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 413         }
 414 }