qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 .float shotgun_load;
   7
   8 void W_Shotgun_SetAmmoCounter()
   9 {
  10         // set ammo counter to the weapon we have switched to
  11         if(!autocvar_g_balance_shotgun_reload_ammo)
  12                 self.ammo_counter = 0; // also keeps the crosshair ammo from displaying
  13         else
  14                 self.ammo_counter = self.shotgun_load;
  15 }
  16
  17 void W_Shotgun_ReloadedAndReady()
  18 {
  19         float t;
  20
  21         // now do the ammo maths
  22         self.ammo_counter = self.old_ammo_counter; // restore ammo counter, in case we still had ammo in the weapon while reloading
  23         while(self.ammo_counter < autocvar_g_balance_shotgun_reload_ammo && self.ammo_shells) // make sure we don't add more than the amount of ammo we have
  24         {
  25                 self.ammo_counter += 1;
  26                 self.ammo_shells -= 1;
  27         }
  28         self.shotgun_load = self.ammo_counter;
  29
  30         t = ATTACK_FINISHED(self) - autocvar_g_balance_shotgun_reload_time - 1;
  31         ATTACK_FINISHED(self) = t;
  32         w_ready();
  33 }
  34
  35 void W_Shotgun_Reload()
  36 {
  37         // reloading is disabled for this weapon
  38         if(!autocvar_g_balance_shotgun_reload_ammo)
  39                 return;
  40
  41         float t;
  42
  43         if(!W_ReloadCheck(self.shotgun_load, autocvar_g_balance_shotgun_primary_ammo, 0))
  44                 return;
  45
  46         sound (self, CHAN_WEAPON2, "weapons/campingrifle_reload.wav", VOL_BASE, ATTN_NORM);
  47
  48         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_shotgun_reload_time + 1;
  49         ATTACK_FINISHED(self) = t;
  50
  51         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_shotgun_reload_time, W_Shotgun_ReloadedAndReady);
  52
  53         self.old_ammo_counter = self.ammo_counter;
  54         self.ammo_counter = -1;
  55 }
  56
  57 void W_Shotgun_Attack (void)
  58 {
  59         float   sc;
  60         float   ammoamount;
  61         float   bullets;
  62         float   d;
  63         float   f;
  64         float   spread;
  65         float   bulletspeed;
  66         float   bulletconstant;
  67         local entity flash;
  68
  69         if(autocvar_g_balance_shotgun_reload_ammo && self.ammo_counter <= 0)
  70                 return; // reloading, so we are done
  71
  72         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  73         bullets = autocvar_g_balance_shotgun_primary_bullets;
  74         d = autocvar_g_balance_shotgun_primary_damage;
  75         f = autocvar_g_balance_shotgun_primary_force;
  76         spread = autocvar_g_balance_shotgun_primary_spread;
  77         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  78         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  79
  80         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
  81         for (sc = 0;sc < bullets;sc = sc + 1)
  82                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  83         endFireBallisticBullet();
  84         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  85         {
  86                 if(!autocvar_g_balance_shotgun_reload_ammo)
  87                         self.ammo_shells = self.ammo_shells - ammoamount;
  88                 else
  89                         self.shotgun_load -= ammoamount;
  90         }
  91
  92         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  93
  94         // casing code
  95         if (autocvar_g_casings >= 1)
  96                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  97                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  98
  99         // muzzle flash for 1st person view
 100         flash = spawn();
 101         setmodel(flash, "models/uziflash.md3"); // precision set below
 102         flash.think = SUB_Remove;
 103         flash.nextthink = time + 0.06;
 104         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 105         W_AttachToShotorg(flash, '5 0 0');
 106
 107         self.ammo_counter = self.ammo_counter - 1;
 108 }
 109
 110 void shotgun_meleethink (void)
 111 {
 112         // store time when we started swinging down inside self.cnt
 113         if(!self.cnt)
 114                 self.cnt = time;
 115
 116         makevectors(self.owner.v_angle);
 117         vector angle;
 118         angle = v_forward;
 119
 120         float meleetime;
 121         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
 122
 123         // perform trace
 124         float f;
 125         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
 126         vector targpos;
 127         targpos = self.owner.origin + self.owner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
 128
 129         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 130
 131         // apply the damage, also remove self
 132         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
 133         {
 134                 vector force;
 135                 force = angle * autocvar_g_balance_shotgun_secondary_force;
 136                 if(accuracy_isgooddamage(self.owner, trace_ent))
 137                         accuracy_add(self.owner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
 138                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
 139                 remove(self);
 140         }
 141         else if(time >= self.cnt + meleetime) // missed, remove ent
 142                 remove(self);
 143         else // continue swinging the weapon in hope of hitting someone :)
 144                 self.nextthink = time;
 145 }
 146
 147 void W_Shotgun_Attack2 (void)
 148 {
 149         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 150         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 151
 152         entity meleetemp;
 153         meleetemp = spawn();
 154         meleetemp.owner = self;
 155         meleetemp.think = shotgun_meleethink;
 156         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
 157         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 158 }
 159
 160 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 161
 162 .float shotgun_primarytime;
 163
 164 float w_shotgun(float req)
 165 {
 166         if (req == WR_AIM)
 167                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 168                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 169                 else
 170                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 171         else if (req == WR_THINK)
 172         {
 173                 if(autocvar_g_balance_shotgun_reload_ammo && self.ammo_counter <= 0) // forced reload
 174                         W_Shotgun_Reload();
 175                 else
 176                 {
 177                         if (self.BUTTON_ATCK)
 178                         {
 179                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 180                                 {
 181                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 182                                         {
 183                                                 W_Shotgun_Attack();
 184                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 185                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 186                                         }
 187                                 }
 188                         }
 189                         if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 190                         if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 191                         {
 192                                 // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 193                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 194                         }
 195                 }
 196         if(self.wish_reload)
 197         {
 198             if(self.switchweapon == self.weapon)
 199             {
 200                 if(self.weaponentity.state == WS_READY)
 201                 {
 202                     self.wish_reload = 0;
 203                     W_Shotgun_Reload();
 204                 }
 205             }
 206         }
 207         }
 208         else if (req == WR_PRECACHE)
 209         {
 210                 precache_model ("models/uziflash.md3");
 211                 precache_model ("models/weapons/g_shotgun.md3");
 212                 precache_model ("models/weapons/v_shotgun.md3");
 213                 precache_model ("models/weapons/h_shotgun.iqm");
 214                 precache_sound ("misc/itempickup.wav");
 215                 precache_sound ("weapons/shotgun_fire.wav");
 216                 precache_sound ("weapons/shotgun_melee.wav");
 217         }
 218         else if (req == WR_SETUP)
 219         {
 220                 weapon_setup(WEP_SHOTGUN);
 221                 W_Shotgun_SetAmmoCounter();
 222         }
 223         else if (req == WR_CHECKAMMO1)
 224         {
 225                 if(autocvar_g_balance_shotgun_reload_ammo)
 226                         return self.shotgun_load >= autocvar_g_balance_shotgun_primary_ammo;
 227                 else
 228                         return self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 229         }
 230         else if (req == WR_CHECKAMMO2)
 231         {
 232                 return TRUE;
 233         }
 234         return TRUE;
 235 };
 236 #endif
 237 #ifdef CSQC
 238 .float prevric;
 239 float w_shotgun(float req)
 240 {
 241         if(req == WR_IMPACTEFFECT)
 242         {
 243                 vector org2;
 244                 org2 = w_org + w_backoff * 2;
 245                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 246                 if(!w_issilent && time - self.prevric > 0.25)
 247                 {
 248                         if(w_random < 0.0165)
 249                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 250                         else if(w_random < 0.033)
 251                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 252                         else if(w_random < 0.05)
 253                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 254                         self.prevric = time;
 255                 }
 256         }
 257         else if(req == WR_PRECACHE)
 258         {
 259                 precache_sound("weapons/ric1.wav");
 260                 precache_sound("weapons/ric2.wav");
 261                 precache_sound("weapons/ric3.wav");
 262         }
 263         else if (req == WR_SUICIDEMESSAGE)
 264                 w_deathtypestring = "%s did the impossible";
 265         else if (req == WR_KILLMESSAGE)
 266         {
 267                 if(w_deathtype & HITTYPE_SECONDARY)
 268                         w_deathtypestring = "%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun";
 269                 else
 270                         w_deathtypestring = "%s was gunned by %s";
 271         }
 272         return TRUE;
 273 }
 274 #endif
 275 #endif