qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "../common/buffs.qh"
   4
   5 #if defined(CSQC)
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8     #include "../common/constants.qh"
   9     #include "../common/stats.qh"
  10     #include "../common/teams.qh"
  11     #include "../common/util.qh"
  12     #include "../common/monsters/sv_monsters.qh"
  13     #include "../common/weapons/weapons.qh"
  14     #include "weapons/weaponstats.qh"
  15     #include "autocvars.qh"
  16     #include "constants.qh"
  17     #include "defs.qh"
  18     #include "../common/notifications.qh"
  19     #include "mutators/mutators_include.qh"
  20     #include "campaign.qh"
  21     #include "../common/mapinfo.qh"
  22     #include "command/common.qh"
  23     #include "command/vote.qh"
  24     #include "command/getreplies.qh"
  25     #include "command/sv_cmd.qh"
  26     #include "anticheat.qh"
  27     #include "cheats.qh"
  28     #include "../common/playerstats.qh"
  29     #include "g_hook.qh"
  30     #include "scores.qh"
  31     #include "mapvoting.qh"
  32     #include "ipban.qh"
  33     #include "race.qh"
  34     #include "antilag.qh"
  35     #include "secret.qh"
  36 #endif
  37
  38 const float LATENCY_THINKRATE = 10;
  39 .float latency_sum;
  40 .float latency_cnt;
  41 .float latency_time;
  42 entity pingplreport;
  43 void PingPLReport_Think()
  44 {
  45         float delta;
  46         entity e;
  47
  48         delta = 3 / maxclients;
  49         if(delta < sys_frametime)
  50                 delta = 0;
  51         self.nextthink = time + delta;
  52
  53         e = edict_num(self.cnt + 1);
  54         if(IS_REAL_CLIENT(e))
  55         {
  56                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  57                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, self.cnt);
  59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  75                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  76                 WriteByte(MSG_BROADCAST, self.cnt);
  77                 WriteShort(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80         }
  81         self.cnt = (self.cnt + 1) % maxclients;
  82 }
  83 void PingPLReport_Spawn()
  84 {
  85         pingplreport = spawn();
  86         pingplreport.classname = "pingplreport";
  87         pingplreport.think = PingPLReport_Think;
  88         pingplreport.nextthink = time;
  89 }
  90
  91 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  92 string redirection_target;
  93 float world_initialized;
  94
  95 string GetGametype();
  96 void GotoNextMap(float reinit);
  97 void ShuffleMaplist();
  98 float(float reinit) DoNextMapOverride;
  99
 100 void SetDefaultAlpha()
 101 {
 102         if(autocvar_g_running_guns)
 103         {
 104                 default_player_alpha = -1;
 105                 default_weapon_alpha = +1;
 106         }
 107         else if(g_cloaked)
 108         {
 109                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
 110                 default_weapon_alpha = default_player_alpha;
 111         }
 112         else
 113         {
 114                 default_player_alpha = autocvar_g_player_alpha;
 115                 if(default_player_alpha == 0)
 116                         default_player_alpha = 1;
 117                 default_weapon_alpha = default_player_alpha;
 118         }
 119 }
 120
 121 void GotoFirstMap()
 122 {
 123         float n;
 124         if(autocvar__sv_init)
 125         {
 126                 // cvar_set("_sv_init", "0");
 127                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 128                 // to this "init" map on a dedicated server will cause no permanent
 129                 // harm
 130                 if(autocvar_g_maplist_shuffle)
 131                         ShuffleMaplist();
 132                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 133                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 134
 135                 MapInfo_Enumerate();
 136                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 137
 138                 if(!DoNextMapOverride(1))
 139                         GotoNextMap(1);
 140
 141                 return;
 142         }
 143
 144         if(time < 5)
 145         {
 146                 self.nextthink = time;
 147         }
 148         else
 149         {
 150                 self.nextthink = time + 1;
 151                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 152         }
 153 }
 154
 155 void cvar_changes_init()
 156 {
 157         float h;
 158         string k, v, d;
 159         float n, i, adding, pureadding;
 160
 161         if(cvar_changes)
 162                 strunzone(cvar_changes);
 163         cvar_changes = string_null;
 164         if(cvar_purechanges)
 165                 strunzone(cvar_purechanges);
 166         cvar_purechanges = string_null;
 167         cvar_purechanges_count = 0;
 168
 169         h = buf_create();
 170         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 171         n = buf_getsize(h);
 172
 173         adding = true;
 174         pureadding = true;
 175
 176         for(i = 0; i < n; ++i)
 177         {
 178                 k = bufstr_get(h, i);
 179
 180 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 181 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 182 #define BADCVAR(p) if(k == p) continue
 183
 184                 // general excludes and namespaces for server admin used cvars
 185                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 186
 187                 // internal
 188                 BADPREFIX("csqc_");
 189                 BADPREFIX("cvar_check_");
 190                 BADCVAR("gamecfg");
 191                 BADCVAR("g_configversion");
 192                 BADCVAR("g_maplist_index");
 193                 BADCVAR("halflifebsp");
 194                 BADPREFIX("sv_world");
 195
 196                 // client
 197                 BADPREFIX("chase_");
 198                 BADPREFIX("cl_");
 199                 BADPREFIX("con_");
 200                 BADPREFIX("scoreboard_");
 201                 BADPREFIX("g_campaign");
 202                 BADPREFIX("g_waypointsprite_");
 203                 BADPREFIX("gl_");
 204                 BADPREFIX("joy");
 205                 BADPREFIX("hud_");
 206                 BADPREFIX("m_");
 207                 BADPREFIX("menu_");
 208                 BADPREFIX("net_slist_");
 209                 BADPREFIX("r_");
 210                 BADPREFIX("sbar_");
 211                 BADPREFIX("scr_");
 212                 BADPREFIX("snd_");
 213                 BADPREFIX("show");
 214                 BADPREFIX("sensitivity");
 215                 BADPREFIX("userbind");
 216                 BADPREFIX("v_");
 217                 BADPREFIX("vid_");
 218                 BADPREFIX("crosshair");
 219                 BADCVAR("mod_q3bsp_lightmapmergepower");
 220                 BADCVAR("mod_q3bsp_nolightmaps");
 221                 BADCVAR("fov");
 222                 BADCVAR("mastervolume");
 223                 BADCVAR("volume");
 224                 BADCVAR("bgmvolume");
 225
 226                 // private
 227                 BADCVAR("developer");
 228                 BADCVAR("log_dest_udp");
 229                 BADCVAR("net_address");
 230                 BADCVAR("net_address_ipv6");
 231                 BADCVAR("port");
 232                 BADCVAR("savedgamecfg");
 233                 BADCVAR("serverconfig");
 234                 BADCVAR("sv_autoscreenshot");
 235                 BADCVAR("sv_heartbeatperiod");
 236                 BADCVAR("sv_vote_master_password");
 237                 BADCVAR("sys_colortranslation");
 238                 BADCVAR("sys_specialcharactertranslation");
 239                 BADCVAR("timeformat");
 240                 BADCVAR("timestamps");
 241                 BADPREFIX("developer_");
 242                 BADPREFIX("g_ban_");
 243                 BADPREFIX("g_banned_list");
 244                 BADPREFIX("g_chat_flood_");
 245                 BADPREFIX("g_ghost_items");
 246                 BADPREFIX("g_playerstats_");
 247                 BADPREFIX("g_respawn_ghosts");
 248                 BADPREFIX("g_voice_flood_");
 249                 BADPREFIX("log_file");
 250                 BADPREFIX("rcon_");
 251                 BADPREFIX("sv_allowdownloads");
 252                 BADPREFIX("sv_autodemo");
 253                 BADPREFIX("sv_curl_");
 254                 BADPREFIX("sv_eventlog");
 255                 BADPREFIX("sv_logscores_");
 256                 BADPREFIX("sv_master");
 257                 BADPREFIX("sv_weaponstats_");
 258                 BADPREFIX("sv_waypointsprite_");
 259                 BADCVAR("rescan_pending");
 260
 261                 // these can contain player IDs, so better hide
 262                 BADPREFIX("g_forced_team_");
 263
 264                 // mapinfo
 265                 BADCVAR("fraglimit");
 266                 BADCVAR("g_assault");
 267                 BADCVAR("g_ca");
 268                 BADCVAR("g_ca_teams");
 269                 BADCVAR("g_ctf");
 270                 BADCVAR("g_cts");
 271                 BADCVAR("g_dm");
 272                 BADCVAR("g_domination");
 273                 BADCVAR("g_domination_default_teams");
 274                 BADCVAR("g_freezetag");
 275                 BADCVAR("g_freezetag_teams");
 276                 BADCVAR("g_keepaway");
 277                 BADCVAR("g_keyhunt");
 278                 BADCVAR("g_keyhunt_teams");
 279                 BADCVAR("g_lms");
 280                 BADCVAR("g_nexball");
 281                 BADCVAR("g_onslaught");
 282                 BADCVAR("g_race");
 283                 BADCVAR("g_race_qualifying_timelimit");
 284                 BADCVAR("g_tdm");
 285                 BADCVAR("g_tdm_teams");
 286                 BADCVAR("leadlimit");
 287                 BADCVAR("nextmap");
 288                 BADCVAR("teamplay");
 289                 BADCVAR("timelimit");
 290
 291                 // long
 292                 BADCVAR("hostname");
 293                 BADCVAR("g_maplist");
 294                 BADCVAR("g_maplist_mostrecent");
 295                 BADCVAR("sv_motd");
 296
 297                 v = cvar_string(k);
 298                 d = cvar_defstring(k);
 299                 if(v == d)
 300                         continue;
 301
 302                 if(adding)
 303                 {
 304                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 305                         if(strlen(cvar_changes) > 16384)
 306                         {
 307                                 cvar_changes = "// too many settings have been changed to show them here\n";
 308                                 adding = 0;
 309                         }
 310                 }
 311
 312                 // now check if the changes are actually gameplay relevant
 313
 314                 // does nothing visible
 315                 BADCVAR("captureleadlimit_override");
 316                 BADCVAR("g_balance_kill_delay");
 317                 BADCVAR("g_ca_point_leadlimit");
 318                 BADCVAR("g_ctf_captimerecord_always");
 319                 BADCVAR("g_ctf_flag_glowtrails");
 320                 BADCVAR("g_ctf_flag_pickup_verbosename");
 321                 BADCVAR("g_domination_point_leadlimit");
 322                 BADCVAR("g_forced_respawn");
 323                 BADCVAR("g_keyhunt_point_leadlimit");
 324                 BADPREFIX("g_mod_");
 325                 BADCVAR("g_nexball_goalleadlimit");
 326                 BADCVAR("leadlimit_and_fraglimit");
 327                 BADCVAR("leadlimit_override");
 328                 BADCVAR("pausable");
 329                 BADCVAR("sv_allow_fullbright");
 330                 BADCVAR("sv_checkforpacketsduringsleep");
 331                 BADCVAR("sv_fraginfo");
 332                 BADCVAR("sv_timeout");
 333                 BADPREFIX("sv_timeout_");
 334                 BADPREFIX("crypto_");
 335                 BADPREFIX("g_chat_");
 336                 BADPREFIX("g_ctf_captimerecord_");
 337                 BADPREFIX("g_maplist_votable_");
 338                 BADPREFIX("net_");
 339                 BADPREFIX("prvm_");
 340                 BADPREFIX("skill_");
 341                 BADPREFIX("sv_cullentities_");
 342                 BADPREFIX("sv_fraginfo_");
 343                 BADPREFIX("sv_maxidle_");
 344                 BADPREFIX("sv_vote_");
 345                 BADPREFIX("timelimit_");
 346                 BADCVAR("gameversion");
 347                 BADPREFIX("gameversion_");
 348                 BADCVAR("sv_namechangetimer");
 349
 350                 // allowed changes to server admins (please sync this to server.cfg)
 351                 // vi commands:
 352                 //   :/"impure"/,$d
 353                 //   :g!,^\/\/[^ /],d
 354                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 355                 //   :%!sort
 356                 // yes, this does contain some redundant stuff, don't really care
 357                 BADCVAR("bot_config_file");
 358                 BADCVAR("bot_number");
 359                 BADCVAR("bot_prefix");
 360                 BADCVAR("bot_suffix");
 361                 BADCVAR("capturelimit_override");
 362                 BADCVAR("fraglimit_override");
 363                 BADCVAR("gametype");
 364                 BADCVAR("g_antilag");
 365                 BADCVAR("g_balance_teams");
 366                 BADCVAR("g_balance_teams_prevent_imbalance");
 367                 BADCVAR("g_balance_teams_scorefactor");
 368                 BADCVAR("g_ban_sync_trusted_servers");
 369                 BADCVAR("g_ban_sync_uri");
 370                 BADCVAR("g_ca_teams_override");
 371                 BADCVAR("g_ctf_ignore_frags");
 372                 BADCVAR("g_domination_point_limit");
 373                 BADCVAR("g_freezetag_teams_override");
 374                 BADCVAR("g_friendlyfire");
 375                 BADCVAR("g_fullbrightitems");
 376                 BADCVAR("g_fullbrightplayers");
 377                 BADCVAR("g_keyhunt_point_limit");
 378                 BADCVAR("g_keyhunt_teams_override");
 379                 BADCVAR("g_lms_lives_override");
 380                 BADCVAR("g_maplist");
 381                 BADCVAR("g_maplist_check_waypoints");
 382                 BADCVAR("g_maplist_mostrecent_count");
 383                 BADCVAR("g_maplist_shuffle");
 384                 BADCVAR("g_maplist_votable");
 385                 BADCVAR("g_maplist_votable_abstain");
 386                 BADCVAR("g_maplist_votable_nodetail");
 387                 BADCVAR("g_maplist_votable_suggestions");
 388                 BADCVAR("g_maxplayers");
 389                 BADCVAR("g_mirrordamage");
 390                 BADCVAR("g_nexball_goallimit");
 391                 BADCVAR("g_powerups");
 392                 BADCVAR("g_start_delay");
 393                 BADCVAR("g_warmup");
 394                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 395                 BADCVAR("hostname");
 396                 BADCVAR("log_file");
 397                 BADCVAR("maxplayers");
 398                 BADCVAR("minplayers");
 399                 BADCVAR("net_address");
 400                 BADCVAR("port");
 401                 BADCVAR("rcon_password");
 402                 BADCVAR("rcon_restricted_commands");
 403                 BADCVAR("rcon_restricted_password");
 404                 BADCVAR("skill");
 405                 BADCVAR("sv_adminnick");
 406                 BADCVAR("sv_autoscreenshot");
 407                 BADCVAR("sv_autotaunt");
 408                 BADCVAR("sv_curl_defaulturl");
 409                 BADCVAR("sv_defaultcharacter");
 410                 BADCVAR("sv_defaultplayercolors");
 411                 BADCVAR("sv_defaultplayermodel");
 412                 BADCVAR("sv_defaultplayerskin");
 413                 BADCVAR("sv_maxidle");
 414                 BADCVAR("sv_maxrate");
 415                 BADCVAR("sv_motd");
 416                 BADCVAR("sv_public");
 417                 BADCVAR("sv_ready_restart");
 418                 BADCVAR("sv_status_privacy");
 419                 BADCVAR("sv_taunt");
 420                 BADCVAR("sv_vote_call");
 421                 BADCVAR("sv_vote_commands");
 422                 BADCVAR("sv_vote_majority_factor");
 423                 BADCVAR("sv_vote_master");
 424                 BADCVAR("sv_vote_master_commands");
 425                 BADCVAR("sv_vote_master_password");
 426                 BADCVAR("sv_vote_simple_majority_factor");
 427                 BADCVAR("teamplay_mode");
 428                 BADCVAR("timelimit_override");
 429                 BADCVAR("g_spawnshieldtime");
 430                 BADPREFIX("g_warmup_");
 431                 BADPREFIX("sv_ready_restart_");
 432
 433                 // mutators that announce themselves properly to the server browser
 434                 BADCVAR("g_instagib");
 435                 BADCVAR("g_new_toys");
 436                 BADCVAR("g_nix");
 437                 BADCVAR("g_grappling_hook");
 438                 BADCVAR("g_jetpack");
 439
 440 #undef BADPREFIX
 441 #undef BADCVAR
 442
 443                 if(pureadding)
 444                 {
 445                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 446                         if(strlen(cvar_purechanges) > 16384)
 447                         {
 448                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 449                                 pureadding = 0;
 450                         }
 451                 }
 452                 ++cvar_purechanges_count;
 453                 // WARNING: this variable is used for the server list
 454                 // NEVER dare to skip this code!
 455                 // Hacks to intentionally appearing as "pure server" even though you DO have
 456                 // modified settings may be punished by removal from the server list.
 457                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 458                 // though.
 459         }
 460         buf_del(h);
 461         if(cvar_changes == "")
 462                 cvar_changes = "// this server runs at default server settings\n";
 463         else
 464                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 465         cvar_changes = strzone(cvar_changes);
 466         if(cvar_purechanges == "")
 467                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 468         else
 469                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 470         cvar_purechanges = strzone(cvar_purechanges);
 471 }
 472
 473 void detect_maptype()
 474 {
 475 #if 0
 476         vector o, v;
 477         float i;
 478
 479         for (;;)
 480         {
 481                 o = world.mins;
 482                 o.x += random() * (world.maxs.x - world.mins.x);
 483                 o.y += random() * (world.maxs.y - world.mins.y);
 484                 o.z += random() * (world.maxs.z - world.mins.z);
 485
 486                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 487                 if(trace_fraction == 1)
 488                         continue;
 489
 490                 v = trace_endpos;
 491
 492                 for(i = 0; i < 64; i += 4)
 493                 {
 494                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 495         if(trace_fraction == 1)
 496                 continue;
 497                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 498                 }
 499
 500                 break;
 501         }
 502 #endif
 503 }
 504
 505 entity randomseed;
 506 float RandomSeed_Send(entity to, float sf)
 507 {
 508         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 509         WriteShort(MSG_ENTITY, self.cnt);
 510         return true;
 511 }
 512 void RandomSeed_Think()
 513 {
 514         self.cnt = bound(0, floor(random() * 65536), 65535);
 515         self.nextthink = time + 5;
 516
 517         self.SendFlags |= 1;
 518 }
 519 void RandomSeed_Spawn()
 520 {
 521         randomseed = spawn();
 522         randomseed.think = RandomSeed_Think;
 523         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 524
 525         entity oldself;
 526         oldself = self;
 527         self = randomseed;
 528         self.think(); // sets random seed and nextthink
 529         self = oldself;
 530 }
 531
 532 void spawnfunc___init_dedicated_server(void)
 533 {
 534         // handler for _init/_init map (only for dedicated server initialization)
 535
 536         world_initialized = -1; // don't complain
 537         cvar = cvar_normal;
 538         cvar_string = cvar_string_normal;
 539         cvar_set = cvar_set_normal;
 540
 541         remove = remove_unsafely;
 542
 543         entity e;
 544         e = spawn();
 545         e.think = GotoFirstMap;
 546         e.nextthink = time; // this is usually 1 at this point
 547
 548         e = spawn();
 549         e.classname = "info_player_deathmatch"; // safeguard against player joining
 550
 551         self.classname = "worldspawn"; // safeguard against various stuff ;)
 552
 553         // needs to be done so early because of the constants they create
 554         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 555         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 556         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 557         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 558         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 559         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 560
 561         MapInfo_Enumerate();
 562         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 563 }
 564
 565 void Map_MarkAsRecent(string m);
 566 float world_already_spawned;
 567 void Nagger_Init();
 568 void ClientInit_Spawn();
 569 void WeaponStats_Init();
 570 void WeaponStats_Shutdown();
 571 void Physics_AddStats();
 572 void spawnfunc_worldspawn (void)
 573 {
 574         float fd, l, i, j, n;
 575         string s;
 576
 577         cvar = cvar_normal;
 578         cvar_string = cvar_string_normal;
 579         cvar_set = cvar_set_normal;
 580
 581         if(world_already_spawned)
 582                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 583         world_already_spawned = true;
 584
 585         remove = remove_safely; // during spawning, watch what you remove!
 586
 587         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 588
 589         compressShortVector_init();
 590
 591         entity head;
 592         head = nextent(world);
 593         maxclients = 0;
 594         while(head)
 595         {
 596                 ++maxclients;
 597                 head = nextent(head);
 598         }
 599
 600         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 601
 602         // needs to be done so early because of the constants they create
 603         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 604         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 605         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 606         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 607         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 608         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 609
 610         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 611
 612         TemporaryDB = db_create();
 613
 614         // 0 normal
 615         lightstyle(0, "m");
 616
 617         // 1 FLICKER (first variety)
 618         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 619
 620         // 2 SLOW STRONG PULSE
 621         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 622
 623         // 3 CANDLE (first variety)
 624         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 625
 626         // 4 FAST STROBE
 627         lightstyle(4, "mamamamamama");
 628
 629         // 5 GENTLE PULSE 1
 630         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 631
 632         // 6 FLICKER (second variety)
 633         lightstyle(6, "nmonqnmomnmomomno");
 634
 635         // 7 CANDLE (second variety)
 636         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 637
 638         // 8 CANDLE (third variety)
 639         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 640
 641         // 9 SLOW STROBE (fourth variety)
 642         lightstyle(9, "aaaaaaaazzzzzzzz");
 643
 644         // 10 FLUORESCENT FLICKER
 645         lightstyle(10, "mmamammmmammamamaaamammma");
 646
 647         // 11 SLOW PULSE NOT FADE TO BLACK
 648         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 649
 650         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 651
 652         // 63 testing
 653         lightstyle(63, "a");
 654
 655         if(autocvar_g_campaign)
 656                 CampaignPreInit();
 657
 658         Map_MarkAsRecent(mapname);
 659
 660         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 661
 662         precache_model ("null"); // we need this one before InitGameplayMode
 663         InitGameplayMode();
 664         readlevelcvars();
 665         GrappleHookInit();
 666
 667         player_count = 0;
 668         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 669         if(bot_waypoints_for_items == 1)
 670                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 671                         bot_waypoints_for_items = 0;
 672
 673         precache();
 674
 675         WaypointSprite_Init();
 676
 677         GameLogInit(); // prepare everything
 678         // NOTE for matchid:
 679         // changing the logic generating it is okay. But:
 680         // it HAS to stay <= 64 chars
 681         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 682         if(autocvar_sv_eventlog)
 683         {
 684                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 685                 matchid = strzone(s);
 686
 687                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 688                 s = ":gameinfo:mutators:LIST";
 689
 690                 ret_string = s;
 691                 MUTATOR_CALLHOOK(BuildMutatorsString);
 692                 s = ret_string;
 693
 694                 // simple, probably not good in the mutator system
 695                 if(autocvar_g_grappling_hook)
 696                         s = strcat(s, ":grappling_hook");
 697
 698                 // initialiation stuff, not good in the mutator system
 699                 if(!autocvar_g_use_ammunition)
 700                         s = strcat(s, ":no_use_ammunition");
 701
 702                 // initialiation stuff, not good in the mutator system
 703                 if(autocvar_g_pickup_items == 0)
 704                         s = strcat(s, ":no_pickup_items");
 705                 if(autocvar_g_pickup_items > 0)
 706                         s = strcat(s, ":pickup_items");
 707
 708                 // initialiation stuff, not good in the mutator system
 709                 if(autocvar_g_weaponarena != "0")
 710                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 711
 712                 // TODO to mutator system
 713                 if(autocvar_g_norecoil)
 714                         s = strcat(s, ":norecoil");
 715
 716                 // TODO to mutator system
 717                 if(autocvar_g_powerups == 0)
 718                         s = strcat(s, ":no_powerups");
 719                 if(autocvar_g_powerups > 0)
 720                         s = strcat(s, ":powerups");
 721
 722                 GameLogEcho(s);
 723                 GameLogEcho(":gameinfo:end");
 724         }
 725         else
 726                 matchid = strzone(ftos(random()));
 727
 728         cvar_set("nextmap", "");
 729
 730         SetDefaultAlpha();
 731
 732         if(autocvar_g_campaign)
 733                 CampaignPostInit();
 734
 735         Ban_LoadBans();
 736
 737         MapInfo_Enumerate();
 738         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 739
 740         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 741         {
 742                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 743                 if(fd != -1)
 744                 {
 745                         while((s = fgets(fd)))
 746                         {
 747                                 l = tokenize_console(s);
 748                                 if(l < 2)
 749                                         continue;
 750                                 if(argv(0) == "cd")
 751                                 {
 752                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 753                                         print("  cdtrack ", argv(2), "\n");
 754                                 }
 755                                 else if(argv(0) == "fog")
 756                                 {
 757                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 758                                         print("  \"fog\" \"", s, "\"\n");
 759                                 }
 760                                 else if(argv(0) == "set")
 761                                 {
 762                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 763                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 764                                 }
 765                                 else if(argv(0) != "//")
 766                                 {
 767                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 768                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 769                                 }
 770                         }
 771                         fclose(fd);
 772                 }
 773         }
 774
 775         WeaponStats_Init();
 776
 777         WepSet_AddStat();
 778         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 779         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 780         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 781         addstat(STAT_ROUNDSTARTTIME, AS_FLOAT, stat_round_starttime);
 782         addstat(STAT_ALLOW_OLDVORTEXBEAM, AS_INT, stat_allow_oldvortexbeam);
 783         Nagger_Init();
 784
 785         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 786         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 787         addstat(STAT_SUPERWEAPONS_FINISHED, AS_FLOAT, superweapons_finished);
 788         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 789         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 790         addstat(STAT_PLASMA, AS_INT, ammo_plasma);
 791         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 792         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 793         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 794         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 795         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 796         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 797         addstat(STAT_DAMAGE_DEALT_TOTAL, AS_INT, damage_dealt_total);
 798         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 799         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 800
 801         addstat(STAT_VORTEX_CHARGE, AS_FLOAT, vortex_charge);
 802         addstat(STAT_VORTEX_CHARGEPOOL, AS_FLOAT, vortex_chargepool_ammo);
 803
 804         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 805
 806         addstat(STAT_ARC_HEAT, AS_FLOAT, arc_heat_percent);
 807
 808         // freeze attacks
 809         addstat(STAT_FROZEN, AS_INT, frozen);
 810         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 811
 812         // physics
 813         Physics_AddStats();
 814
 815         // secrets
 816         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 817         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 818
 819         // monsters
 820         addstat(STAT_MONSTERS_TOTAL, AS_FLOAT, stat_monsters_total);
 821         addstat(STAT_MONSTERS_KILLED, AS_FLOAT, stat_monsters_killed);
 822
 823         // misc
 824         addstat(STAT_RESPAWN_TIME, AS_FLOAT, stat_respawn_time);
 825
 826         next_pingtime = time + 5;
 827
 828         detect_maptype();
 829
 830         // set up information replies for clients and server to use
 831         maplist_reply = strzone(getmaplist());
 832         lsmaps_reply = strzone(getlsmaps());
 833         monsterlist_reply = strzone(getmonsterlist());
 834         for(i = 0; i < 10; ++i)
 835         {
 836                 s = getrecords(i);
 837                 if (s)
 838                         records_reply[i] = strzone(s);
 839         }
 840         ladder_reply = strzone(getladder());
 841         rankings_reply = strzone(getrankings());
 842
 843         // begin other init
 844         ClientInit_Spawn();
 845         RandomSeed_Spawn();
 846         PingPLReport_Spawn();
 847
 848         CheatInit();
 849
 850         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 851
 852         // fill sv_curl_serverpackages from .serverpackage files
 853         if(autocvar_sv_curl_serverpackages_auto)
 854         {
 855                 s = "";
 856                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 857                 for(i = 0; i < n; ++i)
 858                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 859                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 860                                 s = strcat(s, " ", argv(i));
 861                 fd = search_begin("*-serverpackage.txt", true, false);
 862                 if(fd >= 0)
 863                 {
 864                         j = search_getsize(fd);
 865                         for(i = 0; i < j; ++i)
 866                                 s = strcat(s, " ", search_getfilename(fd, i));
 867                         search_end(fd);
 868                 }
 869                 fd = search_begin("*.serverpackage", true, false);
 870                 if(fd >= 0)
 871                 {
 872                         j = search_getsize(fd);
 873                         for(i = 0; i < j; ++i)
 874                                 s = strcat(s, " ", search_getfilename(fd, i));
 875                         search_end(fd);
 876                 }
 877                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 878         }
 879
 880         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 881         modname = "Xonotic";
 882         // physics/balance/config changes that count as mod
 883         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 884                 modname = cvar_string("g_mod_physics");
 885         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 886                 modname = cvar_string("g_mod_balance");
 887         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 888                 modname = cvar_string("g_mod_config");
 889         // extra mutators that deserve to count as mod
 890         MUTATOR_CALLHOOK(SetModname);
 891
 892         // save it for later
 893         modname = strzone(modname);
 894
 895         WinningConditionHelper(); // set worldstatus
 896
 897         world_initialized = 1;
 898 }
 899
 900 void spawnfunc_light (void)
 901 {
 902         //makestatic (self); // Who the f___ did that?
 903         remove(self);
 904 }
 905
 906 string GetGametype()
 907 {
 908         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 909 }
 910
 911 string GetMapname()
 912 {
 913         return mapname;
 914 }
 915
 916 float Map_Count, Map_Current;
 917 string Map_Current_Name;
 918
 919 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 920 float GetMaplistPosition()
 921 {
 922         float pos, idx;
 923         string map;
 924
 925         map = GetMapname();
 926         idx = autocvar_g_maplist_index;
 927
 928         if(idx >= 0)
 929                 if(idx < Map_Count)
 930                         if(map == argv(idx))
 931                                 return idx;
 932
 933         for(pos = 0; pos < Map_Count; ++pos)
 934                 if(map == argv(pos))
 935                         return pos;
 936
 937         // resume normal maplist rotation if current map is not in g_maplist
 938         return idx;
 939 }
 940
 941 float MapHasRightSize(string map)
 942 {
 943         float fh;
 944         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 945         if(autocvar_g_maplist_check_waypoints)
 946         {
 947                 dprint("checkwp "); dprint(map);
 948                 if(!fexists(strcat("maps/", map, ".waypoints")))
 949                 {
 950                         dprint(": no waypoints\n");
 951                         return false;
 952                 }
 953                 dprint(": has waypoints\n");
 954         }
 955
 956         // open map size restriction file
 957         dprint("opensize "); dprint(map);
 958         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 959         if(fh >= 0)
 960         {
 961                 float mapmin, mapmax;
 962                 dprint(": ok, ");
 963                 mapmin = stof(fgets(fh));
 964                 mapmax = stof(fgets(fh));
 965                 fclose(fh);
 966                 if(player_count < mapmin)
 967                 {
 968                         dprint("not enough\n");
 969                         return false;
 970                 }
 971                 if(player_count > mapmax)
 972                 {
 973                         dprint("too many\n");
 974                         return false;
 975                 }
 976                 dprint("right size\n");
 977                 return true;
 978         }
 979         dprint(": not found\n");
 980         return true;
 981 }
 982
 983 string Map_Filename(float position)
 984 {
 985         return strcat("maps/", argv(position), ".bsp");
 986 }
 987
 988 string strwords(string s, float w)
 989 {
 990         float endpos;
 991         for(endpos = 0; w && endpos >= 0; --w)
 992                 endpos = strstrofs(s, " ", endpos + 1);
 993         if(endpos < 0)
 994                 return s;
 995         else
 996                 return substring(s, 0, endpos);
 997 }
 998
 999 float strhasword(string s, string w)
1000 {
1001         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1002 }
1003
1004 void Map_MarkAsRecent(string m)
1005 {
1006         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1007 }
1008
1009 float Map_IsRecent(string m)
1010 {
1011         return strhasword(autocvar_g_maplist_mostrecent, m);
1012 }
1013
1014 float Map_Check(float position, float pass)
1015 {
1016         string filename;
1017         string map_next;
1018         map_next = argv(position);
1019         if(pass <= 1)
1020         {
1021                 if(Map_IsRecent(map_next))
1022                         return 0;
1023         }
1024         filename = Map_Filename(position);
1025         if(MapInfo_CheckMap(map_next))
1026         {
1027                 if(pass == 2)
1028                         return 1;
1029                 if(MapHasRightSize(map_next))
1030                         return 1;
1031                 return 0;
1032         }
1033         else
1034                 dprint( "Couldn't select '", filename, "'..\n" );
1035
1036         return 0;
1037 }
1038
1039 void Map_Goto_SetStr(string nextmapname)
1040 {
1041         if(getmapname_stored != "")
1042                 strunzone(getmapname_stored);
1043         if(nextmapname == "")
1044                 getmapname_stored = "";
1045         else
1046                 getmapname_stored = strzone(nextmapname);
1047 }
1048
1049 void Map_Goto_SetFloat(float position)
1050 {
1051         cvar_set("g_maplist_index", ftos(position));
1052         Map_Goto_SetStr(argv(position));
1053 }
1054
1055 void Map_Goto(float reinit)
1056 {
1057         MapInfo_LoadMap(getmapname_stored, reinit);
1058 }
1059
1060 // return codes of map selectors:
1061 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1062 //   -2 = permanent failure
1063 float() MaplistMethod_Iterate = // usual method
1064 {
1065         float pass, i;
1066
1067         dprint("Trying MaplistMethod_Iterate\n");
1068
1069         for(pass = 1; pass <= 2; ++pass)
1070         {
1071                 for(i = 1; i < Map_Count; ++i)
1072                 {
1073                         float mapindex;
1074                         mapindex = (i + Map_Current) % Map_Count;
1075                         if(Map_Check(mapindex, pass))
1076                                 return mapindex;
1077                 }
1078         }
1079         return -1;
1080 }
1081
1082 float() MaplistMethod_Repeat = // fallback method
1083 {
1084         dprint("Trying MaplistMethod_Repeat\n");
1085
1086         if(Map_Check(Map_Current, 2))
1087                 return Map_Current;
1088         return -2;
1089 }
1090
1091 float() MaplistMethod_Random = // random map selection
1092 {
1093         float i, imax;
1094
1095         dprint("Trying MaplistMethod_Random\n");
1096
1097         imax = 42;
1098
1099         for(i = 0; i <= imax; ++i)
1100         {
1101                 float mapindex;
1102                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1103                 if(Map_Check(mapindex, 1))
1104                         return mapindex;
1105         }
1106         return -1;
1107 }
1108
1109 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1110 // the exponent sets a bias on the map selection:
1111 // the higher the exponent, the less likely "shortly repeated" same maps are
1112 {
1113         float i, j, imax, insertpos;
1114
1115         dprint("Trying MaplistMethod_Shuffle\n");
1116
1117         imax = 42;
1118
1119         for(i = 0; i <= imax; ++i)
1120         {
1121                 string newlist;
1122
1123                 // now reinsert this at another position
1124                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1125                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1126                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1127                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1128
1129                 // insert the current map there
1130                 newlist = "";
1131                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1132                         newlist = strcat(newlist, " ", argv(j));
1133                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1134                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1135                         newlist = strcat(newlist, " ", argv(j));
1136                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1137                 cvar_set("g_maplist", newlist);
1138                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1139
1140                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1141                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1142                 if(Map_Check(Map_Current, 1))
1143                         return Map_Current;
1144         }
1145         return -1;
1146 }
1147
1148 void Maplist_Init()
1149 {
1150         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1151         float i;
1152         for (i = 0; i < Map_Count; ++i)
1153                 if (Map_Check(i, 2))
1154                         break;
1155         if (i == Map_Count)
1156         {
1157                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1158                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1159                 if(autocvar_g_maplist_shuffle)
1160                         ShuffleMaplist();
1161                 localcmd("\nmenu_cmd sync\n");
1162                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1163         }
1164         if(Map_Count == 0)
1165                 error("empty maplist, cannot select a new map");
1166         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1167
1168         if(Map_Current_Name)
1169                 strunzone(Map_Current_Name);
1170         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1171         // this may or may not be correct, but who cares, in the worst case a map
1172         // isn't chosen in the first pass that should have been
1173 }
1174
1175 string GetNextMap()
1176 {
1177         float nextMap;
1178
1179         Maplist_Init();
1180         nextMap = -1;
1181
1182         if(nextMap == -1)
1183                 if(autocvar_g_maplist_shuffle > 0)
1184                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1185
1186         if(nextMap == -1)
1187                 if(autocvar_g_maplist_selectrandom)
1188                         nextMap = MaplistMethod_Random();
1189
1190         if(nextMap == -1)
1191                 nextMap = MaplistMethod_Iterate();
1192
1193         if(nextMap == -1)
1194                 nextMap = MaplistMethod_Repeat();
1195
1196         if(nextMap >= 0)
1197         {
1198                 Map_Goto_SetFloat(nextMap);
1199                 return getmapname_stored;
1200         }
1201
1202         return "";
1203 }
1204
1205 float DoNextMapOverride(float reinit)
1206 {
1207         if(autocvar_g_campaign)
1208         {
1209                 CampaignPostIntermission();
1210                 alreadychangedlevel = true;
1211                 return true;
1212         }
1213         if(autocvar_quit_when_empty)
1214         {
1215                 if(player_count <= currentbots)
1216                 {
1217                         localcmd("quit\n");
1218                         alreadychangedlevel = true;
1219                         return true;
1220                 }
1221         }
1222         if(autocvar_quit_and_redirect != "")
1223         {
1224                 redirection_target = strzone(autocvar_quit_and_redirect);
1225                 alreadychangedlevel = true;
1226                 return true;
1227         }
1228         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1229         {
1230                 localcmd("restart\n");
1231                 alreadychangedlevel = true;
1232                 return true;
1233         }
1234         if(autocvar_nextmap != "")
1235         {
1236                 string m;
1237                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1238                 cvar_set("nextmap",m);
1239
1240                 if(!m || gametypevote)
1241                         return false;
1242                 if(autocvar_sv_vote_gametype)
1243                 {
1244                         Map_Goto_SetStr(m);
1245                         return false;
1246                 }
1247
1248                 if(MapInfo_CheckMap(m))
1249                 {
1250                         Map_Goto_SetStr(m);
1251                         Map_Goto(reinit);
1252                         alreadychangedlevel = true;
1253                         return true;
1254                 }
1255         }
1256         if(!reinit && autocvar_lastlevel)
1257         {
1258                 cvar_settemp_restore();
1259                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1260                 alreadychangedlevel = true;
1261                 return true;
1262         }
1263         return false;
1264 }
1265
1266 void GotoNextMap(float reinit)
1267 {
1268         //string nextmap;
1269         //float n, nummaps;
1270         //string s;
1271         if (alreadychangedlevel)
1272                 return;
1273         alreadychangedlevel = true;
1274
1275         string nextMap;
1276
1277         nextMap = GetNextMap();
1278         if(nextMap == "")
1279                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1280         Map_Goto(reinit);
1281 }
1282
1283
1284 /*
1285 ============
1286 IntermissionThink
1287
1288 When the player presses attack or jump, change to the next level
1289 ============
1290 */
1291 .float autoscreenshot;
1292 void IntermissionThink()
1293 {
1294         FixIntermissionClient(self);
1295
1296         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1297         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1298
1299         if( (server_screenshot || client_screenshot)
1300                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1301         {
1302                 self.autoscreenshot = -1;
1303                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1304                 return;
1305         }
1306
1307         if (time < intermission_exittime)
1308                 return;
1309
1310         if(!mapvote_initialized)
1311                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1312                         return;
1313
1314         MapVote_Start();
1315 }
1316
1317 /*
1318 ============
1319 FindIntermission
1320
1321 Returns the entity to view from
1322 ============
1323 */
1324 /*
1325 entity FindIntermission()
1326 {
1327         local   entity spot;
1328         local   float cyc;
1329
1330 // look for info_intermission first
1331         spot = find (world, classname, "info_intermission");
1332         if (spot)
1333         {       // pick a random one
1334                 cyc = random() * 4;
1335                 while (cyc > 1)
1336                 {
1337                         spot = find (spot, classname, "info_intermission");
1338                         if (!spot)
1339                                 spot = find (spot, classname, "info_intermission");
1340                         cyc = cyc - 1;
1341                 }
1342                 return spot;
1343         }
1344
1345 // then look for the start position
1346         spot = find (world, classname, "info_player_start");
1347         if (spot)
1348                 return spot;
1349
1350 // testinfo_player_start is only found in regioned levels
1351         spot = find (world, classname, "testplayerstart");
1352         if (spot)
1353                 return spot;
1354
1355 // then look for the start position
1356         spot = find (world, classname, "info_player_deathmatch");
1357         if (spot)
1358                 return spot;
1359
1360         //objerror ("FindIntermission: no spot");
1361         return world;
1362 }
1363 */
1364
1365 /*
1366 ===============================================================================
1367
1368 RULES
1369
1370 ===============================================================================
1371 */
1372
1373 void DumpStats(float final)
1374 {
1375         float file;
1376         string s;
1377         float to_console;
1378         float to_eventlog;
1379         float to_file;
1380         float i;
1381
1382         to_console = autocvar_sv_logscores_console;
1383         to_eventlog = autocvar_sv_eventlog;
1384         to_file = autocvar_sv_logscores_file;
1385
1386         if(!final)
1387         {
1388                 to_console = true; // always print printstats replies
1389                 to_eventlog = false; // but never print them to the event log
1390         }
1391
1392         if(to_eventlog)
1393                 if(autocvar_sv_eventlog_console)
1394                         to_console = false; // otherwise we get the output twice
1395
1396         if(final)
1397                 s = ":scores:";
1398         else
1399                 s = ":status:";
1400         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1401
1402         if(to_console)
1403                 print(s, "\n");
1404         if(to_eventlog)
1405                 GameLogEcho(s);
1406
1407         file = -1;
1408         if(to_file)
1409         {
1410                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1411                 if(file == -1)
1412                         to_file = false;
1413                 else
1414                         fputs(file, strcat(s, "\n"));
1415         }
1416
1417         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1418         if(to_console)
1419                 print(s, "\n");
1420         if(to_eventlog)
1421                 GameLogEcho(s);
1422         if(to_file)
1423                 fputs(file, strcat(s, "\n"));
1424
1425         FOR_EACH_CLIENT(other)
1426         {
1427                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1428                 {
1429                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1430                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1431                         if(IS_PLAYER(other) || other.caplayer == 1 || g_lms)
1432                                 s = strcat(s, ftos(other.team), ":");
1433                         else
1434                                 s = strcat(s, "spectator:");
1435
1436                         if(to_console)
1437                                 print(s, other.netname, "\n");
1438                         if(to_eventlog)
1439                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1440                         if(to_file)
1441                                 fputs(file, strcat(s, other.netname, "\n"));
1442                 }
1443         }
1444
1445         if(teamplay)
1446         {
1447                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1448                 if(to_console)
1449                         print(s, "\n");
1450                 if(to_eventlog)
1451                         GameLogEcho(s);
1452                 if(to_file)
1453                         fputs(file, strcat(s, "\n"));
1454
1455                 for(i = 1; i < 16; ++i)
1456                 {
1457                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1458                         s = strcat(s, ":", ftos(i));
1459                         if(to_console)
1460                                 print(s, "\n");
1461                         if(to_eventlog)
1462                                 GameLogEcho(s);
1463                         if(to_file)
1464                                 fputs(file, strcat(s, "\n"));
1465                 }
1466         }
1467
1468         if(to_console)
1469                 print(":end\n");
1470         if(to_eventlog)
1471                 GameLogEcho(":end");
1472         if(to_file)
1473         {
1474                 fputs(file, ":end\n");
1475                 fclose(file);
1476         }
1477 }
1478
1479 void FixIntermissionClient(entity e)
1480 {
1481         string s;
1482         if(!e.autoscreenshot) // initial call
1483         {
1484                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1485                 e.health = -2342;
1486                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1487                 e.solid = SOLID_NOT;
1488                 e.movetype = MOVETYPE_NONE;
1489                 e.takedamage = DAMAGE_NO;
1490                 if(e.weaponentity)
1491                 {
1492                         e.weaponentity.effects = EF_NODRAW;
1493                         if (e.weaponentity.weaponentity)
1494                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1495                 }
1496                 if(IS_REAL_CLIENT(e))
1497                 {
1498                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1499                         s = autocvar_sv_intermission_cdtrack;
1500                         if(s != "")
1501                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1502                         msg_entity = e;
1503                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1504                 }
1505         }
1506 }
1507
1508 /*
1509 go to the next level for deathmatch
1510 only called if a time or frag limit has expired
1511 */
1512 void NextLevel()
1513 {
1514         gameover = true;
1515
1516         intermission_running = 1;
1517
1518 // enforce a wait time before allowing changelevel
1519         if(player_count > 0)
1520                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1521         else
1522                 intermission_exittime = -1;
1523
1524         /*
1525         WriteByte (MSG_ALL, SVC_CDTRACK);
1526         WriteByte (MSG_ALL, 3);
1527         WriteByte (MSG_ALL, 3);
1528         // done in FixIntermission
1529         */
1530
1531         //pos = FindIntermission ();
1532
1533         VoteReset();
1534
1535         DumpStats(true);
1536
1537         // send statistics
1538         PlayerStats_GameReport(true);
1539         WeaponStats_Shutdown();
1540
1541         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1542
1543         if(autocvar_sv_eventlog)
1544                 GameLogEcho(":gameover");
1545
1546         GameLogClose();
1547
1548         FOR_EACH_PLAYER(other) {
1549                 FixIntermissionClient(other);
1550                 if(other.winning)
1551                         bprint(other.netname, " ^7wins.\n");
1552         }
1553
1554         if(autocvar_g_campaign)
1555                 CampaignPreIntermission();
1556
1557         MUTATOR_CALLHOOK(MatchEnd);
1558
1559         localcmd("\nsv_hook_gameend\n");
1560 }
1561
1562 /*
1563 ============
1564 CheckRules_Player
1565
1566 Exit deathmatch games upon conditions
1567 ============
1568 */
1569 void CheckRules_Player()
1570 {
1571         if (gameover)   // someone else quit the game already
1572                 return;
1573
1574         if(self.deadflag == DEAD_NO)
1575                 self.play_time += frametime;
1576
1577         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1578         //   (div0: and that in CheckRules_World please)
1579 }
1580
1581
1582 float InitiateSuddenDeath()
1583 {
1584         // Check first whether normal overtimes could be added before initiating suddendeath mode
1585         // - for this timelimit_overtime needs to be >0 of course
1586         // - also check the winning condition calculated in the previous frame and only add normal overtime
1587         //   again, if at the point at which timelimit would be extended again, still no winner was found
1588         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1589         {
1590                 return 1; // need to call InitiateOvertime later
1591         }
1592         else
1593         {
1594                 if(!checkrules_suddendeathend)
1595                 {
1596                         if(autocvar_g_campaign)
1597                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1598                         else
1599                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1600                         if(g_race && !g_race_qualifying)
1601                                 race_StartCompleting();
1602                 }
1603                 return 0;
1604         }
1605 }
1606
1607 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1608 {
1609         ++checkrules_overtimesadded;
1610         //add one more overtime by simply extending the timelimit
1611         float tl;
1612         tl = autocvar_timelimit;
1613         tl += autocvar_timelimit_overtime;
1614         cvar_set("timelimit", ftos(tl));
1615
1616         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1617 }
1618
1619 float GetWinningCode(float fraglimitreached, float equality)
1620 {
1621         if(autocvar_g_campaign == 1)
1622                 if(fraglimitreached)
1623                         return WINNING_YES;
1624                 else
1625                         return WINNING_NO;
1626
1627         else
1628                 if(equality)
1629                         if(fraglimitreached)
1630                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1631                         else
1632                                 return WINNING_NEVER;
1633                 else
1634                         if(fraglimitreached)
1635                                 return WINNING_YES;
1636                         else
1637                                 return WINNING_NO;
1638 }
1639
1640 // set the .winning flag for exactly those players with a given field value
1641 void SetWinners(.float field, float value)
1642 {
1643         entity head;
1644         FOR_EACH_PLAYER(head)
1645                 head.winning = (head.field == value);
1646 }
1647
1648 // set the .winning flag for those players with a given field value
1649 void AddWinners(.float field, float value)
1650 {
1651         entity head;
1652         FOR_EACH_PLAYER(head)
1653                 if(head.field == value)
1654                         head.winning = 1;
1655 }
1656
1657 // clear the .winning flags
1658 void ClearWinners(void)
1659 {
1660         entity head;
1661         FOR_EACH_PLAYER(head)
1662                 head.winning = 0;
1663 }
1664
1665 // Onslaught winning condition:
1666 // game terminates if only one team has a working generator (or none)
1667 float WinningCondition_Onslaught()
1668 {
1669         entity head;
1670         float t1, t2, t3, t4;
1671
1672         WinningConditionHelper(); // set worldstatus
1673
1674         if(warmup_stage)
1675                 return WINNING_NO;
1676
1677         // first check if the game has ended
1678         t1 = t2 = t3 = t4 = 0;
1679         head = find(world, classname, "onslaught_generator");
1680         while (head)
1681         {
1682                 if (head.health > 0)
1683                 {
1684                         if (head.team == NUM_TEAM_1) t1 = 1;
1685                         if (head.team == NUM_TEAM_2) t2 = 1;
1686                         if (head.team == NUM_TEAM_3) t3 = 1;
1687                         if (head.team == NUM_TEAM_4) t4 = 1;
1688                 }
1689                 head = find(head, classname, "onslaught_generator");
1690         }
1691         if (t1 + t2 + t3 + t4 < 2)
1692         {
1693                 // game over, only one team remains (or none)
1694                 ClearWinners();
1695                 if (t1) SetWinners(team, NUM_TEAM_1);
1696                 if (t2) SetWinners(team, NUM_TEAM_2);
1697                 if (t3) SetWinners(team, NUM_TEAM_3);
1698                 if (t4) SetWinners(team, NUM_TEAM_4);
1699                 dprint("Have a winner, ending game.\n");
1700                 return WINNING_YES;
1701         }
1702
1703         // Two or more teams remain
1704         return WINNING_NO;
1705 }
1706
1707 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1708 // they win. Otherwise the defending team wins once the timelimit passes.
1709 void assault_new_round();
1710 float WinningCondition_Assault()
1711 {
1712         float status;
1713
1714         WinningConditionHelper(); // set worldstatus
1715
1716         status = WINNING_NO;
1717         // as the timelimit has not yet passed just assume the defending team will win
1718         if(assault_attacker_team == NUM_TEAM_1)
1719         {
1720                 SetWinners(team, NUM_TEAM_2);
1721         }
1722         else
1723         {
1724                 SetWinners(team, NUM_TEAM_1);
1725         }
1726
1727         entity ent;
1728         ent = find(world, classname, "target_assault_roundend");
1729         if(ent)
1730         {
1731                 if(ent.winning) // round end has been triggered by attacking team
1732                 {
1733                         bprint("ASSAULT: round completed...\n");
1734                         SetWinners(team, assault_attacker_team);
1735
1736                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1737
1738                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1739                         {
1740                                 status = WINNING_YES;
1741                         }
1742                         else
1743                         {
1744                                 entity oldself;
1745                                 oldself = self;
1746                                 self = ent;
1747                                 assault_new_round();
1748                                 self = oldself;
1749                         }
1750                 }
1751         }
1752
1753         return status;
1754 }
1755
1756 // LMS winning condition: game terminates if and only if there's at most one
1757 // one player who's living lives. Top two scores being equal cancels the time
1758 // limit.
1759 float WinningCondition_LMS()
1760 {
1761         entity head, head2;
1762         float have_player;
1763         float have_players;
1764         float l;
1765
1766         have_player = false;
1767         have_players = false;
1768         l = LMS_NewPlayerLives();
1769
1770         head = find(world, classname, "player");
1771         if(head)
1772                 have_player = true;
1773         head2 = find(head, classname, "player");
1774         if(head2)
1775                 have_players = true;
1776
1777         if(have_player)
1778         {
1779                 // we have at least one player
1780                 if(have_players)
1781                 {
1782                         // two or more active players - continue with the game
1783                 }
1784                 else
1785                 {
1786                         // exactly one player?
1787
1788                         ClearWinners();
1789                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1790
1791                         if(l)
1792                         {
1793                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1794                                 return WINNING_NO;
1795                         }
1796                         else
1797                         {
1798                                 // a winner!
1799                                 // and assign him his first place
1800                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1801                                 return WINNING_YES;
1802                         }
1803                 }
1804         }
1805         else
1806         {
1807                 // nobody is playing at all...
1808                 if(l)
1809                 {
1810                         // wait for players...
1811                 }
1812                 else
1813                 {
1814                         // SNAFU (maybe a draw game?)
1815                         ClearWinners();
1816                         dprint("No players, ending game.\n");
1817                         return WINNING_YES;
1818                 }
1819         }
1820
1821         // When we get here, we have at least two players who are actually LIVING,
1822         // now check if the top two players have equal score.
1823         WinningConditionHelper();
1824
1825         ClearWinners();
1826         if(WinningConditionHelper_winner)
1827                 WinningConditionHelper_winner.winning = true;
1828         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1829                 return WINNING_NEVER;
1830
1831         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1832         return WINNING_NO;
1833 }
1834
1835 void ShuffleMaplist()
1836 {
1837         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1838 }
1839
1840 float leaderfrags;
1841 float WinningCondition_Scores(float limit, float leadlimit)
1842 {
1843         float limitreached;
1844
1845         // TODO make everything use THIS winning condition (except LMS)
1846         WinningConditionHelper();
1847
1848         if(teamplay)
1849         {
1850                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1851                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1852                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1853                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1854         }
1855
1856         ClearWinners();
1857         if(WinningConditionHelper_winner)
1858                 WinningConditionHelper_winner.winning = 1;
1859         if(WinningConditionHelper_winnerteam >= 0)
1860                 SetWinners(team, WinningConditionHelper_winnerteam);
1861
1862         if(WinningConditionHelper_lowerisbetter)
1863         {
1864                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1865                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1866                 limit = -limit;
1867         }
1868
1869         if(WinningConditionHelper_zeroisworst)
1870                 leadlimit = 0; // not supported in this mode
1871
1872         if(g_dm || g_tdm || g_ca || g_freezetag || (g_race && !g_race_qualifying) || g_nexball)
1873         // these modes always score in increments of 1, thus this makes sense
1874         {
1875                 if(leaderfrags != WinningConditionHelper_topscore)
1876                 {
1877                         leaderfrags = WinningConditionHelper_topscore;
1878
1879                         if (limit)
1880                         if (leaderfrags == limit - 1)
1881                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1882                         else if (leaderfrags == limit - 2)
1883                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1884                         else if (leaderfrags == limit - 3)
1885                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1886                 }
1887         }
1888
1889         limitreached = false;
1890         if(limit)
1891                 if(WinningConditionHelper_topscore >= limit)
1892                         limitreached = true;
1893         if(leadlimit)
1894         {
1895                 float leadlimitreached;
1896                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1897                 if(autocvar_leadlimit_and_fraglimit)
1898                         limitreached = (limitreached && leadlimitreached);
1899                 else
1900                         limitreached = (limitreached || leadlimitreached);
1901         }
1902
1903         if(limit)
1904                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1905
1906         return GetWinningCode(
1907                 WinningConditionHelper_topscore && limitreached,
1908                 WinningConditionHelper_equality
1909         );
1910 }
1911
1912 float WinningCondition_Race(float fraglimit)
1913 {
1914         float wc;
1915         entity p;
1916         float n, c;
1917
1918         n = 0;
1919         c = 0;
1920         FOR_EACH_PLAYER(p)
1921         {
1922                 ++n;
1923                 if(p.race_completed)
1924                         ++c;
1925         }
1926         if(n && (n == c))
1927                 return WINNING_YES;
1928         wc = WinningCondition_Scores(fraglimit, 0);
1929
1930         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1931         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1932         // do NOT support equality when the laps are all raced!
1933                 return WINNING_STARTSUDDENDEATHOVERTIME;
1934         else
1935                 return WINNING_NEVER;
1936 }
1937
1938 float WinningCondition_QualifyingThenRace(float limit)
1939 {
1940         float wc;
1941         wc = WinningCondition_Scores(limit, 0);
1942
1943         // NEVER initiate overtime
1944         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1945         {
1946                 return WINNING_YES;
1947         }
1948
1949         return wc;
1950 }
1951
1952 float WinningCondition_RanOutOfSpawns()
1953 {
1954         entity head;
1955
1956         if(have_team_spawns <= 0)
1957                 return WINNING_NO;
1958
1959         if(autocvar_g_spawn_useallspawns <= 0)
1960                 return WINNING_NO;
1961
1962         if(!some_spawn_has_been_used)
1963                 return WINNING_NO;
1964
1965         team1_score = team2_score = team3_score = team4_score = 0;
1966
1967         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1968         {
1969                 if(head.team == NUM_TEAM_1)
1970                         team1_score = 1;
1971                 else if(head.team == NUM_TEAM_2)
1972                         team2_score = 1;
1973                 else if(head.team == NUM_TEAM_3)
1974                         team3_score = 1;
1975                 else if(head.team == NUM_TEAM_4)
1976                         team4_score = 1;
1977         }
1978
1979         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1980         {
1981                 if(head.team == NUM_TEAM_1)
1982                         team1_score = 1;
1983                 else if(head.team == NUM_TEAM_2)
1984                         team2_score = 1;
1985                 else if(head.team == NUM_TEAM_3)
1986                         team3_score = 1;
1987                 else if(head.team == NUM_TEAM_4)
1988                         team4_score = 1;
1989         }
1990
1991         ClearWinners();
1992         if(team1_score + team2_score + team3_score + team4_score == 0)
1993         {
1994                 checkrules_equality = true;
1995                 return WINNING_YES;
1996         }
1997         else if(team1_score + team2_score + team3_score + team4_score == 1)
1998         {
1999                 float t, i;
2000                 if(team1_score)
2001                         t = NUM_TEAM_1;
2002                 else if(team2_score)
2003                         t = NUM_TEAM_2;
2004                 else if(team3_score)
2005                         t = NUM_TEAM_3;
2006                 else // if(team4_score)
2007                         t = NUM_TEAM_4;
2008                 CheckAllowedTeams(world);
2009                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2010                 {
2011                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
2012                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
2013                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
2014                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
2015                 }
2016
2017                 AddWinners(team, t);
2018                 return WINNING_YES;
2019         }
2020         else
2021                 return WINNING_NO;
2022 }
2023
2024 /*
2025 ============
2026 CheckRules_World
2027
2028 Exit deathmatch games upon conditions
2029 ============
2030 */
2031 void ReadyRestart();
2032 void CheckRules_World()
2033 {
2034         float timelimit;
2035         float fraglimit;
2036         float leadlimit;
2037
2038         VoteThink();
2039         MapVote_Think();
2040
2041         SetDefaultAlpha();
2042
2043         if (gameover)   // someone else quit the game already
2044         {
2045                 if(player_count == 0) // Nobody there? Then let's go to the next map
2046                         MapVote_Start();
2047                         // this will actually check the player count in the next frame
2048                         // again, but this shouldn't hurt
2049                 return;
2050         }
2051
2052         timelimit = autocvar_timelimit * 60;
2053         fraglimit = autocvar_fraglimit;
2054         leadlimit = autocvar_leadlimit;
2055
2056         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2057         {
2058                 if(timelimit > 0)
2059                         timelimit = 0; // timelimit is not made for warmup
2060                 if(fraglimit > 0)
2061                         fraglimit = 0; // no fraglimit for now
2062                 leadlimit = 0; // no leadlimit for now
2063         }
2064
2065         if(timelimit > 0)
2066         {
2067                 timelimit += game_starttime;
2068         }
2069         else if (timelimit < 0)
2070         {
2071                 // endmatch
2072                 NextLevel();
2073                 return;
2074         }
2075
2076         if(g_onslaught)
2077                 timelimit = 0; // ONS has its own overtime rule
2078
2079         float wantovertime;
2080         wantovertime = 0;
2081
2082         if(timelimit > game_starttime)
2083                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
2084         else
2085                 game_completion_ratio = 0;
2086
2087         if(checkrules_suddendeathend)
2088         {
2089                 if(!checkrules_suddendeathwarning)
2090                 {
2091                         checkrules_suddendeathwarning = true;
2092                         if(g_race && !g_race_qualifying)
2093                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
2094                         else
2095                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
2096                 }
2097         }
2098         else
2099         {
2100                 if (timelimit && time >= timelimit)
2101                 {
2102                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2103                         {
2104                                 float totalplayers;
2105                                 float playerswithlaps;
2106                                 float readyplayers;
2107                                 entity head;
2108                                 totalplayers = playerswithlaps = readyplayers = 0;
2109                                 FOR_EACH_PLAYER(head)
2110                                 {
2111                                         ++totalplayers;
2112                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2113                                                 ++playerswithlaps;
2114                                         if(head.ready)
2115                                                 ++readyplayers;
2116                                 }
2117
2118                                 // at least 2 of the players have completed a lap: start the RACE
2119                                 // otherwise, the players should end the qualifying on their own
2120                                 if(readyplayers || playerswithlaps >= 2)
2121                                 {
2122                                         checkrules_suddendeathend = 0;
2123                                         ReadyRestart(); // go to race
2124                                         return;
2125                                 }
2126                                 else
2127                                         wantovertime |= InitiateSuddenDeath();
2128                         }
2129                         else
2130                                 wantovertime |= InitiateSuddenDeath();
2131                 }
2132         }
2133
2134         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2135         {
2136                 NextLevel();
2137                 return;
2138         }
2139
2140         float checkrules_status;
2141         checkrules_status = WinningCondition_RanOutOfSpawns();
2142         if(checkrules_status == WINNING_YES)
2143         {
2144                 bprint("Hey! Someone ran out of spawns!\n");
2145         }
2146         else if(g_race && !g_race_qualifying && timelimit >= 0)
2147         {
2148                 checkrules_status = WinningCondition_Race(fraglimit);
2149                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2150         }
2151         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2152         {
2153                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2154                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2155         }
2156         else if(g_assault)
2157         {
2158                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2159         }
2160         else if(g_lms)
2161         {
2162                 checkrules_status = WinningCondition_LMS();
2163         }
2164         else if (g_onslaught)
2165         {
2166                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2167         }
2168         else
2169         {
2170                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2171                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2172         }
2173
2174         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2175         {
2176                 checkrules_status = WINNING_NEVER;
2177                 checkrules_overtimesadded = -1;
2178                 wantovertime |= InitiateSuddenDeath();
2179         }
2180
2181         if(checkrules_status == WINNING_NEVER)
2182                 // equality cases! Nobody wins if the overtime ends in a draw.
2183                 ClearWinners();
2184
2185         if(wantovertime)
2186         {
2187                 if(checkrules_status == WINNING_NEVER)
2188                         InitiateOvertime();
2189                 else
2190                         checkrules_status = WINNING_YES;
2191         }
2192
2193         if(checkrules_suddendeathend)
2194                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2195                         checkrules_status = WINNING_YES;
2196
2197         if(checkrules_status == WINNING_YES)
2198         {
2199                 //print("WINNING\n");
2200                 NextLevel();
2201         }
2202 }
2203
2204 string GotoMap(string m)
2205 {
2206         m = GameTypeVote_MapInfo_FixName(m);
2207         if (!m)
2208                 return "The map you suggested is not available on this server.";
2209         if (!autocvar_sv_vote_gametype)
2210         if(!MapInfo_CheckMap(m))
2211                 return "The map you suggested does not support the current game mode.";
2212         cvar_set("nextmap", m);
2213         cvar_set("timelimit", "-1");
2214         if(mapvote_initialized || alreadychangedlevel)
2215         {
2216                 if(DoNextMapOverride(0))
2217                         return "Map switch initiated.";
2218                 else
2219                         return "Hm... no. For some reason I like THIS map more.";
2220         }
2221         else
2222                 return "Map switch will happen after scoreboard.";
2223 }
2224
2225
2226 void EndFrame()
2227 {
2228         anticheat_endframe();
2229
2230         float altime;
2231         FOR_EACH_REALCLIENT(self)
2232         {
2233                 entity e = IS_SPEC(self) ? self.enemy : self;
2234                 if(e.typehitsound)
2235                         self.typehit_time = time;
2236                 else if(e.damage_dealt)
2237                 {
2238                         self.hit_time = time;
2239                         self.damage_dealt_total += ceil(e.damage_dealt);
2240                 }
2241         }
2242         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2243         // add 1 frametime because after this, engine SV_Physics
2244         // increases time by a frametime and then networks the frame
2245         // add another frametime because client shows everything with
2246         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2247         // needed!
2248         FOR_EACH_CLIENT(self)
2249         {
2250                 self.typehitsound = false;
2251                 self.damage_dealt = 0;
2252                 antilag_record(self, altime);
2253         }
2254         FOR_EACH_MONSTER(self)
2255                 antilag_record(self, altime);
2256 }
2257
2258
2259 /*
2260  * RedirectionThink:
2261  * returns true if redirecting
2262  */
2263 float redirection_timeout;
2264 float redirection_nextthink;
2265 float RedirectionThink()
2266 {
2267         float clients_found;
2268
2269         if(redirection_target == "")
2270                 return false;
2271
2272         if(!redirection_timeout)
2273         {
2274                 cvar_set("sv_public", "-2");
2275                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2276                 if(redirection_target == "self")
2277                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2278                 else
2279                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2280         }
2281
2282         if(time < redirection_nextthink)
2283                 return true;
2284
2285         redirection_nextthink = time + 1;
2286
2287         clients_found = 0;
2288         FOR_EACH_REALCLIENT(self)
2289         {
2290                 // TODO add timer
2291                 print("Redirecting: sending connect command to ", self.netname, "\n");
2292                 if(redirection_target == "self")
2293                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2294                 else
2295                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2296                 ++clients_found;
2297         }
2298
2299         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2300
2301         if(time > redirection_timeout || clients_found == 0)
2302                 localcmd("\nwait; wait; wait; quit\n");
2303
2304         return true;
2305 }
2306
2307 void TargetMusic_RestoreGame();
2308 void RestoreGame()
2309 {
2310         // Loaded from a save game
2311         // some things then break, so let's work around them...
2312
2313         // Progs DB (capture records)
2314         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2315
2316         // Mapinfo
2317         MapInfo_Shutdown();
2318         MapInfo_Enumerate();
2319         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2320         WeaponStats_Init();
2321
2322         TargetMusic_RestoreGame();
2323 }
2324
2325 void Shutdown()
2326 {
2327         gameover = 2;
2328
2329         if(world_initialized > 0)
2330         {
2331                 world_initialized = 0;
2332                 print("Saving persistent data...\n");
2333                 Ban_SaveBans();
2334
2335                 // playerstats with unfinished match
2336                 PlayerStats_GameReport(false);
2337
2338                 if(!cheatcount_total)
2339                 {
2340                         if(autocvar_sv_db_saveasdump)
2341                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2342                         else
2343                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2344                 }
2345                 if(autocvar_developer)
2346                 {
2347                         if(autocvar_sv_db_saveasdump)
2348                                 db_dump(TemporaryDB, "server-temp.db");
2349                         else
2350                                 db_save(TemporaryDB, "server-temp.db");
2351                 }
2352                 CheatShutdown(); // must be after cheatcount check
2353                 db_close(ServerProgsDB);
2354                 db_close(TemporaryDB);
2355                 print("done!\n");
2356                 // tell the bot system the game is ending now
2357                 bot_endgame();
2358
2359                 WeaponStats_Shutdown();
2360                 MapInfo_Shutdown();
2361         }
2362         else if(world_initialized == 0)
2363         {
2364                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2365         }
2366 }